src/Tools/nbe.ML
author haftmann
Tue Dec 21 09:18:29 2010 +0100 (2010-12-21)
changeset 41346 6673f6fa94ca
parent 41247 c5cb19ecbd41
child 41472 f6ab14e61604
permissions -rw-r--r--
canonical handling of theory context argument
     1 (*  Title:      Tools/nbe.ML
     2     Authors:    Klaus Aehlig, LMU Muenchen; Tobias Nipkow, Florian Haftmann, TU Muenchen
     3 
     4 Normalization by evaluation, based on generic code generator.
     5 *)
     6 
     7 signature NBE =
     8 sig
     9   val dynamic_conv: theory -> conv
    10   val dynamic_value: theory -> term -> term
    11   val static_conv: theory -> string list -> conv
    12   val static_value: theory -> string list -> term -> term
    13 
    14   datatype Univ =
    15       Const of int * Univ list               (*named (uninterpreted) constants*)
    16     | DFree of string * int                  (*free (uninterpreted) dictionary parameters*)
    17     | BVar of int * Univ list
    18     | Abs of (int * (Univ list -> Univ)) * Univ list
    19   val apps: Univ -> Univ list -> Univ        (*explicit applications*)
    20   val abss: int -> (Univ list -> Univ) -> Univ
    21                                              (*abstractions as closures*)
    22   val same: Univ * Univ -> bool
    23 
    24   val put_result: (unit -> Univ list -> Univ list) -> Proof.context -> Proof.context
    25   val trace: bool Unsynchronized.ref
    26 
    27   val setup: theory -> theory
    28   val add_const_alias: thm -> theory -> theory
    29 end;
    30 
    31 structure Nbe: NBE =
    32 struct
    33 
    34 (* generic non-sense *)
    35 
    36 val trace = Unsynchronized.ref false;
    37 fun traced f x = if !trace then (tracing (f x); x) else x;
    38 
    39 
    40 (** certificates and oracle for "trivial type classes" **)
    41 
    42 structure Triv_Class_Data = Theory_Data
    43 (
    44   type T = (class * thm) list;
    45   val empty = [];
    46   val extend = I;
    47   fun merge data : T = AList.merge (op =) (K true) data;
    48 );
    49 
    50 fun add_const_alias thm thy =
    51   let
    52     val (ofclass, eqn) = case try Logic.dest_equals (Thm.prop_of thm)
    53      of SOME ofclass_eq => ofclass_eq
    54       | _ => error ("Bad certificate: " ^ Display.string_of_thm_global thy thm);
    55     val (T, class) = case try Logic.dest_of_class ofclass
    56      of SOME T_class => T_class
    57       | _ => error ("Bad certificate: " ^ Display.string_of_thm_global thy thm);
    58     val tvar = case try Term.dest_TVar T
    59      of SOME (tvar as (_, sort)) => if null (filter (can (AxClass.get_info thy)) sort)
    60           then tvar
    61           else error ("Bad sort: " ^ Display.string_of_thm_global thy thm)
    62       | _ => error ("Bad type: " ^ Display.string_of_thm_global thy thm);
    63     val _ = if Term.add_tvars eqn [] = [tvar] then ()
    64       else error ("Inconsistent type: " ^ Display.string_of_thm_global thy thm);
    65     val lhs_rhs = case try Logic.dest_equals eqn
    66      of SOME lhs_rhs => lhs_rhs
    67       | _ => error ("Not an equation: " ^ Syntax.string_of_term_global thy eqn);
    68     val c_c' = case try (pairself (AxClass.unoverload_const thy o dest_Const)) lhs_rhs
    69      of SOME c_c' => c_c'
    70       | _ => error ("Not an equation with two constants: "
    71           ^ Syntax.string_of_term_global thy eqn);
    72     val _ = if the_list (AxClass.class_of_param thy (snd c_c')) = [class] then ()
    73       else error ("Inconsistent class: " ^ Display.string_of_thm_global thy thm);
    74   in Triv_Class_Data.map (AList.update (op =) (class, thm)) thy end;
    75 
    76 local
    77 
    78 val get_triv_classes = map fst o Triv_Class_Data.get;
    79 
    80 val (_, triv_of_class) = Context.>>> (Context.map_theory_result
    81   (Thm.add_oracle (Binding.name "triv_of_class", fn (thy, T, class) =>
    82     Thm.cterm_of thy (Logic.mk_of_class (T, class)))));
    83 
    84 in
    85 
    86 fun lift_triv_classes_conv thy conv ct =
    87   let
    88     val algebra = Sign.classes_of thy;
    89     val certT = Thm.ctyp_of thy;
    90     val triv_classes = get_triv_classes thy;
    91     fun additional_classes sort = filter_out (fn class => Sorts.sort_le algebra (sort, [class])) triv_classes;
    92     fun mk_entry (v, sort) =
    93       let
    94         val T = TFree (v, sort);
    95         val cT = certT T;
    96         val triv_sort = additional_classes sort;
    97       in
    98         (v, (Sorts.inter_sort algebra (sort, triv_sort),
    99           (cT, AList.make (fn class => Thm.of_class (cT, class)) sort
   100             @ AList.make (fn class => triv_of_class (thy, T, class)) triv_sort)))
   101       end;
   102     val vs_tab = map mk_entry (Term.add_tfrees (Thm.term_of ct) []);
   103     fun instantiate thm =
   104       let
   105         val cert_tvars = map (certT o TVar) (Term.add_tvars
   106           ((fst o Logic.dest_equals o Logic.strip_imp_concl o Thm.prop_of) thm) []);
   107         val instantiation =
   108           map2 (fn cert_tvar => fn (_, (_, (cT, _))) => (cert_tvar, cT)) cert_tvars vs_tab;
   109       in Thm.instantiate (instantiation, []) thm end;
   110     fun of_class (TFree (v, _), class) =
   111           the (AList.lookup (op =) ((snd o snd o the o AList.lookup (op =) vs_tab) v) class)
   112       | of_class (T, _) = error ("Bad type " ^ Syntax.string_of_typ_global thy T);
   113     fun strip_of_class thm =
   114       let
   115         val prems_of_class = Thm.prop_of thm
   116           |> Logic.strip_imp_prems
   117           |> map (Logic.dest_of_class #> of_class);
   118       in fold Thm.elim_implies prems_of_class thm end;
   119   in
   120     ct
   121     |> (Drule.cterm_fun o map_types o map_type_tfree)
   122         (fn (v, sort) => TFree (v, (fst o the o AList.lookup (op =) vs_tab) v))
   123     |> conv
   124     |> Thm.strip_shyps
   125     |> Thm.varifyT_global
   126     |> Thm.unconstrainT
   127     |> instantiate
   128     |> strip_of_class
   129   end;
   130 
   131 fun lift_triv_classes_rew thy rew t =
   132   let
   133     val algebra = Sign.classes_of thy;
   134     val triv_classes = get_triv_classes thy;
   135     val vs = Term.add_tfrees t [];
   136   in t
   137     |> (map_types o map_type_tfree)
   138         (fn (v, sort) => TFree (v, Sorts.inter_sort algebra (sort, triv_classes)))
   139     |> rew
   140     |> (map_types o map_type_tfree)
   141         (fn (v, _) => TFree (v, the (AList.lookup (op =) vs v)))
   142   end;
   143 
   144 end;
   145 
   146 
   147 (** the semantic universe **)
   148 
   149 (*
   150    Functions are given by their semantical function value. To avoid
   151    trouble with the ML-type system, these functions have the most
   152    generic type, that is "Univ list -> Univ". The calling convention is
   153    that the arguments come as a list, the last argument first. In
   154    other words, a function call that usually would look like
   155 
   156    f x_1 x_2 ... x_n   or   f(x_1,x_2, ..., x_n)
   157 
   158    would be in our convention called as
   159 
   160               f [x_n,..,x_2,x_1]
   161 
   162    Moreover, to handle functions that are still waiting for some
   163    arguments we have additionally a list of arguments collected to far
   164    and the number of arguments we're still waiting for.
   165 *)
   166 
   167 datatype Univ =
   168     Const of int * Univ list           (*named (uninterpreted) constants*)
   169   | DFree of string * int              (*free (uninterpreted) dictionary parameters*)
   170   | BVar of int * Univ list            (*bound variables, named*)
   171   | Abs of (int * (Univ list -> Univ)) * Univ list
   172                                        (*abstractions as closures*);
   173 
   174 
   175 (* constructor functions *)
   176 
   177 fun abss n f = Abs ((n, f), []);
   178 fun apps (Abs ((n, f), xs)) ys = let val k = n - length ys in
   179       case int_ord (k, 0)
   180        of EQUAL => f (ys @ xs)
   181         | LESS => let val (zs, ws) = chop (~ k) ys in apps (f (ws @ xs)) zs end
   182         | GREATER => Abs ((k, f), ys @ xs) (*note: reverse convention also for apps!*)
   183       end
   184   | apps (Const (name, xs)) ys = Const (name, ys @ xs)
   185   | apps (BVar (n, xs)) ys = BVar (n, ys @ xs);
   186 
   187 fun same (Const (k, xs), Const (l, ys)) = k = l andalso eq_list same (xs, ys)
   188   | same (DFree (s, k), DFree (t, l)) = s = t andalso k = l
   189   | same (BVar (k, xs), BVar (l, ys)) = k = l andalso eq_list same (xs, ys)
   190   | same _ = false;
   191 
   192 
   193 (** assembling and compiling ML code from terms **)
   194 
   195 (* abstract ML syntax *)
   196 
   197 infix 9 `$` `$$`;
   198 fun e1 `$` e2 = "(" ^ e1 ^ " " ^ e2 ^ ")";
   199 fun e `$$` [] = e
   200   | e `$$` es = "(" ^ e ^ " " ^ space_implode " " es ^ ")";
   201 fun ml_abs v e = "(fn " ^ v ^ " => " ^ e ^ ")";
   202 
   203 fun ml_cases t cs =
   204   "(case " ^ t ^ " of " ^ space_implode " | " (map (fn (p, t) => p ^ " => " ^ t) cs) ^ ")";
   205 fun ml_Let d e = "let\n" ^ d ^ " in " ^ e ^ " end";
   206 fun ml_as v t = "(" ^ v ^ " as " ^ t ^ ")";
   207 
   208 fun ml_and [] = "true"
   209   | ml_and [x] = x
   210   | ml_and xs = "(" ^ space_implode " andalso " xs ^ ")";
   211 fun ml_if b x y = "(if " ^ b ^ " then " ^ x ^ " else " ^ y ^ ")";
   212 
   213 fun ml_list es = "[" ^ commas es ^ "]";
   214 
   215 fun ml_fundefs ([(name, [([], e)])]) =
   216       "val " ^ name ^ " = " ^ e ^ "\n"
   217   | ml_fundefs (eqs :: eqss) =
   218       let
   219         fun fundef (name, eqs) =
   220           let
   221             fun eqn (es, e) = name ^ " " ^ space_implode " " es ^ " = " ^ e
   222           in space_implode "\n  | " (map eqn eqs) end;
   223       in
   224         (prefix "fun " o fundef) eqs :: map (prefix "and " o fundef) eqss
   225         |> cat_lines
   226         |> suffix "\n"
   227       end;
   228 
   229 
   230 (* nbe specific syntax and sandbox communication *)
   231 
   232 structure Univs = Proof_Data (
   233   type T = unit -> Univ list -> Univ list
   234   fun init _ () = error "Univs"
   235 );
   236 val put_result = Univs.put;
   237 
   238 local
   239   val prefix =     "Nbe.";
   240   val name_put =   prefix ^ "put_result";
   241   val name_ref =   prefix ^ "univs_ref";
   242   val name_const = prefix ^ "Const";
   243   val name_abss =  prefix ^ "abss";
   244   val name_apps =  prefix ^ "apps";
   245   val name_same =  prefix ^ "same";
   246 in
   247 
   248 val univs_cookie = (Univs.get, put_result, name_put);
   249 
   250 fun nbe_fun 0 "" = "nbe_value"
   251   | nbe_fun i c = "c_" ^ translate_string (fn "." => "_" | c => c) c ^ "_" ^ string_of_int i;
   252 fun nbe_dict v n = "d_" ^ v ^ "_" ^ string_of_int n;
   253 fun nbe_bound v = "v_" ^ v;
   254 fun nbe_bound_optional NONE = "_"
   255   | nbe_bound_optional (SOME v) = nbe_bound v;
   256 fun nbe_default v = "w_" ^ v;
   257 
   258 (*note: these three are the "turning spots" where proper argument order is established!*)
   259 fun nbe_apps t [] = t
   260   | nbe_apps t ts = name_apps `$$` [t, ml_list (rev ts)];
   261 fun nbe_apps_local i c ts = nbe_fun i c `$` ml_list (rev ts);
   262 fun nbe_apps_constr idx_of c ts =
   263   let
   264     val c' = if !trace then string_of_int (idx_of c) ^ " (*" ^ c ^ "*)"
   265       else string_of_int (idx_of c);
   266   in name_const `$` ("(" ^ c' ^ ", " ^ ml_list (rev ts) ^ ")") end;
   267 
   268 fun nbe_abss 0 f = f `$` ml_list []
   269   | nbe_abss n f = name_abss `$$` [string_of_int n, f];
   270 
   271 fun nbe_same (v1, v2) = "(" ^ name_same ^ " (" ^ nbe_bound v1 ^ ", " ^ nbe_bound v2 ^ "))";
   272 
   273 end;
   274 
   275 open Basic_Code_Thingol;
   276 
   277 
   278 (* code generation *)
   279 
   280 fun assemble_eqnss idx_of deps eqnss =
   281   let
   282     fun prep_eqns (c, (vs, eqns)) =
   283       let
   284         val dicts = maps (fn (v, sort) => map_index (nbe_dict v o fst) sort) vs;
   285         val num_args = length dicts + ((length o fst o hd) eqns);
   286       in (c, (num_args, (dicts, eqns))) end;
   287     val eqnss' = map prep_eqns eqnss;
   288 
   289     fun assemble_constapp c dss ts = 
   290       let
   291         val ts' = (maps o map) assemble_dict dss @ ts;
   292       in case AList.lookup (op =) eqnss' c
   293        of SOME (num_args, _) => if num_args <= length ts'
   294             then let val (ts1, ts2) = chop num_args ts'
   295             in nbe_apps (nbe_apps_local 0 c ts1) ts2
   296             end else nbe_apps (nbe_abss num_args (nbe_fun 0 c)) ts'
   297         | NONE => if member (op =) deps c
   298             then nbe_apps (nbe_fun 0 c) ts'
   299             else nbe_apps_constr idx_of c ts'
   300       end
   301     and assemble_classrels classrels =
   302       fold_rev (fn classrel => assemble_constapp classrel [] o single) classrels
   303     and assemble_dict (Dict (classrels, x)) =
   304           assemble_classrels classrels (assemble_plain_dict x)
   305     and assemble_plain_dict (Dict_Const (inst, dss)) =
   306           assemble_constapp inst dss []
   307       | assemble_plain_dict (Dict_Var (v, (n, _))) =
   308           nbe_dict v n
   309 
   310     fun assemble_iterm constapp =
   311       let
   312         fun of_iterm match_cont t =
   313           let
   314             val (t', ts) = Code_Thingol.unfold_app t
   315           in of_iapp match_cont t' (fold_rev (cons o of_iterm NONE) ts []) end
   316         and of_iapp match_cont (IConst (c, ((_, dss), _))) ts = constapp c dss ts
   317           | of_iapp match_cont (IVar v) ts = nbe_apps (nbe_bound_optional v) ts
   318           | of_iapp match_cont ((v, _) `|=> t) ts =
   319               nbe_apps (nbe_abss 1 (ml_abs (ml_list [nbe_bound_optional v]) (of_iterm NONE t))) ts
   320           | of_iapp match_cont (ICase (((t, _), cs), t0)) ts =
   321               nbe_apps (ml_cases (of_iterm NONE t)
   322                 (map (fn (p, t) => (of_iterm NONE p, of_iterm match_cont t)) cs
   323                   @ [("_", case match_cont of SOME s => s | NONE => of_iterm NONE t0)])) ts
   324       in of_iterm end;
   325 
   326     fun subst_nonlin_vars args =
   327       let
   328         val vs = (fold o Code_Thingol.fold_varnames)
   329           (fn v => AList.map_default (op =) (v, 0) (Integer.add 1)) args [];
   330         val names = Name.make_context (map fst vs);
   331         fun declare v k ctxt = let val vs = Name.invents ctxt v k
   332           in (vs, fold Name.declare vs ctxt) end;
   333         val (vs_renames, _) = fold_map (fn (v, k) => if k > 1
   334           then declare v (k - 1) #>> (fn vs => (v, vs))
   335           else pair (v, [])) vs names;
   336         val samepairs = maps (fn (v, vs) => map (pair v) vs) vs_renames;
   337         fun subst_vars (t as IConst _) samepairs = (t, samepairs)
   338           | subst_vars (t as IVar NONE) samepairs = (t, samepairs)
   339           | subst_vars (t as IVar (SOME v)) samepairs = (case AList.lookup (op =) samepairs v
   340              of SOME v' => (IVar (SOME v'), AList.delete (op =) v samepairs)
   341               | NONE => (t, samepairs))
   342           | subst_vars (t1 `$ t2) samepairs = samepairs
   343               |> subst_vars t1
   344               ||>> subst_vars t2
   345               |>> (op `$)
   346           | subst_vars (ICase (_, t)) samepairs = subst_vars t samepairs;
   347         val (args', _) = fold_map subst_vars args samepairs;
   348       in (samepairs, args') end;
   349 
   350     fun assemble_eqn c dicts default_args (i, (args, rhs)) =
   351       let
   352         val is_eval = (c = "");
   353         val default_rhs = nbe_apps_local (i+1) c (dicts @ default_args);
   354         val match_cont = if is_eval then NONE else SOME default_rhs;
   355         val assemble_arg = assemble_iterm
   356           (fn c => fn _ => fn ts => nbe_apps_constr idx_of c ts) NONE;
   357         val assemble_rhs = assemble_iterm assemble_constapp match_cont;
   358         val (samepairs, args') = subst_nonlin_vars args;
   359         val s_args = map assemble_arg args';
   360         val s_rhs = if null samepairs then assemble_rhs rhs
   361           else ml_if (ml_and (map nbe_same samepairs))
   362             (assemble_rhs rhs) default_rhs;
   363         val eqns = if is_eval then
   364             [([ml_list (rev (dicts @ s_args))], s_rhs)]
   365           else
   366             [([ml_list (rev (dicts @ map2 ml_as default_args s_args))], s_rhs),
   367               ([ml_list (rev (dicts @ default_args))], default_rhs)]
   368       in (nbe_fun i c, eqns) end;
   369 
   370     fun assemble_eqns (c, (num_args, (dicts, eqns))) =
   371       let
   372         val default_args = map nbe_default
   373           (Name.invent_list [] "a" (num_args - length dicts));
   374         val eqns' = map_index (assemble_eqn c dicts default_args) eqns
   375           @ (if c = "" then [] else [(nbe_fun (length eqns) c,
   376             [([ml_list (rev (dicts @ default_args))],
   377               nbe_apps_constr idx_of c (dicts @ default_args))])]);
   378       in (eqns', nbe_abss num_args (nbe_fun 0 c)) end;
   379 
   380     val (fun_vars, fun_vals) = map_split assemble_eqns eqnss';
   381     val deps_vars = ml_list (map (nbe_fun 0) deps);
   382   in ml_abs deps_vars (ml_Let (ml_fundefs (flat fun_vars)) (ml_list fun_vals)) end;
   383 
   384 
   385 (* compile equations *)
   386 
   387 fun compile_eqnss thy nbe_program raw_deps [] = []
   388   | compile_eqnss thy nbe_program raw_deps eqnss =
   389       let
   390         val ctxt = ProofContext.init_global thy;
   391         val (deps, deps_vals) = split_list (map_filter
   392           (fn dep => Option.map (fn univ => (dep, univ)) (fst ((Graph.get_node nbe_program dep)))) raw_deps);
   393         val idx_of = raw_deps
   394           |> map (fn dep => (dep, snd (Graph.get_node nbe_program dep)))
   395           |> AList.lookup (op =)
   396           |> (fn f => the o f);
   397         val s = assemble_eqnss idx_of deps eqnss;
   398         val cs = map fst eqnss;
   399       in
   400         s
   401         |> traced (fn s => "\n--- code to be evaluated:\n" ^ s)
   402         |> pair ""
   403         |> Code_Runtime.value ctxt univs_cookie
   404         |> (fn f => f deps_vals)
   405         |> (fn univs => cs ~~ univs)
   406       end;
   407 
   408 
   409 (* extract equations from statements *)
   410 
   411 fun eqns_of_stmt (_, Code_Thingol.Fun (_, ((_, []), _))) =
   412       []
   413   | eqns_of_stmt (const, Code_Thingol.Fun (_, (((vs, _), eqns), _))) =
   414       [(const, (vs, map fst eqns))]
   415   | eqns_of_stmt (_, Code_Thingol.Datatypecons _) =
   416       []
   417   | eqns_of_stmt (_, Code_Thingol.Datatype _) =
   418       []
   419   | eqns_of_stmt (class, Code_Thingol.Class (_, (v, (super_classes, classparams)))) =
   420       let
   421         val names = map snd super_classes @ map fst classparams;
   422         val params = Name.invent_list [] "d" (length names);
   423         fun mk (k, name) =
   424           (name, ([(v, [])],
   425             [([IConst (class, (([], []), [])) `$$ map (IVar o SOME) params],
   426               IVar (SOME (nth params k)))]));
   427       in map_index mk names end
   428   | eqns_of_stmt (_, Code_Thingol.Classrel _) =
   429       []
   430   | eqns_of_stmt (_, Code_Thingol.Classparam _) =
   431       []
   432   | eqns_of_stmt (inst, Code_Thingol.Classinst ((class, (_, arity_args)), (super_instances, (classparam_instances, _)))) =
   433       [(inst, (arity_args, [([], IConst (class, (([], []), [])) `$$
   434         map (fn (_, (_, (inst, dss))) => IConst (inst, (([], dss), []))) super_instances
   435         @ map (IConst o snd o fst) classparam_instances)]))];
   436 
   437 
   438 (* compile whole programs *)
   439 
   440 fun ensure_const_idx name (nbe_program, (maxidx, idx_tab)) =
   441   if can (Graph.get_node nbe_program) name
   442   then (nbe_program, (maxidx, idx_tab))
   443   else (Graph.new_node (name, (NONE, maxidx)) nbe_program,
   444     (maxidx + 1, Inttab.update_new (maxidx, name) idx_tab));
   445 
   446 fun compile_stmts thy stmts_deps =
   447   let
   448     val names = map (fst o fst) stmts_deps;
   449     val names_deps = map (fn ((name, _), deps) => (name, deps)) stmts_deps;
   450     val eqnss = maps (eqns_of_stmt o fst) stmts_deps;
   451     val refl_deps = names_deps
   452       |> maps snd
   453       |> distinct (op =)
   454       |> fold (insert (op =)) names;
   455     fun compile nbe_program = eqnss
   456       |> compile_eqnss thy nbe_program refl_deps
   457       |> rpair nbe_program;
   458   in
   459     fold ensure_const_idx refl_deps
   460     #> apfst (fold (fn (name, deps) => fold (curry Graph.add_edge name) deps) names_deps
   461       #> compile
   462       #-> fold (fn (name, univ) => (Graph.map_node name o apfst) (K (SOME univ))))
   463   end;
   464 
   465 fun compile_program thy program =
   466   let
   467     fun add_stmts names (nbe_program, (maxidx, idx_tab)) = if exists ((can o Graph.get_node) nbe_program) names
   468       then (nbe_program, (maxidx, idx_tab))
   469       else (nbe_program, (maxidx, idx_tab))
   470         |> compile_stmts thy (map (fn name => ((name, Graph.get_node program name),
   471           Graph.imm_succs program name)) names);
   472   in
   473     fold_rev add_stmts (Graph.strong_conn program)
   474   end;
   475 
   476 
   477 (** evaluation **)
   478 
   479 (* term evaluation by compilation *)
   480 
   481 fun compile_term thy nbe_program deps (vs : (string * sort) list, t) =
   482   let 
   483     val dict_frees = maps (fn (v, sort) => map_index (curry DFree v o fst) sort) vs;
   484   in
   485     ("", (vs, [([], t)]))
   486     |> singleton (compile_eqnss thy nbe_program deps)
   487     |> snd
   488     |> (fn t => apps t (rev dict_frees))
   489   end;
   490 
   491 
   492 (* reconstruction *)
   493 
   494 fun typ_of_itype program vs (ityco `%% itys) =
   495       let
   496         val Code_Thingol.Datatype (tyco, _) = Graph.get_node program ityco;
   497       in Type (tyco, map (typ_of_itype program vs) itys) end
   498   | typ_of_itype program vs (ITyVar v) =
   499       let
   500         val sort = (the o AList.lookup (op =) vs) v;
   501       in TFree ("'" ^ v, sort) end;
   502 
   503 fun term_of_univ thy program idx_tab t =
   504   let
   505     fun take_until f [] = []
   506       | take_until f (x::xs) = if f x then [] else x :: take_until f xs;
   507     fun is_dict (Const (idx, _)) = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   508          of Code_Thingol.Class _ => true
   509           | Code_Thingol.Classrel _ => true
   510           | Code_Thingol.Classinst _ => true
   511           | _ => false)
   512       | is_dict (DFree _) = true
   513       | is_dict _ = false;
   514     fun const_of_idx idx = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   515      of Code_Thingol.Fun (c, _) => c
   516       | Code_Thingol.Datatypecons (c, _) => c
   517       | Code_Thingol.Classparam (c, _) => c);
   518     fun of_apps bounds (t, ts) =
   519       fold_map (of_univ bounds) ts
   520       #>> (fn ts' => list_comb (t, rev ts'))
   521     and of_univ bounds (Const (idx, ts)) typidx =
   522           let
   523             val ts' = take_until is_dict ts;
   524             val c = const_of_idx idx;
   525             val T = map_type_tvar (fn ((v, i), _) =>
   526               Type_Infer.param typidx (v ^ string_of_int i, []))
   527                 (Sign.the_const_type thy c);
   528             val typidx' = typidx + 1;
   529           in of_apps bounds (Term.Const (c, T), ts') typidx' end
   530       | of_univ bounds (BVar (n, ts)) typidx =
   531           of_apps bounds (Bound (bounds - n - 1), ts) typidx
   532       | of_univ bounds (t as Abs _) typidx =
   533           typidx
   534           |> of_univ (bounds + 1) (apps t [BVar (bounds, [])])
   535           |-> (fn t' => pair (Term.Abs ("u", dummyT, t')))
   536   in of_univ 0 t 0 |> fst end;
   537 
   538 
   539 (* evaluation with type reconstruction *)
   540 
   541 fun eval_term thy program (nbe_program, idx_tab) ((vs0, (vs, ty)), t) deps =
   542   let
   543     val ctxt = Syntax.init_pretty_global thy;
   544     val string_of_term = Syntax.string_of_term (Config.put show_types true ctxt);
   545     val ty' = typ_of_itype program vs0 ty;
   546     fun type_infer t = singleton
   547       (Type_Infer.infer_types ctxt (try (Type.strip_sorts o Sign.the_const_type thy)) (K NONE))
   548       (Type.constraint ty' t);
   549     fun check_tvars t =
   550       if null (Term.add_tvars t []) then t
   551       else error ("Illegal schematic type variables in normalized term: " ^ string_of_term t);
   552   in
   553     compile_term thy nbe_program deps (vs, t)
   554     |> term_of_univ thy program idx_tab
   555     |> traced (fn t => "Normalized:\n" ^ string_of_term t)
   556     |> type_infer
   557     |> traced (fn t => "Types inferred:\n" ^ string_of_term t)
   558     |> check_tvars
   559     |> traced (fn _ => "---\n")
   560   end;
   561 
   562 
   563 (* function store *)
   564 
   565 structure Nbe_Functions = Code_Data
   566 (
   567   type T = (Univ option * int) Graph.T * (int * string Inttab.table);
   568   val empty = (Graph.empty, (0, Inttab.empty));
   569 );
   570 
   571 fun compile ignore_cache thy program =
   572   let
   573     val (nbe_program, (_, idx_tab)) =
   574       Nbe_Functions.change (if ignore_cache then NONE else SOME thy)
   575         (compile_program thy program);
   576   in (nbe_program, idx_tab) end;
   577 
   578 
   579 (* dynamic evaluation oracle *)
   580 
   581 fun mk_equals thy lhs raw_rhs =
   582   let
   583     val ty = Thm.typ_of (Thm.ctyp_of_term lhs);
   584     val eq = Thm.cterm_of thy (Term.Const ("==", ty --> ty --> propT));
   585     val rhs = Thm.cterm_of thy raw_rhs;
   586   in Thm.mk_binop eq lhs rhs end;
   587 
   588 val (_, raw_oracle) = Context.>>> (Context.map_theory_result
   589   (Thm.add_oracle (Binding.name "normalization_by_evaluation",
   590     fn (thy, program, nbe_program_idx_tab, vsp_ty_t, deps, ct) =>
   591       mk_equals thy ct (eval_term thy program nbe_program_idx_tab vsp_ty_t deps))));
   592 
   593 fun oracle thy program nbe_program_idx_tab vsp_ty_t deps ct =
   594   raw_oracle (thy, program, nbe_program_idx_tab, vsp_ty_t, deps, ct);
   595 
   596 fun dynamic_conv thy = lift_triv_classes_conv thy (Code_Thingol.dynamic_conv thy
   597     (K (fn program => oracle thy program (compile false thy program))));
   598 
   599 fun dynamic_value thy = lift_triv_classes_rew thy
   600   (Code_Thingol.dynamic_value thy I
   601     (K (fn program => eval_term thy program (compile false thy program))));
   602 
   603 fun static_conv thy consts =
   604   lift_triv_classes_conv thy (Code_Thingol.static_conv thy consts
   605     (K (fn program => fn _ => let val nbe_program = compile true thy program
   606       in oracle thy program nbe_program end)));
   607 
   608 fun static_value thy consts = lift_triv_classes_rew thy
   609   (Code_Thingol.static_value thy I consts
   610     (K (fn program => fn _ => let val nbe_program = compile true thy program
   611       in eval_term thy program (compile false thy program) end)));
   612 
   613 
   614 (** setup **)
   615 
   616 val setup = Value.add_evaluator ("nbe", dynamic_value o ProofContext.theory_of);
   617 
   618 end;
   619