src/Pure/pattern.ML
author haftmann
Fri Oct 28 16:35:40 2005 +0200 (2005-10-28)
changeset 18011 685d95c793ff
parent 17756 d4a35f82fbb4
child 18182 786d83044780
permissions -rw-r--r--
cleaned up nth, nth_update, nth_map and nth_string functions
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4 
     5 Unification of Higher-Order Patterns.
     6 
     7 See also:
     8 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     9 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    10 
    11 TODO: optimize red by special-casing it
    12 *)
    13 
    14 infix aeconv;
    15 
    16 signature PATTERN =
    17 sig
    18   val trace_unify_fail: bool ref
    19   val aeconv: term * term -> bool
    20   val eta_contract: term -> term
    21   val eta_long: typ list -> term -> term
    22   val beta_eta_contract: term -> term
    23   val eta_contract_atom: term -> term
    24   val match: theory -> term * term -> Type.tyenv * Envir.tenv
    25   val first_order_match: theory -> term * term -> Type.tyenv * Envir.tenv
    26   val matches: theory -> term * term -> bool
    27   val matches_subterm: theory -> term * term -> bool
    28   val unify: theory * Envir.env * (term * term)list -> Envir.env
    29   val first_order: term -> bool
    30   val pattern: term -> bool
    31   val rewrite_term: theory -> (term * term) list -> (term -> term option) list -> term -> term
    32   exception Unif
    33   exception MATCH
    34   exception Pattern
    35 end;
    36 
    37 structure Pattern: PATTERN =
    38 struct
    39 
    40 exception Unif;
    41 exception Pattern;
    42 
    43 val trace_unify_fail = ref false;
    44 
    45 fun string_of_term thy env binders t = Sign.string_of_term thy
    46   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    47 
    48 fun bname binders i = fst (nth binders i);
    49 fun bnames binders is = space_implode " " (map (bname binders) is);
    50 
    51 fun typ_clash thy (tye,T,U) =
    52   if !trace_unify_fail
    53   then let val t = Sign.string_of_typ thy (Envir.norm_type tye T)
    54            and u = Sign.string_of_typ thy (Envir.norm_type tye U)
    55        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    56   else ()
    57 
    58 fun clash a b =
    59   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    60 
    61 fun boundVar binders i =
    62   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    63 
    64 fun clashBB binders i j =
    65   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    66   else ()
    67 
    68 fun clashB binders i s =
    69   if !trace_unify_fail then clash (boundVar binders i) s
    70   else ()
    71 
    72 fun proj_fail thy (env,binders,F,_,is,t) =
    73   if !trace_unify_fail
    74   then let val f = Syntax.string_of_vname F
    75            val xs = bnames binders is
    76            val u = string_of_term thy env binders t
    77            val ys = bnames binders (loose_bnos t \\ is)
    78        in tracing("Cannot unify variable " ^ f ^
    79                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    80                "\nTerm contains additional bound variable(s) " ^ ys)
    81        end
    82   else ()
    83 
    84 fun ocheck_fail thy (F,t,binders,env) =
    85   if !trace_unify_fail
    86   then let val f = Syntax.string_of_vname F
    87            val u = string_of_term thy env binders t
    88        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    89                   "\nCannot unify!\n")
    90        end
    91   else ()
    92 
    93 fun occurs(F,t,env) =
    94     let fun occ(Var (G, T))   = (case Envir.lookup (env, (G, T)) of
    95                                  SOME(t) => occ t
    96                                | NONE    => F=G)
    97           | occ(t1$t2)      = occ t1 orelse occ t2
    98           | occ(Abs(_,_,t)) = occ t
    99           | occ _           = false
   100     in occ t end;
   101 
   102 
   103 fun mapbnd f =
   104     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   105           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   106           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   107           | mpb _ atom           = atom
   108     in mpb 0 end;
   109 
   110 fun idx [] j     = raise Unif
   111   | idx(i::is) j = if (i:int) =j then length is else idx is j;
   112 
   113 fun mkabs (binders,is,t)  =
   114     let fun mk(i::is) = let val (x,T) = nth binders i
   115                         in Abs(x,T,mk is) end
   116           | mk []     = t
   117     in mk is end;
   118 
   119 val incr = mapbnd (fn i => i+1);
   120 
   121 fun ints_of []             = []
   122   | ints_of (Bound i ::bs) =
   123       let val is = ints_of bs
   124       in if i mem_int is then raise Pattern else i::is end
   125   | ints_of _              = raise Pattern;
   126 
   127 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   128 
   129 
   130 fun app (s,(i::is)) = app (s$Bound(i),is)
   131   | app (s,[])      = s;
   132 
   133 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   134   | red t            []      [] = t
   135   | red t            is      jn = app (mapbnd (nth jn) t,is);
   136 
   137 
   138 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   139 fun split_type (T,0,Ts)                    = (Ts,T)
   140   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   141   | split_type _                           = error("split_type");
   142 
   143 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   144   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   145   in map (nth Ts) is ---> U end;
   146 
   147 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   148 
   149 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   150   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   151   in Envir.update (((F, T), mkhnf (binders, is, G, js)), env') end;
   152 
   153 
   154 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   155 fun mk_proj_list is =
   156     let fun mk(i::is,j) = if isSome i then j :: mk(is,j-1) else mk(is,j-1)
   157           | mk([],_)    = []
   158     in mk(is,length is - 1) end;
   159 
   160 fun proj(s,env,binders,is) =
   161     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   162         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   163               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   164                             in (Abs(a,T,t'),env') end
   165             | t => (case strip_comb t of
   166                 (c as Const _,ts) =>
   167                          let val (ts',env') = prs(ts,env,d,binders)
   168                          in (list_comb(c,ts'),env') end
   169                  | (f as Free _,ts) =>
   170                          let val (ts',env') = prs(ts,env,d,binders)
   171                          in (list_comb(f,ts'),env') end
   172                  | (Bound(i),ts) =>
   173                          let val j = trans d i
   174                              val (ts',env') = prs(ts,env,d,binders)
   175                          in (list_comb(Bound j,ts'),env') end
   176                  | (Var(F as (a,_),Fty),ts) =>
   177                       let val js = ints_of' env ts;
   178                           val js' = map (try (trans d)) js;
   179                           val ks = mk_proj_list js';
   180                           val ls = List.mapPartial I js'
   181                           val Hty = type_of_G env (Fty,length js,ks)
   182                           val (env',H) = Envir.genvar a (env,Hty)
   183                           val env'' =
   184                             Envir.update (((F, Fty), mkhnf (binders, js, H, ks)), env')
   185                       in (app(H,ls),env'') end
   186                  | _  => raise Pattern))
   187         and prs(s::ss,env,d,binders) =
   188               let val (s',env1) = pr(s,env,d,binders)
   189                   val (ss',env2) = prs(ss,env1,d,binders)
   190               in (s'::ss',env2) end
   191           | prs([],env,_,_) = ([],env)
   192    in if downto0(is,length binders - 1) then (s,env)
   193       else pr(s,env,0,binders)
   194    end;
   195 
   196 
   197 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   198 fun mk_ff_list(is,js) =
   199     let fun mk([],[],_)        = []
   200           | mk(i::is,j::js, k) = if (i:int) = j then k :: mk(is,js,k-1)
   201                                         else mk(is,js,k-1)
   202           | mk _               = error"mk_ff_list"
   203     in mk(is,js,length is-1) end;
   204 
   205 fun flexflex1(env,binders,F,Fty,is,js) =
   206   if is=js then env
   207   else let val ks = mk_ff_list(is,js)
   208        in mknewhnf(env,binders,is,F,Fty,ks) end;
   209 
   210 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   211   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   212             if js subset_int is
   213             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   214                  in Envir.update (((F, Fty), t), env) end
   215             else let val ks = is inter_int js
   216                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   217                      val (env',H) = Envir.genvar a (env,Hty)
   218                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   219                  in Envir.update (((G, Gty), lam js), Envir.update (((F, Fty), lam is), env'))
   220                  end;
   221   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   222 
   223 fun unify_types thy (T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   224   if T=U then env
   225   else let val (iTs',maxidx') = Sign.typ_unify thy (U, T) (iTs, maxidx)
   226        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   227        handle Type.TUNIFY => (typ_clash thy (iTs,T,U); raise Unif);
   228 
   229 fun unif thy binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   230       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   231          let val name = if ns = "" then nt else ns
   232          in unif thy ((name,Ts)::binders) (env,(ts,tt)) end
   233     | (Abs(ns,Ts,ts),t) => unif thy ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   234     | (t,Abs(nt,Tt,tt)) => unif thy ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   235     | p => cases thy (binders,env,p)
   236 
   237 and cases thy (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   238        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   239          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   240                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   241       | ((Var(F,Fty),ss),_)           => flexrigid thy (env,binders,F,Fty,ints_of' env ss,t)
   242       | (_,(Var(F,Fty),ts))           => flexrigid thy (env,binders,F,Fty,ints_of' env ts,s)
   243       | ((Const c,ss),(Const d,ts))   => rigidrigid thy (env,binders,c,d,ss,ts)
   244       | ((Free(f),ss),(Free(g),ts))   => rigidrigid thy (env,binders,f,g,ss,ts)
   245       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB thy (env,binders,i,j,ss,ts)
   246       | ((Abs(_),_),_)                => raise Pattern
   247       | (_,(Abs(_),_))                => raise Pattern
   248       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   249       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   250       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   251       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   252       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   253       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   254 
   255 
   256 and rigidrigid thy (env,binders,(a,Ta),(b,Tb),ss,ts) =
   257       if a<>b then (clash a b; raise Unif)
   258       else Library.foldl (unif thy binders) (unify_types thy (Ta,Tb,env), ss~~ts)
   259 
   260 and rigidrigidB thy (env,binders,i,j,ss,ts) =
   261      if i <> j then (clashBB binders i j; raise Unif)
   262      else Library.foldl (unif thy binders) (env ,ss~~ts)
   263 
   264 and flexrigid thy (params as (env,binders,F,Fty,is,t)) =
   265       if occurs(F,t,env) then (ocheck_fail thy (F,t,binders,env); raise Unif)
   266       else (let val (u,env') = proj(t,env,binders,is)
   267             in Envir.update (((F, Fty), mkabs (binders, is, u)), env') end
   268             handle Unif => (proj_fail thy params; raise Unif));
   269 
   270 fun unify(thy,env,tus) = Library.foldl (unif thy []) (env,tus);
   271 
   272 
   273 (*Eta-contract a term (fully)*)
   274 
   275 fun eta_contract t =
   276   let
   277     exception SAME;
   278     fun eta (Abs (a, T, body)) =
   279       ((case eta body of
   280           body' as (f $ Bound 0) =>
   281             if loose_bvar1 (f, 0) then Abs(a, T, body')
   282             else incr_boundvars ~1 f
   283         | body' => Abs (a, T, body')) handle SAME =>
   284        (case body of
   285           (f $ Bound 0) =>
   286             if loose_bvar1 (f, 0) then raise SAME
   287             else incr_boundvars ~1 f
   288         | _ => raise SAME))
   289       | eta (f $ t) =
   290           (let val f' = eta f
   291            in f' $ etah t end handle SAME => f $ eta t)
   292       | eta _ = raise SAME
   293     and etah t = (eta t handle SAME => t)
   294   in etah t end;
   295 
   296 val beta_eta_contract = eta_contract o Envir.beta_norm;
   297 
   298 (*Eta-contract a term from outside: just enough to reduce it to an atom
   299 DOESN'T QUITE WORK!
   300 *)
   301 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   302       (case  eta_contract2 body  of
   303         body' as (f $ Bound 0) =>
   304             if loose_bvar1(f,0) then Abs(a,T,body')
   305             else eta_contract_atom (incr_boundvars ~1 f)
   306       | _ => t0)
   307   | eta_contract_atom t = t
   308 and eta_contract2 (f$t) = f $ eta_contract_atom t
   309   | eta_contract2 t     = eta_contract_atom t;
   310 
   311 (* put a term into eta long beta normal form *)
   312 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   313   | eta_long Ts t = (case strip_comb t of
   314       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   315     | (u, ts) =>
   316       let
   317         val Us = binder_types (fastype_of1 (Ts, t));
   318         val i = length Us
   319       in list_abs (map (pair "x") Us,
   320         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   321           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   322       end);
   323 
   324 
   325 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   326   Note that Consts and Vars may have more than one type.*)
   327 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   328 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   329   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   330   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   331   | aconv_aux (Bound i,    Bound j)    = i=j
   332   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   333   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   334   | aconv_aux _ =  false;
   335 
   336 
   337 (*** Matching ***)
   338 
   339 exception MATCH;
   340 
   341 fun typ_match thy (tyenv, TU) = Sign.typ_match thy TU tyenv
   342   handle Type.TYPE_MATCH => raise MATCH;
   343 
   344 (*First-order matching;
   345   fomatch thy (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   346   The pattern and object may have variables in common.
   347   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   348   Object is eta-contracted on the fly (by eta-expanding the pattern).
   349   Precondition: the pattern is already eta-contracted!
   350   Note: types are matched on the fly *)
   351 fun fomatch thy =
   352   let
   353     fun mtch (instsp as (tyinsts,insts)) = fn
   354         (Var(ixn,T), t)  =>
   355           if loose_bvar(t,0) then raise MATCH
   356           else (case Envir.lookup' (insts, (ixn, T)) of
   357                   NONE => (typ_match thy (tyinsts, (T, fastype_of t)),
   358                            Vartab.update_new (ixn, (T, t)) insts)
   359                 | SOME u => if t aeconv u then instsp else raise MATCH)
   360       | (Free (a,T), Free (b,U)) =>
   361           if a=b then (typ_match thy (tyinsts,(T,U)), insts) else raise MATCH
   362       | (Const (a,T), Const (b,U))  =>
   363           if a=b then (typ_match thy (tyinsts,(T,U)), insts) else raise MATCH
   364       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   365       | (Abs(_,T,t), Abs(_,U,u))  =>
   366           mtch (typ_match thy (tyinsts,(T,U)),insts) (t,u)
   367       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   368       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   369       | _ => raise MATCH
   370   in mtch end;
   371 
   372 fun first_order_match thy = fomatch thy (Vartab.empty, Vartab.empty);
   373 
   374 (* Matching of higher-order patterns *)
   375 
   376 fun match_bind(itms,binders,ixn,T,is,t) =
   377   let val js = loose_bnos t
   378   in if null is
   379      then if null js then Vartab.update_new (ixn, (T, t)) itms else raise MATCH
   380      else if js subset_int is
   381           then let val t' = if downto0(is,length binders - 1) then t
   382                             else mapbnd (idx is) t
   383                in Vartab.update_new (ixn, (T, mkabs (binders, is, t'))) itms end
   384           else raise MATCH
   385   end;
   386 
   387 fun match thy (po as (pat,obj)) =
   388 let
   389   (* Pre: pat and obj have same type *)
   390   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   391     case pat of
   392       Abs(ns,Ts,ts) =>
   393         (case obj of
   394            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   395          | _ => let val Tt = Envir.typ_subst_TVars iTs Ts
   396                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   397     | _ => (case obj of
   398               Abs(nt,Tt,tt) =>
   399                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   400             | _ => cases(binders,env,pat,obj))
   401 
   402   and cases(binders,env as (iTs,itms),pat,obj) =
   403     let val (ph,pargs) = strip_comb pat
   404         fun rigrig1(iTs,oargs) =
   405               Library.foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   406         fun rigrig2((a:string,Ta),(b,Tb),oargs) =
   407               if a <> b then raise MATCH
   408               else rigrig1(typ_match thy (iTs,(Ta,Tb)), oargs)
   409     in case ph of
   410          Var(ixn,T) =>
   411            let val is = ints_of pargs
   412            in case Envir.lookup' (itms, (ixn, T)) of
   413                 NONE => (iTs,match_bind(itms,binders,ixn,T,is,obj))
   414               | SOME u => if obj aeconv (red u is []) then env
   415                           else raise MATCH
   416            end
   417        | _ =>
   418            let val (oh,oargs) = strip_comb obj
   419            in case (ph,oh) of
   420                 (Const c,Const d) => rigrig2(c,d,oargs)
   421               | (Free f,Free g)   => rigrig2(f,g,oargs)
   422               | (Bound i,Bound j) => if i<>j then raise MATCH
   423                                      else rigrig1(iTs,oargs)
   424               | (Abs _, _)        => raise Pattern
   425               | (_, Abs _)        => raise Pattern
   426               | _                 => raise MATCH
   427            end
   428     end;
   429 
   430   val pT = fastype_of pat
   431   and oT = fastype_of obj
   432   val iTs = typ_match thy (Vartab.empty, (pT,oT))
   433   val insts2 = (iTs, Vartab.empty)
   434 
   435 in mtch [] (insts2, po)
   436    handle Pattern => fomatch thy insts2 po
   437 end;
   438 
   439 (*Predicate: does the pattern match the object?*)
   440 fun matches thy po = (match thy po; true) handle MATCH => false;
   441 
   442 (* Does pat match a subterm of obj? *)
   443 fun matches_subterm thy (pat,obj) =
   444   let fun msub(bounds,obj) = matches thy (pat,obj) orelse
   445             (case obj of
   446               Abs(x,T,t) => let val y = variant bounds x
   447                                 val f = Free(":" ^ y,T)
   448                             in msub(x::bounds,subst_bound(f,t)) end
   449             | s$t => msub(bounds,s) orelse msub(bounds,t)
   450             | _ => false)
   451   in msub([],obj) end;
   452 
   453 fun first_order(Abs(_,_,t)) = first_order t
   454   | first_order(t $ u) = first_order t andalso first_order u andalso
   455                          not(is_Var t)
   456   | first_order _ = true;
   457 
   458 fun pattern(Abs(_,_,t)) = pattern t
   459   | pattern(t) = let val (head,args) = strip_comb t
   460                  in if is_Var head
   461                     then let val _ = ints_of args in true end
   462                          handle Pattern => false
   463                     else forall pattern args
   464                  end;
   465 
   466 
   467 (* rewriting -- simple but fast *)
   468 
   469 fun rewrite_term thy rules procs tm =
   470   let
   471     val skel0 = Bound 0;
   472 
   473     fun variant_absfree bounds (x, T, t) =
   474       let
   475         val (x', t') = Term.dest_abs (Term.bound bounds, T, t);
   476         fun abs u = Abs (x, T, abstract_over (Free (x', T), u));
   477       in (abs, t') end;
   478 
   479     fun match_rew tm (tm1, tm2) =
   480       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2 in
   481         SOME (Envir.subst_vars (match thy (tm1, tm)) rtm, rtm)
   482           handle MATCH => NONE
   483       end;
   484 
   485     fun rew (Abs (_, _, body) $ t) = SOME (subst_bound (t, body), skel0)
   486       | rew tm = (case get_first (match_rew tm) rules of
   487           NONE => Option.map (rpair skel0) (get_first (fn p => p tm) procs)
   488         | x => x);
   489 
   490     fun rew1 bounds (Var _) _ = NONE
   491       | rew1 bounds skel tm = (case rew2 bounds skel tm of
   492           SOME tm1 => (case rew tm1 of
   493               SOME (tm2, skel') => SOME (if_none (rew1 bounds skel' tm2) tm2)
   494             | NONE => SOME tm1)
   495         | NONE => (case rew tm of
   496               SOME (tm1, skel') => SOME (if_none (rew1 bounds skel' tm1) tm1)
   497             | NONE => NONE))
   498 
   499     and rew2 bounds skel (tm1 $ tm2) = (case tm1 of
   500             Abs (_, _, body) =>
   501               let val tm' = subst_bound (tm2, body)
   502               in SOME (if_none (rew2 bounds skel0 tm') tm') end
   503           | _ =>
   504             let val (skel1, skel2) = (case skel of
   505                 skel1 $ skel2 => (skel1, skel2)
   506               | _ => (skel0, skel0))
   507             in case rew1 bounds skel1 tm1 of
   508                 SOME tm1' => (case rew1 bounds skel2 tm2 of
   509                     SOME tm2' => SOME (tm1' $ tm2')
   510                   | NONE => SOME (tm1' $ tm2))
   511               | NONE => (case rew1 bounds skel2 tm2 of
   512                     SOME tm2' => SOME (tm1 $ tm2')
   513                   | NONE => NONE)
   514             end)
   515       | rew2 bounds skel (Abs body) =
   516           let
   517             val (abs, tm') = variant_absfree bounds body;
   518             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   519           in case rew1 (bounds + 1) skel' tm' of
   520               SOME tm'' => SOME (abs tm'')
   521             | NONE => NONE
   522           end
   523       | rew2 _ _ _ = NONE;
   524 
   525   in if_none (rew1 0 skel0 tm) tm end;
   526 
   527 end;
   528 
   529 val trace_unify_fail = Pattern.trace_unify_fail;