src/HOL/Complete_Lattices.thy
author haftmann
Sat Mar 22 08:37:43 2014 +0100 (2014-03-22)
changeset 56248 67dc9549fa15
parent 56218 1c3f1f2431f9
child 56741 2b3710a4fa94
permissions -rw-r--r--
generalized and strengthened cong rules on compound operators, similar to 1ed737a98198
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Fun
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 begin
    19 
    20 definition INFIMUM :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    21   INF_def: "INFIMUM A f = \<Sqinter>(f ` A)"
    22 
    23 lemma Inf_image_eq [simp]:
    24   "\<Sqinter>(f ` A) = INFIMUM A f"
    25   by (simp add: INF_def)
    26 
    27 lemma INF_image [simp]:
    28   "INFIMUM (f ` A) g = INFIMUM A (g \<circ> f)"
    29   by (simp only: INF_def image_comp)
    30 
    31 lemma INF_identity_eq [simp]:
    32   "INFIMUM A (\<lambda>x. x) = \<Sqinter>A"
    33   by (simp add: INF_def)
    34 
    35 lemma INF_id_eq [simp]:
    36   "INFIMUM A id = \<Sqinter>A"
    37   by (simp add: id_def)
    38 
    39 lemma INF_cong:
    40   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> INFIMUM A C = INFIMUM B D"
    41   by (simp add: INF_def image_def)
    42 
    43 lemma strong_INF_cong [cong]:
    44   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> INFIMUM A C = INFIMUM B D"
    45   unfolding simp_implies_def by (fact INF_cong)
    46 
    47 end
    48 
    49 class Sup =
    50   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    51 begin
    52 
    53 definition SUPREMUM :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    54   SUP_def: "SUPREMUM A f = \<Squnion>(f ` A)"
    55 
    56 lemma Sup_image_eq [simp]:
    57   "\<Squnion>(f ` A) = SUPREMUM A f"
    58   by (simp add: SUP_def)
    59 
    60 lemma SUP_image [simp]:
    61   "SUPREMUM (f ` A) g = SUPREMUM A (g \<circ> f)"
    62   by (simp only: SUP_def image_comp)
    63 
    64 lemma SUP_identity_eq [simp]:
    65   "SUPREMUM A (\<lambda>x. x) = \<Squnion>A"
    66   by (simp add: SUP_def)
    67 
    68 lemma SUP_id_eq [simp]:
    69   "SUPREMUM A id = \<Squnion>A"
    70   by (simp add: id_def)
    71 
    72 lemma SUP_cong:
    73   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> SUPREMUM A C = SUPREMUM B D"
    74   by (simp add: SUP_def image_def)
    75 
    76 lemma strong_SUP_cong [cong]:
    77   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> SUPREMUM A C = SUPREMUM B D"
    78   unfolding simp_implies_def by (fact SUP_cong)
    79 
    80 end
    81 
    82 text {*
    83   Note: must use names @{const INFIMUM} and @{const SUPREMUM} here instead of
    84   @{text INF} and @{text SUP} to allow the following syntax coexist
    85   with the plain constant names.
    86 *}
    87 
    88 syntax
    89   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    90   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    91   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    92   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax (xsymbols)
    95   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    96   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    97   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    98   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    99 
   100 translations
   101   "INF x y. B"   == "INF x. INF y. B"
   102   "INF x. B"     == "CONST INFIMUM CONST UNIV (%x. B)"
   103   "INF x. B"     == "INF x:CONST UNIV. B"
   104   "INF x:A. B"   == "CONST INFIMUM A (%x. B)"
   105   "SUP x y. B"   == "SUP x. SUP y. B"
   106   "SUP x. B"     == "CONST SUPREMUM CONST UNIV (%x. B)"
   107   "SUP x. B"     == "SUP x:CONST UNIV. B"
   108   "SUP x:A. B"   == "CONST SUPREMUM A (%x. B)"
   109 
   110 print_translation {*
   111   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFIMUM} @{syntax_const "_INF"},
   112     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPREMUM} @{syntax_const "_SUP"}]
   113 *} -- {* to avoid eta-contraction of body *}
   114 
   115 subsection {* Abstract complete lattices *}
   116 
   117 text {* A complete lattice always has a bottom and a top,
   118 so we include them into the following type class,
   119 along with assumptions that define bottom and top
   120 in terms of infimum and supremum. *}
   121 
   122 class complete_lattice = lattice + Inf + Sup + bot + top +
   123   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   124      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   125   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   126      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   127   assumes Inf_empty [simp]: "\<Sqinter>{} = \<top>"
   128   assumes Sup_empty [simp]: "\<Squnion>{} = \<bottom>"
   129 begin
   130 
   131 subclass bounded_lattice
   132 proof
   133   fix a
   134   show "\<bottom> \<le> a" by (auto intro: Sup_least simp only: Sup_empty [symmetric])
   135   show "a \<le> \<top>" by (auto intro: Inf_greatest simp only: Inf_empty [symmetric])
   136 qed
   137 
   138 lemma dual_complete_lattice:
   139   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   140   by (auto intro!: class.complete_lattice.intro dual_lattice)
   141     (unfold_locales, (fact Inf_empty Sup_empty
   142         Sup_upper Sup_least Inf_lower Inf_greatest)+)
   143 
   144 end
   145 
   146 context complete_lattice
   147 begin
   148 
   149 lemma INF_foundation_dual:
   150   "Sup.SUPREMUM Inf = INFIMUM"
   151   by (simp add: fun_eq_iff Sup.SUP_def)
   152 
   153 lemma SUP_foundation_dual:
   154   "Inf.INFIMUM Sup = SUPREMUM"
   155   by (simp add: fun_eq_iff Inf.INF_def)
   156 
   157 lemma Sup_eqI:
   158   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
   159   by (blast intro: antisym Sup_least Sup_upper)
   160 
   161 lemma Inf_eqI:
   162   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
   163   by (blast intro: antisym Inf_greatest Inf_lower)
   164 
   165 lemma SUP_eqI:
   166   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   167   using Sup_eqI [of "f ` A" x] by auto
   168 
   169 lemma INF_eqI:
   170   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   171   using Inf_eqI [of "f ` A" x] by auto
   172 
   173 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   174   using Inf_lower [of _ "f ` A"] by simp
   175 
   176 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   177   using Inf_greatest [of "f ` A"] by auto
   178 
   179 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   180   using Sup_upper [of _ "f ` A"] by simp
   181 
   182 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   183   using Sup_least [of "f ` A"] by auto
   184 
   185 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   186   using Inf_lower [of u A] by auto
   187 
   188 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   189   using INF_lower [of i A f] by auto
   190 
   191 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   192   using Sup_upper [of u A] by auto
   193 
   194 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   195   using SUP_upper [of i A f] by auto
   196 
   197 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   198   by (auto intro: Inf_greatest dest: Inf_lower)
   199 
   200 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   201   using le_Inf_iff [of _ "f ` A"] by simp
   202 
   203 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   204   by (auto intro: Sup_least dest: Sup_upper)
   205 
   206 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   207   using Sup_le_iff [of "f ` A"] by simp
   208 
   209 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   210   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   211 
   212 lemma INF_insert [simp]: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFIMUM A f"
   213   unfolding INF_def Inf_insert by simp
   214 
   215 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   216   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   217 
   218 lemma SUP_insert [simp]: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPREMUM A f"
   219   unfolding SUP_def Sup_insert by simp
   220 
   221 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   222   by (simp add: INF_def)
   223 
   224 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   225   by (simp add: SUP_def)
   226 
   227 lemma Inf_UNIV [simp]:
   228   "\<Sqinter>UNIV = \<bottom>"
   229   by (auto intro!: antisym Inf_lower)
   230 
   231 lemma Sup_UNIV [simp]:
   232   "\<Squnion>UNIV = \<top>"
   233   by (auto intro!: antisym Sup_upper)
   234 
   235 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   236   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   237 
   238 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   239   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   240 
   241 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   242   by (auto intro: Inf_greatest Inf_lower)
   243 
   244 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   245   by (auto intro: Sup_least Sup_upper)
   246 
   247 lemma Inf_mono:
   248   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   249   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   250 proof (rule Inf_greatest)
   251   fix b assume "b \<in> B"
   252   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   253   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   254   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   255 qed
   256 
   257 lemma INF_mono:
   258   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   259   using Inf_mono [of "g ` B" "f ` A"] by auto
   260 
   261 lemma Sup_mono:
   262   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   263   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   264 proof (rule Sup_least)
   265   fix a assume "a \<in> A"
   266   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   267   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   268   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   269 qed
   270 
   271 lemma SUP_mono:
   272   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   273   using Sup_mono [of "f ` A" "g ` B"] by auto
   274 
   275 lemma INF_superset_mono:
   276   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   277   -- {* The last inclusion is POSITIVE! *}
   278   by (blast intro: INF_mono dest: subsetD)
   279 
   280 lemma SUP_subset_mono:
   281   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   282   by (blast intro: SUP_mono dest: subsetD)
   283 
   284 lemma Inf_less_eq:
   285   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   286     and "A \<noteq> {}"
   287   shows "\<Sqinter>A \<sqsubseteq> u"
   288 proof -
   289   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   290   moreover from `v \<in> A` assms(1) have "v \<sqsubseteq> u" by blast
   291   ultimately show ?thesis by (rule Inf_lower2)
   292 qed
   293 
   294 lemma less_eq_Sup:
   295   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   296     and "A \<noteq> {}"
   297   shows "u \<sqsubseteq> \<Squnion>A"
   298 proof -
   299   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   300   moreover from `v \<in> A` assms(1) have "u \<sqsubseteq> v" by blast
   301   ultimately show ?thesis by (rule Sup_upper2)
   302 qed
   303 
   304 lemma SUP_eq:
   305   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   306   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   307   shows "(\<Squnion>i\<in>A. f i) = (\<Squnion>j\<in>B. g j)"
   308   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   309 
   310 lemma INF_eq:
   311   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   312   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   313   shows "(\<Sqinter>i\<in>A. f i) = (\<Sqinter>j\<in>B. g j)"
   314   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   315 
   316 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   317   by (auto intro: Inf_greatest Inf_lower)
   318 
   319 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   320   by (auto intro: Sup_least Sup_upper)
   321 
   322 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   323   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   324 
   325 lemma INF_union:
   326   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   327   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   328 
   329 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   330   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   331 
   332 lemma SUP_union:
   333   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   334   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   335 
   336 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   337   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   338 
   339 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   340 proof (rule antisym)
   341   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   342 next
   343   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   344 qed
   345 
   346 lemma Inf_top_conv [simp]:
   347   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   348   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   349 proof -
   350   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   351   proof
   352     assume "\<forall>x\<in>A. x = \<top>"
   353     then have "A = {} \<or> A = {\<top>}" by auto
   354     then show "\<Sqinter>A = \<top>" by auto
   355   next
   356     assume "\<Sqinter>A = \<top>"
   357     show "\<forall>x\<in>A. x = \<top>"
   358     proof (rule ccontr)
   359       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   360       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   361       then obtain B where "A = insert x B" by blast
   362       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   363     qed
   364   qed
   365   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   366 qed
   367 
   368 lemma INF_top_conv [simp]:
   369   "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   370   "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   371   using Inf_top_conv [of "B ` A"] by simp_all
   372 
   373 lemma Sup_bot_conv [simp]:
   374   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   375   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   376   using dual_complete_lattice
   377   by (rule complete_lattice.Inf_top_conv)+
   378 
   379 lemma SUP_bot_conv [simp]:
   380  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   381  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   382   using Sup_bot_conv [of "B ` A"] by simp_all
   383 
   384 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   385   by (auto intro: antisym INF_lower INF_greatest)
   386 
   387 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   388   by (auto intro: antisym SUP_upper SUP_least)
   389 
   390 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   391   by (cases "A = {}") simp_all
   392 
   393 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   394   by (cases "A = {}") simp_all
   395 
   396 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   397   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   398 
   399 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   400   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   401 
   402 lemma INF_absorb:
   403   assumes "k \<in> I"
   404   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   405 proof -
   406   from assms obtain J where "I = insert k J" by blast
   407   then show ?thesis by simp
   408 qed
   409 
   410 lemma SUP_absorb:
   411   assumes "k \<in> I"
   412   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   413 proof -
   414   from assms obtain J where "I = insert k J" by blast
   415   then show ?thesis by simp
   416 qed
   417 
   418 lemma INF_constant:
   419   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   420   by simp
   421 
   422 lemma SUP_constant:
   423   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   424   by simp
   425 
   426 lemma less_INF_D:
   427   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   428 proof -
   429   note `y < (\<Sqinter>i\<in>A. f i)`
   430   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   431     by (rule INF_lower)
   432   finally show "y < f i" .
   433 qed
   434 
   435 lemma SUP_lessD:
   436   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   437 proof -
   438   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   439     by (rule SUP_upper)
   440   also note `(\<Squnion>i\<in>A. f i) < y`
   441   finally show "f i < y" .
   442 qed
   443 
   444 lemma INF_UNIV_bool_expand:
   445   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   446   by (simp add: UNIV_bool inf_commute)
   447 
   448 lemma SUP_UNIV_bool_expand:
   449   "(\<Squnion>b. A b) = A True \<squnion> A False"
   450   by (simp add: UNIV_bool sup_commute)
   451 
   452 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   453   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   454 
   455 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFIMUM A f \<le> SUPREMUM A f"
   456   using Inf_le_Sup [of "f ` A"] by simp
   457 
   458 lemma INF_eq_const:
   459   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> INFIMUM I f = x"
   460   by (auto intro: INF_eqI)
   461 
   462 lemma SUP_eq_const:
   463   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> SUPREMUM I f = x"
   464   by (auto intro: SUP_eqI)
   465 
   466 lemma INF_eq_iff:
   467   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i \<le> c) \<Longrightarrow> (INFIMUM I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   468   using INF_eq_const [of I f c] INF_lower [of _ I f]
   469   by (auto intro: antisym cong del: strong_INF_cong)
   470 
   471 lemma SUP_eq_iff:
   472   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> c \<le> f i) \<Longrightarrow> (SUPREMUM I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   473   using SUP_eq_const [of I f c] SUP_upper [of _ I f]
   474   by (auto intro: antisym cong del: strong_SUP_cong)
   475 
   476 end
   477 
   478 class complete_distrib_lattice = complete_lattice +
   479   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   480   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   481 begin
   482 
   483 lemma sup_INF:
   484   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   485   by (simp only: INF_def sup_Inf image_image)
   486 
   487 lemma inf_SUP:
   488   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   489   by (simp only: SUP_def inf_Sup image_image)
   490 
   491 lemma dual_complete_distrib_lattice:
   492   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   493   apply (rule class.complete_distrib_lattice.intro)
   494   apply (fact dual_complete_lattice)
   495   apply (rule class.complete_distrib_lattice_axioms.intro)
   496   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   497   done
   498 
   499 subclass distrib_lattice proof
   500   fix a b c
   501   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   502   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   503 qed
   504 
   505 lemma Inf_sup:
   506   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   507   by (simp add: sup_Inf sup_commute)
   508 
   509 lemma Sup_inf:
   510   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   511   by (simp add: inf_Sup inf_commute)
   512 
   513 lemma INF_sup: 
   514   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   515   by (simp add: sup_INF sup_commute)
   516 
   517 lemma SUP_inf:
   518   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   519   by (simp add: inf_SUP inf_commute)
   520 
   521 lemma Inf_sup_eq_top_iff:
   522   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   523   by (simp only: Inf_sup INF_top_conv)
   524 
   525 lemma Sup_inf_eq_bot_iff:
   526   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   527   by (simp only: Sup_inf SUP_bot_conv)
   528 
   529 lemma INF_sup_distrib2:
   530   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   531   by (subst INF_commute) (simp add: sup_INF INF_sup)
   532 
   533 lemma SUP_inf_distrib2:
   534   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   535   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   536 
   537 context
   538   fixes f :: "'a \<Rightarrow> 'b::complete_lattice"
   539   assumes "mono f"
   540 begin
   541 
   542 lemma mono_Inf:
   543   shows "f (\<Sqinter>A) \<le> (\<Sqinter>x\<in>A. f x)"
   544   using `mono f` by (auto intro: complete_lattice_class.INF_greatest Inf_lower dest: monoD)
   545 
   546 lemma mono_Sup:
   547   shows "(\<Squnion>x\<in>A. f x) \<le> f (\<Squnion>A)"
   548   using `mono f` by (auto intro: complete_lattice_class.SUP_least Sup_upper dest: monoD)
   549 
   550 end
   551 
   552 end
   553 
   554 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   555 begin
   556 
   557 lemma dual_complete_boolean_algebra:
   558   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   559   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   560 
   561 lemma uminus_Inf:
   562   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   563 proof (rule antisym)
   564   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   565     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   566   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   567     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   568 qed
   569 
   570 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   571   by (simp only: INF_def SUP_def uminus_Inf image_image)
   572 
   573 lemma uminus_Sup:
   574   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   575 proof -
   576   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_INF)
   577   then show ?thesis by simp
   578 qed
   579   
   580 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   581   by (simp only: INF_def SUP_def uminus_Sup image_image)
   582 
   583 end
   584 
   585 class complete_linorder = linorder + complete_lattice
   586 begin
   587 
   588 lemma dual_complete_linorder:
   589   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   590   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   591 
   592 lemma complete_linorder_inf_min: "inf = min"
   593   by (auto intro: antisym simp add: min_def fun_eq_iff)
   594 
   595 lemma complete_linorder_sup_max: "sup = max"
   596   by (auto intro: antisym simp add: max_def fun_eq_iff)
   597 
   598 lemma Inf_less_iff:
   599   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   600   unfolding not_le [symmetric] le_Inf_iff by auto
   601 
   602 lemma INF_less_iff:
   603   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   604   using Inf_less_iff [of "f ` A"] by simp
   605 
   606 lemma less_Sup_iff:
   607   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   608   unfolding not_le [symmetric] Sup_le_iff by auto
   609 
   610 lemma less_SUP_iff:
   611   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   612   using less_Sup_iff [of _ "f ` A"] by simp
   613 
   614 lemma Sup_eq_top_iff [simp]:
   615   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   616 proof
   617   assume *: "\<Squnion>A = \<top>"
   618   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   619   proof (intro allI impI)
   620     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   621       unfolding less_Sup_iff by auto
   622   qed
   623 next
   624   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   625   show "\<Squnion>A = \<top>"
   626   proof (rule ccontr)
   627     assume "\<Squnion>A \<noteq> \<top>"
   628     with top_greatest [of "\<Squnion>A"]
   629     have "\<Squnion>A < \<top>" unfolding le_less by auto
   630     then have "\<Squnion>A < \<Squnion>A"
   631       using * unfolding less_Sup_iff by auto
   632     then show False by auto
   633   qed
   634 qed
   635 
   636 lemma SUP_eq_top_iff [simp]:
   637   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   638   using Sup_eq_top_iff [of "f ` A"] by simp
   639 
   640 lemma Inf_eq_bot_iff [simp]:
   641   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   642   using dual_complete_linorder
   643   by (rule complete_linorder.Sup_eq_top_iff)
   644 
   645 lemma INF_eq_bot_iff [simp]:
   646   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   647   using Inf_eq_bot_iff [of "f ` A"] by simp
   648 
   649 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   650 proof safe
   651   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   652   then have "y > \<Sqinter>A" by auto
   653   then show "\<exists>a\<in>A. y > a"
   654     unfolding Inf_less_iff .
   655 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   656 
   657 lemma INF_le_iff:
   658   "INFIMUM A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   659   using Inf_le_iff [of "f ` A"] by simp
   660 
   661 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   662 proof safe
   663   fix y assume "x \<le> \<Squnion>A" "y < x"
   664   then have "y < \<Squnion>A" by auto
   665   then show "\<exists>a\<in>A. y < a"
   666     unfolding less_Sup_iff .
   667 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   668 
   669 lemma le_SUP_iff: "x \<le> SUPREMUM A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   670   using le_Sup_iff [of _ "f ` A"] by simp
   671 
   672 subclass complete_distrib_lattice
   673 proof
   674   fix a and B
   675   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   676     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   677       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   678         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   679 qed
   680 
   681 end
   682 
   683 
   684 subsection {* Complete lattice on @{typ bool} *}
   685 
   686 instantiation bool :: complete_lattice
   687 begin
   688 
   689 definition
   690   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   691 
   692 definition
   693   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   694 
   695 instance proof
   696 qed (auto intro: bool_induct)
   697 
   698 end
   699 
   700 lemma not_False_in_image_Ball [simp]:
   701   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   702   by auto
   703 
   704 lemma True_in_image_Bex [simp]:
   705   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   706   by auto
   707 
   708 lemma INF_bool_eq [simp]:
   709   "INFIMUM = Ball"
   710   by (simp add: fun_eq_iff INF_def)
   711 
   712 lemma SUP_bool_eq [simp]:
   713   "SUPREMUM = Bex"
   714   by (simp add: fun_eq_iff SUP_def)
   715 
   716 instance bool :: complete_boolean_algebra proof
   717 qed (auto intro: bool_induct)
   718 
   719 
   720 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   721 
   722 instantiation "fun" :: (type, complete_lattice) complete_lattice
   723 begin
   724 
   725 definition
   726   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   727 
   728 lemma Inf_apply [simp, code]:
   729   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   730   by (simp add: Inf_fun_def)
   731 
   732 definition
   733   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   734 
   735 lemma Sup_apply [simp, code]:
   736   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   737   by (simp add: Sup_fun_def)
   738 
   739 instance proof
   740 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   741 
   742 end
   743 
   744 lemma INF_apply [simp]:
   745   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   746   using Inf_apply [of "f ` A"] by (simp add: comp_def)
   747 
   748 lemma SUP_apply [simp]:
   749   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   750   using Sup_apply [of "f ` A"] by (simp add: comp_def)
   751 
   752 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   753 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf fun_eq_iff image_image
   754   simp del: Inf_image_eq Sup_image_eq)
   755 
   756 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   757 
   758 
   759 subsection {* Complete lattice on unary and binary predicates *}
   760 
   761 lemma INF1_iff: "(\<Sqinter>x\<in>A. B x) b = (\<forall>x\<in>A. B x b)"
   762   by simp
   763 
   764 lemma INF2_iff: "(\<Sqinter>x\<in>A. B x) b c = (\<forall>x\<in>A. B x b c)"
   765   by simp
   766 
   767 lemma INF1_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   768   by auto
   769 
   770 lemma INF2_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   771   by auto
   772 
   773 lemma INF1_D: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   774   by auto
   775 
   776 lemma INF2_D: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   777   by auto
   778 
   779 lemma INF1_E: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> (B a b \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   780   by auto
   781 
   782 lemma INF2_E: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> (B a b c \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   783   by auto
   784 
   785 lemma SUP1_iff: "(\<Squnion>x\<in>A. B x) b = (\<exists>x\<in>A. B x b)"
   786   by simp
   787 
   788 lemma SUP2_iff: "(\<Squnion>x\<in>A. B x) b c = (\<exists>x\<in>A. B x b c)"
   789   by simp
   790 
   791 lemma SUP1_I: "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   792   by auto
   793 
   794 lemma SUP2_I: "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   795   by auto
   796 
   797 lemma SUP1_E: "(\<Squnion>x\<in>A. B x) b \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b \<Longrightarrow> R) \<Longrightarrow> R"
   798   by auto
   799 
   800 lemma SUP2_E: "(\<Squnion>x\<in>A. B x) b c \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b c \<Longrightarrow> R) \<Longrightarrow> R"
   801   by auto
   802 
   803 
   804 subsection {* Complete lattice on @{typ "_ set"} *}
   805 
   806 instantiation "set" :: (type) complete_lattice
   807 begin
   808 
   809 definition
   810   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   811 
   812 definition
   813   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   814 
   815 instance proof
   816 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   817 
   818 end
   819 
   820 instance "set" :: (type) complete_boolean_algebra
   821 proof
   822 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   823   
   824 
   825 subsubsection {* Inter *}
   826 
   827 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   828   "Inter S \<equiv> \<Sqinter>S"
   829   
   830 notation (xsymbols)
   831   Inter  ("\<Inter>_" [900] 900)
   832 
   833 lemma Inter_eq:
   834   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   835 proof (rule set_eqI)
   836   fix x
   837   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   838     by auto
   839   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   840     by (simp add: Inf_set_def image_def)
   841 qed
   842 
   843 lemma Inter_iff [simp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   844   by (unfold Inter_eq) blast
   845 
   846 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   847   by (simp add: Inter_eq)
   848 
   849 text {*
   850   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   851   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   852   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   853 *}
   854 
   855 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   856   by auto
   857 
   858 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   859   -- {* ``Classical'' elimination rule -- does not require proving
   860     @{prop "X \<in> C"}. *}
   861   by (unfold Inter_eq) blast
   862 
   863 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   864   by (fact Inf_lower)
   865 
   866 lemma Inter_subset:
   867   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   868   by (fact Inf_less_eq)
   869 
   870 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   871   by (fact Inf_greatest)
   872 
   873 lemma Inter_empty: "\<Inter>{} = UNIV"
   874   by (fact Inf_empty) (* already simp *)
   875 
   876 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   877   by (fact Inf_UNIV) (* already simp *)
   878 
   879 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   880   by (fact Inf_insert) (* already simp *)
   881 
   882 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   883   by (fact less_eq_Inf_inter)
   884 
   885 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   886   by (fact Inf_union_distrib)
   887 
   888 lemma Inter_UNIV_conv [simp]:
   889   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   890   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   891   by (fact Inf_top_conv)+
   892 
   893 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   894   by (fact Inf_superset_mono)
   895 
   896 
   897 subsubsection {* Intersections of families *}
   898 
   899 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   900   "INTER \<equiv> INFIMUM"
   901 
   902 text {*
   903   Note: must use name @{const INTER} here instead of @{text INT}
   904   to allow the following syntax coexist with the plain constant name.
   905 *}
   906 
   907 syntax
   908   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   909   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   910 
   911 syntax (xsymbols)
   912   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   913   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   914 
   915 syntax (latex output)
   916   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   917   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   918 
   919 translations
   920   "INT x y. B"  == "INT x. INT y. B"
   921   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   922   "INT x. B"    == "INT x:CONST UNIV. B"
   923   "INT x:A. B"  == "CONST INTER A (%x. B)"
   924 
   925 print_translation {*
   926   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   927 *} -- {* to avoid eta-contraction of body *}
   928 
   929 lemma INTER_eq:
   930   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   931   by (auto intro!: INF_eqI)
   932 
   933 lemma Inter_image_eq:
   934   "\<Inter>(B ` A) = (\<Inter>x\<in>A. B x)"
   935   by (fact Inf_image_eq)
   936 
   937 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   938   using Inter_iff [of _ "B ` A"] by simp
   939 
   940 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   941   by (auto simp add: INF_def image_def)
   942 
   943 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   944   by auto
   945 
   946 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   947   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   948   by (auto simp add: INF_def image_def)
   949 
   950 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   951   by blast
   952 
   953 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   954   by blast
   955 
   956 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   957   by (fact INF_lower)
   958 
   959 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   960   by (fact INF_greatest)
   961 
   962 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
   963   by (fact INF_empty)
   964 
   965 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   966   by (fact INF_absorb)
   967 
   968 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   969   by (fact le_INF_iff)
   970 
   971 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   972   by (fact INF_insert)
   973 
   974 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   975   by (fact INF_union)
   976 
   977 lemma INT_insert_distrib:
   978   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   979   by blast
   980 
   981 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   982   by (fact INF_constant)
   983 
   984 lemma INTER_UNIV_conv:
   985  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   986  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   987   by (fact INF_top_conv)+ (* already simp *)
   988 
   989 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   990   by (fact INF_UNIV_bool_expand)
   991 
   992 lemma INT_anti_mono:
   993   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   994   -- {* The last inclusion is POSITIVE! *}
   995   by (fact INF_superset_mono)
   996 
   997 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   998   by blast
   999 
  1000 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
  1001   by blast
  1002 
  1003 
  1004 subsubsection {* Union *}
  1005 
  1006 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
  1007   "Union S \<equiv> \<Squnion>S"
  1008 
  1009 notation (xsymbols)
  1010   Union  ("\<Union>_" [900] 900)
  1011 
  1012 lemma Union_eq:
  1013   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
  1014 proof (rule set_eqI)
  1015   fix x
  1016   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
  1017     by auto
  1018   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
  1019     by (simp add: Sup_set_def image_def)
  1020 qed
  1021 
  1022 lemma Union_iff [simp]:
  1023   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
  1024   by (unfold Union_eq) blast
  1025 
  1026 lemma UnionI [intro]:
  1027   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
  1028   -- {* The order of the premises presupposes that @{term C} is rigid;
  1029     @{term A} may be flexible. *}
  1030   by auto
  1031 
  1032 lemma UnionE [elim!]:
  1033   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
  1034   by auto
  1035 
  1036 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
  1037   by (fact Sup_upper)
  1038 
  1039 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
  1040   by (fact Sup_least)
  1041 
  1042 lemma Union_empty: "\<Union>{} = {}"
  1043   by (fact Sup_empty) (* already simp *)
  1044 
  1045 lemma Union_UNIV: "\<Union>UNIV = UNIV"
  1046   by (fact Sup_UNIV) (* already simp *)
  1047 
  1048 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
  1049   by (fact Sup_insert) (* already simp *)
  1050 
  1051 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
  1052   by (fact Sup_union_distrib)
  1053 
  1054 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1055   by (fact Sup_inter_less_eq)
  1056 
  1057 lemma Union_empty_conv: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1058   by (fact Sup_bot_conv) (* already simp *)
  1059 
  1060 lemma empty_Union_conv: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1061   by (fact Sup_bot_conv) (* already simp *)
  1062 
  1063 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1064   by blast
  1065 
  1066 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1067   by blast
  1068 
  1069 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
  1070   by (fact Sup_subset_mono)
  1071 
  1072 
  1073 subsubsection {* Unions of families *}
  1074 
  1075 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1076   "UNION \<equiv> SUPREMUM"
  1077 
  1078 text {*
  1079   Note: must use name @{const UNION} here instead of @{text UN}
  1080   to allow the following syntax coexist with the plain constant name.
  1081 *}
  1082 
  1083 syntax
  1084   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1085   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1086 
  1087 syntax (xsymbols)
  1088   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1089   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1090 
  1091 syntax (latex output)
  1092   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1093   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1094 
  1095 translations
  1096   "UN x y. B"   == "UN x. UN y. B"
  1097   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
  1098   "UN x. B"     == "UN x:CONST UNIV. B"
  1099   "UN x:A. B"   == "CONST UNION A (%x. B)"
  1100 
  1101 text {*
  1102   Note the difference between ordinary xsymbol syntax of indexed
  1103   unions and intersections (e.g.\ @{text"\<Union>a\<^sub>1\<in>A\<^sub>1. B"})
  1104   and their \LaTeX\ rendition: @{term"\<Union>a\<^sub>1\<in>A\<^sub>1. B"}. The
  1105   former does not make the index expression a subscript of the
  1106   union/intersection symbol because this leads to problems with nested
  1107   subscripts in Proof General.
  1108 *}
  1109 
  1110 print_translation {*
  1111   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1112 *} -- {* to avoid eta-contraction of body *}
  1113 
  1114 lemma UNION_eq:
  1115   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1116   by (auto intro!: SUP_eqI)
  1117 
  1118 lemma bind_UNION [code]:
  1119   "Set.bind A f = UNION A f"
  1120   by (simp add: bind_def UNION_eq)
  1121 
  1122 lemma member_bind [simp]:
  1123   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1124   by (simp add: bind_UNION)
  1125 
  1126 lemma Union_image_eq:
  1127   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
  1128   by (fact Sup_image_eq)
  1129 
  1130 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1131   using Union_iff [of _ "B ` A"] by simp
  1132 
  1133 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1134   -- {* The order of the premises presupposes that @{term A} is rigid;
  1135     @{term b} may be flexible. *}
  1136   by auto
  1137 
  1138 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1139   by (auto simp add: SUP_def image_def)
  1140 
  1141 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1142   by blast
  1143 
  1144 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1145   by (fact SUP_upper)
  1146 
  1147 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1148   by (fact SUP_least)
  1149 
  1150 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1151   by blast
  1152 
  1153 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1154   by blast
  1155 
  1156 lemma UN_empty: "(\<Union>x\<in>{}. B x) = {}"
  1157   by (fact SUP_empty)
  1158 
  1159 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1160   by (fact SUP_bot) (* already simp *)
  1161 
  1162 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1163   by (fact SUP_absorb)
  1164 
  1165 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1166   by (fact SUP_insert)
  1167 
  1168 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1169   by (fact SUP_union)
  1170 
  1171 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1172   by blast
  1173 
  1174 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1175   by (fact SUP_le_iff)
  1176 
  1177 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1178   by (fact SUP_constant)
  1179 
  1180 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1181   by blast
  1182 
  1183 lemma UNION_empty_conv:
  1184   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1185   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1186   by (fact SUP_bot_conv)+ (* already simp *)
  1187 
  1188 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1189   by blast
  1190 
  1191 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1192   by blast
  1193 
  1194 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1195   by blast
  1196 
  1197 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1198   by (auto simp add: split_if_mem2)
  1199 
  1200 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1201   by (fact SUP_UNIV_bool_expand)
  1202 
  1203 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1204   by blast
  1205 
  1206 lemma UN_mono:
  1207   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1208     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1209   by (fact SUP_subset_mono)
  1210 
  1211 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1212   by blast
  1213 
  1214 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1215   by blast
  1216 
  1217 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1218   -- {* NOT suitable for rewriting *}
  1219   by blast
  1220 
  1221 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1222   by blast
  1223 
  1224 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1225   by blast
  1226 
  1227 
  1228 subsubsection {* Distributive laws *}
  1229 
  1230 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1231   by (fact inf_Sup)
  1232 
  1233 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1234   by (fact sup_Inf)
  1235 
  1236 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1237   by (fact Sup_inf)
  1238 
  1239 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1240   by (rule sym) (rule INF_inf_distrib)
  1241 
  1242 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1243   by (rule sym) (rule SUP_sup_distrib)
  1244 
  1245 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)" -- {* FIXME drop *}
  1246   by (simp add: INT_Int_distrib)
  1247 
  1248 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)" -- {* FIXME drop *}
  1249   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1250   -- {* Union of a family of unions *}
  1251   by (simp add: UN_Un_distrib)
  1252 
  1253 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1254   by (fact sup_INF)
  1255 
  1256 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1257   -- {* Halmos, Naive Set Theory, page 35. *}
  1258   by (fact inf_SUP)
  1259 
  1260 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1261   by (fact SUP_inf_distrib2)
  1262 
  1263 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1264   by (fact INF_sup_distrib2)
  1265 
  1266 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1267   by (fact Sup_inf_eq_bot_iff)
  1268 
  1269 
  1270 subsection {* Injections and bijections *}
  1271 
  1272 lemma inj_on_Inter:
  1273   "S \<noteq> {} \<Longrightarrow> (\<And>A. A \<in> S \<Longrightarrow> inj_on f A) \<Longrightarrow> inj_on f (\<Inter>S)"
  1274   unfolding inj_on_def by blast
  1275 
  1276 lemma inj_on_INTER:
  1277   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> inj_on f (A i)) \<Longrightarrow> inj_on f (\<Inter>i \<in> I. A i)"
  1278   unfolding inj_on_def by blast
  1279 
  1280 lemma inj_on_UNION_chain:
  1281   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1282          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1283   shows "inj_on f (\<Union> i \<in> I. A i)"
  1284 proof -
  1285   {
  1286     fix i j x y
  1287     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
  1288       and ***: "f x = f y"
  1289     have "x = y"
  1290     proof -
  1291       {
  1292         assume "A i \<le> A j"
  1293         with ** have "x \<in> A j" by auto
  1294         with INJ * ** *** have ?thesis
  1295         by(auto simp add: inj_on_def)
  1296       }
  1297       moreover
  1298       {
  1299         assume "A j \<le> A i"
  1300         with ** have "y \<in> A i" by auto
  1301         with INJ * ** *** have ?thesis
  1302         by(auto simp add: inj_on_def)
  1303       }
  1304       ultimately show ?thesis using CH * by blast
  1305     qed
  1306   }
  1307   then show ?thesis by (unfold inj_on_def UNION_eq) auto
  1308 qed
  1309 
  1310 lemma bij_betw_UNION_chain:
  1311   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1312          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
  1313   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
  1314 proof (unfold bij_betw_def, auto)
  1315   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1316   using BIJ bij_betw_def[of f] by auto
  1317   thus "inj_on f (\<Union> i \<in> I. A i)"
  1318   using CH inj_on_UNION_chain[of I A f] by auto
  1319 next
  1320   fix i x
  1321   assume *: "i \<in> I" "x \<in> A i"
  1322   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
  1323   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
  1324 next
  1325   fix i x'
  1326   assume *: "i \<in> I" "x' \<in> A' i"
  1327   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
  1328   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
  1329     using * by blast
  1330   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by blast
  1331 qed
  1332 
  1333 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
  1334 lemma image_INT:
  1335    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
  1336     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1337 apply (simp add: inj_on_def, blast)
  1338 done
  1339 
  1340 (*Compare with image_INT: no use of inj_on, and if f is surjective then
  1341   it doesn't matter whether A is empty*)
  1342 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1343 apply (simp add: bij_def)
  1344 apply (simp add: inj_on_def surj_def, blast)
  1345 done
  1346 
  1347 lemma UNION_fun_upd:
  1348   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
  1349 by (auto split: if_splits)
  1350 
  1351 
  1352 subsubsection {* Complement *}
  1353 
  1354 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1355   by (fact uminus_INF)
  1356 
  1357 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1358   by (fact uminus_SUP)
  1359 
  1360 
  1361 subsubsection {* Miniscoping and maxiscoping *}
  1362 
  1363 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1364            and Intersections. *}
  1365 
  1366 lemma UN_simps [simp]:
  1367   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1368   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1369   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1370   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1371   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1372   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1373   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1374   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1375   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1376   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1377   by auto
  1378 
  1379 lemma INT_simps [simp]:
  1380   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1381   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1382   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1383   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1384   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1385   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1386   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1387   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1388   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1389   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1390   by auto
  1391 
  1392 lemma UN_ball_bex_simps [simp]:
  1393   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1394   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1395   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1396   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1397   by auto
  1398 
  1399 
  1400 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1401 
  1402 lemma UN_extend_simps:
  1403   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1404   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1405   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1406   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1407   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1408   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1409   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1410   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1411   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1412   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1413   by auto
  1414 
  1415 lemma INT_extend_simps:
  1416   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1417   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1418   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1419   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1420   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1421   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1422   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1423   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1424   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1425   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1426   by auto
  1427 
  1428 text {* Finally *}
  1429 
  1430 no_notation
  1431   less_eq (infix "\<sqsubseteq>" 50) and
  1432   less (infix "\<sqsubset>" 50)
  1433 
  1434 lemmas mem_simps =
  1435   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1436   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1437   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1438 
  1439 end
  1440