src/HOL/Library/FuncSet.thy
author hoelzl
Mon Nov 19 12:29:02 2012 +0100 (2012-11-19)
changeset 50123 69b35a75caf3
parent 50104 de19856feb54
child 53015 a1119cf551e8
permissions -rw-r--r--
merge extensional dependent function space from FuncSet with the one in Finite_Product_Measure
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    67   unfolding Pi_def by auto
    68 
    69 lemma PiE [elim]:
    70   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    71 by(auto simp: Pi_def)
    72 
    73 lemma Pi_cong:
    74   "(\<And> w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    75   by (auto simp: Pi_def)
    76 
    77 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    78   by auto
    79 
    80 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    81   by (simp add: Pi_def)
    82 
    83 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    84   by auto
    85 
    86 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    87   by auto
    88 
    89 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B x = {})"
    90 apply (simp add: Pi_def, auto)
    91 txt{*Converse direction requires Axiom of Choice to exhibit a function
    92 picking an element from each non-empty @{term "B x"}*}
    93 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    94 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    95 done
    96 
    97 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    98 by (simp add: Pi_def)
    99 
   100 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
   101   by auto
   102 
   103 lemma Pi_UN:
   104   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
   105   assumes "finite I" and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
   106   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   107 proof (intro set_eqI iffI)
   108   fix f assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   109   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i" by auto
   110   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)" by auto
   111   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   112     using `finite I` finite_nat_set_iff_bounded_le[of "n`I"] by auto
   113   have "f \<in> Pi I (A k)"
   114   proof (intro Pi_I)
   115     fix i assume "i \<in> I"
   116     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   117     show "f i \<in> A k i" by auto
   118   qed
   119   then show "f \<in> (\<Union>n. Pi I (A n))" by auto
   120 qed auto
   121 
   122 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
   123 by (simp add: Pi_def)
   124 
   125 text{*Covariance of Pi-sets in their second argument*}
   126 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
   127 by auto
   128 
   129 text{*Contravariance of Pi-sets in their first argument*}
   130 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   131 by auto
   132 
   133 lemma prod_final:
   134   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   135   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   136 proof (rule Pi_I) 
   137   fix z
   138   assume z: "z \<in> A" 
   139   have "f z = (fst (f z), snd (f z))" 
   140     by simp
   141   also have "...  \<in> B z \<times> C z"
   142     by (metis SigmaI PiE o_apply 1 2 z) 
   143   finally show "f z \<in> B z \<times> C z" .
   144 qed
   145 
   146 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   147   by (auto simp: Pi_def)
   148 
   149 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   150   by (auto simp: Pi_def)
   151 
   152 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   153   by (auto simp: Pi_def)
   154 
   155 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   156   by (auto simp: Pi_def)
   157 
   158 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   159   apply auto
   160   apply (drule_tac x=x in Pi_mem)
   161   apply (simp_all split: split_if_asm)
   162   apply (drule_tac x=i in Pi_mem)
   163   apply (auto dest!: Pi_mem)
   164   done
   165 
   166 subsection{*Composition With a Restricted Domain: @{term compose}*}
   167 
   168 lemma funcset_compose:
   169   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   170 by (simp add: Pi_def compose_def restrict_def)
   171 
   172 lemma compose_assoc:
   173     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   174       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   175 by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   176 
   177 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   178 by (simp add: compose_def restrict_def)
   179 
   180 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   181   by (auto simp add: image_def compose_eq)
   182 
   183 
   184 subsection{*Bounded Abstraction: @{term restrict}*}
   185 
   186 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   187   by (simp add: Pi_def restrict_def)
   188 
   189 lemma restrictI[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   190   by (simp add: Pi_def restrict_def)
   191 
   192 lemma restrict_apply [simp]:
   193     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   194   by (simp add: restrict_def)
   195 
   196 lemma restrict_ext:
   197     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   198   by (simp add: fun_eq_iff Pi_def restrict_def)
   199 
   200 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   201   by (simp add: inj_on_def restrict_def)
   202 
   203 lemma Id_compose:
   204     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   205   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   206 
   207 lemma compose_Id:
   208     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   209   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   210 
   211 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   212   by (auto simp add: restrict_def)
   213 
   214 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   215   unfolding restrict_def by (simp add: fun_eq_iff)
   216 
   217 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   218   by (auto simp: restrict_def)
   219 
   220 lemma restrict_upd[simp]:
   221   "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   222   by (auto simp: fun_eq_iff)
   223 
   224 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   225   by (auto simp: restrict_def Pi_def)
   226 
   227 
   228 subsection{*Bijections Between Sets*}
   229 
   230 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   231 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   232 
   233 lemma bij_betwI:
   234 assumes "f \<in> A \<rightarrow> B" and "g \<in> B \<rightarrow> A"
   235     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x" and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   236 shows "bij_betw f A B"
   237 unfolding bij_betw_def
   238 proof
   239   show "inj_on f A" by (metis g_f inj_on_def)
   240 next
   241   have "f ` A \<subseteq> B" using `f \<in> A \<rightarrow> B` by auto
   242   moreover
   243   have "B \<subseteq> f ` A" by auto (metis Pi_mem `g \<in> B \<rightarrow> A` f_g image_iff)
   244   ultimately show "f ` A = B" by blast
   245 qed
   246 
   247 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   248 by (auto simp add: bij_betw_def)
   249 
   250 lemma inj_on_compose:
   251   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   252 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   253 
   254 lemma bij_betw_compose:
   255   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   256 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   257 apply (auto simp add: compose_def image_def)
   258 done
   259 
   260 lemma bij_betw_restrict_eq [simp]:
   261   "bij_betw (restrict f A) A B = bij_betw f A B"
   262 by (simp add: bij_betw_def)
   263 
   264 
   265 subsection{*Extensionality*}
   266 
   267 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   268   unfolding extensional_def by auto
   269 
   270 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   271 by (simp add: extensional_def)
   272 
   273 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   274 by (simp add: restrict_def extensional_def)
   275 
   276 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   277 by (simp add: compose_def)
   278 
   279 lemma extensionalityI:
   280   "[| f \<in> extensional A; g \<in> extensional A;
   281       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   282 by (force simp add: fun_eq_iff extensional_def)
   283 
   284 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   285 by(rule extensionalityI[OF restrict_extensional]) auto
   286 
   287 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   288   unfolding extensional_def by auto
   289 
   290 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   291 by (unfold inv_into_def) (fast intro: someI2)
   292 
   293 lemma compose_inv_into_id:
   294   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   295 apply (simp add: bij_betw_def compose_def)
   296 apply (rule restrict_ext, auto)
   297 done
   298 
   299 lemma compose_id_inv_into:
   300   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   301 apply (simp add: compose_def)
   302 apply (rule restrict_ext)
   303 apply (simp add: f_inv_into_f)
   304 done
   305 
   306 lemma extensional_insert[intro, simp]:
   307   assumes "a \<in> extensional (insert i I)"
   308   shows "a(i := b) \<in> extensional (insert i I)"
   309   using assms unfolding extensional_def by auto
   310 
   311 lemma extensional_Int[simp]:
   312   "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   313   unfolding extensional_def by auto
   314 
   315 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   316   by (auto simp: extensional_def)
   317 
   318 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   319   unfolding restrict_def extensional_def by auto
   320 
   321 lemma extensional_insert_undefined[intro, simp]:
   322   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   323   unfolding extensional_def by auto
   324 
   325 lemma extensional_insert_cancel[intro, simp]:
   326   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   327   unfolding extensional_def by auto
   328 
   329 
   330 subsection{*Cardinality*}
   331 
   332 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   333 by (rule card_inj_on_le) auto
   334 
   335 lemma card_bij:
   336   "[|f \<in> A\<rightarrow>B; inj_on f A;
   337      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   338 by (blast intro: card_inj order_antisym)
   339 
   340 subsection {* Extensional Function Spaces *} 
   341 
   342 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set" where
   343   "PiE S T = Pi S T \<inter> extensional S"
   344 
   345 abbreviation "Pi\<^isub>E A B \<equiv> PiE A B"
   346 
   347 syntax "_PiE"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PIE _:_./ _)" 10)
   348 
   349 syntax (xsymbols) "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^isub>E _\<in>_./ _)" 10)
   350 
   351 syntax (HTML output) "_PiE" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi>\<^isub>E _\<in>_./ _)" 10)
   352 
   353 translations "PIE x:A. B" == "CONST Pi\<^isub>E A (%x. B)"
   354 
   355 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^isub>E" 60) where
   356   "A ->\<^isub>E B \<equiv> (\<Pi>\<^isub>E i\<in>A. B)"
   357 
   358 notation (xsymbols)
   359   extensional_funcset  (infixr "\<rightarrow>\<^isub>E" 60)
   360 
   361 lemma extensional_funcset_def: "extensional_funcset S T = (S -> T) \<inter> extensional S"
   362   by (simp add: PiE_def)
   363 
   364 lemma PiE_empty_domain[simp]: "PiE {} T = {%x. undefined}"
   365   unfolding PiE_def by simp
   366 
   367 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (PIE i:I. F i) = {}"
   368   unfolding PiE_def by auto
   369 
   370 lemma PiE_eq_empty_iff:
   371   "Pi\<^isub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   372 proof
   373   assume "Pi\<^isub>E I F = {}"
   374   show "\<exists>i\<in>I. F i = {}"
   375   proof (rule ccontr)
   376     assume "\<not> ?thesis"
   377     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)" by auto
   378     from choice[OF this] guess f ..
   379     then have "f \<in> Pi\<^isub>E I F" by (auto simp: extensional_def PiE_def)
   380     with `Pi\<^isub>E I F = {}` show False by auto
   381   qed
   382 qed (auto simp: PiE_def)
   383 
   384 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   385   unfolding PiE_def by auto (auto dest!: extensional_arb)
   386 
   387 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   388   unfolding PiE_def by auto
   389 
   390 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   391   unfolding PiE_def extensional_def by auto
   392 
   393 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   394   unfolding PiE_def extensional_def by auto
   395 
   396 lemma PiE_insert_eq:
   397   assumes "x \<notin> S"
   398   shows "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   399 proof -
   400   {
   401     fix f assume "f \<in> PiE (insert x S) T"
   402     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   403       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   404   }
   405   then show ?thesis using assms by (auto intro: PiE_fun_upd)
   406 qed
   407 
   408 lemma PiE_Int: "(Pi\<^isub>E I A) \<inter> (Pi\<^isub>E I B) = Pi\<^isub>E I (\<lambda>x. A x \<inter> B x)"
   409   by (auto simp: PiE_def)
   410 
   411 lemma PiE_cong:
   412   "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^isub>E I A = Pi\<^isub>E I B"
   413   unfolding PiE_def by (auto simp: Pi_cong)
   414 
   415 lemma PiE_E [elim]:
   416   "f \<in> PiE A B \<Longrightarrow> (x \<in> A \<Longrightarrow> f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> f x = undefined \<Longrightarrow> Q) \<Longrightarrow> Q"
   417 by(auto simp: Pi_def PiE_def extensional_def)
   418 
   419 lemma PiE_I[intro!]: "(\<And>x. x \<in> A ==> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   420   by (simp add: PiE_def extensional_def)
   421 
   422 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   423   by auto
   424 
   425 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   426   by (simp add: PiE_def Pi_iff)
   427 
   428 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   429   by (simp add: extensional_restrict PiE_def)
   430 
   431 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   432   by (auto simp: PiE_iff)
   433 
   434 lemma PiE_eq_subset:
   435   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   436   assumes eq: "Pi\<^isub>E I F = Pi\<^isub>E I F'" and "i \<in> I"
   437   shows "F i \<subseteq> F' i"
   438 proof
   439   fix x assume "x \<in> F i"
   440   with ne have "\<forall>j. \<exists>y. ((j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined))" by auto
   441   from choice[OF this] guess f .. note f = this
   442   then have "f \<in> Pi\<^isub>E I F" by (auto simp: extensional_def PiE_def)
   443   then have "f \<in> Pi\<^isub>E I F'" using assms by simp
   444   then show "x \<in> F' i" using f `i \<in> I` by (auto simp: PiE_def)
   445 qed
   446 
   447 lemma PiE_eq_iff_not_empty:
   448   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   449   shows "Pi\<^isub>E I F = Pi\<^isub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   450 proof (intro iffI ballI)
   451   fix i assume eq: "Pi\<^isub>E I F = Pi\<^isub>E I F'" and i: "i \<in> I"
   452   show "F i = F' i"
   453     using PiE_eq_subset[of I F F', OF ne eq i]
   454     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   455     by auto
   456 qed (auto simp: PiE_def)
   457 
   458 lemma PiE_eq_iff:
   459   "Pi\<^isub>E I F = Pi\<^isub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   460 proof (intro iffI disjCI)
   461   assume eq[simp]: "Pi\<^isub>E I F = Pi\<^isub>E I F'"
   462   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   463   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   464     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   465   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i" by auto
   466 next
   467   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   468   then show "Pi\<^isub>E I F = Pi\<^isub>E I F'"
   469     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   470 qed
   471 
   472 lemma extensional_funcset_fun_upd_restricts_rangeI: 
   473   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f : (insert x S) \<rightarrow>\<^isub>E T ==> f(x := undefined) : S \<rightarrow>\<^isub>E (T - {f x})"
   474   unfolding extensional_funcset_def extensional_def
   475   apply auto
   476   apply (case_tac "x = xa")
   477   apply auto
   478   done
   479 
   480 lemma extensional_funcset_fun_upd_extends_rangeI:
   481   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^isub>E (T - {a})"
   482   shows "f(x := a) \<in> (insert x S) \<rightarrow>\<^isub>E  T"
   483   using assms unfolding extensional_funcset_def extensional_def by auto
   484 
   485 subsubsection {* Injective Extensional Function Spaces *}
   486 
   487 lemma extensional_funcset_fun_upd_inj_onI:
   488   assumes "f \<in> S \<rightarrow>\<^isub>E (T - {a})" "inj_on f S"
   489   shows "inj_on (f(x := a)) S"
   490   using assms unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   491 
   492 lemma extensional_funcset_extend_domain_inj_on_eq:
   493   assumes "x \<notin> S"
   494   shows"{f. f \<in> (insert x S) \<rightarrow>\<^isub>E T \<and> inj_on f (insert x S)} =
   495     (%(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^isub>E (T - {y}) \<and> inj_on g S}"
   496 proof -
   497   from assms show ?thesis
   498     apply (auto del: PiE_I PiE_E)
   499     apply (auto intro: extensional_funcset_fun_upd_inj_onI extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   500     apply (auto simp add: image_iff inj_on_def)
   501     apply (rule_tac x="xa x" in exI)
   502     apply (auto intro: PiE_mem del: PiE_I PiE_E)
   503     apply (rule_tac x="xa(x := undefined)" in exI)
   504     apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   505     apply (auto dest!: PiE_mem split: split_if_asm)
   506     done
   507 qed
   508 
   509 lemma extensional_funcset_extend_domain_inj_onI:
   510   assumes "x \<notin> S"
   511   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^isub>E (T - {y}) \<and> inj_on g S}"
   512 proof -
   513   from assms show ?thesis
   514     apply (auto intro!: inj_onI)
   515     apply (metis fun_upd_same)
   516     by (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   517 qed
   518   
   519 
   520 subsubsection {* Cardinality *}
   521 
   522 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (PIE i : S. T i)"
   523   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   524 
   525 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^isub>E S T)"
   526 proof (safe intro!: inj_onI ext)
   527   fix f y g z assume "x \<notin> S" and fg: "f \<in> Pi\<^isub>E S T" "g \<in> Pi\<^isub>E S T"
   528   assume "f(x := y) = g(x := z)"
   529   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   530     unfolding fun_eq_iff by auto
   531   from this[of x] show "y = z" by simp
   532   fix i from *[of i] `x \<notin> S` fg show "f i = g i"
   533     by (auto split: split_if_asm simp: PiE_def extensional_def)
   534 qed
   535 
   536 lemma card_PiE:
   537   "finite S \<Longrightarrow> card (PIE i : S. T i) = (\<Prod> i\<in>S. card (T i))"
   538 proof (induct rule: finite_induct)
   539   case empty then show ?case by auto
   540 next
   541   case (insert x S) then show ?case
   542     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   543 qed
   544 
   545 end