src/HOL/Analysis/Convex_Euclidean_Space.thy
author immler
Tue Jul 10 09:38:35 2018 +0200 (11 months ago)
changeset 68607 67bb59e49834
parent 68527 2f4e2aab190a
child 69064 5840724b1d71
permissions -rw-r--r--
make theorem, corollary, and proposition %important for HOL-Analysis manual
     1 (* Title:      HOL/Analysis/Convex_Euclidean_Space.thy
     2    Author:     L C Paulson, University of Cambridge
     3    Author:     Robert Himmelmann, TU Muenchen
     4    Author:     Bogdan Grechuk, University of Edinburgh
     5    Author:     Armin Heller, TU Muenchen
     6    Author:     Johannes Hoelzl, TU Muenchen
     7 *)
     8 
     9 section \<open>Convex sets, functions and related things\<close>
    10 
    11 theory Convex_Euclidean_Space
    12 imports
    13   Connected
    14   "HOL-Library.Set_Algebras"
    15 begin
    16 
    17 lemma swap_continuous: (*move to Topological_Spaces?*)
    18   assumes "continuous_on (cbox (a,c) (b,d)) (\<lambda>(x,y). f x y)"
    19     shows "continuous_on (cbox (c,a) (d,b)) (\<lambda>(x, y). f y x)"
    20 proof -
    21   have "(\<lambda>(x, y). f y x) = (\<lambda>(x, y). f x y) \<circ> prod.swap"
    22     by auto
    23   then show ?thesis
    24     apply (rule ssubst)
    25     apply (rule continuous_on_compose)
    26     apply (simp add: split_def)
    27     apply (rule continuous_intros | simp add: assms)+
    28     done
    29 qed
    30 
    31 lemma substdbasis_expansion_unique:
    32   assumes d: "d \<subseteq> Basis"
    33   shows "(\<Sum>i\<in>d. f i *\<^sub>R i) = (x::'a::euclidean_space) \<longleftrightarrow>
    34     (\<forall>i\<in>Basis. (i \<in> d \<longrightarrow> f i = x \<bullet> i) \<and> (i \<notin> d \<longrightarrow> x \<bullet> i = 0))"
    35 proof -
    36   have *: "\<And>x a b P. x * (if P then a else b) = (if P then x * a else x * b)"
    37     by auto
    38   have **: "finite d"
    39     by (auto intro: finite_subset[OF assms])
    40   have ***: "\<And>i. i \<in> Basis \<Longrightarrow> (\<Sum>i\<in>d. f i *\<^sub>R i) \<bullet> i = (\<Sum>x\<in>d. if x = i then f x else 0)"
    41     using d
    42     by (auto intro!: sum.cong simp: inner_Basis inner_sum_left)
    43   show ?thesis
    44     unfolding euclidean_eq_iff[where 'a='a] by (auto simp: sum.delta[OF **] ***)
    45 qed
    46 
    47 lemma independent_substdbasis: "d \<subseteq> Basis \<Longrightarrow> independent d"
    48   by (rule independent_mono[OF independent_Basis])
    49 
    50 lemma dim_cball:
    51   assumes "e > 0"
    52   shows "dim (cball (0 :: 'n::euclidean_space) e) = DIM('n)"
    53 proof -
    54   {
    55     fix x :: "'n::euclidean_space"
    56     define y where "y = (e / norm x) *\<^sub>R x"
    57     then have "y \<in> cball 0 e"
    58       using assms by auto
    59     moreover have *: "x = (norm x / e) *\<^sub>R y"
    60       using y_def assms by simp
    61     moreover from * have "x = (norm x/e) *\<^sub>R y"
    62       by auto
    63     ultimately have "x \<in> span (cball 0 e)"
    64       using span_scale[of y "cball 0 e" "norm x/e"]
    65         span_superset[of "cball 0 e"]
    66       by (simp add: span_base)
    67   }
    68   then have "span (cball 0 e) = (UNIV :: 'n::euclidean_space set)"
    69     by auto
    70   then show ?thesis
    71     using dim_span[of "cball (0 :: 'n::euclidean_space) e"] by (auto simp: dim_UNIV)
    72 qed
    73 
    74 lemma sum_not_0: "sum f A \<noteq> 0 \<Longrightarrow> \<exists>a \<in> A. f a \<noteq> 0"
    75   by (rule ccontr) auto
    76 
    77 lemma subset_translation_eq [simp]:
    78     fixes a :: "'a::real_vector" shows "(+) a ` s \<subseteq> (+) a ` t \<longleftrightarrow> s \<subseteq> t"
    79   by auto
    80 
    81 lemma translate_inj_on:
    82   fixes A :: "'a::ab_group_add set"
    83   shows "inj_on (\<lambda>x. a + x) A"
    84   unfolding inj_on_def by auto
    85 
    86 lemma translation_assoc:
    87   fixes a b :: "'a::ab_group_add"
    88   shows "(\<lambda>x. b + x) ` ((\<lambda>x. a + x) ` S) = (\<lambda>x. (a + b) + x) ` S"
    89   by auto
    90 
    91 lemma translation_invert:
    92   fixes a :: "'a::ab_group_add"
    93   assumes "(\<lambda>x. a + x) ` A = (\<lambda>x. a + x) ` B"
    94   shows "A = B"
    95 proof -
    96   have "(\<lambda>x. -a + x) ` ((\<lambda>x. a + x) ` A) = (\<lambda>x. - a + x) ` ((\<lambda>x. a + x) ` B)"
    97     using assms by auto
    98   then show ?thesis
    99     using translation_assoc[of "-a" a A] translation_assoc[of "-a" a B] by auto
   100 qed
   101 
   102 lemma translation_galois:
   103   fixes a :: "'a::ab_group_add"
   104   shows "T = ((\<lambda>x. a + x) ` S) \<longleftrightarrow> S = ((\<lambda>x. (- a) + x) ` T)"
   105   using translation_assoc[of "-a" a S]
   106   apply auto
   107   using translation_assoc[of a "-a" T]
   108   apply auto
   109   done
   110 
   111 lemma translation_inverse_subset:
   112   assumes "((\<lambda>x. - a + x) ` V) \<le> (S :: 'n::ab_group_add set)"
   113   shows "V \<le> ((\<lambda>x. a + x) ` S)"
   114 proof -
   115   {
   116     fix x
   117     assume "x \<in> V"
   118     then have "x-a \<in> S" using assms by auto
   119     then have "x \<in> {a + v |v. v \<in> S}"
   120       apply auto
   121       apply (rule exI[of _ "x-a"], simp)
   122       done
   123     then have "x \<in> ((\<lambda>x. a+x) ` S)" by auto
   124   }
   125   then show ?thesis by auto
   126 qed
   127 
   128 subsection \<open>Convexity\<close>
   129 
   130 definition%important convex :: "'a::real_vector set \<Rightarrow> bool"
   131   where "convex s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u\<ge>0. \<forall>v\<ge>0. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s)"
   132 
   133 lemma convexI:
   134   assumes "\<And>x y u v. x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> 0 \<le> u \<Longrightarrow> 0 \<le> v \<Longrightarrow> u + v = 1 \<Longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s"
   135   shows "convex s"
   136   using assms unfolding convex_def by fast
   137 
   138 lemma convexD:
   139   assumes "convex s" and "x \<in> s" and "y \<in> s" and "0 \<le> u" and "0 \<le> v" and "u + v = 1"
   140   shows "u *\<^sub>R x + v *\<^sub>R y \<in> s"
   141   using assms unfolding convex_def by fast
   142 
   143 lemma convex_alt: "convex s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u. 0 \<le> u \<and> u \<le> 1 \<longrightarrow> ((1 - u) *\<^sub>R x + u *\<^sub>R y) \<in> s)"
   144   (is "_ \<longleftrightarrow> ?alt")
   145 proof
   146   show "convex s" if alt: ?alt
   147   proof -
   148     {
   149       fix x y and u v :: real
   150       assume mem: "x \<in> s" "y \<in> s"
   151       assume "0 \<le> u" "0 \<le> v"
   152       moreover
   153       assume "u + v = 1"
   154       then have "u = 1 - v" by auto
   155       ultimately have "u *\<^sub>R x + v *\<^sub>R y \<in> s"
   156         using alt [rule_format, OF mem] by auto
   157     }
   158     then show ?thesis
   159       unfolding convex_def by auto
   160   qed
   161   show ?alt if "convex s"
   162     using that by (auto simp: convex_def)
   163 qed
   164 
   165 lemma convexD_alt:
   166   assumes "convex s" "a \<in> s" "b \<in> s" "0 \<le> u" "u \<le> 1"
   167   shows "((1 - u) *\<^sub>R a + u *\<^sub>R b) \<in> s"
   168   using assms unfolding convex_alt by auto
   169 
   170 lemma mem_convex_alt:
   171   assumes "convex S" "x \<in> S" "y \<in> S" "u \<ge> 0" "v \<ge> 0" "u + v > 0"
   172   shows "((u/(u+v)) *\<^sub>R x + (v/(u+v)) *\<^sub>R y) \<in> S"
   173   apply (rule convexD)
   174   using assms
   175        apply (simp_all add: zero_le_divide_iff add_divide_distrib [symmetric])
   176   done
   177 
   178 lemma convex_empty[intro,simp]: "convex {}"
   179   unfolding convex_def by simp
   180 
   181 lemma convex_singleton[intro,simp]: "convex {a}"
   182   unfolding convex_def by (auto simp: scaleR_left_distrib[symmetric])
   183 
   184 lemma convex_UNIV[intro,simp]: "convex UNIV"
   185   unfolding convex_def by auto
   186 
   187 lemma convex_Inter: "(\<And>s. s\<in>f \<Longrightarrow> convex s) \<Longrightarrow> convex(\<Inter>f)"
   188   unfolding convex_def by auto
   189 
   190 lemma convex_Int: "convex s \<Longrightarrow> convex t \<Longrightarrow> convex (s \<inter> t)"
   191   unfolding convex_def by auto
   192 
   193 lemma convex_INT: "(\<And>i. i \<in> A \<Longrightarrow> convex (B i)) \<Longrightarrow> convex (\<Inter>i\<in>A. B i)"
   194   unfolding convex_def by auto
   195 
   196 lemma convex_Times: "convex s \<Longrightarrow> convex t \<Longrightarrow> convex (s \<times> t)"
   197   unfolding convex_def by auto
   198 
   199 lemma convex_halfspace_le: "convex {x. inner a x \<le> b}"
   200   unfolding convex_def
   201   by (auto simp: inner_add intro!: convex_bound_le)
   202 
   203 lemma convex_halfspace_ge: "convex {x. inner a x \<ge> b}"
   204 proof -
   205   have *: "{x. inner a x \<ge> b} = {x. inner (-a) x \<le> -b}"
   206     by auto
   207   show ?thesis
   208     unfolding * using convex_halfspace_le[of "-a" "-b"] by auto
   209 qed
   210 
   211 lemma convex_halfspace_abs_le: "convex {x. \<bar>inner a x\<bar> \<le> b}"
   212 proof -
   213   have *: "{x. \<bar>inner a x\<bar> \<le> b} = {x. inner a x \<le> b} \<inter> {x. -b \<le> inner a x}"
   214     by auto
   215   show ?thesis
   216     unfolding * by (simp add: convex_Int convex_halfspace_ge convex_halfspace_le)
   217 qed
   218 
   219 lemma convex_hyperplane: "convex {x. inner a x = b}"
   220 proof -
   221   have *: "{x. inner a x = b} = {x. inner a x \<le> b} \<inter> {x. inner a x \<ge> b}"
   222     by auto
   223   show ?thesis using convex_halfspace_le convex_halfspace_ge
   224     by (auto intro!: convex_Int simp: *)
   225 qed
   226 
   227 lemma convex_halfspace_lt: "convex {x. inner a x < b}"
   228   unfolding convex_def
   229   by (auto simp: convex_bound_lt inner_add)
   230 
   231 lemma convex_halfspace_gt: "convex {x. inner a x > b}"
   232   using convex_halfspace_lt[of "-a" "-b"] by auto
   233 
   234 lemma convex_halfspace_Re_ge: "convex {x. Re x \<ge> b}"
   235   using convex_halfspace_ge[of b "1::complex"] by simp
   236 
   237 lemma convex_halfspace_Re_le: "convex {x. Re x \<le> b}"
   238   using convex_halfspace_le[of "1::complex" b] by simp
   239 
   240 lemma convex_halfspace_Im_ge: "convex {x. Im x \<ge> b}"
   241   using convex_halfspace_ge[of b \<i>] by simp
   242 
   243 lemma convex_halfspace_Im_le: "convex {x. Im x \<le> b}"
   244   using convex_halfspace_le[of \<i> b] by simp
   245 
   246 lemma convex_halfspace_Re_gt: "convex {x. Re x > b}"
   247   using convex_halfspace_gt[of b "1::complex"] by simp
   248 
   249 lemma convex_halfspace_Re_lt: "convex {x. Re x < b}"
   250   using convex_halfspace_lt[of "1::complex" b] by simp
   251 
   252 lemma convex_halfspace_Im_gt: "convex {x. Im x > b}"
   253   using convex_halfspace_gt[of b \<i>] by simp
   254 
   255 lemma convex_halfspace_Im_lt: "convex {x. Im x < b}"
   256   using convex_halfspace_lt[of \<i> b] by simp
   257 
   258 lemma convex_real_interval [iff]:
   259   fixes a b :: "real"
   260   shows "convex {a..}" and "convex {..b}"
   261     and "convex {a<..}" and "convex {..<b}"
   262     and "convex {a..b}" and "convex {a<..b}"
   263     and "convex {a..<b}" and "convex {a<..<b}"
   264 proof -
   265   have "{a..} = {x. a \<le> inner 1 x}"
   266     by auto
   267   then show 1: "convex {a..}"
   268     by (simp only: convex_halfspace_ge)
   269   have "{..b} = {x. inner 1 x \<le> b}"
   270     by auto
   271   then show 2: "convex {..b}"
   272     by (simp only: convex_halfspace_le)
   273   have "{a<..} = {x. a < inner 1 x}"
   274     by auto
   275   then show 3: "convex {a<..}"
   276     by (simp only: convex_halfspace_gt)
   277   have "{..<b} = {x. inner 1 x < b}"
   278     by auto
   279   then show 4: "convex {..<b}"
   280     by (simp only: convex_halfspace_lt)
   281   have "{a..b} = {a..} \<inter> {..b}"
   282     by auto
   283   then show "convex {a..b}"
   284     by (simp only: convex_Int 1 2)
   285   have "{a<..b} = {a<..} \<inter> {..b}"
   286     by auto
   287   then show "convex {a<..b}"
   288     by (simp only: convex_Int 3 2)
   289   have "{a..<b} = {a..} \<inter> {..<b}"
   290     by auto
   291   then show "convex {a..<b}"
   292     by (simp only: convex_Int 1 4)
   293   have "{a<..<b} = {a<..} \<inter> {..<b}"
   294     by auto
   295   then show "convex {a<..<b}"
   296     by (simp only: convex_Int 3 4)
   297 qed
   298 
   299 lemma convex_Reals: "convex \<real>"
   300   by (simp add: convex_def scaleR_conv_of_real)
   301 
   302 
   303 subsection%unimportant \<open>Explicit expressions for convexity in terms of arbitrary sums\<close>
   304 
   305 lemma convex_sum:
   306   fixes C :: "'a::real_vector set"
   307   assumes "finite s"
   308     and "convex C"
   309     and "(\<Sum> i \<in> s. a i) = 1"
   310   assumes "\<And>i. i \<in> s \<Longrightarrow> a i \<ge> 0"
   311     and "\<And>i. i \<in> s \<Longrightarrow> y i \<in> C"
   312   shows "(\<Sum> j \<in> s. a j *\<^sub>R y j) \<in> C"
   313   using assms(1,3,4,5)
   314 proof (induct arbitrary: a set: finite)
   315   case empty
   316   then show ?case by simp
   317 next
   318   case (insert i s) note IH = this(3)
   319   have "a i + sum a s = 1"
   320     and "0 \<le> a i"
   321     and "\<forall>j\<in>s. 0 \<le> a j"
   322     and "y i \<in> C"
   323     and "\<forall>j\<in>s. y j \<in> C"
   324     using insert.hyps(1,2) insert.prems by simp_all
   325   then have "0 \<le> sum a s"
   326     by (simp add: sum_nonneg)
   327   have "a i *\<^sub>R y i + (\<Sum>j\<in>s. a j *\<^sub>R y j) \<in> C"
   328   proof (cases "sum a s = 0")
   329     case True
   330     with \<open>a i + sum a s = 1\<close> have "a i = 1"
   331       by simp
   332     from sum_nonneg_0 [OF \<open>finite s\<close> _ True] \<open>\<forall>j\<in>s. 0 \<le> a j\<close> have "\<forall>j\<in>s. a j = 0"
   333       by simp
   334     show ?thesis using \<open>a i = 1\<close> and \<open>\<forall>j\<in>s. a j = 0\<close> and \<open>y i \<in> C\<close>
   335       by simp
   336   next
   337     case False
   338     with \<open>0 \<le> sum a s\<close> have "0 < sum a s"
   339       by simp
   340     then have "(\<Sum>j\<in>s. (a j / sum a s) *\<^sub>R y j) \<in> C"
   341       using \<open>\<forall>j\<in>s. 0 \<le> a j\<close> and \<open>\<forall>j\<in>s. y j \<in> C\<close>
   342       by (simp add: IH sum_divide_distrib [symmetric])
   343     from \<open>convex C\<close> and \<open>y i \<in> C\<close> and this and \<open>0 \<le> a i\<close>
   344       and \<open>0 \<le> sum a s\<close> and \<open>a i + sum a s = 1\<close>
   345     have "a i *\<^sub>R y i + sum a s *\<^sub>R (\<Sum>j\<in>s. (a j / sum a s) *\<^sub>R y j) \<in> C"
   346       by (rule convexD)
   347     then show ?thesis
   348       by (simp add: scaleR_sum_right False)
   349   qed
   350   then show ?case using \<open>finite s\<close> and \<open>i \<notin> s\<close>
   351     by simp
   352 qed
   353 
   354 lemma convex:
   355   "convex s \<longleftrightarrow> (\<forall>(k::nat) u x. (\<forall>i. 1\<le>i \<and> i\<le>k \<longrightarrow> 0 \<le> u i \<and> x i \<in>s) \<and> (sum u {1..k} = 1)
   356       \<longrightarrow> sum (\<lambda>i. u i *\<^sub>R x i) {1..k} \<in> s)"
   357 proof safe
   358   fix k :: nat
   359   fix u :: "nat \<Rightarrow> real"
   360   fix x
   361   assume "convex s"
   362     "\<forall>i. 1 \<le> i \<and> i \<le> k \<longrightarrow> 0 \<le> u i \<and> x i \<in> s"
   363     "sum u {1..k} = 1"
   364   with convex_sum[of "{1 .. k}" s] show "(\<Sum>j\<in>{1 .. k}. u j *\<^sub>R x j) \<in> s"
   365     by auto
   366 next
   367   assume *: "\<forall>k u x. (\<forall> i :: nat. 1 \<le> i \<and> i \<le> k \<longrightarrow> 0 \<le> u i \<and> x i \<in> s) \<and> sum u {1..k} = 1
   368     \<longrightarrow> (\<Sum>i = 1..k. u i *\<^sub>R (x i :: 'a)) \<in> s"
   369   {
   370     fix \<mu> :: real
   371     fix x y :: 'a
   372     assume xy: "x \<in> s" "y \<in> s"
   373     assume mu: "\<mu> \<ge> 0" "\<mu> \<le> 1"
   374     let ?u = "\<lambda>i. if (i :: nat) = 1 then \<mu> else 1 - \<mu>"
   375     let ?x = "\<lambda>i. if (i :: nat) = 1 then x else y"
   376     have "{1 :: nat .. 2} \<inter> - {x. x = 1} = {2}"
   377       by auto
   378     then have card: "card ({1 :: nat .. 2} \<inter> - {x. x = 1}) = 1"
   379       by simp
   380     then have "sum ?u {1 .. 2} = 1"
   381       using sum.If_cases[of "{(1 :: nat) .. 2}" "\<lambda> x. x = 1" "\<lambda> x. \<mu>" "\<lambda> x. 1 - \<mu>"]
   382       by auto
   383     with *[rule_format, of "2" ?u ?x] have s: "(\<Sum>j \<in> {1..2}. ?u j *\<^sub>R ?x j) \<in> s"
   384       using mu xy by auto
   385     have grarr: "(\<Sum>j \<in> {Suc (Suc 0)..2}. ?u j *\<^sub>R ?x j) = (1 - \<mu>) *\<^sub>R y"
   386       using sum_head_Suc[of "Suc (Suc 0)" 2 "\<lambda> j. (1 - \<mu>) *\<^sub>R y"] by auto
   387     from sum_head_Suc[of "Suc 0" 2 "\<lambda> j. ?u j *\<^sub>R ?x j", simplified this]
   388     have "(\<Sum>j \<in> {1..2}. ?u j *\<^sub>R ?x j) = \<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y"
   389       by auto
   390     then have "(1 - \<mu>) *\<^sub>R y + \<mu> *\<^sub>R x \<in> s"
   391       using s by (auto simp: add.commute)
   392   }
   393   then show "convex s"
   394     unfolding convex_alt by auto
   395 qed
   396 
   397 
   398 lemma convex_explicit:
   399   fixes s :: "'a::real_vector set"
   400   shows "convex s \<longleftrightarrow>
   401     (\<forall>t u. finite t \<and> t \<subseteq> s \<and> (\<forall>x\<in>t. 0 \<le> u x) \<and> sum u t = 1 \<longrightarrow> sum (\<lambda>x. u x *\<^sub>R x) t \<in> s)"
   402 proof safe
   403   fix t
   404   fix u :: "'a \<Rightarrow> real"
   405   assume "convex s"
   406     and "finite t"
   407     and "t \<subseteq> s" "\<forall>x\<in>t. 0 \<le> u x" "sum u t = 1"
   408   then show "(\<Sum>x\<in>t. u x *\<^sub>R x) \<in> s"
   409     using convex_sum[of t s u "\<lambda> x. x"] by auto
   410 next
   411   assume *: "\<forall>t. \<forall> u. finite t \<and> t \<subseteq> s \<and> (\<forall>x\<in>t. 0 \<le> u x) \<and>
   412     sum u t = 1 \<longrightarrow> (\<Sum>x\<in>t. u x *\<^sub>R x) \<in> s"
   413   show "convex s"
   414     unfolding convex_alt
   415   proof safe
   416     fix x y
   417     fix \<mu> :: real
   418     assume **: "x \<in> s" "y \<in> s" "0 \<le> \<mu>" "\<mu> \<le> 1"
   419     show "(1 - \<mu>) *\<^sub>R x + \<mu> *\<^sub>R y \<in> s"
   420     proof (cases "x = y")
   421       case False
   422       then show ?thesis
   423         using *[rule_format, of "{x, y}" "\<lambda> z. if z = x then 1 - \<mu> else \<mu>"] **
   424         by auto
   425     next
   426       case True
   427       then show ?thesis
   428         using *[rule_format, of "{x, y}" "\<lambda> z. 1"] **
   429         by (auto simp: field_simps real_vector.scale_left_diff_distrib)
   430     qed
   431   qed
   432 qed
   433 
   434 lemma convex_finite:
   435   assumes "finite s"
   436   shows "convex s \<longleftrightarrow> (\<forall>u. (\<forall>x\<in>s. 0 \<le> u x) \<and> sum u s = 1 \<longrightarrow> sum (\<lambda>x. u x *\<^sub>R x) s \<in> s)"
   437   unfolding convex_explicit
   438   apply safe
   439   subgoal for u by (erule allE [where x=s], erule allE [where x=u]) auto
   440   subgoal for t u
   441   proof -
   442     have if_distrib_arg: "\<And>P f g x. (if P then f else g) x = (if P then f x else g x)"
   443       by simp
   444     assume sum: "\<forall>u. (\<forall>x\<in>s. 0 \<le> u x) \<and> sum u s = 1 \<longrightarrow> (\<Sum>x\<in>s. u x *\<^sub>R x) \<in> s"
   445     assume *: "\<forall>x\<in>t. 0 \<le> u x" "sum u t = 1"
   446     assume "t \<subseteq> s"
   447     then have "s \<inter> t = t" by auto
   448     with sum[THEN spec[where x="\<lambda>x. if x\<in>t then u x else 0"]] * show "(\<Sum>x\<in>t. u x *\<^sub>R x) \<in> s"
   449       by (auto simp: assms sum.If_cases if_distrib if_distrib_arg)
   450   qed
   451   done
   452 
   453 
   454 subsection \<open>Functions that are convex on a set\<close>
   455 
   456 definition%important convex_on :: "'a::real_vector set \<Rightarrow> ('a \<Rightarrow> real) \<Rightarrow> bool"
   457   where "convex_on s f \<longleftrightarrow>
   458     (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u\<ge>0. \<forall>v\<ge>0. u + v = 1 \<longrightarrow> f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y)"
   459 
   460 lemma convex_onI [intro?]:
   461   assumes "\<And>t x y. t > 0 \<Longrightarrow> t < 1 \<Longrightarrow> x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow>
   462     f ((1 - t) *\<^sub>R x + t *\<^sub>R y) \<le> (1 - t) * f x + t * f y"
   463   shows "convex_on A f"
   464   unfolding convex_on_def
   465 proof clarify
   466   fix x y
   467   fix u v :: real
   468   assume A: "x \<in> A" "y \<in> A" "u \<ge> 0" "v \<ge> 0" "u + v = 1"
   469   from A(5) have [simp]: "v = 1 - u"
   470     by (simp add: algebra_simps)
   471   from A(1-4) show "f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y"
   472     using assms[of u y x]
   473     by (cases "u = 0 \<or> u = 1") (auto simp: algebra_simps)
   474 qed
   475 
   476 lemma convex_on_linorderI [intro?]:
   477   fixes A :: "('a::{linorder,real_vector}) set"
   478   assumes "\<And>t x y. t > 0 \<Longrightarrow> t < 1 \<Longrightarrow> x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> x < y \<Longrightarrow>
   479     f ((1 - t) *\<^sub>R x + t *\<^sub>R y) \<le> (1 - t) * f x + t * f y"
   480   shows "convex_on A f"
   481 proof
   482   fix x y
   483   fix t :: real
   484   assume A: "x \<in> A" "y \<in> A" "t > 0" "t < 1"
   485   with assms [of t x y] assms [of "1 - t" y x]
   486   show "f ((1 - t) *\<^sub>R x + t *\<^sub>R y) \<le> (1 - t) * f x + t * f y"
   487     by (cases x y rule: linorder_cases) (auto simp: algebra_simps)
   488 qed
   489 
   490 lemma convex_onD:
   491   assumes "convex_on A f"
   492   shows "\<And>t x y. t \<ge> 0 \<Longrightarrow> t \<le> 1 \<Longrightarrow> x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow>
   493     f ((1 - t) *\<^sub>R x + t *\<^sub>R y) \<le> (1 - t) * f x + t * f y"
   494   using assms by (auto simp: convex_on_def)
   495 
   496 lemma convex_onD_Icc:
   497   assumes "convex_on {x..y} f" "x \<le> (y :: _ :: {real_vector,preorder})"
   498   shows "\<And>t. t \<ge> 0 \<Longrightarrow> t \<le> 1 \<Longrightarrow>
   499     f ((1 - t) *\<^sub>R x + t *\<^sub>R y) \<le> (1 - t) * f x + t * f y"
   500   using assms(2) by (intro convex_onD [OF assms(1)]) simp_all
   501 
   502 lemma convex_on_subset: "convex_on t f \<Longrightarrow> s \<subseteq> t \<Longrightarrow> convex_on s f"
   503   unfolding convex_on_def by auto
   504 
   505 lemma convex_on_add [intro]:
   506   assumes "convex_on s f"
   507     and "convex_on s g"
   508   shows "convex_on s (\<lambda>x. f x + g x)"
   509 proof -
   510   {
   511     fix x y
   512     assume "x \<in> s" "y \<in> s"
   513     moreover
   514     fix u v :: real
   515     assume "0 \<le> u" "0 \<le> v" "u + v = 1"
   516     ultimately
   517     have "f (u *\<^sub>R x + v *\<^sub>R y) + g (u *\<^sub>R x + v *\<^sub>R y) \<le> (u * f x + v * f y) + (u * g x + v * g y)"
   518       using assms unfolding convex_on_def by (auto simp: add_mono)
   519     then have "f (u *\<^sub>R x + v *\<^sub>R y) + g (u *\<^sub>R x + v *\<^sub>R y) \<le> u * (f x + g x) + v * (f y + g y)"
   520       by (simp add: field_simps)
   521   }
   522   then show ?thesis
   523     unfolding convex_on_def by auto
   524 qed
   525 
   526 lemma convex_on_cmul [intro]:
   527   fixes c :: real
   528   assumes "0 \<le> c"
   529     and "convex_on s f"
   530   shows "convex_on s (\<lambda>x. c * f x)"
   531 proof -
   532   have *: "u * (c * fx) + v * (c * fy) = c * (u * fx + v * fy)"
   533     for u c fx v fy :: real
   534     by (simp add: field_simps)
   535   show ?thesis using assms(2) and mult_left_mono [OF _ assms(1)]
   536     unfolding convex_on_def and * by auto
   537 qed
   538 
   539 lemma convex_lower:
   540   assumes "convex_on s f"
   541     and "x \<in> s"
   542     and "y \<in> s"
   543     and "0 \<le> u"
   544     and "0 \<le> v"
   545     and "u + v = 1"
   546   shows "f (u *\<^sub>R x + v *\<^sub>R y) \<le> max (f x) (f y)"
   547 proof -
   548   let ?m = "max (f x) (f y)"
   549   have "u * f x + v * f y \<le> u * max (f x) (f y) + v * max (f x) (f y)"
   550     using assms(4,5) by (auto simp: mult_left_mono add_mono)
   551   also have "\<dots> = max (f x) (f y)"
   552     using assms(6) by (simp add: distrib_right [symmetric])
   553   finally show ?thesis
   554     using assms unfolding convex_on_def by fastforce
   555 qed
   556 
   557 lemma convex_on_dist [intro]:
   558   fixes s :: "'a::real_normed_vector set"
   559   shows "convex_on s (\<lambda>x. dist a x)"
   560 proof (auto simp: convex_on_def dist_norm)
   561   fix x y
   562   assume "x \<in> s" "y \<in> s"
   563   fix u v :: real
   564   assume "0 \<le> u"
   565   assume "0 \<le> v"
   566   assume "u + v = 1"
   567   have "a = u *\<^sub>R a + v *\<^sub>R a"
   568     unfolding scaleR_left_distrib[symmetric] and \<open>u + v = 1\<close> by simp
   569   then have *: "a - (u *\<^sub>R x + v *\<^sub>R y) = (u *\<^sub>R (a - x)) + (v *\<^sub>R (a - y))"
   570     by (auto simp: algebra_simps)
   571   show "norm (a - (u *\<^sub>R x + v *\<^sub>R y)) \<le> u * norm (a - x) + v * norm (a - y)"
   572     unfolding * using norm_triangle_ineq[of "u *\<^sub>R (a - x)" "v *\<^sub>R (a - y)"]
   573     using \<open>0 \<le> u\<close> \<open>0 \<le> v\<close> by auto
   574 qed
   575 
   576 
   577 subsection%unimportant \<open>Arithmetic operations on sets preserve convexity\<close>
   578 
   579 lemma convex_linear_image:
   580   assumes "linear f"
   581     and "convex s"
   582   shows "convex (f ` s)"
   583 proof -
   584   interpret f: linear f by fact
   585   from \<open>convex s\<close> show "convex (f ` s)"
   586     by (simp add: convex_def f.scaleR [symmetric] f.add [symmetric])
   587 qed
   588 
   589 lemma convex_linear_vimage:
   590   assumes "linear f"
   591     and "convex s"
   592   shows "convex (f -` s)"
   593 proof -
   594   interpret f: linear f by fact
   595   from \<open>convex s\<close> show "convex (f -` s)"
   596     by (simp add: convex_def f.add f.scaleR)
   597 qed
   598 
   599 lemma convex_scaling:
   600   assumes "convex s"
   601   shows "convex ((\<lambda>x. c *\<^sub>R x) ` s)"
   602 proof -
   603   have "linear (\<lambda>x. c *\<^sub>R x)"
   604     by (simp add: linearI scaleR_add_right)
   605   then show ?thesis
   606     using \<open>convex s\<close> by (rule convex_linear_image)
   607 qed
   608 
   609 lemma convex_scaled:
   610   assumes "convex S"
   611   shows "convex ((\<lambda>x. x *\<^sub>R c) ` S)"
   612 proof -
   613   have "linear (\<lambda>x. x *\<^sub>R c)"
   614     by (simp add: linearI scaleR_add_left)
   615   then show ?thesis
   616     using \<open>convex S\<close> by (rule convex_linear_image)
   617 qed
   618 
   619 lemma convex_negations:
   620   assumes "convex S"
   621   shows "convex ((\<lambda>x. - x) ` S)"
   622 proof -
   623   have "linear (\<lambda>x. - x)"
   624     by (simp add: linearI)
   625   then show ?thesis
   626     using \<open>convex S\<close> by (rule convex_linear_image)
   627 qed
   628 
   629 lemma convex_sums:
   630   assumes "convex S"
   631     and "convex T"
   632   shows "convex (\<Union>x\<in> S. \<Union>y \<in> T. {x + y})"
   633 proof -
   634   have "linear (\<lambda>(x, y). x + y)"
   635     by (auto intro: linearI simp: scaleR_add_right)
   636   with assms have "convex ((\<lambda>(x, y). x + y) ` (S \<times> T))"
   637     by (intro convex_linear_image convex_Times)
   638   also have "((\<lambda>(x, y). x + y) ` (S \<times> T)) = (\<Union>x\<in> S. \<Union>y \<in> T. {x + y})"
   639     by auto
   640   finally show ?thesis .
   641 qed
   642 
   643 lemma convex_differences:
   644   assumes "convex S" "convex T"
   645   shows "convex (\<Union>x\<in> S. \<Union>y \<in> T. {x - y})"
   646 proof -
   647   have "{x - y| x y. x \<in> S \<and> y \<in> T} = {x + y |x y. x \<in> S \<and> y \<in> uminus ` T}"
   648     by (auto simp: diff_conv_add_uminus simp del: add_uminus_conv_diff)
   649   then show ?thesis
   650     using convex_sums[OF assms(1) convex_negations[OF assms(2)]] by auto
   651 qed
   652 
   653 lemma convex_translation:
   654   assumes "convex S"
   655   shows "convex ((\<lambda>x. a + x) ` S)"
   656 proof -
   657   have "(\<Union> x\<in> {a}. \<Union>y \<in> S. {x + y}) = (\<lambda>x. a + x) ` S"
   658     by auto
   659   then show ?thesis
   660     using convex_sums[OF convex_singleton[of a] assms] by auto
   661 qed
   662 
   663 lemma convex_affinity:
   664   assumes "convex S"
   665   shows "convex ((\<lambda>x. a + c *\<^sub>R x) ` S)"
   666 proof -
   667   have "(\<lambda>x. a + c *\<^sub>R x) ` S = (+) a ` ( *\<^sub>R) c ` S"
   668     by auto
   669   then show ?thesis
   670     using convex_translation[OF convex_scaling[OF assms], of a c] by auto
   671 qed
   672 
   673 lemma pos_is_convex: "convex {0 :: real <..}"
   674   unfolding convex_alt
   675 proof safe
   676   fix y x \<mu> :: real
   677   assume *: "y > 0" "x > 0" "\<mu> \<ge> 0" "\<mu> \<le> 1"
   678   {
   679     assume "\<mu> = 0"
   680     then have "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y = y"
   681       by simp
   682     then have "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y > 0"
   683       using * by simp
   684   }
   685   moreover
   686   {
   687     assume "\<mu> = 1"
   688     then have "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y > 0"
   689       using * by simp
   690   }
   691   moreover
   692   {
   693     assume "\<mu> \<noteq> 1" "\<mu> \<noteq> 0"
   694     then have "\<mu> > 0" "(1 - \<mu>) > 0"
   695       using * by auto
   696     then have "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y > 0"
   697       using * by (auto simp: add_pos_pos)
   698   }
   699   ultimately show "(1 - \<mu>) *\<^sub>R y + \<mu> *\<^sub>R x > 0"
   700     by fastforce
   701 qed
   702 
   703 lemma convex_on_sum:
   704   fixes a :: "'a \<Rightarrow> real"
   705     and y :: "'a \<Rightarrow> 'b::real_vector"
   706     and f :: "'b \<Rightarrow> real"
   707   assumes "finite s" "s \<noteq> {}"
   708     and "convex_on C f"
   709     and "convex C"
   710     and "(\<Sum> i \<in> s. a i) = 1"
   711     and "\<And>i. i \<in> s \<Longrightarrow> a i \<ge> 0"
   712     and "\<And>i. i \<in> s \<Longrightarrow> y i \<in> C"
   713   shows "f (\<Sum> i \<in> s. a i *\<^sub>R y i) \<le> (\<Sum> i \<in> s. a i * f (y i))"
   714   using assms
   715 proof (induct s arbitrary: a rule: finite_ne_induct)
   716   case (singleton i)
   717   then have ai: "a i = 1"
   718     by auto
   719   then show ?case
   720     by auto
   721 next
   722   case (insert i s)
   723   then have "convex_on C f"
   724     by simp
   725   from this[unfolded convex_on_def, rule_format]
   726   have conv: "\<And>x y \<mu>. x \<in> C \<Longrightarrow> y \<in> C \<Longrightarrow> 0 \<le> \<mu> \<Longrightarrow> \<mu> \<le> 1 \<Longrightarrow>
   727       f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
   728     by simp
   729   show ?case
   730   proof (cases "a i = 1")
   731     case True
   732     then have "(\<Sum> j \<in> s. a j) = 0"
   733       using insert by auto
   734     then have "\<And>j. j \<in> s \<Longrightarrow> a j = 0"
   735       using insert by (fastforce simp: sum_nonneg_eq_0_iff)
   736     then show ?thesis
   737       using insert by auto
   738   next
   739     case False
   740     from insert have yai: "y i \<in> C" "a i \<ge> 0"
   741       by auto
   742     have fis: "finite (insert i s)"
   743       using insert by auto
   744     then have ai1: "a i \<le> 1"
   745       using sum_nonneg_leq_bound[of "insert i s" a] insert by simp
   746     then have "a i < 1"
   747       using False by auto
   748     then have i0: "1 - a i > 0"
   749       by auto
   750     let ?a = "\<lambda>j. a j / (1 - a i)"
   751     have a_nonneg: "?a j \<ge> 0" if "j \<in> s" for j
   752       using i0 insert that by fastforce
   753     have "(\<Sum> j \<in> insert i s. a j) = 1"
   754       using insert by auto
   755     then have "(\<Sum> j \<in> s. a j) = 1 - a i"
   756       using sum.insert insert by fastforce
   757     then have "(\<Sum> j \<in> s. a j) / (1 - a i) = 1"
   758       using i0 by auto
   759     then have a1: "(\<Sum> j \<in> s. ?a j) = 1"
   760       unfolding sum_divide_distrib by simp
   761     have "convex C" using insert by auto
   762     then have asum: "(\<Sum> j \<in> s. ?a j *\<^sub>R y j) \<in> C"
   763       using insert convex_sum [OF \<open>finite s\<close> \<open>convex C\<close> a1 a_nonneg] by auto
   764     have asum_le: "f (\<Sum> j \<in> s. ?a j *\<^sub>R y j) \<le> (\<Sum> j \<in> s. ?a j * f (y j))"
   765       using a_nonneg a1 insert by blast
   766     have "f (\<Sum> j \<in> insert i s. a j *\<^sub>R y j) = f ((\<Sum> j \<in> s. a j *\<^sub>R y j) + a i *\<^sub>R y i)"
   767       using sum.insert[of s i "\<lambda> j. a j *\<^sub>R y j", OF \<open>finite s\<close> \<open>i \<notin> s\<close>] insert
   768       by (auto simp only: add.commute)
   769     also have "\<dots> = f (((1 - a i) * inverse (1 - a i)) *\<^sub>R (\<Sum> j \<in> s. a j *\<^sub>R y j) + a i *\<^sub>R y i)"
   770       using i0 by auto
   771     also have "\<dots> = f ((1 - a i) *\<^sub>R (\<Sum> j \<in> s. (a j * inverse (1 - a i)) *\<^sub>R y j) + a i *\<^sub>R y i)"
   772       using scaleR_right.sum[of "inverse (1 - a i)" "\<lambda> j. a j *\<^sub>R y j" s, symmetric]
   773       by (auto simp: algebra_simps)
   774     also have "\<dots> = f ((1 - a i) *\<^sub>R (\<Sum> j \<in> s. ?a j *\<^sub>R y j) + a i *\<^sub>R y i)"
   775       by (auto simp: divide_inverse)
   776     also have "\<dots> \<le> (1 - a i) *\<^sub>R f ((\<Sum> j \<in> s. ?a j *\<^sub>R y j)) + a i * f (y i)"
   777       using conv[of "y i" "(\<Sum> j \<in> s. ?a j *\<^sub>R y j)" "a i", OF yai(1) asum yai(2) ai1]
   778       by (auto simp: add.commute)
   779     also have "\<dots> \<le> (1 - a i) * (\<Sum> j \<in> s. ?a j * f (y j)) + a i * f (y i)"
   780       using add_right_mono [OF mult_left_mono [of _ _ "1 - a i",
   781             OF asum_le less_imp_le[OF i0]], of "a i * f (y i)"]
   782       by simp
   783     also have "\<dots> = (\<Sum> j \<in> s. (1 - a i) * ?a j * f (y j)) + a i * f (y i)"
   784       unfolding sum_distrib_left[of "1 - a i" "\<lambda> j. ?a j * f (y j)"]
   785       using i0 by auto
   786     also have "\<dots> = (\<Sum> j \<in> s. a j * f (y j)) + a i * f (y i)"
   787       using i0 by auto
   788     also have "\<dots> = (\<Sum> j \<in> insert i s. a j * f (y j))"
   789       using insert by auto
   790     finally show ?thesis
   791       by simp
   792   qed
   793 qed
   794 
   795 lemma convex_on_alt:
   796   fixes C :: "'a::real_vector set"
   797   assumes "convex C"
   798   shows "convex_on C f \<longleftrightarrow>
   799     (\<forall>x \<in> C. \<forall> y \<in> C. \<forall> \<mu> :: real. \<mu> \<ge> 0 \<and> \<mu> \<le> 1 \<longrightarrow>
   800       f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y)"
   801 proof safe
   802   fix x y
   803   fix \<mu> :: real
   804   assume *: "convex_on C f" "x \<in> C" "y \<in> C" "0 \<le> \<mu>" "\<mu> \<le> 1"
   805   from this[unfolded convex_on_def, rule_format]
   806   have "0 \<le> u \<Longrightarrow> 0 \<le> v \<Longrightarrow> u + v = 1 \<Longrightarrow> f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y" for u v
   807     by auto
   808   from this [of "\<mu>" "1 - \<mu>", simplified] *
   809   show "f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
   810     by auto
   811 next
   812   assume *: "\<forall>x\<in>C. \<forall>y\<in>C. \<forall>\<mu>. 0 \<le> \<mu> \<and> \<mu> \<le> 1 \<longrightarrow>
   813     f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
   814   {
   815     fix x y
   816     fix u v :: real
   817     assume **: "x \<in> C" "y \<in> C" "u \<ge> 0" "v \<ge> 0" "u + v = 1"
   818     then have[simp]: "1 - u = v" by auto
   819     from *[rule_format, of x y u]
   820     have "f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y"
   821       using ** by auto
   822   }
   823   then show "convex_on C f"
   824     unfolding convex_on_def by auto
   825 qed
   826 
   827 lemma convex_on_diff:
   828   fixes f :: "real \<Rightarrow> real"
   829   assumes f: "convex_on I f"
   830     and I: "x \<in> I" "y \<in> I"
   831     and t: "x < t" "t < y"
   832   shows "(f x - f t) / (x - t) \<le> (f x - f y) / (x - y)"
   833     and "(f x - f y) / (x - y) \<le> (f t - f y) / (t - y)"
   834 proof -
   835   define a where "a \<equiv> (t - y) / (x - y)"
   836   with t have "0 \<le> a" "0 \<le> 1 - a"
   837     by (auto simp: field_simps)
   838   with f \<open>x \<in> I\<close> \<open>y \<in> I\<close> have cvx: "f (a * x + (1 - a) * y) \<le> a * f x + (1 - a) * f y"
   839     by (auto simp: convex_on_def)
   840   have "a * x + (1 - a) * y = a * (x - y) + y"
   841     by (simp add: field_simps)
   842   also have "\<dots> = t"
   843     unfolding a_def using \<open>x < t\<close> \<open>t < y\<close> by simp
   844   finally have "f t \<le> a * f x + (1 - a) * f y"
   845     using cvx by simp
   846   also have "\<dots> = a * (f x - f y) + f y"
   847     by (simp add: field_simps)
   848   finally have "f t - f y \<le> a * (f x - f y)"
   849     by simp
   850   with t show "(f x - f t) / (x - t) \<le> (f x - f y) / (x - y)"
   851     by (simp add: le_divide_eq divide_le_eq field_simps a_def)
   852   with t show "(f x - f y) / (x - y) \<le> (f t - f y) / (t - y)"
   853     by (simp add: le_divide_eq divide_le_eq field_simps)
   854 qed
   855 
   856 lemma pos_convex_function:
   857   fixes f :: "real \<Rightarrow> real"
   858   assumes "convex C"
   859     and leq: "\<And>x y. x \<in> C \<Longrightarrow> y \<in> C \<Longrightarrow> f' x * (y - x) \<le> f y - f x"
   860   shows "convex_on C f"
   861   unfolding convex_on_alt[OF assms(1)]
   862   using assms
   863 proof safe
   864   fix x y \<mu> :: real
   865   let ?x = "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y"
   866   assume *: "convex C" "x \<in> C" "y \<in> C" "\<mu> \<ge> 0" "\<mu> \<le> 1"
   867   then have "1 - \<mu> \<ge> 0" by auto
   868   then have xpos: "?x \<in> C"
   869     using * unfolding convex_alt by fastforce
   870   have geq: "\<mu> * (f x - f ?x) + (1 - \<mu>) * (f y - f ?x) \<ge>
   871       \<mu> * f' ?x * (x - ?x) + (1 - \<mu>) * f' ?x * (y - ?x)"
   872     using add_mono [OF mult_left_mono [OF leq [OF xpos *(2)] \<open>\<mu> \<ge> 0\<close>]
   873         mult_left_mono [OF leq [OF xpos *(3)] \<open>1 - \<mu> \<ge> 0\<close>]]
   874     by auto
   875   then have "\<mu> * f x + (1 - \<mu>) * f y - f ?x \<ge> 0"
   876     by (auto simp: field_simps)
   877   then show "f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
   878     using convex_on_alt by auto
   879 qed
   880 
   881 lemma atMostAtLeast_subset_convex:
   882   fixes C :: "real set"
   883   assumes "convex C"
   884     and "x \<in> C" "y \<in> C" "x < y"
   885   shows "{x .. y} \<subseteq> C"
   886 proof safe
   887   fix z assume z: "z \<in> {x .. y}"
   888   have less: "z \<in> C" if *: "x < z" "z < y"
   889   proof -
   890     let ?\<mu> = "(y - z) / (y - x)"
   891     have "0 \<le> ?\<mu>" "?\<mu> \<le> 1"
   892       using assms * by (auto simp: field_simps)
   893     then have comb: "?\<mu> * x + (1 - ?\<mu>) * y \<in> C"
   894       using assms iffD1[OF convex_alt, rule_format, of C y x ?\<mu>]
   895       by (simp add: algebra_simps)
   896     have "?\<mu> * x + (1 - ?\<mu>) * y = (y - z) * x / (y - x) + (1 - (y - z) / (y - x)) * y"
   897       by (auto simp: field_simps)
   898     also have "\<dots> = ((y - z) * x + (y - x - (y - z)) * y) / (y - x)"
   899       using assms by (simp only: add_divide_distrib) (auto simp: field_simps)
   900     also have "\<dots> = z"
   901       using assms by (auto simp: field_simps)
   902     finally show ?thesis
   903       using comb by auto
   904   qed
   905   show "z \<in> C"
   906     using z less assms by (auto simp: le_less)
   907 qed
   908 
   909 lemma f''_imp_f':
   910   fixes f :: "real \<Rightarrow> real"
   911   assumes "convex C"
   912     and f': "\<And>x. x \<in> C \<Longrightarrow> DERIV f x :> (f' x)"
   913     and f'': "\<And>x. x \<in> C \<Longrightarrow> DERIV f' x :> (f'' x)"
   914     and pos: "\<And>x. x \<in> C \<Longrightarrow> f'' x \<ge> 0"
   915     and x: "x \<in> C"
   916     and y: "y \<in> C"
   917   shows "f' x * (y - x) \<le> f y - f x"
   918   using assms
   919 proof -
   920   have less_imp: "f y - f x \<ge> f' x * (y - x)" "f' y * (x - y) \<le> f x - f y"
   921     if *: "x \<in> C" "y \<in> C" "y > x" for x y :: real
   922   proof -
   923     from * have ge: "y - x > 0" "y - x \<ge> 0"
   924       by auto
   925     from * have le: "x - y < 0" "x - y \<le> 0"
   926       by auto
   927     then obtain z1 where z1: "z1 > x" "z1 < y" "f y - f x = (y - x) * f' z1"
   928       using subsetD[OF atMostAtLeast_subset_convex[OF \<open>convex C\<close> \<open>x \<in> C\<close> \<open>y \<in> C\<close> \<open>x < y\<close>],
   929           THEN f', THEN MVT2[OF \<open>x < y\<close>, rule_format, unfolded atLeastAtMost_iff[symmetric]]]
   930       by auto
   931     then have "z1 \<in> C"
   932       using atMostAtLeast_subset_convex \<open>convex C\<close> \<open>x \<in> C\<close> \<open>y \<in> C\<close> \<open>x < y\<close>
   933       by fastforce
   934     from z1 have z1': "f x - f y = (x - y) * f' z1"
   935       by (simp add: field_simps)
   936     obtain z2 where z2: "z2 > x" "z2 < z1" "f' z1 - f' x = (z1 - x) * f'' z2"
   937       using subsetD[OF atMostAtLeast_subset_convex[OF \<open>convex C\<close> \<open>x \<in> C\<close> \<open>z1 \<in> C\<close> \<open>x < z1\<close>],
   938           THEN f'', THEN MVT2[OF \<open>x < z1\<close>, rule_format, unfolded atLeastAtMost_iff[symmetric]]] z1
   939       by auto
   940     obtain z3 where z3: "z3 > z1" "z3 < y" "f' y - f' z1 = (y - z1) * f'' z3"
   941       using subsetD[OF atMostAtLeast_subset_convex[OF \<open>convex C\<close> \<open>z1 \<in> C\<close> \<open>y \<in> C\<close> \<open>z1 < y\<close>],
   942           THEN f'', THEN MVT2[OF \<open>z1 < y\<close>, rule_format, unfolded atLeastAtMost_iff[symmetric]]] z1
   943       by auto
   944     have "f' y - (f x - f y) / (x - y) = f' y - f' z1"
   945       using * z1' by auto
   946     also have "\<dots> = (y - z1) * f'' z3"
   947       using z3 by auto
   948     finally have cool': "f' y - (f x - f y) / (x - y) = (y - z1) * f'' z3"
   949       by simp
   950     have A': "y - z1 \<ge> 0"
   951       using z1 by auto
   952     have "z3 \<in> C"
   953       using z3 * atMostAtLeast_subset_convex \<open>convex C\<close> \<open>x \<in> C\<close> \<open>z1 \<in> C\<close> \<open>x < z1\<close>
   954       by fastforce
   955     then have B': "f'' z3 \<ge> 0"
   956       using assms by auto
   957     from A' B' have "(y - z1) * f'' z3 \<ge> 0"
   958       by auto
   959     from cool' this have "f' y - (f x - f y) / (x - y) \<ge> 0"
   960       by auto
   961     from mult_right_mono_neg[OF this le(2)]
   962     have "f' y * (x - y) - (f x - f y) / (x - y) * (x - y) \<le> 0 * (x - y)"
   963       by (simp add: algebra_simps)
   964     then have "f' y * (x - y) - (f x - f y) \<le> 0"
   965       using le by auto
   966     then have res: "f' y * (x - y) \<le> f x - f y"
   967       by auto
   968     have "(f y - f x) / (y - x) - f' x = f' z1 - f' x"
   969       using * z1 by auto
   970     also have "\<dots> = (z1 - x) * f'' z2"
   971       using z2 by auto
   972     finally have cool: "(f y - f x) / (y - x) - f' x = (z1 - x) * f'' z2"
   973       by simp
   974     have A: "z1 - x \<ge> 0"
   975       using z1 by auto
   976     have "z2 \<in> C"
   977       using z2 z1 * atMostAtLeast_subset_convex \<open>convex C\<close> \<open>z1 \<in> C\<close> \<open>y \<in> C\<close> \<open>z1 < y\<close>
   978       by fastforce
   979     then have B: "f'' z2 \<ge> 0"
   980       using assms by auto
   981     from A B have "(z1 - x) * f'' z2 \<ge> 0"
   982       by auto
   983     with cool have "(f y - f x) / (y - x) - f' x \<ge> 0"
   984       by auto
   985     from mult_right_mono[OF this ge(2)]
   986     have "(f y - f x) / (y - x) * (y - x) - f' x * (y - x) \<ge> 0 * (y - x)"
   987       by (simp add: algebra_simps)
   988     then have "f y - f x - f' x * (y - x) \<ge> 0"
   989       using ge by auto
   990     then show "f y - f x \<ge> f' x * (y - x)" "f' y * (x - y) \<le> f x - f y"
   991       using res by auto
   992   qed
   993   show ?thesis
   994   proof (cases "x = y")
   995     case True
   996     with x y show ?thesis by auto
   997   next
   998     case False
   999     with less_imp x y show ?thesis
  1000       by (auto simp: neq_iff)
  1001   qed
  1002 qed
  1003 
  1004 lemma f''_ge0_imp_convex:
  1005   fixes f :: "real \<Rightarrow> real"
  1006   assumes conv: "convex C"
  1007     and f': "\<And>x. x \<in> C \<Longrightarrow> DERIV f x :> (f' x)"
  1008     and f'': "\<And>x. x \<in> C \<Longrightarrow> DERIV f' x :> (f'' x)"
  1009     and pos: "\<And>x. x \<in> C \<Longrightarrow> f'' x \<ge> 0"
  1010   shows "convex_on C f"
  1011   using f''_imp_f'[OF conv f' f'' pos] assms pos_convex_function
  1012   by fastforce
  1013 
  1014 lemma minus_log_convex:
  1015   fixes b :: real
  1016   assumes "b > 1"
  1017   shows "convex_on {0 <..} (\<lambda> x. - log b x)"
  1018 proof -
  1019   have "\<And>z. z > 0 \<Longrightarrow> DERIV (log b) z :> 1 / (ln b * z)"
  1020     using DERIV_log by auto
  1021   then have f': "\<And>z. z > 0 \<Longrightarrow> DERIV (\<lambda> z. - log b z) z :> - 1 / (ln b * z)"
  1022     by (auto simp: DERIV_minus)
  1023   have "\<And>z::real. z > 0 \<Longrightarrow> DERIV inverse z :> - (inverse z ^ Suc (Suc 0))"
  1024     using less_imp_neq[THEN not_sym, THEN DERIV_inverse] by auto
  1025   from this[THEN DERIV_cmult, of _ "- 1 / ln b"]
  1026   have "\<And>z::real. z > 0 \<Longrightarrow>
  1027     DERIV (\<lambda> z. (- 1 / ln b) * inverse z) z :> (- 1 / ln b) * (- (inverse z ^ Suc (Suc 0)))"
  1028     by auto
  1029   then have f''0: "\<And>z::real. z > 0 \<Longrightarrow>
  1030     DERIV (\<lambda> z. - 1 / (ln b * z)) z :> 1 / (ln b * z * z)"
  1031     unfolding inverse_eq_divide by (auto simp: mult.assoc)
  1032   have f''_ge0: "\<And>z::real. z > 0 \<Longrightarrow> 1 / (ln b * z * z) \<ge> 0"
  1033     using \<open>b > 1\<close> by (auto intro!: less_imp_le)
  1034   from f''_ge0_imp_convex[OF pos_is_convex, unfolded greaterThan_iff, OF f' f''0 f''_ge0]
  1035   show ?thesis
  1036     by auto
  1037 qed
  1038 
  1039 
  1040 subsection%unimportant \<open>Convexity of real functions\<close>
  1041 
  1042 lemma convex_on_realI:
  1043   assumes "connected A"
  1044     and "\<And>x. x \<in> A \<Longrightarrow> (f has_real_derivative f' x) (at x)"
  1045     and "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> x \<le> y \<Longrightarrow> f' x \<le> f' y"
  1046   shows "convex_on A f"
  1047 proof (rule convex_on_linorderI)
  1048   fix t x y :: real
  1049   assume t: "t > 0" "t < 1"
  1050   assume xy: "x \<in> A" "y \<in> A" "x < y"
  1051   define z where "z = (1 - t) * x + t * y"
  1052   with \<open>connected A\<close> and xy have ivl: "{x..y} \<subseteq> A"
  1053     using connected_contains_Icc by blast
  1054 
  1055   from xy t have xz: "z > x"
  1056     by (simp add: z_def algebra_simps)
  1057   have "y - z = (1 - t) * (y - x)"
  1058     by (simp add: z_def algebra_simps)
  1059   also from xy t have "\<dots> > 0"
  1060     by (intro mult_pos_pos) simp_all
  1061   finally have yz: "z < y"
  1062     by simp
  1063 
  1064   from assms xz yz ivl t have "\<exists>\<xi>. \<xi> > x \<and> \<xi> < z \<and> f z - f x = (z - x) * f' \<xi>"
  1065     by (intro MVT2) (auto intro!: assms(2))
  1066   then obtain \<xi> where \<xi>: "\<xi> > x" "\<xi> < z" "f' \<xi> = (f z - f x) / (z - x)"
  1067     by auto
  1068   from assms xz yz ivl t have "\<exists>\<eta>. \<eta> > z \<and> \<eta> < y \<and> f y - f z = (y - z) * f' \<eta>"
  1069     by (intro MVT2) (auto intro!: assms(2))
  1070   then obtain \<eta> where \<eta>: "\<eta> > z" "\<eta> < y" "f' \<eta> = (f y - f z) / (y - z)"
  1071     by auto
  1072 
  1073   from \<eta>(3) have "(f y - f z) / (y - z) = f' \<eta>" ..
  1074   also from \<xi> \<eta> ivl have "\<xi> \<in> A" "\<eta> \<in> A"
  1075     by auto
  1076   with \<xi> \<eta> have "f' \<eta> \<ge> f' \<xi>"
  1077     by (intro assms(3)) auto
  1078   also from \<xi>(3) have "f' \<xi> = (f z - f x) / (z - x)" .
  1079   finally have "(f y - f z) * (z - x) \<ge> (f z - f x) * (y - z)"
  1080     using xz yz by (simp add: field_simps)
  1081   also have "z - x = t * (y - x)"
  1082     by (simp add: z_def algebra_simps)
  1083   also have "y - z = (1 - t) * (y - x)"
  1084     by (simp add: z_def algebra_simps)
  1085   finally have "(f y - f z) * t \<ge> (f z - f x) * (1 - t)"
  1086     using xy by simp
  1087   then show "(1 - t) * f x + t * f y \<ge> f ((1 - t) *\<^sub>R x + t *\<^sub>R y)"
  1088     by (simp add: z_def algebra_simps)
  1089 qed
  1090 
  1091 lemma convex_on_inverse:
  1092   assumes "A \<subseteq> {0<..}"
  1093   shows "convex_on A (inverse :: real \<Rightarrow> real)"
  1094 proof (rule convex_on_subset[OF _ assms], intro convex_on_realI[of _ _ "\<lambda>x. -inverse (x^2)"])
  1095   fix u v :: real
  1096   assume "u \<in> {0<..}" "v \<in> {0<..}" "u \<le> v"
  1097   with assms show "-inverse (u^2) \<le> -inverse (v^2)"
  1098     by (intro le_imp_neg_le le_imp_inverse_le power_mono) (simp_all)
  1099 qed (insert assms, auto intro!: derivative_eq_intros simp: divide_simps power2_eq_square)
  1100 
  1101 lemma convex_onD_Icc':
  1102   assumes "convex_on {x..y} f" "c \<in> {x..y}"
  1103   defines "d \<equiv> y - x"
  1104   shows "f c \<le> (f y - f x) / d * (c - x) + f x"
  1105 proof (cases x y rule: linorder_cases)
  1106   case less
  1107   then have d: "d > 0"
  1108     by (simp add: d_def)
  1109   from assms(2) less have A: "0 \<le> (c - x) / d" "(c - x) / d \<le> 1"
  1110     by (simp_all add: d_def divide_simps)
  1111   have "f c = f (x + (c - x) * 1)"
  1112     by simp
  1113   also from less have "1 = ((y - x) / d)"
  1114     by (simp add: d_def)
  1115   also from d have "x + (c - x) * \<dots> = (1 - (c - x) / d) *\<^sub>R x + ((c - x) / d) *\<^sub>R y"
  1116     by (simp add: field_simps)
  1117   also have "f \<dots> \<le> (1 - (c - x) / d) * f x + (c - x) / d * f y"
  1118     using assms less by (intro convex_onD_Icc) simp_all
  1119   also from d have "\<dots> = (f y - f x) / d * (c - x) + f x"
  1120     by (simp add: field_simps)
  1121   finally show ?thesis .
  1122 qed (insert assms(2), simp_all)
  1123 
  1124 lemma convex_onD_Icc'':
  1125   assumes "convex_on {x..y} f" "c \<in> {x..y}"
  1126   defines "d \<equiv> y - x"
  1127   shows "f c \<le> (f x - f y) / d * (y - c) + f y"
  1128 proof (cases x y rule: linorder_cases)
  1129   case less
  1130   then have d: "d > 0"
  1131     by (simp add: d_def)
  1132   from assms(2) less have A: "0 \<le> (y - c) / d" "(y - c) / d \<le> 1"
  1133     by (simp_all add: d_def divide_simps)
  1134   have "f c = f (y - (y - c) * 1)"
  1135     by simp
  1136   also from less have "1 = ((y - x) / d)"
  1137     by (simp add: d_def)
  1138   also from d have "y - (y - c) * \<dots> = (1 - (1 - (y - c) / d)) *\<^sub>R x + (1 - (y - c) / d) *\<^sub>R y"
  1139     by (simp add: field_simps)
  1140   also have "f \<dots> \<le> (1 - (1 - (y - c) / d)) * f x + (1 - (y - c) / d) * f y"
  1141     using assms less by (intro convex_onD_Icc) (simp_all add: field_simps)
  1142   also from d have "\<dots> = (f x - f y) / d * (y - c) + f y"
  1143     by (simp add: field_simps)
  1144   finally show ?thesis .
  1145 qed (insert assms(2), simp_all)
  1146 
  1147 lemma convex_supp_sum:
  1148   assumes "convex S" and 1: "supp_sum u I = 1"
  1149       and "\<And>i. i \<in> I \<Longrightarrow> 0 \<le> u i \<and> (u i = 0 \<or> f i \<in> S)"
  1150     shows "supp_sum (\<lambda>i. u i *\<^sub>R f i) I \<in> S"
  1151 proof -
  1152   have fin: "finite {i \<in> I. u i \<noteq> 0}"
  1153     using 1 sum.infinite by (force simp: supp_sum_def support_on_def)
  1154   then have eq: "supp_sum (\<lambda>i. u i *\<^sub>R f i) I = sum (\<lambda>i. u i *\<^sub>R f i) {i \<in> I. u i \<noteq> 0}"
  1155     by (force intro: sum.mono_neutral_left simp: supp_sum_def support_on_def)
  1156   show ?thesis
  1157     apply (simp add: eq)
  1158     apply (rule convex_sum [OF fin \<open>convex S\<close>])
  1159     using 1 assms apply (auto simp: supp_sum_def support_on_def)
  1160     done
  1161 qed
  1162 
  1163 lemma convex_translation_eq [simp]: "convex ((\<lambda>x. a + x) ` s) \<longleftrightarrow> convex s"
  1164   by (metis convex_translation translation_galois)
  1165 
  1166 lemma convex_linear_image_eq [simp]:
  1167     fixes f :: "'a::real_vector \<Rightarrow> 'b::real_vector"
  1168     shows "\<lbrakk>linear f; inj f\<rbrakk> \<Longrightarrow> convex (f ` s) \<longleftrightarrow> convex s"
  1169     by (metis (no_types) convex_linear_image convex_linear_vimage inj_vimage_image_eq)
  1170 
  1171 lemma closure_bounded_linear_image_subset:
  1172   assumes f: "bounded_linear f"
  1173   shows "f ` closure S \<subseteq> closure (f ` S)"
  1174   using linear_continuous_on [OF f] closed_closure closure_subset
  1175   by (rule image_closure_subset)
  1176 
  1177 lemma closure_linear_image_subset:
  1178   fixes f :: "'m::euclidean_space \<Rightarrow> 'n::real_normed_vector"
  1179   assumes "linear f"
  1180   shows "f ` (closure S) \<subseteq> closure (f ` S)"
  1181   using assms unfolding linear_conv_bounded_linear
  1182   by (rule closure_bounded_linear_image_subset)
  1183 
  1184 lemma closed_injective_linear_image:
  1185     fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1186     assumes S: "closed S" and f: "linear f" "inj f"
  1187     shows "closed (f ` S)"
  1188 proof -
  1189   obtain g where g: "linear g" "g \<circ> f = id"
  1190     using linear_injective_left_inverse [OF f] by blast
  1191   then have confg: "continuous_on (range f) g"
  1192     using linear_continuous_on linear_conv_bounded_linear by blast
  1193   have [simp]: "g ` f ` S = S"
  1194     using g by (simp add: image_comp)
  1195   have cgf: "closed (g ` f ` S)"
  1196     by (simp add: \<open>g \<circ> f = id\<close> S image_comp)
  1197   have [simp]: "(range f \<inter> g -` S) = f ` S"
  1198     using g unfolding o_def id_def image_def by auto metis+
  1199   show ?thesis
  1200   proof (rule closedin_closed_trans [of "range f"])
  1201     show "closedin (subtopology euclidean (range f)) (f ` S)"
  1202       using continuous_closedin_preimage [OF confg cgf] by simp
  1203     show "closed (range f)"
  1204       apply (rule closed_injective_image_subspace)
  1205       using f apply (auto simp: linear_linear linear_injective_0)
  1206       done
  1207   qed
  1208 qed
  1209 
  1210 lemma closed_injective_linear_image_eq:
  1211     fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1212     assumes f: "linear f" "inj f"
  1213       shows "(closed(image f s) \<longleftrightarrow> closed s)"
  1214   by (metis closed_injective_linear_image closure_eq closure_linear_image_subset closure_subset_eq f(1) f(2) inj_image_subset_iff)
  1215 
  1216 lemma closure_injective_linear_image:
  1217     fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1218     shows "\<lbrakk>linear f; inj f\<rbrakk> \<Longrightarrow> f ` (closure S) = closure (f ` S)"
  1219   apply (rule subset_antisym)
  1220   apply (simp add: closure_linear_image_subset)
  1221   by (simp add: closure_minimal closed_injective_linear_image closure_subset image_mono)
  1222 
  1223 lemma closure_bounded_linear_image:
  1224     fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  1225     shows "\<lbrakk>linear f; bounded S\<rbrakk> \<Longrightarrow> f ` (closure S) = closure (f ` S)"
  1226   apply (rule subset_antisym, simp add: closure_linear_image_subset)
  1227   apply (rule closure_minimal, simp add: closure_subset image_mono)
  1228   by (meson bounded_closure closed_closure compact_continuous_image compact_eq_bounded_closed linear_continuous_on linear_conv_bounded_linear)
  1229 
  1230 lemma closure_scaleR:
  1231   fixes S :: "'a::real_normed_vector set"
  1232   shows "(( *\<^sub>R) c) ` (closure S) = closure ((( *\<^sub>R) c) ` S)"
  1233 proof
  1234   show "(( *\<^sub>R) c) ` (closure S) \<subseteq> closure ((( *\<^sub>R) c) ` S)"
  1235     using bounded_linear_scaleR_right
  1236     by (rule closure_bounded_linear_image_subset)
  1237   show "closure ((( *\<^sub>R) c) ` S) \<subseteq> (( *\<^sub>R) c) ` (closure S)"
  1238     by (intro closure_minimal image_mono closure_subset closed_scaling closed_closure)
  1239 qed
  1240 
  1241 lemma fst_linear: "linear fst"
  1242   unfolding linear_iff by (simp add: algebra_simps)
  1243 
  1244 lemma snd_linear: "linear snd"
  1245   unfolding linear_iff by (simp add: algebra_simps)
  1246 
  1247 lemma fst_snd_linear: "linear (\<lambda>(x,y). x + y)"
  1248   unfolding linear_iff by (simp add: algebra_simps)
  1249 
  1250 lemma vector_choose_size:
  1251   assumes "0 \<le> c"
  1252   obtains x :: "'a::{real_normed_vector, perfect_space}" where "norm x = c"
  1253 proof -
  1254   obtain a::'a where "a \<noteq> 0"
  1255     using UNIV_not_singleton UNIV_eq_I set_zero singletonI by fastforce
  1256   then show ?thesis
  1257     by (rule_tac x="scaleR (c / norm a) a" in that) (simp add: assms)
  1258 qed
  1259 
  1260 lemma vector_choose_dist:
  1261   assumes "0 \<le> c"
  1262   obtains y :: "'a::{real_normed_vector, perfect_space}" where "dist x y = c"
  1263 by (metis add_diff_cancel_left' assms dist_commute dist_norm vector_choose_size)
  1264 
  1265 lemma sphere_eq_empty [simp]:
  1266   fixes a :: "'a::{real_normed_vector, perfect_space}"
  1267   shows "sphere a r = {} \<longleftrightarrow> r < 0"
  1268 by (auto simp: sphere_def dist_norm) (metis dist_norm le_less_linear vector_choose_dist)
  1269 
  1270 lemma sum_delta_notmem:
  1271   assumes "x \<notin> s"
  1272   shows "sum (\<lambda>y. if (y = x) then P x else Q y) s = sum Q s"
  1273     and "sum (\<lambda>y. if (x = y) then P x else Q y) s = sum Q s"
  1274     and "sum (\<lambda>y. if (y = x) then P y else Q y) s = sum Q s"
  1275     and "sum (\<lambda>y. if (x = y) then P y else Q y) s = sum Q s"
  1276   apply (rule_tac [!] sum.cong)
  1277   using assms
  1278   apply auto
  1279   done
  1280 
  1281 lemma sum_delta'':
  1282   fixes s::"'a::real_vector set"
  1283   assumes "finite s"
  1284   shows "(\<Sum>x\<in>s. (if y = x then f x else 0) *\<^sub>R x) = (if y\<in>s then (f y) *\<^sub>R y else 0)"
  1285 proof -
  1286   have *: "\<And>x y. (if y = x then f x else (0::real)) *\<^sub>R x = (if x=y then (f x) *\<^sub>R x else 0)"
  1287     by auto
  1288   show ?thesis
  1289     unfolding * using sum.delta[OF assms, of y "\<lambda>x. f x *\<^sub>R x"] by auto
  1290 qed
  1291 
  1292 lemma if_smult: "(if P then x else (y::real)) *\<^sub>R v = (if P then x *\<^sub>R v else y *\<^sub>R v)"
  1293   by (fact if_distrib)
  1294 
  1295 lemma dist_triangle_eq:
  1296   fixes x y z :: "'a::real_inner"
  1297   shows "dist x z = dist x y + dist y z \<longleftrightarrow>
  1298     norm (x - y) *\<^sub>R (y - z) = norm (y - z) *\<^sub>R (x - y)"
  1299 proof -
  1300   have *: "x - y + (y - z) = x - z" by auto
  1301   show ?thesis unfolding dist_norm norm_triangle_eq[of "x - y" "y - z", unfolded *]
  1302     by (auto simp:norm_minus_commute)
  1303 qed
  1304 
  1305 
  1306 subsection \<open>Affine set and affine hull\<close>
  1307 
  1308 definition%important affine :: "'a::real_vector set \<Rightarrow> bool"
  1309   where "affine s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u v. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s)"
  1310 
  1311 lemma affine_alt: "affine s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u::real. (1 - u) *\<^sub>R x + u *\<^sub>R y \<in> s)"
  1312   unfolding affine_def by (metis eq_diff_eq')
  1313 
  1314 lemma affine_empty [iff]: "affine {}"
  1315   unfolding affine_def by auto
  1316 
  1317 lemma affine_sing [iff]: "affine {x}"
  1318   unfolding affine_alt by (auto simp: scaleR_left_distrib [symmetric])
  1319 
  1320 lemma affine_UNIV [iff]: "affine UNIV"
  1321   unfolding affine_def by auto
  1322 
  1323 lemma affine_Inter [intro]: "(\<And>s. s\<in>f \<Longrightarrow> affine s) \<Longrightarrow> affine (\<Inter>f)"
  1324   unfolding affine_def by auto
  1325 
  1326 lemma affine_Int[intro]: "affine s \<Longrightarrow> affine t \<Longrightarrow> affine (s \<inter> t)"
  1327   unfolding affine_def by auto
  1328 
  1329 lemma affine_scaling: "affine s \<Longrightarrow> affine (image (\<lambda>x. c *\<^sub>R x) s)"
  1330   apply (clarsimp simp add: affine_def)
  1331   apply (rule_tac x="u *\<^sub>R x + v *\<^sub>R y" in image_eqI)
  1332   apply (auto simp: algebra_simps)
  1333   done
  1334 
  1335 lemma affine_affine_hull [simp]: "affine(affine hull s)"
  1336   unfolding hull_def
  1337   using affine_Inter[of "{t. affine t \<and> s \<subseteq> t}"] by auto
  1338 
  1339 lemma affine_hull_eq[simp]: "(affine hull s = s) \<longleftrightarrow> affine s"
  1340   by (metis affine_affine_hull hull_same)
  1341 
  1342 lemma affine_hyperplane: "affine {x. a \<bullet> x = b}"
  1343   by (simp add: affine_def algebra_simps) (metis distrib_right mult.left_neutral)
  1344 
  1345 
  1346 subsubsection%unimportant \<open>Some explicit formulations (from Lars Schewe)\<close>
  1347 
  1348 lemma affine:
  1349   fixes V::"'a::real_vector set"
  1350   shows "affine V \<longleftrightarrow>
  1351          (\<forall>S u. finite S \<and> S \<noteq> {} \<and> S \<subseteq> V \<and> sum u S = 1 \<longrightarrow> (\<Sum>x\<in>S. u x *\<^sub>R x) \<in> V)"
  1352 proof -
  1353   have "u *\<^sub>R x + v *\<^sub>R y \<in> V" if "x \<in> V" "y \<in> V" "u + v = (1::real)"
  1354     and *: "\<And>S u. \<lbrakk>finite S; S \<noteq> {}; S \<subseteq> V; sum u S = 1\<rbrakk> \<Longrightarrow> (\<Sum>x\<in>S. u x *\<^sub>R x) \<in> V" for x y u v
  1355   proof (cases "x = y")
  1356     case True
  1357     then show ?thesis
  1358       using that by (metis scaleR_add_left scaleR_one)
  1359   next
  1360     case False
  1361     then show ?thesis
  1362       using that *[of "{x,y}" "\<lambda>w. if w = x then u else v"] by auto
  1363   qed
  1364   moreover have "(\<Sum>x\<in>S. u x *\<^sub>R x) \<in> V"
  1365                 if *: "\<And>x y u v. \<lbrakk>x\<in>V; y\<in>V; u + v = 1\<rbrakk> \<Longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> V"
  1366                   and "finite S" "S \<noteq> {}" "S \<subseteq> V" "sum u S = 1" for S u
  1367   proof -
  1368     define n where "n = card S"
  1369     consider "card S = 0" | "card S = 1" | "card S = 2" | "card S > 2" by linarith
  1370     then show "(\<Sum>x\<in>S. u x *\<^sub>R x) \<in> V"
  1371     proof cases
  1372       assume "card S = 1"
  1373       then obtain a where "S={a}"
  1374         by (auto simp: card_Suc_eq)
  1375       then show ?thesis
  1376         using that by simp
  1377     next
  1378       assume "card S = 2"
  1379       then obtain a b where "S = {a, b}"
  1380         by (metis Suc_1 card_1_singletonE card_Suc_eq)
  1381       then show ?thesis
  1382         using *[of a b] that
  1383         by (auto simp: sum_clauses(2))
  1384     next
  1385       assume "card S > 2"
  1386       then show ?thesis using that n_def
  1387       proof (induct n arbitrary: u S)
  1388         case 0
  1389         then show ?case by auto
  1390       next
  1391         case (Suc n u S)
  1392         have "sum u S = card S" if "\<not> (\<exists>x\<in>S. u x \<noteq> 1)"
  1393           using that unfolding card_eq_sum by auto
  1394         with Suc.prems obtain x where "x \<in> S" and x: "u x \<noteq> 1" by force
  1395         have c: "card (S - {x}) = card S - 1"
  1396           by (simp add: Suc.prems(3) \<open>x \<in> S\<close>)
  1397         have "sum u (S - {x}) = 1 - u x"
  1398           by (simp add: Suc.prems sum_diff1_ring \<open>x \<in> S\<close>)
  1399         with x have eq1: "inverse (1 - u x) * sum u (S - {x}) = 1"
  1400           by auto
  1401         have inV: "(\<Sum>y\<in>S - {x}. (inverse (1 - u x) * u y) *\<^sub>R y) \<in> V"
  1402         proof (cases "card (S - {x}) > 2")
  1403           case True
  1404           then have S: "S - {x} \<noteq> {}" "card (S - {x}) = n"
  1405             using Suc.prems c by force+
  1406           show ?thesis
  1407           proof (rule Suc.hyps)
  1408             show "(\<Sum>a\<in>S - {x}. inverse (1 - u x) * u a) = 1"
  1409               by (auto simp: eq1 sum_distrib_left[symmetric])
  1410           qed (use S Suc.prems True in auto)
  1411         next
  1412           case False
  1413           then have "card (S - {x}) = Suc (Suc 0)"
  1414             using Suc.prems c by auto
  1415           then obtain a b where ab: "(S - {x}) = {a, b}" "a\<noteq>b"
  1416             unfolding card_Suc_eq by auto
  1417           then show ?thesis
  1418             using eq1 \<open>S \<subseteq> V\<close>
  1419             by (auto simp: sum_distrib_left distrib_left intro!: Suc.prems(2)[of a b])
  1420         qed
  1421         have "u x + (1 - u x) = 1 \<Longrightarrow>
  1422           u x *\<^sub>R x + (1 - u x) *\<^sub>R ((\<Sum>y\<in>S - {x}. u y *\<^sub>R y) /\<^sub>R (1 - u x)) \<in> V"
  1423           by (rule Suc.prems) (use \<open>x \<in> S\<close> Suc.prems inV in \<open>auto simp: scaleR_right.sum\<close>)
  1424         moreover have "(\<Sum>a\<in>S. u a *\<^sub>R a) = u x *\<^sub>R x + (\<Sum>a\<in>S - {x}. u a *\<^sub>R a)"
  1425           by (meson Suc.prems(3) sum.remove \<open>x \<in> S\<close>)
  1426         ultimately show "(\<Sum>x\<in>S. u x *\<^sub>R x) \<in> V"
  1427           by (simp add: x)
  1428       qed
  1429     qed (use \<open>S\<noteq>{}\<close> \<open>finite S\<close> in auto)
  1430   qed
  1431   ultimately show ?thesis
  1432     unfolding affine_def by meson
  1433 qed
  1434 
  1435 
  1436 lemma affine_hull_explicit:
  1437   "affine hull p = {y. \<exists>S u. finite S \<and> S \<noteq> {} \<and> S \<subseteq> p \<and> sum u S = 1 \<and> sum (\<lambda>v. u v *\<^sub>R v) S = y}"
  1438   (is "_ = ?rhs")
  1439 proof (rule hull_unique)
  1440   show "p \<subseteq> ?rhs"
  1441   proof (intro subsetI CollectI exI conjI)
  1442     show "\<And>x. sum (\<lambda>z. 1) {x} = 1"
  1443       by auto
  1444   qed auto
  1445   show "?rhs \<subseteq> T" if "p \<subseteq> T" "affine T" for T
  1446     using that unfolding affine by blast
  1447   show "affine ?rhs"
  1448     unfolding affine_def
  1449   proof clarify
  1450     fix u v :: real and sx ux sy uy
  1451     assume uv: "u + v = 1"
  1452       and x: "finite sx" "sx \<noteq> {}" "sx \<subseteq> p" "sum ux sx = (1::real)"
  1453       and y: "finite sy" "sy \<noteq> {}" "sy \<subseteq> p" "sum uy sy = (1::real)" 
  1454     have **: "(sx \<union> sy) \<inter> sx = sx" "(sx \<union> sy) \<inter> sy = sy"
  1455       by auto
  1456     show "\<exists>S w. finite S \<and> S \<noteq> {} \<and> S \<subseteq> p \<and>
  1457         sum w S = 1 \<and> (\<Sum>v\<in>S. w v *\<^sub>R v) = u *\<^sub>R (\<Sum>v\<in>sx. ux v *\<^sub>R v) + v *\<^sub>R (\<Sum>v\<in>sy. uy v *\<^sub>R v)"
  1458     proof (intro exI conjI)
  1459       show "finite (sx \<union> sy)"
  1460         using x y by auto
  1461       show "sum (\<lambda>i. (if i\<in>sx then u * ux i else 0) + (if i\<in>sy then v * uy i else 0)) (sx \<union> sy) = 1"
  1462         using x y uv
  1463         by (simp add: sum_Un sum.distrib sum.inter_restrict[symmetric] sum_distrib_left [symmetric] **)
  1464       have "(\<Sum>i\<in>sx \<union> sy. ((if i \<in> sx then u * ux i else 0) + (if i \<in> sy then v * uy i else 0)) *\<^sub>R i)
  1465           = (\<Sum>i\<in>sx. (u * ux i) *\<^sub>R i) + (\<Sum>i\<in>sy. (v * uy i) *\<^sub>R i)"
  1466         using x y
  1467         unfolding scaleR_left_distrib scaleR_zero_left if_smult
  1468         by (simp add: sum_Un sum.distrib sum.inter_restrict[symmetric]  **)
  1469       also have "\<dots> = u *\<^sub>R (\<Sum>v\<in>sx. ux v *\<^sub>R v) + v *\<^sub>R (\<Sum>v\<in>sy. uy v *\<^sub>R v)"
  1470         unfolding scaleR_scaleR[symmetric] scaleR_right.sum [symmetric] by blast
  1471       finally show "(\<Sum>i\<in>sx \<union> sy. ((if i \<in> sx then u * ux i else 0) + (if i \<in> sy then v * uy i else 0)) *\<^sub>R i) 
  1472                   = u *\<^sub>R (\<Sum>v\<in>sx. ux v *\<^sub>R v) + v *\<^sub>R (\<Sum>v\<in>sy. uy v *\<^sub>R v)" .
  1473     qed (use x y in auto)
  1474   qed
  1475 qed
  1476 
  1477 lemma affine_hull_finite:
  1478   assumes "finite S"
  1479   shows "affine hull S = {y. \<exists>u. sum u S = 1 \<and> sum (\<lambda>v. u v *\<^sub>R v) S = y}"
  1480 proof -
  1481   have *: "\<exists>h. sum h S = 1 \<and> (\<Sum>v\<in>S. h v *\<^sub>R v) = x" 
  1482     if "F \<subseteq> S" "finite F" "F \<noteq> {}" and sum: "sum u F = 1" and x: "(\<Sum>v\<in>F. u v *\<^sub>R v) = x" for x F u
  1483   proof -
  1484     have "S \<inter> F = F"
  1485       using that by auto
  1486     show ?thesis
  1487     proof (intro exI conjI)
  1488       show "(\<Sum>x\<in>S. if x \<in> F then u x else 0) = 1"
  1489         by (metis (mono_tags, lifting) \<open>S \<inter> F = F\<close> assms sum.inter_restrict sum)
  1490       show "(\<Sum>v\<in>S. (if v \<in> F then u v else 0) *\<^sub>R v) = x"
  1491         by (simp add: if_smult cong: if_cong) (metis (no_types) \<open>S \<inter> F = F\<close> assms sum.inter_restrict x)
  1492     qed
  1493   qed
  1494   show ?thesis
  1495     unfolding affine_hull_explicit using assms
  1496     by (fastforce dest: *)
  1497 qed
  1498 
  1499 
  1500 subsubsection%unimportant \<open>Stepping theorems and hence small special cases\<close>
  1501 
  1502 lemma affine_hull_empty[simp]: "affine hull {} = {}"
  1503   by simp
  1504 
  1505 lemma affine_hull_finite_step:
  1506   fixes y :: "'a::real_vector"
  1507   shows "finite S \<Longrightarrow>
  1508       (\<exists>u. sum u (insert a S) = w \<and> sum (\<lambda>x. u x *\<^sub>R x) (insert a S) = y) \<longleftrightarrow>
  1509       (\<exists>v u. sum u S = w - v \<and> sum (\<lambda>x. u x *\<^sub>R x) S = y - v *\<^sub>R a)" (is "_ \<Longrightarrow> ?lhs = ?rhs")
  1510 proof -
  1511   assume fin: "finite S"
  1512   show "?lhs = ?rhs"
  1513   proof
  1514     assume ?lhs
  1515     then obtain u where u: "sum u (insert a S) = w \<and> (\<Sum>x\<in>insert a S. u x *\<^sub>R x) = y"
  1516       by auto
  1517     show ?rhs
  1518     proof (cases "a \<in> S")
  1519       case True
  1520       then show ?thesis
  1521         using u by (simp add: insert_absorb) (metis diff_zero real_vector.scale_zero_left)
  1522     next
  1523       case False
  1524       show ?thesis
  1525         by (rule exI [where x="u a"]) (use u fin False in auto)
  1526     qed
  1527   next
  1528     assume ?rhs
  1529     then obtain v u where vu: "sum u S = w - v"  "(\<Sum>x\<in>S. u x *\<^sub>R x) = y - v *\<^sub>R a"
  1530       by auto
  1531     have *: "\<And>x M. (if x = a then v else M) *\<^sub>R x = (if x = a then v *\<^sub>R x else M *\<^sub>R x)"
  1532       by auto
  1533     show ?lhs
  1534     proof (cases "a \<in> S")
  1535       case True
  1536       show ?thesis
  1537         by (rule exI [where x="\<lambda>x. (if x=a then v else 0) + u x"])
  1538            (simp add: True scaleR_left_distrib sum.distrib sum_clauses fin vu * cong: if_cong)
  1539     next
  1540       case False
  1541       then show ?thesis
  1542         apply (rule_tac x="\<lambda>x. if x=a then v else u x" in exI) 
  1543         apply (simp add: vu sum_clauses(2)[OF fin] *)
  1544         by (simp add: sum_delta_notmem(3) vu)
  1545     qed
  1546   qed
  1547 qed
  1548 
  1549 lemma affine_hull_2:
  1550   fixes a b :: "'a::real_vector"
  1551   shows "affine hull {a,b} = {u *\<^sub>R a + v *\<^sub>R b| u v. (u + v = 1)}"
  1552   (is "?lhs = ?rhs")
  1553 proof -
  1554   have *:
  1555     "\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::real)"
  1556     "\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::'a)" by auto
  1557   have "?lhs = {y. \<exists>u. sum u {a, b} = 1 \<and> (\<Sum>v\<in>{a, b}. u v *\<^sub>R v) = y}"
  1558     using affine_hull_finite[of "{a,b}"] by auto
  1559   also have "\<dots> = {y. \<exists>v u. u b = 1 - v \<and> u b *\<^sub>R b = y - v *\<^sub>R a}"
  1560     by (simp add: affine_hull_finite_step[of "{b}" a])
  1561   also have "\<dots> = ?rhs" unfolding * by auto
  1562   finally show ?thesis by auto
  1563 qed
  1564 
  1565 lemma affine_hull_3:
  1566   fixes a b c :: "'a::real_vector"
  1567   shows "affine hull {a,b,c} = { u *\<^sub>R a + v *\<^sub>R b + w *\<^sub>R c| u v w. u + v + w = 1}"
  1568 proof -
  1569   have *:
  1570     "\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::real)"
  1571     "\<And>x y z. z = x - y \<longleftrightarrow> y + z = (x::'a)" by auto
  1572   show ?thesis
  1573     apply (simp add: affine_hull_finite affine_hull_finite_step)
  1574     unfolding *
  1575     apply safe
  1576      apply (metis add.assoc)
  1577     apply (rule_tac x=u in exI, force)
  1578     done
  1579 qed
  1580 
  1581 lemma mem_affine:
  1582   assumes "affine S" "x \<in> S" "y \<in> S" "u + v = 1"
  1583   shows "u *\<^sub>R x + v *\<^sub>R y \<in> S"
  1584   using assms affine_def[of S] by auto
  1585 
  1586 lemma mem_affine_3:
  1587   assumes "affine S" "x \<in> S" "y \<in> S" "z \<in> S" "u + v + w = 1"
  1588   shows "u *\<^sub>R x + v *\<^sub>R y + w *\<^sub>R z \<in> S"
  1589 proof -
  1590   have "u *\<^sub>R x + v *\<^sub>R y + w *\<^sub>R z \<in> affine hull {x, y, z}"
  1591     using affine_hull_3[of x y z] assms by auto
  1592   moreover
  1593   have "affine hull {x, y, z} \<subseteq> affine hull S"
  1594     using hull_mono[of "{x, y, z}" "S"] assms by auto
  1595   moreover
  1596   have "affine hull S = S"
  1597     using assms affine_hull_eq[of S] by auto
  1598   ultimately show ?thesis by auto
  1599 qed
  1600 
  1601 lemma mem_affine_3_minus:
  1602   assumes "affine S" "x \<in> S" "y \<in> S" "z \<in> S"
  1603   shows "x + v *\<^sub>R (y-z) \<in> S"
  1604   using mem_affine_3[of S x y z 1 v "-v"] assms
  1605   by (simp add: algebra_simps)
  1606 
  1607 corollary mem_affine_3_minus2:
  1608     "\<lbrakk>affine S; x \<in> S; y \<in> S; z \<in> S\<rbrakk> \<Longrightarrow> x - v *\<^sub>R (y-z) \<in> S"
  1609   by (metis add_uminus_conv_diff mem_affine_3_minus real_vector.scale_minus_left)
  1610 
  1611 
  1612 subsubsection%unimportant \<open>Some relations between affine hull and subspaces\<close>
  1613 
  1614 lemma affine_hull_insert_subset_span:
  1615   "affine hull (insert a S) \<subseteq> {a + v| v . v \<in> span {x - a | x . x \<in> S}}"
  1616 proof -
  1617   have "\<exists>v T u. x = a + v \<and> (finite T \<and> T \<subseteq> {x - a |x. x \<in> S} \<and> (\<Sum>v\<in>T. u v *\<^sub>R v) = v)"
  1618     if "finite F" "F \<noteq> {}" "F \<subseteq> insert a S" "sum u F = 1" "(\<Sum>v\<in>F. u v *\<^sub>R v) = x"
  1619     for x F u
  1620   proof -
  1621     have *: "(\<lambda>x. x - a) ` (F - {a}) \<subseteq> {x - a |x. x \<in> S}"
  1622       using that by auto
  1623     show ?thesis
  1624     proof (intro exI conjI)
  1625       show "finite ((\<lambda>x. x - a) ` (F - {a}))"
  1626         by (simp add: that(1))
  1627       show "(\<Sum>v\<in>(\<lambda>x. x - a) ` (F - {a}). u(v+a) *\<^sub>R v) = x-a"
  1628         by (simp add: sum.reindex[unfolded inj_on_def] algebra_simps
  1629             sum_subtractf scaleR_left.sum[symmetric] sum_diff1 that)
  1630     qed (use \<open>F \<subseteq> insert a S\<close> in auto)
  1631   qed
  1632   then show ?thesis
  1633     unfolding affine_hull_explicit span_explicit by blast
  1634 qed
  1635 
  1636 lemma affine_hull_insert_span:
  1637   assumes "a \<notin> S"
  1638   shows "affine hull (insert a S) = {a + v | v . v \<in> span {x - a | x.  x \<in> S}}"
  1639 proof -
  1640   have *: "\<exists>G u. finite G \<and> G \<noteq> {} \<and> G \<subseteq> insert a S \<and> sum u G = 1 \<and> (\<Sum>v\<in>G. u v *\<^sub>R v) = y"
  1641     if "v \<in> span {x - a |x. x \<in> S}" "y = a + v" for y v
  1642   proof -
  1643     from that
  1644     obtain T u where u: "finite T" "T \<subseteq> {x - a |x. x \<in> S}" "a + (\<Sum>v\<in>T. u v *\<^sub>R v) = y"
  1645       unfolding span_explicit by auto
  1646     define F where "F = (\<lambda>x. x + a) ` T"
  1647     have F: "finite F" "F \<subseteq> S" "(\<Sum>v\<in>F. u (v - a) *\<^sub>R (v - a)) = y - a"
  1648       unfolding F_def using u by (auto simp: sum.reindex[unfolded inj_on_def])
  1649     have *: "F \<inter> {a} = {}" "F \<inter> - {a} = F"
  1650       using F assms by auto
  1651     show "\<exists>G u. finite G \<and> G \<noteq> {} \<and> G \<subseteq> insert a S \<and> sum u G = 1 \<and> (\<Sum>v\<in>G. u v *\<^sub>R v) = y"
  1652       apply (rule_tac x = "insert a F" in exI)
  1653       apply (rule_tac x = "\<lambda>x. if x=a then 1 - sum (\<lambda>x. u (x - a)) F else u (x - a)" in exI)
  1654       using assms F
  1655       apply (auto simp:  sum_clauses sum.If_cases if_smult sum_subtractf scaleR_left.sum algebra_simps *)
  1656       done
  1657   qed
  1658   show ?thesis
  1659     by (intro subset_antisym affine_hull_insert_subset_span) (auto simp: affine_hull_explicit dest!: *)
  1660 qed
  1661 
  1662 lemma affine_hull_span:
  1663   assumes "a \<in> S"
  1664   shows "affine hull S = {a + v | v. v \<in> span {x - a | x. x \<in> S - {a}}}"
  1665   using affine_hull_insert_span[of a "S - {a}", unfolded insert_Diff[OF assms]] by auto
  1666 
  1667 
  1668 subsubsection%unimportant \<open>Parallel affine sets\<close>
  1669 
  1670 definition affine_parallel :: "'a::real_vector set \<Rightarrow> 'a::real_vector set \<Rightarrow> bool"
  1671   where "affine_parallel S T \<longleftrightarrow> (\<exists>a. T = (\<lambda>x. a + x) ` S)"
  1672 
  1673 lemma affine_parallel_expl_aux:
  1674   fixes S T :: "'a::real_vector set"
  1675   assumes "\<And>x. x \<in> S \<longleftrightarrow> a + x \<in> T"
  1676   shows "T = (\<lambda>x. a + x) ` S"
  1677 proof -
  1678   have "x \<in> ((\<lambda>x. a + x) ` S)" if "x \<in> T" for x
  1679     using that
  1680     by (simp add: image_iff) (metis add.commute diff_add_cancel assms)
  1681   moreover have "T \<ge> (\<lambda>x. a + x) ` S"
  1682     using assms by auto
  1683   ultimately show ?thesis by auto
  1684 qed
  1685 
  1686 lemma affine_parallel_expl: "affine_parallel S T \<longleftrightarrow> (\<exists>a. \<forall>x. x \<in> S \<longleftrightarrow> a + x \<in> T)"
  1687   unfolding affine_parallel_def
  1688   using affine_parallel_expl_aux[of S _ T] by auto
  1689 
  1690 lemma affine_parallel_reflex: "affine_parallel S S"
  1691   unfolding affine_parallel_def
  1692   using image_add_0 by blast
  1693 
  1694 lemma affine_parallel_commut:
  1695   assumes "affine_parallel A B"
  1696   shows "affine_parallel B A"
  1697 proof -
  1698   from assms obtain a where B: "B = (\<lambda>x. a + x) ` A"
  1699     unfolding affine_parallel_def by auto
  1700   have [simp]: "(\<lambda>x. x - a) = plus (- a)" by (simp add: fun_eq_iff)
  1701   from B show ?thesis
  1702     using translation_galois [of B a A]
  1703     unfolding affine_parallel_def by auto
  1704 qed
  1705 
  1706 lemma affine_parallel_assoc:
  1707   assumes "affine_parallel A B"
  1708     and "affine_parallel B C"
  1709   shows "affine_parallel A C"
  1710 proof -
  1711   from assms obtain ab where "B = (\<lambda>x. ab + x) ` A"
  1712     unfolding affine_parallel_def by auto
  1713   moreover
  1714   from assms obtain bc where "C = (\<lambda>x. bc + x) ` B"
  1715     unfolding affine_parallel_def by auto
  1716   ultimately show ?thesis
  1717     using translation_assoc[of bc ab A] unfolding affine_parallel_def by auto
  1718 qed
  1719 
  1720 lemma affine_translation_aux:
  1721   fixes a :: "'a::real_vector"
  1722   assumes "affine ((\<lambda>x. a + x) ` S)"
  1723   shows "affine S"
  1724 proof -
  1725   {
  1726     fix x y u v
  1727     assume xy: "x \<in> S" "y \<in> S" "(u :: real) + v = 1"
  1728     then have "(a + x) \<in> ((\<lambda>x. a + x) ` S)" "(a + y) \<in> ((\<lambda>x. a + x) ` S)"
  1729       by auto
  1730     then have h1: "u *\<^sub>R  (a + x) + v *\<^sub>R (a + y) \<in> (\<lambda>x. a + x) ` S"
  1731       using xy assms unfolding affine_def by auto
  1732     have "u *\<^sub>R (a + x) + v *\<^sub>R (a + y) = (u + v) *\<^sub>R a + (u *\<^sub>R x + v *\<^sub>R y)"
  1733       by (simp add: algebra_simps)
  1734     also have "\<dots> = a + (u *\<^sub>R x + v *\<^sub>R y)"
  1735       using \<open>u + v = 1\<close> by auto
  1736     ultimately have "a + (u *\<^sub>R x + v *\<^sub>R y) \<in> (\<lambda>x. a + x) ` S"
  1737       using h1 by auto
  1738     then have "u *\<^sub>R x + v *\<^sub>R y \<in> S" by auto
  1739   }
  1740   then show ?thesis unfolding affine_def by auto
  1741 qed
  1742 
  1743 lemma affine_translation:
  1744   fixes a :: "'a::real_vector"
  1745   shows "affine S \<longleftrightarrow> affine ((\<lambda>x. a + x) ` S)"
  1746 proof -
  1747   have "affine S \<Longrightarrow> affine ((\<lambda>x. a + x) ` S)"
  1748     using affine_translation_aux[of "-a" "((\<lambda>x. a + x) ` S)"]
  1749     using translation_assoc[of "-a" a S] by auto
  1750   then show ?thesis using affine_translation_aux by auto
  1751 qed
  1752 
  1753 lemma parallel_is_affine:
  1754   fixes S T :: "'a::real_vector set"
  1755   assumes "affine S" "affine_parallel S T"
  1756   shows "affine T"
  1757 proof -
  1758   from assms obtain a where "T = (\<lambda>x. a + x) ` S"
  1759     unfolding affine_parallel_def by auto
  1760   then show ?thesis
  1761     using affine_translation assms by auto
  1762 qed
  1763 
  1764 lemma subspace_imp_affine: "subspace s \<Longrightarrow> affine s"
  1765   unfolding subspace_def affine_def by auto
  1766 
  1767 
  1768 subsubsection%unimportant \<open>Subspace parallel to an affine set\<close>
  1769 
  1770 lemma subspace_affine: "subspace S \<longleftrightarrow> affine S \<and> 0 \<in> S"
  1771 proof -
  1772   have h0: "subspace S \<Longrightarrow> affine S \<and> 0 \<in> S"
  1773     using subspace_imp_affine[of S] subspace_0 by auto
  1774   {
  1775     assume assm: "affine S \<and> 0 \<in> S"
  1776     {
  1777       fix c :: real
  1778       fix x
  1779       assume x: "x \<in> S"
  1780       have "c *\<^sub>R x = (1-c) *\<^sub>R 0 + c *\<^sub>R x" by auto
  1781       moreover
  1782       have "(1 - c) *\<^sub>R 0 + c *\<^sub>R x \<in> S"
  1783         using affine_alt[of S] assm x by auto
  1784       ultimately have "c *\<^sub>R x \<in> S" by auto
  1785     }
  1786     then have h1: "\<forall>c. \<forall>x \<in> S. c *\<^sub>R x \<in> S" by auto
  1787 
  1788     {
  1789       fix x y
  1790       assume xy: "x \<in> S" "y \<in> S"
  1791       define u where "u = (1 :: real)/2"
  1792       have "(1/2) *\<^sub>R (x+y) = (1/2) *\<^sub>R (x+y)"
  1793         by auto
  1794       moreover
  1795       have "(1/2) *\<^sub>R (x+y)=(1/2) *\<^sub>R x + (1-(1/2)) *\<^sub>R y"
  1796         by (simp add: algebra_simps)
  1797       moreover
  1798       have "(1 - u) *\<^sub>R x + u *\<^sub>R y \<in> S"
  1799         using affine_alt[of S] assm xy by auto
  1800       ultimately
  1801       have "(1/2) *\<^sub>R (x+y) \<in> S"
  1802         using u_def by auto
  1803       moreover
  1804       have "x + y = 2 *\<^sub>R ((1/2) *\<^sub>R (x+y))"
  1805         by auto
  1806       ultimately
  1807       have "x + y \<in> S"
  1808         using h1[rule_format, of "(1/2) *\<^sub>R (x+y)" "2"] by auto
  1809     }
  1810     then have "\<forall>x \<in> S. \<forall>y \<in> S. x + y \<in> S"
  1811       by auto
  1812     then have "subspace S"
  1813       using h1 assm unfolding subspace_def by auto
  1814   }
  1815   then show ?thesis using h0 by metis
  1816 qed
  1817 
  1818 lemma affine_diffs_subspace:
  1819   assumes "affine S" "a \<in> S"
  1820   shows "subspace ((\<lambda>x. (-a)+x) ` S)"
  1821 proof -
  1822   have [simp]: "(\<lambda>x. x - a) = plus (- a)" by (simp add: fun_eq_iff)
  1823   have "affine ((\<lambda>x. (-a)+x) ` S)"
  1824     using  affine_translation assms by auto
  1825   moreover have "0 \<in> ((\<lambda>x. (-a)+x) ` S)"
  1826     using assms exI[of "(\<lambda>x. x\<in>S \<and> -a+x = 0)" a] by auto
  1827   ultimately show ?thesis using subspace_affine by auto
  1828 qed
  1829 
  1830 lemma parallel_subspace_explicit:
  1831   assumes "affine S"
  1832     and "a \<in> S"
  1833   assumes "L \<equiv> {y. \<exists>x \<in> S. (-a) + x = y}"
  1834   shows "subspace L \<and> affine_parallel S L"
  1835 proof -
  1836   from assms have "L = plus (- a) ` S" by auto
  1837   then have par: "affine_parallel S L"
  1838     unfolding affine_parallel_def ..
  1839   then have "affine L" using assms parallel_is_affine by auto
  1840   moreover have "0 \<in> L"
  1841     using assms by auto
  1842   ultimately show ?thesis
  1843     using subspace_affine par by auto
  1844 qed
  1845 
  1846 lemma parallel_subspace_aux:
  1847   assumes "subspace A"
  1848     and "subspace B"
  1849     and "affine_parallel A B"
  1850   shows "A \<supseteq> B"
  1851 proof -
  1852   from assms obtain a where a: "\<forall>x. x \<in> A \<longleftrightarrow> a + x \<in> B"
  1853     using affine_parallel_expl[of A B] by auto
  1854   then have "-a \<in> A"
  1855     using assms subspace_0[of B] by auto
  1856   then have "a \<in> A"
  1857     using assms subspace_neg[of A "-a"] by auto
  1858   then show ?thesis
  1859     using assms a unfolding subspace_def by auto
  1860 qed
  1861 
  1862 lemma parallel_subspace:
  1863   assumes "subspace A"
  1864     and "subspace B"
  1865     and "affine_parallel A B"
  1866   shows "A = B"
  1867 proof
  1868   show "A \<supseteq> B"
  1869     using assms parallel_subspace_aux by auto
  1870   show "A \<subseteq> B"
  1871     using assms parallel_subspace_aux[of B A] affine_parallel_commut by auto
  1872 qed
  1873 
  1874 lemma affine_parallel_subspace:
  1875   assumes "affine S" "S \<noteq> {}"
  1876   shows "\<exists>!L. subspace L \<and> affine_parallel S L"
  1877 proof -
  1878   have ex: "\<exists>L. subspace L \<and> affine_parallel S L"
  1879     using assms parallel_subspace_explicit by auto
  1880   {
  1881     fix L1 L2
  1882     assume ass: "subspace L1 \<and> affine_parallel S L1" "subspace L2 \<and> affine_parallel S L2"
  1883     then have "affine_parallel L1 L2"
  1884       using affine_parallel_commut[of S L1] affine_parallel_assoc[of L1 S L2] by auto
  1885     then have "L1 = L2"
  1886       using ass parallel_subspace by auto
  1887   }
  1888   then show ?thesis using ex by auto
  1889 qed
  1890 
  1891 
  1892 subsection \<open>Cones\<close>
  1893 
  1894 definition%important cone :: "'a::real_vector set \<Rightarrow> bool"
  1895   where "cone s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>c\<ge>0. c *\<^sub>R x \<in> s)"
  1896 
  1897 lemma cone_empty[intro, simp]: "cone {}"
  1898   unfolding cone_def by auto
  1899 
  1900 lemma cone_univ[intro, simp]: "cone UNIV"
  1901   unfolding cone_def by auto
  1902 
  1903 lemma cone_Inter[intro]: "\<forall>s\<in>f. cone s \<Longrightarrow> cone (\<Inter>f)"
  1904   unfolding cone_def by auto
  1905 
  1906 lemma subspace_imp_cone: "subspace S \<Longrightarrow> cone S"
  1907   by (simp add: cone_def subspace_scale)
  1908 
  1909 
  1910 subsubsection \<open>Conic hull\<close>
  1911 
  1912 lemma cone_cone_hull: "cone (cone hull s)"
  1913   unfolding hull_def by auto
  1914 
  1915 lemma cone_hull_eq: "cone hull s = s \<longleftrightarrow> cone s"
  1916   apply (rule hull_eq)
  1917   using cone_Inter
  1918   unfolding subset_eq
  1919   apply auto
  1920   done
  1921 
  1922 lemma mem_cone:
  1923   assumes "cone S" "x \<in> S" "c \<ge> 0"
  1924   shows "c *\<^sub>R x \<in> S"
  1925   using assms cone_def[of S] by auto
  1926 
  1927 lemma cone_contains_0:
  1928   assumes "cone S"
  1929   shows "S \<noteq> {} \<longleftrightarrow> 0 \<in> S"
  1930 proof -
  1931   {
  1932     assume "S \<noteq> {}"
  1933     then obtain a where "a \<in> S" by auto
  1934     then have "0 \<in> S"
  1935       using assms mem_cone[of S a 0] by auto
  1936   }
  1937   then show ?thesis by auto
  1938 qed
  1939 
  1940 lemma cone_0: "cone {0}"
  1941   unfolding cone_def by auto
  1942 
  1943 lemma cone_Union[intro]: "(\<forall>s\<in>f. cone s) \<longrightarrow> cone (\<Union>f)"
  1944   unfolding cone_def by blast
  1945 
  1946 lemma cone_iff:
  1947   assumes "S \<noteq> {}"
  1948   shows "cone S \<longleftrightarrow> 0 \<in> S \<and> (\<forall>c. c > 0 \<longrightarrow> (( *\<^sub>R) c) ` S = S)"
  1949 proof -
  1950   {
  1951     assume "cone S"
  1952     {
  1953       fix c :: real
  1954       assume "c > 0"
  1955       {
  1956         fix x
  1957         assume "x \<in> S"
  1958         then have "x \<in> (( *\<^sub>R) c) ` S"
  1959           unfolding image_def
  1960           using \<open>cone S\<close> \<open>c>0\<close> mem_cone[of S x "1/c"]
  1961             exI[of "(\<lambda>t. t \<in> S \<and> x = c *\<^sub>R t)" "(1 / c) *\<^sub>R x"]
  1962           by auto
  1963       }
  1964       moreover
  1965       {
  1966         fix x
  1967         assume "x \<in> (( *\<^sub>R) c) ` S"
  1968         then have "x \<in> S"
  1969           using \<open>cone S\<close> \<open>c > 0\<close>
  1970           unfolding cone_def image_def \<open>c > 0\<close> by auto
  1971       }
  1972       ultimately have "(( *\<^sub>R) c) ` S = S" by auto
  1973     }
  1974     then have "0 \<in> S \<and> (\<forall>c. c > 0 \<longrightarrow> (( *\<^sub>R) c) ` S = S)"
  1975       using \<open>cone S\<close> cone_contains_0[of S] assms by auto
  1976   }
  1977   moreover
  1978   {
  1979     assume a: "0 \<in> S \<and> (\<forall>c. c > 0 \<longrightarrow> (( *\<^sub>R) c) ` S = S)"
  1980     {
  1981       fix x
  1982       assume "x \<in> S"
  1983       fix c1 :: real
  1984       assume "c1 \<ge> 0"
  1985       then have "c1 = 0 \<or> c1 > 0" by auto
  1986       then have "c1 *\<^sub>R x \<in> S" using a \<open>x \<in> S\<close> by auto
  1987     }
  1988     then have "cone S" unfolding cone_def by auto
  1989   }
  1990   ultimately show ?thesis by blast
  1991 qed
  1992 
  1993 lemma cone_hull_empty: "cone hull {} = {}"
  1994   by (metis cone_empty cone_hull_eq)
  1995 
  1996 lemma cone_hull_empty_iff: "S = {} \<longleftrightarrow> cone hull S = {}"
  1997   by (metis bot_least cone_hull_empty hull_subset xtrans(5))
  1998 
  1999 lemma cone_hull_contains_0: "S \<noteq> {} \<longleftrightarrow> 0 \<in> cone hull S"
  2000   using cone_cone_hull[of S] cone_contains_0[of "cone hull S"] cone_hull_empty_iff[of S]
  2001   by auto
  2002 
  2003 lemma mem_cone_hull:
  2004   assumes "x \<in> S" "c \<ge> 0"
  2005   shows "c *\<^sub>R x \<in> cone hull S"
  2006   by (metis assms cone_cone_hull hull_inc mem_cone)
  2007 
  2008 proposition cone_hull_expl: "cone hull S = {c *\<^sub>R x | c x. c \<ge> 0 \<and> x \<in> S}"
  2009   (is "?lhs = ?rhs")
  2010 proof -
  2011   {
  2012     fix x
  2013     assume "x \<in> ?rhs"
  2014     then obtain cx :: real and xx where x: "x = cx *\<^sub>R xx" "cx \<ge> 0" "xx \<in> S"
  2015       by auto
  2016     fix c :: real
  2017     assume c: "c \<ge> 0"
  2018     then have "c *\<^sub>R x = (c * cx) *\<^sub>R xx"
  2019       using x by (simp add: algebra_simps)
  2020     moreover
  2021     have "c * cx \<ge> 0" using c x by auto
  2022     ultimately
  2023     have "c *\<^sub>R x \<in> ?rhs" using x by auto
  2024   }
  2025   then have "cone ?rhs"
  2026     unfolding cone_def by auto
  2027   then have "?rhs \<in> Collect cone"
  2028     unfolding mem_Collect_eq by auto
  2029   {
  2030     fix x
  2031     assume "x \<in> S"
  2032     then have "1 *\<^sub>R x \<in> ?rhs"
  2033       apply auto
  2034       apply (rule_tac x = 1 in exI, auto)
  2035       done
  2036     then have "x \<in> ?rhs" by auto
  2037   }
  2038   then have "S \<subseteq> ?rhs" by auto
  2039   then have "?lhs \<subseteq> ?rhs"
  2040     using \<open>?rhs \<in> Collect cone\<close> hull_minimal[of S "?rhs" "cone"] by auto
  2041   moreover
  2042   {
  2043     fix x
  2044     assume "x \<in> ?rhs"
  2045     then obtain cx :: real and xx where x: "x = cx *\<^sub>R xx" "cx \<ge> 0" "xx \<in> S"
  2046       by auto
  2047     then have "xx \<in> cone hull S"
  2048       using hull_subset[of S] by auto
  2049     then have "x \<in> ?lhs"
  2050       using x cone_cone_hull[of S] cone_def[of "cone hull S"] by auto
  2051   }
  2052   ultimately show ?thesis by auto
  2053 qed
  2054 
  2055 lemma cone_closure:
  2056   fixes S :: "'a::real_normed_vector set"
  2057   assumes "cone S"
  2058   shows "cone (closure S)"
  2059 proof (cases "S = {}")
  2060   case True
  2061   then show ?thesis by auto
  2062 next
  2063   case False
  2064   then have "0 \<in> S \<and> (\<forall>c. c > 0 \<longrightarrow> ( *\<^sub>R) c ` S = S)"
  2065     using cone_iff[of S] assms by auto
  2066   then have "0 \<in> closure S \<and> (\<forall>c. c > 0 \<longrightarrow> ( *\<^sub>R) c ` closure S = closure S)"
  2067     using closure_subset by (auto simp: closure_scaleR)
  2068   then show ?thesis
  2069     using False cone_iff[of "closure S"] by auto
  2070 qed
  2071 
  2072 
  2073 subsection \<open>Affine dependence and consequential theorems (from Lars Schewe)\<close>
  2074 
  2075 definition%important affine_dependent :: "'a::real_vector set \<Rightarrow> bool"
  2076   where "affine_dependent s \<longleftrightarrow> (\<exists>x\<in>s. x \<in> affine hull (s - {x}))"
  2077 
  2078 lemma affine_dependent_subset:
  2079    "\<lbrakk>affine_dependent s; s \<subseteq> t\<rbrakk> \<Longrightarrow> affine_dependent t"
  2080 apply (simp add: affine_dependent_def Bex_def)
  2081 apply (blast dest: hull_mono [OF Diff_mono [OF _ subset_refl]])
  2082 done
  2083 
  2084 lemma affine_independent_subset:
  2085   shows "\<lbrakk>~ affine_dependent t; s \<subseteq> t\<rbrakk> \<Longrightarrow> ~ affine_dependent s"
  2086 by (metis affine_dependent_subset)
  2087 
  2088 lemma affine_independent_Diff:
  2089    "~ affine_dependent s \<Longrightarrow> ~ affine_dependent(s - t)"
  2090 by (meson Diff_subset affine_dependent_subset)
  2091 
  2092 proposition affine_dependent_explicit:
  2093   "affine_dependent p \<longleftrightarrow>
  2094     (\<exists>S u. finite S \<and> S \<subseteq> p \<and> sum u S = 0 \<and> (\<exists>v\<in>S. u v \<noteq> 0) \<and> sum (\<lambda>v. u v *\<^sub>R v) S = 0)"
  2095 proof -
  2096   have "\<exists>S u. finite S \<and> S \<subseteq> p \<and> sum u S = 0 \<and> (\<exists>v\<in>S. u v \<noteq> 0) \<and> (\<Sum>w\<in>S. u w *\<^sub>R w) = 0"
  2097     if "(\<Sum>w\<in>S. u w *\<^sub>R w) = x" "x \<in> p" "finite S" "S \<noteq> {}" "S \<subseteq> p - {x}" "sum u S = 1" for x S u
  2098   proof (intro exI conjI)
  2099     have "x \<notin> S" 
  2100       using that by auto
  2101     then show "(\<Sum>v \<in> insert x S. if v = x then - 1 else u v) = 0"
  2102       using that by (simp add: sum_delta_notmem)
  2103     show "(\<Sum>w \<in> insert x S. (if w = x then - 1 else u w) *\<^sub>R w) = 0"
  2104       using that \<open>x \<notin> S\<close> by (simp add: if_smult sum_delta_notmem cong: if_cong)
  2105   qed (use that in auto)
  2106   moreover have "\<exists>x\<in>p. \<exists>S u. finite S \<and> S \<noteq> {} \<and> S \<subseteq> p - {x} \<and> sum u S = 1 \<and> (\<Sum>v\<in>S. u v *\<^sub>R v) = x"
  2107     if "(\<Sum>v\<in>S. u v *\<^sub>R v) = 0" "finite S" "S \<subseteq> p" "sum u S = 0" "v \<in> S" "u v \<noteq> 0" for S u v
  2108   proof (intro bexI exI conjI)
  2109     have "S \<noteq> {v}"
  2110       using that by auto
  2111     then show "S - {v} \<noteq> {}"
  2112       using that by auto
  2113     show "(\<Sum>x \<in> S - {v}. - (1 / u v) * u x) = 1"
  2114       unfolding sum_distrib_left[symmetric] sum_diff1[OF \<open>finite S\<close>] by (simp add: that)
  2115     show "(\<Sum>x\<in>S - {v}. (- (1 / u v) * u x) *\<^sub>R x) = v"
  2116       unfolding sum_distrib_left [symmetric] scaleR_scaleR[symmetric]
  2117                 scaleR_right.sum [symmetric] sum_diff1[OF \<open>finite S\<close>] 
  2118       using that by auto
  2119     show "S - {v} \<subseteq> p - {v}"
  2120       using that by auto
  2121   qed (use that in auto)
  2122   ultimately show ?thesis
  2123     unfolding affine_dependent_def affine_hull_explicit by auto
  2124 qed
  2125 
  2126 lemma affine_dependent_explicit_finite:
  2127   fixes S :: "'a::real_vector set"
  2128   assumes "finite S"
  2129   shows "affine_dependent S \<longleftrightarrow>
  2130     (\<exists>u. sum u S = 0 \<and> (\<exists>v\<in>S. u v \<noteq> 0) \<and> sum (\<lambda>v. u v *\<^sub>R v) S = 0)"
  2131   (is "?lhs = ?rhs")
  2132 proof
  2133   have *: "\<And>vt u v. (if vt then u v else 0) *\<^sub>R v = (if vt then (u v) *\<^sub>R v else 0::'a)"
  2134     by auto
  2135   assume ?lhs
  2136   then obtain t u v where
  2137     "finite t" "t \<subseteq> S" "sum u t = 0" "v\<in>t" "u v \<noteq> 0"  "(\<Sum>v\<in>t. u v *\<^sub>R v) = 0"
  2138     unfolding affine_dependent_explicit by auto
  2139   then show ?rhs
  2140     apply (rule_tac x="\<lambda>x. if x\<in>t then u x else 0" in exI)
  2141     apply (auto simp: * sum.inter_restrict[OF assms, symmetric] Int_absorb1[OF \<open>t\<subseteq>S\<close>])
  2142     done
  2143 next
  2144   assume ?rhs
  2145   then obtain u v where "sum u S = 0"  "v\<in>S" "u v \<noteq> 0" "(\<Sum>v\<in>S. u v *\<^sub>R v) = 0"
  2146     by auto
  2147   then show ?lhs unfolding affine_dependent_explicit
  2148     using assms by auto
  2149 qed
  2150 
  2151 
  2152 subsection%unimportant \<open>Connectedness of convex sets\<close>
  2153 
  2154 lemma connectedD:
  2155   "connected S \<Longrightarrow> open A \<Longrightarrow> open B \<Longrightarrow> S \<subseteq> A \<union> B \<Longrightarrow> A \<inter> B \<inter> S = {} \<Longrightarrow> A \<inter> S = {} \<or> B \<inter> S = {}"
  2156   by (rule Topological_Spaces.topological_space_class.connectedD)
  2157 
  2158 lemma convex_connected:
  2159   fixes S :: "'a::real_normed_vector set"
  2160   assumes "convex S"
  2161   shows "connected S"
  2162 proof (rule connectedI)
  2163   fix A B
  2164   assume "open A" "open B" "A \<inter> B \<inter> S = {}" "S \<subseteq> A \<union> B"
  2165   moreover
  2166   assume "A \<inter> S \<noteq> {}" "B \<inter> S \<noteq> {}"
  2167   then obtain a b where a: "a \<in> A" "a \<in> S" and b: "b \<in> B" "b \<in> S" by auto
  2168   define f where [abs_def]: "f u = u *\<^sub>R a + (1 - u) *\<^sub>R b" for u
  2169   then have "continuous_on {0 .. 1} f"
  2170     by (auto intro!: continuous_intros)
  2171   then have "connected (f ` {0 .. 1})"
  2172     by (auto intro!: connected_continuous_image)
  2173   note connectedD[OF this, of A B]
  2174   moreover have "a \<in> A \<inter> f ` {0 .. 1}"
  2175     using a by (auto intro!: image_eqI[of _ _ 1] simp: f_def)
  2176   moreover have "b \<in> B \<inter> f ` {0 .. 1}"
  2177     using b by (auto intro!: image_eqI[of _ _ 0] simp: f_def)
  2178   moreover have "f ` {0 .. 1} \<subseteq> S"
  2179     using \<open>convex S\<close> a b unfolding convex_def f_def by auto
  2180   ultimately show False by auto
  2181 qed
  2182 
  2183 corollary connected_UNIV[intro]: "connected (UNIV :: 'a::real_normed_vector set)"
  2184   by (simp add: convex_connected)
  2185 
  2186 corollary component_complement_connected:
  2187   fixes S :: "'a::real_normed_vector set"
  2188   assumes "connected S" "C \<in> components (-S)"
  2189   shows "connected(-C)"
  2190   using component_diff_connected [of S UNIV] assms
  2191   by (auto simp: Compl_eq_Diff_UNIV)
  2192 
  2193 proposition clopen:
  2194   fixes S :: "'a :: real_normed_vector set"
  2195   shows "closed S \<and> open S \<longleftrightarrow> S = {} \<or> S = UNIV"
  2196     by (force intro!: connected_UNIV [unfolded connected_clopen, rule_format])
  2197 
  2198 corollary compact_open:
  2199   fixes S :: "'a :: euclidean_space set"
  2200   shows "compact S \<and> open S \<longleftrightarrow> S = {}"
  2201   by (auto simp: compact_eq_bounded_closed clopen)
  2202 
  2203 corollary finite_imp_not_open:
  2204     fixes S :: "'a::{real_normed_vector, perfect_space} set"
  2205     shows "\<lbrakk>finite S; open S\<rbrakk> \<Longrightarrow> S={}"
  2206   using clopen [of S] finite_imp_closed not_bounded_UNIV by blast
  2207 
  2208 corollary empty_interior_finite:
  2209     fixes S :: "'a::{real_normed_vector, perfect_space} set"
  2210     shows "finite S \<Longrightarrow> interior S = {}"
  2211   by (metis interior_subset finite_subset open_interior [of S] finite_imp_not_open)
  2212 
  2213 text \<open>Balls, being convex, are connected.\<close>
  2214 
  2215 lemma convex_prod:
  2216   assumes "\<And>i. i \<in> Basis \<Longrightarrow> convex {x. P i x}"
  2217   shows "convex {x. \<forall>i\<in>Basis. P i (x\<bullet>i)}"
  2218   using assms unfolding convex_def
  2219   by (auto simp: inner_add_left)
  2220 
  2221 lemma convex_positive_orthant: "convex {x::'a::euclidean_space. (\<forall>i\<in>Basis. 0 \<le> x\<bullet>i)}"
  2222   by (rule convex_prod) (simp add: atLeast_def[symmetric] convex_real_interval)
  2223 
  2224 lemma convex_local_global_minimum:
  2225   fixes s :: "'a::real_normed_vector set"
  2226   assumes "e > 0"
  2227     and "convex_on s f"
  2228     and "ball x e \<subseteq> s"
  2229     and "\<forall>y\<in>ball x e. f x \<le> f y"
  2230   shows "\<forall>y\<in>s. f x \<le> f y"
  2231 proof (rule ccontr)
  2232   have "x \<in> s" using assms(1,3) by auto
  2233   assume "\<not> ?thesis"
  2234   then obtain y where "y\<in>s" and y: "f x > f y" by auto
  2235   then have xy: "0 < dist x y"  by auto
  2236   then obtain u where "0 < u" "u \<le> 1" and u: "u < e / dist x y"
  2237     using field_lbound_gt_zero[of 1 "e / dist x y"] xy \<open>e>0\<close> by auto
  2238   then have "f ((1-u) *\<^sub>R x + u *\<^sub>R y) \<le> (1-u) * f x + u * f y"
  2239     using \<open>x\<in>s\<close> \<open>y\<in>s\<close>
  2240     using assms(2)[unfolded convex_on_def,
  2241       THEN bspec[where x=x], THEN bspec[where x=y], THEN spec[where x="1-u"]]
  2242     by auto
  2243   moreover
  2244   have *: "x - ((1 - u) *\<^sub>R x + u *\<^sub>R y) = u *\<^sub>R (x - y)"
  2245     by (simp add: algebra_simps)
  2246   have "(1 - u) *\<^sub>R x + u *\<^sub>R y \<in> ball x e"
  2247     unfolding mem_ball dist_norm
  2248     unfolding * and norm_scaleR and abs_of_pos[OF \<open>0<u\<close>]
  2249     unfolding dist_norm[symmetric]
  2250     using u
  2251     unfolding pos_less_divide_eq[OF xy]
  2252     by auto
  2253   then have "f x \<le> f ((1 - u) *\<^sub>R x + u *\<^sub>R y)"
  2254     using assms(4) by auto
  2255   ultimately show False
  2256     using mult_strict_left_mono[OF y \<open>u>0\<close>]
  2257     unfolding left_diff_distrib
  2258     by auto
  2259 qed
  2260 
  2261 lemma convex_ball [iff]:
  2262   fixes x :: "'a::real_normed_vector"
  2263   shows "convex (ball x e)"
  2264 proof (auto simp: convex_def)
  2265   fix y z
  2266   assume yz: "dist x y < e" "dist x z < e"
  2267   fix u v :: real
  2268   assume uv: "0 \<le> u" "0 \<le> v" "u + v = 1"
  2269   have "dist x (u *\<^sub>R y + v *\<^sub>R z) \<le> u * dist x y + v * dist x z"
  2270     using uv yz
  2271     using convex_on_dist [of "ball x e" x, unfolded convex_on_def,
  2272       THEN bspec[where x=y], THEN bspec[where x=z]]
  2273     by auto
  2274   then show "dist x (u *\<^sub>R y + v *\<^sub>R z) < e"
  2275     using convex_bound_lt[OF yz uv] by auto
  2276 qed
  2277 
  2278 lemma convex_cball [iff]:
  2279   fixes x :: "'a::real_normed_vector"
  2280   shows "convex (cball x e)"
  2281 proof -
  2282   {
  2283     fix y z
  2284     assume yz: "dist x y \<le> e" "dist x z \<le> e"
  2285     fix u v :: real
  2286     assume uv: "0 \<le> u" "0 \<le> v" "u + v = 1"
  2287     have "dist x (u *\<^sub>R y + v *\<^sub>R z) \<le> u * dist x y + v * dist x z"
  2288       using uv yz
  2289       using convex_on_dist [of "cball x e" x, unfolded convex_on_def,
  2290         THEN bspec[where x=y], THEN bspec[where x=z]]
  2291       by auto
  2292     then have "dist x (u *\<^sub>R y + v *\<^sub>R z) \<le> e"
  2293       using convex_bound_le[OF yz uv] by auto
  2294   }
  2295   then show ?thesis by (auto simp: convex_def Ball_def)
  2296 qed
  2297 
  2298 lemma connected_ball [iff]:
  2299   fixes x :: "'a::real_normed_vector"
  2300   shows "connected (ball x e)"
  2301   using convex_connected convex_ball by auto
  2302 
  2303 lemma connected_cball [iff]:
  2304   fixes x :: "'a::real_normed_vector"
  2305   shows "connected (cball x e)"
  2306   using convex_connected convex_cball by auto
  2307 
  2308 
  2309 subsection \<open>Convex hull\<close>
  2310 
  2311 lemma convex_convex_hull [iff]: "convex (convex hull s)"
  2312   unfolding hull_def
  2313   using convex_Inter[of "{t. convex t \<and> s \<subseteq> t}"]
  2314   by auto
  2315 
  2316 lemma convex_hull_subset:
  2317     "s \<subseteq> convex hull t \<Longrightarrow> convex hull s \<subseteq> convex hull t"
  2318   by (simp add: convex_convex_hull subset_hull)
  2319 
  2320 lemma convex_hull_eq: "convex hull s = s \<longleftrightarrow> convex s"
  2321   by (metis convex_convex_hull hull_same)
  2322 
  2323 lemma bounded_convex_hull:
  2324   fixes s :: "'a::real_normed_vector set"
  2325   assumes "bounded s"
  2326   shows "bounded (convex hull s)"
  2327 proof -
  2328   from assms obtain B where B: "\<forall>x\<in>s. norm x \<le> B"
  2329     unfolding bounded_iff by auto
  2330   show ?thesis
  2331     apply (rule bounded_subset[OF bounded_cball, of _ 0 B])
  2332     unfolding subset_hull[of convex, OF convex_cball]
  2333     unfolding subset_eq mem_cball dist_norm using B
  2334     apply auto
  2335     done
  2336 qed
  2337 
  2338 lemma finite_imp_bounded_convex_hull:
  2339   fixes s :: "'a::real_normed_vector set"
  2340   shows "finite s \<Longrightarrow> bounded (convex hull s)"
  2341   using bounded_convex_hull finite_imp_bounded
  2342   by auto
  2343 
  2344 
  2345 subsubsection%unimportant \<open>Convex hull is "preserved" by a linear function\<close>
  2346 
  2347 lemma convex_hull_linear_image:
  2348   assumes f: "linear f"
  2349   shows "f ` (convex hull s) = convex hull (f ` s)"
  2350 proof
  2351   show "convex hull (f ` s) \<subseteq> f ` (convex hull s)"
  2352     by (intro hull_minimal image_mono hull_subset convex_linear_image assms convex_convex_hull)
  2353   show "f ` (convex hull s) \<subseteq> convex hull (f ` s)"
  2354   proof (unfold image_subset_iff_subset_vimage, rule hull_minimal)
  2355     show "s \<subseteq> f -` (convex hull (f ` s))"
  2356       by (fast intro: hull_inc)
  2357     show "convex (f -` (convex hull (f ` s)))"
  2358       by (intro convex_linear_vimage [OF f] convex_convex_hull)
  2359   qed
  2360 qed
  2361 
  2362 lemma in_convex_hull_linear_image:
  2363   assumes "linear f"
  2364     and "x \<in> convex hull s"
  2365   shows "f x \<in> convex hull (f ` s)"
  2366   using convex_hull_linear_image[OF assms(1)] assms(2) by auto
  2367 
  2368 lemma convex_hull_Times:
  2369   "convex hull (s \<times> t) = (convex hull s) \<times> (convex hull t)"
  2370 proof
  2371   show "convex hull (s \<times> t) \<subseteq> (convex hull s) \<times> (convex hull t)"
  2372     by (intro hull_minimal Sigma_mono hull_subset convex_Times convex_convex_hull)
  2373   have "(x, y) \<in> convex hull (s \<times> t)" if x: "x \<in> convex hull s" and y: "y \<in> convex hull t" for x y
  2374   proof (rule hull_induct [OF x], rule hull_induct [OF y])
  2375     fix x y assume "x \<in> s" and "y \<in> t"
  2376     then show "(x, y) \<in> convex hull (s \<times> t)"
  2377       by (simp add: hull_inc)
  2378   next
  2379     fix x let ?S = "((\<lambda>y. (0, y)) -` (\<lambda>p. (- x, 0) + p) ` (convex hull s \<times> t))"
  2380     have "convex ?S"
  2381       by (intro convex_linear_vimage convex_translation convex_convex_hull,
  2382         simp add: linear_iff)
  2383     also have "?S = {y. (x, y) \<in> convex hull (s \<times> t)}"
  2384       by (auto simp: image_def Bex_def)
  2385     finally show "convex {y. (x, y) \<in> convex hull (s \<times> t)}" .
  2386   next
  2387     show "convex {x. (x, y) \<in> convex hull s \<times> t}"
  2388     proof -
  2389       fix y let ?S = "((\<lambda>x. (x, 0)) -` (\<lambda>p. (0, - y) + p) ` (convex hull s \<times> t))"
  2390       have "convex ?S"
  2391       by (intro convex_linear_vimage convex_translation convex_convex_hull,
  2392         simp add: linear_iff)
  2393       also have "?S = {x. (x, y) \<in> convex hull (s \<times> t)}"
  2394         by (auto simp: image_def Bex_def)
  2395       finally show "convex {x. (x, y) \<in> convex hull (s \<times> t)}" .
  2396     qed
  2397   qed
  2398   then show "(convex hull s) \<times> (convex hull t) \<subseteq> convex hull (s \<times> t)"
  2399     unfolding subset_eq split_paired_Ball_Sigma by blast
  2400 qed
  2401 
  2402 
  2403 subsubsection%unimportant \<open>Stepping theorems for convex hulls of finite sets\<close>
  2404 
  2405 lemma convex_hull_empty[simp]: "convex hull {} = {}"
  2406   by (rule hull_unique) auto
  2407 
  2408 lemma convex_hull_singleton[simp]: "convex hull {a} = {a}"
  2409   by (rule hull_unique) auto
  2410 
  2411 lemma convex_hull_insert:
  2412   fixes S :: "'a::real_vector set"
  2413   assumes "S \<noteq> {}"
  2414   shows "convex hull (insert a S) =
  2415          {x. \<exists>u\<ge>0. \<exists>v\<ge>0. \<exists>b. (u + v = 1) \<and> b \<in> (convex hull S) \<and> (x = u *\<^sub>R a + v *\<^sub>R b)}"
  2416   (is "_ = ?hull")
  2417 proof (intro equalityI hull_minimal subsetI)
  2418   fix x
  2419   assume "x \<in> insert a S"
  2420   then have "\<exists>u\<ge>0. \<exists>v\<ge>0. u + v = 1 \<and> (\<exists>b. b \<in> convex hull S \<and> x = u *\<^sub>R a + v *\<^sub>R b)"
  2421   unfolding insert_iff
  2422   proof
  2423     assume "x = a"
  2424     then show ?thesis
  2425       by (rule_tac x=1 in exI) (use assms hull_subset in fastforce)
  2426   next
  2427     assume "x \<in> S"
  2428     with hull_subset[of S convex] show ?thesis
  2429       by force
  2430   qed
  2431   then show "x \<in> ?hull"
  2432     by simp
  2433 next
  2434   fix x
  2435   assume "x \<in> ?hull"
  2436   then obtain u v b where obt: "u\<ge>0" "v\<ge>0" "u + v = 1" "b \<in> convex hull S" "x = u *\<^sub>R a + v *\<^sub>R b"
  2437     by auto
  2438   have "a \<in> convex hull insert a S" "b \<in> convex hull insert a S"
  2439     using hull_mono[of S "insert a S" convex] hull_mono[of "{a}" "insert a S" convex] and obt(4)
  2440     by auto
  2441   then show "x \<in> convex hull insert a S"
  2442     unfolding obt(5) using obt(1-3)
  2443     by (rule convexD [OF convex_convex_hull])
  2444 next
  2445   show "convex ?hull"
  2446   proof (rule convexI)
  2447     fix x y u v
  2448     assume as: "(0::real) \<le> u" "0 \<le> v" "u + v = 1" and x: "x \<in> ?hull" and y: "y \<in> ?hull"
  2449     from x obtain u1 v1 b1 where
  2450       obt1: "u1\<ge>0" "v1\<ge>0" "u1 + v1 = 1" "b1 \<in> convex hull S" and xeq: "x = u1 *\<^sub>R a + v1 *\<^sub>R b1"
  2451       by auto
  2452     from y obtain u2 v2 b2 where
  2453       obt2: "u2\<ge>0" "v2\<ge>0" "u2 + v2 = 1" "b2 \<in> convex hull S" and yeq: "y = u2 *\<^sub>R a + v2 *\<^sub>R b2"
  2454       by auto
  2455     have *: "\<And>(x::'a) s1 s2. x - s1 *\<^sub>R x - s2 *\<^sub>R x = ((1::real) - (s1 + s2)) *\<^sub>R x"
  2456       by (auto simp: algebra_simps)
  2457     have "\<exists>b \<in> convex hull S. u *\<^sub>R x + v *\<^sub>R y =
  2458       (u * u1) *\<^sub>R a + (v * u2) *\<^sub>R a + (b - (u * u1) *\<^sub>R b - (v * u2) *\<^sub>R b)"
  2459     proof (cases "u * v1 + v * v2 = 0")
  2460       case True
  2461       have *: "\<And>(x::'a) s1 s2. x - s1 *\<^sub>R x - s2 *\<^sub>R x = ((1::real) - (s1 + s2)) *\<^sub>R x"
  2462         by (auto simp: algebra_simps)
  2463       have eq0: "u * v1 = 0" "v * v2 = 0"
  2464         using True mult_nonneg_nonneg[OF \<open>u\<ge>0\<close> \<open>v1\<ge>0\<close>] mult_nonneg_nonneg[OF \<open>v\<ge>0\<close> \<open>v2\<ge>0\<close>]
  2465         by arith+
  2466       then have "u * u1 + v * u2 = 1"
  2467         using as(3) obt1(3) obt2(3) by auto
  2468       then show ?thesis
  2469         using "*" eq0 as obt1(4) xeq yeq by auto
  2470     next
  2471       case False
  2472       have "1 - (u * u1 + v * u2) = (u + v) - (u * u1 + v * u2)"
  2473         using as(3) obt1(3) obt2(3) by (auto simp: field_simps)
  2474       also have "\<dots> = u * (v1 + u1 - u1) + v * (v2 + u2 - u2)"
  2475         using as(3) obt1(3) obt2(3) by (auto simp: field_simps)
  2476       also have "\<dots> = u * v1 + v * v2"
  2477         by simp
  2478       finally have **:"1 - (u * u1 + v * u2) = u * v1 + v * v2" by auto
  2479       let ?b = "((u * v1) / (u * v1 + v * v2)) *\<^sub>R b1 + ((v * v2) / (u * v1 + v * v2)) *\<^sub>R b2"
  2480       have zeroes: "0 \<le> u * v1 + v * v2" "0 \<le> u * v1" "0 \<le> u * v1 + v * v2" "0 \<le> v * v2"
  2481         using as(1,2) obt1(1,2) obt2(1,2) by auto
  2482       show ?thesis
  2483       proof
  2484         show "u *\<^sub>R x + v *\<^sub>R y = (u * u1) *\<^sub>R a + (v * u2) *\<^sub>R a + (?b - (u * u1) *\<^sub>R ?b - (v * u2) *\<^sub>R ?b)"
  2485           unfolding xeq yeq * **
  2486           using False by (auto simp: scaleR_left_distrib scaleR_right_distrib)
  2487         show "?b \<in> convex hull S"
  2488           using False zeroes obt1(4) obt2(4)
  2489           by (auto simp: convexD [OF convex_convex_hull] scaleR_left_distrib scaleR_right_distrib  add_divide_distrib[symmetric]  zero_le_divide_iff)
  2490       qed
  2491     qed
  2492     then obtain b where b: "b \<in> convex hull S" 
  2493        "u *\<^sub>R x + v *\<^sub>R y = (u * u1) *\<^sub>R a + (v * u2) *\<^sub>R a + (b - (u * u1) *\<^sub>R b - (v * u2) *\<^sub>R b)" ..
  2494 
  2495     have u1: "u1 \<le> 1"
  2496       unfolding obt1(3)[symmetric] and not_le using obt1(2) by auto
  2497     have u2: "u2 \<le> 1"
  2498       unfolding obt2(3)[symmetric] and not_le using obt2(2) by auto
  2499     have "u1 * u + u2 * v \<le> max u1 u2 * u + max u1 u2 * v"
  2500     proof (rule add_mono)
  2501       show "u1 * u \<le> max u1 u2 * u" "u2 * v \<le> max u1 u2 * v"
  2502         by (simp_all add: as mult_right_mono)
  2503     qed
  2504     also have "\<dots> \<le> 1"
  2505       unfolding distrib_left[symmetric] and as(3) using u1 u2 by auto
  2506     finally have le1: "u1 * u + u2 * v \<le> 1" .    
  2507     show "u *\<^sub>R x + v *\<^sub>R y \<in> ?hull"
  2508     proof (intro CollectI exI conjI)
  2509       show "0 \<le> u * u1 + v * u2"
  2510         by (simp add: as(1) as(2) obt1(1) obt2(1))
  2511       show "0 \<le> 1 - u * u1 - v * u2"
  2512         by (simp add: le1 diff_diff_add mult.commute)
  2513     qed (use b in \<open>auto simp: algebra_simps\<close>)
  2514   qed
  2515 qed
  2516 
  2517 lemma convex_hull_insert_alt:
  2518    "convex hull (insert a S) =
  2519      (if S = {} then {a}
  2520       else {(1 - u) *\<^sub>R a + u *\<^sub>R x |x u. 0 \<le> u \<and> u \<le> 1 \<and> x \<in> convex hull S})"
  2521   apply (auto simp: convex_hull_insert)
  2522   using diff_eq_eq apply fastforce
  2523   by (metis add.group_left_neutral add_le_imp_le_diff diff_add_cancel)
  2524 
  2525 subsubsection%unimportant \<open>Explicit expression for convex hull\<close>
  2526 
  2527 proposition convex_hull_indexed:
  2528   fixes S :: "'a::real_vector set"
  2529   shows "convex hull S =
  2530     {y. \<exists>k u x. (\<forall>i\<in>{1::nat .. k}. 0 \<le> u i \<and> x i \<in> S) \<and>
  2531                 (sum u {1..k} = 1) \<and> (\<Sum>i = 1..k. u i *\<^sub>R x i) = y}"
  2532     (is "?xyz = ?hull")
  2533 proof (rule hull_unique [OF _ convexI])
  2534   show "S \<subseteq> ?hull" 
  2535     by (clarsimp, rule_tac x=1 in exI, rule_tac x="\<lambda>x. 1" in exI, auto)
  2536 next
  2537   fix T
  2538   assume "S \<subseteq> T" "convex T"
  2539   then show "?hull \<subseteq> T"
  2540     by (blast intro: convex_sum)
  2541 next
  2542   fix x y u v
  2543   assume uv: "0 \<le> u" "0 \<le> v" "u + v = (1::real)"
  2544   assume xy: "x \<in> ?hull" "y \<in> ?hull"
  2545   from xy obtain k1 u1 x1 where
  2546     x [rule_format]: "\<forall>i\<in>{1::nat..k1}. 0\<le>u1 i \<and> x1 i \<in> S" 
  2547                       "sum u1 {Suc 0..k1} = 1" "(\<Sum>i = Suc 0..k1. u1 i *\<^sub>R x1 i) = x"
  2548     by auto
  2549   from xy obtain k2 u2 x2 where
  2550     y [rule_format]: "\<forall>i\<in>{1::nat..k2}. 0\<le>u2 i \<and> x2 i \<in> S" 
  2551                      "sum u2 {Suc 0..k2} = 1" "(\<Sum>i = Suc 0..k2. u2 i *\<^sub>R x2 i) = y"
  2552     by auto
  2553   have *: "\<And>P (x::'a) y s t i. (if P i then s else t) *\<^sub>R (if P i then x else y) = (if P i then s *\<^sub>R x else t *\<^sub>R y)"
  2554           "{1..k1 + k2} \<inter> {1..k1} = {1..k1}" "{1..k1 + k2} \<inter> - {1..k1} = (\<lambda>i. i + k1) ` {1..k2}"
  2555     by auto
  2556   have inj: "inj_on (\<lambda>i. i + k1) {1..k2}"
  2557     unfolding inj_on_def by auto
  2558   let ?uu = "\<lambda>i. if i \<in> {1..k1} then u * u1 i else v * u2 (i - k1)"
  2559   let ?xx = "\<lambda>i. if i \<in> {1..k1} then x1 i else x2 (i - k1)"
  2560   show "u *\<^sub>R x + v *\<^sub>R y \<in> ?hull"
  2561   proof (intro CollectI exI conjI ballI)
  2562     show "0 \<le> ?uu i" "?xx i \<in> S" if "i \<in> {1..k1+k2}" for i
  2563       using that by (auto simp add: le_diff_conv uv(1) x(1) uv(2) y(1))
  2564     show "(\<Sum>i = 1..k1 + k2. ?uu i) = 1"  "(\<Sum>i = 1..k1 + k2. ?uu i *\<^sub>R ?xx i) = u *\<^sub>R x + v *\<^sub>R y"
  2565       unfolding * sum.If_cases[OF finite_atLeastAtMost[of 1 "k1 + k2"]]
  2566         sum.reindex[OF inj] Collect_mem_eq o_def
  2567       unfolding scaleR_scaleR[symmetric] scaleR_right.sum [symmetric] sum_distrib_left[symmetric]
  2568       by (simp_all add: sum_distrib_left[symmetric]  x(2,3) y(2,3) uv(3))
  2569   qed 
  2570 qed
  2571 
  2572 lemma convex_hull_finite:
  2573   fixes S :: "'a::real_vector set"
  2574   assumes "finite S"
  2575   shows "convex hull S = {y. \<exists>u. (\<forall>x\<in>S. 0 \<le> u x) \<and> sum u S = 1 \<and> sum (\<lambda>x. u x *\<^sub>R x) S = y}"
  2576   (is "?HULL = _")
  2577 proof (rule hull_unique [OF _ convexI]; clarify)
  2578   fix x
  2579   assume "x \<in> S"
  2580   then show "\<exists>u. (\<forall>x\<in>S. 0 \<le> u x) \<and> sum u S = 1 \<and> (\<Sum>x\<in>S. u x *\<^sub>R x) = x"
  2581     by (rule_tac x="\<lambda>y. if x=y then 1 else 0" in exI) (auto simp: sum.delta'[OF assms] sum_delta''[OF assms])
  2582 next
  2583   fix u v :: real
  2584   assume uv: "0 \<le> u" "0 \<le> v" "u + v = 1"
  2585   fix ux assume ux [rule_format]: "\<forall>x\<in>S. 0 \<le> ux x" "sum ux S = (1::real)"
  2586   fix uy assume uy [rule_format]: "\<forall>x\<in>S. 0 \<le> uy x" "sum uy S = (1::real)"
  2587   have "0 \<le> u * ux x + v * uy x" if "x\<in>S" for x
  2588     by (simp add: that uv ux(1) uy(1))
  2589   moreover
  2590   have "(\<Sum>x\<in>S. u * ux x + v * uy x) = 1"
  2591     unfolding sum.distrib and sum_distrib_left[symmetric] ux(2) uy(2)
  2592     using uv(3) by auto
  2593   moreover
  2594   have "(\<Sum>x\<in>S. (u * ux x + v * uy x) *\<^sub>R x) = u *\<^sub>R (\<Sum>x\<in>S. ux x *\<^sub>R x) + v *\<^sub>R (\<Sum>x\<in>S. uy x *\<^sub>R x)"
  2595     unfolding scaleR_left_distrib sum.distrib scaleR_scaleR[symmetric] scaleR_right.sum [symmetric]
  2596     by auto
  2597   ultimately
  2598   show "\<exists>uc. (\<forall>x\<in>S. 0 \<le> uc x) \<and> sum uc S = 1 \<and>
  2599              (\<Sum>x\<in>S. uc x *\<^sub>R x) = u *\<^sub>R (\<Sum>x\<in>S. ux x *\<^sub>R x) + v *\<^sub>R (\<Sum>x\<in>S. uy x *\<^sub>R x)"
  2600     by (rule_tac x="\<lambda>x. u * ux x + v * uy x" in exI, auto)
  2601 qed (use assms in \<open>auto simp: convex_explicit\<close>)
  2602 
  2603 
  2604 subsubsection%unimportant \<open>Another formulation from Lars Schewe\<close>
  2605 
  2606 lemma convex_hull_explicit:
  2607   fixes p :: "'a::real_vector set"
  2608   shows "convex hull p =
  2609     {y. \<exists>S u. finite S \<and> S \<subseteq> p \<and> (\<forall>x\<in>S. 0 \<le> u x) \<and> sum u S = 1 \<and> sum (\<lambda>v. u v *\<^sub>R v) S = y}"
  2610   (is "?lhs = ?rhs")
  2611 proof -
  2612   {
  2613     fix x
  2614     assume "x\<in>?lhs"
  2615     then obtain k u y where
  2616         obt: "\<forall>i\<in>{1::nat..k}. 0 \<le> u i \<and> y i \<in> p" "sum u {1..k} = 1" "(\<Sum>i = 1..k. u i *\<^sub>R y i) = x"
  2617       unfolding convex_hull_indexed by auto
  2618 
  2619     have fin: "finite {1..k}" by auto
  2620     have fin': "\<And>v. finite {i \<in> {1..k}. y i = v}" by auto
  2621     {
  2622       fix j
  2623       assume "j\<in>{1..k}"
  2624       then have "y j \<in> p" "0 \<le> sum u {i. Suc 0 \<le> i \<and> i \<le> k \<and> y i = y j}"
  2625         using obt(1)[THEN bspec[where x=j]] and obt(2)
  2626         apply simp
  2627         apply (rule sum_nonneg)
  2628         using obt(1)
  2629         apply auto
  2630         done
  2631     }
  2632     moreover
  2633     have "(\<Sum>v\<in>y ` {1..k}. sum u {i \<in> {1..k}. y i = v}) = 1"
  2634       unfolding sum_image_gen[OF fin, symmetric] using obt(2) by auto
  2635     moreover have "(\<Sum>v\<in>y ` {1..k}. sum u {i \<in> {1..k}. y i = v} *\<^sub>R v) = x"
  2636       using sum_image_gen[OF fin, of "\<lambda>i. u i *\<^sub>R y i" y, symmetric]
  2637       unfolding scaleR_left.sum using obt(3) by auto
  2638     ultimately
  2639     have "\<exists>S u. finite S \<and> S \<subseteq> p \<and> (\<forall>x\<in>S. 0 \<le> u x) \<and> sum u S = 1 \<and> (\<Sum>v\<in>S. u v *\<^sub>R v) = x"
  2640       apply (rule_tac x="y ` {1..k}" in exI)
  2641       apply (rule_tac x="\<lambda>v. sum u {i\<in>{1..k}. y i = v}" in exI, auto)
  2642       done
  2643     then have "x\<in>?rhs" by auto
  2644   }
  2645   moreover
  2646   {
  2647     fix y
  2648     assume "y\<in>?rhs"
  2649     then obtain S u where
  2650       obt: "finite S" "S \<subseteq> p" "\<forall>x\<in>S. 0 \<le> u x" "sum u S = 1" "(\<Sum>v\<in>S. u v *\<^sub>R v) = y"
  2651       by auto
  2652 
  2653     obtain f where f: "inj_on f {1..card S}" "f ` {1..card S} = S"
  2654       using ex_bij_betw_nat_finite_1[OF obt(1)] unfolding bij_betw_def by auto
  2655 
  2656     {
  2657       fix i :: nat
  2658       assume "i\<in>{1..card S}"
  2659       then have "f i \<in> S"
  2660         using f(2) by blast
  2661       then have "0 \<le> u (f i)" "f i \<in> p" using obt(2,3) by auto
  2662     }
  2663     moreover have *: "finite {1..card S}" by auto
  2664     {
  2665       fix y
  2666       assume "y\<in>S"
  2667       then obtain i where "i\<in>{1..card S}" "f i = y"
  2668         using f using image_iff[of y f "{1..card S}"]
  2669         by auto
  2670       then have "{x. Suc 0 \<le> x \<and> x \<le> card S \<and> f x = y} = {i}"
  2671         apply auto
  2672         using f(1)[unfolded inj_on_def]
  2673         by (metis One_nat_def atLeastAtMost_iff)
  2674       then have "card {x. Suc 0 \<le> x \<and> x \<le> card S \<and> f x = y} = 1" by auto
  2675       then have "(\<Sum>x\<in>{x \<in> {1..card S}. f x = y}. u (f x)) = u y"
  2676           "(\<Sum>x\<in>{x \<in> {1..card S}. f x = y}. u (f x) *\<^sub>R f x) = u y *\<^sub>R y"
  2677         by (auto simp: sum_constant_scaleR)
  2678     }
  2679     then have "(\<Sum>x = 1..card S. u (f x)) = 1" "(\<Sum>i = 1..card S. u (f i) *\<^sub>R f i) = y"
  2680       unfolding sum_image_gen[OF *(1), of "\<lambda>x. u (f x) *\<^sub>R f x" f]
  2681         and sum_image_gen[OF *(1), of "\<lambda>x. u (f x)" f]
  2682       unfolding f
  2683       using sum.cong [of S S "\<lambda>y. (\<Sum>x\<in>{x \<in> {1..card S}. f x = y}. u (f x) *\<^sub>R f x)" "\<lambda>v. u v *\<^sub>R v"]
  2684       using sum.cong [of S S "\<lambda>y. (\<Sum>x\<in>{x \<in> {1..card S}. f x = y}. u (f x))" u]
  2685       unfolding obt(4,5)
  2686       by auto
  2687     ultimately
  2688     have "\<exists>k u x. (\<forall>i\<in>{1..k}. 0 \<le> u i \<and> x i \<in> p) \<and> sum u {1..k} = 1 \<and>
  2689         (\<Sum>i::nat = 1..k. u i *\<^sub>R x i) = y"
  2690       apply (rule_tac x="card S" in exI)
  2691       apply (rule_tac x="u \<circ> f" in exI)
  2692       apply (rule_tac x=f in exI, fastforce)
  2693       done
  2694     then have "y \<in> ?lhs"
  2695       unfolding convex_hull_indexed by auto
  2696   }
  2697   ultimately show ?thesis
  2698     unfolding set_eq_iff by blast
  2699 qed
  2700 
  2701 
  2702 subsubsection%unimportant \<open>A stepping theorem for that expansion\<close>
  2703 
  2704 lemma convex_hull_finite_step:
  2705   fixes S :: "'a::real_vector set"
  2706   assumes "finite S"
  2707   shows
  2708     "(\<exists>u. (\<forall>x\<in>insert a S. 0 \<le> u x) \<and> sum u (insert a S) = w \<and> sum (\<lambda>x. u x *\<^sub>R x) (insert a S) = y)
  2709       \<longleftrightarrow> (\<exists>v\<ge>0. \<exists>u. (\<forall>x\<in>S. 0 \<le> u x) \<and> sum u S = w - v \<and> sum (\<lambda>x. u x *\<^sub>R x) S = y - v *\<^sub>R a)"
  2710   (is "?lhs = ?rhs")
  2711 proof (rule, case_tac[!] "a\<in>S")
  2712   assume "a \<in> S"
  2713   then have *: "insert a S = S" by auto
  2714   assume ?lhs
  2715   then show ?rhs
  2716     unfolding *  by (rule_tac x=0 in exI, auto)
  2717 next
  2718   assume ?lhs
  2719   then obtain u where
  2720       u: "\<forall>x\<in>insert a S. 0 \<le> u x" "sum u (insert a S) = w" "(\<Sum>x\<in>insert a S. u x *\<^sub>R x) = y"
  2721     by auto
  2722   assume "a \<notin> S"
  2723   then show ?rhs
  2724     apply (rule_tac x="u a" in exI)
  2725     using u(1)[THEN bspec[where x=a]]
  2726     apply simp
  2727     apply (rule_tac x=u in exI)
  2728     using u[unfolded sum_clauses(2)[OF assms]] and \<open>a\<notin>S\<close>
  2729     apply auto
  2730     done
  2731 next
  2732   assume "a \<in> S"
  2733   then have *: "insert a S = S" by auto
  2734   have fin: "finite (insert a S)" using assms by auto
  2735   assume ?rhs
  2736   then obtain v u where uv: "v\<ge>0" "\<forall>x\<in>S. 0 \<le> u x" "sum u S = w - v" "(\<Sum>x\<in>S. u x *\<^sub>R x) = y - v *\<^sub>R a"
  2737     by auto
  2738   show ?lhs
  2739     apply (rule_tac x = "\<lambda>x. (if a = x then v else 0) + u x" in exI)
  2740     unfolding scaleR_left_distrib and sum.distrib and sum_delta''[OF fin] and sum.delta'[OF fin]
  2741     unfolding sum_clauses(2)[OF assms]
  2742     using uv and uv(2)[THEN bspec[where x=a]] and \<open>a\<in>S\<close>
  2743     apply auto
  2744     done
  2745 next
  2746   assume ?rhs
  2747   then obtain v u where uv: "v\<ge>0" "\<forall>x\<in>S. 0 \<le> u x" "sum u S = w - v" "(\<Sum>x\<in>S. u x *\<^sub>R x) = y - v *\<^sub>R a"
  2748     by auto
  2749   moreover assume "a \<notin> S"
  2750   moreover
  2751   have "(\<Sum>x\<in>S. if a = x then v else u x) = sum u S"  "(\<Sum>x\<in>S. (if a = x then v else u x) *\<^sub>R x) = (\<Sum>x\<in>S. u x *\<^sub>R x)"
  2752     using \<open>a \<notin> S\<close>
  2753     by (auto simp: intro!: sum.cong)
  2754   ultimately show ?lhs
  2755     by (rule_tac x="\<lambda>x. if a = x then v else u x" in exI) (auto simp: sum_clauses(2)[OF assms])
  2756 qed
  2757 
  2758 
  2759 subsubsection%unimportant \<open>Hence some special cases\<close>
  2760 
  2761 lemma convex_hull_2:
  2762   "convex hull {a,b} = {u *\<^sub>R a + v *\<^sub>R b | u v. 0 \<le> u \<and> 0 \<le> v \<and> u + v = 1}"
  2763 proof -
  2764   have *: "\<And>u. (\<forall>x\<in>{a, b}. 0 \<le> u x) \<longleftrightarrow> 0 \<le> u a \<and> 0 \<le> u b"
  2765     by auto
  2766   have **: "finite {b}" by auto
  2767   show ?thesis
  2768     apply (simp add: convex_hull_finite)
  2769     unfolding convex_hull_finite_step[OF **, of a 1, unfolded * conj_assoc]
  2770     apply auto
  2771     apply (rule_tac x=v in exI)
  2772     apply (rule_tac x="1 - v" in exI, simp)
  2773     apply (rule_tac x=u in exI, simp)
  2774     apply (rule_tac x="\<lambda>x. v" in exI, simp)
  2775     done
  2776 qed
  2777 
  2778 lemma convex_hull_2_alt: "convex hull {a,b} = {a + u *\<^sub>R (b - a) | u.  0 \<le> u \<and> u \<le> 1}"
  2779   unfolding convex_hull_2
  2780 proof (rule Collect_cong)
  2781   have *: "\<And>x y ::real. x + y = 1 \<longleftrightarrow> x = 1 - y"
  2782     by auto
  2783   fix x
  2784   show "(\<exists>v u. x = v *\<^sub>R a + u *\<^sub>R b \<and> 0 \<le> v \<and> 0 \<le> u \<and> v + u = 1) \<longleftrightarrow>
  2785     (\<exists>u. x = a + u *\<^sub>R (b - a) \<and> 0 \<le> u \<and> u \<le> 1)"
  2786     unfolding *
  2787     apply auto
  2788     apply (rule_tac[!] x=u in exI)
  2789     apply (auto simp: algebra_simps)
  2790     done
  2791 qed
  2792 
  2793 lemma convex_hull_3:
  2794   "convex hull {a,b,c} = { u *\<^sub>R a + v *\<^sub>R b + w *\<^sub>R c | u v w. 0 \<le> u \<and> 0 \<le> v \<and> 0 \<le> w \<and> u + v + w = 1}"
  2795 proof -
  2796   have fin: "finite {a,b,c}" "finite {b,c}" "finite {c}"
  2797     by auto
  2798   have *: "\<And>x y z ::real. x + y + z = 1 \<longleftrightarrow> x = 1 - y - z"
  2799     by (auto simp: field_simps)
  2800   show ?thesis
  2801     unfolding convex_hull_finite[OF fin(1)] and convex_hull_finite_step[OF fin(2)] and *
  2802     unfolding convex_hull_finite_step[OF fin(3)]
  2803     apply (rule Collect_cong, simp)
  2804     apply auto
  2805     apply (rule_tac x=va in exI)
  2806     apply (rule_tac x="u c" in exI, simp)
  2807     apply (rule_tac x="1 - v - w" in exI, simp)
  2808     apply (rule_tac x=v in exI, simp)
  2809     apply (rule_tac x="\<lambda>x. w" in exI, simp)
  2810     done
  2811 qed
  2812 
  2813 lemma convex_hull_3_alt:
  2814   "convex hull {a,b,c} = {a + u *\<^sub>R (b - a) + v *\<^sub>R (c - a) | u v.  0 \<le> u \<and> 0 \<le> v \<and> u + v \<le> 1}"
  2815 proof -
  2816   have *: "\<And>x y z ::real. x + y + z = 1 \<longleftrightarrow> x = 1 - y - z"
  2817     by auto
  2818   show ?thesis
  2819     unfolding convex_hull_3
  2820     apply (auto simp: *)
  2821     apply (rule_tac x=v in exI)
  2822     apply (rule_tac x=w in exI)
  2823     apply (simp add: algebra_simps)
  2824     apply (rule_tac x=u in exI)
  2825     apply (rule_tac x=v in exI)
  2826     apply (simp add: algebra_simps)
  2827     done
  2828 qed
  2829 
  2830 
  2831 subsection%unimportant \<open>Relations among closure notions and corresponding hulls\<close>
  2832 
  2833 lemma affine_imp_convex: "affine s \<Longrightarrow> convex s"
  2834   unfolding affine_def convex_def by auto
  2835 
  2836 lemma convex_affine_hull [simp]: "convex (affine hull S)"
  2837   by (simp add: affine_imp_convex)
  2838 
  2839 lemma subspace_imp_convex: "subspace s \<Longrightarrow> convex s"
  2840   using subspace_imp_affine affine_imp_convex by auto
  2841 
  2842 lemma affine_hull_subset_span: "(affine hull s) \<subseteq> (span s)"
  2843   by (metis hull_minimal span_superset subspace_imp_affine subspace_span)
  2844 
  2845 lemma convex_hull_subset_span: "(convex hull s) \<subseteq> (span s)"
  2846   by (metis hull_minimal span_superset subspace_imp_convex subspace_span)
  2847 
  2848 lemma convex_hull_subset_affine_hull: "(convex hull s) \<subseteq> (affine hull s)"
  2849   by (metis affine_affine_hull affine_imp_convex hull_minimal hull_subset)
  2850 
  2851 lemma affine_dependent_imp_dependent: "affine_dependent s \<Longrightarrow> dependent s"
  2852   unfolding affine_dependent_def dependent_def
  2853   using affine_hull_subset_span by auto
  2854 
  2855 lemma dependent_imp_affine_dependent:
  2856   assumes "dependent {x - a| x . x \<in> s}"
  2857     and "a \<notin> s"
  2858   shows "affine_dependent (insert a s)"
  2859 proof -
  2860   from assms(1)[unfolded dependent_explicit] obtain S u v
  2861     where obt: "finite S" "S \<subseteq> {x - a |x. x \<in> s}" "v\<in>S" "u v  \<noteq> 0" "(\<Sum>v\<in>S. u v *\<^sub>R v) = 0"
  2862     by auto
  2863   define t where "t = (\<lambda>x. x + a) ` S"
  2864 
  2865   have inj: "inj_on (\<lambda>x. x + a) S"
  2866     unfolding inj_on_def by auto
  2867   have "0 \<notin> S"
  2868     using obt(2) assms(2) unfolding subset_eq by auto
  2869   have fin: "finite t" and "t \<subseteq> s"
  2870     unfolding t_def using obt(1,2) by auto
  2871   then have "finite (insert a t)" and "insert a t \<subseteq> insert a s"
  2872     by auto
  2873   moreover have *: "\<And>P Q. (\<Sum>x\<in>t. (if x = a then P x else Q x)) = (\<Sum>x\<in>t. Q x)"
  2874     apply (rule sum.cong)
  2875     using \<open>a\<notin>s\<close> \<open>t\<subseteq>s\<close>
  2876     apply auto
  2877     done
  2878   have "(\<Sum>x\<in>insert a t. if x = a then - (\<Sum>x\<in>t. u (x - a)) else u (x - a)) = 0"
  2879     unfolding sum_clauses(2)[OF fin] * using \<open>a\<notin>s\<close> \<open>t\<subseteq>s\<close> by auto
  2880   moreover have "\<exists>v\<in>insert a t. (if v = a then - (\<Sum>x\<in>t. u (x - a)) else u (v - a)) \<noteq> 0"
  2881     using obt(3,4) \<open>0\<notin>S\<close>
  2882     by (rule_tac x="v + a" in bexI) (auto simp: t_def)
  2883   moreover have *: "\<And>P Q. (\<Sum>x\<in>t. (if x = a then P x else Q x) *\<^sub>R x) = (\<Sum>x\<in>t. Q x *\<^sub>R x)"
  2884     using \<open>a\<notin>s\<close> \<open>t\<subseteq>s\<close> by (auto intro!: sum.cong)
  2885   have "(\<Sum>x\<in>t. u (x - a)) *\<^sub>R a = (\<Sum>v\<in>t. u (v - a) *\<^sub>R v)"
  2886     unfolding scaleR_left.sum
  2887     unfolding t_def and sum.reindex[OF inj] and o_def
  2888     using obt(5)
  2889     by (auto simp: sum.distrib scaleR_right_distrib)
  2890   then have "(\<Sum>v\<in>insert a t. (if v = a then - (\<Sum>x\<in>t. u (x - a)) else u (v - a)) *\<^sub>R v) = 0"
  2891     unfolding sum_clauses(2)[OF fin]
  2892     using \<open>a\<notin>s\<close> \<open>t\<subseteq>s\<close>
  2893     by (auto simp: *)
  2894   ultimately show ?thesis
  2895     unfolding affine_dependent_explicit
  2896     apply (rule_tac x="insert a t" in exI, auto)
  2897     done
  2898 qed
  2899 
  2900 lemma convex_cone:
  2901   "convex s \<and> cone s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. (x + y) \<in> s) \<and> (\<forall>x\<in>s. \<forall>c\<ge>0. (c *\<^sub>R x) \<in> s)"
  2902   (is "?lhs = ?rhs")
  2903 proof -
  2904   {
  2905     fix x y
  2906     assume "x\<in>s" "y\<in>s" and ?lhs
  2907     then have "2 *\<^sub>R x \<in>s" "2 *\<^sub>R y \<in> s"
  2908       unfolding cone_def by auto
  2909     then have "x + y \<in> s"
  2910       using \<open>?lhs\<close>[unfolded convex_def, THEN conjunct1]
  2911       apply (erule_tac x="2*\<^sub>R x" in ballE)
  2912       apply (erule_tac x="2*\<^sub>R y" in ballE)
  2913       apply (erule_tac x="1/2" in allE, simp)
  2914       apply (erule_tac x="1/2" in allE, auto)
  2915       done
  2916   }
  2917   then show ?thesis
  2918     unfolding convex_def cone_def by blast
  2919 qed
  2920 
  2921 lemma affine_dependent_biggerset:
  2922   fixes s :: "'a::euclidean_space set"
  2923   assumes "finite s" "card s \<ge> DIM('a) + 2"
  2924   shows "affine_dependent s"
  2925 proof -
  2926   have "s \<noteq> {}" using assms by auto
  2927   then obtain a where "a\<in>s" by auto
  2928   have *: "{x - a |x. x \<in> s - {a}} = (\<lambda>x. x - a) ` (s - {a})"
  2929     by auto
  2930   have "card {x - a |x. x \<in> s - {a}} = card (s - {a})"
  2931     unfolding * by (simp add: card_image inj_on_def)
  2932   also have "\<dots> > DIM('a)" using assms(2)
  2933     unfolding card_Diff_singleton[OF assms(1) \<open>a\<in>s\<close>] by auto
  2934   finally show ?thesis
  2935     apply (subst insert_Diff[OF \<open>a\<in>s\<close>, symmetric])
  2936     apply (rule dependent_imp_affine_dependent)
  2937     apply (rule dependent_biggerset, auto)
  2938     done
  2939 qed
  2940 
  2941 lemma affine_dependent_biggerset_general:
  2942   assumes "finite (S :: 'a::euclidean_space set)"
  2943     and "card S \<ge> dim S + 2"
  2944   shows "affine_dependent S"
  2945 proof -
  2946   from assms(2) have "S \<noteq> {}" by auto
  2947   then obtain a where "a\<in>S" by auto
  2948   have *: "{x - a |x. x \<in> S - {a}} = (\<lambda>x. x - a) ` (S - {a})"
  2949     by auto
  2950   have **: "card {x - a |x. x \<in> S - {a}} = card (S - {a})"
  2951     by (metis (no_types, lifting) "*" card_image diff_add_cancel inj_on_def)
  2952   have "dim {x - a |x. x \<in> S - {a}} \<le> dim S"
  2953     using \<open>a\<in>S\<close> by (auto simp: span_base span_diff intro: subset_le_dim)
  2954   also have "\<dots> < dim S + 1" by auto
  2955   also have "\<dots> \<le> card (S - {a})"
  2956     using assms
  2957     using card_Diff_singleton[OF assms(1) \<open>a\<in>S\<close>]
  2958     by auto
  2959   finally show ?thesis
  2960     apply (subst insert_Diff[OF \<open>a\<in>S\<close>, symmetric])
  2961     apply (rule dependent_imp_affine_dependent)
  2962     apply (rule dependent_biggerset_general)
  2963     unfolding **
  2964     apply auto
  2965     done
  2966 qed
  2967 
  2968 
  2969 subsection%unimportant \<open>Some Properties of Affine Dependent Sets\<close>
  2970 
  2971 lemma affine_independent_0 [simp]: "\<not> affine_dependent {}"
  2972   by (simp add: affine_dependent_def)
  2973 
  2974 lemma affine_independent_1 [simp]: "\<not> affine_dependent {a}"
  2975   by (simp add: affine_dependent_def)
  2976 
  2977 lemma affine_independent_2 [simp]: "\<not> affine_dependent {a,b}"
  2978   by (simp add: affine_dependent_def insert_Diff_if hull_same)
  2979 
  2980 lemma affine_hull_translation: "affine hull ((\<lambda>x. a + x) `  S) = (\<lambda>x. a + x) ` (affine hull S)"
  2981 proof -
  2982   have "affine ((\<lambda>x. a + x) ` (affine hull S))"
  2983     using affine_translation affine_affine_hull by blast
  2984   moreover have "(\<lambda>x. a + x) `  S \<subseteq> (\<lambda>x. a + x) ` (affine hull S)"
  2985     using hull_subset[of S] by auto
  2986   ultimately have h1: "affine hull ((\<lambda>x. a + x) `  S) \<subseteq> (\<lambda>x. a + x) ` (affine hull S)"
  2987     by (metis hull_minimal)
  2988   have "affine((\<lambda>x. -a + x) ` (affine hull ((\<lambda>x. a + x) `  S)))"
  2989     using affine_translation affine_affine_hull by blast
  2990   moreover have "(\<lambda>x. -a + x) ` (\<lambda>x. a + x) `  S \<subseteq> (\<lambda>x. -a + x) ` (affine hull ((\<lambda>x. a + x) `  S))"
  2991     using hull_subset[of "(\<lambda>x. a + x) `  S"] by auto
  2992   moreover have "S = (\<lambda>x. -a + x) ` (\<lambda>x. a + x) `  S"
  2993     using translation_assoc[of "-a" a] by auto
  2994   ultimately have "(\<lambda>x. -a + x) ` (affine hull ((\<lambda>x. a + x) `  S)) >= (affine hull S)"
  2995     by (metis hull_minimal)
  2996   then have "affine hull ((\<lambda>x. a + x) ` S) >= (\<lambda>x. a + x) ` (affine hull S)"
  2997     by auto
  2998   then show ?thesis using h1 by auto
  2999 qed
  3000 
  3001 lemma affine_dependent_translation:
  3002   assumes "affine_dependent S"
  3003   shows "affine_dependent ((\<lambda>x. a + x) ` S)"
  3004 proof -
  3005   obtain x where x: "x \<in> S \<and> x \<in> affine hull (S - {x})"
  3006     using assms affine_dependent_def by auto
  3007   have "(+) a ` (S - {x}) = (+) a ` S - {a + x}"
  3008     by auto
  3009   then have "a + x \<in> affine hull ((\<lambda>x. a + x) ` S - {a + x})"
  3010     using affine_hull_translation[of a "S - {x}"] x by auto
  3011   moreover have "a + x \<in> (\<lambda>x. a + x) ` S"
  3012     using x by auto
  3013   ultimately show ?thesis
  3014     unfolding affine_dependent_def by auto
  3015 qed
  3016 
  3017 lemma affine_dependent_translation_eq:
  3018   "affine_dependent S \<longleftrightarrow> affine_dependent ((\<lambda>x. a + x) ` S)"
  3019 proof -
  3020   {
  3021     assume "affine_dependent ((\<lambda>x. a + x) ` S)"
  3022     then have "affine_dependent S"
  3023       using affine_dependent_translation[of "((\<lambda>x. a + x) ` S)" "-a"] translation_assoc[of "-a" a]
  3024       by auto
  3025   }
  3026   then show ?thesis
  3027     using affine_dependent_translation by auto
  3028 qed
  3029 
  3030 lemma affine_hull_0_dependent:
  3031   assumes "0 \<in> affine hull S"
  3032   shows "dependent S"
  3033 proof -
  3034   obtain s u where s_u: "finite s \<and> s \<noteq> {} \<and> s \<subseteq> S \<and> sum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = 0"
  3035     using assms affine_hull_explicit[of S] by auto
  3036   then have "\<exists>v\<in>s. u v \<noteq> 0"
  3037     using sum_not_0[of "u" "s"] by auto
  3038   then have "finite s \<and> s \<subseteq> S \<and> (\<exists>v\<in>s. u v \<noteq> 0 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = 0)"
  3039     using s_u by auto
  3040   then show ?thesis
  3041     unfolding dependent_explicit[of S] by auto
  3042 qed
  3043 
  3044 lemma affine_dependent_imp_dependent2:
  3045   assumes "affine_dependent (insert 0 S)"
  3046   shows "dependent S"
  3047 proof -
  3048   obtain x where x: "x \<in> insert 0 S \<and> x \<in> affine hull (insert 0 S - {x})"
  3049     using affine_dependent_def[of "(insert 0 S)"] assms by blast
  3050   then have "x \<in> span (insert 0 S - {x})"
  3051     using affine_hull_subset_span by auto
  3052   moreover have "span (insert 0 S - {x}) = span (S - {x})"
  3053     using insert_Diff_if[of "0" S "{x}"] span_insert_0[of "S-{x}"] by auto
  3054   ultimately have "x \<in> span (S - {x})" by auto
  3055   then have "x \<noteq> 0 \<Longrightarrow> dependent S"
  3056     using x dependent_def by auto
  3057   moreover
  3058   {
  3059     assume "x = 0"
  3060     then have "0 \<in> affine hull S"
  3061       using x hull_mono[of "S - {0}" S] by auto
  3062     then have "dependent S"
  3063       using affine_hull_0_dependent by auto
  3064   }
  3065   ultimately show ?thesis by auto
  3066 qed
  3067 
  3068 lemma affine_dependent_iff_dependent:
  3069   assumes "a \<notin> S"
  3070   shows "affine_dependent (insert a S) \<longleftrightarrow> dependent ((\<lambda>x. -a + x) ` S)"
  3071 proof -
  3072   have "((+) (- a) ` S) = {x - a| x . x \<in> S}" by auto
  3073   then show ?thesis
  3074     using affine_dependent_translation_eq[of "(insert a S)" "-a"]
  3075       affine_dependent_imp_dependent2 assms
  3076       dependent_imp_affine_dependent[of a S]
  3077     by (auto simp del: uminus_add_conv_diff)
  3078 qed
  3079 
  3080 lemma affine_dependent_iff_dependent2:
  3081   assumes "a \<in> S"
  3082   shows "affine_dependent S \<longleftrightarrow> dependent ((\<lambda>x. -a + x) ` (S-{a}))"
  3083 proof -
  3084   have "insert a (S - {a}) = S"
  3085     using assms by auto
  3086   then show ?thesis
  3087     using assms affine_dependent_iff_dependent[of a "S-{a}"] by auto
  3088 qed
  3089 
  3090 lemma affine_hull_insert_span_gen:
  3091   "affine hull (insert a s) = (\<lambda>x. a + x) ` span ((\<lambda>x. - a + x) ` s)"
  3092 proof -
  3093   have h1: "{x - a |x. x \<in> s} = ((\<lambda>x. -a+x) ` s)"
  3094     by auto
  3095   {
  3096     assume "a \<notin> s"
  3097     then have ?thesis
  3098       using affine_hull_insert_span[of a s] h1 by auto
  3099   }
  3100   moreover
  3101   {
  3102     assume a1: "a \<in> s"
  3103     have "\<exists>x. x \<in> s \<and> -a+x=0"
  3104       apply (rule exI[of _ a])
  3105       using a1
  3106       apply auto
  3107       done
  3108     then have "insert 0 ((\<lambda>x. -a+x) ` (s - {a})) = (\<lambda>x. -a+x) ` s"
  3109       by auto
  3110     then have "span ((\<lambda>x. -a+x) ` (s - {a}))=span ((\<lambda>x. -a+x) ` s)"
  3111       using span_insert_0[of "(+) (- a) ` (s - {a})"] by (auto simp del: uminus_add_conv_diff)
  3112     moreover have "{x - a |x. x \<in> (s - {a})} = ((\<lambda>x. -a+x) ` (s - {a}))"
  3113       by auto
  3114     moreover have "insert a (s - {a}) = insert a s"
  3115       by auto
  3116     ultimately have ?thesis
  3117       using affine_hull_insert_span[of "a" "s-{a}"] by auto
  3118   }
  3119   ultimately show ?thesis by auto
  3120 qed
  3121 
  3122 lemma affine_hull_span2:
  3123   assumes "a \<in> s"
  3124   shows "affine hull s = (\<lambda>x. a+x) ` span ((\<lambda>x. -a+x) ` (s-{a}))"
  3125   using affine_hull_insert_span_gen[of a "s - {a}", unfolded insert_Diff[OF assms]]
  3126   by auto
  3127 
  3128 lemma affine_hull_span_gen:
  3129   assumes "a \<in> affine hull s"
  3130   shows "affine hull s = (\<lambda>x. a+x) ` span ((\<lambda>x. -a+x) ` s)"
  3131 proof -
  3132   have "affine hull (insert a s) = affine hull s"
  3133     using hull_redundant[of a affine s] assms by auto
  3134   then show ?thesis
  3135     using affine_hull_insert_span_gen[of a "s"] by auto
  3136 qed
  3137 
  3138 lemma affine_hull_span_0:
  3139   assumes "0 \<in> affine hull S"
  3140   shows "affine hull S = span S"
  3141   using affine_hull_span_gen[of "0" S] assms by auto
  3142 
  3143 lemma extend_to_affine_basis_nonempty:
  3144   fixes S V :: "'n::euclidean_space set"
  3145   assumes "\<not> affine_dependent S" "S \<subseteq> V" "S \<noteq> {}"
  3146   shows "\<exists>T. \<not> affine_dependent T \<and> S \<subseteq> T \<and> T \<subseteq> V \<and> affine hull T = affine hull V"
  3147 proof -
  3148   obtain a where a: "a \<in> S"
  3149     using assms by auto
  3150   then have h0: "independent  ((\<lambda>x. -a + x) ` (S-{a}))"
  3151     using affine_dependent_iff_dependent2 assms by auto
  3152   obtain B where B:
  3153     "(\<lambda>x. -a+x) ` (S - {a}) \<subseteq> B \<and> B \<subseteq> (\<lambda>x. -a+x) ` V \<and> independent B \<and> (\<lambda>x. -a+x) ` V \<subseteq> span B"
  3154     using assms
  3155     by (blast intro: maximal_independent_subset_extend[OF _ h0, of "(\<lambda>x. -a + x) ` V"])
  3156   define T where "T = (\<lambda>x. a+x) ` insert 0 B"
  3157   then have "T = insert a ((\<lambda>x. a+x) ` B)"
  3158     by auto
  3159   then have "affine hull T = (\<lambda>x. a+x) ` span B"
  3160     using affine_hull_insert_span_gen[of a "((\<lambda>x. a+x) ` B)"] translation_assoc[of "-a" a B]
  3161     by auto
  3162   then have "V \<subseteq> affine hull T"
  3163     using B assms translation_inverse_subset[of a V "span B"]
  3164     by auto
  3165   moreover have "T \<subseteq> V"
  3166     using T_def B a assms by auto
  3167   ultimately have "affine hull T = affine hull V"
  3168     by (metis Int_absorb1 Int_absorb2 hull_hull hull_mono)
  3169   moreover have "S \<subseteq> T"
  3170     using T_def B translation_inverse_subset[of a "S-{a}" B]
  3171     by auto
  3172   moreover have "\<not> affine_dependent T"
  3173     using T_def affine_dependent_translation_eq[of "insert 0 B"]
  3174       affine_dependent_imp_dependent2 B
  3175     by auto
  3176   ultimately show ?thesis using \<open>T \<subseteq> V\<close> by auto
  3177 qed
  3178 
  3179 lemma affine_basis_exists:
  3180   fixes V :: "'n::euclidean_space set"
  3181   shows "\<exists>B. B \<subseteq> V \<and> \<not> affine_dependent B \<and> affine hull V = affine hull B"
  3182 proof (cases "V = {}")
  3183   case True
  3184   then show ?thesis
  3185     using affine_independent_0 by auto
  3186 next
  3187   case False
  3188   then obtain x where "x \<in> V" by auto
  3189   then show ?thesis
  3190     using affine_dependent_def[of "{x}"] extend_to_affine_basis_nonempty[of "{x}" V]
  3191     by auto
  3192 qed
  3193 
  3194 proposition extend_to_affine_basis:
  3195   fixes S V :: "'n::euclidean_space set"
  3196   assumes "\<not> affine_dependent S" "S \<subseteq> V"
  3197   obtains T where "\<not> affine_dependent T" "S \<subseteq> T" "T \<subseteq> V" "affine hull T = affine hull V"
  3198 proof (cases "S = {}")
  3199   case True then show ?thesis
  3200     using affine_basis_exists by (metis empty_subsetI that)
  3201 next
  3202   case False
  3203   then show ?thesis by (metis assms extend_to_affine_basis_nonempty that)
  3204 qed
  3205 
  3206 
  3207 subsection \<open>Affine Dimension of a Set\<close>
  3208 
  3209 definition%important aff_dim :: "('a::euclidean_space) set \<Rightarrow> int"
  3210   where "aff_dim V =
  3211   (SOME d :: int.
  3212     \<exists>B. affine hull B = affine hull V \<and> \<not> affine_dependent B \<and> of_nat (card B) = d + 1)"
  3213 
  3214 lemma aff_dim_basis_exists:
  3215   fixes V :: "('n::euclidean_space) set"
  3216   shows "\<exists>B. affine hull B = affine hull V \<and> \<not> affine_dependent B \<and> of_nat (card B) = aff_dim V + 1"
  3217 proof -
  3218   obtain B where "\<not> affine_dependent B \<and> affine hull B = affine hull V"
  3219     using affine_basis_exists[of V] by auto
  3220   then show ?thesis
  3221     unfolding aff_dim_def
  3222       some_eq_ex[of "\<lambda>d. \<exists>B. affine hull B = affine hull V \<and> \<not> affine_dependent B \<and> of_nat (card B) = d + 1"]
  3223     apply auto
  3224     apply (rule exI[of _ "int (card B) - (1 :: int)"])
  3225     apply (rule exI[of _ "B"], auto)
  3226     done
  3227 qed
  3228 
  3229 lemma affine_hull_nonempty: "S \<noteq> {} \<longleftrightarrow> affine hull S \<noteq> {}"
  3230 proof -
  3231   have "S = {} \<Longrightarrow> affine hull S = {}"
  3232     using affine_hull_empty by auto
  3233   moreover have "affine hull S = {} \<Longrightarrow> S = {}"
  3234     unfolding hull_def by auto
  3235   ultimately show ?thesis by blast
  3236 qed
  3237 
  3238 lemma aff_dim_parallel_subspace_aux:
  3239   fixes B :: "'n::euclidean_space set"
  3240   assumes "\<not> affine_dependent B" "a \<in> B"
  3241   shows "finite B \<and> ((card B) - 1 = dim (span ((\<lambda>x. -a+x) ` (B-{a}))))"
  3242 proof -
  3243   have "independent ((\<lambda>x. -a + x) ` (B-{a}))"
  3244     using affine_dependent_iff_dependent2 assms by auto
  3245   then have fin: "dim (span ((\<lambda>x. -a+x) ` (B-{a}))) = card ((\<lambda>x. -a + x) ` (B-{a}))"
  3246     "finite ((\<lambda>x. -a + x) ` (B - {a}))"
  3247     using indep_card_eq_dim_span[of "(\<lambda>x. -a+x) ` (B-{a})"] by auto
  3248   show ?thesis
  3249   proof (cases "(\<lambda>x. -a + x) ` (B - {a}) = {}")
  3250     case True
  3251     have "B = insert a ((\<lambda>x. a + x) ` (\<lambda>x. -a + x) ` (B - {a}))"
  3252       using translation_assoc[of "a" "-a" "(B - {a})"] assms by auto
  3253     then have "B = {a}" using True by auto
  3254     then show ?thesis using assms fin by auto
  3255   next
  3256     case False
  3257     then have "card ((\<lambda>x. -a + x) ` (B - {a})) > 0"
  3258       using fin by auto
  3259     moreover have h1: "card ((\<lambda>x. -a + x) ` (B-{a})) = card (B-{a})"
  3260       by (rule card_image) (use translate_inj_on in blast)
  3261     ultimately have "card (B-{a}) > 0" by auto
  3262     then have *: "finite (B - {a})"
  3263       using card_gt_0_iff[of "(B - {a})"] by auto
  3264     then have "card (B - {a}) = card B - 1"
  3265       using card_Diff_singleton assms by auto
  3266     with * show ?thesis using fin h1 by auto
  3267   qed
  3268 qed
  3269 
  3270 lemma aff_dim_parallel_subspace:
  3271   fixes V L :: "'n::euclidean_space set"
  3272   assumes "V \<noteq> {}"
  3273     and "subspace L"
  3274     and "affine_parallel (affine hull V) L"
  3275   shows "aff_dim V = int (dim L)"
  3276 proof -
  3277   obtain B where
  3278     B: "affine hull B = affine hull V \<and> \<not> affine_dependent B \<and> int (card B) = aff_dim V + 1"
  3279     using aff_dim_basis_exists by auto
  3280   then have "B \<noteq> {}"
  3281     using assms B affine_hull_nonempty[of V] affine_hull_nonempty[of B]
  3282     by auto
  3283   then obtain a where a: "a \<in> B" by auto
  3284   define Lb where "Lb = span ((\<lambda>x. -a+x) ` (B-{a}))"
  3285   moreover have "affine_parallel (affine hull B) Lb"
  3286     using Lb_def B assms affine_hull_span2[of a B] a
  3287       affine_parallel_commut[of "Lb" "(affine hull B)"]
  3288     unfolding affine_parallel_def
  3289     by auto
  3290   moreover have "subspace Lb"
  3291     using Lb_def subspace_span by auto
  3292   moreover have "affine hull B \<noteq> {}"
  3293     using assms B affine_hull_nonempty[of V] by auto
  3294   ultimately have "L = Lb"
  3295     using assms affine_parallel_subspace[of "affine hull B"] affine_affine_hull[of B] B
  3296     by auto
  3297   then have "dim L = dim Lb"
  3298     by auto
  3299   moreover have "card B - 1 = dim Lb" and "finite B"
  3300     using Lb_def aff_dim_parallel_subspace_aux a B by auto
  3301   ultimately show ?thesis
  3302     using B \<open>B \<noteq> {}\<close> card_gt_0_iff[of B] by auto
  3303 qed
  3304 
  3305 lemma aff_independent_finite:
  3306   fixes B :: "'n::euclidean_space set"
  3307   assumes "\<not> affine_dependent B"
  3308   shows "finite B"
  3309 proof -
  3310   {
  3311     assume "B \<noteq> {}"
  3312     then obtain a where "a \<in> B" by auto
  3313     then have ?thesis
  3314       using aff_dim_parallel_subspace_aux assms by auto
  3315   }
  3316   then show ?thesis by auto
  3317 qed
  3318 
  3319 lemmas independent_finite = independent_imp_finite
  3320 
  3321 lemma span_substd_basis:
  3322   assumes d: "d \<subseteq> Basis"
  3323   shows "span d = {x. \<forall>i\<in>Basis. i \<notin> d \<longrightarrow> x\<bullet>i = 0}"
  3324   (is "_ = ?B")
  3325 proof -
  3326   have "d \<subseteq> ?B"
  3327     using d by (auto simp: inner_Basis)
  3328   moreover have s: "subspace ?B"
  3329     using subspace_substandard[of "\<lambda>i. i \<notin> d"] .
  3330   ultimately have "span d \<subseteq> ?B"
  3331     using span_mono[of d "?B"] span_eq_iff[of "?B"] by blast
  3332   moreover have *: "card d \<le> dim (span d)"
  3333     using independent_card_le_dim[of d "span d"] independent_substdbasis[OF assms]
  3334       span_superset[of d]
  3335     by auto
  3336   moreover from * have "dim ?B \<le> dim (span d)"
  3337     using dim_substandard[OF assms] by auto
  3338   ultimately show ?thesis
  3339     using s subspace_dim_equal[of "span d" "?B"] subspace_span[of d] by auto
  3340 qed
  3341 
  3342 lemma basis_to_substdbasis_subspace_isomorphism:
  3343   fixes B :: "'a::euclidean_space set"
  3344   assumes "independent B"
  3345   shows "\<exists>f d::'a set. card d = card B \<and> linear f \<and> f ` B = d \<and>
  3346     f ` span B = {x. \<forall>i\<in>Basis. i \<notin> d \<longrightarrow> x \<bullet> i = 0} \<and> inj_on f (span B) \<and> d \<subseteq> Basis"
  3347 proof -
  3348   have B: "card B = dim B"
  3349     using dim_unique[of B B "card B"] assms span_superset[of B] by auto
  3350   have "dim B \<le> card (Basis :: 'a set)"
  3351     using dim_subset_UNIV[of B] by simp
  3352   from ex_card[OF this] obtain d :: "'a set" where d: "d \<subseteq> Basis" and t: "card d = dim B"
  3353     by auto
  3354   let ?t = "{x::'a::euclidean_space. \<forall>i\<in>Basis. i \<notin> d \<longrightarrow> x\<bullet>i = 0}"
  3355   have "\<exists>f. linear f \<and> f ` B = d \<and> f ` span B = ?t \<and> inj_on f (span B)"
  3356   proof (intro basis_to_basis_subspace_isomorphism subspace_span subspace_substandard span_superset)
  3357     show "d \<subseteq> {x. \<forall>i\<in>Basis. i \<notin> d \<longrightarrow> x \<bullet> i = 0}"
  3358       using d inner_not_same_Basis by blast
  3359   qed (auto simp: span_substd_basis independent_substdbasis dim_substandard d t B assms)
  3360   with t \<open>card B = dim B\<close> d show ?thesis by auto
  3361 qed
  3362 
  3363 lemma aff_dim_empty:
  3364   fixes S :: "'n::euclidean_space set"
  3365   shows "S = {} \<longleftrightarrow> aff_dim S = -1"
  3366 proof -
  3367   obtain B where *: "affine hull B = affine hull S"
  3368     and "\<not> affine_dependent B"
  3369     and "int (card B) = aff_dim S + 1"
  3370     using aff_dim_basis_exists by auto
  3371   moreover
  3372   from * have "S = {} \<longleftrightarrow> B = {}"
  3373     using affine_hull_nonempty[of B] affine_hull_nonempty[of S] by auto
  3374   ultimately show ?thesis
  3375     using aff_independent_finite[of B] card_gt_0_iff[of B] by auto
  3376 qed
  3377 
  3378 lemma aff_dim_empty_eq [simp]: "aff_dim ({}::'a::euclidean_space set) = -1"
  3379   by (simp add: aff_dim_empty [symmetric])
  3380 
  3381 lemma aff_dim_affine_hull [simp]: "aff_dim (affine hull S) = aff_dim S"
  3382   unfolding aff_dim_def using hull_hull[of _ S] by auto
  3383 
  3384 lemma aff_dim_affine_hull2:
  3385   assumes "affine hull S = affine hull T"
  3386   shows "aff_dim S = aff_dim T"
  3387   unfolding aff_dim_def using assms by auto
  3388 
  3389 lemma aff_dim_unique:
  3390   fixes B V :: "'n::euclidean_space set"
  3391   assumes "affine hull B = affine hull V \<and> \<not> affine_dependent B"
  3392   shows "of_nat (card B) = aff_dim V + 1"
  3393 proof (cases "B = {}")
  3394   case True
  3395   then have "V = {}"
  3396     using affine_hull_nonempty[of V] affine_hull_nonempty[of B] assms
  3397     by auto
  3398   then have "aff_dim V = (-1::int)"
  3399     using aff_dim_empty by auto
  3400   then show ?thesis
  3401     using \<open>B = {}\<close> by auto
  3402 next
  3403   case False
  3404   then obtain a where a: "a \<in> B" by auto
  3405   define Lb where "Lb = span ((\<lambda>x. -a+x) ` (B-{a}))"
  3406   have "affine_parallel (affine hull B) Lb"
  3407     using Lb_def affine_hull_span2[of a B] a
  3408       affine_parallel_commut[of "Lb" "(affine hull B)"]
  3409     unfolding affine_parallel_def by auto
  3410   moreover have "subspace Lb"
  3411     using Lb_def subspace_span by auto
  3412   ultimately have "aff_dim B = int(dim Lb)"
  3413     using aff_dim_parallel_subspace[of B Lb] \<open>B \<noteq> {}\<close> by auto
  3414   moreover have "(card B) - 1 = dim Lb" "finite B"
  3415     using Lb_def aff_dim_parallel_subspace_aux a assms by auto
  3416   ultimately have "of_nat (card B) = aff_dim B + 1"
  3417     using \<open>B \<noteq> {}\<close> card_gt_0_iff[of B] by auto
  3418   then show ?thesis
  3419     using aff_dim_affine_hull2 assms by auto
  3420 qed
  3421 
  3422 lemma aff_dim_affine_independent:
  3423   fixes B :: "'n::euclidean_space set"
  3424   assumes "\<not> affine_dependent B"
  3425   shows "of_nat (card B) = aff_dim B + 1"
  3426   using aff_dim_unique[of B B] assms by auto
  3427 
  3428 lemma affine_independent_iff_card:
  3429     fixes s :: "'a::euclidean_space set"
  3430     shows "~ affine_dependent s \<longleftrightarrow> finite s \<and> aff_dim s = int(card s) - 1"
  3431   apply (rule iffI)
  3432   apply (simp add: aff_dim_affine_independent aff_independent_finite)
  3433   by (metis affine_basis_exists [of s] aff_dim_unique card_subset_eq diff_add_cancel of_nat_eq_iff)
  3434 
  3435 lemma aff_dim_sing [simp]:
  3436   fixes a :: "'n::euclidean_space"
  3437   shows "aff_dim {a} = 0"
  3438   using aff_dim_affine_independent[of "{a}"] affine_independent_1 by auto
  3439 
  3440 lemma aff_dim_2 [simp]: "aff_dim {a,b} = (if a = b then 0 else 1)"
  3441 proof (clarsimp)
  3442   assume "a \<noteq> b"
  3443   then have "aff_dim{a,b} = card{a,b} - 1"
  3444     using affine_independent_2 [of a b] aff_dim_affine_independent by fastforce
  3445   also have "\<dots> = 1"
  3446     using \<open>a \<noteq> b\<close> by simp
  3447   finally show "aff_dim {a, b} = 1" .
  3448 qed
  3449 
  3450 lemma aff_dim_inner_basis_exists:
  3451   fixes V :: "('n::euclidean_space) set"
  3452   shows "\<exists>B. B \<subseteq> V \<and> affine hull B = affine hull V \<and>
  3453     \<not> affine_dependent B \<and> of_nat (card B) = aff_dim V + 1"
  3454 proof -
  3455   obtain B where B: "\<not> affine_dependent B" "B \<subseteq> V" "affine hull B = affine hull V"
  3456     using affine_basis_exists[of V] by auto
  3457   then have "of_nat(card B) = aff_dim V+1" using aff_dim_unique by auto
  3458   with B show ?thesis by auto
  3459 qed
  3460 
  3461 lemma aff_dim_le_card:
  3462   fixes V :: "'n::euclidean_space set"
  3463   assumes "finite V"
  3464   shows "aff_dim V \<le> of_nat (card V) - 1"
  3465 proof -
  3466   obtain B where B: "B \<subseteq> V" "of_nat (card B) = aff_dim V + 1"
  3467     using aff_dim_inner_basis_exists[of V] by auto
  3468   then have "card B \<le> card V"
  3469     using assms card_mono by auto
  3470   with B show ?thesis by auto
  3471 qed
  3472 
  3473 lemma aff_dim_parallel_eq:
  3474   fixes S T :: "'n::euclidean_space set"
  3475   assumes "affine_parallel (affine hull S) (affine hull T)"
  3476   shows "aff_dim S = aff_dim T"
  3477 proof -
  3478   {
  3479     assume "T \<noteq> {}" "S \<noteq> {}"
  3480     then obtain L where L: "subspace L \<and> affine_parallel (affine hull T) L"
  3481       using affine_parallel_subspace[of "affine hull T"]
  3482         affine_affine_hull[of T] affine_hull_nonempty
  3483       by auto
  3484     then have "aff_dim T = int (dim L)"
  3485       using aff_dim_parallel_subspace \<open>T \<noteq> {}\<close> by auto
  3486     moreover have *: "subspace L \<and> affine_parallel (affine hull S) L"
  3487        using L affine_parallel_assoc[of "affine hull S" "affine hull T" L] assms by auto
  3488     moreover from * have "aff_dim S = int (dim L)"
  3489       using aff_dim_parallel_subspace \<open>S \<noteq> {}\<close> by auto
  3490     ultimately have ?thesis by auto
  3491   }
  3492   moreover
  3493   {
  3494     assume "S = {}"
  3495     then have "S = {}" and "T = {}"
  3496       using assms affine_hull_nonempty
  3497       unfolding affine_parallel_def
  3498       by auto
  3499     then have ?thesis using aff_dim_empty by auto
  3500   }
  3501   moreover
  3502   {
  3503     assume "T = {}"
  3504     then have "S = {}" and "T = {}"
  3505       using assms affine_hull_nonempty
  3506       unfolding affine_parallel_def
  3507       by auto
  3508     then have ?thesis
  3509       using aff_dim_empty by auto
  3510   }
  3511   ultimately show ?thesis by blast
  3512 qed
  3513 
  3514 lemma aff_dim_translation_eq:
  3515   fixes a :: "'n::euclidean_space"
  3516   shows "aff_dim ((\<lambda>x. a + x) ` S) = aff_dim S"
  3517 proof -
  3518   have "affine_parallel (affine hull S) (affine hull ((\<lambda>x. a + x) ` S))"
  3519     unfolding affine_parallel_def
  3520     apply (rule exI[of _ "a"])
  3521     using affine_hull_translation[of a S]
  3522     apply auto
  3523     done
  3524   then show ?thesis
  3525     using aff_dim_parallel_eq[of S "(\<lambda>x. a + x) ` S"] by auto
  3526 qed
  3527 
  3528 lemma aff_dim_affine:
  3529   fixes S L :: "'n::euclidean_space set"
  3530   assumes "S \<noteq> {}"
  3531     and "affine S"
  3532     and "subspace L"
  3533     and "affine_parallel S L"
  3534   shows "aff_dim S = int (dim L)"
  3535 proof -
  3536   have *: "affine hull S = S"
  3537     using assms affine_hull_eq[of S] by auto
  3538   then have "affine_parallel (affine hull S) L"
  3539     using assms by (simp add: *)
  3540   then show ?thesis
  3541     using assms aff_dim_parallel_subspace[of S L] by blast
  3542 qed
  3543 
  3544 lemma dim_affine_hull:
  3545   fixes S :: "'n::euclidean_space set"
  3546   shows "dim (affine hull S) = dim S"
  3547 proof -
  3548   have "dim (affine hull S) \<ge> dim S"
  3549     using dim_subset by auto
  3550   moreover have "dim (span S) \<ge> dim (affine hull S)"
  3551     using dim_subset affine_hull_subset_span by blast
  3552   moreover have "dim (span S) = dim S"
  3553     using dim_span by auto
  3554   ultimately show ?thesis by auto
  3555 qed
  3556 
  3557 lemma aff_dim_subspace:
  3558   fixes S :: "'n::euclidean_space set"
  3559   assumes "subspace S"
  3560   shows "aff_dim S = int (dim S)"
  3561 proof (cases "S={}")
  3562   case True with assms show ?thesis
  3563     by (simp add: subspace_affine)
  3564 next
  3565   case False
  3566   with aff_dim_affine[of S S] assms subspace_imp_affine[of S] affine_parallel_reflex[of S] subspace_affine
  3567   show ?thesis by auto
  3568 qed
  3569 
  3570 lemma aff_dim_zero:
  3571   fixes S :: "'n::euclidean_space set"
  3572   assumes "0 \<in> affine hull S"
  3573   shows "aff_dim S = int (dim S)"
  3574 proof -
  3575   have "subspace (affine hull S)"
  3576     using subspace_affine[of "affine hull S"] affine_affine_hull assms
  3577     by auto
  3578   then have "aff_dim (affine hull S) = int (dim (affine hull S))"
  3579     using assms aff_dim_subspace[of "affine hull S"] by auto
  3580   then show ?thesis
  3581     using aff_dim_affine_hull[of S] dim_affine_hull[of S]
  3582     by auto
  3583 qed
  3584 
  3585 lemma aff_dim_eq_dim:
  3586   fixes S :: "'n::euclidean_space set"
  3587   assumes "a \<in> affine hull S"
  3588   shows "aff_dim S = int (dim ((\<lambda>x. -a+x) ` S))"
  3589 proof -
  3590   have "0 \<in> affine hull ((\<lambda>x. -a+x) ` S)"
  3591     unfolding Convex_Euclidean_Space.affine_hull_translation
  3592     using assms by (simp add: ab_group_add_class.ab_left_minus image_iff)
  3593   with aff_dim_zero show ?thesis
  3594     by (metis aff_dim_translation_eq)
  3595 qed
  3596 
  3597 lemma aff_dim_UNIV [simp]: "aff_dim (UNIV :: 'n::euclidean_space set) = int(DIM('n))"
  3598   using aff_dim_subspace[of "(UNIV :: 'n::euclidean_space set)"]
  3599     dim_UNIV[where 'a="'n::euclidean_space"]
  3600   by auto
  3601 
  3602 lemma aff_dim_geq:
  3603   fixes V :: "'n::euclidean_space set"
  3604   shows "aff_dim V \<ge> -1"
  3605 proof -
  3606   obtain B where "affine hull B = affine hull V"
  3607     and "\<not> affine_dependent B"
  3608     and "int (card B) = aff_dim V + 1"
  3609     using aff_dim_basis_exists by auto
  3610   then show ?thesis by auto
  3611 qed
  3612 
  3613 lemma aff_dim_negative_iff [simp]:
  3614   fixes S :: "'n::euclidean_space set"
  3615   shows "aff_dim S < 0 \<longleftrightarrow>S = {}"
  3616 by (metis aff_dim_empty aff_dim_geq diff_0 eq_iff zle_diff1_eq)
  3617 
  3618 lemma aff_lowdim_subset_hyperplane:
  3619   fixes S :: "'a::euclidean_space set"
  3620   assumes "aff_dim S < DIM('a)"
  3621   obtains a b where "a \<noteq> 0" "S \<subseteq> {x. a \<bullet> x = b}"
  3622 proof (cases "S={}")
  3623   case True
  3624   moreover
  3625   have "(SOME b. b \<in> Basis) \<noteq> 0"
  3626     by (metis norm_some_Basis norm_zero zero_neq_one)
  3627   ultimately show ?thesis
  3628     using that by blast
  3629 next
  3630   case False
  3631   then obtain c S' where "c \<notin> S'" "S = insert c S'"
  3632     by (meson equals0I mk_disjoint_insert)
  3633   have "dim ((+) (-c) ` S) < DIM('a)"
  3634     by (metis \<open>S = insert c S'\<close> aff_dim_eq_dim assms hull_inc insertI1 of_nat_less_imp_less)
  3635   then obtain a where "a \<noteq> 0" "span ((+) (-c) ` S) \<subseteq> {x. a \<bullet> x = 0}"
  3636     using lowdim_subset_hyperplane by blast
  3637   moreover
  3638   have "a \<bullet> w = a \<bullet> c" if "span ((+) (- c) ` S) \<subseteq> {x. a \<bullet> x = 0}" "w \<in> S" for w
  3639   proof -
  3640     have "w-c \<in> span ((+) (- c) ` S)"
  3641       by (simp add: span_base \<open>w \<in> S\<close>)
  3642     with that have "w-c \<in> {x. a \<bullet> x = 0}"
  3643       by blast
  3644     then show ?thesis
  3645       by (auto simp: algebra_simps)
  3646   qed
  3647   ultimately have "S \<subseteq> {x. a \<bullet> x = a \<bullet> c}"
  3648     by blast
  3649   then show ?thesis
  3650     by (rule that[OF \<open>a \<noteq> 0\<close>])
  3651 qed
  3652 
  3653 lemma affine_independent_card_dim_diffs:
  3654   fixes S :: "'a :: euclidean_space set"
  3655   assumes "~ affine_dependent S" "a \<in> S"
  3656     shows "card S = dim {x - a|x. x \<in> S} + 1"
  3657 proof -
  3658   have 1: "{b - a|b. b \<in> (S - {a})} \<subseteq> {x - a|x. x \<in> S}" by auto
  3659   have 2: "x - a \<in> span {b - a |b. b \<in> S - {a}}" if "x \<in> S" for x
  3660   proof (cases "x = a")
  3661     case True then show ?thesis by (simp add: span_clauses)
  3662   next
  3663     case False then show ?thesis
  3664       using assms by (blast intro: span_base that)
  3665   qed
  3666   have "\<not> affine_dependent (insert a S)"
  3667     by (simp add: assms insert_absorb)
  3668   then have 3: "independent {b - a |b. b \<in> S - {a}}"
  3669       using dependent_imp_affine_dependent by fastforce
  3670   have "{b - a |b. b \<in> S - {a}} = (\<lambda>b. b-a) ` (S - {a})"
  3671     by blast
  3672   then have "card {b - a |b. b \<in> S - {a}} = card ((\<lambda>b. b-a) ` (S - {a}))"
  3673     by simp
  3674   also have "\<dots> = card (S - {a})"
  3675     by (metis (no_types, lifting) card_image diff_add_cancel inj_onI)
  3676   also have "\<dots> = card S - 1"
  3677     by (simp add: aff_independent_finite assms)
  3678   finally have 4: "card {b - a |b. b \<in> S - {a}} = card S - 1" .
  3679   have "finite S"
  3680     by (meson assms aff_independent_finite)
  3681   with \<open>a \<in> S\<close> have "card S \<noteq> 0" by auto
  3682   moreover have "dim {x - a |x. x \<in> S} = card S - 1"
  3683     using 2 by (blast intro: dim_unique [OF 1 _ 3 4])
  3684   ultimately show ?thesis
  3685     by auto
  3686 qed
  3687 
  3688 lemma independent_card_le_aff_dim:
  3689   fixes B :: "'n::euclidean_space set"
  3690   assumes "B \<subseteq> V"
  3691   assumes "\<not> affine_dependent B"
  3692   shows "int (card B) \<le> aff_dim V + 1"
  3693 proof -
  3694   obtain T where T: "\<not> affine_dependent T \<and> B \<subseteq> T \<and> T \<subseteq> V \<and> affine hull T = affine hull V"
  3695     by (metis assms extend_to_affine_basis[of B V])
  3696   then have "of_nat (card T) = aff_dim V + 1"
  3697     using aff_dim_unique by auto
  3698   then show ?thesis
  3699     using T card_mono[of T B] aff_independent_finite[of T] by auto
  3700 qed
  3701 
  3702 lemma aff_dim_subset:
  3703   fixes S T :: "'n::euclidean_space set"
  3704   assumes "S \<subseteq> T"
  3705   shows "aff_dim S \<le> aff_dim T"
  3706 proof -
  3707   obtain B where B: "\<not> affine_dependent B" "B \<subseteq> S" "affine hull B = affine hull S"
  3708     "of_nat (card B) = aff_dim S + 1"
  3709     using aff_dim_inner_basis_exists[of S] by auto
  3710   then have "int (card B) \<le> aff_dim T + 1"
  3711     using assms independent_card_le_aff_dim[of B T] by auto
  3712   with B show ?thesis by auto
  3713 qed
  3714 
  3715 lemma aff_dim_le_DIM:
  3716   fixes S :: "'n::euclidean_space set"
  3717   shows "aff_dim S \<le> int (DIM('n))"
  3718 proof -
  3719   have "aff_dim (UNIV :: 'n::euclidean_space set) = int(DIM('n))"
  3720     using aff_dim_UNIV by auto
  3721   then show "aff_dim (S:: 'n::euclidean_space set) \<le> int(DIM('n))"
  3722     using aff_dim_subset[of S "(UNIV :: ('n::euclidean_space) set)"] subset_UNIV by auto
  3723 qed
  3724 
  3725 lemma affine_dim_equal:
  3726   fixes S :: "'n::euclidean_space set"
  3727   assumes "affine S" "affine T" "S \<noteq> {}" "S \<subseteq> T" "aff_dim S = aff_dim T"
  3728   shows "S = T"
  3729 proof -
  3730   obtain a where "a \<in> S" using assms by auto
  3731   then have "a \<in> T" using assms by auto
  3732   define LS where "LS = {y. \<exists>x \<in> S. (-a) + x = y}"
  3733   then have ls: "subspace LS" "affine_parallel S LS"
  3734     using assms parallel_subspace_explicit[of S a LS] \<open>a \<in> S\<close> by auto
  3735   then have h1: "int(dim LS) = aff_dim S"
  3736     using assms aff_dim_affine[of S LS] by auto
  3737   have "T \<noteq> {}" using assms by auto
  3738   define LT where "LT = {y. \<exists>x \<in> T. (-a) + x = y}"
  3739   then have lt: "subspace LT \<and> affine_parallel T LT"
  3740     using assms parallel_subspace_explicit[of T a LT] \<open>a \<in> T\<close> by auto
  3741   then have "int(dim LT) = aff_dim T"
  3742     using assms aff_dim_affine[of T LT] \<open>T \<noteq> {}\<close> by auto
  3743   then have "dim LS = dim LT"
  3744     using h1 assms by auto
  3745   moreover have "LS \<le> LT"
  3746     using LS_def LT_def assms by auto
  3747   ultimately have "LS = LT"
  3748     using subspace_dim_equal[of LS LT] ls lt by auto
  3749   moreover have "S = {x. \<exists>y \<in> LS. a+y=x}"
  3750     using LS_def by auto
  3751   moreover have "T = {x. \<exists>y \<in> LT. a+y=x}"
  3752     using LT_def by auto
  3753   ultimately show ?thesis by auto
  3754 qed
  3755 
  3756 lemma aff_dim_eq_0:
  3757   fixes S :: "'a::euclidean_space set"
  3758   shows "aff_dim S = 0 \<longleftrightarrow> (\<exists>a. S = {a})"
  3759 proof (cases "S = {}")
  3760   case True
  3761   then show ?thesis
  3762     by auto
  3763 next
  3764   case False
  3765   then obtain a where "a \<in> S" by auto
  3766   show ?thesis
  3767   proof safe
  3768     assume 0: "aff_dim S = 0"
  3769     have "~ {a,b} \<subseteq> S" if "b \<noteq> a" for b
  3770       by (metis "0" aff_dim_2 aff_dim_subset not_one_le_zero that)
  3771     then show "\<exists>a. S = {a}"
  3772       using \<open>a \<in> S\<close> by blast
  3773   qed auto
  3774 qed
  3775 
  3776 lemma affine_hull_UNIV:
  3777   fixes S :: "'n::euclidean_space set"
  3778   assumes "aff_dim S = int(DIM('n))"
  3779   shows "affine hull S = (UNIV :: ('n::euclidean_space) set)"
  3780 proof -
  3781   have "S \<noteq> {}"
  3782     using assms aff_dim_empty[of S] by auto
  3783   have h0: "S \<subseteq> affine hull S"
  3784     using hull_subset[of S _] by auto
  3785   have h1: "aff_dim (UNIV :: ('n::euclidean_space) set) = aff_dim S"
  3786     using aff_dim_UNIV assms by auto
  3787   then have h2: "aff_dim (affine hull S) \<le> aff_dim (UNIV :: ('n::euclidean_space) set)"
  3788     using aff_dim_le_DIM[of "affine hull S"] assms h0 by auto
  3789   have h3: "aff_dim S \<le> aff_dim (affine hull S)"
  3790     using h0 aff_dim_subset[of S "affine hull S"] assms by auto
  3791   then have h4: "aff_dim (affine hull S) = aff_dim (UNIV :: ('n::euclidean_space) set)"
  3792     using h0 h1 h2 by auto
  3793   then show ?thesis
  3794     using affine_dim_equal[of "affine hull S" "(UNIV :: ('n::euclidean_space) set)"]
  3795       affine_affine_hull[of S] affine_UNIV assms h4 h0 \<open>S \<noteq> {}\<close>
  3796     by auto
  3797 qed
  3798 
  3799 lemma disjoint_affine_hull:
  3800   fixes s :: "'n::euclidean_space set"
  3801   assumes "~ affine_dependent s" "t \<subseteq> s" "u \<subseteq> s" "t \<inter> u = {}"
  3802     shows "(affine hull t) \<inter> (affine hull u) = {}"
  3803 proof -
  3804   have "finite s" using assms by (simp add: aff_independent_finite)
  3805   then have "finite t" "finite u" using assms finite_subset by blast+
  3806   { fix y
  3807     assume yt: "y \<in> affine hull t" and yu: "y \<in> affine hull u"
  3808     then obtain a b
  3809            where a1 [simp]: "sum a t = 1" and [simp]: "sum (\<lambda>v. a v *\<^sub>R v) t = y"
  3810              and [simp]: "sum b u = 1" "sum (\<lambda>v. b v *\<^sub>R v) u = y"
  3811       by (auto simp: affine_hull_finite \<open>finite t\<close> \<open>finite u\<close>)
  3812     define c where "c x = (if x \<in> t then a x else if x \<in> u then -(b x) else 0)" for x
  3813     have [simp]: "s \<inter> t = t" "s \<inter> - t \<inter> u = u" using assms by auto
  3814     have "sum c s = 0"
  3815       by (simp add: c_def comm_monoid_add_class.sum.If_cases \<open>finite s\<close> sum_negf)
  3816     moreover have "~ (\<forall>v\<in>s. c v = 0)"
  3817       by (metis (no_types) IntD1 \<open>s \<inter> t = t\<close> a1 c_def sum_not_0 zero_neq_one)
  3818     moreover have "(\<Sum>v\<in>s. c v *\<^sub>R v) = 0"
  3819       by (simp add: c_def if_smult sum_negf
  3820              comm_monoid_add_class.sum.If_cases \<open>finite s\<close>)
  3821     ultimately have False
  3822       using assms \<open>finite s\<close> by (auto simp: affine_dependent_explicit)
  3823   }
  3824   then show ?thesis by blast
  3825 qed
  3826 
  3827 lemma aff_dim_convex_hull:
  3828   fixes S :: "'n::euclidean_space set"
  3829   shows "aff_dim (convex hull S) = aff_dim S"
  3830   using aff_dim_affine_hull[of S] convex_hull_subset_affine_hull[of S]
  3831     hull_subset[of S "convex"] aff_dim_subset[of S "convex hull S"]
  3832     aff_dim_subset[of "convex hull S" "affine hull S"]
  3833   by auto
  3834 
  3835 lemma aff_dim_cball:
  3836   fixes a :: "'n::euclidean_space"
  3837   assumes "e > 0"
  3838   shows "aff_dim (cball a e) = int (DIM('n))"
  3839 proof -
  3840   have "(\<lambda>x. a + x) ` (cball 0 e) \<subseteq> cball a e"
  3841     unfolding cball_def dist_norm by auto
  3842   then have "aff_dim (cball (0 :: 'n::euclidean_space) e) \<le> aff_dim (cball a e)"
  3843     using aff_dim_translation_eq[of a "cball 0 e"]
  3844           aff_dim_subset[of "(+) a ` cball 0 e" "cball a e"]
  3845     by auto
  3846   moreover have "aff_dim (cball (0 :: 'n::euclidean_space) e) = int (DIM('n))"
  3847     using hull_inc[of "(0 :: 'n::euclidean_space)" "cball 0 e"]
  3848       centre_in_cball[of "(0 :: 'n::euclidean_space)"] assms
  3849     by (simp add: dim_cball[of e] aff_dim_zero[of "cball 0 e"])
  3850   ultimately show ?thesis
  3851     using aff_dim_le_DIM[of "cball a e"] by auto
  3852 qed
  3853 
  3854 lemma aff_dim_open:
  3855   fixes S :: "'n::euclidean_space set"
  3856   assumes "open S"
  3857     and "S \<noteq> {}"
  3858   shows "aff_dim S = int (DIM('n))"
  3859 proof -
  3860   obtain x where "x \<in> S"
  3861     using assms by auto
  3862   then obtain e where e: "e > 0" "cball x e \<subseteq> S"
  3863     using open_contains_cball[of S] assms by auto
  3864   then have "aff_dim (cball x e) \<le> aff_dim S"
  3865     using aff_dim_subset by auto
  3866   with e show ?thesis
  3867     using aff_dim_cball[of e x] aff_dim_le_DIM[of S] by auto
  3868 qed
  3869 
  3870 lemma low_dim_interior:
  3871   fixes S :: "'n::euclidean_space set"
  3872   assumes "\<not> aff_dim S = int (DIM('n))"
  3873   shows "interior S = {}"
  3874 proof -
  3875   have "aff_dim(interior S) \<le> aff_dim S"
  3876     using interior_subset aff_dim_subset[of "interior S" S] by auto
  3877   then show ?thesis
  3878     using aff_dim_open[of "interior S"] aff_dim_le_DIM[of S] assms by auto
  3879 qed
  3880 
  3881 corollary empty_interior_lowdim:
  3882   fixes S :: "'n::euclidean_space set"
  3883   shows "dim S < DIM ('n) \<Longrightarrow> interior S = {}"
  3884 by (metis low_dim_interior affine_hull_UNIV dim_affine_hull less_not_refl dim_UNIV)
  3885 
  3886 corollary aff_dim_nonempty_interior:
  3887   fixes S :: "'a::euclidean_space set"
  3888   shows "interior S \<noteq> {} \<Longrightarrow> aff_dim S = DIM('a)"
  3889 by (metis low_dim_interior)
  3890 
  3891 
  3892 subsection \<open>Caratheodory's theorem\<close>
  3893 
  3894 lemma convex_hull_caratheodory_aff_dim:
  3895   fixes p :: "('a::euclidean_space) set"
  3896   shows "convex hull p =
  3897     {y. \<exists>s u. finite s \<and> s \<subseteq> p \<and> card s \<le> aff_dim p + 1 \<and>
  3898       (\<forall>x\<in>s. 0 \<le> u x) \<and> sum u s = 1 \<and> sum (\<lambda>v. u v *\<^sub>R v) s = y}"
  3899   unfolding convex_hull_explicit set_eq_iff mem_Collect_eq
  3900 proof (intro allI iffI)
  3901   fix y
  3902   let ?P = "\<lambda>n. \<exists>s u. finite s \<and> card s = n \<and> s \<subseteq> p \<and> (\<forall>x\<in>s. 0 \<le> u x) \<and>
  3903     sum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y"
  3904   assume "\<exists>s u. finite s \<and> s \<subseteq> p \<and> (\<forall>x\<in>s. 0 \<le> u x) \<and> sum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y"
  3905   then obtain N where "?P N" by auto
  3906   then have "\<exists>n\<le>N. (\<forall>k<n. \<not> ?P k) \<and> ?P n"
  3907     apply (rule_tac ex_least_nat_le, auto)
  3908     done
  3909   then obtain n where "?P n" and smallest: "\<forall>k<n. \<not> ?P k"
  3910     by blast
  3911   then obtain s u where obt: "finite s" "card s = n" "s\<subseteq>p" "\<forall>x\<in>s. 0 \<le> u x"
  3912     "sum u s = 1"  "(\<Sum>v\<in>s. u v *\<^sub>R v) = y" by auto
  3913 
  3914   have "card s \<le> aff_dim p + 1"
  3915   proof (rule ccontr, simp only: not_le)
  3916     assume "aff_dim p + 1 < card s"
  3917     then have "affine_dependent s"
  3918       using affine_dependent_biggerset[OF obt(1)] independent_card_le_aff_dim not_less obt(3)
  3919       by blast
  3920     then obtain w v where wv: "sum w s = 0" "v\<in>s" "w v \<noteq> 0" "(\<Sum>v\<in>s. w v *\<^sub>R v) = 0"
  3921       using affine_dependent_explicit_finite[OF obt(1)] by auto
  3922     define i where "i = (\<lambda>v. (u v) / (- w v)) ` {v\<in>s. w v < 0}"
  3923     define t where "t = Min i"
  3924     have "\<exists>x\<in>s. w x < 0"
  3925     proof (rule ccontr, simp add: not_less)
  3926       assume as:"\<forall>x\<in>s. 0 \<le> w x"
  3927       then have "sum w (s - {v}) \<ge> 0"
  3928         apply (rule_tac sum_nonneg, auto)
  3929         done
  3930       then have "sum w s > 0"
  3931         unfolding sum.remove[OF obt(1) \<open>v\<in>s\<close>]
  3932         using as[THEN bspec[where x=v]]  \<open>v\<in>s\<close>  \<open>w v \<noteq> 0\<close> by auto
  3933       then show False using wv(1) by auto
  3934     qed
  3935     then have "i \<noteq> {}" unfolding i_def by auto
  3936     then have "t \<ge> 0"
  3937       using Min_ge_iff[of i 0 ] and obt(1)
  3938       unfolding t_def i_def
  3939       using obt(4)[unfolded le_less]
  3940       by (auto simp: divide_le_0_iff)
  3941     have t: "\<forall>v\<in>s. u v + t * w v \<ge> 0"
  3942     proof
  3943       fix v
  3944       assume "v \<in> s"
  3945       then have v: "0 \<le> u v"
  3946         using obt(4)[THEN bspec[where x=v]] by auto
  3947       show "0 \<le> u v + t * w v"
  3948       proof (cases "w v < 0")
  3949         case False
  3950         thus ?thesis using v \<open>t\<ge>0\<close> by auto
  3951       next
  3952         case True
  3953         then have "t \<le> u v / (- w v)"
  3954           using \<open>v\<in>s\<close> unfolding t_def i_def
  3955           apply (rule_tac Min_le)
  3956           using obt(1) apply auto
  3957           done
  3958         then show ?thesis
  3959           unfolding real_0_le_add_iff
  3960           using pos_le_divide_eq[OF True[unfolded neg_0_less_iff_less[symmetric]]]
  3961           by auto
  3962       qed
  3963     qed
  3964     obtain a where "a \<in> s" and "t = (\<lambda>v. (u v) / (- w v)) a" and "w a < 0"
  3965       using Min_in[OF _ \<open>i\<noteq>{}\<close>] and obt(1) unfolding i_def t_def by auto
  3966     then have a: "a \<in> s" "u a + t * w a = 0" by auto
  3967     have *: "\<And>f. sum f (s - {a}) = sum f s - ((f a)::'b::ab_group_add)"
  3968       unfolding sum.remove[OF obt(1) \<open>a\<in>s\<close>] by auto
  3969     have "(\<Sum>v\<in>s. u v + t * w v) = 1"
  3970       unfolding sum.distrib wv(1) sum_distrib_left[symmetric] obt(5) by auto
  3971     moreover have "(\<Sum>v\<in>s. u v *\<^sub>R v + (t * w v) *\<^sub>R v) - (u a *\<^sub>R a + (t * w a) *\<^sub>R a) = y"
  3972       unfolding sum.distrib obt(6) scaleR_scaleR[symmetric] scaleR_right.sum [symmetric] wv(4)
  3973       using a(2) [THEN eq_neg_iff_add_eq_0 [THEN iffD2]] by simp
  3974     ultimately have "?P (n - 1)"
  3975       apply (rule_tac x="(s - {a})" in exI)
  3976       apply (rule_tac x="\<lambda>v. u v + t * w v" in exI)
  3977       using obt(1-3) and t and a
  3978       apply (auto simp: * scaleR_left_distrib)
  3979       done
  3980     then show False
  3981       using smallest[THEN spec[where x="n - 1"]] by auto
  3982   qed
  3983   then show "\<exists>s u. finite s \<and> s \<subseteq> p \<and> card s \<le> aff_dim p + 1 \<and>
  3984       (\<forall>x\<in>s. 0 \<le> u x) \<and> sum u s = 1 \<and> (\<Sum>v\<in>s. u v *\<^sub>R v) = y"
  3985     using obt by auto
  3986 qed auto
  3987 
  3988 lemma caratheodory_aff_dim:
  3989   fixes p :: "('a::euclidean_space) set"
  3990   shows "convex hull p = {x. \<exists>s. finite s \<and> s \<subseteq> p \<and> card s \<le> aff_dim p + 1 \<and> x \<in> convex hull s}"
  3991         (is "?lhs = ?rhs")
  3992 proof
  3993   show "?lhs \<subseteq> ?rhs"
  3994     apply (subst convex_hull_caratheodory_aff_dim, clarify)
  3995     apply (rule_tac x=s in exI)
  3996     apply (simp add: hull_subset convex_explicit [THEN iffD1, OF convex_convex_hull])
  3997     done
  3998 next
  3999   show "?rhs \<subseteq> ?lhs"
  4000     using hull_mono by blast
  4001 qed
  4002 
  4003 lemma convex_hull_caratheodory:
  4004   fixes p :: "('a::euclidean_space) set"
  4005   shows "convex hull p =
  4006             {y. \<exists>s u. finite s \<and> s \<subseteq> p \<and> card s \<le> DIM('a) + 1 \<and>
  4007               (\<forall>x\<in>s. 0 \<le> u x) \<and> sum u s = 1 \<and> sum (\<lambda>v. u v *\<^sub>R v) s = y}"
  4008         (is "?lhs = ?rhs")
  4009 proof (intro set_eqI iffI)
  4010   fix x
  4011   assume "x \<in> ?lhs" then show "x \<in> ?rhs"
  4012     apply (simp only: convex_hull_caratheodory_aff_dim Set.mem_Collect_eq)
  4013     apply (erule ex_forward)+
  4014     using aff_dim_le_DIM [of p]
  4015     apply simp
  4016     done
  4017 next
  4018   fix x
  4019   assume "x \<in> ?rhs" then show "x \<in> ?lhs"
  4020     by (auto simp: convex_hull_explicit)
  4021 qed
  4022 
  4023 theorem caratheodory:
  4024   "convex hull p =
  4025     {x::'a::euclidean_space. \<exists>s. finite s \<and> s \<subseteq> p \<and>
  4026       card s \<le> DIM('a) + 1 \<and> x \<in> convex hull s}"
  4027 proof safe
  4028   fix x
  4029   assume "x \<in> convex hull p"
  4030   then obtain s u where "finite s" "s \<subseteq> p" "card s \<le> DIM('a) + 1"
  4031     "\<forall>x\<in>s. 0 \<le> u x" "sum u s = 1" "(\<Sum>v\<in>s. u v *\<^sub>R v) = x"
  4032     unfolding convex_hull_caratheodory by auto
  4033   then show "\<exists>s. finite s \<and> s \<subseteq> p \<and> card s \<le> DIM('a) + 1 \<and> x \<in> convex hull s"
  4034     apply (rule_tac x=s in exI)
  4035     using hull_subset[of s convex]
  4036     using convex_convex_hull[simplified convex_explicit, of s,
  4037       THEN spec[where x=s], THEN spec[where x=u]]
  4038     apply auto
  4039     done
  4040 next
  4041   fix x s
  4042   assume  "finite s" "s \<subseteq> p" "card s \<le> DIM('a) + 1" "x \<in> convex hull s"
  4043   then show "x \<in> convex hull p"
  4044     using hull_mono[OF \<open>s\<subseteq>p\<close>] by auto
  4045 qed
  4046 
  4047 
  4048 subsection \<open>Relative interior of a set\<close>
  4049 
  4050 definition%important "rel_interior S =
  4051   {x. \<exists>T. openin (subtopology euclidean (affine hull S)) T \<and> x \<in> T \<and> T \<subseteq> S}"
  4052 
  4053 lemma rel_interior_mono:
  4054    "\<lbrakk>S \<subseteq> T; affine hull S = affine hull T\<rbrakk>
  4055    \<Longrightarrow> (rel_interior S) \<subseteq> (rel_interior T)"
  4056   by (auto simp: rel_interior_def)
  4057 
  4058 lemma rel_interior_maximal:
  4059    "\<lbrakk>T \<subseteq> S; openin(subtopology euclidean (affine hull S)) T\<rbrakk> \<Longrightarrow> T \<subseteq> (rel_interior S)"
  4060   by (auto simp: rel_interior_def)
  4061 
  4062 lemma rel_interior:
  4063   "rel_interior S = {x \<in> S. \<exists>T. open T \<and> x \<in> T \<and> T \<inter> affine hull S \<subseteq> S}"
  4064   unfolding rel_interior_def[of S] openin_open[of "affine hull S"]
  4065   apply auto
  4066 proof -
  4067   fix x T
  4068   assume *: "x \<in> S" "open T" "x \<in> T" "T \<inter> affine hull S \<subseteq> S"
  4069   then have **: "x \<in> T \<inter> affine hull S"
  4070     using hull_inc by auto
  4071   show "\<exists>Tb. (\<exists>Ta. open Ta \<and> Tb = affine hull S \<inter> Ta) \<and> x \<in> Tb \<and> Tb \<subseteq> S"
  4072     apply (rule_tac x = "T \<inter> (affine hull S)" in exI)
  4073     using * **
  4074     apply auto
  4075     done
  4076 qed
  4077 
  4078 lemma mem_rel_interior: "x \<in> rel_interior S \<longleftrightarrow> (\<exists>T. open T \<and> x \<in> T \<inter> S \<and> T \<inter> affine hull S \<subseteq> S)"
  4079   by (auto simp: rel_interior)
  4080 
  4081 lemma mem_rel_interior_ball:
  4082   "x \<in> rel_interior S \<longleftrightarrow> x \<in> S \<and> (\<exists>e. e > 0 \<and> ball x e \<inter> affine hull S \<subseteq> S)"
  4083   apply (simp add: rel_interior, safe)
  4084   apply (force simp: open_contains_ball)
  4085   apply (rule_tac x = "ball x e" in exI, simp)
  4086   done
  4087 
  4088 lemma rel_interior_ball:
  4089   "rel_interior S = {x \<in> S. \<exists>e. e > 0 \<and> ball x e \<inter> affine hull S \<subseteq> S}"
  4090   using mem_rel_interior_ball [of _ S] by auto
  4091 
  4092 lemma mem_rel_interior_cball:
  4093   "x \<in> rel_interior S \<longleftrightarrow> x \<in> S \<and> (\<exists>e. e > 0 \<and> cball x e \<inter> affine hull S \<subseteq> S)"
  4094   apply (simp add: rel_interior, safe)
  4095   apply (force simp: open_contains_cball)
  4096   apply (rule_tac x = "ball x e" in exI)
  4097   apply (simp add: subset_trans [OF ball_subset_cball], auto)
  4098   done
  4099 
  4100 lemma rel_interior_cball:
  4101   "rel_interior S = {x \<in> S. \<exists>e. e > 0 \<and> cball x e \<inter> affine hull S \<subseteq> S}"
  4102   using mem_rel_interior_cball [of _ S] by auto
  4103 
  4104 lemma rel_interior_empty [simp]: "rel_interior {} = {}"
  4105    by (auto simp: rel_interior_def)
  4106 
  4107 lemma affine_hull_sing [simp]: "affine hull {a :: 'n::euclidean_space} = {a}"
  4108   by (metis affine_hull_eq affine_sing)
  4109 
  4110 lemma rel_interior_sing [simp]:
  4111     fixes a :: "'n::euclidean_space"  shows "rel_interior {a} = {a}"
  4112   apply (auto simp: rel_interior_ball)
  4113   apply (rule_tac x=1 in exI, force)
  4114   done
  4115 
  4116 lemma subset_rel_interior:
  4117   fixes S T :: "'n::euclidean_space set"
  4118   assumes "S \<subseteq> T"
  4119     and "affine hull S = affine hull T"
  4120   shows "rel_interior S \<subseteq> rel_interior T"
  4121   using assms by (auto simp: rel_interior_def)
  4122 
  4123 lemma rel_interior_subset: "rel_interior S \<subseteq> S"
  4124   by (auto simp: rel_interior_def)
  4125 
  4126 lemma rel_interior_subset_closure: "rel_interior S \<subseteq> closure S"
  4127   using rel_interior_subset by (auto simp: closure_def)
  4128 
  4129 lemma interior_subset_rel_interior: "interior S \<subseteq> rel_interior S"
  4130   by (auto simp: rel_interior interior_def)
  4131 
  4132 lemma interior_rel_interior:
  4133   fixes S :: "'n::euclidean_space set"
  4134   assumes "aff_dim S = int(DIM('n))"
  4135   shows "rel_interior S = interior S"
  4136 proof -
  4137   have "affine hull S = UNIV"
  4138     using assms affine_hull_UNIV[of S] by auto
  4139   then show ?thesis
  4140     unfolding rel_interior interior_def by auto
  4141 qed
  4142 
  4143 lemma rel_interior_interior:
  4144   fixes S :: "'n::euclidean_space set"
  4145   assumes "affine hull S = UNIV"
  4146   shows "rel_interior S = interior S"
  4147   using assms unfolding rel_interior interior_def by auto
  4148 
  4149 lemma rel_interior_open:
  4150   fixes S :: "'n::euclidean_space set"
  4151   assumes "open S"
  4152   shows "rel_interior S = S"
  4153   by (metis assms interior_eq interior_subset_rel_interior rel_interior_subset set_eq_subset)
  4154 
  4155 lemma interior_ball [simp]: "interior (ball x e) = ball x e"
  4156   by (simp add: interior_open)
  4157 
  4158 lemma interior_rel_interior_gen:
  4159   fixes S :: "'n::euclidean_space set"
  4160   shows "interior S = (if aff_dim S = int(DIM('n)) then rel_interior S else {})"
  4161   by (metis interior_rel_interior low_dim_interior)
  4162 
  4163 lemma rel_interior_nonempty_interior:
  4164   fixes S :: "'n::euclidean_space set"
  4165   shows "interior S \<noteq> {} \<Longrightarrow> rel_interior S = interior S"
  4166 by (metis interior_rel_interior_gen)
  4167 
  4168 lemma affine_hull_nonempty_interior:
  4169   fixes S :: "'n::euclidean_space set"
  4170   shows "interior S \<noteq> {} \<Longrightarrow> affine hull S = UNIV"
  4171 by (metis affine_hull_UNIV interior_rel_interior_gen)
  4172 
  4173 lemma rel_interior_affine_hull [simp]:
  4174   fixes S :: "'n::euclidean_space set"
  4175   shows "rel_interior (affine hull S) = affine hull S"
  4176 proof -
  4177   have *: "rel_interior (affine hull S) \<subseteq> affine hull S"
  4178     using rel_interior_subset by auto
  4179   {
  4180     fix x
  4181     assume x: "x \<in> affine hull S"
  4182     define e :: real where "e = 1"
  4183     then have "e > 0" "ball x e \<inter> affine hull (affine hull S) \<subseteq> affine hull S"
  4184       using hull_hull[of _ S] by auto
  4185     then have "x \<in> rel_interior (affine hull S)"
  4186       using x rel_interior_ball[of "affine hull S"] by auto
  4187   }
  4188   then show ?thesis using * by auto
  4189 qed
  4190 
  4191 lemma rel_interior_UNIV [simp]: "rel_interior (UNIV :: ('n::euclidean_space) set) = UNIV"
  4192   by (metis open_UNIV rel_interior_open)
  4193 
  4194 lemma rel_interior_convex_shrink:
  4195   fixes S :: "'a::euclidean_space set"
  4196   assumes "convex S"
  4197     and "c \<in> rel_interior S"
  4198     and "x \<in> S"
  4199     and "0 < e"
  4200     and "e \<le> 1"
  4201   shows "x - e *\<^sub>R (x - c) \<in> rel_interior S"
  4202 proof -
  4203   obtain d where "d > 0" and d: "ball c d \<inter> affine hull S \<subseteq> S"
  4204     using assms(2) unfolding  mem_rel_interior_ball by auto
  4205   {
  4206     fix y
  4207     assume as: "dist (x - e *\<^sub>R (x - c)) y < e * d" "y \<in> affine hull S"
  4208     have *: "y = (1 - (1 - e)) *\<^sub>R ((1 / e) *\<^sub>R y - ((1 - e) / e) *\<^sub>R x) + (1 - e) *\<^sub>R x"
  4209       using \<open>e > 0\<close> by (auto simp: scaleR_left_diff_distrib scaleR_right_diff_distrib)
  4210     have "x \<in> affine hull S"
  4211       using assms hull_subset[of S] by auto
  4212     moreover have "1 / e + - ((1 - e) / e) = 1"
  4213       using \<open>e > 0\<close> left_diff_distrib[of "1" "(1-e)" "1/e"] by auto
  4214     ultimately have **: "(1 / e) *\<^sub>R y - ((1 - e) / e) *\<^sub>R x \<in> affine hull S"
  4215       using as affine_affine_hull[of S] mem_affine[of "affine hull S" y x "(1 / e)" "-((1 - e) / e)"]
  4216       by (simp add: algebra_simps)
  4217     have "dist c ((1 / e) *\<^sub>R y - ((1 - e) / e) *\<^sub>R x) = \<bar>1/e\<bar> * norm (e *\<^sub>R c - y + (1 - e) *\<^sub>R x)"
  4218       unfolding dist_norm norm_scaleR[symmetric]
  4219       apply (rule arg_cong[where f=norm])
  4220       using \<open>e > 0\<close>
  4221       apply (auto simp: euclidean_eq_iff[where 'a='a] field_simps inner_simps)
  4222       done
  4223     also have "\<dots> = \<bar>1/e\<bar> * norm (x - e *\<^sub>R (x - c) - y)"
  4224       by (auto intro!:arg_cong[where f=norm] simp add: algebra_simps)
  4225     also have "\<dots> < d"
  4226       using as[unfolded dist_norm] and \<open>e > 0\<close>
  4227       by (auto simp:pos_divide_less_eq[OF \<open>e > 0\<close>] mult.commute)
  4228     finally have "y \<in> S"
  4229       apply (subst *)
  4230       apply (rule assms(1)[unfolded convex_alt,rule_format])
  4231       apply (rule d[THEN subsetD])
  4232       unfolding mem_ball
  4233       using assms(3-5) **
  4234       apply auto
  4235       done
  4236   }
  4237   then have "ball (x - e *\<^sub>R (x - c)) (e*d) \<inter> affine hull S \<subseteq> S"
  4238     by auto
  4239   moreover have "e * d > 0"
  4240     using \<open>e > 0\<close> \<open>d > 0\<close> by simp
  4241   moreover have c: "c \<in> S"
  4242     using assms rel_interior_subset by auto
  4243   moreover from c have "x - e *\<^sub>R (x - c) \<in> S"
  4244     using convexD_alt[of S x c e]
  4245     apply (simp add: algebra_simps)
  4246     using assms
  4247     apply auto
  4248     done
  4249   ultimately show ?thesis
  4250     using mem_rel_interior_ball[of "x - e *\<^sub>R (x - c)" S] \<open>e > 0\<close> by auto
  4251 qed
  4252 
  4253 lemma interior_real_semiline:
  4254   fixes a :: real
  4255   shows "interior {a..} = {a<..}"
  4256 proof -
  4257   {
  4258     fix y
  4259     assume "a < y"
  4260     then have "y \<in> interior {a..}"
  4261       apply (simp add: mem_interior)
  4262       apply (rule_tac x="(y-a)" in exI)
  4263       apply (auto simp: dist_norm)
  4264       done
  4265   }
  4266   moreover
  4267   {
  4268     fix y
  4269     assume "y \<in> interior {a..}"
  4270     then obtain e where e: "e > 0" "cball y e \<subseteq> {a..}"
  4271       using mem_interior_cball[of y "{a..}"] by auto
  4272     moreover from e have "y - e \<in> cball y e"
  4273       by (auto simp: cball_def dist_norm)
  4274     ultimately have "a \<le> y - e" by blast
  4275     then have "a < y" using e by auto
  4276   }
  4277   ultimately show ?thesis by auto
  4278 qed
  4279 
  4280 lemma continuous_ge_on_Ioo:
  4281   assumes "continuous_on {c..d} g" "\<And>x. x \<in> {c<..<d} \<Longrightarrow> g x \<ge> a" "c < d" "x \<in> {c..d}"
  4282   shows "g (x::real) \<ge> (a::real)"
  4283 proof-
  4284   from assms(3) have "{c..d} = closure {c<..<d}" by (rule closure_greaterThanLessThan[symmetric])
  4285   also from assms(2) have "{c<..<d} \<subseteq> (g -` {a..} \<inter> {c..d})" by auto
  4286   hence "closure {c<..<d} \<subseteq> closure (g -` {a..} \<inter> {c..d})" by (rule closure_mono)
  4287   also from assms(1) have "closed (g -` {a..} \<inter> {c..d})"
  4288     by (auto simp: continuous_on_closed_vimage)
  4289   hence "closure (g -` {a..} \<inter> {c..d}) = g -` {a..} \<inter> {c..d}" by simp
  4290   finally show ?thesis using \<open>x \<in> {c..d}\<close> by auto
  4291 qed
  4292 
  4293 lemma interior_real_semiline':
  4294   fixes a :: real
  4295   shows "interior {..a} = {..<a}"
  4296 proof -
  4297   {
  4298     fix y
  4299     assume "a > y"
  4300     then have "y \<in> interior {..a}"
  4301       apply (simp add: mem_interior)
  4302       apply (rule_tac x="(a-y)" in exI)
  4303       apply (auto simp: dist_norm)
  4304       done
  4305   }
  4306   moreover
  4307   {
  4308     fix y
  4309     assume "y \<in> interior {..a}"
  4310     then obtain e where e: "e > 0" "cball y e \<subseteq> {..a}"
  4311       using mem_interior_cball[of y "{..a}"] by auto
  4312     moreover from e have "y + e \<in> cball y e"
  4313       by (auto simp: cball_def dist_norm)
  4314     ultimately have "a \<ge> y + e" by auto
  4315     then have "a > y" using e by auto
  4316   }
  4317   ultimately show ?thesis by auto
  4318 qed
  4319 
  4320 lemma interior_atLeastAtMost_real [simp]: "interior {a..b} = {a<..<b :: real}"
  4321 proof-
  4322   have "{a..b} = {a..} \<inter> {..b}" by auto
  4323   also have "interior \<dots> = {a<..} \<inter> {..<b}"
  4324     by (simp add: interior_real_semiline interior_real_semiline')
  4325   also have "\<dots> = {a<..<b}" by auto
  4326   finally show ?thesis .
  4327 qed
  4328 
  4329 lemma interior_atLeastLessThan [simp]:
  4330   fixes a::real shows "interior {a..<b} = {a<..<b}"
  4331   by (metis atLeastLessThan_def greaterThanLessThan_def interior_atLeastAtMost_real interior_Int interior_interior interior_real_semiline)
  4332 
  4333 lemma interior_lessThanAtMost [simp]:
  4334   fixes a::real shows "interior {a<..b} = {a<..<b}"
  4335   by (metis atLeastAtMost_def greaterThanAtMost_def interior_atLeastAtMost_real interior_Int
  4336             interior_interior interior_real_semiline)
  4337 
  4338 lemma interior_greaterThanLessThan_real [simp]: "interior {a<..<b} = {a<..<b :: real}"
  4339   by (metis interior_atLeastAtMost_real interior_interior)
  4340 
  4341 lemma frontier_real_Iic [simp]:
  4342   fixes a :: real
  4343   shows "frontier {..a} = {a}"
  4344   unfolding frontier_def by (auto simp: interior_real_semiline')
  4345 
  4346 lemma rel_interior_real_box [simp]:
  4347   fixes a b :: real
  4348   assumes "a < b"
  4349   shows "rel_interior {a .. b} = {a <..< b}"
  4350 proof -
  4351   have "box a b \<noteq> {}"
  4352     using assms
  4353     unfolding set_eq_iff
  4354     by (auto intro!: exI[of _ "(a + b) / 2"] simp: box_def)
  4355   then show ?thesis
  4356     using interior_rel_interior_gen[of "cbox a b", symmetric]
  4357     by (simp split: if_split_asm del: box_real add: box_real[symmetric] interior_cbox)
  4358 qed
  4359 
  4360 lemma rel_interior_real_semiline [simp]:
  4361   fixes a :: real
  4362   shows "rel_interior {a..} = {a<..}"
  4363 proof -
  4364   have *: "{a<..} \<noteq> {}"
  4365     unfolding set_eq_iff by (auto intro!: exI[of _ "a + 1"])
  4366   then show ?thesis using interior_real_semiline interior_rel_interior_gen[of "{a..}"]
  4367     by (auto split: if_split_asm)
  4368 qed
  4369 
  4370 subsubsection \<open>Relative open sets\<close>
  4371 
  4372 definition%important "rel_open S \<longleftrightarrow> rel_interior S = S"
  4373 
  4374 lemma rel_open: "rel_open S \<longleftrightarrow> openin (subtopology euclidean (affine hull S)) S"
  4375   unfolding rel_open_def rel_interior_def
  4376   apply auto
  4377   using openin_subopen[of "subtopology euclidean (affine hull S)" S]
  4378   apply auto
  4379   done
  4380 
  4381 lemma openin_rel_interior: "openin (subtopology euclidean (affine hull S)) (rel_interior S)"
  4382   apply (simp add: rel_interior_def)
  4383   apply (subst openin_subopen, blast)
  4384   done
  4385 
  4386 lemma openin_set_rel_interior:
  4387    "openin (subtopology euclidean S) (rel_interior S)"
  4388 by (rule openin_subset_trans [OF openin_rel_interior rel_interior_subset hull_subset])
  4389 
  4390 lemma affine_rel_open:
  4391   fixes S :: "'n::euclidean_space set"
  4392   assumes "affine S"
  4393   shows "rel_open S"
  4394   unfolding rel_open_def
  4395   using assms rel_interior_affine_hull[of S] affine_hull_eq[of S]
  4396   by metis
  4397 
  4398 lemma affine_closed:
  4399   fixes S :: "'n::euclidean_space set"
  4400   assumes "affine S"
  4401   shows "closed S"
  4402 proof -
  4403   {
  4404     assume "S \<noteq> {}"
  4405     then obtain L where L: "subspace L" "affine_parallel S L"
  4406       using assms affine_parallel_subspace[of S] by auto
  4407     then obtain a where a: "S = ((+) a ` L)"
  4408       using affine_parallel_def[of L S] affine_parallel_commut by auto
  4409     from L have "closed L" using closed_subspace by auto
  4410     then have "closed S"
  4411       using closed_translation a by auto
  4412   }
  4413   then show ?thesis by auto
  4414 qed
  4415 
  4416 lemma closure_affine_hull:
  4417   fixes S :: "'n::euclidean_space set"
  4418   shows "closure S \<subseteq> affine hull S"
  4419   by (intro closure_minimal hull_subset affine_closed affine_affine_hull)
  4420 
  4421 lemma closure_same_affine_hull [simp]:
  4422   fixes S :: "'n::euclidean_space set"
  4423   shows "affine hull (closure S) = affine hull S"
  4424 proof -
  4425   have "affine hull (closure S) \<subseteq> affine hull S"
  4426     using hull_mono[of "closure S" "affine hull S" "affine"]
  4427       closure_affine_hull[of S] hull_hull[of "affine" S]
  4428     by auto
  4429   moreover have "affine hull (closure S) \<supseteq> affine hull S"
  4430     using hull_mono[of "S" "closure S" "affine"] closure_subset by auto
  4431   ultimately show ?thesis by auto
  4432 qed
  4433 
  4434 lemma closure_aff_dim [simp]:
  4435   fixes S :: "'n::euclidean_space set"
  4436   shows "aff_dim (closure S) = aff_dim S"
  4437 proof -
  4438   have "aff_dim S \<le> aff_dim (closure S)"
  4439     using aff_dim_subset closure_subset by auto
  4440   moreover have "aff_dim (closure S) \<le> aff_dim (affine hull S)"
  4441     using aff_dim_subset closure_affine_hull by blast
  4442   moreover have "aff_dim (affine hull S) = aff_dim S"
  4443     using aff_dim_affine_hull by auto
  4444   ultimately show ?thesis by auto
  4445 qed
  4446 
  4447 lemma rel_interior_closure_convex_shrink:
  4448   fixes S :: "_::euclidean_space set"
  4449   assumes "convex S"
  4450     and "c \<in> rel_interior S"
  4451     and "x \<in> closure S"
  4452     and "e > 0"
  4453     and "e \<le> 1"
  4454   shows "x - e *\<^sub>R (x - c) \<in> rel_interior S"
  4455 proof -
  4456   obtain d where "d > 0" and d: "ball c d \<inter> affine hull S \<subseteq> S"
  4457     using assms(2) unfolding mem_rel_interior_ball by auto
  4458   have "\<exists>y \<in> S. norm (y - x) * (1 - e) < e * d"
  4459   proof (cases "x \<in> S")
  4460     case True
  4461     then show ?thesis using \<open>e > 0\<close> \<open>d > 0\<close>
  4462       apply (rule_tac bexI[where x=x], auto)
  4463       done
  4464   next
  4465     case False
  4466     then have x: "x islimpt S"
  4467       using assms(3)[unfolded closure_def] by auto
  4468     show ?thesis
  4469     proof (cases "e = 1")
  4470       case True
  4471       obtain y where "y \<in> S" "y \<noteq> x" "dist y x < 1"
  4472         using x[unfolded islimpt_approachable,THEN spec[where x=1]] by auto
  4473       then show ?thesis
  4474         apply (rule_tac x=y in bexI)
  4475         unfolding True
  4476         using \<open>d > 0\<close>
  4477         apply auto
  4478         done
  4479     next
  4480       case False
  4481       then have "0 < e * d / (1 - e)" and *: "1 - e > 0"
  4482         using \<open>e \<le> 1\<close> \<open>e > 0\<close> \<open>d > 0\<close> by auto
  4483       then obtain y where "y \<in> S" "y \<noteq> x" "dist y x < e * d / (1 - e)"
  4484         using x[unfolded islimpt_approachable,THEN spec[where x="e*d / (1 - e)"]] by auto
  4485       then show ?thesis
  4486         apply (rule_tac x=y in bexI)
  4487         unfolding dist_norm
  4488         using pos_less_divide_eq[OF *]
  4489         apply auto
  4490         done
  4491     qed
  4492   qed
  4493   then obtain y where "y \<in> S" and y: "norm (y - x) * (1 - e) < e * d"
  4494     by auto
  4495   define z where "z = c + ((1 - e) / e) *\<^sub>R (x - y)"
  4496   have *: "x - e *\<^sub>R (x - c) = y - e *\<^sub>R (y - z)"
  4497     unfolding z_def using \<open>e > 0\<close>
  4498     by (auto simp: scaleR_right_diff_distrib scaleR_right_distrib scaleR_left_diff_distrib)
  4499   have zball: "z \<in> ball c d"
  4500     using mem_ball z_def dist_norm[of c]
  4501     using y and assms(4,5)
  4502     by (auto simp:field_simps norm_minus_commute)
  4503   have "x \<in> affine hull S"
  4504     using closure_affine_hull assms by auto
  4505   moreover have "y \<in> affine hull S"
  4506     using \<open>y \<in> S\<close> hull_subset[of S] by auto
  4507   moreover have "c \<in> affine hull S"
  4508     using assms rel_interior_subset hull_subset[of S] by auto
  4509   ultimately have "z \<in> affine hull S"
  4510     using z_def affine_affine_hull[of S]
  4511       mem_affine_3_minus [of "affine hull S" c x y "(1 - e) / e"]
  4512       assms
  4513     by (auto simp: field_simps)
  4514   then have "z \<in> S" using d zball by auto
  4515   obtain d1 where "d1 > 0" and d1: "ball z d1 \<le> ball c d"
  4516     using zball open_ball[of c d] openE[of "ball c d" z] by auto
  4517   then have "ball z d1 \<inter> affine hull S \<subseteq> ball c d \<inter> affine hull S"
  4518     by auto
  4519   then have "ball z d1 \<inter> affine hull S \<subseteq> S"
  4520     using d by auto
  4521   then have "z \<in> rel_interior S"
  4522     using mem_rel_interior_ball using \<open>d1 > 0\<close> \<open>z \<in> S\<close> by auto
  4523   then have "y - e *\<^sub>R (y - z) \<in> rel_interior S"
  4524     using rel_interior_convex_shrink[of S z y e] assms \<open>y \<in> S\<close> by auto
  4525   then show ?thesis using * by auto
  4526 qed
  4527 
  4528 lemma rel_interior_eq:
  4529    "rel_interior s = s \<longleftrightarrow> openin(subtopology euclidean (affine hull s)) s"
  4530 using rel_open rel_open_def by blast
  4531 
  4532 lemma rel_interior_openin:
  4533    "openin(subtopology euclidean (affine hull s)) s \<Longrightarrow> rel_interior s = s"
  4534 by (simp add: rel_interior_eq)
  4535 
  4536 lemma rel_interior_affine:
  4537   fixes S :: "'n::euclidean_space set"
  4538   shows  "affine S \<Longrightarrow> rel_interior S = S"
  4539 using affine_rel_open rel_open_def by auto
  4540 
  4541 lemma rel_interior_eq_closure:
  4542   fixes S :: "'n::euclidean_space set"
  4543   shows "rel_interior S = closure S \<longleftrightarrow> affine S"
  4544 proof (cases "S = {}")
  4545   case True
  4546  then show ?thesis
  4547     by auto
  4548 next
  4549   case False show ?thesis
  4550   proof
  4551     assume eq: "rel_interior S = closure S"
  4552     have "S = {} \<or> S = affine hull S"
  4553       apply (rule connected_clopen [THEN iffD1, rule_format])
  4554        apply (simp add: affine_imp_convex convex_connected)
  4555       apply (rule conjI)
  4556        apply (metis eq closure_subset openin_rel_interior rel_interior_subset subset_antisym)
  4557       apply (metis closed_subset closure_subset_eq eq hull_subset rel_interior_subset)
  4558       done
  4559     with False have "affine hull S = S"
  4560       by auto
  4561     then show "affine S"
  4562       by (metis affine_hull_eq)
  4563   next
  4564     assume "affine S"
  4565     then show "rel_interior S = closure S"
  4566       by (simp add: rel_interior_affine affine_closed)
  4567   qed
  4568 qed
  4569 
  4570 
  4571 subsubsection%unimportant\<open>Relative interior preserves under linear transformations\<close>
  4572 
  4573 lemma rel_interior_translation_aux:
  4574   fixes a :: "'n::euclidean_space"
  4575   shows "((\<lambda>x. a + x) ` rel_interior S) \<subseteq> rel_interior ((\<lambda>x. a + x) ` S)"
  4576 proof -
  4577   {
  4578     fix x
  4579     assume x: "x \<in> rel_interior S"
  4580     then obtain T where "open T" "x \<in> T \<inter> S" "T \<inter> affine hull S \<subseteq> S"
  4581       using mem_rel_interior[of x S] by auto
  4582     then have "open ((\<lambda>x. a + x) ` T)"
  4583       and "a + x \<in> ((\<lambda>x. a + x) ` T) \<inter> ((\<lambda>x. a + x) ` S)"
  4584       and "((\<lambda>x. a + x) ` T) \<inter> affine hull ((\<lambda>x. a + x) ` S) \<subseteq> (\<lambda>x. a + x) ` S"
  4585       using affine_hull_translation[of a S] open_translation[of T a] x by auto
  4586     then have "a + x \<in> rel_interior ((\<lambda>x. a + x) ` S)"
  4587       using mem_rel_interior[of "a+x" "((\<lambda>x. a + x) ` S)"] by auto
  4588   }
  4589   then show ?thesis by auto
  4590 qed
  4591 
  4592 lemma rel_interior_translation:
  4593   fixes a :: "'n::euclidean_space"
  4594   shows "rel_interior ((\<lambda>x. a + x) ` S) = (\<lambda>x. a + x) ` rel_interior S"
  4595 proof -
  4596   have "(\<lambda>x. (-a) + x) ` rel_interior ((\<lambda>x. a + x) ` S) \<subseteq> rel_interior S"
  4597     using rel_interior_translation_aux[of "-a" "(\<lambda>x. a + x) ` S"]
  4598       translation_assoc[of "-a" "a"]
  4599     by auto
  4600   then have "((\<lambda>x. a + x) ` rel_interior S) \<supseteq> rel_interior ((\<lambda>x. a + x) ` S)"
  4601     using translation_inverse_subset[of a "rel_interior ((+) a ` S)" "rel_interior S"]
  4602     by auto
  4603   then show ?thesis
  4604     using rel_interior_translation_aux[of a S] by auto
  4605 qed
  4606 
  4607 
  4608 lemma affine_hull_linear_image:
  4609   assumes "bounded_linear f"
  4610   shows "f ` (affine hull s) = affine hull f ` s"
  4611 proof -
  4612   interpret f: bounded_linear f by fact
  4613   have "affine {x. f x \<in> affine hull f ` s}"
  4614     unfolding affine_def
  4615     by (auto simp: f.scaleR f.add affine_affine_hull[unfolded affine_def, rule_format])
  4616   moreover have "affine {x. x \<in> f ` (affine hull s)}"
  4617     using affine_affine_hull[unfolded affine_def, of s]
  4618     unfolding affine_def by (auto simp: f.scaleR [symmetric] f.add [symmetric])
  4619   ultimately show ?thesis
  4620     by (auto simp: hull_inc elim!: hull_induct)
  4621 qed 
  4622 
  4623 
  4624 lemma rel_interior_injective_on_span_linear_image:
  4625   fixes f :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space"
  4626     and S :: "'m::euclidean_space set"
  4627   assumes "bounded_linear f"
  4628     and "inj_on f (span S)"
  4629   shows "rel_interior (f ` S) = f ` (rel_interior S)"
  4630 proof -
  4631   {
  4632     fix z
  4633     assume z: "z \<in> rel_interior (f ` S)"
  4634     then have "z \<in> f ` S"
  4635       using rel_interior_subset[of "f ` S"] by auto
  4636     then obtain x where x: "x \<in> S" "f x = z" by auto
  4637     obtain e2 where e2: "e2 > 0" "cball z e2 \<inter> affine hull (f ` S) \<subseteq> (f ` S)"
  4638       using z rel_interior_cball[of "f ` S"] by auto
  4639     obtain K where K: "K > 0" "\<And>x. norm (f x) \<le> norm x * K"
  4640      using assms Real_Vector_Spaces.bounded_linear.pos_bounded[of f] by auto
  4641     define e1 where "e1 = 1 / K"
  4642     then have e1: "e1 > 0" "\<And>x. e1 * norm (f x) \<le> norm x"
  4643       using K pos_le_divide_eq[of e1] by auto
  4644     define e where "e = e1 * e2"
  4645     then have "e > 0" using e1 e2 by auto
  4646     {
  4647       fix y
  4648       assume y: "y \<in> cball x e \<inter> affine hull S"
  4649       then have h1: "f y \<in> affine hull (f ` S)"
  4650         using affine_hull_linear_image[of f S] assms by auto
  4651       from y have "norm (x-y) \<le> e1 * e2"
  4652         using cball_def[of x e] dist_norm[of x y] e_def by auto
  4653       moreover have "f x - f y = f (x - y)"
  4654         using assms linear_diff[of f x y] linear_conv_bounded_linear[of f] by auto
  4655       moreover have "e1 * norm (f (x-y)) \<le> norm (x - y)"
  4656         using e1 by auto
  4657       ultimately have "e1 * norm ((f x)-(f y)) \<le> e1 * e2"
  4658         by auto
  4659       then have "f y \<in> cball z e2"
  4660         using cball_def[of "f x" e2] dist_norm[of "f x" "f y"] e1 x by auto
  4661       then have "f y \<in> f ` S"
  4662         using y e2 h1 by auto
  4663       then have "y \<in> S"
  4664         using assms y hull_subset[of S] affine_hull_subset_span
  4665           inj_on_image_mem_iff [OF \<open>inj_on f (span S)\<close>]
  4666         by (metis Int_iff span_superset subsetCE)
  4667     }
  4668     then have "z \<in> f ` (rel_interior S)"
  4669       using mem_rel_interior_cball[of x S] \<open>e > 0\<close> x by auto
  4670   }
  4671   moreover
  4672   {
  4673     fix x
  4674     assume x: "x \<in> rel_interior S"
  4675     then obtain e2 where e2: "e2 > 0" "cball x e2 \<inter> affine hull S \<subseteq> S"
  4676       using rel_interior_cball[of S] by auto
  4677     have "x \<in> S" using x rel_interior_subset by auto
  4678     then have *: "f x \<in> f ` S" by auto
  4679     have "\<forall>x\<in>span S. f x = 0 \<longrightarrow> x = 0"
  4680       using assms subspace_span linear_conv_bounded_linear[of f]
  4681         linear_injective_on_subspace_0[of f "span S"]
  4682       by auto
  4683     then obtain e1 where e1: "e1 > 0" "\<forall>x \<in> span S. e1 * norm x \<le> norm (f x)"
  4684       using assms injective_imp_isometric[of "span S" f]
  4685         subspace_span[of S] closed_subspace[of "span S"]
  4686       by auto
  4687     define e where "e = e1 * e2"
  4688     hence "e > 0" using e1 e2 by auto
  4689     {
  4690       fix y
  4691       assume y: "y \<in> cball (f x) e \<inter> affine hull (f ` S)"
  4692       then have "y \<in> f ` (affine hull S)"
  4693         using affine_hull_linear_image[of f S] assms by auto
  4694       then obtain xy where xy: "xy \<in> affine hull S" "f xy = y" by auto
  4695       with y have "norm (f x - f xy) \<le> e1 * e2"
  4696         using cball_def[of "f x" e] dist_norm[of "f x" y] e_def by auto
  4697       moreover have "f x - f xy = f (x - xy)"
  4698         using assms linear_diff[of f x xy] linear_conv_bounded_linear[of f] by auto
  4699       moreover have *: "x - xy \<in> span S"
  4700         using subspace_diff[of "span S" x xy] subspace_span \<open>x \<in> S\<close> xy
  4701           affine_hull_subset_span[of S] span_superset
  4702         by auto
  4703       moreover from * have "e1 * norm (x - xy) \<le> norm (f (x - xy))"
  4704         using e1 by auto
  4705       ultimately have "e1 * norm (x - xy) \<le> e1 * e2"
  4706         by auto
  4707       then have "xy \<in> cball x e2"
  4708         using cball_def[of x e2] dist_norm[of x xy] e1 by auto
  4709       then have "y \<in> f ` S"
  4710         using xy e2 by auto
  4711     }
  4712     then have "f x \<in> rel_interior (f ` S)"
  4713       using mem_rel_interior_cball[of "(f x)" "(f ` S)"] * \<open>e > 0\<close> by auto
  4714   }
  4715   ultimately show ?thesis by auto
  4716 qed
  4717 
  4718 lemma rel_interior_injective_linear_image:
  4719   fixes f :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space"
  4720   assumes "bounded_linear f"
  4721     and "inj f"
  4722   shows "rel_interior (f ` S) = f ` (rel_interior S)"
  4723   using assms rel_interior_injective_on_span_linear_image[of f S]
  4724     subset_inj_on[of f "UNIV" "span S"]
  4725   by auto
  4726 
  4727 
  4728 subsection%unimportant\<open>Some Properties of subset of standard basis\<close>
  4729 
  4730 lemma affine_hull_substd_basis:
  4731   assumes "d \<subseteq> Basis"
  4732   shows "affine hull (insert 0 d) = {x::'a::euclidean_space. \<forall>i\<in>Basis. i \<notin> d \<longrightarrow> x\<bullet>i = 0}"
  4733   (is "affine hull (insert 0 ?A) = ?B")
  4734 proof -
  4735   have *: "\<And>A. (+) (0::'a) ` A = A" "\<And>A. (+) (- (0::'a)) ` A = A"
  4736     by auto
  4737   show ?thesis
  4738     unfolding affine_hull_insert_span_gen span_substd_basis[OF assms,symmetric] * ..
  4739 qed
  4740 
  4741 lemma affine_hull_convex_hull [simp]: "affine hull (convex hull S) = affine hull S"
  4742   by (metis Int_absorb1 Int_absorb2 convex_hull_subset_affine_hull hull_hull hull_mono hull_subset)
  4743 
  4744 
  4745 subsection%unimportant \<open>Openness and compactness are preserved by convex hull operation\<close>
  4746 
  4747 lemma open_convex_hull[intro]:
  4748   fixes S :: "'a::real_normed_vector set"
  4749   assumes "open S"
  4750   shows "open (convex hull S)"
  4751 proof (clarsimp simp: open_contains_cball convex_hull_explicit)
  4752   fix T and u :: "'a\<Rightarrow>real"
  4753   assume obt: "finite T" "T\<subseteq>S" "\<forall>x\<in>T. 0 \<le> u x" "sum u T = 1" 
  4754 
  4755   from assms[unfolded open_contains_cball] obtain b
  4756     where b: "\<And>x. x\<in>S \<Longrightarrow> 0 < b x \<and> cball x (b x) \<subseteq> S" by metis
  4757   have "b ` T \<noteq> {}"
  4758     using obt by auto
  4759   define i where "i = b ` T"
  4760   let ?\<Phi> = "\<lambda>y. \<exists>F. finite F \<and> F \<subseteq> S \<and> (\<exists>u. (\<forall>x\<in>F. 0 \<le> u x) \<and> sum u F = 1 \<and> (\<Sum>v\<in>F. u v *\<^sub>R v) = y)"
  4761   let ?a = "\<Sum>v\<in>T. u v *\<^sub>R v"
  4762   show "\<exists>e > 0. cball ?a e \<subseteq> {y. ?\<Phi> y}"
  4763   proof (intro exI subsetI conjI)
  4764     show "0 < Min i"
  4765       unfolding i_def and Min_gr_iff[OF finite_imageI[OF obt(1)] \<open>b ` T\<noteq>{}\<close>]
  4766       using b \<open>T\<subseteq>S\<close> by auto
  4767   next
  4768     fix y
  4769     assume "y \<in> cball ?a (Min i)"
  4770     then have y: "norm (?a - y) \<le> Min i"
  4771       unfolding dist_norm[symmetric] by auto
  4772     { fix x
  4773       assume "x \<in> T"
  4774       then have "Min i \<le> b x"
  4775         by (simp add: i_def obt(1))
  4776       then have "x + (y - ?a) \<in> cball x (b x)"
  4777         using y unfolding mem_cball dist_norm by auto
  4778       moreover have "x \<in> S"
  4779         using \<open>x\<in>T\<close> \<open>T\<subseteq>S\<close> by auto
  4780       ultimately have "x + (y - ?a) \<in> S"
  4781         using y b by blast
  4782     }
  4783     moreover
  4784     have *: "inj_on (\<lambda>v. v + (y - ?a)) T"
  4785       unfolding inj_on_def by auto
  4786     have "(\<Sum>v\<in>(\<lambda>v. v + (y - ?a)) ` T. u (v - (y - ?a)) *\<^sub>R v) = y"
  4787       unfolding sum.reindex[OF *] o_def using obt(4)
  4788       by (simp add: sum.distrib sum_subtractf scaleR_left.sum[symmetric] scaleR_right_distrib)
  4789     ultimately show "y \<in> {y. ?\<Phi> y}"
  4790     proof (intro CollectI exI conjI)
  4791       show "finite ((\<lambda>v. v + (y - ?a)) ` T)"
  4792         by (simp add: obt(1))
  4793       show "sum (\<lambda>v. u (v - (y - ?a))) ((\<lambda>v. v + (y - ?a)) ` T) = 1"
  4794         unfolding sum.reindex[OF *] o_def using obt(4) by auto
  4795     qed (use obt(1, 3) in auto)
  4796   qed
  4797 qed
  4798 
  4799 lemma compact_convex_combinations:
  4800   fixes S T :: "'a::real_normed_vector set"
  4801   assumes "compact S" "compact T"
  4802   shows "compact { (1 - u) *\<^sub>R x + u *\<^sub>R y | x y u. 0 \<le> u \<and> u \<le> 1 \<and> x \<in> S \<and> y \<in> T}"
  4803 proof -
  4804   let ?X = "{0..1} \<times> S \<times> T"
  4805   let ?h = "(\<lambda>z. (1 - fst z) *\<^sub>R fst (snd z) + fst z *\<^sub>R snd (snd z))"
  4806   have *: "{ (1 - u) *\<^sub>R x + u *\<^sub>R y | x y u. 0 \<le> u \<and> u \<le> 1 \<and> x \<in> S \<and> y \<in> T} = ?h ` ?X"
  4807     by force
  4808   have "continuous_on ?X (\<lambda>z. (1 - fst z) *\<^sub>R fst (snd z) + fst z *\<^sub>R snd (snd z))"
  4809     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  4810   with assms show ?thesis
  4811     by (simp add: * compact_Times compact_continuous_image)
  4812 qed
  4813 
  4814 lemma finite_imp_compact_convex_hull:
  4815   fixes S :: "'a::real_normed_vector set"
  4816   assumes "finite S"
  4817   shows "compact (convex hull S)"
  4818 proof (cases "S = {}")
  4819   case True
  4820   then show ?thesis by simp
  4821 next
  4822   case False
  4823   with assms show ?thesis
  4824   proof (induct rule: finite_ne_induct)
  4825     case (singleton x)
  4826     show ?case by simp
  4827   next
  4828     case (insert x A)
  4829     let ?f = "\<lambda>(u, y::'a). u *\<^sub>R x + (1 - u) *\<^sub>R y"
  4830     let ?T = "{0..1::real} \<times> (convex hull A)"
  4831     have "continuous_on ?T ?f"
  4832       unfolding split_def continuous_on by (intro ballI tendsto_intros)
  4833     moreover have "compact ?T"
  4834       by (intro compact_Times compact_Icc insert)
  4835     ultimately have "compact (?f ` ?T)"
  4836       by (rule compact_continuous_image)
  4837     also have "?f ` ?T = convex hull (insert x A)"
  4838       unfolding convex_hull_insert [OF \<open>A \<noteq> {}\<close>]
  4839       apply safe
  4840       apply (rule_tac x=a in exI, simp)
  4841       apply (rule_tac x="1 - a" in exI, simp, fast)
  4842       apply (rule_tac x="(u, b)" in image_eqI, simp_all)
  4843       done
  4844     finally show "compact (convex hull (insert x A))" .
  4845   qed
  4846 qed
  4847 
  4848 lemma compact_convex_hull:
  4849   fixes S :: "'a::euclidean_space set"
  4850   assumes "compact S"
  4851   shows "compact (convex hull S)"
  4852 proof (cases "S = {}")
  4853   case True
  4854   then show ?thesis using compact_empty by simp
  4855 next
  4856   case False
  4857   then obtain w where "w \<in> S" by auto
  4858   show ?thesis
  4859     unfolding caratheodory[of S]
  4860   proof (induct ("DIM('a) + 1"))
  4861     case 0
  4862     have *: "{x.\<exists>sa. finite sa \<and> sa \<subseteq> S \<and> card sa \<le> 0 \<and> x \<in> convex hull sa} = {}"
  4863       using compact_empty by auto
  4864     from 0 show ?case unfolding * by simp
  4865   next
  4866     case (Suc n)
  4867     show ?case
  4868     proof (cases "n = 0")
  4869       case True
  4870       have "{x. \<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> Suc n \<and> x \<in> convex hull T} = S"
  4871         unfolding set_eq_iff and mem_Collect_eq
  4872       proof (rule, rule)
  4873         fix x
  4874         assume "\<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> Suc n \<and> x \<in> convex hull T"
  4875         then obtain T where T: "finite T" "T \<subseteq> S" "card T \<le> Suc n" "x \<in> convex hull T"
  4876           by auto
  4877         show "x \<in> S"
  4878         proof (cases "card T = 0")
  4879           case True
  4880           then show ?thesis
  4881             using T(4) unfolding card_0_eq[OF T(1)] by simp
  4882         next
  4883           case False
  4884           then have "card T = Suc 0" using T(3) \<open>n=0\<close> by auto
  4885           then obtain a where "T = {a}" unfolding card_Suc_eq by auto
  4886           then show ?thesis using T(2,4) by simp
  4887         qed
  4888       next
  4889         fix x assume "x\<in>S"
  4890         then show "\<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> Suc n \<and> x \<in> convex hull T"
  4891           apply (rule_tac x="{x}" in exI)
  4892           unfolding convex_hull_singleton
  4893           apply auto
  4894           done
  4895       qed
  4896       then show ?thesis using assms by simp
  4897     next
  4898       case False
  4899       have "{x. \<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> Suc n \<and> x \<in> convex hull T} =
  4900         {(1 - u) *\<^sub>R x + u *\<^sub>R y | x y u.
  4901           0 \<le> u \<and> u \<le> 1 \<and> x \<in> S \<and> y \<in> {x. \<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> n \<and> x \<in> convex hull T}}"
  4902         unfolding set_eq_iff and mem_Collect_eq
  4903       proof (rule, rule)
  4904         fix x
  4905         assume "\<exists>u v c. x = (1 - c) *\<^sub>R u + c *\<^sub>R v \<and>
  4906           0 \<le> c \<and> c \<le> 1 \<and> u \<in> S \<and> (\<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> n \<and> v \<in> convex hull T)"
  4907         then obtain u v c T where obt: "x = (1 - c) *\<^sub>R u + c *\<^sub>R v"
  4908           "0 \<le> c \<and> c \<le> 1" "u \<in> S" "finite T" "T \<subseteq> S" "card T \<le> n"  "v \<in> convex hull T"
  4909           by auto
  4910         moreover have "(1 - c) *\<^sub>R u + c *\<^sub>R v \<in> convex hull insert u T"
  4911           apply (rule convexD_alt)
  4912           using obt(2) and convex_convex_hull and hull_subset[of "insert u T" convex]
  4913           using obt(7) and hull_mono[of T "insert u T"]
  4914           apply auto
  4915           done
  4916         ultimately show "\<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> Suc n \<and> x \<in> convex hull T"
  4917           apply (rule_tac x="insert u T" in exI)
  4918           apply (auto simp: card_insert_if)
  4919           done
  4920       next
  4921         fix x
  4922         assume "\<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> Suc n \<and> x \<in> convex hull T"
  4923         then obtain T where T: "finite T" "T \<subseteq> S" "card T \<le> Suc n" "x \<in> convex hull T"
  4924           by auto
  4925         show "\<exists>u v c. x = (1 - c) *\<^sub>R u + c *\<^sub>R v \<and>
  4926           0 \<le> c \<and> c \<le> 1 \<and> u \<in> S \<and> (\<exists>T. finite T \<and> T \<subseteq> S \<and> card T \<le> n \<and> v \<in> convex hull T)"
  4927         proof (cases "card T = Suc n")
  4928           case False
  4929           then have "card T \<le> n" using T(3) by auto
  4930           then show ?thesis
  4931             apply (rule_tac x=w in exI, rule_tac x=x in exI, rule_tac x=1 in exI)
  4932             using \<open>w\<in>S\<close> and T
  4933             apply (auto intro!: exI[where x=T])
  4934             done
  4935         next
  4936           case True
  4937           then obtain a u where au: "T = insert a u" "a\<notin>u"
  4938             apply (drule_tac card_eq_SucD, auto)
  4939             done
  4940           show ?thesis
  4941           proof (cases "u = {}")
  4942             case True
  4943             then have "x = a" using T(4)[unfolded au] by auto
  4944             show ?thesis unfolding \<open>x = a\<close>
  4945               apply (rule_tac x=a in exI)
  4946               apply (rule_tac x=a in exI)
  4947               apply (rule_tac x=1 in exI)
  4948               using T and \<open>n \<noteq> 0\<close>
  4949               unfolding au
  4950               apply (auto intro!: exI[where x="{a}"])
  4951               done
  4952           next
  4953             case False
  4954             obtain ux vx b where obt: "ux\<ge>0" "vx\<ge>0" "ux + vx = 1"
  4955               "b \<in> convex hull u" "x = ux *\<^sub>R a + vx *\<^sub>R b"
  4956               using T(4)[unfolded au convex_hull_insert[OF False]]
  4957               by auto
  4958             have *: "1 - vx = ux" using obt(3) by auto
  4959             show ?thesis
  4960               apply (rule_tac x=a in exI)
  4961               apply (rule_tac x=b in exI)
  4962               apply (rule_tac x=vx in exI)
  4963               using obt and T(1-3)
  4964               unfolding au and * using card_insert_disjoint[OF _ au(2)]
  4965               apply (auto intro!: exI[where x=u])
  4966               done
  4967           qed
  4968         qed
  4969       qed
  4970       then show ?thesis
  4971         using compact_convex_combinations[OF assms Suc] by simp
  4972     qed
  4973   qed
  4974 qed
  4975 
  4976 
  4977 subsection%unimportant \<open>Extremal points of a simplex are some vertices\<close>
  4978 
  4979 lemma dist_increases_online:
  4980   fixes a b d :: "'a::real_inner"
  4981   assumes "d \<noteq> 0"
  4982   shows "dist a (b + d) > dist a b \<or> dist a (b - d) > dist a b"
  4983 proof (cases "inner a d - inner b d > 0")
  4984   case True
  4985   then have "0 < inner d d + (inner a d * 2 - inner b d * 2)"
  4986     apply (rule_tac add_pos_pos)
  4987     using assms
  4988     apply auto
  4989     done
  4990   then show ?thesis
  4991     apply (rule_tac disjI2)
  4992     unfolding dist_norm and norm_eq_sqrt_inner and real_sqrt_less_iff
  4993     apply  (simp add: algebra_simps inner_commute)
  4994     done
  4995 next
  4996   case False
  4997   then have "0 < inner d d + (inner b d * 2 - inner a d * 2)"
  4998     apply (rule_tac add_pos_nonneg)
  4999     using assms
  5000     apply auto
  5001     done
  5002   then show ?thesis
  5003     apply (rule_tac disjI1)
  5004     unfolding dist_norm and norm_eq_sqrt_inner and real_sqrt_less_iff
  5005     apply (simp add: algebra_simps inner_commute)
  5006     done
  5007 qed
  5008 
  5009 lemma norm_increases_online:
  5010   fixes d :: "'a::real_inner"
  5011   shows "d \<noteq> 0 \<Longrightarrow> norm (a + d) > norm a \<or> norm(a - d) > norm a"
  5012   using dist_increases_online[of d a 0] unfolding dist_norm by auto
  5013 
  5014 lemma simplex_furthest_lt:
  5015   fixes S :: "'a::real_inner set"
  5016   assumes "finite S"
  5017   shows "\<forall>x \<in> convex hull S.  x \<notin> S \<longrightarrow> (\<exists>y \<in> convex hull S. norm (x - a) < norm(y - a))"
  5018   using assms
  5019 proof induct
  5020   fix x S
  5021   assume as: "finite S" "x\<notin>S" "\<forall>x\<in>convex hull S. x \<notin> S \<longrightarrow> (\<exists>y\<in>convex hull S. norm (x - a) < norm (y - a))"
  5022   show "\<forall>xa\<in>convex hull insert x S. xa \<notin> insert x S \<longrightarrow>
  5023     (\<exists>y\<in>convex hull insert x S. norm (xa - a) < norm (y - a))"
  5024   proof (intro impI ballI, cases "S = {}")
  5025     case False
  5026     fix y
  5027     assume y: "y \<in> convex hull insert x S" "y \<notin> insert x S"
  5028     obtain u v b where obt: "u\<ge>0" "v\<ge>0" "u + v = 1" "b \<in> convex hull S" "y = u *\<^sub>R x + v *\<^sub>R b"
  5029       using y(1)[unfolded convex_hull_insert[OF False]] by auto
  5030     show "\<exists>z\<in>convex hull insert x S. norm (y - a) < norm (z - a)"
  5031     proof (cases "y \<in> convex hull S")
  5032       case True
  5033       then obtain z where "z \<in> convex hull S" "norm (y - a) < norm (z - a)"
  5034         using as(3)[THEN bspec[where x=y]] and y(2) by auto
  5035       then show ?thesis
  5036         apply (rule_tac x=z in bexI)
  5037         unfolding convex_hull_insert[OF False]
  5038         apply auto
  5039         done
  5040     next
  5041       case False
  5042       show ?thesis
  5043         using obt(3)
  5044       proof (cases "u = 0", case_tac[!] "v = 0")
  5045         assume "u = 0" "v \<noteq> 0"
  5046         then have "y = b" using obt by auto
  5047         then show ?thesis using False and obt(4) by auto
  5048       next
  5049         assume "u \<noteq> 0" "v = 0"
  5050         then have "y = x" using obt by auto
  5051         then show ?thesis using y(2) by auto
  5052       next
  5053         assume "u \<noteq> 0" "v \<noteq> 0"
  5054         then obtain w where w: "w>0" "w<u" "w<v"
  5055           using field_lbound_gt_zero[of u v] and obt(1,2) by auto
  5056         have "x \<noteq> b"
  5057         proof
  5058           assume "x = b"
  5059           then have "y = b" unfolding obt(5)
  5060             using obt(3) by (auto simp: scaleR_left_distrib[symmetric])
  5061           then show False using obt(4) and False by simp
  5062         qed
  5063         then have *: "w *\<^sub>R (x - b) \<noteq> 0" using w(1) by auto
  5064         show ?thesis
  5065           using dist_increases_online[OF *, of a y]
  5066         proof (elim disjE)
  5067           assume "dist a y < dist a (y + w *\<^sub>R (x - b))"
  5068           then have "norm (y - a) < norm ((u + w) *\<^sub>R x + (v - w) *\<^sub>R b - a)"
  5069             unfolding dist_commute[of a]
  5070             unfolding dist_norm obt(5)
  5071             by (simp add: algebra_simps)
  5072           moreover have "(u + w) *\<^sub>R x + (v - w) *\<^sub>R b \<in> convex hull insert x S"
  5073             unfolding convex_hull_insert[OF \<open>S\<noteq>{}\<close>]
  5074           proof (intro CollectI conjI exI)
  5075             show "u + w \<ge> 0" "v - w \<ge> 0"
  5076               using obt(1) w by auto
  5077           qed (use obt in auto)
  5078           ultimately show ?thesis by auto
  5079         next
  5080           assume "dist a y < dist a (y - w *\<^sub>R (x - b))"
  5081           then have "norm (y - a) < norm ((u - w) *\<^sub>R x + (v + w) *\<^sub>R b - a)"
  5082             unfolding dist_commute[of a]
  5083             unfolding dist_norm obt(5)
  5084             by (simp add: algebra_simps)
  5085           moreover have "(u - w) *\<^sub>R x + (v + w) *\<^sub>R b \<in> convex hull insert x S"
  5086             unfolding convex_hull_insert[OF \<open>S\<noteq>{}\<close>]
  5087           proof (intro CollectI conjI exI)
  5088             show "u - w \<ge> 0" "v + w \<ge> 0"
  5089               using obt(1) w by auto
  5090           qed (use obt in auto)
  5091           ultimately show ?thesis by auto
  5092         qed
  5093       qed auto
  5094     qed
  5095   qed auto
  5096 qed (auto simp: assms)
  5097 
  5098 lemma simplex_furthest_le:
  5099   fixes S :: "'a::real_inner set"
  5100   assumes "finite S"
  5101     and "S \<noteq> {}"
  5102   shows "\<exists>y\<in>S. \<forall>x\<in> convex hull S. norm (x - a) \<le> norm (y - a)"
  5103 proof -
  5104   have "convex hull S \<noteq> {}"
  5105     using hull_subset[of S convex] and assms(2) by auto
  5106   then obtain x where x: "x \<in> convex hull S" "\<forall>y\<in>convex hull S. norm (y - a) \<le> norm (x - a)"
  5107     using distance_attains_sup[OF finite_imp_compact_convex_hull[OF \<open>finite S\<close>], of a]
  5108     unfolding dist_commute[of a]
  5109     unfolding dist_norm
  5110     by auto
  5111   show ?thesis
  5112   proof (cases "x \<in> S")
  5113     case False
  5114     then obtain y where "y \<in> convex hull S" "norm (x - a) < norm (y - a)"
  5115       using simplex_furthest_lt[OF assms(1), THEN bspec[where x=x]] and x(1)
  5116       by auto
  5117     then show ?thesis
  5118       using x(2)[THEN bspec[where x=y]] by auto
  5119   next
  5120     case True
  5121     with x show ?thesis by auto
  5122   qed
  5123 qed
  5124 
  5125 lemma simplex_furthest_le_exists:
  5126   fixes S :: "('a::real_inner) set"
  5127   shows "finite S \<Longrightarrow> \<forall>x\<in>(convex hull S). \<exists>y\<in>S. norm (x - a) \<le> norm (y - a)"
  5128   using simplex_furthest_le[of S] by (cases "S = {}") auto
  5129 
  5130 lemma simplex_extremal_le:
  5131   fixes S :: "'a::real_inner set"
  5132   assumes "finite S"
  5133     and "S \<noteq> {}"
  5134   shows "\<exists>u\<in>S. \<exists>v\<in>S. \<forall>x\<in>convex hull S. \<forall>y \<in> convex hull S. norm (x - y) \<le> norm (u - v)"
  5135 proof -
  5136   have "convex hull S \<noteq> {}"
  5137     using hull_subset[of S convex] and assms(2) by auto
  5138   then obtain u v where obt: "u \<in> convex hull S" "v \<in> convex hull S"
  5139     "\<forall>x\<in>convex hull S. \<forall>y\<in>convex hull S. norm (x - y) \<le> norm (u - v)"
  5140     using compact_sup_maxdistance[OF finite_imp_compact_convex_hull[OF assms(1)]]
  5141     by (auto simp: dist_norm)
  5142   then show ?thesis
  5143   proof (cases "u\<notin>S \<or> v\<notin>S", elim disjE)
  5144     assume "u \<notin> S"
  5145     then obtain y where "y \<in> convex hull S" "norm (u - v) < norm (y - v)"
  5146       using simplex_furthest_lt[OF assms(1), THEN bspec[where x=u]] and obt(1)
  5147       by auto
  5148     then show ?thesis
  5149       using obt(3)[THEN bspec[where x=y], THEN bspec[where x=v]] and obt(2)
  5150       by auto
  5151   next
  5152     assume "v \<notin> S"
  5153     then obtain y where "y \<in> convex hull S" "norm (v - u) < norm (y - u)"
  5154       using simplex_furthest_lt[OF assms(1), THEN bspec[where x=v]] and obt(2)
  5155       by auto
  5156     then show ?thesis
  5157       using obt(3)[THEN bspec[where x=u], THEN bspec[where x=y]] and obt(1)
  5158       by (auto simp: norm_minus_commute)
  5159   qed auto
  5160 qed
  5161 
  5162 lemma simplex_extremal_le_exists:
  5163   fixes S :: "'a::real_inner set"
  5164   shows "finite S \<Longrightarrow> x \<in> convex hull S \<Longrightarrow> y \<in> convex hull S \<Longrightarrow>
  5165     \<exists>u\<in>S. \<exists>v\<in>S. norm (x - y) \<le> norm (u - v)"
  5166   using convex_hull_empty simplex_extremal_le[of S]
  5167   by(cases "S = {}") auto
  5168 
  5169 
  5170 subsection \<open>Closest point of a convex set is unique, with a continuous projection\<close>
  5171 
  5172 definition%important closest_point :: "'a::{real_inner,heine_borel} set \<Rightarrow> 'a \<Rightarrow> 'a"
  5173   where "closest_point S a = (SOME x. x \<in> S \<and> (\<forall>y\<in>S. dist a x \<le> dist a y))"
  5174 
  5175 lemma closest_point_exists:
  5176   assumes "closed S"
  5177     and "S \<noteq> {}"
  5178   shows "closest_point S a \<in> S"
  5179     and "\<forall>y\<in>S. dist a (closest_point S a) \<le> dist a y"
  5180   unfolding closest_point_def
  5181   apply(rule_tac[!] someI2_ex)
  5182   apply (auto intro: distance_attains_inf[OF assms(1,2), of a])
  5183   done
  5184 
  5185 lemma closest_point_in_set: "closed S \<Longrightarrow> S \<noteq> {} \<Longrightarrow> closest_point S a \<in> S"
  5186   by (meson closest_point_exists)
  5187 
  5188 lemma closest_point_le: "closed S \<Longrightarrow> x \<in> S \<Longrightarrow> dist a (closest_point S a) \<le> dist a x"
  5189   using closest_point_exists[of S] by auto
  5190 
  5191 lemma closest_point_self:
  5192   assumes "x \<in> S"
  5193   shows "closest_point S x = x"
  5194   unfolding closest_point_def
  5195   apply (rule some1_equality, rule ex1I[of _ x])
  5196   using assms
  5197   apply auto
  5198   done
  5199 
  5200 lemma closest_point_refl: "closed S \<Longrightarrow> S \<noteq> {} \<Longrightarrow> closest_point S x = x \<longleftrightarrow> x \<in> S"
  5201   using closest_point_in_set[of S x] closest_point_self[of x S]
  5202   by auto
  5203 
  5204 lemma closer_points_lemma:
  5205   assumes "inner y z > 0"
  5206   shows "\<exists>u>0. \<forall>v>0. v \<le> u \<longrightarrow> norm(v *\<^sub>R z - y) < norm y"
  5207 proof -
  5208   have z: "inner z z > 0"
  5209     unfolding inner_gt_zero_iff using assms by auto
  5210   have "norm (v *\<^sub>R z - y) < norm y"
  5211     if "0 < v" and "v \<le> inner y z / inner z z" for v
  5212     unfolding norm_lt using z assms that
  5213     by (simp add: field_simps inner_diff inner_commute mult_strict_left_mono[OF _ \<open>0<v\<close>])
  5214   then show ?thesis
  5215     using assms z
  5216     by (rule_tac x = "inner y z / inner z z" in exI) auto
  5217 qed
  5218 
  5219 lemma closer_point_lemma:
  5220   assumes "inner (y - x) (z - x) > 0"
  5221   shows "\<exists>u>0. u \<le> 1 \<and> dist (x + u *\<^sub>R (z - x)) y < dist x y"
  5222 proof -
  5223   obtain u where "u > 0"
  5224     and u: "\<forall>v>0. v \<le> u \<longrightarrow> norm (v *\<^sub>R (z - x) - (y - x)) < norm (y - x)"
  5225     using closer_points_lemma[OF assms] by auto
  5226   show ?thesis
  5227     apply (rule_tac x="min u 1" in exI)
  5228     using u[THEN spec[where x="min u 1"]] and \<open>u > 0\<close>
  5229     unfolding dist_norm by (auto simp: norm_minus_commute field_simps)
  5230 qed
  5231 
  5232 lemma any_closest_point_dot:
  5233   assumes "convex S" "closed S" "x \<in> S" "y \<in> S" "\<forall>z\<in>S. dist a x \<le> dist a z"
  5234   shows "inner (a - x) (y - x) \<le> 0"
  5235 proof (rule ccontr)
  5236   assume "\<not> ?thesis"
  5237   then obtain u where u: "u>0" "u\<le>1" "dist (x + u *\<^sub>R (y - x)) a < dist x a"
  5238     using closer_point_lemma[of a x y] by auto
  5239   let ?z = "(1 - u) *\<^sub>R x + u *\<^sub>R y"
  5240   have "?z \<in> S"
  5241     using convexD_alt[OF assms(1,3,4), of u] using u by auto
  5242   then show False
  5243     using assms(5)[THEN bspec[where x="?z"]] and u(3)
  5244     by (auto simp: dist_commute algebra_simps)
  5245 qed
  5246 
  5247 lemma any_closest_point_unique:
  5248   fixes x :: "'a::real_inner"
  5249   assumes "convex S" "closed S" "x \<in> S" "y \<in> S"
  5250     "\<forall>z\<in>S. dist a x \<le> dist a z" "\<forall>z\<in>S. dist a y \<le> dist a z"
  5251   shows "x = y"
  5252   using any_closest_point_dot[OF assms(1-4,5)] and any_closest_point_dot[OF assms(1-2,4,3,6)]
  5253   unfolding norm_pths(1) and norm_le_square
  5254   by (auto simp: algebra_simps)
  5255 
  5256 lemma closest_point_unique:
  5257   assumes "convex S" "closed S" "x \<in> S" "\<forall>z\<in>S. dist a x \<le> dist a z"
  5258   shows "x = closest_point S a"
  5259   using any_closest_point_unique[OF assms(1-3) _ assms(4), of "closest_point S a"]
  5260   using closest_point_exists[OF assms(2)] and assms(3) by auto
  5261 
  5262 lemma closest_point_dot:
  5263   assumes "convex S" "closed S" "x \<in> S"
  5264   shows "inner (a - closest_point S a) (x - closest_point S a) \<le> 0"
  5265   apply (rule any_closest_point_dot[OF assms(1,2) _ assms(3)])
  5266   using closest_point_exists[OF assms(2)] and assms(3)
  5267   apply auto
  5268   done
  5269 
  5270 lemma closest_point_lt:
  5271   assumes "convex S" "closed S" "x \<in> S" "x \<noteq> closest_point S a"
  5272   shows "dist a (closest_point S a) < dist a x"
  5273   apply (rule ccontr)
  5274   apply (rule_tac notE[OF assms(4)])
  5275   apply (rule closest_point_unique[OF assms(1-3), of a])
  5276   using closest_point_le[OF assms(2), of _ a]
  5277   apply fastforce
  5278   done
  5279 
  5280 lemma closest_point_lipschitz:
  5281   assumes "convex S"
  5282     and "closed S" "S \<noteq> {}"
  5283   shows "dist (closest_point S x) (closest_point S y) \<le> dist x y"
  5284 proof -
  5285   have "inner (x - closest_point S x) (closest_point S y - closest_point S x) \<le> 0"
  5286     and "inner (y - closest_point S y) (closest_point S x - closest_point S y) \<le> 0"
  5287     apply (rule_tac[!] any_closest_point_dot[OF assms(1-2)])
  5288     using closest_point_exists[OF assms(2-3)]
  5289     apply auto
  5290     done
  5291   then show ?thesis unfolding dist_norm and norm_le
  5292     using inner_ge_zero[of "(x - closest_point S x) - (y - closest_point S y)"]
  5293     by (simp add: inner_add inner_diff inner_commute)
  5294 qed
  5295 
  5296 lemma continuous_at_closest_point:
  5297   assumes "convex S"
  5298     and "closed S"
  5299     and "S \<noteq> {}"
  5300   shows "continuous (at x) (closest_point S)"
  5301   unfolding continuous_at_eps_delta
  5302   using le_less_trans[OF closest_point_lipschitz[OF assms]] by auto
  5303 
  5304 lemma continuous_on_closest_point:
  5305   assumes "convex S"
  5306     and "closed S"
  5307     and "S \<noteq> {}"
  5308   shows "continuous_on t (closest_point S)"
  5309   by (metis continuous_at_imp_continuous_on continuous_at_closest_point[OF assms])
  5310 
  5311 proposition closest_point_in_rel_interior:
  5312   assumes "closed S" "S \<noteq> {}" and x: "x \<in> affine hull S"
  5313     shows "closest_point S x \<in> rel_interior S \<longleftrightarrow> x \<in> rel_interior S"
  5314 proof (cases "x \<in> S")
  5315   case True
  5316   then show ?thesis
  5317     by (simp add: closest_point_self)
  5318 next
  5319   case False
  5320   then have "False" if asm: "closest_point S x \<in> rel_interior S"
  5321   proof -
  5322     obtain e where "e > 0" and clox: "closest_point S x \<in> S"
  5323                and e: "cball (closest_point S x) e \<inter> affine hull S \<subseteq> S"
  5324       using asm mem_rel_interior_cball by blast
  5325     then have clo_notx: "closest_point S x \<noteq> x"
  5326       using \<open>x \<notin> S\<close> by auto
  5327     define y where "y \<equiv> closest_point S x -
  5328                         (min 1 (e / norm(closest_point S x - x))) *\<^sub>R (closest_point S x - x)"
  5329     have "x - y = (1 - min 1 (e / norm (closest_point S x - x))) *\<^sub>R (x - closest_point S x)"
  5330       by (simp add: y_def algebra_simps)
  5331     then have "norm (x - y) = abs ((1 - min 1 (e / norm (closest_point S x - x)))) * norm(x - closest_point S x)"
  5332       by simp
  5333     also have "\<dots> < norm(x - closest_point S x)"
  5334       using clo_notx \<open>e > 0\<close>
  5335       by (auto simp: mult_less_cancel_right2 divide_simps)
  5336     finally have no_less: "norm (x - y) < norm (x - closest_point S x)" .
  5337     have "y \<in> affine hull S"
  5338       unfolding y_def
  5339       by (meson affine_affine_hull clox hull_subset mem_affine_3_minus2 subsetD x)
  5340     moreover have "dist (closest_point S x) y \<le> e"
  5341       using \<open>e > 0\<close> by (auto simp: y_def min_mult_distrib_right)
  5342     ultimately have "y \<in> S"
  5343       using subsetD [OF e] by simp
  5344     then have "dist x (closest_point S x) \<le> dist x y"
  5345       by (simp add: closest_point_le \<open>closed S\<close>)
  5346     with no_less show False
  5347       by (simp add: dist_norm)
  5348   qed
  5349   moreover have "x \<notin> rel_interior S"
  5350     using rel_interior_subset False by blast
  5351   ultimately show ?thesis by blast
  5352 qed
  5353 
  5354 
  5355 subsubsection%unimportant \<open>Various point-to-set separating/supporting hyperplane theorems\<close>
  5356 
  5357 lemma supporting_hyperplane_closed_point:
  5358   fixes z :: "'a::{real_inner,heine_borel}"
  5359   assumes "convex S"
  5360     and "closed S"
  5361     and "S \<noteq> {}"
  5362     and "z \<notin> S"
  5363   shows "\<exists>a b. \<exists>y\<in>S. inner a z < b \<and> inner a y = b \<and> (\<forall>x\<in>S. inner a x \<ge> b)"
  5364 proof -
  5365   obtain y where "y \<in> S" and y: "\<forall>x\<in>S. dist z y \<le> dist z x"
  5366     by (metis distance_attains_inf[OF assms(2-3)])
  5367   show ?thesis
  5368   proof (intro exI bexI conjI ballI)
  5369     show "(y - z) \<bullet> z < (y - z) \<bullet> y"
  5370       by (metis \<open>y \<in> S\<close> assms(4) diff_gt_0_iff_gt inner_commute inner_diff_left inner_gt_zero_iff right_minus_eq)
  5371     show "(y - z) \<bullet> y \<le> (y - z) \<bullet> x" if "x \<in> S" for x
  5372     proof (rule ccontr)
  5373       have *: "\<And>u. 0 \<le> u \<and> u \<le> 1 \<longrightarrow> dist z y \<le> dist z ((1 - u) *\<^sub>R y + u *\<^sub>R x)"
  5374         using assms(1)[unfolded convex_alt] and y and \<open>x\<in>S\<close> and \<open>y\<in>S\<close> by auto
  5375       assume "\<not> (y - z) \<bullet> y \<le> (y - z) \<bullet> x"
  5376       then obtain v where "v > 0" "v \<le> 1" "dist (y + v *\<^sub>R (x - y)) z < dist y z"
  5377         using closer_point_lemma[of z y x] by (auto simp: inner_diff)
  5378       then show False
  5379         using *[of v] by (auto simp: dist_commute algebra_simps)
  5380     qed
  5381   qed (use \<open>y \<in> S\<close> in auto)
  5382 qed
  5383 
  5384 lemma separating_hyperplane_closed_point:
  5385   fixes z :: "'a::{real_inner,heine_borel}"
  5386   assumes "convex S"
  5387     and "closed S"
  5388     and "z \<notin> S"
  5389   shows "\<exists>a b. inner a z < b \<and> (\<forall>x\<in>S. inner a x > b)"
  5390 proof (cases "S = {}")
  5391   case True
  5392   then show ?thesis
  5393     by (simp add: gt_ex)
  5394 next
  5395   case False
  5396   obtain y where "y \<in> S" and y: "\<And>x. x \<in> S \<Longrightarrow> dist z y \<le> dist z x"
  5397     by (metis distance_attains_inf[OF assms(2) False])
  5398   show ?thesis
  5399   proof (intro exI conjI ballI)
  5400     show "(y - z) \<bullet> z < inner (y - z) z + (norm (y - z))\<^sup>2 / 2"
  5401       using \<open>y\<in>S\<close> \<open>z\<notin>S\<close> by auto
  5402   next
  5403     fix x
  5404     assume "x \<in> S"
  5405     have "False" if *: "0 < inner (z - y) (x - y)"
  5406     proof -
  5407       obtain u where "u > 0" "u \<le> 1" "dist (y + u *\<^sub>R (x - y)) z < dist y z"
  5408         using * closer_point_lemma by blast
  5409       then show False using y[of "y + u *\<^sub>R (x - y)"] convexD_alt [OF \<open>convex S\<close>]
  5410         using \<open>x\<in>S\<close> \<open>y\<in>S\<close> by (auto simp: dist_commute algebra_simps)
  5411     qed
  5412     moreover have "0 < (norm (y - z))\<^sup>2"
  5413       using \<open>y\<in>S\<close> \<open>z\<notin>S\<close> by auto
  5414     then have "0 < inner (y - z) (y - z)"
  5415       unfolding power2_norm_eq_inner by simp
  5416     ultimately show "(y - z) \<bullet> z + (norm (y - z))\<^sup>2 / 2 < (y - z) \<bullet> x"
  5417       by (force simp: field_simps power2_norm_eq_inner inner_commute inner_diff)
  5418   qed 
  5419 qed
  5420 
  5421 lemma separating_hyperplane_closed_0:
  5422   assumes "convex (S::('a::euclidean_space) set)"
  5423     and "closed S"
  5424     and "0 \<notin> S"
  5425   shows "\<exists>a b. a \<noteq> 0 \<and> 0 < b \<and> (\<forall>x\<in>S. inner a x > b)"
  5426 proof (cases "S = {}")
  5427   case True
  5428   have "(SOME i. i\<in>Basis) \<noteq> (0::'a)"
  5429     by (metis Basis_zero SOME_Basis)
  5430   then show ?thesis
  5431     using True zero_less_one by blast
  5432 next
  5433   case False
  5434   then show ?thesis
  5435     using False using separating_hyperplane_closed_point[OF assms]
  5436     by (metis all_not_in_conv inner_zero_left inner_zero_right less_eq_real_def not_le)
  5437 qed
  5438 
  5439 
  5440 subsubsection%unimportant \<open>Now set-to-set for closed/compact sets\<close>
  5441 
  5442 lemma separating_hyperplane_closed_compact:
  5443   fixes S :: "'a::euclidean_space set"
  5444   assumes "convex S"
  5445     and "closed S"
  5446     and "convex T"
  5447     and "compact T"
  5448     and "T \<noteq> {}"
  5449     and "S \<inter> T = {}"
  5450   shows "\<exists>a b. (\<forall>x\<in>S. inner a x < b) \<and> (\<forall>x\<in>T. inner a x > b)"
  5451 proof (cases "S = {}")
  5452   case True
  5453   obtain b where b: "b > 0" "\<forall>x\<in>T. norm x \<le> b"
  5454     using compact_imp_bounded[OF assms(4)] unfolding bounded_pos by auto
  5455   obtain z :: 'a where z: "norm z = b + 1"
  5456     using vector_choose_size[of "b + 1"] and b(1) by auto
  5457   then have "z \<notin> T" using b(2)[THEN bspec[where x=z]] by auto
  5458   then obtain a b where ab: "inner a z < b" "\<forall>x\<in>T. b < inner a x"
  5459     using separating_hyperplane_closed_point[OF assms(3) compact_imp_closed[OF assms(4)], of z]
  5460     by auto
  5461   then show ?thesis
  5462     using True by auto
  5463 next
  5464   case False
  5465   then obtain y where "y \<in> S" by auto
  5466   obtain a b where "0 < b" "\<forall>x \<in> (\<Union>x\<in> S. \<Union>y \<in> T. {x - y}). b < inner a x"
  5467     using separating_hyperplane_closed_point[OF convex_differences[OF assms(1,3)], of 0]
  5468     using closed_compact_differences[OF assms(2,4)]
  5469     using assms(6) by auto 
  5470   then have ab: "\<forall>x\<in>S. \<forall>y\<in>T. b + inner a y < inner a x"
  5471     apply -
  5472     apply rule
  5473     apply rule
  5474     apply (erule_tac x="x - y" in ballE)
  5475     apply (auto simp: inner_diff)
  5476     done
  5477   define k where "k = (SUP x:T. a \<bullet> x)"
  5478   show ?thesis
  5479     apply (rule_tac x="-a" in exI)
  5480     apply (rule_tac x="-(k + b / 2)" in exI)
  5481     apply (intro conjI ballI)
  5482     unfolding inner_minus_left and neg_less_iff_less
  5483   proof -
  5484     fix x assume "x \<in> T"
  5485     then have "inner a x - b / 2 < k"
  5486       unfolding k_def
  5487     proof (subst less_cSUP_iff)
  5488       show "T \<noteq> {}" by fact
  5489       show "bdd_above ((\<bullet>) a ` T)"
  5490         using ab[rule_format, of y] \<open>y \<in> S\<close>
  5491         by (intro bdd_aboveI2[where M="inner a y - b"]) (auto simp: field_simps intro: less_imp_le)
  5492     qed (auto intro!: bexI[of _ x] \<open>0<b\<close>)
  5493     then show "inner a x < k + b / 2"
  5494       by auto
  5495   next
  5496     fix x
  5497     assume "x \<in> S"
  5498     then have "k \<le> inner a x - b"
  5499       unfolding k_def
  5500       apply (rule_tac cSUP_least)
  5501       using assms(5)
  5502       using ab[THEN bspec[where x=x]]
  5503       apply auto
  5504       done
  5505     then show "k + b / 2 < inner a x"
  5506       using \<open>0 < b\<close> by auto
  5507   qed
  5508 qed
  5509 
  5510 lemma separating_hyperplane_compact_closed:
  5511   fixes S :: "'a::euclidean_space set"
  5512   assumes "convex S"
  5513     and "compact S"
  5514     and "S \<noteq> {}"
  5515     and "convex T"
  5516     and "closed T"
  5517     and "S \<inter> T = {}"
  5518   shows "\<exists>a b. (\<forall>x\<in>S. inner a x < b) \<and> (\<forall>x\<in>T. inner a x > b)"
  5519 proof -
  5520   obtain a b where "(\<forall>x\<in>T. inner a x < b) \<and> (\<forall>x\<in>S. b < inner a x)"
  5521     using separating_hyperplane_closed_compact[OF assms(4-5,1-2,3)] and assms(6)
  5522     by auto
  5523   then show ?thesis
  5524     apply (rule_tac x="-a" in exI)
  5525     apply (rule_tac x="-b" in exI, auto)
  5526     done
  5527 qed
  5528 
  5529 
  5530 subsubsection%unimportant \<open>General case without assuming closure and getting non-strict separation\<close>
  5531 
  5532 lemma separating_hyperplane_set_0:
  5533   assumes "convex S" "(0::'a::euclidean_space) \<notin> S"
  5534   shows "\<exists>a. a \<noteq> 0 \<and> (\<forall>x\<in>S. 0 \<le> inner a x)"
  5535 proof -
  5536   let ?k = "\<lambda>c. {x::'a. 0 \<le> inner c x}"
  5537   have *: "frontier (cball 0 1) \<inter> \<Inter>f \<noteq> {}" if as: "f \<subseteq> ?k ` S" "finite f" for f
  5538   proof -
  5539     obtain c where c: "f = ?k ` c" "c \<subseteq> S" "finite c"
  5540       using finite_subset_image[OF as(2,1)] by auto
  5541     then obtain a b where ab: "a \<noteq> 0" "0 < b" "\<forall>x\<in>convex hull c. b < inner a x"
  5542       using separating_hyperplane_closed_0[OF convex_convex_hull, of c]
  5543       using finite_imp_compact_convex_hull[OF c(3), THEN compact_imp_closed] and assms(2)
  5544       using subset_hull[of convex, OF assms(1), symmetric, of c]
  5545       by force
  5546     then have "\<exists>x. norm x = 1 \<and> (\<forall>y\<in>c. 0 \<le> inner y x)"
  5547       apply (rule_tac x = "inverse(norm a) *\<^sub>R a" in exI)
  5548       using hull_subset[of c convex]
  5549       unfolding subset_eq and inner_scaleR
  5550       by (auto simp: inner_commute del: ballE elim!: ballE)
  5551     then show "frontier (cball 0 1) \<inter> \<Inter>f \<noteq> {}"
  5552       unfolding c(1) frontier_cball sphere_def dist_norm by auto
  5553   qed
  5554   have "frontier (cball 0 1) \<inter> (\<Inter>(?k ` S)) \<noteq> {}"
  5555     apply (rule compact_imp_fip)
  5556     apply (rule compact_frontier[OF compact_cball])
  5557     using * closed_halfspace_ge
  5558     by auto
  5559   then obtain x where "norm x = 1" "\<forall>y\<in>S. x\<in>?k y"
  5560     unfolding frontier_cball dist_norm sphere_def by auto
  5561   then show ?thesis
  5562     by (metis inner_commute mem_Collect_eq norm_eq_zero zero_neq_one)
  5563 qed
  5564 
  5565 lemma separating_hyperplane_sets:
  5566   fixes S T :: "'a::euclidean_space set"
  5567   assumes "convex S"
  5568     and "convex T"
  5569     and "S \<noteq> {}"
  5570     and "T \<noteq> {}"
  5571     and "S \<inter> T = {}"
  5572   shows "\<exists>a b. a \<noteq> 0 \<and> (\<forall>x\<in>S. inner a x \<le> b) \<and> (\<forall>x\<in>T. inner a x \<ge> b)"
  5573 proof -
  5574   from separating_hyperplane_set_0[OF convex_differences[OF assms(2,1)]]
  5575   obtain a where "a \<noteq> 0" "\<forall>x\<in>{x - y |x y. x \<in> T \<and> y \<in> S}. 0 \<le> inner a x"
  5576     using assms(3-5) by force
  5577   then have *: "\<And>x y. x \<in> T \<Longrightarrow> y \<in> S \<Longrightarrow> inner a y \<le> inner a x"
  5578     by (force simp: inner_diff)
  5579   then have bdd: "bdd_above (((\<bullet>) a)`S)"
  5580     using \<open>T \<noteq> {}\<close> by (auto intro: bdd_aboveI2[OF *])
  5581   show ?thesis
  5582     using \<open>a\<noteq>0\<close>
  5583     by (intro exI[of _ a] exI[of _ "SUP x:S. a \<bullet> x"])
  5584        (auto intro!: cSUP_upper bdd cSUP_least \<open>a \<noteq> 0\<close> \<open>S \<noteq> {}\<close> *)
  5585 qed
  5586 
  5587 
  5588 subsection%unimportant \<open>More convexity generalities\<close>
  5589 
  5590 lemma convex_closure [intro,simp]:
  5591   fixes S :: "'a::real_normed_vector set"
  5592   assumes "convex S"
  5593   shows "convex (closure S)"
  5594   apply (rule convexI)
  5595   apply (unfold closure_sequential, elim exE)
  5596   apply (rule_tac x="\<lambda>n. u *\<^sub>R xa n + v *\<^sub>R xb n" in exI)
  5597   apply (rule,rule)
  5598   apply (rule convexD [OF assms])
  5599   apply (auto del: tendsto_const intro!: tendsto_intros)
  5600   done
  5601 
  5602 lemma convex_interior [intro,simp]:
  5603   fixes S :: "'a::real_normed_vector set"
  5604   assumes "convex S"
  5605   shows "convex (interior S)"
  5606   unfolding convex_alt Ball_def mem_interior
  5607 proof clarify
  5608   fix x y u
  5609   assume u: "0 \<le> u" "u \<le> (1::real)"
  5610   fix e d
  5611   assume ed: "ball x e \<subseteq> S" "ball y d \<subseteq> S" "0<d" "0<e"
  5612   show "\<exists>e>0. ball ((1 - u) *\<^sub>R x + u *\<^sub>R y) e \<subseteq> S"
  5613   proof (intro exI conjI subsetI)
  5614     fix z
  5615     assume "z \<in> ball ((1 - u) *\<^sub>R x + u *\<^sub>R y) (min d e)"
  5616     then have "(1- u) *\<^sub>R (z - u *\<^sub>R (y - x)) + u *\<^sub>R (z + (1 - u) *\<^sub>R (y - x)) \<in> S"
  5617       apply (rule_tac assms[unfolded convex_alt, rule_format])
  5618       using ed(1,2) and u
  5619       unfolding subset_eq mem_ball Ball_def dist_norm
  5620       apply (auto simp: algebra_simps)
  5621       done
  5622     then show "z \<in> S"
  5623       using u by (auto simp: algebra_simps)
  5624   qed(insert u ed(3-4), auto)
  5625 qed
  5626 
  5627 lemma convex_hull_eq_empty[simp]: "convex hull S = {} \<longleftrightarrow> S = {}"
  5628   using hull_subset[of S convex] convex_hull_empty by auto
  5629 
  5630 
  5631 subsection%unimportant \<open>Moving and scaling convex hulls\<close>
  5632 
  5633 lemma convex_hull_set_plus:
  5634   "convex hull (S + T) = convex hull S + convex hull T"
  5635   unfolding set_plus_image
  5636   apply (subst convex_hull_linear_image [symmetric])
  5637   apply (simp add: linear_iff scaleR_right_distrib)
  5638   apply (simp add: convex_hull_Times)
  5639   done
  5640 
  5641 lemma translation_eq_singleton_plus: "(\<lambda>x. a + x) ` T = {a} + T"
  5642   unfolding set_plus_def by auto
  5643 
  5644 lemma convex_hull_translation:
  5645   "convex hull ((\<lambda>x. a + x) ` S) = (\<lambda>x. a + x) ` (convex hull S)"
  5646   unfolding translation_eq_singleton_plus
  5647   by (simp only: convex_hull_set_plus convex_hull_singleton)
  5648 
  5649 lemma convex_hull_scaling:
  5650   "convex hull ((\<lambda>x. c *\<^sub>R x) ` S) = (\<lambda>x. c *\<^sub>R x) ` (convex hull S)"
  5651   using linear_scaleR by (rule convex_hull_linear_image [symmetric])
  5652 
  5653 lemma convex_hull_affinity:
  5654   "convex hull ((\<lambda>x. a + c *\<^sub>R x) ` S) = (\<lambda>x. a + c *\<^sub>R x) ` (convex hull S)"
  5655   by(simp only: image_image[symmetric] convex_hull_scaling convex_hull_translation)
  5656 
  5657 
  5658 subsection%unimportant \<open>Convexity of cone hulls\<close>
  5659 
  5660 lemma convex_cone_hull:
  5661   assumes "convex S"
  5662   shows "convex (cone hull S)"
  5663 proof (rule convexI)
  5664   fix x y
  5665   assume xy: "x \<in> cone hull S" "y \<in> cone hull S"
  5666   then have "S \<noteq> {}"
  5667     using cone_hull_empty_iff[of S] by auto
  5668   fix u v :: real
  5669   assume uv: "u \<ge> 0" "v \<ge> 0" "u + v = 1"
  5670   then have *: "u *\<^sub>R x \<in> cone hull S" "v *\<^sub>R y \<in> cone hull S"
  5671     using cone_cone_hull[of S] xy cone_def[of "cone hull S"] by auto
  5672   from * obtain cx :: real and xx where x: "u *\<^sub>R x = cx *\<^sub>R xx" "cx \<ge> 0" "xx \<in> S"
  5673     using cone_hull_expl[of S] by auto
  5674   from * obtain cy :: real and yy where y: "v *\<^sub>R y = cy *\<^sub>R yy" "cy \<ge> 0" "yy \<in> S"
  5675     using cone_hull_expl[of S] by auto
  5676   {
  5677     assume "cx + cy \<le> 0"
  5678     then have "u *\<^sub>R x = 0" and "v *\<^sub>R y = 0"
  5679       using x y by auto
  5680     then have "u *\<^sub>R x + v *\<^sub>R y = 0"
  5681       by auto
  5682     then have "u *\<^sub>R x + v *\<^sub>R y \<in> cone hull S"
  5683       using cone_hull_contains_0[of S] \<open>S \<noteq> {}\<close> by auto
  5684   }
  5685   moreover
  5686   {
  5687     assume "cx + cy > 0"
  5688     then have "(cx / (cx + cy)) *\<^sub>R xx + (cy / (cx + cy)) *\<^sub>R yy \<in> S"
  5689       using assms mem_convex_alt[of S xx yy cx cy] x y by auto
  5690     then have "cx *\<^sub>R xx + cy *\<^sub>R yy \<in> cone hull S"
  5691       using mem_cone_hull[of "(cx/(cx+cy)) *\<^sub>R xx + (cy/(cx+cy)) *\<^sub>R yy" S "cx+cy"] \<open>cx+cy>0\<close>
  5692       by (auto simp: scaleR_right_distrib)
  5693     then have "u *\<^sub>R x + v *\<^sub>R y \<in> cone hull S"
  5694       using x y by auto
  5695   }
  5696   moreover have "cx + cy \<le> 0 \<or> cx + cy > 0" by auto
  5697   ultimately show "u *\<^sub>R x + v *\<^sub>R y \<in> cone hull S" by blast
  5698 qed
  5699 
  5700 lemma cone_convex_hull:
  5701   assumes "cone S"
  5702   shows "cone (convex hull S)"
  5703 proof (cases "S = {}")
  5704   case True
  5705   then show ?thesis by auto
  5706 next
  5707   case False
  5708   then have *: "0 \<in> S \<and> (\<forall>c. c > 0 \<longrightarrow> ( *\<^sub>R) c ` S = S)"
  5709     using cone_iff[of S] assms by auto
  5710   {
  5711     fix c :: real
  5712     assume "c > 0"
  5713     then have "( *\<^sub>R) c ` (convex hull S) = convex hull (( *\<^sub>R) c ` S)"
  5714       using convex_hull_scaling[of _ S] by auto
  5715     also have "\<dots> = convex hull S"
  5716       using * \<open>c > 0\<close> by auto
  5717     finally have "( *\<^sub>R) c ` (convex hull S) = convex hull S"
  5718       by auto
  5719   }
  5720   then have "0 \<in> convex hull S" "\<And>c. c > 0 \<Longrightarrow> (( *\<^sub>R) c ` (convex hull S)) = (convex hull S)"
  5721     using * hull_subset[of S convex] by auto
  5722   then show ?thesis
  5723     using \<open>S \<noteq> {}\<close> cone_iff[of "convex hull S"] by auto
  5724 qed
  5725 
  5726 subsection%unimportant \<open>Convex set as intersection of halfspaces\<close>
  5727 
  5728 lemma convex_halfspace_intersection:
  5729   fixes s :: "('a::euclidean_space) set"
  5730   assumes "closed s" "convex s"
  5731   shows "s = \<Inter>{h. s \<subseteq> h \<and> (\<exists>a b. h = {x. inner a x \<le> b})}"
  5732   apply (rule set_eqI, rule)
  5733   unfolding Inter_iff Ball_def mem_Collect_eq
  5734   apply (rule,rule,erule conjE)
  5735 proof -
  5736   fix x
  5737   assume "\<forall>xa. s \<subseteq> xa \<and> (\<exists>a b. xa = {x. inner a x \<le> b}) \<longrightarrow> x \<in> xa"
  5738   then have "\<forall>a b. s \<subseteq> {x. inner a x \<le> b} \<longrightarrow> x \<in> {x. inner a x \<le> b}"
  5739     by blast
  5740   then show "x \<in> s"
  5741     apply (rule_tac ccontr)
  5742     apply (drule separating_hyperplane_closed_point[OF assms(2,1)])
  5743     apply (erule exE)+
  5744     apply (erule_tac x="-a" in allE)
  5745     apply (erule_tac x="-b" in allE, auto)
  5746     done
  5747 qed auto
  5748 
  5749 
  5750 subsection \<open>Radon's theorem (from Lars Schewe)\<close>
  5751 
  5752 lemma radon_ex_lemma:
  5753   assumes "finite c" "affine_dependent c"
  5754   shows "\<exists>u. sum u c = 0 \<and> (\<exists>v\<in>c. u v \<noteq> 0) \<and> sum (\<lambda>v. u v *\<^sub>R v) c = 0"
  5755 proof -
  5756   from assms(2)[unfolded affine_dependent_explicit]
  5757   obtain s u where
  5758       "finite s" "s \<subseteq> c" "sum u s = 0" "\<exists>v\<in>s. u v \<noteq> 0" "(\<Sum>v\<in>s. u v *\<^sub>R v) = 0"
  5759     by blast
  5760   then show ?thesis
  5761     apply (rule_tac x="\<lambda>v. if v\<in>s then u v else 0" in exI)
  5762     unfolding if_smult scaleR_zero_left and sum.inter_restrict[OF assms(1), symmetric]
  5763     apply (auto simp: Int_absorb1)
  5764     done
  5765 qed
  5766 
  5767 lemma radon_s_lemma:
  5768   assumes "finite s"
  5769     and "sum f s = (0::real)"
  5770   shows "sum f {x\<in>s. 0 < f x} = - sum f {x\<in>s. f x < 0}"
  5771 proof -
  5772   have *: "\<And>x. (if f x < 0 then f x else 0) + (if 0 < f x then f x else 0) = f x"
  5773     by auto
  5774   show ?thesis
  5775     unfolding add_eq_0_iff[symmetric] and sum.inter_filter[OF assms(1)]
  5776       and sum.distrib[symmetric] and *
  5777     using assms(2)
  5778     by assumption
  5779 qed
  5780 
  5781 lemma radon_v_lemma:
  5782   assumes "finite s"
  5783     and "sum f s = 0"
  5784     and "\<forall>x. g x = (0::real) \<longrightarrow> f x = (0::'a::euclidean_space)"
  5785   shows "(sum f {x\<in>s. 0 < g x}) = - sum f {x\<in>s. g x < 0}"
  5786 proof -
  5787   have *: "\<And>x. (if 0 < g x then f x else 0) + (if g x < 0 then f x else 0) = f x"
  5788     using assms(3) by auto
  5789   show ?thesis
  5790     unfolding eq_neg_iff_add_eq_0 and sum.inter_filter[OF assms(1)]
  5791       and sum.distrib[symmetric] and *
  5792     using assms(2)
  5793     apply assumption
  5794     done
  5795 qed
  5796 
  5797 lemma radon_partition:
  5798   assumes "finite c" "affine_dependent c"
  5799   shows "\<exists>m p. m \<inter> p = {} \<and> m \<union> p = c \<and> (convex hull m) \<inter> (convex hull p) \<noteq> {}"
  5800 proof -
  5801   obtain u v where uv: "sum u c = 0" "v\<in>c" "u v \<noteq> 0"  "(\<Sum>v\<in>c. u v *\<^sub>R v) = 0"
  5802     using radon_ex_lemma[OF assms] by auto
  5803   have fin: "finite {x \<in> c. 0 < u x}" "finite {x \<in> c. 0 > u x}"
  5804     using assms(1) by auto
  5805   define z  where "z = inverse (sum u {x\<in>c. u x > 0}) *\<^sub>R sum (\<lambda>x. u x *\<^sub>R x) {x\<in>c. u x > 0}"
  5806   have "sum u {x \<in> c. 0 < u x} \<noteq> 0"
  5807   proof (cases "u v \<ge> 0")
  5808     case False
  5809     then have "u v < 0" by auto
  5810     then show ?thesis
  5811     proof (cases "\<exists>w\<in>{x \<in> c. 0 < u x}. u w > 0")
  5812       case True
  5813       then show ?thesis
  5814         using sum_nonneg_eq_0_iff[of _ u, OF fin(1)] by auto
  5815     next
  5816       case False
  5817       then have "sum u c \<le> sum (\<lambda>x. if x=v then u v else 0) c"
  5818         apply (rule_tac sum_mono, auto)
  5819         done
  5820       then show ?thesis
  5821         unfolding sum.delta[OF assms(1)] using uv(2) and \<open>u v < 0\<close> and uv(1) by auto
  5822     qed
  5823   qed (insert sum_nonneg_eq_0_iff[of _ u, OF fin(1)] uv(2-3), auto)
  5824 
  5825   then have *: "sum u {x\<in>c. u x > 0} > 0"
  5826     unfolding less_le
  5827     apply (rule_tac conjI)
  5828     apply (rule_tac sum_nonneg, auto)
  5829     done
  5830   moreover have "sum u ({x \<in> c. 0 < u x} \<union> {x \<in> c. u x < 0}) = sum u c"
  5831     "(\<Sum>x\<in>{x \<in> c. 0 < u x} \<union> {x \<in> c. u x < 0}. u x *\<^sub>R x) = (\<Sum>x\<in>c. u x *\<^sub>R x)"
  5832     using assms(1)
  5833     apply (rule_tac[!] sum.mono_neutral_left, auto)
  5834     done
  5835   then have "sum u {x \<in> c. 0 < u x} = - sum u {x \<in> c. 0 > u x}"
  5836     "(\<Sum>x\<in>{x \<in> c. 0 < u x}. u x *\<^sub>R x) = - (\<Sum>x\<in>{x \<in> c. 0 > u x}. u x *\<^sub>R x)"
  5837     unfolding eq_neg_iff_add_eq_0
  5838     using uv(1,4)
  5839     by (auto simp: sum.union_inter_neutral[OF fin, symmetric])
  5840   moreover have "\<forall>x\<in>{v \<in> c. u v < 0}. 0 \<le> inverse (sum u {x \<in> c. 0 < u x}) * - u x"
  5841     apply rule
  5842     apply (rule mult_nonneg_nonneg)
  5843     using *
  5844     apply auto
  5845     done
  5846   ultimately have "z \<in> convex hull {v \<in> c. u v \<le> 0}"
  5847     unfolding convex_hull_explicit mem_Collect_eq
  5848     apply (rule_tac x="{v \<in> c. u v < 0}" in exI)
  5849     apply (rule_tac x="\<lambda>y. inverse (sum u {x\<in>c. u x > 0}) * - u y" in exI)
  5850     using assms(1) unfolding scaleR_scaleR[symmetric] scaleR_right.sum [symmetric] and z_def
  5851     apply (auto simp: sum_negf sum_distrib_left[symmetric])
  5852     done
  5853   moreover have "\<forall>x\<in>{v \<in> c. 0 < u v}. 0 \<le> inverse (sum u {x \<in> c. 0 < u x}) * u x"
  5854     apply rule
  5855     apply (rule mult_nonneg_nonneg)
  5856     using *
  5857     apply auto
  5858     done
  5859   then have "z \<in> convex hull {v \<in> c. u v > 0}"
  5860     unfolding convex_hull_explicit mem_Collect_eq
  5861     apply (rule_tac x="{v \<in> c. 0 < u v}" in exI)
  5862     apply (rule_tac x="\<lambda>y. inverse (sum u {x\<in>c. u x > 0}) * u y" in exI)
  5863     using assms(1)
  5864     unfolding scaleR_scaleR[symmetric] scaleR_right.sum [symmetric] and z_def
  5865     using *
  5866     apply (auto simp: sum_negf sum_distrib_left[symmetric])
  5867     done
  5868   ultimately show ?thesis
  5869     apply (rule_tac x="{v\<in>c. u v \<le> 0}" in exI)
  5870     apply (rule_tac x="{v\<in>c. u v > 0}" in exI, auto)
  5871     done
  5872 qed
  5873 
  5874 theorem radon:
  5875   assumes "affine_dependent c"
  5876   obtains m p where "m \<subseteq> c" "p \<subseteq> c" "m \<inter> p = {}" "(convex hull m) \<inter> (convex hull p) \<noteq> {}"
  5877 proof -
  5878   from assms[unfolded affine_dependent_explicit]
  5879   obtain s u where
  5880       "finite s" "s \<subseteq> c" "sum u s = 0" "\<exists>v\<in>s. u v \<noteq> 0" "(\<Sum>v\<in>s. u v *\<^sub>R v) = 0"
  5881     by blast
  5882   then have *: "finite s" "affine_dependent s" and s: "s \<subseteq> c"
  5883     unfolding affine_dependent_explicit by auto
  5884   from radon_partition[OF *]
  5885   obtain m p where "m \<inter> p = {}" "m \<union> p = s" "convex hull m \<inter> convex hull p \<noteq> {}"
  5886     by blast
  5887   then show ?thesis
  5888     apply (rule_tac that[of p m])
  5889     using s
  5890     apply auto
  5891     done
  5892 qed
  5893 
  5894 
  5895 subsection \<open>Helly's theorem\<close>
  5896 
  5897 lemma helly_induct:
  5898   fixes f :: "'a::euclidean_space set set"
  5899   assumes "card f = n"
  5900     and "n \<ge> DIM('a) + 1"
  5901     and "\<forall>s\<in>f. convex s" "\<forall>t\<subseteq>f. card t = DIM('a) + 1 \<longrightarrow> \<Inter>t \<noteq> {}"
  5902   shows "\<Inter>f \<noteq> {}"
  5903   using assms
  5904 proof (induction n arbitrary: f)
  5905   case 0
  5906   then show ?case by auto
  5907 next
  5908   case (Suc n)
  5909   have "finite f"
  5910     using \<open>card f = Suc n\<close> by (auto intro: card_ge_0_finite)
  5911   show "\<Inter>f \<noteq> {}"
  5912   proof (cases "n = DIM('a)")
  5913     case True
  5914     then show ?thesis
  5915       by (simp add: Suc.prems(1) Suc.prems(4))
  5916   next
  5917     case False
  5918     have "\<Inter>(f - {s}) \<noteq> {}" if "s \<in> f" for s
  5919     proof (rule Suc.IH[rule_format])
  5920       show "card (f - {s}) = n"
  5921         by (simp add: Suc.prems(1) \<open>finite f\<close> that)
  5922       show "DIM('a) + 1 \<le> n"
  5923         using False Suc.prems(2) by linarith
  5924       show "\<And>t. \<lbrakk>t \<subseteq> f - {s}; card t = DIM('a) + 1\<rbrakk> \<Longrightarrow> \<Inter>t \<noteq> {}"
  5925         by (simp add: Suc.prems(4) subset_Diff_insert)
  5926     qed (use Suc in auto)
  5927     then have "\<forall>s\<in>f. \<exists>x. x \<in> \<Inter>(f - {s})"
  5928       by blast
  5929     then obtain X where X: "\<And>s. s\<in>f \<Longrightarrow> X s \<in> \<Inter>(f - {s})"
  5930       by metis
  5931     show ?thesis
  5932     proof (cases "inj_on X f")
  5933       case False
  5934       then obtain s t where "s\<noteq>t" and st: "s\<in>f" "t\<in>f" "X s = X t"
  5935         unfolding inj_on_def by auto
  5936       then have *: "\<Inter>f = \<Inter>(f - {s}) \<inter> \<Inter>(f - {t})" by auto
  5937       show ?thesis
  5938         by (metis "*" X disjoint_iff_not_equal st)
  5939     next
  5940       case True
  5941       then obtain m p where mp: "m \<inter> p = {}" "m \<union> p = X ` f" "convex hull m \<inter> convex hull p \<noteq> {}"
  5942         using radon_partition[of "X ` f"] and affine_dependent_biggerset[of "X ` f"]
  5943         unfolding card_image[OF True] and \<open>card f = Suc n\<close>
  5944         using Suc(3) \<open>finite f\<close> and False
  5945         by auto
  5946       have "m \<subseteq> X ` f" "p \<subseteq> X ` f"
  5947         using mp(2) by auto
  5948       then obtain g h where gh:"m = X ` g" "p = X ` h" "g \<subseteq> f" "h \<subseteq> f"
  5949         unfolding subset_image_iff by auto
  5950       then have "f \<union> (g \<union> h) = f" by auto
  5951       then have f: "f = g \<union> h"
  5952         using inj_on_Un_image_eq_iff[of X f "g \<union> h"] and True
  5953         unfolding mp(2)[unfolded image_Un[symmetric] gh]
  5954         by auto
  5955       have *: "g \<inter> h = {}"
  5956         using mp(1)
  5957         unfolding gh
  5958         using inj_on_image_Int[OF True gh(3,4)]
  5959         by auto
  5960       have "convex hull (X ` h) \<subseteq> \<Inter>g" "convex hull (X ` g) \<subseteq> \<Inter>h"
  5961         by (rule hull_minimal; use X * f in \<open>auto simp: Suc.prems(3) convex_Inter\<close>)+
  5962       then show ?thesis
  5963         unfolding f using mp(3)[unfolded gh] by blast
  5964     qed
  5965   qed 
  5966 qed
  5967 
  5968 theorem helly:
  5969   fixes f :: "'a::euclidean_space set set"
  5970   assumes "card f \<ge> DIM('a) + 1" "\<forall>s\<in>f. convex s"
  5971     and "\<And>t. \<lbrakk>t\<subseteq>f; card t = DIM('a) + 1\<rbrakk> \<Longrightarrow> \<Inter>t \<noteq> {}"
  5972   shows "\<Inter>f \<noteq> {}"
  5973   apply (rule helly_induct)
  5974   using assms
  5975   apply auto
  5976   done
  5977 
  5978 
  5979 subsection \<open>Epigraphs of convex functions\<close>
  5980 
  5981 definition%important "epigraph S (f :: _ \<Rightarrow> real) = {xy. fst xy \<in> S \<and> f (fst xy) \<le> snd xy}"
  5982 
  5983 lemma mem_epigraph: "(x, y) \<in> epigraph S f \<longleftrightarrow> x \<in> S \<and> f x \<le> y"
  5984   unfolding epigraph_def by auto
  5985 
  5986 lemma convex_epigraph: "convex (epigraph S f) \<longleftrightarrow> convex_on S f \<and> convex S"
  5987 proof safe
  5988   assume L: "convex (epigraph S f)"
  5989   then show "convex_on S f"
  5990     by (auto simp: convex_def convex_on_def epigraph_def)
  5991   show "convex S"
  5992     using L
  5993     apply (clarsimp simp: convex_def convex_on_def epigraph_def)
  5994     apply (erule_tac x=x in allE)
  5995     apply (erule_tac x="f x" in allE, safe)
  5996     apply (erule_tac x=y in allE)
  5997     apply (erule_tac x="f y" in allE)
  5998     apply (auto simp: )
  5999     done
  6000 next
  6001   assume "convex_on S f" "convex S"
  6002   then show "convex (epigraph S f)"
  6003     unfolding convex_def convex_on_def epigraph_def
  6004     apply safe
  6005      apply (rule_tac [2] y="u * f a + v * f aa" in order_trans)