src/Pure/axclass.ML
author wenzelm
Sat Jan 21 23:02:14 2006 +0100 (2006-01-21)
changeset 18728 6790126ab5f6
parent 18708 4b3dadb4fe33
child 18754 4e41252eae57
permissions -rw-r--r--
simplified type attribute;
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Axiomatic type class package.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val quiet_mode: bool ref
    11   val print_axclasses: theory -> unit
    12   val get_info: theory -> string -> {super_classes: class list, intro: thm, axioms: thm list}
    13   val add_axclass: bstring * xstring list -> ((bstring * string) * Attrib.src list) list ->
    14     theory -> {intro: thm, axioms: thm list} * theory
    15   val add_axclass_i: bstring * class list -> ((bstring * term) * attribute list) list ->
    16     theory -> {intro: thm, axioms: thm list} * theory
    17   val add_classrel_thms: thm list -> theory -> theory
    18   val add_arity_thms: thm list -> theory -> theory
    19   val add_inst_subclass: xstring * xstring -> tactic -> theory -> theory
    20   val add_inst_subclass_i: class * class -> tactic -> theory -> theory
    21   val add_inst_arity: xstring * string list * string -> tactic -> theory -> theory
    22   val add_inst_arity_i: string * sort list * sort -> tactic -> theory -> theory
    23   val instance_subclass: xstring * xstring -> theory -> Proof.state
    24   val instance_subclass_i: class * class -> theory -> Proof.state
    25   val instance_arity: xstring * string list * string -> theory -> Proof.state
    26   val instance_arity_i: string * sort list * sort -> theory -> Proof.state
    27   val read_arity: theory -> xstring * string list * string -> arity
    28   val cert_arity: theory -> string * sort list * sort -> arity
    29   val intro_classes_tac: thm list -> tactic
    30   val default_intro_classes_tac: thm list -> tactic
    31 end;
    32 
    33 structure AxClass: AX_CLASS =
    34 struct
    35 
    36 
    37 (** utilities **)
    38 
    39 (* messages *)
    40 
    41 val quiet_mode = ref false;
    42 fun message s = if ! quiet_mode then () else writeln s;
    43 
    44 
    45 (* type vars *)
    46 
    47 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    48   | map_typ_frees f (TFree a) = f a
    49   | map_typ_frees _ a = a;
    50 
    51 val map_term_tfrees = map_term_types o map_typ_frees;
    52 
    53 fun aT S = TFree ("'a", S);
    54 
    55 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    56   | dest_varT (TVar xi_S) = xi_S
    57   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    58 
    59 
    60 
    61 (** abstract syntax operations **)
    62 
    63 (* names *)
    64 
    65 val introN = "intro";
    66 val axiomsN = "axioms";
    67 
    68 
    69 (* subclass relations as terms *)
    70 
    71 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    72 
    73 fun dest_classrel tm =
    74   let
    75     fun err () = raise TERM ("dest_classrel", [tm]);
    76 
    77     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    78     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    79       handle TYPE _ => err ();
    80   in (c1, c2) end;
    81 
    82 
    83 (* arities as terms *)
    84 
    85 fun mk_arity (t, Ss, c) =
    86   let
    87     val tfrees = ListPair.map TFree (Term.invent_names [] "'a" (length Ss), Ss);
    88   in Logic.mk_inclass (Type (t, tfrees), c) end;
    89 
    90 fun mk_arities (t, Ss, S) = map (fn c => mk_arity (t, Ss, c)) S;
    91 
    92 fun dest_arity tm =
    93   let
    94     fun err () = raise TERM ("dest_arity", [tm]);
    95 
    96     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
    97     val (t, tvars) =
    98       (case ty of
    99         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   100       | _ => err ());
   101     val ss =
   102       if null (gen_duplicates (eq_fst (op =)) tvars)
   103       then map snd tvars else err ();
   104   in (t, ss, c) end;
   105 
   106 
   107 
   108 (** axclass info **)
   109 
   110 type axclass_info =
   111   {super_classes: class list,
   112     intro: thm,
   113     axioms: thm list};
   114 
   115 structure AxclassesData = TheoryDataFun
   116 (struct
   117   val name = "Pure/axclasses";
   118   type T = axclass_info Symtab.table;
   119 
   120   val empty = Symtab.empty;
   121   val copy = I;
   122   val extend = I;
   123   fun merge _ = Symtab.merge (K true);
   124 
   125   fun print thy tab =
   126     let
   127       fun pretty_class c cs = Pretty.block
   128         (Pretty.str (Sign.extern_class thy c) :: Pretty.str " <" :: Pretty.brk 1 ::
   129           Pretty.breaks (map (Pretty.str o Sign.extern_class thy) cs));
   130 
   131       fun pretty_thms name thms = Pretty.big_list (name ^ ":")
   132         (map (Display.pretty_thm_sg thy) thms);
   133 
   134       fun pretty_axclass (name, {super_classes, intro, axioms}) = Pretty.block (Pretty.fbreaks
   135         [pretty_class name super_classes, pretty_thms introN [intro], pretty_thms axiomsN axioms]);
   136     in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest tab))) end;
   137 end);
   138 
   139 val _ = Context.add_setup AxclassesData.init;
   140 val print_axclasses = AxclassesData.print;
   141 
   142 
   143 val lookup_info = Symtab.lookup o AxclassesData.get;
   144 
   145 fun get_info thy c =
   146   (case lookup_info thy c of
   147     NONE => error ("Unknown axclass " ^ quote c)
   148   | SOME info => info);
   149 
   150 
   151 fun class_axms thy =
   152   let val classes = Sign.classes thy in
   153     map (Thm.class_triv thy) classes @
   154     List.mapPartial (Option.map #intro o lookup_info thy) classes
   155   end;
   156 
   157 
   158 
   159 (** add axiomatic type classes **)
   160 
   161 local
   162 
   163 fun err_bad_axsort ax c =
   164   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   165 
   166 fun err_bad_tfrees ax =
   167   error ("More than one type variable in axiom " ^ quote ax);
   168 
   169 fun ext_axclass prep_class prep_axm prep_att (bclass, raw_super_classes) raw_axioms_atts thy =
   170   let
   171     val class = Sign.full_name thy bclass;
   172     val super_classes = map (prep_class thy) raw_super_classes;
   173     val axms = map (prep_axm thy o fst) raw_axioms_atts;
   174     val atts = map (map (prep_att thy) o snd) raw_axioms_atts;
   175 
   176     (*declare class*)
   177     val class_thy =
   178       thy |> Theory.add_classes_i [(bclass, super_classes)];
   179 
   180     (*prepare abstract axioms*)
   181     fun abs_axm ax =
   182       if null (term_tfrees ax) then
   183         Logic.mk_implies (Logic.mk_inclass (aT [], class), ax)
   184       else map_term_tfrees (K (aT [class])) ax;
   185     val abs_axms = map (abs_axm o snd) axms;
   186 
   187     fun axm_sort (name, ax) =
   188       (case term_tfrees ax of
   189         [] => []
   190       | [(_, S)] => if Sign.subsort class_thy ([class], S) then S else err_bad_axsort name class
   191       | _ => err_bad_tfrees name);
   192     val axS = Sign.certify_sort class_thy (List.concat (map axm_sort axms));
   193 
   194     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   195     fun inclass c = Logic.mk_inclass (aT axS, c);
   196 
   197     val intro_axm = Logic.list_implies
   198       (map inclass super_classes @ map (int_axm o #2) axms, inclass class);
   199 
   200     (*declare axioms and rule*)
   201     val (([intro], [axioms]), axms_thy) =
   202       class_thy
   203       |> Theory.add_path (Sign.const_of_class bclass)
   204       |> PureThy.add_axioms_i [Thm.no_attributes (introN, intro_axm)]
   205       ||>> PureThy.add_axiomss_i [Thm.no_attributes (axiomsN, abs_axms)];
   206     val info = {super_classes = super_classes, intro = intro, axioms = axioms};
   207 
   208     (*store info*)
   209     val (_, final_thy) =
   210       axms_thy
   211       |> Theory.add_finals_i false [Const (Sign.const_of_class class, a_itselfT --> propT)]
   212       |> PureThy.add_thms ((map #1 axms ~~ axioms) ~~ atts)
   213       ||> Theory.restore_naming class_thy
   214       ||> AxclassesData.map (Symtab.update (class, info));
   215   in ({intro = intro, axioms = axioms}, final_thy) end;
   216 
   217 in
   218 
   219 val add_axclass = ext_axclass Sign.intern_class Theory.read_axm Attrib.attribute;
   220 val add_axclass_i = ext_axclass (K I) Theory.cert_axm (K I);
   221 
   222 end;
   223 
   224 
   225 
   226 (** proven class instantiation **)
   227 
   228 (* add thms to type signature *)
   229 
   230 fun add_classrel_thms thms thy =
   231   let
   232     fun prep_thm thm =
   233       let
   234         val prop = Drule.plain_prop_of (Thm.transfer thy thm);
   235         val (c1, c2) = dest_classrel prop handle TERM _ =>
   236           raise THM ("add_classrel_thms: not a class relation", 0, [thm]);
   237       in (c1, c2) end;
   238   in Theory.add_classrel_i (map prep_thm thms) thy end;
   239 
   240 fun add_arity_thms thms thy =
   241   let
   242     fun prep_thm thm =
   243       let
   244         val prop = Drule.plain_prop_of (Thm.transfer thy thm);
   245         val (t, ss, c) = dest_arity prop handle TERM _ =>
   246           raise THM ("add_arity_thms: not an arity", 0, [thm]);
   247       in (t, ss, [c]) end;
   248   in Theory.add_arities_i (map prep_thm thms) thy end;
   249 
   250 
   251 (* prepare classes and arities *)
   252 
   253 fun read_class thy c = Sign.certify_class thy (Sign.intern_class thy c);
   254 
   255 fun test_classrel thy cc = (Type.add_classrel (Sign.pp thy) [cc] (Sign.tsig_of thy); cc);
   256 fun cert_classrel thy = test_classrel thy o Library.pairself (Sign.certify_class thy);
   257 fun read_classrel thy = test_classrel thy o Library.pairself (read_class thy);
   258 
   259 fun test_arity thy ar = (Type.add_arities (Sign.pp thy) [ar] (Sign.tsig_of thy); ar);
   260 
   261 fun prep_arity prep_tycon prep_sort prep thy (t, Ss, x) =
   262   test_arity thy (prep_tycon thy t, map (prep_sort thy) Ss, prep thy x);
   263 
   264 val read_arity = prep_arity Sign.intern_type Sign.read_sort Sign.read_sort;
   265 val cert_arity = prep_arity (K I) Sign.certify_sort Sign.certify_sort;
   266 
   267 
   268 (* instance declarations -- tactical proof *)
   269 
   270 local
   271 
   272 fun ext_inst_subclass prep_classrel raw_cc tac thy =
   273   let
   274     val (c1, c2) = prep_classrel thy raw_cc;
   275     val txt = quote (Sign.string_of_classrel thy [c1, c2]);
   276     val _ = message ("Proving class inclusion " ^ txt ^ " ...");
   277     val th = Goal.prove thy [] [] (mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   278       cat_error msg ("The error(s) above occurred while trying to prove " ^ txt);
   279   in add_classrel_thms [th] thy end;
   280 
   281 fun ext_inst_arity prep_arity raw_arity tac thy =
   282   let
   283     val arity = prep_arity thy raw_arity;
   284     val txt = quote (Sign.string_of_arity thy arity);
   285     val _ = message ("Proving type arity " ^ txt ^ " ...");
   286     val props = (mk_arities arity);
   287     val ths = Goal.prove_multi thy [] [] props
   288       (fn _ => Tactic.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   289         cat_error msg ("\nThe error(s) above occurred while trying to prove " ^ txt);
   290   in add_arity_thms ths thy end;
   291 
   292 in
   293 
   294 val add_inst_subclass = ext_inst_subclass read_classrel;
   295 val add_inst_subclass_i = ext_inst_subclass cert_classrel;
   296 val add_inst_arity = ext_inst_arity read_arity;
   297 val add_inst_arity_i = ext_inst_arity cert_arity;
   298 
   299 end;
   300 
   301 
   302 (* instance declarations -- Isar proof *)
   303 
   304 local
   305 
   306 fun gen_instance mk_prop add_thms inst thy = thy
   307   |> ProofContext.init
   308   |> Proof.theorem_i Drule.internalK NONE (fold add_thms) NONE ("", [])
   309     (map (fn t => (("", []), [(t, ([], []))])) (mk_prop thy inst));
   310 
   311 in
   312 
   313 val instance_subclass =
   314   gen_instance (single oo (mk_classrel oo read_classrel)) add_classrel_thms;
   315 val instance_subclass_i =
   316   gen_instance (single oo (mk_classrel oo cert_classrel)) add_classrel_thms;
   317 val instance_arity = gen_instance (mk_arities oo read_arity) add_arity_thms;
   318 val instance_arity_i = gen_instance (mk_arities oo cert_arity) add_arity_thms;
   319 
   320 end;
   321 
   322 
   323 (* tactics and methods *)
   324 
   325 fun intro_classes_tac facts st =
   326   (ALLGOALS (Method.insert_tac facts THEN'
   327       REPEAT_ALL_NEW (resolve_tac (class_axms (Thm.theory_of_thm st))))
   328     THEN Tactic.distinct_subgoals_tac) st;
   329 
   330 fun default_intro_classes_tac [] = intro_classes_tac []
   331   | default_intro_classes_tac _ = Tactical.no_tac;    (*no error message!*)
   332 
   333 fun default_tac rules ctxt facts =
   334   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   335     default_intro_classes_tac facts;
   336 
   337 val _ = Context.add_setup (Method.add_methods
   338  [("intro_classes", Method.no_args (Method.METHOD intro_classes_tac),
   339     "back-chain introduction rules of axiomatic type classes"),
   340   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac), "apply some intro/elim rule")]);
   341 
   342 
   343 
   344 (** outer syntax **)
   345 
   346 local structure P = OuterParse and K = OuterKeyword in
   347 
   348 val axclassP =
   349   OuterSyntax.command "axclass" "define axiomatic type class" K.thy_decl
   350     ((P.name -- Scan.optional ((P.$$$ "\\<subseteq>" || P.$$$ "<") |--
   351         P.!!! (P.list1 P.xname)) []) -- Scan.repeat P.spec_name
   352       >> (Toplevel.theory o (snd oo uncurry add_axclass)));
   353 
   354 val instanceP =
   355   OuterSyntax.command "instance" "prove type arity or subclass relation" K.thy_goal
   356    ((P.xname -- ((P.$$$ "\\<subseteq>" || P.$$$ "<") |-- P.!!! P.xname) >> instance_subclass ||
   357       P.xname -- (P.$$$ "::" |-- P.!!! P.arity) >> (instance_arity o P.triple2))
   358     >> (Toplevel.print oo Toplevel.theory_to_proof));
   359 
   360 val _ = OuterSyntax.add_parsers [axclassP, instanceP];
   361 
   362 end;
   363 
   364 end;