src/Pure/sign.ML
author wenzelm
Thu Aug 30 15:04:44 2007 +0200 (2007-08-30)
changeset 24485 687bbb686ef9
parent 24370 757b093e3459
child 24517 eaed6ac5f7f2
permissions -rw-r--r--
infer_types: general check_typs instead of Type.cert_typ_mode;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_trfuns:
    27     (string * (ast list -> ast)) list *
    28     (string * (term list -> term)) list *
    29     (string * (term list -> term)) list *
    30     (string * (ast list -> ast)) list -> theory -> theory
    31   val add_trfunsT:
    32     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    33   val add_advanced_trfuns:
    34     (string * (Proof.context -> ast list -> ast)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> term list -> term)) list *
    37     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    38   val add_advanced_trfunsT:
    39     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    40   val add_tokentrfuns:
    41     (string * string * (string -> output * int)) list -> theory -> theory
    42   val add_mode_tokentrfuns: string -> (string * (string -> output * int)) list
    43     -> theory -> theory
    44   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    46   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    48   val add_path: string -> theory -> theory
    49   val parent_path: theory -> theory
    50   val root_path: theory -> theory
    51   val absolute_path: theory -> theory
    52   val local_path: theory -> theory
    53   val no_base_names: theory -> theory
    54   val qualified_names: theory -> theory
    55   val sticky_prefix: string -> theory -> theory
    56   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    57     theory -> theory
    58   val restore_naming: theory -> theory -> theory
    59 end
    60 
    61 signature SIGN =
    62 sig
    63   val rep_sg: theory ->
    64    {naming: NameSpace.naming,
    65     syn: Syntax.syntax,
    66     tsig: Type.tsig,
    67     consts: Consts.T}
    68   val naming_of: theory -> NameSpace.naming
    69   val base_name: string -> bstring
    70   val full_name: theory -> bstring -> string
    71   val full_name_path: theory -> string -> bstring -> string
    72   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    73   val syn_of: theory -> Syntax.syntax
    74   val tsig_of: theory -> Type.tsig
    75   val classes_of: theory -> Sorts.algebra
    76   val all_classes: theory -> class list
    77   val super_classes: theory -> class -> class list
    78   val defaultS: theory -> sort
    79   val subsort: theory -> sort * sort -> bool
    80   val of_sort: theory -> typ * sort -> bool
    81   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    82   val universal_witness: theory -> (typ * sort) option
    83   val all_sorts_nonempty: theory -> bool
    84   val typ_instance: theory -> typ * typ -> bool
    85   val typ_equiv: theory -> typ * typ -> bool
    86   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    87   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    88   val is_logtype: theory -> string -> bool
    89   val consts_of: theory -> Consts.T
    90   val const_constraint: theory -> string -> typ option
    91   val the_const_constraint: theory -> string -> typ
    92   val const_type: theory -> string -> typ option
    93   val the_const_type: theory -> string -> typ
    94   val declared_tyname: theory -> string -> bool
    95   val declared_const: theory -> string -> bool
    96   val const_monomorphic: theory -> string -> bool
    97   val const_syntax_name: theory -> string -> string
    98   val const_typargs: theory -> string * typ -> typ list
    99   val const_instance: theory -> string * typ list -> typ
   100   val class_space: theory -> NameSpace.T
   101   val type_space: theory -> NameSpace.T
   102   val const_space: theory -> NameSpace.T
   103   val intern_class: theory -> xstring -> string
   104   val extern_class: theory -> string -> xstring
   105   val intern_type: theory -> xstring -> string
   106   val extern_type: theory -> string -> xstring
   107   val intern_const: theory -> xstring -> string
   108   val extern_const: theory -> string -> xstring
   109   val intern_sort: theory -> sort -> sort
   110   val extern_sort: theory -> sort -> sort
   111   val intern_typ: theory -> typ -> typ
   112   val extern_typ: theory -> typ -> typ
   113   val intern_term: theory -> term -> term
   114   val extern_term: (string -> xstring) -> theory -> term -> term
   115   val intern_tycons: theory -> typ -> typ
   116   val pretty_term': Proof.context -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   117   val pretty_term: theory -> term -> Pretty.T
   118   val pretty_typ: theory -> typ -> Pretty.T
   119   val pretty_sort: theory -> sort -> Pretty.T
   120   val pretty_classrel: theory -> class list -> Pretty.T
   121   val pretty_arity: theory -> arity -> Pretty.T
   122   val string_of_term: theory -> term -> string
   123   val string_of_typ: theory -> typ -> string
   124   val string_of_sort: theory -> sort -> string
   125   val string_of_classrel: theory -> class list -> string
   126   val string_of_arity: theory -> arity -> string
   127   val pp: theory -> Pretty.pp
   128   val arity_number: theory -> string -> int
   129   val arity_sorts: theory -> string -> sort -> sort list
   130   val certify_class: theory -> class -> class
   131   val certify_sort: theory -> sort -> sort
   132   val certify_typ: theory -> typ -> typ
   133   val certify_typ_mode: Type.mode -> theory -> typ -> typ
   134   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   135   val certify_term: theory -> term -> term * typ * int
   136   val certify_prop: theory -> term -> term * typ * int
   137   val cert_term: theory -> term -> term
   138   val cert_prop: theory -> term -> term
   139   val no_frees: Pretty.pp -> term -> term
   140   val no_vars: Pretty.pp -> term -> term
   141   val cert_def: Pretty.pp -> term -> (string * typ) * term
   142   val read_class: theory -> xstring -> class
   143   val read_arity: theory -> xstring * string list * string -> arity
   144   val cert_arity: theory -> arity -> arity
   145   val get_sort: theory ->
   146     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   147   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   148   val read_typ: theory -> string -> typ
   149   val read_typ_syntax: theory -> string -> typ
   150   val read_typ_abbrev: theory -> string -> typ
   151   val read_tyname: theory -> string -> typ
   152   val read_const: theory -> string -> term
   153   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   154     (string -> string option) -> Proof.context ->
   155     (indexname -> typ option) * (indexname -> sort option) ->
   156     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   157   val read_def_terms:
   158     theory * (indexname -> typ option) * (indexname -> sort option) ->
   159     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   160   val simple_read_term: theory -> typ -> string -> term
   161   val read_term: theory -> string -> term
   162   val read_prop: theory -> string -> term
   163   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   164   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   165   val add_abbrev: string -> bstring * term -> theory -> (term * term) * theory
   166   include SIGN_THEORY
   167   val add_const_constraint: xstring * string option -> theory -> theory
   168   val add_const_constraint_i: string * typ option -> theory -> theory
   169   val primitive_class: string * class list -> theory -> theory
   170   val primitive_classrel: class * class -> theory -> theory
   171   val primitive_arity: arity -> theory -> theory
   172   val hide_classes: bool -> xstring list -> theory -> theory
   173   val hide_classes_i: bool -> string list -> theory -> theory
   174   val hide_types: bool -> xstring list -> theory -> theory
   175   val hide_types_i: bool -> string list -> theory -> theory
   176   val hide_consts: bool -> xstring list -> theory -> theory
   177   val hide_consts_i: bool -> string list -> theory -> theory
   178   val hide_names: bool -> string * xstring list -> theory -> theory
   179   val hide_names_i: bool -> string * string list -> theory -> theory
   180 end
   181 
   182 structure Sign: SIGN =
   183 struct
   184 
   185 (** datatype sign **)
   186 
   187 datatype sign = Sign of
   188  {naming: NameSpace.naming,     (*common naming conventions*)
   189   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   190   tsig: Type.tsig,              (*order-sorted signature of types*)
   191   consts: Consts.T};            (*polymorphic constants*)
   192 
   193 fun make_sign (naming, syn, tsig, consts) =
   194   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   195 
   196 structure SignData = TheoryDataFun
   197 (
   198   type T = sign;
   199   val copy = I;
   200   fun extend (Sign {syn, tsig, consts, ...}) =
   201     make_sign (NameSpace.default_naming, syn, tsig, consts);
   202 
   203   val empty =
   204     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   205 
   206   fun merge pp (sign1, sign2) =
   207     let
   208       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   209       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   210 
   211       val naming = NameSpace.default_naming;
   212       val syn = Syntax.merge_syntaxes syn1 syn2;
   213       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   214       val consts = Consts.merge (consts1, consts2);
   215     in make_sign (naming, syn, tsig, consts) end;
   216 );
   217 
   218 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   219 
   220 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   221   make_sign (f (naming, syn, tsig, consts)));
   222 
   223 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   224 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   225 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   226 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   227 
   228 
   229 (* naming *)
   230 
   231 val naming_of = #naming o rep_sg;
   232 val base_name = NameSpace.base;
   233 val full_name = NameSpace.full o naming_of;
   234 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   235 val declare_name = NameSpace.declare o naming_of;
   236 
   237 
   238 (* syntax *)
   239 
   240 val syn_of = #syn o rep_sg;
   241 
   242 
   243 (* type signature *)
   244 
   245 val tsig_of = #tsig o rep_sg;
   246 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   247 val all_classes = Sorts.all_classes o classes_of;
   248 val minimal_classes = Sorts.minimal_classes o classes_of;
   249 val super_classes = Sorts.super_classes o classes_of;
   250 val defaultS = Type.defaultS o tsig_of;
   251 val subsort = Type.subsort o tsig_of;
   252 val of_sort = Type.of_sort o tsig_of;
   253 val witness_sorts = Type.witness_sorts o tsig_of;
   254 val universal_witness = Type.universal_witness o tsig_of;
   255 val all_sorts_nonempty = is_some o universal_witness;
   256 val typ_instance = Type.typ_instance o tsig_of;
   257 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   258 val typ_match = Type.typ_match o tsig_of;
   259 val typ_unify = Type.unify o tsig_of;
   260 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   261 
   262 
   263 (* polymorphic constants *)
   264 
   265 val consts_of = #consts o rep_sg;
   266 val the_const_constraint = Consts.the_constraint o consts_of;
   267 val const_constraint = try o the_const_constraint;
   268 val the_const_type = Consts.the_declaration o consts_of;
   269 val const_type = try o the_const_type;
   270 val const_monomorphic = Consts.is_monomorphic o consts_of;
   271 val const_syntax_name = Consts.syntax_name o consts_of;
   272 val const_typargs = Consts.typargs o consts_of;
   273 val const_instance = Consts.instance o consts_of;
   274 
   275 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   276 val declared_const = is_some oo const_constraint;
   277 
   278 
   279 
   280 (** intern / extern names **)
   281 
   282 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   283 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   284 val const_space = Consts.space_of o consts_of;
   285 
   286 val intern_class = NameSpace.intern o class_space;
   287 val extern_class = NameSpace.extern o class_space;
   288 val intern_type = NameSpace.intern o type_space;
   289 val extern_type = NameSpace.extern o type_space;
   290 val intern_const = NameSpace.intern o const_space;
   291 val extern_const = NameSpace.extern o const_space;
   292 
   293 val intern_sort = map o intern_class;
   294 val extern_sort = map o extern_class;
   295 
   296 local
   297 
   298 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   299   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   300   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   301 
   302 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   303   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   304   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   305   | map_term _ _ _ (t as Bound _) = t
   306   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   307   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   308 
   309 val add_classesT = Term.fold_atyps
   310   (fn TFree (_, S) => fold (insert (op =)) S
   311     | TVar (_, S) => fold (insert (op =)) S
   312     | _ => I);
   313 
   314 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   315   | add_tyconsT _ = I;
   316 
   317 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   318 
   319 fun mapping add_names f t =
   320   let
   321     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   322     val tab = map_filter f' (add_names t []);
   323     fun get x = the_default x (AList.lookup (op =) tab x);
   324   in get end;
   325 
   326 fun typ_mapping f g thy T =
   327   T |> map_typ
   328     (mapping add_classesT (f thy) T)
   329     (mapping add_tyconsT (g thy) T);
   330 
   331 fun term_mapping f g h thy t =
   332   t |> map_term
   333     (mapping (Term.fold_types add_classesT) (f thy) t)
   334     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   335     (mapping add_consts (h thy) t);
   336 
   337 in
   338 
   339 val intern_typ = typ_mapping intern_class intern_type;
   340 val extern_typ = typ_mapping extern_class extern_type;
   341 val intern_term = term_mapping intern_class intern_type intern_const;
   342 fun extern_term h = term_mapping extern_class extern_type (K h);
   343 val intern_tycons = typ_mapping (K I) intern_type;
   344 
   345 end;
   346 
   347 
   348 
   349 (** pretty printing of terms, types etc. **)
   350 
   351 fun pretty_term' ctxt syn ext t =
   352   let val curried = Context.exists_name Context.CPureN (ProofContext.theory_of ctxt)
   353   in Syntax.pretty_term ext ctxt syn curried t end;
   354 
   355 fun pretty_term thy t =
   356   pretty_term' (ProofContext.init thy) (syn_of thy) (Consts.extern (consts_of thy))
   357     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   358 
   359 fun pretty_typ thy T =
   360   Syntax.pretty_typ (ProofContext.init thy) (syn_of thy) (extern_typ thy T);
   361 
   362 fun pretty_sort thy S =
   363   Syntax.pretty_sort (ProofContext.init thy) (syn_of thy) (extern_sort thy S);
   364 
   365 fun pretty_classrel thy cs = Pretty.block (flat
   366   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   367 
   368 fun pretty_arity thy (a, Ss, S) =
   369   let
   370     val a' = extern_type thy a;
   371     val dom =
   372       if null Ss then []
   373       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   374   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   375 
   376 val string_of_term = Pretty.string_of oo pretty_term;
   377 val string_of_typ = Pretty.string_of oo pretty_typ;
   378 val string_of_sort = Pretty.string_of oo pretty_sort;
   379 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   380 val string_of_arity = Pretty.string_of oo pretty_arity;
   381 
   382 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   383   pretty_classrel thy, pretty_arity thy);
   384 
   385 
   386 
   387 (** certify entities **)    (*exception TYPE*)
   388 
   389 (* certify wrt. type signature *)
   390 
   391 val arity_number = Type.arity_number o tsig_of;
   392 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   393 
   394 val certify_class         = Type.cert_class o tsig_of;
   395 val certify_sort          = Type.cert_sort o tsig_of;
   396 val certify_typ           = Type.cert_typ o tsig_of;
   397 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   398 
   399 
   400 (* certify term/prop *)
   401 
   402 local
   403 
   404 fun type_check pp tm =
   405   let
   406     fun err_appl why bs t T u U =
   407       let
   408         val xs = map Free bs;           (*we do not rename here*)
   409         val t' = subst_bounds (xs, t);
   410         val u' = subst_bounds (xs, u);
   411         val msg = cat_lines
   412           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   413       in raise TYPE (msg, [T, U], [t', u']) end;
   414 
   415     fun typ_of (_, Const (_, T)) = T
   416       | typ_of (_, Free  (_, T)) = T
   417       | typ_of (_, Var (_, T)) = T
   418       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   419           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   420       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   421       | typ_of (bs, t $ u) =
   422           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   423             (case T of
   424               Type ("fun", [T1, T2]) =>
   425                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   426             | _ => err_appl "Operator not of function type" bs t T u U)
   427           end;
   428   in typ_of ([], tm) end;
   429 
   430 fun err msg = raise TYPE (msg, [], []);
   431 
   432 fun check_vars (t $ u) = (check_vars t; check_vars u)
   433   | check_vars (Abs (_, _, t)) = check_vars t
   434   | check_vars (Var (xi as (_, i), _)) =
   435       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   436   | check_vars _ = ();
   437 
   438 in
   439 
   440 fun certify' normalize prop pp consts thy tm =
   441   let
   442     val _ = check_vars tm;
   443     val tm' = Term.map_types (certify_typ thy) tm;
   444     val T = type_check pp tm';
   445     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   446     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   447     val tm'' = if normalize then tm'' else tm';
   448   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   449 
   450 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   451 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   452 
   453 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   454 val cert_term = #1 oo certify_term;
   455 val cert_prop = #1 oo certify_prop;
   456 
   457 end;
   458 
   459 
   460 (* specifications *)
   461 
   462 fun no_variables kind add addT mk mkT pp tm =
   463   (case (add tm [], addT tm []) of
   464     ([], []) => tm
   465   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   466       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   467        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   468 
   469 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   470 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   471 
   472 fun cert_def pp tm =
   473   let val ((lhs, rhs), _) = tm
   474     |> no_vars pp
   475     |> Logic.strip_imp_concl
   476     |> PrimitiveDefs.dest_def pp Term.is_Const (K false) (K false)
   477   in (Term.dest_Const (Term.head_of lhs), rhs) end
   478   handle TERM (msg, _) => error msg;
   479 
   480 
   481 
   482 (** read and certify entities **)    (*exception ERROR*)
   483 
   484 (* classes *)
   485 
   486 fun read_class thy c = certify_class thy (intern_class thy c)
   487   handle TYPE (msg, _, _) => error msg;
   488 
   489 
   490 (* type arities *)
   491 
   492 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   493   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   494   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   495 
   496 val read_arity = prep_arity intern_type Syntax.global_read_sort;
   497 val cert_arity = prep_arity (K I) certify_sort;
   498 
   499 
   500 (* types *)
   501 
   502 fun get_sort thy def_sort raw_env =
   503   let
   504     val tsig = tsig_of thy;
   505 
   506     fun eq ((xi, S), (xi', S')) =
   507       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   508     val env = distinct eq raw_env;
   509     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   510       | dups => error ("Inconsistent sort constraints for type variable(s) "
   511           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   512 
   513     fun get xi =
   514       (case (AList.lookup (op =) env xi, def_sort xi) of
   515         (NONE, NONE) => Type.defaultS tsig
   516       | (NONE, SOME S) => S
   517       | (SOME S, NONE) => S
   518       | (SOME S, SOME S') =>
   519           if Type.eq_sort tsig (S, S') then S'
   520           else error ("Sort constraint inconsistent with default for type variable " ^
   521             quote (Term.string_of_vname' xi)));
   522   in get end;
   523 
   524 local
   525 
   526 fun gen_read_typ mode (thy, def_sort) str =
   527   let
   528     val ctxt = ProofContext.init thy;
   529     val syn = syn_of thy;
   530     val T = intern_tycons thy
   531       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   532   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   533   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   534 
   535 in
   536 
   537 fun no_def_sort thy = (thy: theory, K NONE);
   538 
   539 val read_def_typ     = gen_read_typ Type.mode_default;
   540 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   541 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   542 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   543 
   544 end;
   545 
   546 
   547 (* type and constant names *)
   548 
   549 fun read_tyname thy raw_c =
   550   let val c = intern_type thy raw_c
   551   in Type (c, replicate (arity_number thy c) dummyT) end;
   552 
   553 val read_const = Consts.read_const o consts_of;
   554 
   555 
   556 
   557 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   558 
   559 (*
   560   def_type: partial map from indexnames to types (constrains Frees and Vars)
   561   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   562   used: context of already used type variables
   563   freeze: if true then generated parameters are turned into TFrees, else TVars
   564 *)
   565 
   566 fun read_def_terms'
   567     pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze raw_args =
   568   let
   569     val thy = ProofContext.theory_of ctxt;
   570     val check_typs = Syntax.check_typs (Type.set_mode Type.mode_default ctxt);
   571 
   572     fun infer args = TypeInfer.infer_types pp (tsig_of thy) check_typs
   573         (try (Consts.the_constraint consts)) def_type used freeze args |>> map fst
   574       handle TYPE (msg, _, _) => error msg;
   575 
   576     fun check T t = Exn.Result (singleton (fst o infer) (t, T))
   577       handle ERROR msg => Exn.Exn (ERROR msg);
   578     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   579     fun read T = Syntax.standard_parse_term pp (check T) (get_sort thy def_sort) map_const map_free
   580         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn T;
   581   in
   582     raw_args
   583     |> map (fn (s, raw_T) =>
   584       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   585       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end)
   586     |> infer
   587   end;
   588 
   589 fun read_def_terms (thy, types, sorts) used freeze sTs =
   590   let
   591     val pp = pp thy;
   592     val consts = consts_of thy;
   593     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   594     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   595     val (ts, inst) =
   596       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   597         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   598   in (map cert_consts ts, inst) end;
   599 
   600 fun simple_read_term thy T s =
   601   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   602   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   603 
   604 fun read_term thy = simple_read_term thy dummyT;
   605 fun read_prop thy = simple_read_term thy propT;
   606 
   607 
   608 
   609 (** signature extension functions **)  (*exception ERROR/TYPE*)
   610 
   611 (* add default sort *)
   612 
   613 fun gen_add_defsort prep_sort s thy =
   614   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   615 
   616 val add_defsort = gen_add_defsort Syntax.global_read_sort;
   617 val add_defsort_i = gen_add_defsort certify_sort;
   618 
   619 
   620 (* add type constructors *)
   621 
   622 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   623   let
   624     val syn' = Syntax.extend_type_gram types syn;
   625     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   626     val tsig' = Type.add_types naming decls tsig;
   627   in (naming, syn', tsig', consts) end);
   628 
   629 fun add_typedecls decls thy =
   630   let
   631     fun type_of (a, vs: string list, mx) =
   632       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   633       else error ("Duplicate parameters in type declaration: " ^ quote a);
   634   in add_types (map type_of decls) thy end;
   635 
   636 
   637 (* add nonterminals *)
   638 
   639 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   640   let
   641     val syn' = Syntax.extend_consts ns syn;
   642     val tsig' = Type.add_nonterminals naming ns tsig;
   643   in (naming, syn', tsig', consts) end);
   644 
   645 
   646 (* add type abbreviations *)
   647 
   648 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   649   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   650     let
   651       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   652       val a' = Syntax.type_name a mx;
   653       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (prep_typ thy rhs))
   654         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   655       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   656     in (naming, syn', tsig', consts) end);
   657 
   658 val add_tyabbrs = fold (gen_add_tyabbr Syntax.global_parse_typ);
   659 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   660 
   661 
   662 (* modify syntax *)
   663 
   664 fun gen_syntax change_gram prep_typ mode args thy =
   665   let
   666     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (prep_typ thy T), mx)
   667       handle ERROR msg =>
   668         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   669   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   670 
   671 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   672 
   673 val add_modesyntax = gen_add_syntax Syntax.global_parse_typ;
   674 val add_modesyntax_i = gen_add_syntax (K I);
   675 val add_syntax = add_modesyntax Syntax.default_mode;
   676 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   677 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.global_parse_typ;
   678 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   679 
   680 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   681   | const_syntax _ _ = NONE;
   682 
   683 fun add_notation mode args thy =
   684   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   685 
   686 
   687 (* add constants *)
   688 
   689 local
   690 
   691 fun gen_add_consts prep_typ authentic raw_args thy =
   692   let
   693     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   694     fun prep (raw_c, raw_T, raw_mx) =
   695       let
   696         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   697         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   698         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   699           cat_error msg ("in declaration of constant " ^ quote c);
   700       in (((c, T), authentic), (c', T, mx)) end;
   701     val args = map prep raw_args;
   702   in
   703     thy
   704     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   705     |> add_syntax_i (map #2 args)
   706   end;
   707 
   708 in
   709 
   710 val add_consts = gen_add_consts read_typ false;
   711 val add_consts_i = gen_add_consts certify_typ false;
   712 val add_consts_authentic = gen_add_consts certify_typ true;
   713 
   714 end;
   715 
   716 
   717 (* add abbreviations *)
   718 
   719 fun add_abbrev mode (c, raw_t) thy =
   720   let
   721     val pp = pp thy;
   722     val prep_tm = Compress.term thy o no_frees pp o
   723       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   724       Term.no_dummy_patterns o cert_term_abbrev thy;
   725     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   726       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   727     val (res, consts') = consts_of thy
   728       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (c, t);
   729   in (res, thy |> map_consts (K consts')) end;
   730 
   731 
   732 (* add constraints *)
   733 
   734 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   735   let
   736     val c = int_const thy raw_c;
   737     fun prepT raw_T =
   738       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   739       in cert_term thy (Const (c, T)); T end
   740       handle TYPE (msg, _, _) => error msg;
   741   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   742 
   743 val add_const_constraint = gen_add_constraint intern_const read_typ;
   744 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   745 
   746 
   747 (* primitive classes and arities *)
   748 
   749 fun primitive_class (bclass, classes) thy =
   750   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   751     let
   752       val syn' = Syntax.extend_consts [bclass] syn;
   753       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   754     in (naming, syn', tsig', consts) end)
   755   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   756 
   757 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   758 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   759 
   760 
   761 (* add translation functions *)
   762 
   763 local
   764 
   765 fun mk trs = map Syntax.mk_trfun trs;
   766 
   767 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   768   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   769 
   770 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   771 
   772 in
   773 
   774 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   775 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   776 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   777 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   778 
   779 end;
   780 
   781 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   782 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   783 
   784 
   785 (* translation rules *)
   786 
   787 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   788   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   789   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   790 
   791 val add_trrules = gen_trrules Syntax.extend_trrules;
   792 val del_trrules = gen_trrules Syntax.remove_trrules;
   793 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   794 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   795 
   796 
   797 (* modify naming *)
   798 
   799 val add_path        = map_naming o NameSpace.add_path;
   800 val no_base_names   = map_naming NameSpace.no_base_names;
   801 val qualified_names = map_naming NameSpace.qualified_names;
   802 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   803 val set_policy      = map_naming o NameSpace.set_policy;
   804 val restore_naming  = map_naming o K o naming_of;
   805 
   806 val parent_path   = add_path "..";
   807 val root_path     = add_path "/";
   808 val absolute_path = add_path "//";
   809 
   810 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   811 
   812 
   813 (* hide names *)
   814 
   815 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   816 val hide_classes_i = map_tsig oo Type.hide_classes;
   817 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   818 val hide_types_i = map_tsig oo Type.hide_types;
   819 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   820 val hide_consts_i = map_consts oo (fold o Consts.hide);
   821 
   822 local
   823 
   824 val kinds =
   825  [("class", (intern_class, can o certify_class, hide_classes_i)),
   826   ("type", (intern_type, declared_tyname, hide_types_i)),
   827   ("const", (intern_const, declared_const, hide_consts_i))];
   828 
   829 fun gen_hide int b (kind, xnames) thy =
   830   (case AList.lookup (op =) kinds kind of
   831     SOME (intern, check, hide) =>
   832       let
   833         val names = if int then map (intern thy) xnames else xnames;
   834         val bads = filter_out (check thy) names;
   835       in
   836         if null bads then hide b names thy
   837         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   838       end
   839   | NONE => error ("Bad name space specification: " ^ quote kind));
   840 
   841 in
   842 
   843 val hide_names = gen_hide true;
   844 val hide_names_i = gen_hide false;
   845 
   846 end;
   847 
   848 end;