src/HOL/List.thy
author wenzelm
Sat Apr 08 22:51:06 2006 +0200 (2006-04-08)
changeset 19363 667b5ea637dd
parent 19302 e1bda4fc1d1d
child 19390 6c7383f80ad1
permissions -rw-r--r--
refined 'abbreviation';
     1 (*  Title:      HOL/List.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* The datatype of finite lists *}
     7 
     8 theory List
     9 imports PreList
    10 begin
    11 
    12 datatype 'a list =
    13     Nil    ("[]")
    14   | Cons 'a  "'a list"    (infixr "#" 65)
    15 
    16 subsection{*Basic list processing functions*}
    17 
    18 consts
    19   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    20   filter:: "('a => bool) => 'a list => 'a list"
    21   concat:: "'a list list => 'a list"
    22   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    23   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    24   hd:: "'a list => 'a"
    25   tl:: "'a list => 'a list"
    26   last:: "'a list => 'a"
    27   butlast :: "'a list => 'a list"
    28   set :: "'a list => 'a set"
    29   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    30   map :: "('a=>'b) => ('a list => 'b list)"
    31   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    32   list_update :: "'a list => nat => 'a => 'a list"
    33   take:: "nat => 'a list => 'a list"
    34   drop:: "nat => 'a list => 'a list"
    35   takeWhile :: "('a => bool) => 'a list => 'a list"
    36   dropWhile :: "('a => bool) => 'a list => 'a list"
    37   rev :: "'a list => 'a list"
    38   zip :: "'a list => 'b list => ('a * 'b) list"
    39   upt :: "nat => nat => nat list" ("(1[_..</_'])")
    40   remdups :: "'a list => 'a list"
    41   remove1 :: "'a => 'a list => 'a list"
    42   null:: "'a list => bool"
    43   "distinct":: "'a list => bool"
    44   replicate :: "nat => 'a => 'a list"
    45   rotate1 :: "'a list \<Rightarrow> 'a list"
    46   rotate :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list"
    47   sublist :: "'a list => nat set => 'a list"
    48 (* For efficiency *)
    49   mem :: "'a => 'a list => bool"    (infixl 55)
    50   list_inter :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
    51   list_ex :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool"
    52   list_all:: "('a => bool) => ('a list => bool)"
    53   itrev :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
    54   filtermap :: "('a \<Rightarrow> 'b option) \<Rightarrow> 'a list \<Rightarrow> 'b list"
    55   map_filter :: "('a => 'b) => ('a => bool) => 'a list => 'b list"
    56 
    57 abbreviation
    58   upto:: "nat => nat => nat list"    ("(1[_../_])")
    59   "[i..j] == [i..<(Suc j)]"
    60 
    61 
    62 nonterminals lupdbinds lupdbind
    63 
    64 syntax
    65   -- {* list Enumeration *}
    66   "@list" :: "args => 'a list"    ("[(_)]")
    67 
    68   -- {* Special syntax for filter *}
    69   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    70 
    71   -- {* list update *}
    72   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    73   "" :: "lupdbind => lupdbinds"    ("_")
    74   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    75   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    76 
    77 translations
    78   "[x, xs]" == "x#[xs]"
    79   "[x]" == "x#[]"
    80   "[x:xs . P]"== "filter (%x. P) xs"
    81 
    82   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    83   "xs[i:=x]" == "list_update xs i x"
    84 
    85 
    86 syntax (xsymbols)
    87   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    88 syntax (HTML output)
    89   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    90 
    91 
    92 text {*
    93   Function @{text size} is overloaded for all datatypes. Users may
    94   refer to the list version as @{text length}. *}
    95 
    96 abbreviation
    97   length :: "'a list => nat"
    98   "length == size"
    99 
   100 primrec
   101   "hd(x#xs) = x"
   102 
   103 primrec
   104   "tl([]) = []"
   105   "tl(x#xs) = xs"
   106 
   107 primrec
   108   "null([]) = True"
   109   "null(x#xs) = False"
   110 
   111 primrec
   112   "last(x#xs) = (if xs=[] then x else last xs)"
   113 
   114 primrec
   115   "butlast []= []"
   116   "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   117 
   118 primrec
   119   "set [] = {}"
   120   "set (x#xs) = insert x (set xs)"
   121 
   122 primrec
   123   "map f [] = []"
   124   "map f (x#xs) = f(x)#map f xs"
   125 
   126 primrec
   127   append_Nil:"[]@ys = ys"
   128   append_Cons: "(x#xs)@ys = x#(xs@ys)"
   129 
   130 primrec
   131   "rev([]) = []"
   132   "rev(x#xs) = rev(xs) @ [x]"
   133 
   134 primrec
   135   "filter P [] = []"
   136   "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   137 
   138 primrec
   139   foldl_Nil:"foldl f a [] = a"
   140   foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   141 
   142 primrec
   143   "foldr f [] a = a"
   144   "foldr f (x#xs) a = f x (foldr f xs a)"
   145 
   146 primrec
   147   "concat([]) = []"
   148   "concat(x#xs) = x @ concat(xs)"
   149 
   150 primrec
   151   drop_Nil:"drop n [] = []"
   152   drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   153   -- {*Warning: simpset does not contain this definition, but separate
   154        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   155 
   156 primrec
   157   take_Nil:"take n [] = []"
   158   take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   159   -- {*Warning: simpset does not contain this definition, but separate
   160        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   161 
   162 primrec
   163   nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   164   -- {*Warning: simpset does not contain this definition, but separate
   165        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   166 
   167 primrec
   168   "[][i:=v] = []"
   169   "(x#xs)[i:=v] = (case i of 0 => v # xs | Suc j => x # xs[j:=v])"
   170 
   171 primrec
   172   "takeWhile P [] = []"
   173   "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   174 
   175 primrec
   176   "dropWhile P [] = []"
   177   "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   178 
   179 primrec
   180   "zip xs [] = []"
   181   zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   182   -- {*Warning: simpset does not contain this definition, but separate
   183        theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   184 
   185 primrec
   186   upt_0: "[i..<0] = []"
   187   upt_Suc: "[i..<(Suc j)] = (if i <= j then [i..<j] @ [j] else [])"
   188 
   189 primrec
   190   "distinct [] = True"
   191   "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   192 
   193 primrec
   194   "remdups [] = []"
   195   "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   196 
   197 primrec
   198   "remove1 x [] = []"
   199   "remove1 x (y#xs) = (if x=y then xs else y # remove1 x xs)"
   200 
   201 primrec
   202   replicate_0: "replicate 0 x = []"
   203   replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   204 
   205 defs
   206 rotate1_def: "rotate1 xs == (case xs of [] \<Rightarrow> [] | x#xs \<Rightarrow> xs @ [x])"
   207 rotate_def:  "rotate n == rotate1 ^ n"
   208 
   209 list_all2_def:
   210  "list_all2 P xs ys ==
   211   length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   212 
   213 sublist_def:
   214  "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..<size xs]))"
   215 
   216 primrec
   217   "x mem [] = False"
   218   "x mem (y#ys) = (if y=x then True else x mem ys)"
   219 
   220 primrec
   221  "list_inter [] bs = []"
   222  "list_inter (a#as) bs =
   223   (if a \<in> set bs then a#(list_inter as bs) else list_inter as bs)"
   224 
   225 primrec
   226   "list_all P [] = True"
   227   "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   228 
   229 primrec
   230 "list_ex P [] = False"
   231 "list_ex P (x#xs) = (P x \<or> list_ex P xs)"
   232 
   233 primrec
   234  "filtermap f [] = []"
   235  "filtermap f (x#xs) =
   236     (case f x of None \<Rightarrow> filtermap f xs
   237      | Some y \<Rightarrow> y # (filtermap f xs))"
   238 
   239 primrec
   240   "map_filter f P [] = []"
   241   "map_filter f P (x#xs) = (if P x then f x # map_filter f P xs else 
   242                map_filter f P xs)"
   243 
   244 primrec
   245 "itrev [] ys = ys"
   246 "itrev (x#xs) ys = itrev xs (x#ys)"
   247 
   248 
   249 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   250 by (induct xs) auto
   251 
   252 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   253 
   254 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   255 by (induct xs) auto
   256 
   257 lemma length_induct:
   258 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   259 by (rule measure_induct [of length]) iprover
   260 
   261 
   262 subsubsection {* @{text length} *}
   263 
   264 text {*
   265 Needs to come before @{text "@"} because of theorem @{text
   266 append_eq_append_conv}.
   267 *}
   268 
   269 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   270 by (induct xs) auto
   271 
   272 lemma length_map [simp]: "length (map f xs) = length xs"
   273 by (induct xs) auto
   274 
   275 lemma length_rev [simp]: "length (rev xs) = length xs"
   276 by (induct xs) auto
   277 
   278 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   279 by (cases xs) auto
   280 
   281 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   282 by (induct xs) auto
   283 
   284 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   285 by (induct xs) auto
   286 
   287 lemma length_Suc_conv:
   288 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   289 by (induct xs) auto
   290 
   291 lemma Suc_length_conv:
   292 "(Suc n = length xs) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   293 apply (induct xs, simp, simp)
   294 apply blast
   295 done
   296 
   297 lemma impossible_Cons [rule_format]: 
   298   "length xs <= length ys --> xs = x # ys = False"
   299 apply (induct xs, auto)
   300 done
   301 
   302 lemma list_induct2[consumes 1]: "\<And>ys.
   303  \<lbrakk> length xs = length ys;
   304    P [] [];
   305    \<And>x xs y ys. \<lbrakk> length xs = length ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys) \<rbrakk>
   306  \<Longrightarrow> P xs ys"
   307 apply(induct xs)
   308  apply simp
   309 apply(case_tac ys)
   310  apply simp
   311 apply(simp)
   312 done
   313 
   314 subsubsection {* @{text "@"} -- append *}
   315 
   316 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   317 by (induct xs) auto
   318 
   319 lemma append_Nil2 [simp]: "xs @ [] = xs"
   320 by (induct xs) auto
   321 
   322 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   323 by (induct xs) auto
   324 
   325 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   326 by (induct xs) auto
   327 
   328 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   329 by (induct xs) auto
   330 
   331 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   332 by (induct xs) auto
   333 
   334 lemma append_eq_append_conv [simp]:
   335  "!!ys. length xs = length ys \<or> length us = length vs
   336  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   337 apply (induct xs)
   338  apply (case_tac ys, simp, force)
   339 apply (case_tac ys, force, simp)
   340 done
   341 
   342 lemma append_eq_append_conv2: "!!ys zs ts.
   343  (xs @ ys = zs @ ts) =
   344  (EX us. xs = zs @ us & us @ ys = ts | xs @ us = zs & ys = us@ ts)"
   345 apply (induct xs)
   346  apply fastsimp
   347 apply(case_tac zs)
   348  apply simp
   349 apply fastsimp
   350 done
   351 
   352 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   353 by simp
   354 
   355 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   356 by simp
   357 
   358 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   359 by simp
   360 
   361 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   362 using append_same_eq [of _ _ "[]"] by auto
   363 
   364 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   365 using append_same_eq [of "[]"] by auto
   366 
   367 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   368 by (induct xs) auto
   369 
   370 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   371 by (induct xs) auto
   372 
   373 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   374 by (simp add: hd_append split: list.split)
   375 
   376 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   377 by (simp split: list.split)
   378 
   379 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   380 by (simp add: tl_append split: list.split)
   381 
   382 
   383 lemma Cons_eq_append_conv: "x#xs = ys@zs =
   384  (ys = [] & x#xs = zs | (EX ys'. x#ys' = ys & xs = ys'@zs))"
   385 by(cases ys) auto
   386 
   387 lemma append_eq_Cons_conv: "(ys@zs = x#xs) =
   388  (ys = [] & zs = x#xs | (EX ys'. ys = x#ys' & ys'@zs = xs))"
   389 by(cases ys) auto
   390 
   391 
   392 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   393 
   394 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   395 by simp
   396 
   397 lemma Cons_eq_appendI:
   398 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   399 by (drule sym) simp
   400 
   401 lemma append_eq_appendI:
   402 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   403 by (drule sym) simp
   404 
   405 
   406 text {*
   407 Simplification procedure for all list equalities.
   408 Currently only tries to rearrange @{text "@"} to see if
   409 - both lists end in a singleton list,
   410 - or both lists end in the same list.
   411 *}
   412 
   413 ML_setup {*
   414 local
   415 
   416 val append_assoc = thm "append_assoc";
   417 val append_Nil = thm "append_Nil";
   418 val append_Cons = thm "append_Cons";
   419 val append1_eq_conv = thm "append1_eq_conv";
   420 val append_same_eq = thm "append_same_eq";
   421 
   422 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   423   (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   424   | last (Const("List.op @",_) $ _ $ ys) = last ys
   425   | last t = t;
   426 
   427 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   428   | list1 _ = false;
   429 
   430 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   431   (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   432   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   433   | butlast xs = Const("List.list.Nil",fastype_of xs);
   434 
   435 val rearr_ss = HOL_basic_ss addsimps [append_assoc, append_Nil, append_Cons];
   436 
   437 fun list_eq sg ss (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   438   let
   439     val lastl = last lhs and lastr = last rhs;
   440     fun rearr conv =
   441       let
   442         val lhs1 = butlast lhs and rhs1 = butlast rhs;
   443         val Type(_,listT::_) = eqT
   444         val appT = [listT,listT] ---> listT
   445         val app = Const("List.op @",appT)
   446         val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   447         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   448         val thm = Goal.prove sg [] [] eq
   449           (K (simp_tac (Simplifier.inherit_context ss rearr_ss) 1));
   450       in SOME ((conv RS (thm RS trans)) RS eq_reflection) end;
   451 
   452   in
   453     if list1 lastl andalso list1 lastr then rearr append1_eq_conv
   454     else if lastl aconv lastr then rearr append_same_eq
   455     else NONE
   456   end;
   457 
   458 in
   459 
   460 val list_eq_simproc =
   461   Simplifier.simproc (Theory.sign_of (the_context ())) "list_eq" ["(xs::'a list) = ys"] list_eq;
   462 
   463 end;
   464 
   465 Addsimprocs [list_eq_simproc];
   466 *}
   467 
   468 
   469 subsubsection {* @{text map} *}
   470 
   471 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   472 by (induct xs) simp_all
   473 
   474 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   475 by (rule ext, induct_tac xs) auto
   476 
   477 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   478 by (induct xs) auto
   479 
   480 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   481 by (induct xs) (auto simp add: o_def)
   482 
   483 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   484 by (induct xs) auto
   485 
   486 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   487 by (induct xs) auto
   488 
   489 lemma map_cong [recdef_cong]:
   490 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   491 -- {* a congruence rule for @{text map} *}
   492 by simp
   493 
   494 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   495 by (cases xs) auto
   496 
   497 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   498 by (cases xs) auto
   499 
   500 lemma map_eq_Cons_conv:
   501  "(map f xs = y#ys) = (\<exists>z zs. xs = z#zs \<and> f z = y \<and> map f zs = ys)"
   502 by (cases xs) auto
   503 
   504 lemma Cons_eq_map_conv:
   505  "(x#xs = map f ys) = (\<exists>z zs. ys = z#zs \<and> x = f z \<and> xs = map f zs)"
   506 by (cases ys) auto
   507 
   508 lemmas map_eq_Cons_D = map_eq_Cons_conv [THEN iffD1]
   509 lemmas Cons_eq_map_D = Cons_eq_map_conv [THEN iffD1]
   510 declare map_eq_Cons_D [dest!]  Cons_eq_map_D [dest!]
   511 
   512 lemma ex_map_conv:
   513   "(EX xs. ys = map f xs) = (ALL y : set ys. EX x. y = f x)"
   514 by(induct ys, auto simp add: Cons_eq_map_conv)
   515 
   516 lemma map_eq_imp_length_eq:
   517   "!!xs. map f xs = map f ys ==> length xs = length ys"
   518 apply (induct ys)
   519  apply simp
   520 apply(simp (no_asm_use))
   521 apply clarify
   522 apply(simp (no_asm_use))
   523 apply fast
   524 done
   525 
   526 lemma map_inj_on:
   527  "[| map f xs = map f ys; inj_on f (set xs Un set ys) |]
   528   ==> xs = ys"
   529 apply(frule map_eq_imp_length_eq)
   530 apply(rotate_tac -1)
   531 apply(induct rule:list_induct2)
   532  apply simp
   533 apply(simp)
   534 apply (blast intro:sym)
   535 done
   536 
   537 lemma inj_on_map_eq_map:
   538  "inj_on f (set xs Un set ys) \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   539 by(blast dest:map_inj_on)
   540 
   541 lemma map_injective:
   542  "!!xs. map f xs = map f ys ==> inj f ==> xs = ys"
   543 by (induct ys) (auto dest!:injD)
   544 
   545 lemma inj_map_eq_map[simp]: "inj f \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   546 by(blast dest:map_injective)
   547 
   548 lemma inj_mapI: "inj f ==> inj (map f)"
   549 by (iprover dest: map_injective injD intro: inj_onI)
   550 
   551 lemma inj_mapD: "inj (map f) ==> inj f"
   552 apply (unfold inj_on_def, clarify)
   553 apply (erule_tac x = "[x]" in ballE)
   554  apply (erule_tac x = "[y]" in ballE, simp, blast)
   555 apply blast
   556 done
   557 
   558 lemma inj_map[iff]: "inj (map f) = inj f"
   559 by (blast dest: inj_mapD intro: inj_mapI)
   560 
   561 lemma inj_on_mapI: "inj_on f (\<Union>(set ` A)) \<Longrightarrow> inj_on (map f) A"
   562 apply(rule inj_onI)
   563 apply(erule map_inj_on)
   564 apply(blast intro:inj_onI dest:inj_onD)
   565 done
   566 
   567 lemma map_idI: "(\<And>x. x \<in> set xs \<Longrightarrow> f x = x) \<Longrightarrow> map f xs = xs"
   568 by (induct xs, auto)
   569 
   570 lemma map_fun_upd [simp]: "y \<notin> set xs \<Longrightarrow> map (f(y:=v)) xs = map f xs"
   571 by (induct xs) auto
   572 
   573 lemma map_fst_zip[simp]:
   574   "length xs = length ys \<Longrightarrow> map fst (zip xs ys) = xs"
   575 by (induct rule:list_induct2, simp_all)
   576 
   577 lemma map_snd_zip[simp]:
   578   "length xs = length ys \<Longrightarrow> map snd (zip xs ys) = ys"
   579 by (induct rule:list_induct2, simp_all)
   580 
   581 
   582 subsubsection {* @{text rev} *}
   583 
   584 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   585 by (induct xs) auto
   586 
   587 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   588 by (induct xs) auto
   589 
   590 lemma rev_swap: "(rev xs = ys) = (xs = rev ys)"
   591 by auto
   592 
   593 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   594 by (induct xs) auto
   595 
   596 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   597 by (induct xs) auto
   598 
   599 lemma rev_singleton_conv [simp]: "(rev xs = [x]) = (xs = [x])"
   600 by (cases xs) auto
   601 
   602 lemma singleton_rev_conv [simp]: "([x] = rev xs) = (xs = [x])"
   603 by (cases xs) auto
   604 
   605 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   606 apply (induct xs, force)
   607 apply (case_tac ys, simp, force)
   608 done
   609 
   610 lemma inj_on_rev[iff]: "inj_on rev A"
   611 by(simp add:inj_on_def)
   612 
   613 lemma rev_induct [case_names Nil snoc]:
   614   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   615 apply(simplesubst rev_rev_ident[symmetric])
   616 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   617 done
   618 
   619 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   620 
   621 lemma rev_exhaust [case_names Nil snoc]:
   622   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   623 by (induct xs rule: rev_induct) auto
   624 
   625 lemmas rev_cases = rev_exhaust
   626 
   627 lemma rev_eq_Cons_iff[iff]: "(rev xs = y#ys) = (xs = rev ys @ [y])"
   628 by(rule rev_cases[of xs]) auto
   629 
   630 
   631 subsubsection {* @{text set} *}
   632 
   633 lemma finite_set [iff]: "finite (set xs)"
   634 by (induct xs) auto
   635 
   636 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   637 by (induct xs) auto
   638 
   639 lemma hd_in_set[simp]: "xs \<noteq> [] \<Longrightarrow> hd xs : set xs"
   640 by(cases xs) auto
   641 
   642 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   643 by auto
   644 
   645 lemma set_ConsD: "y \<in> set (x # xs) \<Longrightarrow> y=x \<or> y \<in> set xs" 
   646 by auto
   647 
   648 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   649 by (induct xs) auto
   650 
   651 lemma set_empty2[iff]: "({} = set xs) = (xs = [])"
   652 by(induct xs) auto
   653 
   654 lemma set_rev [simp]: "set (rev xs) = set xs"
   655 by (induct xs) auto
   656 
   657 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   658 by (induct xs) auto
   659 
   660 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   661 by (induct xs) auto
   662 
   663 lemma set_upt [simp]: "set[i..<j] = {k. i \<le> k \<and> k < j}"
   664 apply (induct j, simp_all)
   665 apply (erule ssubst, auto)
   666 done
   667 
   668 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   669 proof (induct xs)
   670   case Nil show ?case by simp
   671   case (Cons a xs)
   672   show ?case
   673   proof 
   674     assume "x \<in> set (a # xs)"
   675     with prems show "\<exists>ys zs. a # xs = ys @ x # zs"
   676       by (simp, blast intro: Cons_eq_appendI)
   677   next
   678     assume "\<exists>ys zs. a # xs = ys @ x # zs"
   679     then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   680     show "x \<in> set (a # xs)" 
   681       by (cases ys, auto simp add: eq)
   682   qed
   683 qed
   684 
   685 lemma in_set_conv_decomp_first:
   686  "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys)"
   687 proof (induct xs)
   688   case Nil show ?case by simp
   689 next
   690   case (Cons a xs)
   691   show ?case
   692   proof cases
   693     assume "x = a" thus ?case using Cons by force
   694   next
   695     assume "x \<noteq> a"
   696     show ?case
   697     proof
   698       assume "x \<in> set (a # xs)"
   699       from prems show "\<exists>ys zs. a # xs = ys @ x # zs \<and> x \<notin> set ys"
   700 	by(fastsimp intro!: Cons_eq_appendI)
   701     next
   702       assume "\<exists>ys zs. a # xs = ys @ x # zs \<and> x \<notin> set ys"
   703       then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   704       show "x \<in> set (a # xs)" by (cases ys, auto simp add: eq)
   705     qed
   706   qed
   707 qed
   708 
   709 lemmas split_list       = in_set_conv_decomp[THEN iffD1, standard]
   710 lemmas split_list_first = in_set_conv_decomp_first[THEN iffD1, standard]
   711 
   712 
   713 lemma finite_list: "finite A ==> EX l. set l = A"
   714 apply (erule finite_induct, auto)
   715 apply (rule_tac x="x#l" in exI, auto)
   716 done
   717 
   718 lemma card_length: "card (set xs) \<le> length xs"
   719 by (induct xs) (auto simp add: card_insert_if)
   720 
   721 
   722 subsubsection {* @{text filter} *}
   723 
   724 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   725 by (induct xs) auto
   726 
   727 lemma rev_filter: "rev (filter P xs) = filter P (rev xs)"
   728 by (induct xs) simp_all
   729 
   730 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   731 by (induct xs) auto
   732 
   733 lemma length_filter_le [simp]: "length (filter P xs) \<le> length xs"
   734 by (induct xs) (auto simp add: le_SucI)
   735 
   736 lemma sum_length_filter_compl:
   737   "length(filter P xs) + length(filter (%x. ~P x) xs) = length xs"
   738 by(induct xs) simp_all
   739 
   740 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   741 by (induct xs) auto
   742 
   743 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   744 by (induct xs) auto
   745 
   746 lemma filter_empty_conv: "(filter P xs = []) = (\<forall>x\<in>set xs. \<not> P x)" 
   747   by (induct xs) simp_all
   748 
   749 lemma filter_id_conv: "(filter P xs = xs) = (\<forall>x\<in>set xs. P x)"
   750 apply (induct xs)
   751  apply auto
   752 apply(cut_tac P=P and xs=xs in length_filter_le)
   753 apply simp
   754 done
   755 
   756 lemma filter_map:
   757   "filter P (map f xs) = map f (filter (P o f) xs)"
   758 by (induct xs) simp_all
   759 
   760 lemma length_filter_map[simp]:
   761   "length (filter P (map f xs)) = length(filter (P o f) xs)"
   762 by (simp add:filter_map)
   763 
   764 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   765 by auto
   766 
   767 lemma length_filter_less:
   768   "\<lbrakk> x : set xs; ~ P x \<rbrakk> \<Longrightarrow> length(filter P xs) < length xs"
   769 proof (induct xs)
   770   case Nil thus ?case by simp
   771 next
   772   case (Cons x xs) thus ?case
   773     apply (auto split:split_if_asm)
   774     using length_filter_le[of P xs] apply arith
   775   done
   776 qed
   777 
   778 lemma length_filter_conv_card:
   779  "length(filter p xs) = card{i. i < length xs & p(xs!i)}"
   780 proof (induct xs)
   781   case Nil thus ?case by simp
   782 next
   783   case (Cons x xs)
   784   let ?S = "{i. i < length xs & p(xs!i)}"
   785   have fin: "finite ?S" by(fast intro: bounded_nat_set_is_finite)
   786   show ?case (is "?l = card ?S'")
   787   proof (cases)
   788     assume "p x"
   789     hence eq: "?S' = insert 0 (Suc ` ?S)"
   790       by(auto simp add: nth_Cons image_def split:nat.split elim:lessE)
   791     have "length (filter p (x # xs)) = Suc(card ?S)"
   792       using Cons by simp
   793     also have "\<dots> = Suc(card(Suc ` ?S))" using fin
   794       by (simp add: card_image inj_Suc)
   795     also have "\<dots> = card ?S'" using eq fin
   796       by (simp add:card_insert_if) (simp add:image_def)
   797     finally show ?thesis .
   798   next
   799     assume "\<not> p x"
   800     hence eq: "?S' = Suc ` ?S"
   801       by(auto simp add: nth_Cons image_def split:nat.split elim:lessE)
   802     have "length (filter p (x # xs)) = card ?S"
   803       using Cons by simp
   804     also have "\<dots> = card(Suc ` ?S)" using fin
   805       by (simp add: card_image inj_Suc)
   806     also have "\<dots> = card ?S'" using eq fin
   807       by (simp add:card_insert_if)
   808     finally show ?thesis .
   809   qed
   810 qed
   811 
   812 lemma Cons_eq_filterD:
   813  "x#xs = filter P ys \<Longrightarrow>
   814   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
   815   (concl is "\<exists>us vs. ?P ys us vs")
   816 proof(induct ys)
   817   case Nil thus ?case by simp
   818 next
   819   case (Cons y ys)
   820   show ?case (is "\<exists>x. ?Q x")
   821   proof cases
   822     assume Py: "P y"
   823     show ?thesis
   824     proof cases
   825       assume xy: "x = y"
   826       show ?thesis
   827       proof from Py xy Cons(2) show "?Q []" by simp qed
   828     next
   829       assume "x \<noteq> y" with Py Cons(2) show ?thesis by simp
   830     qed
   831   next
   832     assume Py: "\<not> P y"
   833     with Cons obtain us vs where 1 : "?P (y#ys) (y#us) vs" by fastsimp
   834     show ?thesis (is "? us. ?Q us")
   835     proof show "?Q (y#us)" using 1 by simp qed
   836   qed
   837 qed
   838 
   839 lemma filter_eq_ConsD:
   840  "filter P ys = x#xs \<Longrightarrow>
   841   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
   842 by(rule Cons_eq_filterD) simp
   843 
   844 lemma filter_eq_Cons_iff:
   845  "(filter P ys = x#xs) =
   846   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
   847 by(auto dest:filter_eq_ConsD)
   848 
   849 lemma Cons_eq_filter_iff:
   850  "(x#xs = filter P ys) =
   851   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
   852 by(auto dest:Cons_eq_filterD)
   853 
   854 lemma filter_cong[recdef_cong]:
   855  "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> P x = Q x) \<Longrightarrow> filter P xs = filter Q ys"
   856 apply simp
   857 apply(erule thin_rl)
   858 by (induct ys) simp_all
   859 
   860 
   861 subsubsection {* @{text concat} *}
   862 
   863 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   864 by (induct xs) auto
   865 
   866 lemma concat_eq_Nil_conv [simp]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   867 by (induct xss) auto
   868 
   869 lemma Nil_eq_concat_conv [simp]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   870 by (induct xss) auto
   871 
   872 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   873 by (induct xs) auto
   874 
   875 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   876 by (induct xs) auto
   877 
   878 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   879 by (induct xs) auto
   880 
   881 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   882 by (induct xs) auto
   883 
   884 
   885 subsubsection {* @{text nth} *}
   886 
   887 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   888 by auto
   889 
   890 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   891 by auto
   892 
   893 declare nth.simps [simp del]
   894 
   895 lemma nth_append:
   896 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   897 apply (induct "xs", simp)
   898 apply (case_tac n, auto)
   899 done
   900 
   901 lemma nth_append_length [simp]: "(xs @ x # ys) ! length xs = x"
   902 by (induct "xs") auto
   903 
   904 lemma nth_append_length_plus[simp]: "(xs @ ys) ! (length xs + n) = ys ! n"
   905 by (induct "xs") auto
   906 
   907 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   908 apply (induct xs, simp)
   909 apply (case_tac n, auto)
   910 done
   911 
   912 lemma hd_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd xs = xs!0"
   913 by(cases xs) simp_all
   914 
   915 
   916 lemma list_eq_iff_nth_eq:
   917  "!!ys. (xs = ys) = (length xs = length ys \<and> (ALL i<length xs. xs!i = ys!i))"
   918 apply(induct xs)
   919  apply simp apply blast
   920 apply(case_tac ys)
   921  apply simp
   922 apply(simp add:nth_Cons split:nat.split)apply blast
   923 done
   924 
   925 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   926 apply (induct xs, simp, simp)
   927 apply safe
   928 apply (rule_tac x = 0 in exI, simp)
   929  apply (rule_tac x = "Suc i" in exI, simp)
   930 apply (case_tac i, simp)
   931 apply (rename_tac j)
   932 apply (rule_tac x = j in exI, simp)
   933 done
   934 
   935 lemma in_set_conv_nth: "(x \<in> set xs) = (\<exists>i < length xs. xs!i = x)"
   936 by(auto simp:set_conv_nth)
   937 
   938 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   939 by (auto simp add: set_conv_nth)
   940 
   941 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   942 by (auto simp add: set_conv_nth)
   943 
   944 lemma all_nth_imp_all_set:
   945 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   946 by (auto simp add: set_conv_nth)
   947 
   948 lemma all_set_conv_all_nth:
   949 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   950 by (auto simp add: set_conv_nth)
   951 
   952 
   953 subsubsection {* @{text list_update} *}
   954 
   955 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   956 by (induct xs) (auto split: nat.split)
   957 
   958 lemma nth_list_update:
   959 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   960 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   961 
   962 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   963 by (simp add: nth_list_update)
   964 
   965 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   966 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   967 
   968 lemma list_update_overwrite [simp]:
   969 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   970 by (induct xs) (auto split: nat.split)
   971 
   972 lemma list_update_id[simp]: "!!i. i < length xs ==> xs[i := xs!i] = xs"
   973 apply (induct xs, simp)
   974 apply(simp split:nat.splits)
   975 done
   976 
   977 lemma list_update_beyond[simp]: "\<And>i. length xs \<le> i \<Longrightarrow> xs[i:=x] = xs"
   978 apply (induct xs)
   979  apply simp
   980 apply (case_tac i)
   981 apply simp_all
   982 done
   983 
   984 lemma list_update_same_conv:
   985 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   986 by (induct xs) (auto split: nat.split)
   987 
   988 lemma list_update_append1:
   989  "!!i. i < size xs \<Longrightarrow> (xs @ ys)[i:=x] = xs[i:=x] @ ys"
   990 apply (induct xs, simp)
   991 apply(simp split:nat.split)
   992 done
   993 
   994 lemma list_update_append:
   995   "!!n. (xs @ ys) [n:= x] = 
   996   (if n < length xs then xs[n:= x] @ ys else xs @ (ys [n-length xs:= x]))"
   997 by (induct xs) (auto split:nat.splits)
   998 
   999 lemma list_update_length [simp]:
  1000  "(xs @ x # ys)[length xs := y] = (xs @ y # ys)"
  1001 by (induct xs, auto)
  1002 
  1003 lemma update_zip:
  1004 "!!i xy xs. length xs = length ys ==>
  1005 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
  1006 by (induct ys) (auto, case_tac xs, auto split: nat.split)
  1007 
  1008 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
  1009 by (induct xs) (auto split: nat.split)
  1010 
  1011 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
  1012 by (blast dest!: set_update_subset_insert [THEN subsetD])
  1013 
  1014 lemma set_update_memI: "!!n. n < length xs \<Longrightarrow> x \<in> set (xs[n := x])"
  1015 by (induct xs) (auto split:nat.splits)
  1016 
  1017 
  1018 subsubsection {* @{text last} and @{text butlast} *}
  1019 
  1020 lemma last_snoc [simp]: "last (xs @ [x]) = x"
  1021 by (induct xs) auto
  1022 
  1023 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
  1024 by (induct xs) auto
  1025 
  1026 lemma last_ConsL: "xs = [] \<Longrightarrow> last(x#xs) = x"
  1027 by(simp add:last.simps)
  1028 
  1029 lemma last_ConsR: "xs \<noteq> [] \<Longrightarrow> last(x#xs) = last xs"
  1030 by(simp add:last.simps)
  1031 
  1032 lemma last_append: "last(xs @ ys) = (if ys = [] then last xs else last ys)"
  1033 by (induct xs) (auto)
  1034 
  1035 lemma last_appendL[simp]: "ys = [] \<Longrightarrow> last(xs @ ys) = last xs"
  1036 by(simp add:last_append)
  1037 
  1038 lemma last_appendR[simp]: "ys \<noteq> [] \<Longrightarrow> last(xs @ ys) = last ys"
  1039 by(simp add:last_append)
  1040 
  1041 lemma hd_rev: "xs \<noteq> [] \<Longrightarrow> hd(rev xs) = last xs"
  1042 by(rule rev_exhaust[of xs]) simp_all
  1043 
  1044 lemma last_rev: "xs \<noteq> [] \<Longrightarrow> last(rev xs) = hd xs"
  1045 by(cases xs) simp_all
  1046 
  1047 lemma last_in_set[simp]: "as \<noteq> [] \<Longrightarrow> last as \<in> set as"
  1048 by (induct as) auto
  1049 
  1050 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
  1051 by (induct xs rule: rev_induct) auto
  1052 
  1053 lemma butlast_append:
  1054 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
  1055 by (induct xs) auto
  1056 
  1057 lemma append_butlast_last_id [simp]:
  1058 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
  1059 by (induct xs) auto
  1060 
  1061 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
  1062 by (induct xs) (auto split: split_if_asm)
  1063 
  1064 lemma in_set_butlast_appendI:
  1065 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
  1066 by (auto dest: in_set_butlastD simp add: butlast_append)
  1067 
  1068 lemma last_drop[simp]: "!!n. n < length xs \<Longrightarrow> last (drop n xs) = last xs"
  1069 apply (induct xs)
  1070  apply simp
  1071 apply (auto split:nat.split)
  1072 done
  1073 
  1074 lemma last_conv_nth: "xs\<noteq>[] \<Longrightarrow> last xs = xs!(length xs - 1)"
  1075 by(induct xs)(auto simp:neq_Nil_conv)
  1076 
  1077 
  1078 subsubsection {* @{text take} and @{text drop} *}
  1079 
  1080 lemma take_0 [simp]: "take 0 xs = []"
  1081 by (induct xs) auto
  1082 
  1083 lemma drop_0 [simp]: "drop 0 xs = xs"
  1084 by (induct xs) auto
  1085 
  1086 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
  1087 by simp
  1088 
  1089 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
  1090 by simp
  1091 
  1092 declare take_Cons [simp del] and drop_Cons [simp del]
  1093 
  1094 lemma take_Suc: "xs ~= [] ==> take (Suc n) xs = hd xs # take n (tl xs)"
  1095 by(clarsimp simp add:neq_Nil_conv)
  1096 
  1097 lemma drop_Suc: "drop (Suc n) xs = drop n (tl xs)"
  1098 by(cases xs, simp_all)
  1099 
  1100 lemma drop_tl: "!!n. drop n (tl xs) = tl(drop n xs)"
  1101 by(induct xs, simp_all add:drop_Cons drop_Suc split:nat.split)
  1102 
  1103 lemma nth_via_drop: "!!n. drop n xs = y#ys \<Longrightarrow> xs!n = y"
  1104 apply (induct xs, simp)
  1105 apply(simp add:drop_Cons nth_Cons split:nat.splits)
  1106 done
  1107 
  1108 lemma take_Suc_conv_app_nth:
  1109  "!!i. i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
  1110 apply (induct xs, simp)
  1111 apply (case_tac i, auto)
  1112 done
  1113 
  1114 lemma drop_Suc_conv_tl:
  1115   "!!i. i < length xs \<Longrightarrow> (xs!i) # (drop (Suc i) xs) = drop i xs"
  1116 apply (induct xs, simp)
  1117 apply (case_tac i, auto)
  1118 done
  1119 
  1120 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
  1121 by (induct n) (auto, case_tac xs, auto)
  1122 
  1123 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
  1124 by (induct n) (auto, case_tac xs, auto)
  1125 
  1126 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
  1127 by (induct n) (auto, case_tac xs, auto)
  1128 
  1129 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
  1130 by (induct n) (auto, case_tac xs, auto)
  1131 
  1132 lemma take_append [simp]:
  1133 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
  1134 by (induct n) (auto, case_tac xs, auto)
  1135 
  1136 lemma drop_append [simp]:
  1137 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
  1138 by (induct n) (auto, case_tac xs, auto)
  1139 
  1140 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
  1141 apply (induct m, auto)
  1142 apply (case_tac xs, auto)
  1143 apply (case_tac n, auto)
  1144 done
  1145 
  1146 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
  1147 apply (induct m, auto)
  1148 apply (case_tac xs, auto)
  1149 done
  1150 
  1151 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
  1152 apply (induct m, auto)
  1153 apply (case_tac xs, auto)
  1154 done
  1155 
  1156 lemma drop_take: "!!m n. drop n (take m xs) = take (m-n) (drop n xs)"
  1157 apply(induct xs)
  1158  apply simp
  1159 apply(simp add: take_Cons drop_Cons split:nat.split)
  1160 done
  1161 
  1162 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
  1163 apply (induct n, auto)
  1164 apply (case_tac xs, auto)
  1165 done
  1166 
  1167 lemma take_eq_Nil[simp]: "!!n. (take n xs = []) = (n = 0 \<or> xs = [])"
  1168 apply(induct xs)
  1169  apply simp
  1170 apply(simp add:take_Cons split:nat.split)
  1171 done
  1172 
  1173 lemma drop_eq_Nil[simp]: "!!n. (drop n xs = []) = (length xs <= n)"
  1174 apply(induct xs)
  1175 apply simp
  1176 apply(simp add:drop_Cons split:nat.split)
  1177 done
  1178 
  1179 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
  1180 apply (induct n, auto)
  1181 apply (case_tac xs, auto)
  1182 done
  1183 
  1184 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
  1185 apply (induct n, auto)
  1186 apply (case_tac xs, auto)
  1187 done
  1188 
  1189 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
  1190 apply (induct xs, auto)
  1191 apply (case_tac i, auto)
  1192 done
  1193 
  1194 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
  1195 apply (induct xs, auto)
  1196 apply (case_tac i, auto)
  1197 done
  1198 
  1199 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
  1200 apply (induct xs, auto)
  1201 apply (case_tac n, blast)
  1202 apply (case_tac i, auto)
  1203 done
  1204 
  1205 lemma nth_drop [simp]:
  1206 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
  1207 apply (induct n, auto)
  1208 apply (case_tac xs, auto)
  1209 done
  1210 
  1211 lemma hd_drop_conv_nth: "\<lbrakk> xs \<noteq> []; n < length xs \<rbrakk> \<Longrightarrow> hd(drop n xs) = xs!n"
  1212 by(simp add: hd_conv_nth)
  1213 
  1214 lemma set_take_subset: "\<And>n. set(take n xs) \<subseteq> set xs"
  1215 by(induct xs)(auto simp:take_Cons split:nat.split)
  1216 
  1217 lemma set_drop_subset: "\<And>n. set(drop n xs) \<subseteq> set xs"
  1218 by(induct xs)(auto simp:drop_Cons split:nat.split)
  1219 
  1220 lemma in_set_takeD: "x : set(take n xs) \<Longrightarrow> x : set xs"
  1221 using set_take_subset by fast
  1222 
  1223 lemma in_set_dropD: "x : set(drop n xs) \<Longrightarrow> x : set xs"
  1224 using set_drop_subset by fast
  1225 
  1226 lemma append_eq_conv_conj:
  1227 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
  1228 apply (induct xs, simp, clarsimp)
  1229 apply (case_tac zs, auto)
  1230 done
  1231 
  1232 lemma take_add [rule_format]: 
  1233     "\<forall>i. i+j \<le> length(xs) --> take (i+j) xs = take i xs @ take j (drop i xs)"
  1234 apply (induct xs, auto) 
  1235 apply (case_tac i, simp_all) 
  1236 done
  1237 
  1238 lemma append_eq_append_conv_if:
  1239  "!! ys\<^isub>1. (xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>1 @ ys\<^isub>2) =
  1240   (if size xs\<^isub>1 \<le> size ys\<^isub>1
  1241    then xs\<^isub>1 = take (size xs\<^isub>1) ys\<^isub>1 \<and> xs\<^isub>2 = drop (size xs\<^isub>1) ys\<^isub>1 @ ys\<^isub>2
  1242    else take (size ys\<^isub>1) xs\<^isub>1 = ys\<^isub>1 \<and> drop (size ys\<^isub>1) xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>2)"
  1243 apply(induct xs\<^isub>1)
  1244  apply simp
  1245 apply(case_tac ys\<^isub>1)
  1246 apply simp_all
  1247 done
  1248 
  1249 lemma take_hd_drop:
  1250   "!!n. n < length xs \<Longrightarrow> take n xs @ [hd (drop n xs)] = take (n+1) xs"
  1251 apply(induct xs)
  1252 apply simp
  1253 apply(simp add:drop_Cons split:nat.split)
  1254 done
  1255 
  1256 lemma id_take_nth_drop:
  1257  "i < length xs \<Longrightarrow> xs = take i xs @ xs!i # drop (Suc i) xs" 
  1258 proof -
  1259   assume si: "i < length xs"
  1260   hence "xs = take (Suc i) xs @ drop (Suc i) xs" by auto
  1261   moreover
  1262   from si have "take (Suc i) xs = take i xs @ [xs!i]"
  1263     apply (rule_tac take_Suc_conv_app_nth) by arith
  1264   ultimately show ?thesis by auto
  1265 qed
  1266   
  1267 lemma upd_conv_take_nth_drop:
  1268  "i < length xs \<Longrightarrow> xs[i:=a] = take i xs @ a # drop (Suc i) xs"
  1269 proof -
  1270   assume i: "i < length xs"
  1271   have "xs[i:=a] = (take i xs @ xs!i # drop (Suc i) xs)[i:=a]"
  1272     by(rule arg_cong[OF id_take_nth_drop[OF i]])
  1273   also have "\<dots> = take i xs @ a # drop (Suc i) xs"
  1274     using i by (simp add: list_update_append)
  1275   finally show ?thesis .
  1276 qed
  1277 
  1278 
  1279 subsubsection {* @{text takeWhile} and @{text dropWhile} *}
  1280 
  1281 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
  1282 by (induct xs) auto
  1283 
  1284 lemma takeWhile_append1 [simp]:
  1285 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
  1286 by (induct xs) auto
  1287 
  1288 lemma takeWhile_append2 [simp]:
  1289 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
  1290 by (induct xs) auto
  1291 
  1292 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
  1293 by (induct xs) auto
  1294 
  1295 lemma dropWhile_append1 [simp]:
  1296 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
  1297 by (induct xs) auto
  1298 
  1299 lemma dropWhile_append2 [simp]:
  1300 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
  1301 by (induct xs) auto
  1302 
  1303 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
  1304 by (induct xs) (auto split: split_if_asm)
  1305 
  1306 lemma takeWhile_eq_all_conv[simp]:
  1307  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
  1308 by(induct xs, auto)
  1309 
  1310 lemma dropWhile_eq_Nil_conv[simp]:
  1311  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
  1312 by(induct xs, auto)
  1313 
  1314 lemma dropWhile_eq_Cons_conv:
  1315  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
  1316 by(induct xs, auto)
  1317 
  1318 text{* The following two lemmmas could be generalized to an arbitrary
  1319 property. *}
  1320 
  1321 lemma takeWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  1322  takeWhile (\<lambda>y. y \<noteq> x) (rev xs) = rev (tl (dropWhile (\<lambda>y. y \<noteq> x) xs))"
  1323 by(induct xs) (auto simp: takeWhile_tail[where l="[]"])
  1324 
  1325 lemma dropWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  1326   dropWhile (\<lambda>y. y \<noteq> x) (rev xs) = x # rev (takeWhile (\<lambda>y. y \<noteq> x) xs)"
  1327 apply(induct xs)
  1328  apply simp
  1329 apply auto
  1330 apply(subst dropWhile_append2)
  1331 apply auto
  1332 done
  1333 
  1334 lemma takeWhile_not_last:
  1335  "\<lbrakk> xs \<noteq> []; distinct xs\<rbrakk> \<Longrightarrow> takeWhile (\<lambda>y. y \<noteq> last xs) xs = butlast xs"
  1336 apply(induct xs)
  1337  apply simp
  1338 apply(case_tac xs)
  1339 apply(auto)
  1340 done
  1341 
  1342 lemma takeWhile_cong [recdef_cong]:
  1343   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  1344   ==> takeWhile P l = takeWhile Q k"
  1345   by (induct k fixing: l, simp_all)
  1346 
  1347 lemma dropWhile_cong [recdef_cong]:
  1348   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  1349   ==> dropWhile P l = dropWhile Q k"
  1350   by (induct k fixing: l, simp_all)
  1351 
  1352 
  1353 subsubsection {* @{text zip} *}
  1354 
  1355 lemma zip_Nil [simp]: "zip [] ys = []"
  1356 by (induct ys) auto
  1357 
  1358 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  1359 by simp
  1360 
  1361 declare zip_Cons [simp del]
  1362 
  1363 lemma zip_Cons1:
  1364  "zip (x#xs) ys = (case ys of [] \<Rightarrow> [] | y#ys \<Rightarrow> (x,y)#zip xs ys)"
  1365 by(auto split:list.split)
  1366 
  1367 lemma length_zip [simp]:
  1368 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
  1369 apply (induct ys, simp)
  1370 apply (case_tac xs, auto)
  1371 done
  1372 
  1373 lemma zip_append1:
  1374 "!!xs. zip (xs @ ys) zs =
  1375 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
  1376 apply (induct zs, simp)
  1377 apply (case_tac xs, simp_all)
  1378 done
  1379 
  1380 lemma zip_append2:
  1381 "!!ys. zip xs (ys @ zs) =
  1382 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
  1383 apply (induct xs, simp)
  1384 apply (case_tac ys, simp_all)
  1385 done
  1386 
  1387 lemma zip_append [simp]:
  1388  "[| length xs = length us; length ys = length vs |] ==>
  1389 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
  1390 by (simp add: zip_append1)
  1391 
  1392 lemma zip_rev:
  1393 "length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
  1394 by (induct rule:list_induct2, simp_all)
  1395 
  1396 lemma nth_zip [simp]:
  1397 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
  1398 apply (induct ys, simp)
  1399 apply (case_tac xs)
  1400  apply (simp_all add: nth.simps split: nat.split)
  1401 done
  1402 
  1403 lemma set_zip:
  1404 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
  1405 by (simp add: set_conv_nth cong: rev_conj_cong)
  1406 
  1407 lemma zip_update:
  1408 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
  1409 by (rule sym, simp add: update_zip)
  1410 
  1411 lemma zip_replicate [simp]:
  1412 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
  1413 apply (induct i, auto)
  1414 apply (case_tac j, auto)
  1415 done
  1416 
  1417 
  1418 subsubsection {* @{text list_all2} *}
  1419 
  1420 lemma list_all2_lengthD [intro?]: 
  1421   "list_all2 P xs ys ==> length xs = length ys"
  1422 by (simp add: list_all2_def)
  1423 
  1424 lemma list_all2_Nil [iff,code]: "list_all2 P [] ys = (ys = [])"
  1425 by (simp add: list_all2_def)
  1426 
  1427 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
  1428 by (simp add: list_all2_def)
  1429 
  1430 lemma list_all2_Cons [iff,code]:
  1431 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
  1432 by (auto simp add: list_all2_def)
  1433 
  1434 lemma list_all2_Cons1:
  1435 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  1436 by (cases ys) auto
  1437 
  1438 lemma list_all2_Cons2:
  1439 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  1440 by (cases xs) auto
  1441 
  1442 lemma list_all2_rev [iff]:
  1443 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  1444 by (simp add: list_all2_def zip_rev cong: conj_cong)
  1445 
  1446 lemma list_all2_rev1:
  1447 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  1448 by (subst list_all2_rev [symmetric]) simp
  1449 
  1450 lemma list_all2_append1:
  1451 "list_all2 P (xs @ ys) zs =
  1452 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  1453 list_all2 P xs us \<and> list_all2 P ys vs)"
  1454 apply (simp add: list_all2_def zip_append1)
  1455 apply (rule iffI)
  1456  apply (rule_tac x = "take (length xs) zs" in exI)
  1457  apply (rule_tac x = "drop (length xs) zs" in exI)
  1458  apply (force split: nat_diff_split simp add: min_def, clarify)
  1459 apply (simp add: ball_Un)
  1460 done
  1461 
  1462 lemma list_all2_append2:
  1463 "list_all2 P xs (ys @ zs) =
  1464 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1465 list_all2 P us ys \<and> list_all2 P vs zs)"
  1466 apply (simp add: list_all2_def zip_append2)
  1467 apply (rule iffI)
  1468  apply (rule_tac x = "take (length ys) xs" in exI)
  1469  apply (rule_tac x = "drop (length ys) xs" in exI)
  1470  apply (force split: nat_diff_split simp add: min_def, clarify)
  1471 apply (simp add: ball_Un)
  1472 done
  1473 
  1474 lemma list_all2_append:
  1475   "length xs = length ys \<Longrightarrow>
  1476   list_all2 P (xs@us) (ys@vs) = (list_all2 P xs ys \<and> list_all2 P us vs)"
  1477 by (induct rule:list_induct2, simp_all)
  1478 
  1479 lemma list_all2_appendI [intro?, trans]:
  1480   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  1481   by (simp add: list_all2_append list_all2_lengthD)
  1482 
  1483 lemma list_all2_conv_all_nth:
  1484 "list_all2 P xs ys =
  1485 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1486 by (force simp add: list_all2_def set_zip)
  1487 
  1488 lemma list_all2_trans:
  1489   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  1490   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  1491         (is "!!bs cs. PROP ?Q as bs cs")
  1492 proof (induct as)
  1493   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  1494   show "!!cs. PROP ?Q (x # xs) bs cs"
  1495   proof (induct bs)
  1496     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  1497     show "PROP ?Q (x # xs) (y # ys) cs"
  1498       by (induct cs) (auto intro: tr I1 I2)
  1499   qed simp
  1500 qed simp
  1501 
  1502 lemma list_all2_all_nthI [intro?]:
  1503   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  1504   by (simp add: list_all2_conv_all_nth)
  1505 
  1506 lemma list_all2I:
  1507   "\<forall>x \<in> set (zip a b). split P x \<Longrightarrow> length a = length b \<Longrightarrow> list_all2 P a b"
  1508   by (simp add: list_all2_def)
  1509 
  1510 lemma list_all2_nthD:
  1511   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1512   by (simp add: list_all2_conv_all_nth)
  1513 
  1514 lemma list_all2_nthD2:
  1515   "\<lbrakk>list_all2 P xs ys; p < size ys\<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1516   by (frule list_all2_lengthD) (auto intro: list_all2_nthD)
  1517 
  1518 lemma list_all2_map1: 
  1519   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  1520   by (simp add: list_all2_conv_all_nth)
  1521 
  1522 lemma list_all2_map2: 
  1523   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  1524   by (auto simp add: list_all2_conv_all_nth)
  1525 
  1526 lemma list_all2_refl [intro?]:
  1527   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  1528   by (simp add: list_all2_conv_all_nth)
  1529 
  1530 lemma list_all2_update_cong:
  1531   "\<lbrakk> i<size xs; list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1532   by (simp add: list_all2_conv_all_nth nth_list_update)
  1533 
  1534 lemma list_all2_update_cong2:
  1535   "\<lbrakk>list_all2 P xs ys; P x y; i < length ys\<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1536   by (simp add: list_all2_lengthD list_all2_update_cong)
  1537 
  1538 lemma list_all2_takeI [simp,intro?]:
  1539   "\<And>n ys. list_all2 P xs ys \<Longrightarrow> list_all2 P (take n xs) (take n ys)"
  1540   apply (induct xs)
  1541    apply simp
  1542   apply (clarsimp simp add: list_all2_Cons1)
  1543   apply (case_tac n)
  1544   apply auto
  1545   done
  1546 
  1547 lemma list_all2_dropI [simp,intro?]:
  1548   "\<And>n bs. list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  1549   apply (induct as, simp)
  1550   apply (clarsimp simp add: list_all2_Cons1)
  1551   apply (case_tac n, simp, simp)
  1552   done
  1553 
  1554 lemma list_all2_mono [intro?]:
  1555   "\<And>y. list_all2 P x y \<Longrightarrow> (\<And>x y. P x y \<Longrightarrow> Q x y) \<Longrightarrow> list_all2 Q x y"
  1556   apply (induct x, simp)
  1557   apply (case_tac y, auto)
  1558   done
  1559 
  1560 
  1561 subsubsection {* @{text foldl} and @{text foldr} *}
  1562 
  1563 lemma foldl_append [simp]:
  1564 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1565 by (induct xs) auto
  1566 
  1567 lemma foldr_append[simp]: "foldr f (xs @ ys) a = foldr f xs (foldr f ys a)"
  1568 by (induct xs) auto
  1569 
  1570 lemma foldl_cong [recdef_cong]:
  1571   "[| a = b; l = k; !!a x. x : set l ==> f a x = g a x |] 
  1572   ==> foldl f a l = foldl g b k"
  1573   by (induct k fixing: a b l, simp_all)
  1574 
  1575 lemma foldr_cong [recdef_cong]:
  1576   "[| a = b; l = k; !!a x. x : set l ==> f x a = g x a |] 
  1577   ==> foldr f l a = foldr g k b"
  1578   by (induct k fixing: a b l, simp_all)
  1579 
  1580 lemma foldr_foldl: "foldr f xs a = foldl (%x y. f y x) a (rev xs)"
  1581 by (induct xs) auto
  1582 
  1583 lemma foldl_foldr: "foldl f a xs = foldr (%x y. f y x) (rev xs) a"
  1584 by (simp add: foldr_foldl [of "%x y. f y x" "rev xs"])
  1585 
  1586 text {*
  1587 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1588 difficult to use because it requires an additional transitivity step.
  1589 *}
  1590 
  1591 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1592 by (induct ns) auto
  1593 
  1594 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1595 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1596 
  1597 lemma sum_eq_0_conv [iff]:
  1598 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1599 by (induct ns) auto
  1600 
  1601 
  1602 subsubsection {* @{text upto} *}
  1603 
  1604 lemma upt_rec[code]: "[i..<j] = (if i<j then i#[Suc i..<j] else [])"
  1605 -- {* simp does not terminate! *}
  1606 by (induct j) auto
  1607 
  1608 lemma upt_conv_Nil [simp]: "j <= i ==> [i..<j] = []"
  1609 by (subst upt_rec) simp
  1610 
  1611 lemma upt_eq_Nil_conv[simp]: "([i..<j] = []) = (j = 0 \<or> j <= i)"
  1612 by(induct j)simp_all
  1613 
  1614 lemma upt_eq_Cons_conv:
  1615  "!!x xs. ([i..<j] = x#xs) = (i < j & i = x & [i+1..<j] = xs)"
  1616 apply(induct j)
  1617  apply simp
  1618 apply(clarsimp simp add: append_eq_Cons_conv)
  1619 apply arith
  1620 done
  1621 
  1622 lemma upt_Suc_append: "i <= j ==> [i..<(Suc j)] = [i..<j]@[j]"
  1623 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1624 by simp
  1625 
  1626 lemma upt_conv_Cons: "i < j ==> [i..<j] = i # [Suc i..<j]"
  1627 apply(rule trans)
  1628 apply(subst upt_rec)
  1629  prefer 2 apply (rule refl, simp)
  1630 done
  1631 
  1632 lemma upt_add_eq_append: "i<=j ==> [i..<j+k] = [i..<j]@[j..<j+k]"
  1633 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1634 by (induct k) auto
  1635 
  1636 lemma length_upt [simp]: "length [i..<j] = j - i"
  1637 by (induct j) (auto simp add: Suc_diff_le)
  1638 
  1639 lemma nth_upt [simp]: "i + k < j ==> [i..<j] ! k = i + k"
  1640 apply (induct j)
  1641 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1642 done
  1643 
  1644 
  1645 lemma hd_upt[simp]: "i < j \<Longrightarrow> hd[i..<j] = i"
  1646 by(simp add:upt_conv_Cons)
  1647 
  1648 lemma last_upt[simp]: "i < j \<Longrightarrow> last[i..<j] = j - 1"
  1649 apply(cases j)
  1650  apply simp
  1651 by(simp add:upt_Suc_append)
  1652 
  1653 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..<n] = [i..<i+m]"
  1654 apply (induct m, simp)
  1655 apply (subst upt_rec)
  1656 apply (rule sym)
  1657 apply (subst upt_rec)
  1658 apply (simp del: upt.simps)
  1659 done
  1660 
  1661 lemma drop_upt[simp]: "drop m [i..<j] = [i+m..<j]"
  1662 apply(induct j)
  1663 apply auto
  1664 apply arith
  1665 done
  1666 
  1667 lemma map_Suc_upt: "map Suc [m..<n] = [Suc m..n]"
  1668 by (induct n) auto
  1669 
  1670 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..<n]) ! i = f(m+i)"
  1671 apply (induct n m rule: diff_induct)
  1672 prefer 3 apply (subst map_Suc_upt[symmetric])
  1673 apply (auto simp add: less_diff_conv nth_upt)
  1674 done
  1675 
  1676 lemma nth_take_lemma:
  1677   "!!xs ys. k <= length xs ==> k <= length ys ==>
  1678      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  1679 apply (atomize, induct k)
  1680 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib, clarify)
  1681 txt {* Both lists must be non-empty *}
  1682 apply (case_tac xs, simp)
  1683 apply (case_tac ys, clarify)
  1684  apply (simp (no_asm_use))
  1685 apply clarify
  1686 txt {* prenexing's needed, not miniscoping *}
  1687 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1688 apply blast
  1689 done
  1690 
  1691 lemma nth_equalityI:
  1692  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1693 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1694 apply (simp_all add: take_all)
  1695 done
  1696 
  1697 (* needs nth_equalityI *)
  1698 lemma list_all2_antisym:
  1699   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  1700   \<Longrightarrow> xs = ys"
  1701   apply (simp add: list_all2_conv_all_nth) 
  1702   apply (rule nth_equalityI, blast, simp)
  1703   done
  1704 
  1705 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1706 -- {* The famous take-lemma. *}
  1707 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1708 apply (simp add: le_max_iff_disj take_all)
  1709 done
  1710 
  1711 
  1712 lemma take_Cons':
  1713      "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1714 by (cases n) simp_all
  1715 
  1716 lemma drop_Cons':
  1717      "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1718 by (cases n) simp_all
  1719 
  1720 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1721 by (cases n) simp_all
  1722 
  1723 lemmas take_Cons_number_of = take_Cons'[of "number_of v",standard]
  1724 lemmas drop_Cons_number_of = drop_Cons'[of "number_of v",standard]
  1725 lemmas nth_Cons_number_of = nth_Cons'[of _ _ "number_of v",standard]
  1726 
  1727 declare take_Cons_number_of [simp] 
  1728         drop_Cons_number_of [simp] 
  1729         nth_Cons_number_of [simp] 
  1730 
  1731 
  1732 subsubsection {* @{text "distinct"} and @{text remdups} *}
  1733 
  1734 lemma distinct_append [simp]:
  1735 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1736 by (induct xs) auto
  1737 
  1738 lemma distinct_rev[simp]: "distinct(rev xs) = distinct xs"
  1739 by(induct xs) auto
  1740 
  1741 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1742 by (induct xs) (auto simp add: insert_absorb)
  1743 
  1744 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1745 by (induct xs) auto
  1746 
  1747 lemma remdups_eq_nil_iff [simp]: "(remdups x = []) = (x = [])"
  1748   by (induct x, auto) 
  1749 
  1750 lemma remdups_eq_nil_right_iff [simp]: "([] = remdups x) = (x = [])"
  1751   by (induct x, auto)
  1752 
  1753 lemma length_remdups_leq[iff]: "length(remdups xs) <= length xs"
  1754 by (induct xs) auto
  1755 
  1756 lemma length_remdups_eq[iff]:
  1757   "(length (remdups xs) = length xs) = (remdups xs = xs)"
  1758 apply(induct xs)
  1759  apply auto
  1760 apply(subgoal_tac "length (remdups xs) <= length xs")
  1761  apply arith
  1762 apply(rule length_remdups_leq)
  1763 done
  1764 
  1765 
  1766 lemma distinct_map:
  1767   "distinct(map f xs) = (distinct xs & inj_on f (set xs))"
  1768 by (induct xs) auto
  1769 
  1770 
  1771 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1772 by (induct xs) auto
  1773 
  1774 lemma distinct_upt[simp]: "distinct[i..<j]"
  1775 by (induct j) auto
  1776 
  1777 lemma distinct_take[simp]: "\<And>i. distinct xs \<Longrightarrow> distinct (take i xs)"
  1778 apply(induct xs)
  1779  apply simp
  1780 apply (case_tac i)
  1781  apply simp_all
  1782 apply(blast dest:in_set_takeD)
  1783 done
  1784 
  1785 lemma distinct_drop[simp]: "\<And>i. distinct xs \<Longrightarrow> distinct (drop i xs)"
  1786 apply(induct xs)
  1787  apply simp
  1788 apply (case_tac i)
  1789  apply simp_all
  1790 done
  1791 
  1792 lemma distinct_list_update:
  1793 assumes d: "distinct xs" and a: "a \<notin> set xs - {xs!i}"
  1794 shows "distinct (xs[i:=a])"
  1795 proof (cases "i < length xs")
  1796   case True
  1797   with a have "a \<notin> set (take i xs @ xs ! i # drop (Suc i) xs) - {xs!i}"
  1798     apply (drule_tac id_take_nth_drop) by simp
  1799   with d True show ?thesis
  1800     apply (simp add: upd_conv_take_nth_drop)
  1801     apply (drule subst [OF id_take_nth_drop]) apply assumption
  1802     apply simp apply (cases "a = xs!i") apply simp by blast
  1803 next
  1804   case False with d show ?thesis by auto
  1805 qed
  1806 
  1807 
  1808 text {* It is best to avoid this indexed version of distinct, but
  1809 sometimes it is useful. *}
  1810 
  1811 lemma distinct_conv_nth:
  1812 "distinct xs = (\<forall>i < size xs. \<forall>j < size xs. i \<noteq> j --> xs!i \<noteq> xs!j)"
  1813 apply (induct xs, simp, simp)
  1814 apply (rule iffI, clarsimp)
  1815  apply (case_tac i)
  1816 apply (case_tac j, simp)
  1817 apply (simp add: set_conv_nth)
  1818  apply (case_tac j)
  1819 apply (clarsimp simp add: set_conv_nth, simp)
  1820 apply (rule conjI)
  1821  apply (clarsimp simp add: set_conv_nth)
  1822  apply (erule_tac x = 0 in allE, simp)
  1823  apply (erule_tac x = "Suc i" in allE, simp, clarsimp)
  1824 apply (erule_tac x = "Suc i" in allE, simp)
  1825 apply (erule_tac x = "Suc j" in allE, simp)
  1826 done
  1827 
  1828 lemma nth_eq_iff_index_eq:
  1829  "\<lbrakk> distinct xs; i < length xs; j < length xs \<rbrakk> \<Longrightarrow> (xs!i = xs!j) = (i = j)"
  1830 by(auto simp: distinct_conv_nth)
  1831 
  1832 lemma distinct_card: "distinct xs ==> card (set xs) = size xs"
  1833   by (induct xs) auto
  1834 
  1835 lemma card_distinct: "card (set xs) = size xs ==> distinct xs"
  1836 proof (induct xs)
  1837   case Nil thus ?case by simp
  1838 next
  1839   case (Cons x xs)
  1840   show ?case
  1841   proof (cases "x \<in> set xs")
  1842     case False with Cons show ?thesis by simp
  1843   next
  1844     case True with Cons.prems
  1845     have "card (set xs) = Suc (length xs)" 
  1846       by (simp add: card_insert_if split: split_if_asm)
  1847     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  1848     ultimately have False by simp
  1849     thus ?thesis ..
  1850   qed
  1851 qed
  1852 
  1853 
  1854 lemma length_remdups_concat:
  1855  "length(remdups(concat xss)) = card(\<Union>xs \<in> set xss. set xs)"
  1856 by(simp add: distinct_card[symmetric])
  1857 
  1858 
  1859 subsubsection {* @{text remove1} *}
  1860 
  1861 lemma remove1_append:
  1862   "remove1 x (xs @ ys) =
  1863   (if x \<in> set xs then remove1 x xs @ ys else xs @ remove1 x ys)"
  1864 by (induct xs) auto
  1865 
  1866 lemma set_remove1_subset: "set(remove1 x xs) <= set xs"
  1867 apply(induct xs)
  1868  apply simp
  1869 apply simp
  1870 apply blast
  1871 done
  1872 
  1873 lemma set_remove1_eq [simp]: "distinct xs ==> set(remove1 x xs) = set xs - {x}"
  1874 apply(induct xs)
  1875  apply simp
  1876 apply simp
  1877 apply blast
  1878 done
  1879 
  1880 lemma remove1_filter_not[simp]:
  1881   "\<not> P x \<Longrightarrow> remove1 x (filter P xs) = filter P xs"
  1882 by(induct xs) auto
  1883 
  1884 lemma notin_set_remove1[simp]: "x ~: set xs ==> x ~: set(remove1 y xs)"
  1885 apply(insert set_remove1_subset)
  1886 apply fast
  1887 done
  1888 
  1889 lemma distinct_remove1[simp]: "distinct xs ==> distinct(remove1 x xs)"
  1890 by (induct xs) simp_all
  1891 
  1892 
  1893 subsubsection {* @{text replicate} *}
  1894 
  1895 lemma length_replicate [simp]: "length (replicate n x) = n"
  1896 by (induct n) auto
  1897 
  1898 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1899 by (induct n) auto
  1900 
  1901 lemma replicate_app_Cons_same:
  1902 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1903 by (induct n) auto
  1904 
  1905 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1906 apply (induct n, simp)
  1907 apply (simp add: replicate_app_Cons_same)
  1908 done
  1909 
  1910 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1911 by (induct n) auto
  1912 
  1913 text{* Courtesy of Matthias Daum: *}
  1914 lemma append_replicate_commute:
  1915   "replicate n x @ replicate k x = replicate k x @ replicate n x"
  1916 apply (simp add: replicate_add [THEN sym])
  1917 apply (simp add: add_commute)
  1918 done
  1919 
  1920 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1921 by (induct n) auto
  1922 
  1923 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1924 by (induct n) auto
  1925 
  1926 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1927 by (atomize (full), induct n) auto
  1928 
  1929 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1930 apply (induct n, simp)
  1931 apply (simp add: nth_Cons split: nat.split)
  1932 done
  1933 
  1934 text{* Courtesy of Matthias Daum (2 lemmas): *}
  1935 lemma take_replicate[simp]: "take i (replicate k x) = replicate (min i k) x"
  1936 apply (case_tac "k \<le> i")
  1937  apply  (simp add: min_def)
  1938 apply (drule not_leE)
  1939 apply (simp add: min_def)
  1940 apply (subgoal_tac "replicate k x = replicate i x @ replicate (k - i) x")
  1941  apply  simp
  1942 apply (simp add: replicate_add [symmetric])
  1943 done
  1944 
  1945 lemma drop_replicate[simp]: "!!i. drop i (replicate k x) = replicate (k-i) x"
  1946 apply (induct k)
  1947  apply simp
  1948 apply clarsimp
  1949 apply (case_tac i)
  1950  apply simp
  1951 apply clarsimp
  1952 done
  1953 
  1954 
  1955 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1956 by (induct n) auto
  1957 
  1958 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1959 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1960 
  1961 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1962 by auto
  1963 
  1964 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1965 by (simp add: set_replicate_conv_if split: split_if_asm)
  1966 
  1967 
  1968 subsubsection{*@{text rotate1} and @{text rotate}*}
  1969 
  1970 lemma rotate_simps[simp]: "rotate1 [] = [] \<and> rotate1 (x#xs) = xs @ [x]"
  1971 by(simp add:rotate1_def)
  1972 
  1973 lemma rotate0[simp]: "rotate 0 = id"
  1974 by(simp add:rotate_def)
  1975 
  1976 lemma rotate_Suc[simp]: "rotate (Suc n) xs = rotate1(rotate n xs)"
  1977 by(simp add:rotate_def)
  1978 
  1979 lemma rotate_add:
  1980   "rotate (m+n) = rotate m o rotate n"
  1981 by(simp add:rotate_def funpow_add)
  1982 
  1983 lemma rotate_rotate: "rotate m (rotate n xs) = rotate (m+n) xs"
  1984 by(simp add:rotate_add)
  1985 
  1986 lemma rotate1_rotate_swap: "rotate1 (rotate n xs) = rotate n (rotate1 xs)"
  1987 by(simp add:rotate_def funpow_swap1)
  1988 
  1989 lemma rotate1_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate1 xs = xs"
  1990 by(cases xs) simp_all
  1991 
  1992 lemma rotate_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate n xs = xs"
  1993 apply(induct n)
  1994  apply simp
  1995 apply (simp add:rotate_def)
  1996 done
  1997 
  1998 lemma rotate1_hd_tl: "xs \<noteq> [] \<Longrightarrow> rotate1 xs = tl xs @ [hd xs]"
  1999 by(simp add:rotate1_def split:list.split)
  2000 
  2001 lemma rotate_drop_take:
  2002   "rotate n xs = drop (n mod length xs) xs @ take (n mod length xs) xs"
  2003 apply(induct n)
  2004  apply simp
  2005 apply(simp add:rotate_def)
  2006 apply(cases "xs = []")
  2007  apply (simp)
  2008 apply(case_tac "n mod length xs = 0")
  2009  apply(simp add:mod_Suc)
  2010  apply(simp add: rotate1_hd_tl drop_Suc take_Suc)
  2011 apply(simp add:mod_Suc rotate1_hd_tl drop_Suc[symmetric] drop_tl[symmetric]
  2012                 take_hd_drop linorder_not_le)
  2013 done
  2014 
  2015 lemma rotate_conv_mod: "rotate n xs = rotate (n mod length xs) xs"
  2016 by(simp add:rotate_drop_take)
  2017 
  2018 lemma rotate_id[simp]: "n mod length xs = 0 \<Longrightarrow> rotate n xs = xs"
  2019 by(simp add:rotate_drop_take)
  2020 
  2021 lemma length_rotate1[simp]: "length(rotate1 xs) = length xs"
  2022 by(simp add:rotate1_def split:list.split)
  2023 
  2024 lemma length_rotate[simp]: "!!xs. length(rotate n xs) = length xs"
  2025 by (induct n) (simp_all add:rotate_def)
  2026 
  2027 lemma distinct1_rotate[simp]: "distinct(rotate1 xs) = distinct xs"
  2028 by(simp add:rotate1_def split:list.split) blast
  2029 
  2030 lemma distinct_rotate[simp]: "distinct(rotate n xs) = distinct xs"
  2031 by (induct n) (simp_all add:rotate_def)
  2032 
  2033 lemma rotate_map: "rotate n (map f xs) = map f (rotate n xs)"
  2034 by(simp add:rotate_drop_take take_map drop_map)
  2035 
  2036 lemma set_rotate1[simp]: "set(rotate1 xs) = set xs"
  2037 by(simp add:rotate1_def split:list.split)
  2038 
  2039 lemma set_rotate[simp]: "set(rotate n xs) = set xs"
  2040 by (induct n) (simp_all add:rotate_def)
  2041 
  2042 lemma rotate1_is_Nil_conv[simp]: "(rotate1 xs = []) = (xs = [])"
  2043 by(simp add:rotate1_def split:list.split)
  2044 
  2045 lemma rotate_is_Nil_conv[simp]: "(rotate n xs = []) = (xs = [])"
  2046 by (induct n) (simp_all add:rotate_def)
  2047 
  2048 lemma rotate_rev:
  2049   "rotate n (rev xs) = rev(rotate (length xs - (n mod length xs)) xs)"
  2050 apply(simp add:rotate_drop_take rev_drop rev_take)
  2051 apply(cases "length xs = 0")
  2052  apply simp
  2053 apply(cases "n mod length xs = 0")
  2054  apply simp
  2055 apply(simp add:rotate_drop_take rev_drop rev_take)
  2056 done
  2057 
  2058 lemma hd_rotate_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd(rotate n xs) = xs!(n mod length xs)"
  2059 apply(simp add:rotate_drop_take hd_append hd_drop_conv_nth hd_conv_nth)
  2060 apply(subgoal_tac "length xs \<noteq> 0")
  2061  prefer 2 apply simp
  2062 using mod_less_divisor[of "length xs" n] by arith
  2063 
  2064 
  2065 subsubsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  2066 
  2067 lemma sublist_empty [simp]: "sublist xs {} = []"
  2068 by (auto simp add: sublist_def)
  2069 
  2070 lemma sublist_nil [simp]: "sublist [] A = []"
  2071 by (auto simp add: sublist_def)
  2072 
  2073 lemma length_sublist:
  2074   "length(sublist xs I) = card{i. i < length xs \<and> i : I}"
  2075 by(simp add: sublist_def length_filter_conv_card cong:conj_cong)
  2076 
  2077 lemma sublist_shift_lemma_Suc:
  2078   "!!is. map fst (filter (%p. P(Suc(snd p))) (zip xs is)) =
  2079          map fst (filter (%p. P(snd p)) (zip xs (map Suc is)))"
  2080 apply(induct xs)
  2081  apply simp
  2082 apply (case_tac "is")
  2083  apply simp
  2084 apply simp
  2085 done
  2086 
  2087 lemma sublist_shift_lemma:
  2088      "map fst [p:zip xs [i..<i + length xs] . snd p : A] =
  2089       map fst [p:zip xs [0..<length xs] . snd p + i : A]"
  2090 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  2091 
  2092 lemma sublist_append:
  2093      "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  2094 apply (unfold sublist_def)
  2095 apply (induct l' rule: rev_induct, simp)
  2096 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  2097 apply (simp add: add_commute)
  2098 done
  2099 
  2100 lemma sublist_Cons:
  2101 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  2102 apply (induct l rule: rev_induct)
  2103  apply (simp add: sublist_def)
  2104 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  2105 done
  2106 
  2107 lemma set_sublist: "!!I. set(sublist xs I) = {xs!i|i. i<size xs \<and> i \<in> I}"
  2108 apply(induct xs)
  2109  apply simp
  2110 apply(auto simp add:sublist_Cons nth_Cons split:nat.split elim: lessE)
  2111  apply(erule lessE)
  2112   apply auto
  2113 apply(erule lessE)
  2114 apply auto
  2115 done
  2116 
  2117 lemma set_sublist_subset: "set(sublist xs I) \<subseteq> set xs"
  2118 by(auto simp add:set_sublist)
  2119 
  2120 lemma notin_set_sublistI[simp]: "x \<notin> set xs \<Longrightarrow> x \<notin> set(sublist xs I)"
  2121 by(auto simp add:set_sublist)
  2122 
  2123 lemma in_set_sublistD: "x \<in> set(sublist xs I) \<Longrightarrow> x \<in> set xs"
  2124 by(auto simp add:set_sublist)
  2125 
  2126 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  2127 by (simp add: sublist_Cons)
  2128 
  2129 
  2130 lemma distinct_sublistI[simp]: "!!I. distinct xs \<Longrightarrow> distinct(sublist xs I)"
  2131 apply(induct xs)
  2132  apply simp
  2133 apply(auto simp add:sublist_Cons)
  2134 done
  2135 
  2136 
  2137 lemma sublist_upt_eq_take [simp]: "sublist l {..<n} = take n l"
  2138 apply (induct l rule: rev_induct, simp)
  2139 apply (simp split: nat_diff_split add: sublist_append)
  2140 done
  2141 
  2142 lemma filter_in_sublist: "\<And>s. distinct xs \<Longrightarrow>
  2143   filter (%x. x \<in> set(sublist xs s)) xs = sublist xs s"
  2144 proof (induct xs)
  2145   case Nil thus ?case by simp
  2146 next
  2147   case (Cons a xs)
  2148   moreover hence "!x. x: set xs \<longrightarrow> x \<noteq> a" by auto
  2149   ultimately show ?case by(simp add: sublist_Cons cong:filter_cong)
  2150 qed
  2151 
  2152 
  2153 subsubsection{*Sets of Lists*}
  2154 
  2155 subsubsection {* @{text lists}: the list-forming operator over sets *}
  2156 
  2157 consts lists :: "'a set => 'a list set"
  2158 inductive "lists A"
  2159  intros
  2160   Nil [intro!]: "[]: lists A"
  2161   Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
  2162 
  2163 inductive_cases listsE [elim!]: "x#l : lists A"
  2164 
  2165 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
  2166 by (unfold lists.defs) (blast intro!: lfp_mono)
  2167 
  2168 lemma lists_IntI:
  2169   assumes l: "l: lists A" shows "l: lists B ==> l: lists (A Int B)" using l
  2170   by induct blast+
  2171 
  2172 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
  2173 proof (rule mono_Int [THEN equalityI])
  2174   show "mono lists" by (simp add: mono_def lists_mono)
  2175   show "lists A \<inter> lists B \<subseteq> lists (A \<inter> B)" by (blast intro: lists_IntI)
  2176 qed
  2177 
  2178 lemma append_in_lists_conv [iff]:
  2179      "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
  2180 by (induct xs) auto
  2181 
  2182 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
  2183 -- {* eliminate @{text lists} in favour of @{text set} *}
  2184 by (induct xs) auto
  2185 
  2186 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
  2187 by (rule in_lists_conv_set [THEN iffD1])
  2188 
  2189 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
  2190 by (rule in_lists_conv_set [THEN iffD2])
  2191 
  2192 lemma lists_UNIV [simp]: "lists UNIV = UNIV"
  2193 by auto
  2194 
  2195 subsubsection {* For efficiency *}
  2196 
  2197 text{* Only use @{text mem} for generating executable code.  Otherwise
  2198 use @{prop"x : set xs"} instead --- it is much easier to reason about.
  2199 The same is true for @{const list_all} and @{const list_ex}: write
  2200 @{text"\<forall>x\<in>set xs"} and @{text"\<exists>x\<in>set xs"} instead because the HOL
  2201 quantifiers are aleady known to the automatic provers. In fact, the declarations in the Code subsection make sure that @{text"\<in>"}, @{text"\<forall>x\<in>set xs"}
  2202 and @{text"\<exists>x\<in>set xs"} are implemented efficiently.
  2203 
  2204 The functions @{const itrev}, @{const filtermap} and @{const
  2205 map_filter} are just there to generate efficient code. Do not use them
  2206 for modelling and proving. *}
  2207 
  2208 lemma mem_iff: "(x mem xs) = (x : set xs)"
  2209 by (induct xs) auto
  2210 
  2211 lemma list_inter_conv: "set(list_inter xs ys) = set xs \<inter> set ys"
  2212 by (induct xs) auto
  2213 
  2214 lemma list_all_iff: "list_all P xs = (\<forall>x \<in> set xs. P x)"
  2215 by (induct xs) auto
  2216 
  2217 lemma list_all_append [simp]:
  2218 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
  2219 by (induct xs) auto
  2220 
  2221 lemma list_all_rev [simp]: "list_all P (rev xs) = list_all P xs"
  2222 by (simp add: list_all_iff)
  2223 
  2224 lemma list_ex_iff: "list_ex P xs = (\<exists>x \<in> set xs. P x)"
  2225 by (induct xs) simp_all
  2226 
  2227 lemma itrev[simp]: "ALL ys. itrev xs ys = rev xs @ ys"
  2228 by (induct xs) simp_all
  2229 
  2230 lemma filtermap_conv:
  2231      "filtermap f xs = map (%x. the(f x)) (filter (%x. f x \<noteq> None) xs)"
  2232   by (induct xs) (simp_all split: option.split) 
  2233 
  2234 lemma map_filter_conv[simp]: "map_filter f P xs = map f (filter P xs)"
  2235 by (induct xs) auto
  2236 
  2237 
  2238 subsubsection {* Code generation *}
  2239 
  2240 text{* Defaults for generating efficient code for some standard functions. *}
  2241 
  2242 lemmas in_set_code[code unfold] = mem_iff[symmetric, THEN eq_reflection]
  2243 
  2244 lemma rev_code[code unfold]: "rev xs == itrev xs []"
  2245 by simp
  2246 
  2247 lemma distinct_Cons_mem[code]: "distinct (x#xs) = (~(x mem xs) \<and> distinct xs)"
  2248 by (simp add:mem_iff)
  2249 
  2250 lemma remdups_Cons_mem[code]:
  2251  "remdups (x#xs) = (if x mem xs then remdups xs else x # remdups xs)"
  2252 by (simp add:mem_iff)
  2253 
  2254 lemma list_inter_Cons_mem[code]:  "list_inter (a#as) bs =
  2255   (if a mem bs then a#(list_inter as bs) else list_inter as bs)"
  2256 by(simp add:mem_iff)
  2257 
  2258 text{* For implementing bounded quantifiers over lists by
  2259 @{const list_ex}/@{const list_all}: *}
  2260 
  2261 lemmas list_bex_code[code unfold] = list_ex_iff[symmetric, THEN eq_reflection]
  2262 lemmas list_ball_code[code unfold] = list_all_iff[symmetric, THEN eq_reflection]
  2263 
  2264 
  2265 subsubsection{* Inductive definition for membership *}
  2266 
  2267 consts ListMem :: "('a \<times> 'a list)set"
  2268 inductive ListMem
  2269 intros
  2270  elem:  "(x,x#xs) \<in> ListMem"
  2271  insert:  "(x,xs) \<in> ListMem \<Longrightarrow> (x,y#xs) \<in> ListMem"
  2272 
  2273 lemma ListMem_iff: "((x,xs) \<in> ListMem) = (x \<in> set xs)"
  2274 apply (rule iffI)
  2275  apply (induct set: ListMem)
  2276   apply auto
  2277 apply (induct xs)
  2278  apply (auto intro: ListMem.intros)
  2279 done
  2280 
  2281 
  2282 
  2283 subsubsection{*Lists as Cartesian products*}
  2284 
  2285 text{*@{text"set_Cons A Xs"}: the set of lists with head drawn from
  2286 @{term A} and tail drawn from @{term Xs}.*}
  2287 
  2288 constdefs
  2289   set_Cons :: "'a set \<Rightarrow> 'a list set \<Rightarrow> 'a list set"
  2290   "set_Cons A XS == {z. \<exists>x xs. z = x#xs & x \<in> A & xs \<in> XS}"
  2291 
  2292 lemma set_Cons_sing_Nil [simp]: "set_Cons A {[]} = (%x. [x])`A"
  2293 by (auto simp add: set_Cons_def)
  2294 
  2295 text{*Yields the set of lists, all of the same length as the argument and
  2296 with elements drawn from the corresponding element of the argument.*}
  2297 
  2298 consts  listset :: "'a set list \<Rightarrow> 'a list set"
  2299 primrec
  2300    "listset []    = {[]}"
  2301    "listset(A#As) = set_Cons A (listset As)"
  2302 
  2303 
  2304 subsection{*Relations on Lists*}
  2305 
  2306 subsubsection {* Length Lexicographic Ordering *}
  2307 
  2308 text{*These orderings preserve well-foundedness: shorter lists 
  2309   precede longer lists. These ordering are not used in dictionaries.*}
  2310 
  2311 consts lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
  2312         --{*The lexicographic ordering for lists of the specified length*}
  2313 primrec
  2314   "lexn r 0 = {}"
  2315   "lexn r (Suc n) =
  2316     (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
  2317     {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
  2318 
  2319 constdefs
  2320   lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
  2321     "lex r == \<Union>n. lexn r n"
  2322         --{*Holds only between lists of the same length*}
  2323 
  2324   lenlex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
  2325     "lenlex r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
  2326         --{*Compares lists by their length and then lexicographically*}
  2327 
  2328 
  2329 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  2330 apply (induct n, simp, simp)
  2331 apply(rule wf_subset)
  2332  prefer 2 apply (rule Int_lower1)
  2333 apply(rule wf_prod_fun_image)
  2334  prefer 2 apply (rule inj_onI, auto)
  2335 done
  2336 
  2337 lemma lexn_length:
  2338      "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  2339 by (induct n) auto
  2340 
  2341 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  2342 apply (unfold lex_def)
  2343 apply (rule wf_UN)
  2344 apply (blast intro: wf_lexn, clarify)
  2345 apply (rename_tac m n)
  2346 apply (subgoal_tac "m \<noteq> n")
  2347  prefer 2 apply blast
  2348 apply (blast dest: lexn_length not_sym)
  2349 done
  2350 
  2351 lemma lexn_conv:
  2352   "lexn r n =
  2353     {(xs,ys). length xs = n \<and> length ys = n \<and>
  2354     (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  2355 apply (induct n, simp)
  2356 apply (simp add: image_Collect lex_prod_def, safe, blast)
  2357  apply (rule_tac x = "ab # xys" in exI, simp)
  2358 apply (case_tac xys, simp_all, blast)
  2359 done
  2360 
  2361 lemma lex_conv:
  2362   "lex r =
  2363     {(xs,ys). length xs = length ys \<and>
  2364     (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  2365 by (force simp add: lex_def lexn_conv)
  2366 
  2367 lemma wf_lenlex [intro!]: "wf r ==> wf (lenlex r)"
  2368 by (unfold lenlex_def) blast
  2369 
  2370 lemma lenlex_conv:
  2371     "lenlex r = {(xs,ys). length xs < length ys |
  2372                  length xs = length ys \<and> (xs, ys) : lex r}"
  2373 by (simp add: lenlex_def diag_def lex_prod_def measure_def inv_image_def)
  2374 
  2375 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  2376 by (simp add: lex_conv)
  2377 
  2378 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  2379 by (simp add:lex_conv)
  2380 
  2381 lemma Cons_in_lex [simp]:
  2382     "((x # xs, y # ys) : lex r) =
  2383       ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  2384 apply (simp add: lex_conv)
  2385 apply (rule iffI)
  2386  prefer 2 apply (blast intro: Cons_eq_appendI, clarify)
  2387 apply (case_tac xys, simp, simp)
  2388 apply blast
  2389 done
  2390 
  2391 
  2392 subsubsection {* Lexicographic Ordering *}
  2393 
  2394 text {* Classical lexicographic ordering on lists, ie. "a" < "ab" < "b".
  2395     This ordering does \emph{not} preserve well-foundedness.
  2396      Author: N. Voelker, March 2005. *} 
  2397 
  2398 constdefs 
  2399   lexord :: "('a * 'a)set \<Rightarrow> ('a list * 'a list) set" 
  2400   "lexord  r == {(x,y). \<exists> a v. y = x @ a # v \<or> 
  2401             (\<exists> u a b v w. (a,b) \<in> r \<and> x = u @ (a # v) \<and> y = u @ (b # w))}"
  2402 
  2403 lemma lexord_Nil_left[simp]:  "([],y) \<in> lexord r = (\<exists> a x. y = a # x)"
  2404   by (unfold lexord_def, induct_tac y, auto) 
  2405 
  2406 lemma lexord_Nil_right[simp]: "(x,[]) \<notin> lexord r"
  2407   by (unfold lexord_def, induct_tac x, auto)
  2408 
  2409 lemma lexord_cons_cons[simp]:
  2410      "((a # x, b # y) \<in> lexord r) = ((a,b)\<in> r | (a = b & (x,y)\<in> lexord r))"
  2411   apply (unfold lexord_def, safe, simp_all)
  2412   apply (case_tac u, simp, simp)
  2413   apply (case_tac u, simp, clarsimp, blast, blast, clarsimp)
  2414   apply (erule_tac x="b # u" in allE)
  2415   by force
  2416 
  2417 lemmas lexord_simps = lexord_Nil_left lexord_Nil_right lexord_cons_cons
  2418 
  2419 lemma lexord_append_rightI: "\<exists> b z. y = b # z \<Longrightarrow> (x, x @ y) \<in> lexord r"
  2420   by (induct_tac x, auto)  
  2421 
  2422 lemma lexord_append_left_rightI:
  2423      "(a,b) \<in> r \<Longrightarrow> (u @ a # x, u @ b # y) \<in> lexord r"
  2424   by (induct_tac u, auto)
  2425 
  2426 lemma lexord_append_leftI: " (u,v) \<in> lexord r \<Longrightarrow> (x @ u, x @ v) \<in> lexord r"
  2427   by (induct x, auto)
  2428 
  2429 lemma lexord_append_leftD:
  2430      "\<lbrakk> (x @ u, x @ v) \<in> lexord r; (! a. (a,a) \<notin> r) \<rbrakk> \<Longrightarrow> (u,v) \<in> lexord r"
  2431   by (erule rev_mp, induct_tac x, auto)
  2432 
  2433 lemma lexord_take_index_conv: 
  2434    "((x,y) : lexord r) = 
  2435     ((length x < length y \<and> take (length x) y = x) \<or> 
  2436      (\<exists>i. i < min(length x)(length y) & take i x = take i y & (x!i,y!i) \<in> r))"
  2437   apply (unfold lexord_def Let_def, clarsimp) 
  2438   apply (rule_tac f = "(% a b. a \<or> b)" in arg_cong2)
  2439   apply auto 
  2440   apply (rule_tac x="hd (drop (length x) y)" in exI)
  2441   apply (rule_tac x="tl (drop (length x) y)" in exI)
  2442   apply (erule subst, simp add: min_def) 
  2443   apply (rule_tac x ="length u" in exI, simp) 
  2444   apply (rule_tac x ="take i x" in exI) 
  2445   apply (rule_tac x ="x ! i" in exI) 
  2446   apply (rule_tac x ="y ! i" in exI, safe) 
  2447   apply (rule_tac x="drop (Suc i) x" in exI)
  2448   apply (drule sym, simp add: drop_Suc_conv_tl) 
  2449   apply (rule_tac x="drop (Suc i) y" in exI)
  2450   by (simp add: drop_Suc_conv_tl) 
  2451 
  2452 -- {* lexord is extension of partial ordering List.lex *} 
  2453 lemma lexord_lex: " (x,y) \<in> lex r = ((x,y) \<in> lexord r \<and> length x = length y)"
  2454   apply (rule_tac x = y in spec) 
  2455   apply (induct_tac x, clarsimp) 
  2456   by (clarify, case_tac x, simp, force)
  2457 
  2458 lemma lexord_irreflexive: "(! x. (x,x) \<notin> r) \<Longrightarrow> (y,y) \<notin> lexord r"
  2459   by (induct y, auto)
  2460 
  2461 lemma lexord_trans: 
  2462     "\<lbrakk> (x, y) \<in> lexord r; (y, z) \<in> lexord r; trans r \<rbrakk> \<Longrightarrow> (x, z) \<in> lexord r"
  2463    apply (erule rev_mp)+
  2464    apply (rule_tac x = x in spec) 
  2465   apply (rule_tac x = z in spec) 
  2466   apply ( induct_tac y, simp, clarify)
  2467   apply (case_tac xa, erule ssubst) 
  2468   apply (erule allE, erule allE) -- {* avoid simp recursion *} 
  2469   apply (case_tac x, simp, simp) 
  2470   apply (case_tac x, erule allE, erule allE, simp) 
  2471   apply (erule_tac x = listb in allE) 
  2472   apply (erule_tac x = lista in allE, simp)
  2473   apply (unfold trans_def)
  2474   by blast
  2475 
  2476 lemma lexord_transI:  "trans r \<Longrightarrow> trans (lexord r)"
  2477   by (rule transI, drule lexord_trans, blast) 
  2478 
  2479 lemma lexord_linear: "(! a b. (a,b)\<in> r | a = b | (b,a) \<in> r) \<Longrightarrow> (x,y) : lexord r | x = y | (y,x) : lexord r"
  2480   apply (rule_tac x = y in spec) 
  2481   apply (induct_tac x, rule allI) 
  2482   apply (case_tac x, simp, simp) 
  2483   apply (rule allI, case_tac x, simp, simp) 
  2484   by blast
  2485 
  2486 
  2487 subsubsection{*Lifting a Relation on List Elements to the Lists*}
  2488 
  2489 consts  listrel :: "('a * 'a)set => ('a list * 'a list)set"
  2490 
  2491 inductive "listrel(r)"
  2492  intros
  2493    Nil:  "([],[]) \<in> listrel r"
  2494    Cons: "[| (x,y) \<in> r; (xs,ys) \<in> listrel r |] ==> (x#xs, y#ys) \<in> listrel r"
  2495 
  2496 inductive_cases listrel_Nil1 [elim!]: "([],xs) \<in> listrel r"
  2497 inductive_cases listrel_Nil2 [elim!]: "(xs,[]) \<in> listrel r"
  2498 inductive_cases listrel_Cons1 [elim!]: "(y#ys,xs) \<in> listrel r"
  2499 inductive_cases listrel_Cons2 [elim!]: "(xs,y#ys) \<in> listrel r"
  2500 
  2501 
  2502 lemma listrel_mono: "r \<subseteq> s \<Longrightarrow> listrel r \<subseteq> listrel s"
  2503 apply clarify  
  2504 apply (erule listrel.induct)
  2505 apply (blast intro: listrel.intros)+
  2506 done
  2507 
  2508 lemma listrel_subset: "r \<subseteq> A \<times> A \<Longrightarrow> listrel r \<subseteq> lists A \<times> lists A"
  2509 apply clarify 
  2510 apply (erule listrel.induct, auto) 
  2511 done
  2512 
  2513 lemma listrel_refl: "refl A r \<Longrightarrow> refl (lists A) (listrel r)" 
  2514 apply (simp add: refl_def listrel_subset Ball_def)
  2515 apply (rule allI) 
  2516 apply (induct_tac x) 
  2517 apply (auto intro: listrel.intros)
  2518 done
  2519 
  2520 lemma listrel_sym: "sym r \<Longrightarrow> sym (listrel r)" 
  2521 apply (auto simp add: sym_def)
  2522 apply (erule listrel.induct) 
  2523 apply (blast intro: listrel.intros)+
  2524 done
  2525 
  2526 lemma listrel_trans: "trans r \<Longrightarrow> trans (listrel r)" 
  2527 apply (simp add: trans_def)
  2528 apply (intro allI) 
  2529 apply (rule impI) 
  2530 apply (erule listrel.induct) 
  2531 apply (blast intro: listrel.intros)+
  2532 done
  2533 
  2534 theorem equiv_listrel: "equiv A r \<Longrightarrow> equiv (lists A) (listrel r)"
  2535 by (simp add: equiv_def listrel_refl listrel_sym listrel_trans) 
  2536 
  2537 lemma listrel_Nil [simp]: "listrel r `` {[]} = {[]}"
  2538 by (blast intro: listrel.intros)
  2539 
  2540 lemma listrel_Cons:
  2541      "listrel r `` {x#xs} = set_Cons (r``{x}) (listrel r `` {xs})";
  2542 by (auto simp add: set_Cons_def intro: listrel.intros) 
  2543 
  2544 
  2545 subsection{*Miscellany*}
  2546 
  2547 subsubsection {* Characters and strings *}
  2548 
  2549 datatype nibble =
  2550     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  2551   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  2552 
  2553 datatype char = Char nibble nibble
  2554   -- "Note: canonical order of character encoding coincides with standard term ordering"
  2555 
  2556 types string = "char list"
  2557 
  2558 syntax
  2559   "_Char" :: "xstr => char"    ("CHR _")
  2560   "_String" :: "xstr => string"    ("_")
  2561 
  2562 parse_ast_translation {*
  2563   let
  2564     val constants = Syntax.Appl o map Syntax.Constant;
  2565 
  2566     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  2567     fun mk_char c =
  2568       if Symbol.is_ascii c andalso Symbol.is_printable c then
  2569         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  2570       else error ("Printable ASCII character expected: " ^ quote c);
  2571 
  2572     fun mk_string [] = Syntax.Constant "Nil"
  2573       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  2574 
  2575     fun char_ast_tr [Syntax.Variable xstr] =
  2576         (case Syntax.explode_xstr xstr of
  2577           [c] => mk_char c
  2578         | _ => error ("Single character expected: " ^ xstr))
  2579       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  2580 
  2581     fun string_ast_tr [Syntax.Variable xstr] =
  2582         (case Syntax.explode_xstr xstr of
  2583           [] => constants [Syntax.constrainC, "Nil", "string"]
  2584         | cs => mk_string cs)
  2585       | string_ast_tr asts = raise AST ("string_tr", asts);
  2586   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  2587 *}
  2588 
  2589 ML {*
  2590 fun int_of_nibble h =
  2591   if "0" <= h andalso h <= "9" then ord h - ord "0"
  2592   else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  2593   else raise Match;
  2594 
  2595 fun nibble_of_int i =
  2596   if i <= 9 then chr (ord "0" + i) else chr (ord "A" + i - 10);
  2597 *}
  2598 
  2599 print_ast_translation {*
  2600   let
  2601     fun dest_nib (Syntax.Constant c) =
  2602         (case explode c of
  2603           ["N", "i", "b", "b", "l", "e", h] => int_of_nibble h
  2604         | _ => raise Match)
  2605       | dest_nib _ = raise Match;
  2606 
  2607     fun dest_chr c1 c2 =
  2608       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  2609       in if Symbol.is_printable c then c else raise Match end;
  2610 
  2611     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  2612       | dest_char _ = raise Match;
  2613 
  2614     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  2615 
  2616     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  2617       | char_ast_tr' _ = raise Match;
  2618 
  2619     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  2620             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  2621       | list_ast_tr' ts = raise Match;
  2622   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  2623 *}
  2624 
  2625 subsubsection {* Code generator setup *}
  2626 
  2627 ML {*
  2628 local
  2629 
  2630 fun list_codegen thy defs gr dep thyname b t =
  2631   let val (gr', ps) = foldl_map (Codegen.invoke_codegen thy defs dep thyname false)
  2632     (gr, HOLogic.dest_list t)
  2633   in SOME (gr', Pretty.list "[" "]" ps) end handle TERM _ => NONE;
  2634 
  2635 fun dest_nibble (Const (s, _)) = int_of_nibble (unprefix "List.nibble.Nibble" s)
  2636   | dest_nibble _ = raise Match;
  2637 
  2638 fun char_codegen thy defs gr dep thyname b (Const ("List.char.Char", _) $ c1 $ c2) =
  2639     (let val c = chr (dest_nibble c1 * 16 + dest_nibble c2)
  2640      in if Symbol.is_printable c then SOME (gr, Pretty.quote (Pretty.str c))
  2641        else NONE
  2642      end handle Fail _ => NONE | Match => NONE)
  2643   | char_codegen thy defs gr dep thyname b _ = NONE;
  2644 
  2645 in
  2646 
  2647 val list_codegen_setup =
  2648   Codegen.add_codegen "list_codegen" list_codegen #>
  2649   Codegen.add_codegen "char_codegen" char_codegen #>
  2650   fold (CodegenPackage.add_pretty_list "Nil" "Cons") [
  2651     ("ml", (7, "::")),
  2652     ("haskell", (5, ":"))];
  2653 
  2654 end;
  2655 *}
  2656 
  2657 types_code
  2658   "list" ("_ list")
  2659 attach (term_of) {*
  2660 val term_of_list = HOLogic.mk_list;
  2661 *}
  2662 attach (test) {*
  2663 fun gen_list' aG i j = frequency
  2664   [(i, fn () => aG j :: gen_list' aG (i-1) j), (1, fn () => [])] ()
  2665 and gen_list aG i = gen_list' aG i i;
  2666 *}
  2667   "char" ("string")
  2668 attach (term_of) {*
  2669 val nibbleT = Type ("List.nibble", []);
  2670 
  2671 fun term_of_char c =
  2672   Const ("List.char.Char", nibbleT --> nibbleT --> Type ("List.char", [])) $
  2673     Const ("List.nibble.Nibble" ^ nibble_of_int (ord c div 16), nibbleT) $
  2674     Const ("List.nibble.Nibble" ^ nibble_of_int (ord c mod 16), nibbleT);
  2675 *}
  2676 attach (test) {*
  2677 fun gen_char i = chr (random_range (ord "a") (Int.min (ord "a" + i, ord "z")));
  2678 *}
  2679 
  2680 consts_code "Cons" ("(_ ::/ _)")
  2681 
  2682 code_alias
  2683   "List.op @" "List.append"
  2684   "List.op mem" "List.member"
  2685 
  2686 code_generate Nil Cons
  2687 
  2688 code_syntax_tyco
  2689   list
  2690     ml ("_ list")
  2691     haskell (target_atom "[_]")
  2692 
  2693 code_syntax_const
  2694   Nil
  2695     ml (target_atom "[]")
  2696     haskell (target_atom "[]")
  2697 
  2698 setup list_codegen_setup
  2699 
  2700 setup CodegenPackage.rename_inconsistent
  2701 
  2702 end