src/HOL/Auth/OtwayRees_AN.ML
author paulson
Mon Sep 29 11:47:01 1997 +0200 (1997-09-29)
changeset 3730 6933d20f335f
parent 3683 aafe719dff14
child 3919 c036caebfc75
permissions -rw-r--r--
Step_tac -> Safe_tac
     1 (*  Title:      HOL/Auth/OtwayRees
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 
     6 Inductive relation "otway" for the Otway-Rees protocol.
     7 
     8 Simplified version with minimal encryption but explicit messages
     9 
    10 From page 11 of
    11   Abadi and Needham.  Prudent Engineering Practice for Cryptographic Protocols.
    12   IEEE Trans. SE 22 (1), 1996
    13 *)
    14 
    15 open OtwayRees_AN;
    16 
    17 proof_timing:=true;
    18 HOL_quantifiers := false;
    19 
    20 
    21 (*A "possibility property": there are traces that reach the end*)
    22 goal thy 
    23  "!!A B. [| A ~= B; A ~= Server; B ~= Server |]                               \
    24 \        ==> EX K. EX NA. EX evs: otway.                                      \
    25 \             Says B A (Crypt (shrK A) {|Nonce NA, Agent A, Agent B, Key K|}) \
    26 \             : set evs";
    27 by (REPEAT (resolve_tac [exI,bexI] 1));
    28 by (rtac (otway.Nil RS otway.OR1 RS otway.OR2 RS otway.OR3 RS otway.OR4) 2);
    29 by possibility_tac;
    30 result();
    31 
    32 
    33 (**** Inductive proofs about otway ****)
    34 
    35 (*Nobody sends themselves messages*)
    36 goal thy "!!evs. evs : otway ==> ALL A X. Says A A X ~: set evs";
    37 by (etac otway.induct 1);
    38 by (Auto_tac());
    39 qed_spec_mp "not_Says_to_self";
    40 Addsimps [not_Says_to_self];
    41 AddSEs   [not_Says_to_self RSN (2, rev_notE)];
    42 
    43 
    44 (** For reasoning about the encrypted portion of messages **)
    45 
    46 goal thy "!!evs. Says S' B {|X, Crypt(shrK B) X'|} : set evs ==> \
    47 \                X : analz (spies evs)";
    48 by (blast_tac (!claset addSDs [Says_imp_spies RS analz.Inj]) 1);
    49 qed "OR4_analz_spies";
    50 
    51 goal thy "!!evs. Says Server B {|X, Crypt K' {|NB, a, Agent B, K|}|} \
    52 \                  : set evs ==> K : parts (spies evs)";
    53 by (blast_tac (!claset addSEs spies_partsEs) 1);
    54 qed "Oops_parts_spies";
    55 
    56 (*OR4_analz_spies lets us treat those cases using the same 
    57   argument as for the Fake case.  This is possible for most, but not all,
    58   proofs, since Fake messages originate from the Spy. *)
    59 
    60 bind_thm ("OR4_parts_spies",
    61           OR4_analz_spies RS (impOfSubs analz_subset_parts));
    62 
    63 (*For proving the easier theorems about X ~: parts (spies evs).*)
    64 fun parts_induct_tac i = 
    65     etac otway.induct i			THEN 
    66     forward_tac [Oops_parts_spies] (i+6) THEN
    67     forward_tac [OR4_parts_spies]  (i+5) THEN
    68     prove_simple_subgoals_tac  i;
    69 
    70 
    71 (** Theorems of the form X ~: parts (spies evs) imply that NOBODY
    72     sends messages containing X! **)
    73 
    74 (*Spy never sees another agent's shared key! (unless it's bad at start)*)
    75 goal thy 
    76  "!!evs. evs : otway ==> (Key (shrK A) : parts (spies evs)) = (A : bad)";
    77 by (parts_induct_tac 1);
    78 by (Fake_parts_insert_tac 1);
    79 by (Blast_tac 1);
    80 qed "Spy_see_shrK";
    81 Addsimps [Spy_see_shrK];
    82 
    83 goal thy 
    84  "!!evs. evs : otway ==> (Key (shrK A) : analz (spies evs)) = (A : bad)";
    85 by (auto_tac(!claset addDs [impOfSubs analz_subset_parts], !simpset));
    86 qed "Spy_analz_shrK";
    87 Addsimps [Spy_analz_shrK];
    88 
    89 goal thy  "!!A. [| Key (shrK A) : parts (spies evs); evs : otway |] ==> A:bad";
    90 by (blast_tac (!claset addDs [Spy_see_shrK]) 1);
    91 qed "Spy_see_shrK_D";
    92 
    93 bind_thm ("Spy_analz_shrK_D", analz_subset_parts RS subsetD RS Spy_see_shrK_D);
    94 AddSDs [Spy_see_shrK_D, Spy_analz_shrK_D];
    95 
    96 
    97 (*Nobody can have used non-existent keys!*)
    98 goal thy "!!evs. evs : otway ==>          \
    99 \         Key K ~: used evs --> K ~: keysFor (parts (spies evs))";
   100 by (parts_induct_tac 1);
   101 (*Fake*)
   102 by (best_tac
   103       (!claset addIs [impOfSubs analz_subset_parts]
   104                addDs [impOfSubs (analz_subset_parts RS keysFor_mono),
   105                       impOfSubs (parts_insert_subset_Un RS keysFor_mono)]
   106                addss (!simpset)) 1);
   107 (*OR3*)
   108 by (Blast_tac 1);
   109 qed_spec_mp "new_keys_not_used";
   110 
   111 bind_thm ("new_keys_not_analzd",
   112           [analz_subset_parts RS keysFor_mono,
   113            new_keys_not_used] MRS contra_subsetD);
   114 
   115 Addsimps [new_keys_not_used, new_keys_not_analzd];
   116 
   117 
   118 
   119 (*** Proofs involving analz ***)
   120 
   121 (*Describes the form of K and NA when the Server sends this message.*)
   122 goal thy 
   123  "!!evs. [| Says Server B                                           \
   124 \              {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},    \
   125 \                Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|}   \
   126 \             : set evs;                                            \
   127 \           evs : otway |]                                          \
   128 \        ==> K ~: range shrK & (EX i. NA = Nonce i) & (EX j. NB = Nonce j)";
   129 by (etac rev_mp 1);
   130 by (etac otway.induct 1);
   131 by (ALLGOALS Asm_simp_tac);
   132 by (Blast_tac 1);
   133 qed "Says_Server_message_form";
   134 
   135 
   136 (*For proofs involving analz.*)
   137 val analz_spies_tac = 
   138     dtac OR4_analz_spies 6 THEN
   139     forward_tac [Says_Server_message_form] 7 THEN
   140     assume_tac 7 THEN
   141     REPEAT ((eresolve_tac [exE, conjE] ORELSE' hyp_subst_tac) 7);
   142 
   143 
   144 (****
   145  The following is to prove theorems of the form
   146 
   147   Key K : analz (insert (Key KAB) (spies evs)) ==>
   148   Key K : analz (spies evs)
   149 
   150  A more general formula must be proved inductively.
   151 ****)
   152 
   153 
   154 (** Session keys are not used to encrypt other session keys **)
   155 
   156 (*The equality makes the induction hypothesis easier to apply*)
   157 goal thy  
   158  "!!evs. evs : otway ==>                                    \
   159 \  ALL K KK. KK <= Compl (range shrK) -->                   \
   160 \            (Key K : analz (Key``KK Un (spies evs))) =  \
   161 \            (K : KK | Key K : analz (spies evs))";
   162 by (etac otway.induct 1);
   163 by analz_spies_tac;
   164 by (REPEAT_FIRST (resolve_tac [allI, impI]));
   165 by (REPEAT_FIRST (rtac analz_image_freshK_lemma ));
   166 by (ALLGOALS (asm_simp_tac analz_image_freshK_ss));
   167 (*Fake*) 
   168 by (spy_analz_tac 2);
   169 (*Base*)
   170 by (Blast_tac 1);
   171 qed_spec_mp "analz_image_freshK";
   172 
   173 
   174 goal thy
   175  "!!evs. [| evs : otway;  KAB ~: range shrK |] ==>          \
   176 \        Key K : analz (insert (Key KAB) (spies evs)) =  \
   177 \        (K = KAB | Key K : analz (spies evs))";
   178 by (asm_simp_tac (analz_image_freshK_ss addsimps [analz_image_freshK]) 1);
   179 qed "analz_insert_freshK";
   180 
   181 
   182 (*** The Key K uniquely identifies the Server's  message. **)
   183 
   184 goal thy 
   185  "!!evs. evs : otway ==>                                            \
   186 \      EX A' B' NA' NB'. ALL A B NA NB.                             \
   187 \       Says Server B                                               \
   188 \         {|Crypt (shrK A) {|NA, Agent A, Agent B, K|},             \
   189 \           Crypt (shrK B) {|NB, Agent A, Agent B, K|}|} : set evs  \
   190 \       --> A=A' & B=B' & NA=NA' & NB=NB'";
   191 by (etac otway.induct 1);
   192 by (ALLGOALS (asm_simp_tac (!simpset addsimps [all_conj_distrib])));
   193 by (ALLGOALS Clarify_tac);
   194 (*Remaining cases: OR3 and OR4*)
   195 by (ex_strip_tac 2);
   196 by (Blast_tac 2);
   197 by (expand_case_tac "K = ?y" 1);
   198 by (REPEAT (ares_tac [refl,exI,impI,conjI] 2));
   199 (*...we assume X is a recent message and handle this case by contradiction*)
   200 by (blast_tac (!claset addSEs spies_partsEs
   201                        delrules[conjI] (*prevent splitup into 4 subgoals*)) 1);
   202 val lemma = result();
   203 
   204 
   205 goal thy 
   206 "!!evs. [| Says Server B                                           \
   207 \            {|Crypt (shrK A) {|NA, Agent A, Agent B, K|},         \
   208 \              Crypt (shrK B) {|NB, Agent A, Agent B, K|}|}        \
   209 \           : set evs;                                             \
   210 \          Says Server B'                                          \
   211 \            {|Crypt (shrK A') {|NA', Agent A', Agent B', K|},     \
   212 \              Crypt (shrK B') {|NB', Agent A', Agent B', K|}|}    \
   213 \           : set evs;                                             \
   214 \          evs : otway |]                                          \
   215 \       ==> A=A' & B=B' & NA=NA' & NB=NB'";
   216 by (prove_unique_tac lemma 1);
   217 qed "unique_session_keys";
   218 
   219 
   220 
   221 (**** Authenticity properties relating to NA ****)
   222 
   223 (*If the encrypted message appears then it originated with the Server!*)
   224 goal thy 
   225  "!!evs. [| A ~: bad;  evs : otway |]                 \
   226 \ ==> Crypt (shrK A) {|NA, Agent A, Agent B, Key K|} : parts (spies evs) \
   227 \     --> (EX NB. Says Server B                                          \
   228 \                  {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},     \
   229 \                    Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|}    \
   230 \                  : set evs)";
   231 by (parts_induct_tac 1);
   232 by (Fake_parts_insert_tac 1);
   233 by (ALLGOALS (asm_simp_tac (!simpset addsimps [ex_disj_distrib])));
   234 (*OR3*)
   235 by (Blast_tac 1);
   236 qed_spec_mp "NA_Crypt_imp_Server_msg";
   237 
   238 
   239 (*Corollary: if A receives B's OR4 message then it originated with the Server.
   240   Freshness may be inferred from nonce NA.*)
   241 goal thy 
   242  "!!evs. [| Says B' A (Crypt (shrK A) {|NA, Agent A, Agent B, Key K|})  \
   243 \            : set evs;                                                 \
   244 \           A ~: bad;  evs : otway |]                                  \
   245 \        ==> EX NB. Says Server B                                       \
   246 \                    {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},  \
   247 \                      Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|} \
   248 \                   : set evs";
   249 by (blast_tac (!claset addSIs [NA_Crypt_imp_Server_msg]
   250                       addEs  spies_partsEs) 1);
   251 qed "A_trusts_OR4";
   252 
   253 
   254 (** Crucial secrecy property: Spy does not see the keys sent in msg OR3
   255     Does not in itself guarantee security: an attack could violate 
   256     the premises, e.g. by having A=Spy **)
   257 
   258 goal thy 
   259  "!!evs. [| A ~: bad;  B ~: bad;  evs : otway |]                 \
   260 \        ==> Says Server B                                         \
   261 \             {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},    \
   262 \               Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|}   \
   263 \            : set evs -->                                         \
   264 \            Says B Spy {|NA, NB, Key K|} ~: set evs -->           \
   265 \            Key K ~: analz (spies evs)";
   266 by (etac otway.induct 1);
   267 by analz_spies_tac;
   268 by (ALLGOALS
   269     (asm_simp_tac (!simpset addcongs [conj_cong, if_weak_cong] 
   270                             addsimps [analz_insert_eq, analz_insert_freshK]
   271                             setloop split_tac [expand_if])));
   272 (*Oops*)
   273 by (blast_tac (!claset addSDs [unique_session_keys]) 4);
   274 (*OR4*) 
   275 by (Blast_tac 3);
   276 (*OR3*)
   277 by (blast_tac (!claset addSEs spies_partsEs
   278                        addIs [impOfSubs analz_subset_parts]) 2);
   279 (*Fake*) 
   280 by (spy_analz_tac 1);
   281 val lemma = result() RS mp RS mp RSN(2,rev_notE);
   282 
   283 goal thy 
   284  "!!evs. [| Says Server B                                           \
   285 \              {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},    \
   286 \                Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|}   \
   287 \             : set evs;                                            \
   288 \           Says B Spy {|NA, NB, Key K|} ~: set evs;                \
   289 \           A ~: bad;  B ~: bad;  evs : otway |]                  \
   290 \        ==> Key K ~: analz (spies evs)";
   291 by (forward_tac [Says_Server_message_form] 1 THEN assume_tac 1);
   292 by (blast_tac (!claset addSEs [lemma]) 1);
   293 qed "Spy_not_see_encrypted_key";
   294 
   295 
   296 (**** Authenticity properties relating to NB ****)
   297 
   298 (*If the encrypted message appears then it originated with the Server!*)
   299 goal thy 
   300  "!!evs. [| B ~: bad;  evs : otway |]                                 \
   301 \    ==> Crypt (shrK B) {|NB, Agent A, Agent B, Key K|} : parts (spies evs) \
   302 \        --> (EX NA. Says Server B                                          \
   303 \                     {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},     \
   304 \                       Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|}    \
   305 \                     : set evs)";
   306 by (parts_induct_tac 1);
   307 by (Fake_parts_insert_tac 1);
   308 by (ALLGOALS (asm_simp_tac (!simpset addsimps [ex_disj_distrib])));
   309 (*OR3*)
   310 by (Blast_tac 1);
   311 qed_spec_mp "NB_Crypt_imp_Server_msg";
   312 
   313 
   314 (*Guarantee for B: if it gets a well-formed certificate then the Server
   315   has sent the correct message in round 3.*)
   316 goal thy 
   317  "!!evs. [| B ~: bad;  evs : otway;                                        \
   318 \           Says S' B {|X, Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|} \
   319 \            : set evs |]                                                   \
   320 \        ==> EX NA. Says Server B                                           \
   321 \                     {|Crypt (shrK A) {|NA, Agent A, Agent B, Key K|},     \
   322 \                       Crypt (shrK B) {|NB, Agent A, Agent B, Key K|}|}    \
   323 \                     : set evs";
   324 by (blast_tac (!claset addSIs [NB_Crypt_imp_Server_msg]
   325                        addEs  spies_partsEs) 1);
   326 qed "B_trusts_OR3";