src/Pure/library.ML
author wenzelm
Mon Jul 04 17:07:10 2005 +0200 (2005-07-04)
changeset 16676 671bd433b9eb
parent 16654 d964cbaa6c1c
child 16688 e3de7ea24c23
permissions -rw-r--r--
added fast_string_ord;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*old options -- invalidated*)
    35   datatype invalid = None of invalid
    36   exception OPTION of invalid
    37 
    38   (*options*)
    39   val the: 'a option -> 'a
    40   val if_none: 'a option -> 'a -> 'a
    41   val is_some: 'a option -> bool
    42   val is_none: 'a option -> bool
    43 
    44   exception ERROR
    45   val try: ('a -> 'b) -> 'a -> 'b option
    46   val can: ('a -> 'b) -> 'a -> bool
    47   datatype 'a result = Result of 'a | Exn of exn
    48   val capture: ('a -> 'b) -> 'a -> 'b result
    49   val release: 'a result -> 'a
    50   val get_result: 'a result -> 'a option
    51   val get_exn: 'a result -> exn option
    52 
    53   (*pairs*)
    54   val pair: 'a -> 'b -> 'a * 'b
    55   val rpair: 'a -> 'b -> 'b * 'a
    56   val fst: 'a * 'b -> 'a
    57   val snd: 'a * 'b -> 'b
    58   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    59   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    60   val swap: 'a * 'b -> 'b * 'a
    61   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    62   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    63   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    64 
    65   (*booleans*)
    66   val equal: ''a -> ''a -> bool
    67   val not_equal: ''a -> ''a -> bool
    68   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    69   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val exists: ('a -> bool) -> 'a list -> bool
    71   val forall: ('a -> bool) -> 'a list -> bool
    72   val set: bool ref -> bool
    73   val reset: bool ref -> bool
    74   val toggle: bool ref -> bool
    75   val change: 'a ref -> ('a -> 'a) -> unit
    76   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    77   val conditional: bool -> (unit -> unit) -> unit
    78 
    79   (*lists*)
    80   exception UnequalLengths
    81   val cons: 'a -> 'a list -> 'a list
    82   val single: 'a -> 'a list
    83   val append: 'a list -> 'a list -> 'a list
    84   val apply: ('a -> 'a) list -> 'a -> 'a
    85   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    86   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    87   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    88   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    89   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val unflat: 'a list list -> 'b list -> 'b list list
    91   val splitAt: int * 'a list -> 'a list * 'a list
    92   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    93   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    94   val split_last: 'a list -> 'a list * 'a
    95   val nth_update: 'a -> int * 'a list -> 'a list
    96   val find_index: ('a -> bool) -> 'a list -> int
    97   val find_index_eq: ''a -> ''a list -> int
    98   val find_first: ('a -> bool) -> 'a list -> 'a option
    99   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   100   val separate: 'a -> 'a list -> 'a list
   101   val replicate: int -> 'a -> 'a list
   102   val multiply: 'a list * 'a list list -> 'a list list
   103   val product: 'a list -> 'b list -> ('a * 'b) list
   104   val filter: ('a -> bool) -> 'a list -> 'a list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: IntInf.int * IntInf.int -> IntInf.int
   121   val lcm: IntInf.int * IntInf.int -> IntInf.int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131   val read_radixint: int * string list -> int * string list
   132   val read_int: string list -> int * string list
   133   val oct_char: string -> string
   134 
   135   (*rational numbers*)
   136   type rat
   137   exception RAT of string
   138   val rep_rat: rat -> IntInf.int * IntInf.int
   139   val ratadd: rat * rat -> rat
   140   val ratmul: rat * rat -> rat
   141   val ratinv: rat -> rat
   142   val int_ratdiv: IntInf.int * IntInf.int -> rat
   143   val ratneg: rat -> rat
   144   val rat_of_int: int -> rat
   145   val rat_of_intinf: IntInf.int -> rat
   146 
   147   (*strings*)
   148   val nth_elem_string: int * string -> string
   149   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   150   val exists_string: (string -> bool) -> string -> bool
   151   val forall_string: (string -> bool) -> string -> bool
   152   val enclose: string -> string -> string -> string
   153   val unenclose: string -> string
   154   val quote: string -> string
   155   val space_implode: string -> string list -> string
   156   val commas: string list -> string
   157   val commas_quote: string list -> string
   158   val cat_lines: string list -> string
   159   val space_explode: string -> string -> string list
   160   val split_lines: string -> string list
   161   val prefix_lines: string -> string -> string
   162   val untabify: string list -> string list
   163   val suffix: string -> string -> string
   164   val unsuffix: string -> string -> string
   165   val unprefix: string -> string -> string
   166   val replicate_string: int -> string -> string
   167   val translate_string: (string -> string) -> string -> string
   168 
   169   (*lists as sets -- see also Pure/General/ord_list.ML*)
   170   val mem: ''a * ''a list -> bool
   171   val mem_int: int * int list -> bool
   172   val mem_string: string * string list -> bool
   173   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   174   val ins: ''a * ''a list -> ''a list
   175   val ins_int: int * int list -> int list
   176   val ins_string: string * string list -> string list
   177   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   178   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   179   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   180   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   181   val union: ''a list * ''a list -> ''a list
   182   val union_int: int list * int list -> int list
   183   val union_string: string list * string list -> string list
   184   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   185   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   186   val inter: ''a list * ''a list -> ''a list
   187   val inter_int: int list * int list -> int list
   188   val inter_string: string list * string list -> string list
   189   val subset: ''a list * ''a list -> bool
   190   val subset_int: int list * int list -> bool
   191   val subset_string: string list * string list -> bool
   192   val eq_set: ''a list * ''a list -> bool
   193   val eq_set_string: string list * string list -> bool
   194   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   195   val \ : ''a list * ''a -> ''a list
   196   val \\ : ''a list * ''a list -> ''a list
   197   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   198   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   199   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   200   val distinct: ''a list -> ''a list
   201   val findrep: ''a list -> ''a list
   202   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   203   val duplicates: ''a list -> ''a list
   204 
   205   (*association lists*)
   206   val assoc: (''a * 'b) list * ''a -> 'b option
   207   val assoc_int: (int * 'a) list * int -> 'a option
   208   val assoc_string: (string * 'a) list * string -> 'a option
   209   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   210   val assocs: (''a * 'b list) list -> ''a -> 'b list
   211   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   212   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   213   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   214   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   215 
   216   (*lists as tables*)
   217   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   218   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   219   val merge_lists: ''a list -> ''a list -> ''a list
   220   val merge_lists': ''a list -> ''a list -> ''a list
   221   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   222   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   223 
   224   (*balanced trees*)
   225   exception Balance
   226   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   227   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   228   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   229 
   230   (*orders*)
   231   val rev_order: order -> order
   232   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   233   val int_ord: int * int -> order
   234   val string_ord: string * string -> order
   235   val fast_string_ord: string * string -> order
   236   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   237   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   238   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   239   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   240   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   241   val sort_strings: string list -> string list
   242   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   243   val unique_strings: string list -> string list
   244 
   245   (*random numbers*)
   246   exception RANDOM
   247   val random: unit -> real
   248   val random_range: int -> int -> int
   249   val one_of: 'a list -> 'a
   250   val frequency: (int * 'a) list -> 'a
   251 
   252   (*current directory*)
   253   val cd: string -> unit
   254   val pwd: unit -> string
   255 
   256   (*misc*)
   257   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   258   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   259   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   260   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   261   val gensym: string -> string
   262   val scanwords: (string -> bool) -> string list -> string list
   263   type stamp
   264   val stamp: unit -> stamp
   265   type serial
   266   val serial: unit -> serial
   267   structure Object: sig type T end
   268 end;
   269 
   270 signature LIBRARY =
   271 sig
   272   include BASIC_LIBRARY
   273   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   274   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   275   val take: int * 'a list -> 'a list
   276   val drop: int * 'a list -> 'a list
   277   val nth_elem: int * 'a list -> 'a
   278   val last_elem: 'a list -> 'a
   279   val flat: 'a list list -> 'a list
   280   val seq: ('a -> unit) -> 'a list -> unit
   281   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   282   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   283 end;
   284 
   285 structure Library: LIBRARY =
   286 struct
   287 
   288 
   289 (** functions **)
   290 
   291 (*handy combinators*)
   292 fun curry f x y = f (x, y);
   293 fun uncurry f (x, y) = f x y;
   294 fun I x = x;
   295 fun K x y = x;
   296 
   297 (*reverse apply*)
   298 fun (x |> f) = f x;
   299 fun ((x, y) |>> f) = (f x, y);
   300 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   301 
   302 (*application of (infix) operator to its left or right argument*)
   303 fun apl (x, f) y = f (x, y);
   304 fun apr (f, y) x = f (x, y);
   305 
   306 (*function exponentiation: f(...(f x)...) with n applications of f*)
   307 fun funpow n f x =
   308   let fun rep (0, x) = x
   309         | rep (n, x) = rep (n - 1, f x)
   310   in rep (n, x) end;
   311 
   312 (*concatenation: 2 and 3 args*)
   313 fun (f oo g) x y = f (g x y);
   314 fun (f ooo g) x y z = f (g x y z);
   315 fun (f oooo g) x y z w = f (g x y z w);
   316 
   317 
   318 
   319 (** options **)
   320 
   321 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   322 datatype invalid = None of invalid;
   323 exception OPTION of invalid;
   324 
   325 val the = Option.valOf;
   326 
   327 (*strict!*)
   328 fun if_none NONE y = y
   329   | if_none (SOME x) _ = x;
   330 
   331 fun is_some (SOME _) = true
   332   | is_some NONE = false;
   333 
   334 fun is_none (SOME _) = false
   335   | is_none NONE = true;
   336 
   337 
   338 (* exception handling *)
   339 
   340 exception ERROR;
   341 
   342 fun try f x = SOME (f x)
   343   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   344 
   345 fun can f x = is_some (try f x);
   346 
   347 
   348 datatype 'a result =
   349   Result of 'a |
   350   Exn of exn;
   351 
   352 fun capture f x = Result (f x) handle e => Exn e;
   353 
   354 fun release (Result y) = y
   355   | release (Exn e) = raise e;
   356 
   357 fun get_result (Result x) = SOME x
   358   | get_result _ = NONE;
   359 
   360 fun get_exn (Exn exn) = SOME exn
   361   | get_exn _ = NONE;
   362 
   363 
   364 
   365 (** pairs **)
   366 
   367 fun pair x y = (x, y);
   368 fun rpair x y = (y, x);
   369 
   370 fun fst (x, y) = x;
   371 fun snd (x, y) = y;
   372 
   373 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   374 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   375 
   376 fun swap (x, y) = (y, x);
   377 
   378 (*apply function to components*)
   379 fun apfst f (x, y) = (f x, y);
   380 fun apsnd f (x, y) = (x, f y);
   381 fun pairself f (x, y) = (f x, f y);
   382 
   383 
   384 
   385 (** booleans **)
   386 
   387 (* equality *)
   388 
   389 fun equal x y = x = y;
   390 fun not_equal x y = x <> y;
   391 
   392 
   393 (* operators for combining predicates *)
   394 
   395 fun (p orf q) = fn x => p x orelse q x;
   396 fun (p andf q) = fn x => p x andalso q x;
   397 
   398 
   399 (* predicates on lists *)
   400 
   401 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   402 fun exists (pred: 'a -> bool) : 'a list -> bool =
   403   let fun boolf [] = false
   404         | boolf (x :: xs) = pred x orelse boolf xs
   405   in boolf end;
   406 
   407 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   408 fun forall (pred: 'a -> bool) : 'a list -> bool =
   409   let fun boolf [] = true
   410         | boolf (x :: xs) = pred x andalso boolf xs
   411   in boolf end;
   412 
   413 
   414 (* flags *)
   415 
   416 fun set flag = (flag := true; true);
   417 fun reset flag = (flag := false; false);
   418 fun toggle flag = (flag := not (! flag); ! flag);
   419 
   420 fun change r f = r := f (! r);
   421 
   422 (*temporarily set flag, handling exceptions*)
   423 fun setmp flag value f x =
   424   let
   425     val orig_value = ! flag;
   426     fun return y = (flag := orig_value; y);
   427   in
   428     flag := value;
   429     return (f x handle exn => (return (); raise exn))
   430   end;
   431 
   432 
   433 (* conditional execution *)
   434 
   435 fun conditional b f = if b then f () else ();
   436 
   437 
   438 
   439 (** lists **)
   440 
   441 exception UnequalLengths;
   442 
   443 fun cons x xs = x :: xs;
   444 fun single x = [x];
   445 
   446 fun append xs ys = xs @ ys;
   447 
   448 fun apply [] x = x
   449   | apply (f :: fs) x = apply fs (f x);
   450 
   451 
   452 (* fold *)
   453 
   454 fun fold f =
   455   let
   456     fun fold_aux [] y = y
   457       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   458   in fold_aux end;
   459 
   460 fun fold_rev f =
   461   let
   462     fun fold_aux [] y = y
   463       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   464   in fold_aux end;
   465 
   466 fun foldl_map f =
   467   let
   468     fun fold_aux (x, []) = (x, [])
   469       | fold_aux (x, y :: ys) =
   470           let
   471             val (x', y') = f (x, y);
   472             val (x'', ys') = fold_aux (x', ys);
   473           in (x'', y' :: ys') end;
   474   in fold_aux end;
   475 
   476 (*the following versions of fold are designed to fit nicely with infixes*)
   477 
   478 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   479     for operators that associate to the left (TAIL RECURSIVE)*)
   480 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   481   let fun itl (e, [])  = e
   482         | itl (e, a::l) = itl (f(e, a), l)
   483   in  itl end;
   484 
   485 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   486     for operators that associate to the right (not tail recursive)*)
   487 fun foldr f (l, e) =
   488   let fun itr [] = e
   489         | itr (a::l) = f(a, itr l)
   490   in  itr l  end;
   491 
   492 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   493     for n > 0, operators that associate to the right (not tail recursive)*)
   494 fun foldr1 f l =
   495   let fun itr [x] = x
   496         | itr (x::l) = f(x, itr l)
   497   in  itr l  end;
   498 
   499 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   500 
   501 
   502 (* basic list functions *)
   503 
   504 (*take the first n elements from a list*)
   505 fun take (n, []) = []
   506   | take (n, x :: xs) =
   507       if n > 0 then x :: take (n - 1, xs) else [];
   508 
   509 (*drop the first n elements from a list*)
   510 fun drop (n, []) = []
   511   | drop (n, x :: xs) =
   512       if n > 0 then drop (n - 1, xs) else x :: xs;
   513 
   514 fun splitAt(n,[]) = ([],[])
   515   | splitAt(n,xs as x::ys) =
   516       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   517       else ([],xs)
   518 
   519 fun dropwhile P [] = []
   520   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   521 
   522 (*return nth element of a list, where 0 designates the first element;
   523   raise EXCEPTION if list too short*)
   524 fun nth_elem (i,xs) = List.nth(xs,i);
   525 
   526 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   527   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   528   | map_nth_elem _ _ [] = raise Subscript;
   529 
   530 (*last element of a list*)
   531 val last_elem = List.last;
   532 
   533 (*rear decomposition*)
   534 fun split_last [] = raise Empty
   535   | split_last [x] = ([], x)
   536   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   537 
   538 (*update nth element*)
   539 fun nth_update x n_xs =
   540     (case splitAt n_xs of
   541       (_,[]) => raise Subscript
   542     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   543 
   544 (*find the position of an element in a list*)
   545 fun find_index pred =
   546   let fun find _ [] = ~1
   547         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   548   in find 0 end;
   549 
   550 fun find_index_eq x = find_index (equal x);
   551 
   552 (*find first element satisfying predicate*)
   553 fun find_first _ [] = NONE
   554   | find_first pred (x :: xs) =
   555       if pred x then SOME x else find_first pred xs;
   556 
   557 (*get first element by lookup function*)
   558 fun get_first _ [] = NONE
   559   | get_first f (x :: xs) =
   560       (case f x of
   561         NONE => get_first f xs
   562       | some => some);
   563 
   564 (*flatten a list of lists to a list*)
   565 val flat = List.concat;
   566 
   567 fun unflat (xs :: xss) ys =
   568       let val (ps,qs) = splitAt(length xs,ys)
   569       in ps :: unflat xss qs end
   570   | unflat [] [] = []
   571   | unflat _ _ = raise UnequalLengths;
   572 
   573 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   574   (proc x1; ...; proc xn) for side effects*)
   575 val seq = List.app;
   576 
   577 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   578 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   579   | separate _ xs = xs;
   580 
   581 (*make the list [x, x, ..., x] of length n*)
   582 fun replicate n (x: 'a) : 'a list =
   583   let fun rep (0, xs) = xs
   584         | rep (n, xs) = rep (n - 1, x :: xs)
   585   in
   586     if n < 0 then raise Subscript
   587     else rep (n, [])
   588   end;
   589 
   590 fun translate_string f = String.translate (f o String.str);
   591 
   592 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   593 fun multiply ([], _) = []
   594   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   595 
   596 (*direct product*)
   597 fun product _ [] = []
   598   | product [] _ = []
   599   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   600 
   601 
   602 (* filter *)
   603 
   604 (*copy the list preserving elements that satisfy the predicate*)
   605 val filter = List.filter;
   606 fun filter_out f = filter (not o f);
   607 val mapfilter = List.mapPartial;
   608 
   609 
   610 (* lists of pairs *)
   611 
   612 exception UnequalLengths;
   613 
   614 fun map2 _ ([], []) = []
   615   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   616   | map2 _ _ = raise UnequalLengths;
   617 
   618 fun exists2 _ ([], []) = false
   619   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   620   | exists2 _ _ = raise UnequalLengths;
   621 
   622 fun forall2 _ ([], []) = true
   623   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   624   | forall2 _ _ = raise UnequalLengths;
   625 
   626 fun seq2 _ ([], []) = ()
   627   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   628   | seq2 _ _ = raise UnequalLengths;
   629 
   630 (*combine two lists forming a list of pairs:
   631   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   632 fun [] ~~ [] = []
   633   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   634   | _ ~~ _ = raise UnequalLengths;
   635 
   636 (*inverse of ~~; the old 'split':
   637   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   638 val split_list = ListPair.unzip;
   639 
   640 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   641 
   642 
   643 (* prefixes, suffixes *)
   644 
   645 fun [] prefix _ = true
   646   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   647   | _ prefix _ = false;
   648 
   649 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   650    where xi is the first element that does not satisfy the predicate*)
   651 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   652   let fun take (rxs, []) = (rev rxs, [])
   653         | take (rxs, x :: xs) =
   654             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   655   in  take([], xs)  end;
   656 
   657 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   658    where xi is the last element that does not satisfy the predicate*)
   659 fun take_suffix _ [] = ([], [])
   660   | take_suffix pred (x :: xs) =
   661       (case take_suffix pred xs of
   662         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   663       | (prfx, sffx) => (x :: prfx, sffx));
   664 
   665 fun prefixes1 [] = []
   666   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   667 
   668 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   669 
   670 
   671 
   672 (** integers **)
   673 
   674 fun gcd (x, y) =
   675   let fun gxd x y : IntInf.int =
   676     if y = 0 then x else gxd y (x mod y)
   677   in if x < y then gxd y x else gxd x y end;
   678 
   679 fun lcm (x, y) = (x * y) div gcd (x, y);
   680 
   681 fun inc i = (i := ! i + 1; ! i);
   682 fun dec i = (i := ! i - 1; ! i);
   683 
   684 
   685 (* lists of integers *)
   686 
   687 (*make the list [from, from + 1, ..., to]*)
   688 fun (from upto to) =
   689   if from > to then [] else from :: ((from + 1) upto to);
   690 
   691 (*make the list [from, from - 1, ..., to]*)
   692 fun (from downto to) =
   693   if from < to then [] else from :: ((from - 1) downto to);
   694 
   695 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   696 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   697   | downto0 ([], n) = n = ~1;
   698 
   699 
   700 (* convert integers to strings *)
   701 
   702 (*expand the number in the given base;
   703   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   704 fun radixpand (base, num) : int list =
   705   let
   706     fun radix (n, tail) =
   707       if n < base then n :: tail
   708       else radix (n div base, (n mod base) :: tail)
   709   in radix (num, []) end;
   710 
   711 (*expands a number into a string of characters starting from "zerochar";
   712   example: radixstring (2, "0", 8) gives "1000"*)
   713 fun radixstring (base, zerochar, num) =
   714   let val offset = ord zerochar;
   715       fun chrof n = chr (offset + n)
   716   in implode (map chrof (radixpand (base, num))) end;
   717 
   718 
   719 val string_of_int = Int.toString;
   720 
   721 fun string_of_indexname (a,0) = a
   722   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   723 
   724 
   725 (* read integers *)
   726 
   727 fun read_radixint (radix: int, cs) : int * string list =
   728   let val zero = ord"0"
   729       val limit = zero+radix
   730       fun scan (num,[]) = (num,[])
   731         | scan (num, c::cs) =
   732               if  zero <= ord c  andalso  ord c < limit
   733               then scan(radix*num + ord c - zero, cs)
   734               else (num, c::cs)
   735   in  scan(0,cs)  end;
   736 
   737 fun read_int cs = read_radixint (10, cs);
   738 
   739 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   740 
   741 
   742 
   743 (** strings **)
   744 
   745 (* functions tuned for strings, avoiding explode *)
   746 
   747 fun nth_elem_string (i, str) =
   748   (case try String.substring (str, i, 1) of
   749     SOME s => s
   750   | NONE => raise Subscript);
   751 
   752 fun fold_string f str x0 =
   753   let
   754     val n = size str;
   755     fun iter (x, i) =
   756       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   757   in iter (x0, 0) end;
   758 
   759 fun exists_string pred str =
   760   let
   761     val n = size str;
   762     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   763   in ex 0 end;
   764 
   765 fun forall_string pred = not o exists_string (not o pred);
   766 
   767 (*enclose in brackets*)
   768 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   769 fun unenclose str = String.substring (str, 1, size str - 2);
   770 
   771 (*simple quoting (does not escape special chars)*)
   772 val quote = enclose "\"" "\"";
   773 
   774 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   775 fun space_implode a bs = implode (separate a bs);
   776 
   777 val commas = space_implode ", ";
   778 val commas_quote = commas o map quote;
   779 
   780 (*concatenate messages, one per line, into a string*)
   781 val cat_lines = space_implode "\n";
   782 
   783 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   784 fun space_explode _ "" = []
   785   | space_explode sep str =
   786       let
   787         fun expl chs =
   788           (case take_prefix (not_equal sep) chs of
   789             (cs, []) => [implode cs]
   790           | (cs, _ :: cs') => implode cs :: expl cs');
   791       in expl (explode str) end;
   792 
   793 val split_lines = space_explode "\n";
   794 
   795 fun prefix_lines "" txt = txt
   796   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   797 
   798 fun untabify chs =
   799   let
   800     val tab_width = 8;
   801 
   802     fun untab (_, "\n") = (0, ["\n"])
   803       | untab (pos, "\t") =
   804           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   805       | untab (pos, c) = (pos + 1, [c]);
   806   in
   807     if not (exists (equal "\t") chs) then chs
   808     else flat (#2 (foldl_map untab (0, chs)))
   809   end;
   810 
   811 fun suffix sffx s = s ^ sffx;
   812 
   813 fun unsuffix sffx s =
   814   let val m = size sffx; val n = size s - m in
   815     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   816     else raise Fail "unsuffix"
   817   end;
   818 
   819 fun unprefix prfx s =
   820   let val m = size prfx; val n = size s - m in
   821     if String.isPrefix prfx s then String.substring (s, m, n)
   822     else raise Fail "unprefix"
   823   end;
   824 
   825 fun replicate_string 0 _ = ""
   826   | replicate_string 1 a = a
   827   | replicate_string k a =
   828       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   829       else replicate_string (k div 2) (a ^ a) ^ a;
   830 
   831 
   832 
   833 (** lists as sets -- see also Pure/General/ord_list.ML **)
   834 
   835 (*membership in a list*)
   836 fun x mem [] = false
   837   | x mem (y :: ys) = x = y orelse x mem ys;
   838 
   839 (*membership in a list, optimized version for ints*)
   840 fun (x:int) mem_int [] = false
   841   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   842 
   843 (*membership in a list, optimized version for strings*)
   844 fun (x:string) mem_string [] = false
   845   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   846 
   847 (*generalized membership test*)
   848 fun gen_mem eq (x, []) = false
   849   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   850 
   851 (*member, insert, and remove -- with canonical argument order*)
   852 fun member eq xs x = gen_mem eq (x, xs);
   853 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   854 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   855 
   856 (*insertion into list if not already there*)
   857 fun (x ins xs) = if x mem xs then xs else x :: xs;
   858 
   859 (*insertion into list, optimized version for ints*)
   860 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   861 
   862 (*insertion into list, optimized version for strings*)
   863 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   864 
   865 (*generalized insertion*)
   866 fun gen_ins eq (x, xs) = insert eq x xs;
   867 
   868 (*union of sets represented as lists: no repetitions*)
   869 fun xs union [] = xs
   870   | [] union ys = ys
   871   | (x :: xs) union ys = xs union (x ins ys);
   872 
   873 (*union of sets, optimized version for ints*)
   874 fun (xs:int list) union_int [] = xs
   875   | [] union_int ys = ys
   876   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   877 
   878 (*union of sets, optimized version for strings*)
   879 fun (xs:string list) union_string [] = xs
   880   | [] union_string ys = ys
   881   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   882 
   883 (*generalized union*)
   884 fun gen_union eq (xs, []) = xs
   885   | gen_union eq ([], ys) = ys
   886   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   887 
   888 
   889 (*intersection*)
   890 fun [] inter ys = []
   891   | (x :: xs) inter ys =
   892       if x mem ys then x :: (xs inter ys) else xs inter ys;
   893 
   894 (*intersection, optimized version for ints*)
   895 fun ([]:int list) inter_int ys = []
   896   | (x :: xs) inter_int ys =
   897       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   898 
   899 (*intersection, optimized version for strings *)
   900 fun ([]:string list) inter_string ys = []
   901   | (x :: xs) inter_string ys =
   902       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   903 
   904 (*generalized intersection*)
   905 fun gen_inter eq ([], ys) = []
   906   | gen_inter eq (x::xs, ys) =
   907       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   908                            else      gen_inter eq (xs, ys);
   909 
   910 
   911 (*subset*)
   912 fun [] subset ys = true
   913   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   914 
   915 (*subset, optimized version for ints*)
   916 fun ([]: int list) subset_int ys = true
   917   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   918 
   919 (*subset, optimized version for strings*)
   920 fun ([]: string list) subset_string ys = true
   921   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   922 
   923 (*set equality*)
   924 fun eq_set (xs, ys) =
   925   xs = ys orelse (xs subset ys andalso ys subset xs);
   926 
   927 (*set equality for strings*)
   928 fun eq_set_string ((xs: string list), ys) =
   929   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   930 
   931 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   932 
   933 
   934 (*removing an element from a list WITHOUT duplicates*)
   935 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   936   | [] \ x = [];
   937 
   938 fun ys \\ xs = foldl (op \) (ys,xs);
   939 
   940 (*removing an element from a list -- possibly WITH duplicates*)
   941 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   942 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   943 
   944 (*makes a list of the distinct members of the input; preserves order, takes
   945   first of equal elements*)
   946 fun gen_distinct eq lst =
   947   let
   948     val memb = gen_mem eq;
   949 
   950     fun dist (rev_seen, []) = rev rev_seen
   951       | dist (rev_seen, x :: xs) =
   952           if memb (x, rev_seen) then dist (rev_seen, xs)
   953           else dist (x :: rev_seen, xs);
   954   in
   955     dist ([], lst)
   956   end;
   957 
   958 fun distinct l = gen_distinct (op =) l;
   959 
   960 
   961 (*returns the tail beginning with the first repeated element, or []*)
   962 fun findrep [] = []
   963   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   964 
   965 
   966 (*returns a list containing all repeated elements exactly once; preserves
   967   order, takes first of equal elements*)
   968 fun gen_duplicates eq lst =
   969   let
   970     val memb = gen_mem eq;
   971 
   972     fun dups (rev_dups, []) = rev rev_dups
   973       | dups (rev_dups, x :: xs) =
   974           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   975             dups (rev_dups, xs)
   976           else dups (x :: rev_dups, xs);
   977   in
   978     dups ([], lst)
   979   end;
   980 
   981 fun duplicates l = gen_duplicates (op =) l;
   982 
   983 
   984 
   985 (** association lists **)
   986 
   987 (*association list lookup*)
   988 fun assoc ([], key) = NONE
   989   | assoc ((keyi, xi) :: pairs, key) =
   990       if key = keyi then SOME xi else assoc (pairs, key);
   991 
   992 (*association list lookup, optimized version for ints*)
   993 fun assoc_int ([], (key:int)) = NONE
   994   | assoc_int ((keyi, xi) :: pairs, key) =
   995       if key = keyi then SOME xi else assoc_int (pairs, key);
   996 
   997 (*association list lookup, optimized version for strings*)
   998 fun assoc_string ([], (key:string)) = NONE
   999   | assoc_string ((keyi, xi) :: pairs, key) =
  1000       if key = keyi then SOME xi else assoc_string (pairs, key);
  1001 
  1002 (*association list lookup, optimized version for string*ints*)
  1003 fun assoc_string_int ([], (key:string*int)) = NONE
  1004   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1005       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1006 
  1007 fun assocs ps x =
  1008   (case assoc (ps, x) of
  1009     NONE => []
  1010   | SOME ys => ys);
  1011 
  1012 (*two-fold association list lookup*)
  1013 fun assoc2 (aal, (key1, key2)) =
  1014   (case assoc (aal, key1) of
  1015     SOME al => assoc (al, key2)
  1016   | NONE => NONE);
  1017 
  1018 (*generalized association list lookup*)
  1019 fun gen_assoc eq ([], key) = NONE
  1020   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1021       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1022 
  1023 (*association list update*)
  1024 fun overwrite (al, p as (key, _)) =
  1025   let fun over ((q as (keyi, _)) :: pairs) =
  1026             if keyi = key then p :: pairs else q :: (over pairs)
  1027         | over [] = [p]
  1028   in over al end;
  1029 
  1030 fun gen_overwrite eq (al, p as (key, _)) =
  1031   let fun over ((q as (keyi, _)) :: pairs) =
  1032             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1033         | over [] = [p]
  1034   in over al end;
  1035 
  1036 
  1037 (* lists as tables *)
  1038 
  1039 fun gen_merge_lists _ xs [] = xs
  1040   | gen_merge_lists _ [] ys = ys
  1041   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1042 
  1043 fun gen_merge_lists' _ xs [] = xs
  1044   | gen_merge_lists' _ [] ys = ys
  1045   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1046 
  1047 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1048 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1049 fun merge_alists al = gen_merge_lists eq_fst al;
  1050 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1051 
  1052 
  1053 
  1054 (** balanced trees **)
  1055 
  1056 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1057 
  1058 (*balanced folding; avoids deep nesting*)
  1059 fun fold_bal f [x] = x
  1060   | fold_bal f [] = raise Balance
  1061   | fold_bal f xs =
  1062       let val (ps,qs) = splitAt(length xs div 2, xs)
  1063       in  f (fold_bal f ps, fold_bal f qs)  end;
  1064 
  1065 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1066 fun access_bal (f, g, x) n i =
  1067   let fun acc n i =     (*1<=i<=n*)
  1068           if n=1 then x else
  1069           let val n2 = n div 2
  1070           in  if i<=n2 then f (acc n2 i)
  1071                        else g (acc (n-n2) (i-n2))
  1072           end
  1073   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1074 
  1075 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1076 fun accesses_bal (f, g, x) n =
  1077   let fun acc n =
  1078           if n=1 then [x] else
  1079           let val n2 = n div 2
  1080               val acc2 = acc n2
  1081           in  if n-n2=n2 then map f acc2 @ map g acc2
  1082                          else map f acc2 @ map g (acc (n-n2)) end
  1083   in  if 1<=n then acc n else raise Balance  end;
  1084 
  1085 
  1086 
  1087 (** orders **)
  1088 
  1089 fun rev_order LESS = GREATER
  1090   | rev_order EQUAL = EQUAL
  1091   | rev_order GREATER = LESS;
  1092 
  1093 (*assume rel is a linear strict order*)
  1094 fun make_ord rel (x, y) =
  1095   if rel (x, y) then LESS
  1096   else if rel (y, x) then GREATER
  1097   else EQUAL;
  1098 
  1099 val int_ord = Int.compare;
  1100 val string_ord = String.compare;
  1101 
  1102 fun fast_string_ord (s1, s2) =
  1103   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1104 
  1105 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1106   | option_ord _ (NONE, NONE) = EQUAL
  1107   | option_ord _ (NONE, SOME _) = LESS
  1108   | option_ord _ (SOME _, NONE) = GREATER;
  1109 
  1110 (*lexicographic product*)
  1111 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1112   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1113 
  1114 (*dictionary order -- in general NOT well-founded!*)
  1115 fun dict_ord _ ([], []) = EQUAL
  1116   | dict_ord _ ([], _ :: _) = LESS
  1117   | dict_ord _ (_ :: _, []) = GREATER
  1118   | dict_ord elem_ord (x :: xs, y :: ys) =
  1119       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1120 
  1121 (*lexicographic product of lists*)
  1122 fun list_ord elem_ord (xs, ys) =
  1123   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1124 
  1125 
  1126 (* sorting *)
  1127 
  1128 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1129 fun sort ord =
  1130   let
  1131     fun qsort xs =
  1132       let val len = length xs in
  1133         if len <= 1 then xs
  1134         else
  1135           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1136             qsort lts @ eqs @ qsort gts
  1137           end
  1138       end
  1139     and part _ [] = ([], [], [])
  1140       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1141     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1142       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1143       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1144   in qsort end;
  1145 
  1146 (*sort strings*)
  1147 val sort_strings = sort string_ord;
  1148 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1149 
  1150 fun unique_strings ([]: string list) = []
  1151   | unique_strings [x] = [x]
  1152   | unique_strings (x :: y :: ys) =
  1153       if x = y then unique_strings (y :: ys)
  1154       else x :: unique_strings (y :: ys);
  1155 
  1156 
  1157 (** random numbers **)
  1158 
  1159 exception RANDOM;
  1160 
  1161 fun rmod x y = x - y * Real.realFloor (x / y);
  1162 
  1163 local
  1164   val a = 16807.0;
  1165   val m = 2147483647.0;
  1166   val random_seed = ref 1.0;
  1167 in
  1168 
  1169 fun random () =
  1170   let val r = rmod (a * !random_seed) m
  1171   in (random_seed := r; r) end;
  1172 
  1173 end;
  1174 
  1175 fun random_range l h =
  1176   if h < l orelse l < 0 then raise RANDOM
  1177   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1178 
  1179 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1180 
  1181 fun frequency xs =
  1182   let
  1183     val sum = foldl op + (0, map fst xs);
  1184     fun pick n ((k, x) :: xs) =
  1185       if n <= k then x else pick (n - k) xs
  1186   in pick (random_range 1 sum) xs end;
  1187 
  1188 
  1189 (** current directory **)
  1190 
  1191 val cd = OS.FileSys.chDir;
  1192 val pwd = OS.FileSys.getDir;
  1193 
  1194 
  1195 
  1196 (** rational numbers **)
  1197 
  1198 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1199 
  1200 exception RAT of string;
  1201 
  1202 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1203 
  1204 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1205   let val absp = abs p
  1206       val m = gcd(absp,q)
  1207   in Rat(a = (0 <= p), absp div m, q div m) end;
  1208 
  1209 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1210   let val den = lcm(q,s)
  1211       val p = p*(den div q) and r = r*(den div s)
  1212       val num = (if a then p else ~p) + (if b then r else ~r)
  1213   in ratnorm(true,num,den) end;
  1214 
  1215 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1216 
  1217 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1218 
  1219 fun int_ratdiv(p,q) =
  1220   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1221 
  1222 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1223 
  1224 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1225 
  1226 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1227 
  1228 
  1229 (** misc **)
  1230 
  1231 (*use the keyfun to make a list of (x, key) pairs*)
  1232 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1233   let fun keypair x = (x, keyfun x)
  1234   in map keypair end;
  1235 
  1236 (*given a list of (x, key) pairs and a searchkey
  1237   return the list of xs from each pair whose key equals searchkey*)
  1238 fun keyfilter [] searchkey = []
  1239   | keyfilter ((x, key) :: pairs) searchkey =
  1240       if key = searchkey then x :: keyfilter pairs searchkey
  1241       else keyfilter pairs searchkey;
  1242 
  1243 
  1244 (*Partition list into elements that satisfy predicate and those that don't.
  1245   Preserves order of elements in both lists.*)
  1246 val partition = List.partition;
  1247 
  1248 
  1249 fun partition_eq (eq:'a * 'a -> bool) =
  1250     let fun part [] = []
  1251           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1252                            in (x::xs)::(part xs') end
  1253     in part end;
  1254 
  1255 
  1256 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1257    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1258 fun partition_list p i j =
  1259   let fun part k xs =
  1260             if k>j then
  1261               (case xs of [] => []
  1262                          | _ => raise Fail "partition_list")
  1263             else
  1264             let val (ns, rest) = partition (p k) xs;
  1265             in  ns :: part(k+1)rest  end
  1266   in  part i end;
  1267 
  1268 
  1269 (* generating identifiers *)
  1270 
  1271 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1272 local
  1273 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1274 fun char i =      if i<26 then chr (ord "A" + i)
  1275              else if i<52 then chr (ord "a" + i - 26)
  1276              else if i<62 then chr (ord"0" + i - 52)
  1277              else if i=62 then "_"
  1278              else  (*i=63*)    "'";
  1279 
  1280 val charVec = Vector.tabulate (64, char);
  1281 
  1282 fun newid n =
  1283   let
  1284   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1285 
  1286 val seedr = ref 0;
  1287 
  1288 in
  1289 
  1290 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1291 
  1292 end;
  1293 
  1294 
  1295 (* lexical scanning *)
  1296 
  1297 (*scan a list of characters into "words" composed of "letters" (recognized by
  1298   is_let) and separated by any number of non-"letters"*)
  1299 fun scanwords is_let cs =
  1300   let fun scan1 [] = []
  1301         | scan1 cs =
  1302             let val (lets, rest) = take_prefix is_let cs
  1303             in implode lets :: scanwords is_let rest end;
  1304   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1305 
  1306 
  1307 (* stamps and serial numbers *)
  1308 
  1309 type stamp = unit ref;
  1310 val stamp: unit -> stamp = ref;
  1311 
  1312 type serial = int;
  1313 local val count = ref 0
  1314 in fun serial () = inc count end;
  1315 
  1316 
  1317 (* generic objects *)
  1318 
  1319 (*note that the builtin exception datatype may be extended by new
  1320   constructors at any time*)
  1321 structure Object = struct type T = exn end;
  1322 
  1323 end;
  1324 
  1325 structure BasicLibrary: BASIC_LIBRARY = Library;
  1326 open BasicLibrary;