src/HOL/Relation.thy
author haftmann
Sat Apr 26 14:53:22 2014 +0200 (2014-04-26)
changeset 56742 678a52e676b6
parent 56545 8f1e7596deb7
child 56790 f54097170704
permissions -rw-r--r--
more complete classical rules for Inf and Sup, modelled after theiry counterparts on Inter and Union (and INF and SUP)
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 header {* Relations – as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare Inf1_I [intro!]
    34 declare INF1_I [intro!]
    35 declare Inf2_I [intro!]
    36 declare INF2_I [intro!]
    37 declare Inf1_D [elim]
    38 declare INF1_D [elim]
    39 declare Inf2_D [elim]
    40 declare INF2_D [elim]
    41 declare Inf1_E [elim]
    42 declare INF1_E [elim]
    43 declare Inf2_E [elim]
    44 declare INF2_E [elim]
    45 declare Sup1_I [intro]
    46 declare SUP1_I [intro]
    47 declare Sup2_I [intro]
    48 declare SUP2_I [intro]
    49 declare Sup1_E [elim!]
    50 declare SUP1_E [elim!]
    51 declare Sup2_E [elim!]
    52 declare SUP2_E [elim!]
    53 
    54 subsection {* Fundamental *}
    55 
    56 subsubsection {* Relations as sets of pairs *}
    57 
    58 type_synonym 'a rel = "('a * 'a) set"
    59 
    60 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    61   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    62   by auto
    63 
    64 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    65   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    66     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    67   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    68 
    69 
    70 subsubsection {* Conversions between set and predicate relations *}
    71 
    72 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    73   by (simp add: set_eq_iff fun_eq_iff)
    74 
    75 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    79   by (simp add: subset_iff le_fun_def)
    80 
    81 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    85   by (auto simp add: fun_eq_iff)
    86 
    87 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    97   by (simp add: inf_fun_def)
    98 
    99 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   103   by (simp add: sup_fun_def)
   104 
   105 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   109   by (simp add: fun_eq_iff)
   110 
   111 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   142   by (simp add: fun_eq_iff)
   143 
   144 subsection {* Properties of relations *}
   145 
   146 subsubsection {* Reflexivity *}
   147 
   148 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   149 where
   150   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   151 
   152 abbreviation refl :: "'a rel \<Rightarrow> bool"
   153 where -- {* reflexivity over a type *}
   154   "refl \<equiv> refl_on UNIV"
   155 
   156 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   157 where
   158   "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   159 
   160 lemma reflp_refl_eq [pred_set_conv]:
   161   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   165   by (unfold refl_on_def) (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   168   by (unfold refl_on_def) blast
   169 
   170 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   171   by (unfold refl_on_def) blast
   172 
   173 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   174   by (unfold refl_on_def) blast
   175 
   176 lemma reflpI:
   177   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   178   by (auto intro: refl_onI simp add: reflp_def)
   179 
   180 lemma reflpE:
   181   assumes "reflp r"
   182   obtains "r x x"
   183   using assms by (auto dest: refl_onD simp add: reflp_def)
   184 
   185 lemma reflpD:
   186   assumes "reflp r"
   187   shows "r x x"
   188   using assms by (auto elim: reflpE)
   189 
   190 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   191   by (unfold refl_on_def) blast
   192 
   193 lemma reflp_inf:
   194   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   195   by (auto intro: reflpI elim: reflpE)
   196 
   197 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   198   by (unfold refl_on_def) blast
   199 
   200 lemma reflp_sup:
   201   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   202   by (auto intro: reflpI elim: reflpE)
   203 
   204 lemma refl_on_INTER:
   205   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   206   by (unfold refl_on_def) fast
   207 
   208 lemma refl_on_UNION:
   209   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   210   by (unfold refl_on_def) blast
   211 
   212 lemma refl_on_empty [simp]: "refl_on {} {}"
   213   by (simp add:refl_on_def)
   214 
   215 lemma refl_on_def' [nitpick_unfold, code]:
   216   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   217   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   218 
   219 
   220 subsubsection {* Irreflexivity *}
   221 
   222 definition irrefl :: "'a rel \<Rightarrow> bool"
   223 where
   224   "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   225 
   226 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   227 where
   228   "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   229 
   230 lemma irreflp_irrefl_eq [pred_set_conv]:
   231   "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R" 
   232   by (simp add: irrefl_def irreflp_def)
   233 
   234 lemma irreflI:
   235   "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   236   by (simp add: irrefl_def)
   237 
   238 lemma irreflpI:
   239   "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   240   by (fact irreflI [to_pred])
   241 
   242 lemma irrefl_distinct [code]:
   243   "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   244   by (auto simp add: irrefl_def)
   245 
   246 
   247 subsubsection {* Asymmetry *}
   248 
   249 inductive asym :: "'a rel \<Rightarrow> bool"
   250 where
   251   asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   252 
   253 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   254 where
   255   asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   256 
   257 lemma asymp_asym_eq [pred_set_conv]:
   258   "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R" 
   259   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   260 
   261 
   262 subsubsection {* Symmetry *}
   263 
   264 definition sym :: "'a rel \<Rightarrow> bool"
   265 where
   266   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   267 
   268 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   269 where
   270   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   271 
   272 lemma symp_sym_eq [pred_set_conv]:
   273   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   274   by (simp add: sym_def symp_def)
   275 
   276 lemma symI:
   277   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   278   by (unfold sym_def) iprover
   279 
   280 lemma sympI:
   281   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   282   by (fact symI [to_pred])
   283 
   284 lemma symE:
   285   assumes "sym r" and "(b, a) \<in> r"
   286   obtains "(a, b) \<in> r"
   287   using assms by (simp add: sym_def)
   288 
   289 lemma sympE:
   290   assumes "symp r" and "r b a"
   291   obtains "r a b"
   292   using assms by (rule symE [to_pred])
   293 
   294 lemma symD:
   295   assumes "sym r" and "(b, a) \<in> r"
   296   shows "(a, b) \<in> r"
   297   using assms by (rule symE)
   298 
   299 lemma sympD:
   300   assumes "symp r" and "r b a"
   301   shows "r a b"
   302   using assms by (rule symD [to_pred])
   303 
   304 lemma sym_Int:
   305   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   306   by (fast intro: symI elim: symE)
   307 
   308 lemma symp_inf:
   309   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   310   by (fact sym_Int [to_pred])
   311 
   312 lemma sym_Un:
   313   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   314   by (fast intro: symI elim: symE)
   315 
   316 lemma symp_sup:
   317   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   318   by (fact sym_Un [to_pred])
   319 
   320 lemma sym_INTER:
   321   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   322   by (fast intro: symI elim: symE)
   323 
   324 lemma symp_INF:
   325   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   326   by (fact sym_INTER [to_pred])
   327 
   328 lemma sym_UNION:
   329   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   330   by (fast intro: symI elim: symE)
   331 
   332 lemma symp_SUP:
   333   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   334   by (fact sym_UNION [to_pred])
   335 
   336 
   337 subsubsection {* Antisymmetry *}
   338 
   339 definition antisym :: "'a rel \<Rightarrow> bool"
   340 where
   341   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   342 
   343 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   344 where
   345   "antisymP r \<equiv> antisym {(x, y). r x y}"
   346 
   347 lemma antisymI:
   348   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   349   by (unfold antisym_def) iprover
   350 
   351 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   352   by (unfold antisym_def) iprover
   353 
   354 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   355   by (unfold antisym_def) blast
   356 
   357 lemma antisym_empty [simp]: "antisym {}"
   358   by (unfold antisym_def) blast
   359 
   360 
   361 subsubsection {* Transitivity *}
   362 
   363 definition trans :: "'a rel \<Rightarrow> bool"
   364 where
   365   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   366 
   367 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   368 where
   369   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   370 
   371 lemma transp_trans_eq [pred_set_conv]:
   372   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   373   by (simp add: trans_def transp_def)
   374 
   375 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   376 where -- {* FIXME drop *}
   377   "transP r \<equiv> trans {(x, y). r x y}"
   378 
   379 lemma transI:
   380   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   381   by (unfold trans_def) iprover
   382 
   383 lemma transpI:
   384   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   385   by (fact transI [to_pred])
   386 
   387 lemma transE:
   388   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   389   obtains "(x, z) \<in> r"
   390   using assms by (unfold trans_def) iprover
   391 
   392 lemma transpE:
   393   assumes "transp r" and "r x y" and "r y z"
   394   obtains "r x z"
   395   using assms by (rule transE [to_pred])
   396 
   397 lemma transD:
   398   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   399   shows "(x, z) \<in> r"
   400   using assms by (rule transE)
   401 
   402 lemma transpD:
   403   assumes "transp r" and "r x y" and "r y z"
   404   shows "r x z"
   405   using assms by (rule transD [to_pred])
   406 
   407 lemma trans_Int:
   408   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   409   by (fast intro: transI elim: transE)
   410 
   411 lemma transp_inf:
   412   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   413   by (fact trans_Int [to_pred])
   414 
   415 lemma trans_INTER:
   416   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   417   by (fast intro: transI elim: transD)
   418 
   419 (* FIXME thm trans_INTER [to_pred] *)
   420 
   421 lemma trans_join [code]:
   422   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   423   by (auto simp add: trans_def)
   424 
   425 lemma transp_trans:
   426   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   427   by (simp add: trans_def transp_def)
   428 
   429 
   430 subsubsection {* Totality *}
   431 
   432 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   433 where
   434   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   435 
   436 abbreviation "total \<equiv> total_on UNIV"
   437 
   438 lemma total_on_empty [simp]: "total_on {} r"
   439   by (simp add: total_on_def)
   440 
   441 
   442 subsubsection {* Single valued relations *}
   443 
   444 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   445 where
   446   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   447 
   448 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   449   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   450 
   451 lemma single_valuedI:
   452   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   453   by (unfold single_valued_def)
   454 
   455 lemma single_valuedD:
   456   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   457   by (simp add: single_valued_def)
   458 
   459 lemma simgle_valued_empty[simp]: "single_valued {}"
   460 by(simp add: single_valued_def)
   461 
   462 lemma single_valued_subset:
   463   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   464   by (unfold single_valued_def) blast
   465 
   466 
   467 subsection {* Relation operations *}
   468 
   469 subsubsection {* The identity relation *}
   470 
   471 definition Id :: "'a rel"
   472 where
   473   [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   474 
   475 lemma IdI [intro]: "(a, a) : Id"
   476   by (simp add: Id_def)
   477 
   478 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   479   by (unfold Id_def) (iprover elim: CollectE)
   480 
   481 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   482   by (unfold Id_def) blast
   483 
   484 lemma refl_Id: "refl Id"
   485   by (simp add: refl_on_def)
   486 
   487 lemma antisym_Id: "antisym Id"
   488   -- {* A strange result, since @{text Id} is also symmetric. *}
   489   by (simp add: antisym_def)
   490 
   491 lemma sym_Id: "sym Id"
   492   by (simp add: sym_def)
   493 
   494 lemma trans_Id: "trans Id"
   495   by (simp add: trans_def)
   496 
   497 lemma single_valued_Id [simp]: "single_valued Id"
   498   by (unfold single_valued_def) blast
   499 
   500 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   501   by (simp add:irrefl_def)
   502 
   503 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   504   unfolding antisym_def trans_def by blast
   505 
   506 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   507   by (simp add: total_on_def)
   508 
   509 
   510 subsubsection {* Diagonal: identity over a set *}
   511 
   512 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   513 where
   514   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   515 
   516 lemma Id_on_empty [simp]: "Id_on {} = {}"
   517   by (simp add: Id_on_def) 
   518 
   519 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   520   by (simp add: Id_on_def)
   521 
   522 lemma Id_onI [intro!]: "a : A ==> (a, a) : Id_on A"
   523   by (rule Id_on_eqI) (rule refl)
   524 
   525 lemma Id_onE [elim!]:
   526   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   527   -- {* The general elimination rule. *}
   528   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   529 
   530 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   531   by blast
   532 
   533 lemma Id_on_def' [nitpick_unfold]:
   534   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   535   by auto
   536 
   537 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   538   by blast
   539 
   540 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   541   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   542 
   543 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   544   by (unfold antisym_def) blast
   545 
   546 lemma sym_Id_on [simp]: "sym (Id_on A)"
   547   by (rule symI) clarify
   548 
   549 lemma trans_Id_on [simp]: "trans (Id_on A)"
   550   by (fast intro: transI elim: transD)
   551 
   552 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   553   by (unfold single_valued_def) blast
   554 
   555 
   556 subsubsection {* Composition *}
   557 
   558 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   559   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   560 where
   561   relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   562 
   563 notation relcompp (infixr "OO" 75)
   564 
   565 lemmas relcomppI = relcompp.intros
   566 
   567 text {*
   568   For historic reasons, the elimination rules are not wholly corresponding.
   569   Feel free to consolidate this.
   570 *}
   571 
   572 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   573 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   574 
   575 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   576   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   577   by (cases xz) (simp, erule relcompEpair, iprover)
   578 
   579 lemma R_O_Id [simp]:
   580   "R O Id = R"
   581   by fast
   582 
   583 lemma Id_O_R [simp]:
   584   "Id O R = R"
   585   by fast
   586 
   587 lemma relcomp_empty1 [simp]:
   588   "{} O R = {}"
   589   by blast
   590 
   591 lemma relcompp_bot1 [simp]:
   592   "\<bottom> OO R = \<bottom>"
   593   by (fact relcomp_empty1 [to_pred])
   594 
   595 lemma relcomp_empty2 [simp]:
   596   "R O {} = {}"
   597   by blast
   598 
   599 lemma relcompp_bot2 [simp]:
   600   "R OO \<bottom> = \<bottom>"
   601   by (fact relcomp_empty2 [to_pred])
   602 
   603 lemma O_assoc:
   604   "(R O S) O T = R O (S O T)"
   605   by blast
   606 
   607 
   608 lemma relcompp_assoc:
   609   "(r OO s) OO t = r OO (s OO t)"
   610   by (fact O_assoc [to_pred])
   611 
   612 lemma trans_O_subset:
   613   "trans r \<Longrightarrow> r O r \<subseteq> r"
   614   by (unfold trans_def) blast
   615 
   616 lemma transp_relcompp_less_eq:
   617   "transp r \<Longrightarrow> r OO r \<le> r "
   618   by (fact trans_O_subset [to_pred])
   619 
   620 lemma relcomp_mono:
   621   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   622   by blast
   623 
   624 lemma relcompp_mono:
   625   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   626   by (fact relcomp_mono [to_pred])
   627 
   628 lemma relcomp_subset_Sigma:
   629   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   630   by blast
   631 
   632 lemma relcomp_distrib [simp]:
   633   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   634   by auto
   635 
   636 lemma relcompp_distrib [simp]:
   637   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   638   by (fact relcomp_distrib [to_pred])
   639 
   640 lemma relcomp_distrib2 [simp]:
   641   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   642   by auto
   643 
   644 lemma relcompp_distrib2 [simp]:
   645   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   646   by (fact relcomp_distrib2 [to_pred])
   647 
   648 lemma relcomp_UNION_distrib:
   649   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   650   by auto
   651 
   652 (* FIXME thm relcomp_UNION_distrib [to_pred] *)
   653 
   654 lemma relcomp_UNION_distrib2:
   655   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   656   by auto
   657 
   658 (* FIXME thm relcomp_UNION_distrib2 [to_pred] *)
   659 
   660 lemma single_valued_relcomp:
   661   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   662   by (unfold single_valued_def) blast
   663 
   664 lemma relcomp_unfold:
   665   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   666   by (auto simp add: set_eq_iff)
   667 
   668 lemma eq_OO: "op= OO R = R"
   669 by blast
   670 
   671 
   672 subsubsection {* Converse *}
   673 
   674 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   675   for r :: "('a \<times> 'b) set"
   676 where
   677   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   678 
   679 notation (xsymbols)
   680   converse  ("(_\<inverse>)" [1000] 999)
   681 
   682 notation
   683   conversep ("(_^--1)" [1000] 1000)
   684 
   685 notation (xsymbols)
   686   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   687 
   688 lemma converseI [sym]:
   689   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   690   by (fact converse.intros)
   691 
   692 lemma conversepI (* CANDIDATE [sym] *):
   693   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   694   by (fact conversep.intros)
   695 
   696 lemma converseD [sym]:
   697   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   698   by (erule converse.cases) iprover
   699 
   700 lemma conversepD (* CANDIDATE [sym] *):
   701   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   702   by (fact converseD [to_pred])
   703 
   704 lemma converseE [elim!]:
   705   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   706   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   707   by (cases yx) (simp, erule converse.cases, iprover)
   708 
   709 lemmas conversepE [elim!] = conversep.cases
   710 
   711 lemma converse_iff [iff]:
   712   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   713   by (auto intro: converseI)
   714 
   715 lemma conversep_iff [iff]:
   716   "r\<inverse>\<inverse> a b = r b a"
   717   by (fact converse_iff [to_pred])
   718 
   719 lemma converse_converse [simp]:
   720   "(r\<inverse>)\<inverse> = r"
   721   by (simp add: set_eq_iff)
   722 
   723 lemma conversep_conversep [simp]:
   724   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   725   by (fact converse_converse [to_pred])
   726 
   727 lemma converse_empty[simp]: "{}\<inverse> = {}"
   728 by auto
   729 
   730 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   731 by auto
   732 
   733 lemma converse_relcomp: "(r O s)^-1 = s^-1 O r^-1"
   734   by blast
   735 
   736 lemma converse_relcompp: "(r OO s)^--1 = s^--1 OO r^--1"
   737   by (iprover intro: order_antisym conversepI relcomppI
   738     elim: relcomppE dest: conversepD)
   739 
   740 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   741   by blast
   742 
   743 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   744   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   745 
   746 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   747   by blast
   748 
   749 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   750   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   751 
   752 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   753   by fast
   754 
   755 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   756   by blast
   757 
   758 lemma converse_mono[simp]: "r^-1 \<subseteq> s ^-1 \<longleftrightarrow> r \<subseteq> s"
   759   by auto
   760 
   761 lemma conversep_mono[simp]: "r^--1 \<le> s ^--1 \<longleftrightarrow> r \<le> s"
   762   by (fact converse_mono[to_pred])
   763 
   764 lemma converse_inject[simp]: "r^-1 = s ^-1 \<longleftrightarrow> r = s"
   765   by auto
   766 
   767 lemma conversep_inject[simp]: "r^--1 = s ^--1 \<longleftrightarrow> r = s"
   768   by (fact converse_inject[to_pred])
   769 
   770 lemma converse_subset_swap: "r \<subseteq> s ^-1 = (r ^-1 \<subseteq> s)"
   771   by auto
   772 
   773 lemma conversep_le_swap: "r \<le> s ^--1 = (r ^--1 \<le> s)"
   774   by (fact converse_subset_swap[to_pred])
   775 
   776 lemma converse_Id [simp]: "Id^-1 = Id"
   777   by blast
   778 
   779 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   780   by blast
   781 
   782 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   783   by (unfold refl_on_def) auto
   784 
   785 lemma sym_converse [simp]: "sym (converse r) = sym r"
   786   by (unfold sym_def) blast
   787 
   788 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   789   by (unfold antisym_def) blast
   790 
   791 lemma trans_converse [simp]: "trans (converse r) = trans r"
   792   by (unfold trans_def) blast
   793 
   794 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   795   by (unfold sym_def) fast
   796 
   797 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   798   by (unfold sym_def) blast
   799 
   800 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   801   by (unfold sym_def) blast
   802 
   803 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   804   by (auto simp: total_on_def)
   805 
   806 lemma finite_converse [iff]: "finite (r^-1) = finite r"  
   807   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   808   by (auto elim: finite_imageD simp: inj_on_def)
   809 
   810 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   811   by (auto simp add: fun_eq_iff)
   812 
   813 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   814   by (auto simp add: fun_eq_iff)
   815 
   816 lemma converse_unfold [code]:
   817   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   818   by (simp add: set_eq_iff)
   819 
   820 
   821 subsubsection {* Domain, range and field *}
   822 
   823 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   824   for r :: "('a \<times> 'b) set"
   825 where
   826   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   827 
   828 abbreviation (input) "DomainP \<equiv> Domainp"
   829 
   830 lemmas DomainPI = Domainp.DomainI
   831 
   832 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   833 inductive_cases DomainpE [elim!]: "Domainp r a"
   834 
   835 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   836   for r :: "('a \<times> 'b) set"
   837 where
   838   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   839 
   840 abbreviation (input) "RangeP \<equiv> Rangep"
   841 
   842 lemmas RangePI = Rangep.RangeI
   843 
   844 inductive_cases RangeE [elim!]: "b \<in> Range r"
   845 inductive_cases RangepE [elim!]: "Rangep r b"
   846 
   847 definition Field :: "'a rel \<Rightarrow> 'a set"
   848 where
   849   "Field r = Domain r \<union> Range r"
   850 
   851 lemma Domain_fst [code]:
   852   "Domain r = fst ` r"
   853   by force
   854 
   855 lemma Range_snd [code]:
   856   "Range r = snd ` r"
   857   by force
   858 
   859 lemma fst_eq_Domain: "fst ` R = Domain R"
   860   by force
   861 
   862 lemma snd_eq_Range: "snd ` R = Range R"
   863   by force
   864 
   865 lemma Domain_empty [simp]: "Domain {} = {}"
   866   by auto
   867 
   868 lemma Range_empty [simp]: "Range {} = {}"
   869   by auto
   870 
   871 lemma Field_empty [simp]: "Field {} = {}"
   872   by (simp add: Field_def)
   873 
   874 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   875   by auto
   876 
   877 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   878   by auto
   879 
   880 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   881   by blast
   882 
   883 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   884   by blast
   885 
   886 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   887   by (auto simp add: Field_def)
   888 
   889 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   890   by blast
   891 
   892 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   893   by blast
   894 
   895 lemma Domain_Id [simp]: "Domain Id = UNIV"
   896   by blast
   897 
   898 lemma Range_Id [simp]: "Range Id = UNIV"
   899   by blast
   900 
   901 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   902   by blast
   903 
   904 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   905   by blast
   906 
   907 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   908   by blast
   909 
   910 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   911   by blast
   912 
   913 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   914   by (auto simp: Field_def)
   915 
   916 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   917   by blast
   918 
   919 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   920   by blast
   921 
   922 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   923   by blast
   924 
   925 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   926   by blast
   927 
   928 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   929   by blast
   930 
   931 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   932   by blast
   933 
   934 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   935   by (auto simp: Field_def)
   936 
   937 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   938   by auto
   939 
   940 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   941   by blast
   942 
   943 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   944   by (auto simp: Field_def)
   945 
   946 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   947   by auto
   948 
   949 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   950   by auto
   951 
   952 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   953   by (induct set: finite) auto
   954 
   955 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   956   by (induct set: finite) auto
   957 
   958 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   959   by (simp add: Field_def finite_Domain finite_Range)
   960 
   961 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   962   by blast
   963 
   964 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   965   by blast
   966 
   967 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   968   by (auto simp: Field_def Domain_def Range_def)
   969 
   970 lemma Domain_unfold:
   971   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   972   by blast
   973 
   974 
   975 subsubsection {* Image of a set under a relation *}
   976 
   977 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixr "``" 90)
   978 where
   979   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   980 
   981 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   982   by (simp add: Image_def)
   983 
   984 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   985   by (simp add: Image_def)
   986 
   987 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   988   by (rule Image_iff [THEN trans]) simp
   989 
   990 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
   991   by (unfold Image_def) blast
   992 
   993 lemma ImageE [elim!]:
   994   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   995   by (unfold Image_def) (iprover elim!: CollectE bexE)
   996 
   997 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   998   -- {* This version's more effective when we already have the required @{text a} *}
   999   by blast
  1000 
  1001 lemma Image_empty [simp]: "R``{} = {}"
  1002   by blast
  1003 
  1004 lemma Image_Id [simp]: "Id `` A = A"
  1005   by blast
  1006 
  1007 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1008   by blast
  1009 
  1010 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1011   by blast
  1012 
  1013 lemma Image_Int_eq:
  1014   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1015   by (simp add: single_valued_def, blast) 
  1016 
  1017 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1018   by blast
  1019 
  1020 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1021   by blast
  1022 
  1023 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
  1024   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1025 
  1026 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1027   -- {* NOT suitable for rewriting *}
  1028   by blast
  1029 
  1030 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
  1031   by blast
  1032 
  1033 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1034   by blast
  1035 
  1036 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1037   by auto
  1038 
  1039 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1040   by blast
  1041 
  1042 text{*Converse inclusion requires some assumptions*}
  1043 lemma Image_INT_eq:
  1044      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1045 apply (rule equalityI)
  1046  apply (rule Image_INT_subset) 
  1047 apply  (simp add: single_valued_def, blast)
  1048 done
  1049 
  1050 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
  1051   by blast
  1052 
  1053 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1054   by auto
  1055 
  1056 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1057   by auto
  1058 
  1059 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1060   by auto
  1061 
  1062 subsubsection {* Inverse image *}
  1063 
  1064 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1065 where
  1066   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1067 
  1068 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1069 where
  1070   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1071 
  1072 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1073   by (simp add: inv_image_def inv_imagep_def)
  1074 
  1075 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1076   by (unfold sym_def inv_image_def) blast
  1077 
  1078 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1079   apply (unfold trans_def inv_image_def)
  1080   apply (simp (no_asm))
  1081   apply blast
  1082   done
  1083 
  1084 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1085   by (auto simp:inv_image_def)
  1086 
  1087 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1088   unfolding inv_image_def converse_unfold by auto
  1089 
  1090 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1091   by (simp add: inv_imagep_def)
  1092 
  1093 
  1094 subsubsection {* Powerset *}
  1095 
  1096 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1097 where
  1098   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1099 
  1100 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1101   by (auto simp add: Powp_def fun_eq_iff)
  1102 
  1103 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1104 
  1105 subsubsection {* Expressing relation operations via @{const Finite_Set.fold} *}
  1106 
  1107 lemma Id_on_fold:
  1108   assumes "finite A"
  1109   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1110 proof -
  1111   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)" by default auto
  1112   show ?thesis using assms unfolding Id_on_def by (induct A) simp_all
  1113 qed
  1114 
  1115 lemma comp_fun_commute_Image_fold:
  1116   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1117 proof -
  1118   interpret comp_fun_idem Set.insert
  1119       by (fact comp_fun_idem_insert)
  1120   show ?thesis 
  1121   by default (auto simp add: fun_eq_iff comp_fun_commute split:prod.split)
  1122 qed
  1123 
  1124 lemma Image_fold:
  1125   assumes "finite R"
  1126   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1127 proof -
  1128   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)" 
  1129     by (rule comp_fun_commute_Image_fold)
  1130   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1131     by (force intro: rev_ImageI)
  1132   show ?thesis using assms by (induct R) (auto simp: *)
  1133 qed
  1134 
  1135 lemma insert_relcomp_union_fold:
  1136   assumes "finite S"
  1137   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1138 proof -
  1139   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1140   proof - 
  1141     interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
  1142     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1143     by default (auto simp add: fun_eq_iff split:prod.split)
  1144   qed
  1145   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x,z) \<in> S}" by (auto simp: relcomp_unfold intro!: exI)
  1146   show ?thesis unfolding *
  1147   using `finite S` by (induct S) (auto split: prod.split)
  1148 qed
  1149 
  1150 lemma insert_relcomp_fold:
  1151   assumes "finite S"
  1152   shows "Set.insert x R O S = 
  1153     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1154 proof -
  1155   have "Set.insert x R O S = ({x} O S) \<union> (R O S)" by auto
  1156   then show ?thesis by (auto simp: insert_relcomp_union_fold[OF assms])
  1157 qed
  1158 
  1159 lemma comp_fun_commute_relcomp_fold:
  1160   assumes "finite S"
  1161   shows "comp_fun_commute (\<lambda>(x,y) A. 
  1162     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1163 proof -
  1164   have *: "\<And>a b A. 
  1165     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1166     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1167   show ?thesis by default (auto simp: *)
  1168 qed
  1169 
  1170 lemma relcomp_fold:
  1171   assumes "finite R"
  1172   assumes "finite S"
  1173   shows "R O S = Finite_Set.fold 
  1174     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1175   using assms by (induct R)
  1176     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1177       cong: if_cong)
  1178 
  1179 end