src/HOL/Library/Code_Target_Int.thy
author blanchet
Thu Mar 06 13:36:48 2014 +0100 (2014-03-06)
changeset 55932 68c5104d2204
parent 55736 f1ed1e9cd080
child 57512 cc97b347b301
permissions -rw-r--r--
renamed 'map_pair' to 'map_prod'
     1 (*  Title:      HOL/Library/Code_Target_Int.thy
     2     Author:     Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 header {* Implementation of integer numbers by target-language integers *}
     6 
     7 theory Code_Target_Int
     8 imports Main
     9 begin
    10 
    11 code_datatype int_of_integer
    12 
    13 declare [[code drop: integer_of_int]]
    14 
    15 context
    16 includes integer.lifting
    17 begin
    18 
    19 lemma [code]:
    20   "integer_of_int (int_of_integer k) = k"
    21   by transfer rule
    22 
    23 lemma [code]:
    24   "Int.Pos = int_of_integer \<circ> integer_of_num"
    25   by transfer (simp add: fun_eq_iff) 
    26 
    27 lemma [code]:
    28   "Int.Neg = int_of_integer \<circ> uminus \<circ> integer_of_num"
    29   by transfer (simp add: fun_eq_iff) 
    30 
    31 lemma [code_abbrev]:
    32   "int_of_integer (numeral k) = Int.Pos k"
    33   by transfer simp
    34 
    35 lemma [code_abbrev]:
    36   "int_of_integer (- numeral k) = Int.Neg k"
    37   by transfer simp
    38   
    39 lemma [code, symmetric, code_post]:
    40   "0 = int_of_integer 0"
    41   by transfer simp
    42 
    43 lemma [code, symmetric, code_post]:
    44   "1 = int_of_integer 1"
    45   by transfer simp
    46 
    47 lemma [code]:
    48   "k + l = int_of_integer (of_int k + of_int l)"
    49   by transfer simp
    50 
    51 lemma [code]:
    52   "- k = int_of_integer (- of_int k)"
    53   by transfer simp
    54 
    55 lemma [code]:
    56   "k - l = int_of_integer (of_int k - of_int l)"
    57   by transfer simp
    58 
    59 lemma [code]:
    60   "Int.dup k = int_of_integer (Code_Numeral.dup (of_int k))"
    61   by transfer simp
    62 
    63 declare [[code drop: Int.sub]]
    64 
    65 lemma [code]:
    66   "k * l = int_of_integer (of_int k * of_int l)"
    67   by simp
    68 
    69 lemma [code]:
    70   "Divides.divmod_abs k l = map_prod int_of_integer int_of_integer
    71     (Code_Numeral.divmod_abs (of_int k) (of_int l))"
    72   by (simp add: prod_eq_iff)
    73 
    74 lemma [code]:
    75   "k div l = int_of_integer (of_int k div of_int l)"
    76   by simp
    77 
    78 lemma [code]:
    79   "k mod l = int_of_integer (of_int k mod of_int l)"
    80   by simp
    81 
    82 lemma [code]:
    83   "HOL.equal k l = HOL.equal (of_int k :: integer) (of_int l)"
    84   by transfer (simp add: equal)
    85 
    86 lemma [code]:
    87   "k \<le> l \<longleftrightarrow> (of_int k :: integer) \<le> of_int l"
    88   by transfer rule
    89 
    90 lemma [code]:
    91   "k < l \<longleftrightarrow> (of_int k :: integer) < of_int l"
    92   by transfer rule
    93 end
    94 
    95 lemma (in ring_1) of_int_code_if:
    96   "of_int k = (if k = 0 then 0
    97      else if k < 0 then - of_int (- k)
    98      else let
    99        (l, j) = divmod_int k 2;
   100        l' = 2 * of_int l
   101      in if j = 0 then l' else l' + 1)"
   102 proof -
   103   from mod_div_equality have *: "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp
   104   show ?thesis
   105     by (simp add: Let_def divmod_int_mod_div of_int_add [symmetric])
   106       (simp add: * mult_commute)
   107 qed
   108 
   109 declare of_int_code_if [code]
   110 
   111 lemma [code]:
   112   "nat = nat_of_integer \<circ> of_int"
   113   including integer.lifting by transfer (simp add: fun_eq_iff)
   114 
   115 code_identifier
   116   code_module Code_Target_Int \<rightharpoonup>
   117     (SML) Arith and (OCaml) Arith and (Haskell) Arith
   118 
   119 end
   120