src/HOL/SEQ.thy
author wenzelm
Sat Oct 17 14:43:18 2009 +0200 (2009-10-17)
changeset 32960 69916a850301
parent 32877 6f09346c7c08
child 33042 ddf1f03a9ad9
permissions -rw-r--r--
eliminated hard tabulators, guessing at each author's individual tab-width;
tuned headers;
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits
    14 begin
    15 
    16 definition
    17   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    18     --{*Standard definition of sequence converging to zero*}
    19   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    20 
    21 definition
    22   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    23     ("((_)/ ----> (_))" [60, 60] 60) where
    24     --{*Standard definition of convergence of sequence*}
    25   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    26 
    27 definition
    28   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    29     --{*Standard definition of limit using choice operator*}
    30   "lim X = (THE L. X ----> L)"
    31 
    32 definition
    33   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    34     --{*Standard definition of convergence*}
    35   "convergent X = (\<exists>L. X ----> L)"
    36 
    37 definition
    38   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    39     --{*Standard definition for bounded sequence*}
    40   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    41 
    42 definition
    43   monoseq :: "(nat=>real)=>bool" where
    44     --{*Definition of monotonicity. 
    45         The use of disjunction here complicates proofs considerably. 
    46         One alternative is to add a Boolean argument to indicate the direction. 
    47         Another is to develop the notions of increasing and decreasing first.*}
    48   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    49 
    50 definition
    51   incseq :: "(nat=>real)=>bool" where
    52     --{*Increasing sequence*}
    53   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    54 
    55 definition
    56   decseq :: "(nat=>real)=>bool" where
    57     --{*Increasing sequence*}
    58   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    59 
    60 definition
    61   subseq :: "(nat => nat) => bool" where
    62     --{*Definition of subsequence*}
    63   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    64 
    65 definition
    66   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    67     --{*Standard definition of the Cauchy condition*}
    68   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    69 
    70 
    71 subsection {* Bounded Sequences *}
    72 
    73 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    74 unfolding Bseq_def
    75 proof (intro exI conjI allI)
    76   show "0 < max K 1" by simp
    77 next
    78   fix n::nat
    79   have "norm (X n) \<le> K" by (rule K)
    80   thus "norm (X n) \<le> max K 1" by simp
    81 qed
    82 
    83 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    84 unfolding Bseq_def by auto
    85 
    86 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    87 proof (rule BseqI')
    88   let ?A = "norm ` X ` {..N}"
    89   have 1: "finite ?A" by simp
    90   fix n::nat
    91   show "norm (X n) \<le> max K (Max ?A)"
    92   proof (cases rule: linorder_le_cases)
    93     assume "n \<ge> N"
    94     hence "norm (X n) \<le> K" using K by simp
    95     thus "norm (X n) \<le> max K (Max ?A)" by simp
    96   next
    97     assume "n \<le> N"
    98     hence "norm (X n) \<in> ?A" by simp
    99     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
   100     thus "norm (X n) \<le> max K (Max ?A)" by simp
   101   qed
   102 qed
   103 
   104 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   105 unfolding Bseq_def by auto
   106 
   107 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   108 apply (erule BseqE)
   109 apply (rule_tac N="k" and K="K" in BseqI2')
   110 apply clarify
   111 apply (drule_tac x="n - k" in spec, simp)
   112 done
   113 
   114 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   115 unfolding Bfun_def eventually_sequentially
   116 apply (rule iffI)
   117 apply (simp add: Bseq_def)
   118 apply (auto intro: BseqI2')
   119 done
   120 
   121 
   122 subsection {* Sequences That Converge to Zero *}
   123 
   124 lemma ZseqI:
   125   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   126 unfolding Zseq_def by simp
   127 
   128 lemma ZseqD:
   129   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   130 unfolding Zseq_def by simp
   131 
   132 lemma Zseq_conv_Zfun: "Zseq X \<longleftrightarrow> Zfun X sequentially"
   133 unfolding Zseq_def Zfun_def eventually_sequentially ..
   134 
   135 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   136 unfolding Zseq_def by simp
   137 
   138 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   139 unfolding Zseq_def by force
   140 
   141 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   142 unfolding Zseq_def by simp
   143 
   144 lemma Zseq_imp_Zseq:
   145   assumes X: "Zseq X"
   146   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   147   shows "Zseq (\<lambda>n. Y n)"
   148 using X Y Zfun_imp_Zfun [of X sequentially Y K]
   149 unfolding Zseq_conv_Zfun by simp
   150 
   151 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   152 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   153 
   154 lemma Zseq_add:
   155   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n + Y n)"
   156 unfolding Zseq_conv_Zfun by (rule Zfun_add)
   157 
   158 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   159 unfolding Zseq_def by simp
   160 
   161 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   162 by (simp only: diff_minus Zseq_add Zseq_minus)
   163 
   164 lemma (in bounded_linear) Zseq:
   165   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. f (X n))"
   166 unfolding Zseq_conv_Zfun by (rule Zfun)
   167 
   168 lemma (in bounded_bilinear) Zseq:
   169   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   170 unfolding Zseq_conv_Zfun by (rule Zfun)
   171 
   172 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   173   "Zseq X \<Longrightarrow> Bseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   174 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   175 by (rule Zfun_prod_Bfun)
   176 
   177 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   178   "Bseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   179 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   180 by (rule Bfun_prod_Zfun)
   181 
   182 lemma (in bounded_bilinear) Zseq_left:
   183   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   184 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   185 
   186 lemma (in bounded_bilinear) Zseq_right:
   187   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   188 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   189 
   190 lemmas Zseq_mult = mult.Zseq
   191 lemmas Zseq_mult_right = mult.Zseq_right
   192 lemmas Zseq_mult_left = mult.Zseq_left
   193 
   194 
   195 subsection {* Limits of Sequences *}
   196 
   197 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   198   by simp
   199 
   200 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   201 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   202 
   203 lemma LIMSEQ_iff:
   204   fixes L :: "'a::real_normed_vector"
   205   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   206 unfolding LIMSEQ_def dist_norm ..
   207 
   208 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   209 by (simp only: LIMSEQ_iff Zseq_def)
   210 
   211 lemma metric_LIMSEQ_I:
   212   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   213 by (simp add: LIMSEQ_def)
   214 
   215 lemma metric_LIMSEQ_D:
   216   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   217 by (simp add: LIMSEQ_def)
   218 
   219 lemma LIMSEQ_I:
   220   fixes L :: "'a::real_normed_vector"
   221   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   222 by (simp add: LIMSEQ_iff)
   223 
   224 lemma LIMSEQ_D:
   225   fixes L :: "'a::real_normed_vector"
   226   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   227 by (simp add: LIMSEQ_iff)
   228 
   229 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   230 by (simp add: LIMSEQ_def)
   231 
   232 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   233 apply (safe intro!: LIMSEQ_const)
   234 apply (rule ccontr)
   235 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   236 apply (simp add: zero_less_dist_iff)
   237 apply auto
   238 done
   239 
   240 lemma LIMSEQ_norm:
   241   fixes a :: "'a::real_normed_vector"
   242   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   243 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   244 
   245 lemma LIMSEQ_ignore_initial_segment:
   246   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   247 apply (rule metric_LIMSEQ_I)
   248 apply (drule (1) metric_LIMSEQ_D)
   249 apply (erule exE, rename_tac N)
   250 apply (rule_tac x=N in exI)
   251 apply simp
   252 done
   253 
   254 lemma LIMSEQ_offset:
   255   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   256 apply (rule metric_LIMSEQ_I)
   257 apply (drule (1) metric_LIMSEQ_D)
   258 apply (erule exE, rename_tac N)
   259 apply (rule_tac x="N + k" in exI)
   260 apply clarify
   261 apply (drule_tac x="n - k" in spec)
   262 apply (simp add: le_diff_conv2)
   263 done
   264 
   265 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   266 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   267 
   268 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   269 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   270 
   271 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   272 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   273 
   274 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   275   unfolding LIMSEQ_def
   276   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   277 
   278 lemma LIMSEQ_add:
   279   fixes a b :: "'a::real_normed_vector"
   280   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   281 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   282 
   283 lemma LIMSEQ_minus:
   284   fixes a :: "'a::real_normed_vector"
   285   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   286 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   287 
   288 lemma LIMSEQ_minus_cancel:
   289   fixes a :: "'a::real_normed_vector"
   290   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   291 by (drule LIMSEQ_minus, simp)
   292 
   293 lemma LIMSEQ_diff:
   294   fixes a b :: "'a::real_normed_vector"
   295   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   296 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   297 
   298 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   299 apply (rule ccontr)
   300 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   301 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   302 apply (clarify, rename_tac M N)
   303 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   304 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   305 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   306 apply (subst dist_commute, rule dist_triangle)
   307 done
   308 
   309 lemma (in bounded_linear) LIMSEQ:
   310   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   311 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   312 
   313 lemma (in bounded_bilinear) LIMSEQ:
   314   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   315 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   316 
   317 lemma LIMSEQ_mult:
   318   fixes a b :: "'a::real_normed_algebra"
   319   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   320 by (rule mult.LIMSEQ)
   321 
   322 lemma increasing_LIMSEQ:
   323   fixes f :: "nat \<Rightarrow> real"
   324   assumes inc: "!!n. f n \<le> f (Suc n)"
   325       and bdd: "!!n. f n \<le> l"
   326       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   327   shows "f ----> l"
   328 proof (auto simp add: LIMSEQ_def)
   329   fix e :: real
   330   assume e: "0 < e"
   331   then obtain N where "l \<le> f N + e/2"
   332     by (metis half_gt_zero e en that)
   333   hence N: "l < f N + e" using e
   334     by simp
   335   { fix k
   336     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   337       by (simp add: bdd) 
   338     have "\<bar>f (N+k) - l\<bar> < e"
   339     proof (induct k)
   340       case 0 show ?case using N
   341         by simp   
   342     next
   343       case (Suc k) thus ?case using N inc [of "N+k"]
   344         by simp
   345     qed 
   346   } note 1 = this
   347   { fix n
   348     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   349       by simp 
   350   } note [intro] = this
   351   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   352     by (auto simp add: dist_real_def) 
   353   qed
   354 
   355 lemma Bseq_inverse_lemma:
   356   fixes x :: "'a::real_normed_div_algebra"
   357   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   358 apply (subst nonzero_norm_inverse, clarsimp)
   359 apply (erule (1) le_imp_inverse_le)
   360 done
   361 
   362 lemma Bseq_inverse:
   363   fixes a :: "'a::real_normed_div_algebra"
   364   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   365 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   366 by (rule Bfun_inverse)
   367 
   368 lemma LIMSEQ_inverse:
   369   fixes a :: "'a::real_normed_div_algebra"
   370   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   371 unfolding LIMSEQ_conv_tendsto
   372 by (rule tendsto_inverse)
   373 
   374 lemma LIMSEQ_divide:
   375   fixes a b :: "'a::real_normed_field"
   376   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   377 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   378 
   379 lemma LIMSEQ_pow:
   380   fixes a :: "'a::{power, real_normed_algebra}"
   381   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   382 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   383 
   384 lemma LIMSEQ_setsum:
   385   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   386   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   387   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   388 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   389 
   390 lemma LIMSEQ_setprod:
   391   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   392   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   393   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   394 proof (cases "finite S")
   395   case True
   396   thus ?thesis using n
   397   proof (induct)
   398     case empty
   399     show ?case
   400       by (simp add: LIMSEQ_const)
   401   next
   402     case insert
   403     thus ?case
   404       by (simp add: LIMSEQ_mult)
   405   qed
   406 next
   407   case False
   408   thus ?thesis
   409     by (simp add: setprod_def LIMSEQ_const)
   410 qed
   411 
   412 lemma LIMSEQ_add_const:
   413   fixes a :: "'a::real_normed_vector"
   414   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   415 by (simp add: LIMSEQ_add LIMSEQ_const)
   416 
   417 (* FIXME: delete *)
   418 lemma LIMSEQ_add_minus:
   419   fixes a b :: "'a::real_normed_vector"
   420   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   421 by (simp only: LIMSEQ_add LIMSEQ_minus)
   422 
   423 lemma LIMSEQ_diff_const:
   424   fixes a b :: "'a::real_normed_vector"
   425   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   426 by (simp add: LIMSEQ_diff LIMSEQ_const)
   427 
   428 lemma LIMSEQ_diff_approach_zero:
   429   fixes L :: "'a::real_normed_vector"
   430   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   431 by (drule (1) LIMSEQ_add, simp)
   432 
   433 lemma LIMSEQ_diff_approach_zero2:
   434   fixes L :: "'a::real_normed_vector"
   435   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L";
   436 by (drule (1) LIMSEQ_diff, simp)
   437 
   438 text{*A sequence tends to zero iff its abs does*}
   439 lemma LIMSEQ_norm_zero:
   440   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   441   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   442 by (simp add: LIMSEQ_iff)
   443 
   444 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   445 by (simp add: LIMSEQ_iff)
   446 
   447 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   448 by (drule LIMSEQ_norm, simp)
   449 
   450 text{*An unbounded sequence's inverse tends to 0*}
   451 
   452 lemma LIMSEQ_inverse_zero:
   453   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   454 apply (rule LIMSEQ_I)
   455 apply (drule_tac x="inverse r" in spec, safe)
   456 apply (rule_tac x="N" in exI, safe)
   457 apply (drule_tac x="n" in spec, safe)
   458 apply (frule positive_imp_inverse_positive)
   459 apply (frule (1) less_imp_inverse_less)
   460 apply (subgoal_tac "0 < X n", simp)
   461 apply (erule (1) order_less_trans)
   462 done
   463 
   464 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   465 
   466 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   467 apply (rule LIMSEQ_inverse_zero, safe)
   468 apply (cut_tac x = r in reals_Archimedean2)
   469 apply (safe, rule_tac x = n in exI)
   470 apply (auto simp add: real_of_nat_Suc)
   471 done
   472 
   473 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   474 infinity is now easily proved*}
   475 
   476 lemma LIMSEQ_inverse_real_of_nat_add:
   477      "(%n. r + inverse(real(Suc n))) ----> r"
   478 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   479 
   480 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   481      "(%n. r + -inverse(real(Suc n))) ----> r"
   482 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   483 
   484 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   485      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   486 by (cut_tac b=1 in
   487         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   488 
   489 lemma LIMSEQ_le_const:
   490   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   491 apply (rule ccontr, simp only: linorder_not_le)
   492 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   493 apply clarsimp
   494 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   495 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   496 apply simp
   497 done
   498 
   499 lemma LIMSEQ_le_const2:
   500   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   501 apply (subgoal_tac "- a \<le> - x", simp)
   502 apply (rule LIMSEQ_le_const)
   503 apply (erule LIMSEQ_minus)
   504 apply simp
   505 done
   506 
   507 lemma LIMSEQ_le:
   508   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   509 apply (subgoal_tac "0 \<le> y - x", simp)
   510 apply (rule LIMSEQ_le_const)
   511 apply (erule (1) LIMSEQ_diff)
   512 apply (simp add: le_diff_eq)
   513 done
   514 
   515 
   516 subsection {* Convergence *}
   517 
   518 lemma limI: "X ----> L ==> lim X = L"
   519 apply (simp add: lim_def)
   520 apply (blast intro: LIMSEQ_unique)
   521 done
   522 
   523 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   524 by (simp add: convergent_def)
   525 
   526 lemma convergentI: "(X ----> L) ==> convergent X"
   527 by (auto simp add: convergent_def)
   528 
   529 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   530 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   531 
   532 lemma convergent_minus_iff:
   533   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   534   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   535 apply (simp add: convergent_def)
   536 apply (auto dest: LIMSEQ_minus)
   537 apply (drule LIMSEQ_minus, auto)
   538 done
   539 
   540 lemma lim_le:
   541   fixes x :: real
   542   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   543   shows "lim f \<le> x"
   544 proof (rule classical)
   545   assume "\<not> lim f \<le> x"
   546   hence 0: "0 < lim f - x" by arith
   547   have 1: "f----> lim f"
   548     by (metis convergent_LIMSEQ_iff f) 
   549   thus ?thesis
   550     proof (simp add: LIMSEQ_iff)
   551       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   552       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   553         by (metis 0)
   554       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   555         by blast
   556       thus "lim f \<le> x"
   557         by (metis add_cancel_end add_minus_cancel diff_def linorder_linear 
   558                   linorder_not_le minus_diff_eq abs_diff_less_iff fn_le) 
   559     qed
   560 qed
   561 
   562 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   563 
   564 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   565   unfolding Ex1_def
   566   apply (rule_tac x="nat_rec e f" in exI)
   567   apply (rule conjI)+
   568 apply (rule def_nat_rec_0, simp)
   569 apply (rule allI, rule def_nat_rec_Suc, simp)
   570 apply (rule allI, rule impI, rule ext)
   571 apply (erule conjE)
   572 apply (induct_tac x)
   573 apply (simp add: nat_rec_0)
   574 apply (erule_tac x="n" in allE)
   575 apply (simp)
   576 done
   577 
   578 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   579 
   580 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   581 apply (simp add: subseq_def)
   582 apply (auto dest!: less_imp_Suc_add)
   583 apply (induct_tac k)
   584 apply (auto intro: less_trans)
   585 done
   586 
   587 lemma monoseq_Suc:
   588    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   589                  | (\<forall>n. X (Suc n) \<le> X n))"
   590 apply (simp add: monoseq_def)
   591 apply (auto dest!: le_imp_less_or_eq)
   592 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   593 apply (induct_tac "ka")
   594 apply (auto intro: order_trans)
   595 apply (erule contrapos_np)
   596 apply (induct_tac "k")
   597 apply (auto intro: order_trans)
   598 done
   599 
   600 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   601 by (simp add: monoseq_def)
   602 
   603 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   604 by (simp add: monoseq_def)
   605 
   606 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   607 by (simp add: monoseq_Suc)
   608 
   609 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   610 by (simp add: monoseq_Suc)
   611 
   612 lemma monoseq_minus: assumes "monoseq a"
   613   shows "monoseq (\<lambda> n. - a n)"
   614 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   615   case True
   616   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   617   thus ?thesis by (rule monoI2)
   618 next
   619   case False
   620   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   621   thus ?thesis by (rule monoI1)
   622 qed
   623 
   624 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   625   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   626          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   627 proof -
   628   { fix x n fix a :: "nat \<Rightarrow> real"
   629     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   630     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   631     have "a n \<le> x"
   632     proof (rule ccontr)
   633       assume "\<not> a n \<le> x" hence "x < a n" by auto
   634       hence "0 < a n - x" by auto
   635       from `a ----> x`[THEN LIMSEQ_D, OF this]
   636       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   637       hence "norm (a (max no n) - x) < a n - x" by auto
   638       moreover
   639       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   640       hence "x < a (max no n)" by auto
   641       ultimately
   642       have "a (max no n) < a n" by auto
   643       with monotone[where m=n and n="max no n"]
   644       show False by (auto simp:max_def split:split_if_asm)
   645     qed
   646   } note top_down = this
   647   { fix x n m fix a :: "nat \<Rightarrow> real"
   648     assume "a ----> x" and "monoseq a" and "a m < x"
   649     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   650     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   651       case True with top_down and `a ----> x` show ?thesis by auto
   652     next
   653       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   654       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   655       hence False using `a m < x` by auto
   656       thus ?thesis ..
   657     qed
   658   } note when_decided = this
   659 
   660   show ?thesis
   661   proof (cases "\<exists> m. a m \<noteq> x")
   662     case True then obtain m where "a m \<noteq> x" by auto
   663     show ?thesis
   664     proof (cases "a m < x")
   665       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   666       show ?thesis by blast
   667     next
   668       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   669       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   670       show ?thesis by auto
   671     qed
   672   qed auto
   673 qed
   674 
   675 text{* for any sequence, there is a mootonic subsequence *}
   676 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   677 proof-
   678   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   679     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   680     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   681     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   682     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   683       using H apply - 
   684       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   685       unfolding order_le_less by blast 
   686     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   687     {fix n
   688       have "?P (f (Suc n)) (f n)" 
   689         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   690         using H apply - 
   691       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   692       unfolding order_le_less by blast 
   693     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   694   note fSuc = this
   695     {fix p q assume pq: "p \<ge> f q"
   696       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   697         by (cases q, simp_all) }
   698     note pqth = this
   699     {fix q
   700       have "f (Suc q) > f q" apply (induct q) 
   701         using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   702     note fss = this
   703     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   704     {fix a b 
   705       have "f a \<le> f (a + b)"
   706       proof(induct b)
   707         case 0 thus ?case by simp
   708       next
   709         case (Suc b)
   710         from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   711       qed}
   712     note fmon0 = this
   713     have "monoseq (\<lambda>n. s (f n))" 
   714     proof-
   715       {fix n
   716         have "s (f n) \<ge> s (f (Suc n))" 
   717         proof(cases n)
   718           case 0
   719           assume n0: "n = 0"
   720           from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   721           from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   722         next
   723           case (Suc m)
   724           assume m: "n = Suc m"
   725           from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   726           from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   727         qed}
   728       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   729     qed
   730     with th1 have ?thesis by blast}
   731   moreover
   732   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   733     {fix p assume p: "p \<ge> Suc N" 
   734       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   735       have "m \<noteq> p" using m(2) by auto 
   736       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   737     note th0 = this
   738     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   739     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   740     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   741       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   742     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   743       using N apply - 
   744       apply (erule allE[where x="Suc N"], clarsimp)
   745       apply (rule_tac x="m" in exI)
   746       apply auto
   747       apply (subgoal_tac "Suc N \<noteq> m")
   748       apply simp
   749       apply (rule ccontr, simp)
   750       done
   751     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   752     {fix n
   753       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   754         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   755       proof (induct n)
   756         case 0 thus ?case
   757           using f0 N apply auto 
   758           apply (erule allE[where x="f 0"], clarsimp) 
   759           apply (rule_tac x="m" in exI, simp)
   760           by (subgoal_tac "f 0 \<noteq> m", auto)
   761       next
   762         case (Suc n)
   763         from Suc.hyps have Nfn: "N < f n" by blast
   764         from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   765         with Nfn have mN: "m > N" by arith
   766         note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   767         
   768         from key have th0: "f (Suc n) > N" by simp
   769         from N[rule_format, OF th0]
   770         obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   771         have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   772         hence "m' > f (Suc n)" using m'(1) by simp
   773         with key m'(2) show ?case by auto
   774       qed}
   775     note fSuc = this
   776     {fix n
   777       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   778       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   779     note thf = this
   780     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   781     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   782       apply -
   783       apply (rule disjI1)
   784       apply auto
   785       apply (rule order_less_imp_le)
   786       apply blast
   787       done
   788     then have ?thesis  using sqf by blast}
   789   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   790 qed
   791 
   792 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   793 proof(induct n)
   794   case 0 thus ?case by simp
   795 next
   796   case (Suc n)
   797   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   798   have "n < f (Suc n)" by arith 
   799   thus ?case by arith
   800 qed
   801 
   802 lemma LIMSEQ_subseq_LIMSEQ:
   803   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   804 apply (auto simp add: LIMSEQ_def) 
   805 apply (drule_tac x=r in spec, clarify)  
   806 apply (rule_tac x=no in exI, clarify) 
   807 apply (blast intro: seq_suble le_trans dest!: spec) 
   808 done
   809 
   810 subsection {* Bounded Monotonic Sequences *}
   811 
   812 
   813 text{*Bounded Sequence*}
   814 
   815 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   816 by (simp add: Bseq_def)
   817 
   818 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   819 by (auto simp add: Bseq_def)
   820 
   821 lemma lemma_NBseq_def:
   822      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   823       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   824 proof auto
   825   fix K :: real
   826   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   827   then have "K \<le> real (Suc n)" by auto
   828   assume "\<forall>m. norm (X m) \<le> K"
   829   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   830   proof
   831     fix m :: 'a
   832     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   833     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   834   qed
   835   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   836 next
   837   fix N :: nat
   838   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   839   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   840   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   841 qed
   842 
   843 
   844 text{* alternative definition for Bseq *}
   845 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   846 apply (simp add: Bseq_def)
   847 apply (simp (no_asm) add: lemma_NBseq_def)
   848 done
   849 
   850 lemma lemma_NBseq_def2:
   851      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   852 apply (subst lemma_NBseq_def, auto)
   853 apply (rule_tac x = "Suc N" in exI)
   854 apply (rule_tac [2] x = N in exI)
   855 apply (auto simp add: real_of_nat_Suc)
   856  prefer 2 apply (blast intro: order_less_imp_le)
   857 apply (drule_tac x = n in spec, simp)
   858 done
   859 
   860 (* yet another definition for Bseq *)
   861 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   862 by (simp add: Bseq_def lemma_NBseq_def2)
   863 
   864 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   865 
   866 lemma Bseq_isUb:
   867   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   868 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   869 
   870 
   871 text{* Use completeness of reals (supremum property)
   872    to show that any bounded sequence has a least upper bound*}
   873 
   874 lemma Bseq_isLub:
   875   "!!(X::nat=>real). Bseq X ==>
   876    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   877 by (blast intro: reals_complete Bseq_isUb)
   878 
   879 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   880 
   881 lemma lemma_converg1:
   882      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   883                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   884                |] ==> \<forall>n \<ge> ma. X n = X ma"
   885 apply safe
   886 apply (drule_tac y = "X n" in isLubD2)
   887 apply (blast dest: order_antisym)+
   888 done
   889 
   890 text{* The best of both worlds: Easier to prove this result as a standard
   891    theorem and then use equivalence to "transfer" it into the
   892    equivalent nonstandard form if needed!*}
   893 
   894 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   895 apply (simp add: LIMSEQ_def)
   896 apply (rule_tac x = "X m" in exI, safe)
   897 apply (rule_tac x = m in exI, safe)
   898 apply (drule spec, erule impE, auto)
   899 done
   900 
   901 lemma lemma_converg2:
   902    "!!(X::nat=>real).
   903     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   904 apply safe
   905 apply (drule_tac y = "X m" in isLubD2)
   906 apply (auto dest!: order_le_imp_less_or_eq)
   907 done
   908 
   909 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   910 by (rule setleI [THEN isUbI], auto)
   911 
   912 text{* FIXME: @{term "U - T < U"} is redundant *}
   913 lemma lemma_converg4: "!!(X::nat=> real).
   914                [| \<forall>m. X m ~= U;
   915                   isLub UNIV {x. \<exists>n. X n = x} U;
   916                   0 < T;
   917                   U + - T < U
   918                |] ==> \<exists>m. U + -T < X m & X m < U"
   919 apply (drule lemma_converg2, assumption)
   920 apply (rule ccontr, simp)
   921 apply (simp add: linorder_not_less)
   922 apply (drule lemma_converg3)
   923 apply (drule isLub_le_isUb, assumption)
   924 apply (auto dest: order_less_le_trans)
   925 done
   926 
   927 text{*A standard proof of the theorem for monotone increasing sequence*}
   928 
   929 lemma Bseq_mono_convergent:
   930      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   931 apply (simp add: convergent_def)
   932 apply (frule Bseq_isLub, safe)
   933 apply (case_tac "\<exists>m. X m = U", auto)
   934 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   935 (* second case *)
   936 apply (rule_tac x = U in exI)
   937 apply (subst LIMSEQ_iff, safe)
   938 apply (frule lemma_converg2, assumption)
   939 apply (drule lemma_converg4, auto)
   940 apply (rule_tac x = m in exI, safe)
   941 apply (subgoal_tac "X m \<le> X n")
   942  prefer 2 apply blast
   943 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   944 done
   945 
   946 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   947 by (simp add: Bseq_def)
   948 
   949 text{*Main monotonicity theorem*}
   950 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   951 apply (simp add: monoseq_def, safe)
   952 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   953 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   954 apply (auto intro!: Bseq_mono_convergent)
   955 done
   956 
   957 subsubsection{*Increasing and Decreasing Series*}
   958 
   959 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   960   by (simp add: incseq_def monoseq_def) 
   961 
   962 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   963   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   964 proof
   965   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   966   thus ?thesis by simp
   967 next
   968   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   969   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   970     by (auto simp add: incseq_def intro: order_antisym)
   971   have X: "!!n. X n = X 0"
   972     by (blast intro: const [of 0]) 
   973   have "X = (\<lambda>n. X 0)"
   974     by (blast intro: ext X)
   975   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   976     by (auto intro: LIMSEQ_unique lim) 
   977   thus ?thesis
   978     by (blast intro: eq_refl X)
   979 qed
   980 
   981 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   982   by (simp add: decseq_def monoseq_def)
   983 
   984 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
   985   by (simp add: decseq_def incseq_def)
   986 
   987 
   988 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   989 proof -
   990   have inc: "incseq (\<lambda>n. - X n)" using dec
   991     by (simp add: decseq_eq_incseq)
   992   have "- X n \<le> - L" 
   993     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   994   thus ?thesis
   995     by simp
   996 qed
   997 
   998 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   999 
  1000 text{*alternative formulation for boundedness*}
  1001 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
  1002 apply (unfold Bseq_def, safe)
  1003 apply (rule_tac [2] x = "k + norm x" in exI)
  1004 apply (rule_tac x = K in exI, simp)
  1005 apply (rule exI [where x = 0], auto)
  1006 apply (erule order_less_le_trans, simp)
  1007 apply (drule_tac x=n in spec, fold diff_def)
  1008 apply (drule order_trans [OF norm_triangle_ineq2])
  1009 apply simp
  1010 done
  1011 
  1012 text{*alternative formulation for boundedness*}
  1013 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
  1014 apply safe
  1015 apply (simp add: Bseq_def, safe)
  1016 apply (rule_tac x = "K + norm (X N)" in exI)
  1017 apply auto
  1018 apply (erule order_less_le_trans, simp)
  1019 apply (rule_tac x = N in exI, safe)
  1020 apply (drule_tac x = n in spec)
  1021 apply (rule order_trans [OF norm_triangle_ineq], simp)
  1022 apply (auto simp add: Bseq_iff2)
  1023 done
  1024 
  1025 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
  1026 apply (simp add: Bseq_def)
  1027 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
  1028 apply (drule_tac x = n in spec, arith)
  1029 done
  1030 
  1031 
  1032 subsection {* Cauchy Sequences *}
  1033 
  1034 lemma metric_CauchyI:
  1035   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1036 by (simp add: Cauchy_def)
  1037 
  1038 lemma metric_CauchyD:
  1039   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1040 by (simp add: Cauchy_def)
  1041 
  1042 lemma Cauchy_iff:
  1043   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1044   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1045 unfolding Cauchy_def dist_norm ..
  1046 
  1047 lemma CauchyI:
  1048   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1049   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1050 by (simp add: Cauchy_iff)
  1051 
  1052 lemma CauchyD:
  1053   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1054   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1055 by (simp add: Cauchy_iff)
  1056 
  1057 lemma Cauchy_subseq_Cauchy:
  1058   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1059 apply (auto simp add: Cauchy_def)
  1060 apply (drule_tac x=e in spec, clarify)
  1061 apply (rule_tac x=M in exI, clarify)
  1062 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1063 done
  1064 
  1065 subsubsection {* Cauchy Sequences are Bounded *}
  1066 
  1067 text{*A Cauchy sequence is bounded -- this is the standard
  1068   proof mechanization rather than the nonstandard proof*}
  1069 
  1070 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1071           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1072 apply (clarify, drule spec, drule (1) mp)
  1073 apply (simp only: norm_minus_commute)
  1074 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1075 apply simp
  1076 done
  1077 
  1078 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1079 apply (simp add: Cauchy_iff)
  1080 apply (drule spec, drule mp, rule zero_less_one, safe)
  1081 apply (drule_tac x="M" in spec, simp)
  1082 apply (drule lemmaCauchy)
  1083 apply (rule_tac k="M" in Bseq_offset)
  1084 apply (simp add: Bseq_def)
  1085 apply (rule_tac x="1 + norm (X M)" in exI)
  1086 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1087 apply (simp add: order_less_imp_le)
  1088 done
  1089 
  1090 subsubsection {* Cauchy Sequences are Convergent *}
  1091 
  1092 axclass complete_space \<subseteq> metric_space
  1093   Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1094 
  1095 axclass banach \<subseteq> real_normed_vector, complete_space
  1096 
  1097 theorem LIMSEQ_imp_Cauchy:
  1098   assumes X: "X ----> a" shows "Cauchy X"
  1099 proof (rule metric_CauchyI)
  1100   fix e::real assume "0 < e"
  1101   hence "0 < e/2" by simp
  1102   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1103   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1104   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1105   proof (intro exI allI impI)
  1106     fix m assume "N \<le> m"
  1107     hence m: "dist (X m) a < e/2" using N by fast
  1108     fix n assume "N \<le> n"
  1109     hence n: "dist (X n) a < e/2" using N by fast
  1110     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1111       by (rule dist_triangle2)
  1112     also from m n have "\<dots> < e" by simp
  1113     finally show "dist (X m) (X n) < e" .
  1114   qed
  1115 qed
  1116 
  1117 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1118 unfolding convergent_def
  1119 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1120 
  1121 lemma Cauchy_convergent_iff:
  1122   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1123   shows "Cauchy X = convergent X"
  1124 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1125 
  1126 lemma convergent_subseq_convergent:
  1127   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1128   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1129   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1130 
  1131 text {*
  1132 Proof that Cauchy sequences converge based on the one from
  1133 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1134 *}
  1135 
  1136 text {*
  1137   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1138   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1139 *}
  1140 
  1141 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1142 by (simp add: isUbI setleI)
  1143 
  1144 locale real_Cauchy =
  1145   fixes X :: "nat \<Rightarrow> real"
  1146   assumes X: "Cauchy X"
  1147   fixes S :: "real set"
  1148   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1149 
  1150 lemma real_CauchyI:
  1151   assumes "Cauchy X"
  1152   shows "real_Cauchy X"
  1153   proof qed (fact assms)
  1154 
  1155 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1156 by (unfold S_def, auto)
  1157 
  1158 lemma (in real_Cauchy) bound_isUb:
  1159   assumes N: "\<forall>n\<ge>N. X n < x"
  1160   shows "isUb UNIV S x"
  1161 proof (rule isUb_UNIV_I)
  1162   fix y::real assume "y \<in> S"
  1163   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1164     by (simp add: S_def)
  1165   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1166   hence "y < X (max M N)" by simp
  1167   also have "\<dots> < x" using N by simp
  1168   finally show "y \<le> x"
  1169     by (rule order_less_imp_le)
  1170 qed
  1171 
  1172 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1173 proof (rule reals_complete)
  1174   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1175     using CauchyD [OF X zero_less_one] by auto
  1176   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1177   show "\<exists>x. x \<in> S"
  1178   proof
  1179     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1180       by (simp add: abs_diff_less_iff)
  1181     thus "X N - 1 \<in> S" by (rule mem_S)
  1182   qed
  1183   show "\<exists>u. isUb UNIV S u"
  1184   proof
  1185     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1186       by (simp add: abs_diff_less_iff)
  1187     thus "isUb UNIV S (X N + 1)"
  1188       by (rule bound_isUb)
  1189   qed
  1190 qed
  1191 
  1192 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1193   assumes x: "isLub UNIV S x"
  1194   shows "X ----> x"
  1195 proof (rule LIMSEQ_I)
  1196   fix r::real assume "0 < r"
  1197   hence r: "0 < r/2" by simp
  1198   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1199     using CauchyD [OF X r] by auto
  1200   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1201   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1202     by (simp only: real_norm_def abs_diff_less_iff)
  1203 
  1204   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1205   hence "X N - r/2 \<in> S" by (rule mem_S)
  1206   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1207 
  1208   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1209   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1210   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1211 
  1212   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1213   proof (intro exI allI impI)
  1214     fix n assume n: "N \<le> n"
  1215     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1216     thus "norm (X n - x) < r" using 1 2
  1217       by (simp add: abs_diff_less_iff)
  1218   qed
  1219 qed
  1220 
  1221 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1222 proof -
  1223   obtain x where "isLub UNIV S x"
  1224     using isLub_ex by fast
  1225   hence "X ----> x"
  1226     by (rule isLub_imp_LIMSEQ)
  1227   thus ?thesis ..
  1228 qed
  1229 
  1230 lemma real_Cauchy_convergent:
  1231   fixes X :: "nat \<Rightarrow> real"
  1232   shows "Cauchy X \<Longrightarrow> convergent X"
  1233 unfolding convergent_def
  1234 by (rule real_Cauchy.LIMSEQ_ex)
  1235  (rule real_CauchyI)
  1236 
  1237 instance real :: banach
  1238 by intro_classes (rule real_Cauchy_convergent)
  1239 
  1240 
  1241 subsection {* Power Sequences *}
  1242 
  1243 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1244 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1245   also fact that bounded and monotonic sequence converges.*}
  1246 
  1247 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1248 apply (simp add: Bseq_def)
  1249 apply (rule_tac x = 1 in exI)
  1250 apply (simp add: power_abs)
  1251 apply (auto dest: power_mono)
  1252 done
  1253 
  1254 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1255 apply (clarify intro!: mono_SucI2)
  1256 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1257 done
  1258 
  1259 lemma convergent_realpow:
  1260   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1261 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1262 
  1263 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1264   fixes x :: real
  1265   assumes x: "0 \<le> x"
  1266   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1267 apply (induct n)
  1268 apply simp
  1269 apply simp
  1270 apply (rule order_trans)
  1271 prefer 2
  1272 apply (erule mult_left_mono)
  1273 apply (rule add_increasing [OF x], simp)
  1274 apply (simp add: real_of_nat_Suc)
  1275 apply (simp add: ring_distribs)
  1276 apply (simp add: mult_nonneg_nonneg x)
  1277 done
  1278 
  1279 lemma LIMSEQ_inverse_realpow_zero:
  1280   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1281 proof (rule LIMSEQ_inverse_zero [rule_format])
  1282   fix y :: real
  1283   assume x: "1 < x"
  1284   hence "0 < x - 1" by simp
  1285   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1286     by (rule reals_Archimedean3)
  1287   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1288   then obtain N::nat where "y < real N * (x - 1)" ..
  1289   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1290   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1291     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1292   also have "\<dots> = x ^ N" by simp
  1293   finally have "y < x ^ N" .
  1294   hence "\<forall>n\<ge>N. y < x ^ n"
  1295     apply clarify
  1296     apply (erule order_less_le_trans)
  1297     apply (erule power_increasing)
  1298     apply (rule order_less_imp_le [OF x])
  1299     done
  1300   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1301 qed
  1302 
  1303 lemma LIMSEQ_realpow_zero:
  1304   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1305 proof (cases)
  1306   assume "x = 0"
  1307   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1308   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1309 next
  1310   assume "0 \<le> x" and "x \<noteq> 0"
  1311   hence x0: "0 < x" by simp
  1312   assume x1: "x < 1"
  1313   from x0 x1 have "1 < inverse x"
  1314     by (rule real_inverse_gt_one)
  1315   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1316     by (rule LIMSEQ_inverse_realpow_zero)
  1317   thus ?thesis by (simp add: power_inverse)
  1318 qed
  1319 
  1320 lemma LIMSEQ_power_zero:
  1321   fixes x :: "'a::{real_normed_algebra_1}"
  1322   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1323 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1324 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1325 apply (simp add: power_abs norm_power_ineq)
  1326 done
  1327 
  1328 lemma LIMSEQ_divide_realpow_zero:
  1329   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1330 apply (cut_tac a = a and x1 = "inverse x" in
  1331         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1332 apply (auto simp add: divide_inverse power_inverse)
  1333 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1334 done
  1335 
  1336 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1337 
  1338 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1339 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1340 
  1341 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1342 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1343 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1344 done
  1345 
  1346 end