src/HOL/Probability/Finite_Product_Measure.thy
author hoelzl
Mon Nov 19 12:29:02 2012 +0100 (2012-11-19)
changeset 50123 69b35a75caf3
parent 50104 de19856feb54
child 50244 de72bbe42190
permissions -rw-r--r--
merge extensional dependent function space from FuncSet with the one in Finite_Product_Measure
     1 (*  Title:      HOL/Probability/Finite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {*Finite product measures*}
     6 
     7 theory Finite_Product_Measure
     8 imports Binary_Product_Measure
     9 begin
    10 
    11 lemma split_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
    12   by auto
    13 
    14 subsubsection {* Merge two extensional functions *}
    15 
    16 definition
    17   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
    18 
    19 lemma merge_apply[simp]:
    20   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    21   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    22   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    23   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    24   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
    25   unfolding merge_def by auto
    26 
    27 lemma merge_commute:
    28   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
    29   by (force simp: merge_def)
    30 
    31 lemma Pi_cancel_merge_range[simp]:
    32   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    33   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    34   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    35   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    36   by (auto simp: Pi_def)
    37 
    38 lemma Pi_cancel_merge[simp]:
    39   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    40   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    41   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    42   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    43   by (auto simp: Pi_def)
    44 
    45 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
    46   by (auto simp: extensional_def)
    47 
    48 lemma restrict_merge[simp]:
    49   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    50   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    51   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    52   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    53   by (auto simp: restrict_def)
    54 
    55 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    56   unfolding merge_def by auto
    57 
    58 lemma PiE_cancel_merge[simp]:
    59   "I \<inter> J = {} \<Longrightarrow>
    60     merge I J (x, y) \<in> PiE (I \<union> J) B \<longleftrightarrow> x \<in> Pi I B \<and> y \<in> Pi J B"
    61   by (auto simp: PiE_def restrict_Pi_cancel)
    62 
    63 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
    64   unfolding merge_def by (auto simp: fun_eq_iff)
    65 
    66 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    67   unfolding merge_def extensional_def by auto
    68 
    69 lemma merge_restrict[simp]:
    70   "merge I J (restrict x I, y) = merge I J (x, y)"
    71   "merge I J (x, restrict y J) = merge I J (x, y)"
    72   unfolding merge_def by auto
    73 
    74 lemma merge_x_x_eq_restrict[simp]:
    75   "merge I J (x, x) = restrict x (I \<union> J)"
    76   unfolding merge_def by auto
    77 
    78 lemma injective_vimage_restrict:
    79   assumes J: "J \<subseteq> I"
    80   and sets: "A \<subseteq> (\<Pi>\<^isub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^isub>E i\<in>J. S i)" and ne: "(\<Pi>\<^isub>E i\<in>I. S i) \<noteq> {}"
    81   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^isub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^isub>E i\<in>I. S i)"
    82   shows "A = B"
    83 proof  (intro set_eqI)
    84   fix x
    85   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    86   have "J \<inter> (I - J) = {}" by auto
    87   show "x \<in> A \<longleftrightarrow> x \<in> B"
    88   proof cases
    89     assume x: "x \<in> (\<Pi>\<^isub>E i\<in>J. S i)"
    90     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^isub>E i\<in>I. S i)"
    91       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    92       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1)
    93     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    94       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    95       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1 eq)
    96   qed (insert sets, auto)
    97 qed
    98 
    99 lemma restrict_vimage:
   100   "I \<inter> J = {} \<Longrightarrow>
   101     (\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^isub>E I E \<times> Pi\<^isub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
   102   by (auto simp: restrict_Pi_cancel PiE_def)
   103 
   104 lemma merge_vimage:
   105   "I \<inter> J = {} \<Longrightarrow> merge I J -` Pi\<^isub>E (I \<union> J) E = Pi I E \<times> Pi J E"
   106   by (auto simp: restrict_Pi_cancel PiE_def)
   107 
   108 section "Finite product spaces"
   109 
   110 section "Products"
   111 
   112 definition prod_emb where
   113   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (PIE i:I. space (M i))"
   114 
   115 lemma prod_emb_iff: 
   116   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
   117   unfolding prod_emb_def PiE_def by auto
   118 
   119 lemma
   120   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
   121     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
   122     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
   123     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
   124     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
   125     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
   126   by (auto simp: prod_emb_def)
   127 
   128 lemma prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
   129     prod_emb I M J (\<Pi>\<^isub>E i\<in>J. E i) = (\<Pi>\<^isub>E i\<in>I. if i \<in> J then E i else space (M i))"
   130   by (force simp: prod_emb_def PiE_iff split_if_mem2)
   131 
   132 lemma prod_emb_PiE_same_index[simp]:
   133     "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^isub>E I E) = Pi\<^isub>E I E"
   134   by (auto simp: prod_emb_def PiE_iff)
   135 
   136 lemma prod_emb_trans[simp]:
   137   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
   138   by (auto simp add: Int_absorb1 prod_emb_def PiE_def)
   139 
   140 lemma prod_emb_Pi:
   141   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
   142   shows "prod_emb K M J (Pi\<^isub>E J X) = (\<Pi>\<^isub>E i\<in>K. if i \<in> J then X i else space (M i))"
   143   using assms space_closed
   144   by (auto simp: prod_emb_def PiE_iff split: split_if_asm) blast+
   145 
   146 lemma prod_emb_id:
   147   "B \<subseteq> (\<Pi>\<^isub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
   148   by (auto simp: prod_emb_def subset_eq extensional_restrict)
   149 
   150 lemma prod_emb_mono:
   151   "F \<subseteq> G \<Longrightarrow> prod_emb A M B F \<subseteq> prod_emb A M B G"
   152   by (auto simp: prod_emb_def)
   153 
   154 definition PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
   155   "PiM I M = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
   156     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
   157     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
   158     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   159 
   160 definition prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
   161   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j)) `
   162     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
   163 
   164 abbreviation
   165   "Pi\<^isub>M I M \<equiv> PiM I M"
   166 
   167 syntax
   168   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3PIM _:_./ _)" 10)
   169 
   170 syntax (xsymbols)
   171   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^isub>M _\<in>_./ _)"  10)
   172 
   173 syntax (HTML output)
   174   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^isub>M _\<in>_./ _)"  10)
   175 
   176 translations
   177   "PIM x:I. M" == "CONST PiM I (%x. M)"
   178 
   179 lemma prod_algebra_sets_into_space:
   180   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^isub>E i\<in>I. space (M i))"
   181   using assms by (auto simp: prod_emb_def prod_algebra_def)
   182 
   183 lemma prod_algebra_eq_finite:
   184   assumes I: "finite I"
   185   shows "prod_algebra I M = {(\<Pi>\<^isub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
   186 proof (intro iffI set_eqI)
   187   fix A assume "A \<in> ?L"
   188   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   189     and A: "A = prod_emb I M J (PIE j:J. E j)"
   190     by (auto simp: prod_algebra_def)
   191   let ?A = "\<Pi>\<^isub>E i\<in>I. if i \<in> J then E i else space (M i)"
   192   have A: "A = ?A"
   193     unfolding A using J by (intro prod_emb_PiE sets_into_space) auto
   194   show "A \<in> ?R" unfolding A using J top
   195     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
   196 next
   197   fix A assume "A \<in> ?R"
   198   then obtain X where A: "A = (\<Pi>\<^isub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
   199   then have A: "A = prod_emb I M I (\<Pi>\<^isub>E i\<in>I. X i)"
   200     by (simp add: prod_emb_PiE_same_index[OF sets_into_space] Pi_iff)
   201   from X I show "A \<in> ?L" unfolding A
   202     by (auto simp: prod_algebra_def)
   203 qed
   204 
   205 lemma prod_algebraI:
   206   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
   207     \<Longrightarrow> prod_emb I M J (PIE j:J. E j) \<in> prod_algebra I M"
   208   by (auto simp: prod_algebra_def)
   209 
   210 lemma prod_algebraI_finite:
   211   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^isub>E I E) \<in> prod_algebra I M"
   212   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets_into_space] by simp
   213 
   214 lemma Int_stable_PiE: "Int_stable {Pi\<^isub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
   215 proof (safe intro!: Int_stableI)
   216   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   217   then show "\<exists>G. Pi\<^isub>E J E \<inter> Pi\<^isub>E J F = Pi\<^isub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
   218     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"] simp: PiE_Int)
   219 qed
   220 
   221 lemma prod_algebraE:
   222   assumes A: "A \<in> prod_algebra I M"
   223   obtains J E where "A = prod_emb I M J (PIE j:J. E j)"
   224     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)" 
   225   using A by (auto simp: prod_algebra_def)
   226 
   227 lemma prod_algebraE_all:
   228   assumes A: "A \<in> prod_algebra I M"
   229   obtains E where "A = Pi\<^isub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
   230 proof -
   231   from A obtain E J where A: "A = prod_emb I M J (Pi\<^isub>E J E)"
   232     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
   233     by (auto simp: prod_algebra_def)
   234   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
   235     using sets_into_space by auto
   236   then have "A = (\<Pi>\<^isub>E i\<in>I. if i\<in>J then E i else space (M i))"
   237     using A J by (auto simp: prod_emb_PiE)
   238   moreover then have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
   239     using top E by auto
   240   ultimately show ?thesis using that by auto
   241 qed
   242 
   243 lemma Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
   244 proof (unfold Int_stable_def, safe)
   245   fix A assume "A \<in> prod_algebra I M"
   246   from prod_algebraE[OF this] guess J E . note A = this
   247   fix B assume "B \<in> prod_algebra I M"
   248   from prod_algebraE[OF this] guess K F . note B = this
   249   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^isub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter> 
   250       (if i \<in> K then F i else space (M i)))"
   251     unfolding A B using A(2,3,4) A(5)[THEN sets_into_space] B(2,3,4) B(5)[THEN sets_into_space]
   252     apply (subst (1 2 3) prod_emb_PiE)
   253     apply (simp_all add: subset_eq PiE_Int)
   254     apply blast
   255     apply (intro PiE_cong)
   256     apply auto
   257     done
   258   also have "\<dots> \<in> prod_algebra I M"
   259     using A B by (auto intro!: prod_algebraI)
   260   finally show "A \<inter> B \<in> prod_algebra I M" .
   261 qed
   262 
   263 lemma prod_algebra_mono:
   264   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
   265   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
   266   shows "prod_algebra I E \<subseteq> prod_algebra I F"
   267 proof
   268   fix A assume "A \<in> prod_algebra I E"
   269   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
   270     and A: "A = prod_emb I E J (\<Pi>\<^isub>E i\<in>J. G i)"
   271     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
   272     by (auto simp: prod_algebra_def)
   273   moreover
   274   from space have "(\<Pi>\<^isub>E i\<in>I. space (E i)) = (\<Pi>\<^isub>E i\<in>I. space (F i))"
   275     by (rule PiE_cong)
   276   with A have "A = prod_emb I F J (\<Pi>\<^isub>E i\<in>J. G i)"
   277     by (simp add: prod_emb_def)
   278   moreover
   279   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
   280     by auto
   281   ultimately show "A \<in> prod_algebra I F"
   282     apply (simp add: prod_algebra_def image_iff)
   283     apply (intro exI[of _ J] exI[of _ G] conjI)
   284     apply auto
   285     done
   286 qed
   287 
   288 lemma prod_algebra_cong:
   289   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   290   shows "prod_algebra I M = prod_algebra J N"
   291 proof -
   292   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   293     using sets_eq_imp_space_eq[OF sets] by auto
   294   with sets show ?thesis unfolding `I = J`
   295     by (intro antisym prod_algebra_mono) auto
   296 qed
   297 
   298 lemma space_in_prod_algebra:
   299   "(\<Pi>\<^isub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   300 proof cases
   301   assume "I = {}" then show ?thesis
   302     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   303 next
   304   assume "I \<noteq> {}"
   305   then obtain i where "i \<in> I" by auto
   306   then have "(\<Pi>\<^isub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^isub>E i\<in>{i}. space (M i))"
   307     by (auto simp: prod_emb_def)
   308   also have "\<dots> \<in> prod_algebra I M"
   309     using `i \<in> I` by (intro prod_algebraI) auto
   310   finally show ?thesis .
   311 qed
   312 
   313 lemma space_PiM: "space (\<Pi>\<^isub>M i\<in>I. M i) = (\<Pi>\<^isub>E i\<in>I. space (M i))"
   314   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
   315 
   316 lemma sets_PiM: "sets (\<Pi>\<^isub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) (prod_algebra I M)"
   317   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
   318 
   319 lemma sets_PiM_single: "sets (PiM I M) =
   320     sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
   321     (is "_ = sigma_sets ?\<Omega> ?R")
   322   unfolding sets_PiM
   323 proof (rule sigma_sets_eqI)
   324   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
   325   fix A assume "A \<in> prod_algebra I M"
   326   from prod_algebraE[OF this] guess J X . note X = this
   327   show "A \<in> sigma_sets ?\<Omega> ?R"
   328   proof cases
   329     assume "I = {}"
   330     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
   331     with `I = {}` show ?thesis by (auto intro!: sigma_sets_top)
   332   next
   333     assume "I \<noteq> {}"
   334     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^isub>E i\<in>I. space (M i)). f j \<in> X j})"
   335       by (auto simp: prod_emb_def)
   336     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
   337       using X `I \<noteq> {}` by (intro R.finite_INT sigma_sets.Basic) auto
   338     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
   339   qed
   340 next
   341   fix A assume "A \<in> ?R"
   342   then obtain i B where A: "A = {f\<in>\<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)" 
   343     by auto
   344   then have "A = prod_emb I M {i} (\<Pi>\<^isub>E i\<in>{i}. B)"
   345      by (auto simp: prod_emb_def)
   346   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
   347     using A by (intro sigma_sets.Basic prod_algebraI) auto
   348   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
   349 qed
   350 
   351 lemma sets_PiM_I:
   352   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   353   shows "prod_emb I M J (PIE j:J. E j) \<in> sets (PIM i:I. M i)"
   354 proof cases
   355   assume "J = {}"
   356   then have "prod_emb I M J (PIE j:J. E j) = (PIE j:I. space (M j))"
   357     by (auto simp: prod_emb_def)
   358   then show ?thesis
   359     by (auto simp add: sets_PiM intro!: sigma_sets_top)
   360 next
   361   assume "J \<noteq> {}" with assms show ?thesis
   362     by (force simp add: sets_PiM prod_algebra_def)
   363 qed
   364 
   365 lemma measurable_PiM:
   366   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   367   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   368     f -` prod_emb I M J (Pi\<^isub>E J X) \<inter> space N \<in> sets N" 
   369   shows "f \<in> measurable N (PiM I M)"
   370   using sets_PiM prod_algebra_sets_into_space space
   371 proof (rule measurable_sigma_sets)
   372   fix A assume "A \<in> prod_algebra I M"
   373   from prod_algebraE[OF this] guess J X .
   374   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
   375 qed
   376 
   377 lemma measurable_PiM_Collect:
   378   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   379   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   380     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N" 
   381   shows "f \<in> measurable N (PiM I M)"
   382   using sets_PiM prod_algebra_sets_into_space space
   383 proof (rule measurable_sigma_sets)
   384   fix A assume "A \<in> prod_algebra I M"
   385   from prod_algebraE[OF this] guess J X . note X = this
   386   then have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
   387     using space by (auto simp: prod_emb_def del: PiE_I)
   388   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
   389   finally show "f -` A \<inter> space N \<in> sets N" .
   390 qed
   391 
   392 lemma measurable_PiM_single:
   393   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   394   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N" 
   395   shows "f \<in> measurable N (PiM I M)"
   396   using sets_PiM_single
   397 proof (rule measurable_sigma_sets)
   398   fix A assume "A \<in> {{f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   399   then obtain B i where "A = {f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
   400     by auto
   401   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
   402   also have "\<dots> \<in> sets N" using B by (rule sets)
   403   finally show "f -` A \<inter> space N \<in> sets N" .
   404 qed (auto simp: space)
   405 
   406 lemma measurable_PiM_single':
   407   assumes f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> measurable N (M i)"
   408     and "(\<lambda>\<omega> i. f i \<omega>) \<in> space N \<rightarrow> (\<Pi>\<^isub>E i\<in>I. space (M i))"
   409   shows "(\<lambda>\<omega> i. f i \<omega>) \<in> measurable N (Pi\<^isub>M I M)"
   410 proof (rule measurable_PiM_single)
   411   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   412   then have "{\<omega> \<in> space N. f i \<omega> \<in> A} = f i -` A \<inter> space N"
   413     by auto
   414   then show "{\<omega> \<in> space N. f i \<omega> \<in> A} \<in> sets N"
   415     using A f by (auto intro!: measurable_sets)
   416 qed fact
   417 
   418 lemma sets_PiM_I_finite[measurable]:
   419   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
   420   shows "(PIE j:I. E j) \<in> sets (PIM i:I. M i)"
   421   using sets_PiM_I[of I I E M] sets_into_space[OF sets] `finite I` sets by auto
   422 
   423 lemma measurable_component_singleton:
   424   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^isub>M I M) (M i)"
   425 proof (unfold measurable_def, intro CollectI conjI ballI)
   426   fix A assume "A \<in> sets (M i)"
   427   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^isub>M I M) = prod_emb I M {i} (\<Pi>\<^isub>E j\<in>{i}. A)"
   428     using sets_into_space `i \<in> I`
   429     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: split_if_asm)
   430   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^isub>M I M) \<in> sets (Pi\<^isub>M I M)"
   431     using `A \<in> sets (M i)` `i \<in> I` by (auto intro!: sets_PiM_I)
   432 qed (insert `i \<in> I`, auto simp: space_PiM)
   433 
   434 lemma measurable_component_singleton'[measurable_app]:
   435   assumes f: "f \<in> measurable N (Pi\<^isub>M I M)"
   436   assumes i: "i \<in> I"
   437   shows "(\<lambda>x. (f x) i) \<in> measurable N (M i)"
   438   using measurable_compose[OF f measurable_component_singleton, OF i] .
   439 
   440 lemma measurable_PiM_component_rev[measurable (raw)]:
   441   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<lambda>x. f (x i)) \<in> measurable (PiM I M) N"
   442   by simp
   443 
   444 lemma measurable_nat_case[measurable (raw)]:
   445   assumes [measurable (raw)]: "i = 0 \<Longrightarrow> f \<in> measurable M N"
   446     "\<And>j. i = Suc j \<Longrightarrow> (\<lambda>x. g x j) \<in> measurable M N"
   447   shows "(\<lambda>x. nat_case (f x) (g x) i) \<in> measurable M N"
   448   by (cases i) simp_all
   449 
   450 lemma measurable_nat_case'[measurable (raw)]:
   451   assumes fg[measurable]: "f \<in> measurable N M" "g \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   452   shows "(\<lambda>x. nat_case (f x) (g x)) \<in> measurable N (\<Pi>\<^isub>M i\<in>UNIV. M)"
   453   using fg[THEN measurable_space]
   454   by (auto intro!: measurable_PiM_single' simp add: space_PiM PiE_iff split: nat.split)
   455 
   456 lemma measurable_add_dim[measurable]:
   457   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M M i) (Pi\<^isub>M (insert i I) M)"
   458     (is "?f \<in> measurable ?P ?I")
   459 proof (rule measurable_PiM_single)
   460   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
   461   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
   462     (if j = i then space (Pi\<^isub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
   463     using sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
   464   also have "\<dots> \<in> sets ?P"
   465     using A j
   466     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   467   finally show "{\<omega> \<in> space ?P. prod_case (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
   468 qed (auto simp: space_pair_measure space_PiM PiE_def)
   469 
   470 lemma measurable_component_update:
   471   "x \<in> space (Pi\<^isub>M I M) \<Longrightarrow> i \<notin> I \<Longrightarrow> (\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^isub>M (insert i I) M)"
   472   by simp
   473 
   474 lemma measurable_merge[measurable]:
   475   "merge I J \<in> measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) (Pi\<^isub>M (I \<union> J) M)"
   476     (is "?f \<in> measurable ?P ?U")
   477 proof (rule measurable_PiM_single)
   478   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
   479   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
   480     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
   481     by (auto simp: merge_def)
   482   also have "\<dots> \<in> sets ?P"
   483     using A
   484     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   485   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
   486 qed (auto simp: space_pair_measure space_PiM PiE_iff merge_def extensional_def)
   487 
   488 lemma measurable_restrict[measurable (raw)]:
   489   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
   490   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^isub>M I M)"
   491 proof (rule measurable_PiM_single)
   492   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   493   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
   494     by auto
   495   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
   496     using A X by (auto intro!: measurable_sets)
   497 qed (insert X, auto simp add: PiE_def dest: measurable_space)
   498 
   499 lemma measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^isub>M L M) (Pi\<^isub>M J M)"
   500   by (intro measurable_restrict measurable_component_singleton) auto
   501 
   502 lemma measurable_prod_emb[intro, simp]:
   503   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^isub>M L M)"
   504   unfolding prod_emb_def space_PiM[symmetric]
   505   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
   506 
   507 lemma sets_in_Pi_aux:
   508   "finite I \<Longrightarrow> (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   509   {x\<in>space (PiM I M). x \<in> Pi I F} \<in> sets (PiM I M)"
   510   by (simp add: subset_eq Pi_iff)
   511 
   512 lemma sets_in_Pi[measurable (raw)]:
   513   "finite I \<Longrightarrow> f \<in> measurable N (PiM I M) \<Longrightarrow>
   514   (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   515   Sigma_Algebra.pred N (\<lambda>x. f x \<in> Pi I F)"
   516   unfolding pred_def
   517   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_Pi_aux]) auto
   518 
   519 lemma sets_in_extensional_aux:
   520   "{x\<in>space (PiM I M). x \<in> extensional I} \<in> sets (PiM I M)"
   521 proof -
   522   have "{x\<in>space (PiM I M). x \<in> extensional I} = space (PiM I M)"
   523     by (auto simp add: extensional_def space_PiM)
   524   then show ?thesis by simp
   525 qed
   526 
   527 lemma sets_in_extensional[measurable (raw)]:
   528   "f \<in> measurable N (PiM I M) \<Longrightarrow> Sigma_Algebra.pred N (\<lambda>x. f x \<in> extensional I)"
   529   unfolding pred_def
   530   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_extensional_aux]) auto
   531 
   532 locale product_sigma_finite =
   533   fixes M :: "'i \<Rightarrow> 'a measure"
   534   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
   535 
   536 sublocale product_sigma_finite \<subseteq> M: sigma_finite_measure "M i" for i
   537   by (rule sigma_finite_measures)
   538 
   539 locale finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
   540   fixes I :: "'i set"
   541   assumes finite_index: "finite I"
   542 
   543 lemma (in finite_product_sigma_finite) sigma_finite_pairs:
   544   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
   545     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
   546     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^isub>E i\<in>I. F i k) \<and>
   547     (\<Union>k. \<Pi>\<^isub>E i\<in>I. F i k) = space (PiM I M)"
   548 proof -
   549   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
   550     using M.sigma_finite_incseq by metis
   551   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   552   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
   553     by auto
   554   let ?F = "\<lambda>k. \<Pi>\<^isub>E i\<in>I. F i k"
   555   note space_PiM[simp]
   556   show ?thesis
   557   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
   558     fix i show "range (F i) \<subseteq> sets (M i)" by fact
   559   next
   560     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
   561   next
   562     fix x assume "x \<in> (\<Union>i. ?F i)" with F(1) show "x \<in> space (PiM I M)"
   563       by (auto simp: PiE_def dest!: sets_into_space)
   564   next
   565     fix f assume "f \<in> space (PiM I M)"
   566     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
   567     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def PiE_def)
   568   next
   569     fix i show "?F i \<subseteq> ?F (Suc i)"
   570       using `\<And>i. incseq (F i)`[THEN incseq_SucD] by auto
   571   qed
   572 qed
   573 
   574 lemma
   575   shows space_PiM_empty: "space (Pi\<^isub>M {} M) = {\<lambda>k. undefined}"
   576     and sets_PiM_empty: "sets (Pi\<^isub>M {} M) = { {}, {\<lambda>k. undefined} }"
   577   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
   578 
   579 lemma emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
   580 proof -
   581   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ereal)"
   582   have "emeasure (Pi\<^isub>M {} M) (prod_emb {} M {} (\<Pi>\<^isub>E i\<in>{}. {})) = 1"
   583   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   584     show "positive (PiM {} M) ?\<mu>"
   585       by (auto simp: positive_def)
   586     show "countably_additive (PiM {} M) ?\<mu>"
   587       by (rule countably_additiveI_finite)
   588          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
   589   qed (auto simp: prod_emb_def)
   590   also have "(prod_emb {} M {} (\<Pi>\<^isub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
   591     by (auto simp: prod_emb_def)
   592   finally show ?thesis
   593     by simp
   594 qed
   595 
   596 lemma PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
   597   by (rule measure_eqI) (auto simp add: sets_PiM_empty one_ereal_def)
   598 
   599 lemma (in product_sigma_finite) emeasure_PiM:
   600   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   601 proof (induct I arbitrary: A rule: finite_induct)
   602   case (insert i I)
   603   interpret finite_product_sigma_finite M I by default fact
   604   have "finite (insert i I)" using `finite I` by auto
   605   interpret I': finite_product_sigma_finite M "insert i I" by default fact
   606   let ?h = "(\<lambda>(f, y). f(i := y))"
   607 
   608   let ?P = "distr (Pi\<^isub>M I M \<Otimes>\<^isub>M M i) (Pi\<^isub>M (insert i I) M) ?h"
   609   let ?\<mu> = "emeasure ?P"
   610   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
   611   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
   612 
   613   have "emeasure (Pi\<^isub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^isub>E (insert i I) A)) =
   614     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
   615   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   616     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
   617     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
   618     let ?p = "prod_emb (insert i I) M J (Pi\<^isub>E J E)"
   619     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^isub>E j\<in>J-{i}. E j)"
   620     have "?\<mu> ?p =
   621       emeasure (Pi\<^isub>M I M \<Otimes>\<^isub>M (M i)) (?h -` ?p \<inter> space (Pi\<^isub>M I M \<Otimes>\<^isub>M M i))"
   622       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
   623     also have "?h -` ?p \<inter> space (Pi\<^isub>M I M \<Otimes>\<^isub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
   624       using J E[rule_format, THEN sets_into_space]
   625       by (force simp: space_pair_measure space_PiM prod_emb_iff PiE_def Pi_iff split: split_if_asm)
   626     also have "emeasure (Pi\<^isub>M I M \<Otimes>\<^isub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
   627       emeasure (Pi\<^isub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
   628       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
   629     also have "?p' = (\<Pi>\<^isub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
   630       using J E[rule_format, THEN sets_into_space]
   631       by (auto simp: prod_emb_iff PiE_def Pi_iff split: split_if_asm) blast+
   632     also have "emeasure (Pi\<^isub>M I M) (\<Pi>\<^isub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
   633       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
   634       using E by (subst insert) (auto intro!: setprod_cong)
   635     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
   636        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
   637       using insert by (auto simp: mult_commute intro!: arg_cong2[where f="op *"] setprod_cong)
   638     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
   639       using insert(1,2) J E by (intro setprod_mono_one_right) auto
   640     finally show "?\<mu> ?p = \<dots>" .
   641 
   642     show "prod_emb (insert i I) M J (Pi\<^isub>E J E) \<in> Pow (\<Pi>\<^isub>E i\<in>insert i I. space (M i))"
   643       using J E[rule_format, THEN sets_into_space] by (auto simp: prod_emb_iff PiE_def)
   644   next
   645     show "positive (sets (Pi\<^isub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^isub>M (insert i I) M)) ?\<mu>"
   646       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
   647   next
   648     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
   649       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
   650       using insert by auto
   651   qed (auto intro!: setprod_cong)
   652   with insert show ?case
   653     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets_into_space)
   654 qed simp
   655 
   656 lemma (in product_sigma_finite) sigma_finite: 
   657   assumes "finite I"
   658   shows "sigma_finite_measure (PiM I M)"
   659 proof -
   660   interpret finite_product_sigma_finite M I by default fact
   661 
   662   from sigma_finite_pairs guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   663   then have F: "\<And>j. j \<in> I \<Longrightarrow> range (F j) \<subseteq> sets (M j)"
   664     "incseq (\<lambda>k. \<Pi>\<^isub>E j \<in> I. F j k)"
   665     "(\<Union>k. \<Pi>\<^isub>E j \<in> I. F j k) = space (Pi\<^isub>M I M)"
   666     "\<And>k. \<And>j. j \<in> I \<Longrightarrow> emeasure (M j) (F j k) \<noteq> \<infinity>"
   667     by blast+
   668   let ?F = "\<lambda>k. \<Pi>\<^isub>E j \<in> I. F j k"
   669 
   670   show ?thesis
   671   proof (unfold_locales, intro exI[of _ ?F] conjI allI)
   672     show "range ?F \<subseteq> sets (Pi\<^isub>M I M)" using F(1) `finite I` by auto
   673   next
   674     from F(3) show "(\<Union>i. ?F i) = space (Pi\<^isub>M I M)" by simp
   675   next
   676     fix j
   677     from F `finite I` setprod_PInf[of I, OF emeasure_nonneg, of M]
   678     show "emeasure (\<Pi>\<^isub>M i\<in>I. M i) (?F j) \<noteq> \<infinity>"
   679       by (subst emeasure_PiM) auto
   680   qed
   681 qed
   682 
   683 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^isub>M I M"
   684   using sigma_finite[OF finite_index] .
   685 
   686 lemma (in finite_product_sigma_finite) measure_times:
   687   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^isub>M I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   688   using emeasure_PiM[OF finite_index] by auto
   689 
   690 lemma (in product_sigma_finite) positive_integral_empty:
   691   assumes pos: "0 \<le> f (\<lambda>k. undefined)"
   692   shows "integral\<^isup>P (Pi\<^isub>M {} M) f = f (\<lambda>k. undefined)"
   693 proof -
   694   interpret finite_product_sigma_finite M "{}" by default (fact finite.emptyI)
   695   have "\<And>A. emeasure (Pi\<^isub>M {} M) (Pi\<^isub>E {} A) = 1"
   696     using assms by (subst measure_times) auto
   697   then show ?thesis
   698     unfolding positive_integral_def simple_function_def simple_integral_def[abs_def]
   699   proof (simp add: space_PiM_empty sets_PiM_empty, intro antisym)
   700     show "f (\<lambda>k. undefined) \<le> (SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined))"
   701       by (intro SUP_upper) (auto simp: le_fun_def split: split_max)
   702     show "(SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined)) \<le> f (\<lambda>k. undefined)" using pos
   703       by (intro SUP_least) (auto simp: le_fun_def simp: max_def split: split_if_asm)
   704   qed
   705 qed
   706 
   707 lemma (in product_sigma_finite) distr_merge:
   708   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   709   shows "distr (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) (Pi\<^isub>M (I \<union> J) M) (merge I J) = Pi\<^isub>M (I \<union> J) M"
   710    (is "?D = ?P")
   711 proof -
   712   interpret I: finite_product_sigma_finite M I by default fact
   713   interpret J: finite_product_sigma_finite M J by default fact
   714   have "finite (I \<union> J)" using fin by auto
   715   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   716   interpret P: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" by default
   717   let ?g = "merge I J"
   718 
   719   from IJ.sigma_finite_pairs obtain F where
   720     F: "\<And>i. i\<in> I \<union> J \<Longrightarrow> range (F i) \<subseteq> sets (M i)"
   721        "incseq (\<lambda>k. \<Pi>\<^isub>E i\<in>I \<union> J. F i k)"
   722        "(\<Union>k. \<Pi>\<^isub>E i\<in>I \<union> J. F i k) = space ?P"
   723        "\<And>k. \<forall>i\<in>I\<union>J. emeasure (M i) (F i k) \<noteq> \<infinity>"
   724     by auto
   725   let ?F = "\<lambda>k. \<Pi>\<^isub>E i\<in>I \<union> J. F i k"
   726   
   727   show ?thesis
   728   proof (rule measure_eqI_generator_eq[symmetric])
   729     show "Int_stable (prod_algebra (I \<union> J) M)"
   730       by (rule Int_stable_prod_algebra)
   731     show "prod_algebra (I \<union> J) M \<subseteq> Pow (\<Pi>\<^isub>E i \<in> I \<union> J. space (M i))"
   732       by (rule prod_algebra_sets_into_space)
   733     show "sets ?P = sigma_sets (\<Pi>\<^isub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   734       by (rule sets_PiM)
   735     then show "sets ?D = sigma_sets (\<Pi>\<^isub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   736       by simp
   737 
   738     show "range ?F \<subseteq> prod_algebra (I \<union> J) M" using F
   739       using fin by (auto simp: prod_algebra_eq_finite)
   740     show "(\<Union>i. \<Pi>\<^isub>E ia\<in>I \<union> J. F ia i) = (\<Pi>\<^isub>E i\<in>I \<union> J. space (M i))"
   741       using F(3) by (simp add: space_PiM)
   742   next
   743     fix k
   744     from F `finite I` setprod_PInf[of "I \<union> J", OF emeasure_nonneg, of M]
   745     show "emeasure ?P (?F k) \<noteq> \<infinity>" by (subst IJ.measure_times) auto
   746   next
   747     fix A assume A: "A \<in> prod_algebra (I \<union> J) M"
   748     with fin obtain F where A_eq: "A = (Pi\<^isub>E (I \<union> J) F)" and F: "\<forall>i\<in>J. F i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   749       by (auto simp add: prod_algebra_eq_finite)
   750     let ?B = "Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M"
   751     let ?X = "?g -` A \<inter> space ?B"
   752     have "Pi\<^isub>E I F \<subseteq> space (Pi\<^isub>M I M)" "Pi\<^isub>E J F \<subseteq> space (Pi\<^isub>M J M)"
   753       using F[rule_format, THEN sets_into_space] by (force simp: space_PiM)+
   754     then have X: "?X = (Pi\<^isub>E I F \<times> Pi\<^isub>E J F)"
   755       unfolding A_eq by (subst merge_vimage) (auto simp: space_pair_measure space_PiM)
   756     have "emeasure ?D A = emeasure ?B ?X"
   757       using A by (intro emeasure_distr measurable_merge) (auto simp: sets_PiM)
   758     also have "emeasure ?B ?X = (\<Prod>i\<in>I. emeasure (M i) (F i)) * (\<Prod>i\<in>J. emeasure (M i) (F i))"
   759       using `finite J` `finite I` F unfolding X
   760       by (simp add: J.emeasure_pair_measure_Times I.measure_times J.measure_times)
   761     also have "\<dots> = (\<Prod>i\<in>I \<union> J. emeasure (M i) (F i))"
   762       using `finite J` `finite I` `I \<inter> J = {}`  by (simp add: setprod_Un_one)
   763     also have "\<dots> = emeasure ?P (Pi\<^isub>E (I \<union> J) F)"
   764       using `finite J` `finite I` F unfolding A
   765       by (intro IJ.measure_times[symmetric]) auto
   766     finally show "emeasure ?P A = emeasure ?D A" using A_eq by simp
   767   qed
   768 qed
   769 
   770 lemma (in product_sigma_finite) product_positive_integral_fold:
   771   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
   772   and f: "f \<in> borel_measurable (Pi\<^isub>M (I \<union> J) M)"
   773   shows "integral\<^isup>P (Pi\<^isub>M (I \<union> J) M) f =
   774     (\<integral>\<^isup>+ x. (\<integral>\<^isup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^isub>M J M)) \<partial>(Pi\<^isub>M I M))"
   775 proof -
   776   interpret I: finite_product_sigma_finite M I by default fact
   777   interpret J: finite_product_sigma_finite M J by default fact
   778   interpret P: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" by default
   779   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M)"
   780     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
   781   show ?thesis
   782     apply (subst distr_merge[OF IJ, symmetric])
   783     apply (subst positive_integral_distr[OF measurable_merge f])
   784     apply (subst J.positive_integral_fst_measurable(2)[symmetric, OF P_borel])
   785     apply simp
   786     done
   787 qed
   788 
   789 lemma (in product_sigma_finite) distr_singleton:
   790   "distr (Pi\<^isub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
   791 proof (intro measure_eqI[symmetric])
   792   interpret I: finite_product_sigma_finite M "{i}" by default simp
   793   fix A assume A: "A \<in> sets (M i)"
   794   moreover then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^isub>M {i} M) = (\<Pi>\<^isub>E i\<in>{i}. A)"
   795     using sets_into_space by (auto simp: space_PiM)
   796   ultimately show "emeasure (M i) A = emeasure ?D A"
   797     using A I.measure_times[of "\<lambda>_. A"]
   798     by (simp add: emeasure_distr measurable_component_singleton)
   799 qed simp
   800 
   801 lemma (in product_sigma_finite) product_positive_integral_singleton:
   802   assumes f: "f \<in> borel_measurable (M i)"
   803   shows "integral\<^isup>P (Pi\<^isub>M {i} M) (\<lambda>x. f (x i)) = integral\<^isup>P (M i) f"
   804 proof -
   805   interpret I: finite_product_sigma_finite M "{i}" by default simp
   806   from f show ?thesis
   807     apply (subst distr_singleton[symmetric])
   808     apply (subst positive_integral_distr[OF measurable_component_singleton])
   809     apply simp_all
   810     done
   811 qed
   812 
   813 lemma (in product_sigma_finite) product_positive_integral_insert:
   814   assumes I[simp]: "finite I" "i \<notin> I"
   815     and f: "f \<in> borel_measurable (Pi\<^isub>M (insert i I) M)"
   816   shows "integral\<^isup>P (Pi\<^isub>M (insert i I) M) f = (\<integral>\<^isup>+ x. (\<integral>\<^isup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^isub>M I M))"
   817 proof -
   818   interpret I: finite_product_sigma_finite M I by default auto
   819   interpret i: finite_product_sigma_finite M "{i}" by default auto
   820   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
   821     using f by auto
   822   show ?thesis
   823     unfolding product_positive_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
   824   proof (rule positive_integral_cong, subst product_positive_integral_singleton[symmetric])
   825     fix x assume x: "x \<in> space (Pi\<^isub>M I M)"
   826     let ?f = "\<lambda>y. f (x(i := y))"
   827     show "?f \<in> borel_measurable (M i)"
   828       using measurable_comp[OF measurable_component_update f, OF x `i \<notin> I`]
   829       unfolding comp_def .
   830     show "(\<integral>\<^isup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^isub>M {i} M) = (\<integral>\<^isup>+ y. f (x(i := y i)) \<partial>Pi\<^isub>M {i} M)"
   831       using x
   832       by (auto intro!: positive_integral_cong arg_cong[where f=f]
   833                simp add: space_PiM extensional_def PiE_def)
   834   qed
   835 qed
   836 
   837 lemma (in product_sigma_finite) product_positive_integral_setprod:
   838   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> ereal"
   839   assumes "finite I" and borel: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
   840   and pos: "\<And>i x. i \<in> I \<Longrightarrow> 0 \<le> f i x"
   841   shows "(\<integral>\<^isup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^isub>M I M) = (\<Prod>i\<in>I. integral\<^isup>P (M i) (f i))"
   842 using assms proof induct
   843   case (insert i I)
   844   note `finite I`[intro, simp]
   845   interpret I: finite_product_sigma_finite M I by default auto
   846   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
   847     using insert by (auto intro!: setprod_cong)
   848   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^isub>M J M)"
   849     using sets_into_space insert
   850     by (intro borel_measurable_ereal_setprod
   851               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
   852        auto
   853   then show ?case
   854     apply (simp add: product_positive_integral_insert[OF insert(1,2) prod])
   855     apply (simp add: insert(2-) * pos borel setprod_ereal_pos positive_integral_multc)
   856     apply (subst positive_integral_cmult)
   857     apply (auto simp add: pos borel insert(2-) setprod_ereal_pos positive_integral_positive)
   858     done
   859 qed (simp add: space_PiM)
   860 
   861 lemma (in product_sigma_finite) product_integral_singleton:
   862   assumes f: "f \<in> borel_measurable (M i)"
   863   shows "(\<integral>x. f (x i) \<partial>Pi\<^isub>M {i} M) = integral\<^isup>L (M i) f"
   864 proof -
   865   interpret I: finite_product_sigma_finite M "{i}" by default simp
   866   have *: "(\<lambda>x. ereal (f x)) \<in> borel_measurable (M i)"
   867     "(\<lambda>x. ereal (- f x)) \<in> borel_measurable (M i)"
   868     using assms by auto
   869   show ?thesis
   870     unfolding lebesgue_integral_def *[THEN product_positive_integral_singleton] ..
   871 qed
   872 lemma (in product_sigma_finite) distr_component:
   873   "distr (M i) (Pi\<^isub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^isub>M {i} M" (is "?D = ?P")
   874 proof (intro measure_eqI[symmetric])
   875   interpret I: finite_product_sigma_finite M "{i}" by default simp
   876 
   877   have eq: "\<And>x. x \<in> extensional {i} \<Longrightarrow> (\<lambda>j\<in>{i}. x i) = x"
   878     by (auto simp: extensional_def restrict_def)
   879 
   880   fix A assume A: "A \<in> sets ?P"
   881   then have "emeasure ?P A = (\<integral>\<^isup>+x. indicator A x \<partial>?P)" 
   882     by simp
   883   also have "\<dots> = (\<integral>\<^isup>+x. indicator ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i)) (x i) \<partial>PiM {i} M)" 
   884     by (intro positive_integral_cong) (auto simp: space_PiM indicator_def PiE_def eq)
   885   also have "\<dots> = emeasure ?D A"
   886     using A by (simp add: product_positive_integral_singleton emeasure_distr)
   887   finally show "emeasure (Pi\<^isub>M {i} M) A = emeasure ?D A" .
   888 qed simp
   889 
   890 lemma (in product_sigma_finite) product_integral_fold:
   891   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   892   and f: "integrable (Pi\<^isub>M (I \<union> J) M) f"
   893   shows "integral\<^isup>L (Pi\<^isub>M (I \<union> J) M) f = (\<integral>x. (\<integral>y. f (merge I J (x, y)) \<partial>Pi\<^isub>M J M) \<partial>Pi\<^isub>M I M)"
   894 proof -
   895   interpret I: finite_product_sigma_finite M I by default fact
   896   interpret J: finite_product_sigma_finite M J by default fact
   897   have "finite (I \<union> J)" using fin by auto
   898   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   899   interpret P: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" by default
   900   let ?M = "merge I J"
   901   let ?f = "\<lambda>x. f (?M x)"
   902   from f have f_borel: "f \<in> borel_measurable (Pi\<^isub>M (I \<union> J) M)"
   903     by auto
   904   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M)"
   905     using measurable_comp[OF measurable_merge f_borel] by (simp add: comp_def)
   906   have f_int: "integrable (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) ?f"
   907     by (rule integrable_distr[OF measurable_merge]) (simp add: distr_merge[OF IJ fin] f)
   908   show ?thesis
   909     apply (subst distr_merge[symmetric, OF IJ fin])
   910     apply (subst integral_distr[OF measurable_merge f_borel])
   911     apply (subst P.integrable_fst_measurable(2)[symmetric, OF f_int])
   912     apply simp
   913     done
   914 qed
   915 
   916 lemma (in product_sigma_finite)
   917   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^isub>M (I \<union> J) M)"
   918   shows emeasure_fold_integral:
   919     "emeasure (Pi\<^isub>M (I \<union> J) M) A = (\<integral>\<^isup>+x. emeasure (Pi\<^isub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^isub>M J M)) \<partial>Pi\<^isub>M I M)" (is ?I)
   920     and emeasure_fold_measurable:
   921     "(\<lambda>x. emeasure (Pi\<^isub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^isub>M J M))) \<in> borel_measurable (Pi\<^isub>M I M)" (is ?B)
   922 proof -
   923   interpret I: finite_product_sigma_finite M I by default fact
   924   interpret J: finite_product_sigma_finite M J by default fact
   925   interpret IJ: pair_sigma_finite "Pi\<^isub>M I M" "Pi\<^isub>M J M" ..
   926   have merge: "merge I J -` A \<inter> space (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M) \<in> sets (Pi\<^isub>M I M \<Otimes>\<^isub>M Pi\<^isub>M J M)"
   927     by (intro measurable_sets[OF _ A] measurable_merge assms)
   928 
   929   show ?I
   930     apply (subst distr_merge[symmetric, OF IJ])
   931     apply (subst emeasure_distr[OF measurable_merge A])
   932     apply (subst J.emeasure_pair_measure_alt[OF merge])
   933     apply (auto intro!: positive_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
   934     done
   935 
   936   show ?B
   937     using IJ.measurable_emeasure_Pair1[OF merge]
   938     by (simp add: vimage_compose[symmetric] comp_def space_pair_measure cong: measurable_cong)
   939 qed
   940 
   941 lemma (in product_sigma_finite) product_integral_insert:
   942   assumes I: "finite I" "i \<notin> I"
   943     and f: "integrable (Pi\<^isub>M (insert i I) M) f"
   944   shows "integral\<^isup>L (Pi\<^isub>M (insert i I) M) f = (\<integral>x. (\<integral>y. f (x(i:=y)) \<partial>M i) \<partial>Pi\<^isub>M I M)"
   945 proof -
   946   have "integral\<^isup>L (Pi\<^isub>M (insert i I) M) f = integral\<^isup>L (Pi\<^isub>M (I \<union> {i}) M) f"
   947     by simp
   948   also have "\<dots> = (\<integral>x. (\<integral>y. f (merge I {i} (x,y)) \<partial>Pi\<^isub>M {i} M) \<partial>Pi\<^isub>M I M)"
   949     using f I by (intro product_integral_fold) auto
   950   also have "\<dots> = (\<integral>x. (\<integral>y. f (x(i := y)) \<partial>M i) \<partial>Pi\<^isub>M I M)"
   951   proof (rule integral_cong, subst product_integral_singleton[symmetric])
   952     fix x assume x: "x \<in> space (Pi\<^isub>M I M)"
   953     have f_borel: "f \<in> borel_measurable (Pi\<^isub>M (insert i I) M)"
   954       using f by auto
   955     show "(\<lambda>y. f (x(i := y))) \<in> borel_measurable (M i)"
   956       using measurable_comp[OF measurable_component_update f_borel, OF x `i \<notin> I`]
   957       unfolding comp_def .
   958     from x I show "(\<integral> y. f (merge I {i} (x,y)) \<partial>Pi\<^isub>M {i} M) = (\<integral> xa. f (x(i := xa i)) \<partial>Pi\<^isub>M {i} M)"
   959       by (auto intro!: integral_cong arg_cong[where f=f] simp: merge_def space_PiM extensional_def PiE_def)
   960   qed
   961   finally show ?thesis .
   962 qed
   963 
   964 lemma (in product_sigma_finite) product_integrable_setprod:
   965   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> real"
   966   assumes [simp]: "finite I" and integrable: "\<And>i. i \<in> I \<Longrightarrow> integrable (M i) (f i)"
   967   shows "integrable (Pi\<^isub>M I M) (\<lambda>x. (\<Prod>i\<in>I. f i (x i)))" (is "integrable _ ?f")
   968 proof -
   969   interpret finite_product_sigma_finite M I by default fact
   970   have f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
   971     using integrable unfolding integrable_def by auto
   972   have borel: "?f \<in> borel_measurable (Pi\<^isub>M I M)"
   973     using measurable_comp[OF measurable_component_singleton[of _ I M] f] by (auto simp: comp_def)
   974   moreover have "integrable (Pi\<^isub>M I M) (\<lambda>x. \<bar>\<Prod>i\<in>I. f i (x i)\<bar>)"
   975   proof (unfold integrable_def, intro conjI)
   976     show "(\<lambda>x. abs (?f x)) \<in> borel_measurable (Pi\<^isub>M I M)"
   977       using borel by auto
   978     have "(\<integral>\<^isup>+x. ereal (abs (?f x)) \<partial>Pi\<^isub>M I M) = (\<integral>\<^isup>+x. (\<Prod>i\<in>I. ereal (abs (f i (x i)))) \<partial>Pi\<^isub>M I M)"
   979       by (simp add: setprod_ereal abs_setprod)
   980     also have "\<dots> = (\<Prod>i\<in>I. (\<integral>\<^isup>+x. ereal (abs (f i x)) \<partial>M i))"
   981       using f by (subst product_positive_integral_setprod) auto
   982     also have "\<dots> < \<infinity>"
   983       using integrable[THEN integrable_abs]
   984       by (simp add: setprod_PInf integrable_def positive_integral_positive)
   985     finally show "(\<integral>\<^isup>+x. ereal (abs (?f x)) \<partial>(Pi\<^isub>M I M)) \<noteq> \<infinity>" by auto
   986     have "(\<integral>\<^isup>+x. ereal (- abs (?f x)) \<partial>(Pi\<^isub>M I M)) = (\<integral>\<^isup>+x. 0 \<partial>(Pi\<^isub>M I M))"
   987       by (intro positive_integral_cong_pos) auto
   988     then show "(\<integral>\<^isup>+x. ereal (- abs (?f x)) \<partial>(Pi\<^isub>M I M)) \<noteq> \<infinity>" by simp
   989   qed
   990   ultimately show ?thesis
   991     by (rule integrable_abs_iff[THEN iffD1])
   992 qed
   993 
   994 lemma (in product_sigma_finite) product_integral_setprod:
   995   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> real"
   996   assumes "finite I" and integrable: "\<And>i. i \<in> I \<Longrightarrow> integrable (M i) (f i)"
   997   shows "(\<integral>x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^isub>M I M) = (\<Prod>i\<in>I. integral\<^isup>L (M i) (f i))"
   998 using assms proof induct
   999   case empty
  1000   interpret finite_measure "Pi\<^isub>M {} M"
  1001     by rule (simp add: space_PiM)
  1002   show ?case by (simp add: space_PiM measure_def)
  1003 next
  1004   case (insert i I)
  1005   then have iI: "finite (insert i I)" by auto
  1006   then have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow>
  1007     integrable (Pi\<^isub>M J M) (\<lambda>x. (\<Prod>i\<in>J. f i (x i)))"
  1008     by (intro product_integrable_setprod insert(4)) (auto intro: finite_subset)
  1009   interpret I: finite_product_sigma_finite M I by default fact
  1010   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
  1011     using `i \<notin> I` by (auto intro!: setprod_cong)
  1012   show ?case
  1013     unfolding product_integral_insert[OF insert(1,2) prod[OF subset_refl]]
  1014     by (simp add: * insert integral_multc integral_cmult[OF prod] subset_insertI)
  1015 qed
  1016 
  1017 lemma sets_Collect_single:
  1018   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^isub>M I M). x i \<in> A } \<in> sets (Pi\<^isub>M I M)"
  1019   by simp
  1020 
  1021 lemma sigma_prod_algebra_sigma_eq_infinite:
  1022   fixes E :: "'i \<Rightarrow> 'a set set"
  1023   assumes S_union: "\<And>i. i \<in> I \<Longrightarrow> (\<Union>j. S i j) = space (M i)"
  1024     and S_in_E: "\<And>i. i \<in> I \<Longrightarrow> range (S i) \<subseteq> E i"
  1025   assumes E_closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M i))"
  1026     and E_generates: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sigma_sets (space (M i)) (E i)"
  1027   defines "P == {{f\<in>\<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> E i}"
  1028   shows "sets (PiM I M) = sigma_sets (space (PiM I M)) P"
  1029 proof
  1030   let ?P = "sigma (space (Pi\<^isub>M I M)) P"
  1031   have P_closed: "P \<subseteq> Pow (space (Pi\<^isub>M I M))"
  1032     using E_closed by (auto simp: space_PiM P_def subset_eq)
  1033   then have space_P: "space ?P = (\<Pi>\<^isub>E i\<in>I. space (M i))"
  1034     by (simp add: space_PiM)
  1035   have "sets (PiM I M) =
  1036       sigma_sets (space ?P) {{f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
  1037     using sets_PiM_single[of I M] by (simp add: space_P)
  1038   also have "\<dots> \<subseteq> sets (sigma (space (PiM I M)) P)"
  1039   proof (safe intro!: sigma_sets_subset)
  1040     fix i A assume "i \<in> I" and A: "A \<in> sets (M i)"
  1041     then have "(\<lambda>x. x i) \<in> measurable ?P (sigma (space (M i)) (E i))"
  1042       apply (subst measurable_iff_measure_of)
  1043       apply (simp_all add: P_closed)
  1044       using E_closed
  1045       apply (force simp: subset_eq space_PiM)
  1046       apply (force simp: subset_eq space_PiM)
  1047       apply (auto simp: P_def intro!: sigma_sets.Basic exI[of _ i])
  1048       apply (rule_tac x=Aa in exI)
  1049       apply (auto simp: space_PiM)
  1050       done
  1051     from measurable_sets[OF this, of A] A `i \<in> I` E_closed
  1052     have "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1053       by (simp add: E_generates)
  1054     also have "(\<lambda>x. x i) -` A \<inter> space ?P = {f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A}"
  1055       using P_closed by (auto simp: space_PiM)
  1056     finally show "\<dots> \<in> sets ?P" .
  1057   qed
  1058   finally show "sets (PiM I M) \<subseteq> sigma_sets (space (PiM I M)) P"
  1059     by (simp add: P_closed)
  1060   show "sigma_sets (space (PiM I M)) P \<subseteq> sets (PiM I M)"
  1061     unfolding P_def space_PiM[symmetric]
  1062     by (intro sigma_sets_subset) (auto simp: E_generates sets_Collect_single)
  1063 qed
  1064 
  1065 lemma sigma_prod_algebra_sigma_eq:
  1066   fixes E :: "'i \<Rightarrow> 'a set set" and S :: "'i \<Rightarrow> nat \<Rightarrow> 'a set"
  1067   assumes "finite I"
  1068   assumes S_union: "\<And>i. i \<in> I \<Longrightarrow> (\<Union>j. S i j) = space (M i)"
  1069     and S_in_E: "\<And>i. i \<in> I \<Longrightarrow> range (S i) \<subseteq> E i"
  1070   assumes E_closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M i))"
  1071     and E_generates: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sigma_sets (space (M i)) (E i)"
  1072   defines "P == { Pi\<^isub>E I F | F. \<forall>i\<in>I. F i \<in> E i }"
  1073   shows "sets (PiM I M) = sigma_sets (space (PiM I M)) P"
  1074 proof
  1075   let ?P = "sigma (space (Pi\<^isub>M I M)) P"
  1076   from `finite I`[THEN ex_bij_betw_finite_nat] guess T ..
  1077   then have T: "\<And>i. i \<in> I \<Longrightarrow> T i < card I" "\<And>i. i\<in>I \<Longrightarrow> the_inv_into I T (T i) = i"
  1078     by (auto simp add: bij_betw_def set_eq_iff image_iff the_inv_into_f_f)
  1079   have P_closed: "P \<subseteq> Pow (space (Pi\<^isub>M I M))"
  1080     using E_closed by (auto simp: space_PiM P_def subset_eq)
  1081   then have space_P: "space ?P = (\<Pi>\<^isub>E i\<in>I. space (M i))"
  1082     by (simp add: space_PiM)
  1083   have "sets (PiM I M) =
  1084       sigma_sets (space ?P) {{f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
  1085     using sets_PiM_single[of I M] by (simp add: space_P)
  1086   also have "\<dots> \<subseteq> sets (sigma (space (PiM I M)) P)"
  1087   proof (safe intro!: sigma_sets_subset)
  1088     fix i A assume "i \<in> I" and A: "A \<in> sets (M i)"
  1089     have "(\<lambda>x. x i) \<in> measurable ?P (sigma (space (M i)) (E i))"
  1090     proof (subst measurable_iff_measure_of)
  1091       show "E i \<subseteq> Pow (space (M i))" using `i \<in> I` by fact
  1092       from space_P `i \<in> I` show "(\<lambda>x. x i) \<in> space ?P \<rightarrow> space (M i)" by auto
  1093       show "\<forall>A\<in>E i. (\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1094       proof
  1095         fix A assume A: "A \<in> E i"
  1096         then have "(\<lambda>x. x i) -` A \<inter> space ?P = (\<Pi>\<^isub>E j\<in>I. if i = j then A else space (M j))"
  1097           using E_closed `i \<in> I` by (auto simp: space_P subset_eq split: split_if_asm)
  1098         also have "\<dots> = (\<Pi>\<^isub>E j\<in>I. \<Union>n. if i = j then A else S j n)"
  1099           by (intro PiE_cong) (simp add: S_union)
  1100         also have "\<dots> = (\<Union>xs\<in>{xs. length xs = card I}. \<Pi>\<^isub>E j\<in>I. if i = j then A else S j (xs ! T j))"
  1101           using T
  1102           apply (auto simp: PiE_iff bchoice_iff)
  1103           apply (rule_tac x="map (\<lambda>n. f (the_inv_into I T n)) [0..<card I]" in exI)
  1104           apply (auto simp: bij_betw_def)
  1105           done
  1106         also have "\<dots> \<in> sets ?P"
  1107         proof (safe intro!: countable_UN)
  1108           fix xs show "(\<Pi>\<^isub>E j\<in>I. if i = j then A else S j (xs ! T j)) \<in> sets ?P"
  1109             using A S_in_E
  1110             by (simp add: P_closed)
  1111                (auto simp: P_def subset_eq intro!: exI[of _ "\<lambda>j. if i = j then A else S j (xs ! T j)"])
  1112         qed
  1113         finally show "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1114           using P_closed by simp
  1115       qed
  1116     qed
  1117     from measurable_sets[OF this, of A] A `i \<in> I` E_closed
  1118     have "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1119       by (simp add: E_generates)
  1120     also have "(\<lambda>x. x i) -` A \<inter> space ?P = {f \<in> \<Pi>\<^isub>E i\<in>I. space (M i). f i \<in> A}"
  1121       using P_closed by (auto simp: space_PiM)
  1122     finally show "\<dots> \<in> sets ?P" .
  1123   qed
  1124   finally show "sets (PiM I M) \<subseteq> sigma_sets (space (PiM I M)) P"
  1125     by (simp add: P_closed)
  1126   show "sigma_sets (space (PiM I M)) P \<subseteq> sets (PiM I M)"
  1127     using `finite I`
  1128     by (auto intro!: sigma_sets_subset sets_PiM_I_finite simp: E_generates P_def)
  1129 qed
  1130 
  1131 lemma pair_measure_eq_distr_PiM:
  1132   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1133   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1134   shows "(M1 \<Otimes>\<^isub>M M2) = distr (Pi\<^isub>M UNIV (bool_case M1 M2)) (M1 \<Otimes>\<^isub>M M2) (\<lambda>x. (x True, x False))"
  1135     (is "?P = ?D")
  1136 proof (rule pair_measure_eqI[OF assms])
  1137   interpret B: product_sigma_finite "bool_case M1 M2"
  1138     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1139   let ?B = "Pi\<^isub>M UNIV (bool_case M1 M2)"
  1140 
  1141   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1142     by auto
  1143   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1144   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (bool_case M1 M2 i) (bool_case A B i))"
  1145     by (simp add: UNIV_bool ac_simps)
  1146   also have "\<dots> = emeasure ?B (Pi\<^isub>E UNIV (bool_case A B))"
  1147     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1148   also have "Pi\<^isub>E UNIV (bool_case A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1149     using A[THEN sets_into_space] B[THEN sets_into_space]
  1150     by (auto simp: PiE_iff all_bool_eq space_PiM split: bool.split)
  1151   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1152     using A B
  1153       measurable_component_singleton[of True UNIV "bool_case M1 M2"]
  1154       measurable_component_singleton[of False UNIV "bool_case M1 M2"]
  1155     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1156 qed simp
  1157 
  1158 end