src/HOL/Analysis/Complex_Analysis_Basics.thy
author paulson <lp15@cam.ac.uk>
Sat May 26 22:11:55 2018 +0100 (12 months ago)
changeset 68296 69d680e94961
parent 68255 009f783d1bac
child 68721 53ad5c01be3f
permissions -rw-r--r--
tidying and reorganisation around Cauchy Integral Theorem
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((( * ) c) has_derivative (( * ) c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_ident])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_field:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "( * ) f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    31 
    32 lemma fact_cancel:
    33   fixes c :: "'a::real_field"
    34   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    35   using of_nat_neq_0 by force
    36 
    37 lemma bilinear_times:
    38   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    39   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    40 
    41 lemma linear_cnj: "linear cnj"
    42   using bounded_linear.linear[OF bounded_linear_cnj] .
    43 
    44 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = ( * ) 0"
    45   by auto
    46 
    47 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = ( * ) 1"
    48   by auto
    49 
    50 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    51   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    52   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
    53   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
    54 
    55 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
    56   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    57   assumes "uniformly_continuous_on s f"
    58     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
    59 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
    60 
    61 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
    62   by (rule continuous_norm [OF continuous_ident])
    63 
    64 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
    65   by (intro continuous_on_id continuous_on_norm)
    66 
    67 subsection\<open>DERIV stuff\<close>
    68 
    69 lemma DERIV_zero_connected_constant:
    70   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
    71   assumes "connected S"
    72       and "open S"
    73       and "finite K"
    74       and "continuous_on S f"
    75       and "\<forall>x\<in>(S - K). DERIV f x :> 0"
    76     obtains c where "\<And>x. x \<in> S \<Longrightarrow> f(x) = c"
    77 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
    78 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
    79 
    80 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
    81 
    82 lemma DERIV_zero_unique:
    83   assumes "convex S"
    84       and d0: "\<And>x. x\<in>S \<Longrightarrow> (f has_field_derivative 0) (at x within S)"
    85       and "a \<in> S"
    86       and "x \<in> S"
    87     shows "f x = f a"
    88   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
    89      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
    90 
    91 lemma DERIV_zero_connected_unique:
    92   assumes "connected S"
    93       and "open S"
    94       and d0: "\<And>x. x\<in>S \<Longrightarrow> DERIV f x :> 0"
    95       and "a \<in> S"
    96       and "x \<in> S"
    97     shows "f x = f a"
    98     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
    99        (metis has_field_derivative_def lambda_zero d0)
   100 
   101 lemma DERIV_transform_within:
   102   assumes "(f has_field_derivative f') (at a within S)"
   103       and "0 < d" "a \<in> S"
   104       and "\<And>x. x\<in>S \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   105     shows "(g has_field_derivative f') (at a within S)"
   106   using assms unfolding has_field_derivative_def
   107   by (blast intro: has_derivative_transform_within)
   108 
   109 lemma DERIV_transform_within_open:
   110   assumes "DERIV f a :> f'"
   111       and "open S" "a \<in> S"
   112       and "\<And>x. x\<in>S \<Longrightarrow> f x = g x"
   113     shows "DERIV g a :> f'"
   114   using assms unfolding has_field_derivative_def
   115 by (metis has_derivative_transform_within_open)
   116 
   117 lemma DERIV_transform_at:
   118   assumes "DERIV f a :> f'"
   119       and "0 < d"
   120       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   121     shows "DERIV g a :> f'"
   122   by (blast intro: assms DERIV_transform_within)
   123 
   124 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   125 lemma DERIV_zero_UNIV_unique:
   126   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   127   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   128 
   129 subsection \<open>Some limit theorems about real part of real series etc\<close>
   130 
   131 (*MOVE? But not to Finite_Cartesian_Product*)
   132 lemma sums_vec_nth :
   133   assumes "f sums a"
   134   shows "(\<lambda>x. f x $ i) sums a $ i"
   135 using assms unfolding sums_def
   136 by (auto dest: tendsto_vec_nth [where i=i])
   137 
   138 lemma summable_vec_nth :
   139   assumes "summable f"
   140   shows "summable (\<lambda>x. f x $ i)"
   141 using assms unfolding summable_def
   142 by (blast intro: sums_vec_nth)
   143 
   144 subsection \<open>Complex number lemmas\<close>
   145 
   146 lemma
   147   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   148     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   149     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   150     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   151     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   152     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   153     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   154     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   155     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   156     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   157   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   158             continuous_on_Im continuous_on_id continuous_on_const)+
   159 
   160 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   161 proof -
   162   have "(\<real> :: complex set) = {z. Im z = 0}"
   163     by (auto simp: complex_is_Real_iff)
   164   then show ?thesis
   165     by (metis closed_halfspace_Im_eq)
   166 qed
   167 
   168 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   169   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   170 
   171 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   172 proof -
   173   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   174     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   175   then show ?thesis
   176     by (metis closed_Real_halfspace_Re_le)
   177 qed
   178 
   179 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   180   using closed_halfspace_Re_ge
   181   by (simp add: closed_Int closed_complex_Reals)
   182 
   183 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   184 proof -
   185   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   186     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   187   then show ?thesis
   188     by (metis closed_Real_halfspace_Re_ge)
   189 qed
   190 
   191 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   192 proof -
   193   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   194     by auto
   195   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   196     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   197 qed
   198 
   199 lemma real_lim:
   200   fixes l::complex
   201   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   202   shows  "l \<in> \<real>"
   203 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   204   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   205     using assms(3, 4) by (auto intro: eventually_mono)
   206 qed
   207 
   208 lemma real_lim_sequentially:
   209   fixes l::complex
   210   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   211 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   212 
   213 lemma real_series:
   214   fixes l::complex
   215   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   216 unfolding sums_def
   217 by (metis real_lim_sequentially sum_in_Reals)
   218 
   219 lemma Lim_null_comparison_Re:
   220   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   221   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   222 
   223 subsection\<open>Holomorphic functions\<close>
   224 
   225 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   226            (infixl "(holomorphic'_on)" 50)
   227   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   228 
   229 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   230 
   231 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   232   by (simp add: holomorphic_on_def)
   233 
   234 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   235   by (simp add: holomorphic_on_def)
   236 
   237 lemma holomorphic_on_imp_differentiable_on:
   238     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   239   unfolding holomorphic_on_def differentiable_on_def
   240   by (simp add: field_differentiable_imp_differentiable)
   241 
   242 lemma holomorphic_on_imp_differentiable_at:
   243    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   244 using at_within_open holomorphic_on_def by fastforce
   245 
   246 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   247   by (simp add: holomorphic_on_def)
   248 
   249 lemma holomorphic_on_open:
   250     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   251   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   252 
   253 lemma holomorphic_on_imp_continuous_on:
   254     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   255   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   256 
   257 lemma holomorphic_on_subset [elim]:
   258     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   259   unfolding holomorphic_on_def
   260   by (metis field_differentiable_within_subset subsetD)
   261 
   262 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   263   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   264 
   265 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   266   by (metis holomorphic_transform)
   267 
   268 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(( * ) c) holomorphic_on s"
   269   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   270 
   271 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   272   unfolding holomorphic_on_def by (metis field_differentiable_const)
   273 
   274 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   275   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   276 
   277 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   278   unfolding id_def by (rule holomorphic_on_ident)
   279 
   280 lemma holomorphic_on_compose:
   281   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   282   using field_differentiable_compose_within[of f _ s g]
   283   by (auto simp: holomorphic_on_def)
   284 
   285 lemma holomorphic_on_compose_gen:
   286   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   287   by (metis holomorphic_on_compose holomorphic_on_subset)
   288 
   289 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   290   by (metis field_differentiable_minus holomorphic_on_def)
   291 
   292 lemma holomorphic_on_add [holomorphic_intros]:
   293   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   294   unfolding holomorphic_on_def by (metis field_differentiable_add)
   295 
   296 lemma holomorphic_on_diff [holomorphic_intros]:
   297   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   298   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   299 
   300 lemma holomorphic_on_mult [holomorphic_intros]:
   301   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   302   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   303 
   304 lemma holomorphic_on_inverse [holomorphic_intros]:
   305   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   306   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   307 
   308 lemma holomorphic_on_divide [holomorphic_intros]:
   309   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   310   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   311 
   312 lemma holomorphic_on_power [holomorphic_intros]:
   313   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   314   unfolding holomorphic_on_def by (metis field_differentiable_power)
   315 
   316 lemma holomorphic_on_sum [holomorphic_intros]:
   317   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   318   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   319 
   320 lemma holomorphic_on_prod [holomorphic_intros]:
   321   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. prod (\<lambda>i. f i x) I) holomorphic_on s"
   322   by (induction I rule: infinite_finite_induct) (auto intro: holomorphic_intros)
   323 
   324 lemma holomorphic_pochhammer [holomorphic_intros]:
   325   "f holomorphic_on A \<Longrightarrow> (\<lambda>s. pochhammer (f s) n) holomorphic_on A"
   326   by (induction n) (auto intro!: holomorphic_intros simp: pochhammer_Suc)
   327 
   328 lemma holomorphic_on_scaleR [holomorphic_intros]:
   329   "f holomorphic_on A \<Longrightarrow> (\<lambda>x. c *\<^sub>R f x) holomorphic_on A"
   330   by (auto simp: scaleR_conv_of_real intro!: holomorphic_intros)
   331 
   332 lemma holomorphic_on_Un [holomorphic_intros]:
   333   assumes "f holomorphic_on A" "f holomorphic_on B" "open A" "open B"
   334   shows   "f holomorphic_on (A \<union> B)"
   335   using assms by (auto simp: holomorphic_on_def  at_within_open[of _ A]
   336                              at_within_open[of _ B]  at_within_open[of _ "A \<union> B"] open_Un)
   337 
   338 lemma holomorphic_on_If_Un [holomorphic_intros]:
   339   assumes "f holomorphic_on A" "g holomorphic_on B" "open A" "open B"
   340   assumes "\<And>z. z \<in> A \<Longrightarrow> z \<in> B \<Longrightarrow> f z = g z"
   341   shows   "(\<lambda>z. if z \<in> A then f z else g z) holomorphic_on (A \<union> B)" (is "?h holomorphic_on _")
   342 proof (intro holomorphic_on_Un)
   343   note \<open>f holomorphic_on A\<close>
   344   also have "f holomorphic_on A \<longleftrightarrow> ?h holomorphic_on A"
   345     by (intro holomorphic_cong) auto
   346   finally show \<dots> .
   347 next
   348   note \<open>g holomorphic_on B\<close>
   349   also have "g holomorphic_on B \<longleftrightarrow> ?h holomorphic_on B"
   350     using assms by (intro holomorphic_cong) auto
   351   finally show \<dots> .
   352 qed (insert assms, auto)
   353 
   354 lemma leibniz_rule_holomorphic:
   355   fixes f::"complex \<Rightarrow> 'b::euclidean_space \<Rightarrow> complex"
   356   assumes "\<And>x t. x \<in> U \<Longrightarrow> t \<in> cbox a b \<Longrightarrow> ((\<lambda>x. f x t) has_field_derivative fx x t) (at x within U)"
   357   assumes "\<And>x. x \<in> U \<Longrightarrow> (f x) integrable_on cbox a b"
   358   assumes "continuous_on (U \<times> (cbox a b)) (\<lambda>(x, t). fx x t)"
   359   assumes "convex U"
   360   shows "(\<lambda>x. integral (cbox a b) (f x)) holomorphic_on U"
   361   using leibniz_rule_field_differentiable[OF assms(1-3) _ assms(4)]
   362   by (auto simp: holomorphic_on_def)
   363 
   364 lemma DERIV_deriv_iff_field_differentiable:
   365   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   366   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   367 
   368 lemma holomorphic_derivI:
   369      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   370       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   371 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   372 
   373 lemma complex_derivative_chain:
   374   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   375     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   376   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   377 
   378 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   379   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   380 
   381 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   382   by (metis DERIV_imp_deriv DERIV_ident)
   383 
   384 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   385   by (simp add: id_def)
   386 
   387 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   388   by (metis DERIV_imp_deriv DERIV_const)
   389 
   390 lemma deriv_add [simp]:
   391   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   392    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   393   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   394   by (auto intro!: DERIV_imp_deriv derivative_intros)
   395 
   396 lemma deriv_diff [simp]:
   397   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   398    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   399   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   400   by (auto intro!: DERIV_imp_deriv derivative_intros)
   401 
   402 lemma deriv_mult [simp]:
   403   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   404    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   405   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   406   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   407 
   408 lemma deriv_cmult:
   409   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   410   by simp
   411 
   412 lemma deriv_cmult_right:
   413   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   414   by simp
   415 
   416 lemma deriv_inverse [simp]:
   417   "\<lbrakk>f field_differentiable at z; f z \<noteq> 0\<rbrakk>
   418    \<Longrightarrow> deriv (\<lambda>w. inverse (f w)) z = - deriv f z / f z ^ 2"
   419   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   420   by (safe intro!: DERIV_imp_deriv derivative_eq_intros) (auto simp: divide_simps power2_eq_square)
   421 
   422 lemma deriv_divide [simp]:
   423   "\<lbrakk>f field_differentiable at z; g field_differentiable at z; g z \<noteq> 0\<rbrakk>
   424    \<Longrightarrow> deriv (\<lambda>w. f w / g w) z = (deriv f z * g z - f z * deriv g z) / g z ^ 2"
   425   by (simp add: field_class.field_divide_inverse field_differentiable_inverse)
   426      (simp add: divide_simps power2_eq_square)
   427 
   428 lemma deriv_cdivide_right:
   429   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   430   by (simp add: field_class.field_divide_inverse)
   431 
   432 lemma complex_derivative_transform_within_open:
   433   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   434    \<Longrightarrow> deriv f z = deriv g z"
   435   unfolding holomorphic_on_def
   436   by (rule DERIV_imp_deriv)
   437      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   438 
   439 lemma deriv_compose_linear:
   440   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   441 apply (rule DERIV_imp_deriv)
   442   unfolding DERIV_deriv_iff_field_differentiable [symmetric]
   443   by (metis (full_types) DERIV_chain2 DERIV_cmult_Id mult.commute)
   444 
   445 
   446 lemma nonzero_deriv_nonconstant:
   447   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   448     shows "\<not> f constant_on S"
   449 unfolding constant_on_def
   450 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   451 
   452 lemma holomorphic_nonconstant:
   453   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   454     shows "\<not> f constant_on S"
   455   by (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   456     (use assms in \<open>auto simp: holomorphic_derivI\<close>)
   457 
   458 subsection\<open>Caratheodory characterization\<close>
   459 
   460 lemma field_differentiable_caratheodory_at:
   461   "f field_differentiable (at z) \<longleftrightarrow>
   462          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   463   using CARAT_DERIV [of f]
   464   by (simp add: field_differentiable_def has_field_derivative_def)
   465 
   466 lemma field_differentiable_caratheodory_within:
   467   "f field_differentiable (at z within s) \<longleftrightarrow>
   468          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   469   using DERIV_caratheodory_within [of f]
   470   by (simp add: field_differentiable_def has_field_derivative_def)
   471 
   472 subsection\<open>Analyticity on a set\<close>
   473 
   474 definition analytic_on (infixl "(analytic'_on)" 50)
   475   where "f analytic_on S \<equiv> \<forall>x \<in> S. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   476 
   477 named_theorems analytic_intros "introduction rules for proving analyticity"
   478 
   479 lemma analytic_imp_holomorphic: "f analytic_on S \<Longrightarrow> f holomorphic_on S"
   480   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   481      (metis centre_in_ball field_differentiable_at_within)
   482 
   483 lemma analytic_on_open: "open S \<Longrightarrow> f analytic_on S \<longleftrightarrow> f holomorphic_on S"
   484 apply (auto simp: analytic_imp_holomorphic)
   485 apply (auto simp: analytic_on_def holomorphic_on_def)
   486 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   487 
   488 lemma analytic_on_imp_differentiable_at:
   489   "f analytic_on S \<Longrightarrow> x \<in> S \<Longrightarrow> f field_differentiable (at x)"
   490  apply (auto simp: analytic_on_def holomorphic_on_def)
   491 by (metis open_ball centre_in_ball field_differentiable_within_open)
   492 
   493 lemma analytic_on_subset: "f analytic_on S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> f analytic_on T"
   494   by (auto simp: analytic_on_def)
   495 
   496 lemma analytic_on_Un: "f analytic_on (S \<union> T) \<longleftrightarrow> f analytic_on S \<and> f analytic_on T"
   497   by (auto simp: analytic_on_def)
   498 
   499 lemma analytic_on_Union: "f analytic_on (\<Union>\<T>) \<longleftrightarrow> (\<forall>T \<in> \<T>. f analytic_on T)"
   500   by (auto simp: analytic_on_def)
   501 
   502 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. S i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (S i))"
   503   by (auto simp: analytic_on_def)
   504 
   505 lemma analytic_on_holomorphic:
   506   "f analytic_on S \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f holomorphic_on T)"
   507   (is "?lhs = ?rhs")
   508 proof -
   509   have "?lhs \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T)"
   510   proof safe
   511     assume "f analytic_on S"
   512     then show "\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T"
   513       apply (simp add: analytic_on_def)
   514       apply (rule exI [where x="\<Union>{U. open U \<and> f analytic_on U}"], auto)
   515       apply (metis open_ball analytic_on_open centre_in_ball)
   516       by (metis analytic_on_def)
   517   next
   518     fix T
   519     assume "open T" "S \<subseteq> T" "f analytic_on T"
   520     then show "f analytic_on S"
   521         by (metis analytic_on_subset)
   522   qed
   523   also have "... \<longleftrightarrow> ?rhs"
   524     by (auto simp: analytic_on_open)
   525   finally show ?thesis .
   526 qed
   527 
   528 lemma analytic_on_linear [analytic_intros,simp]: "(( * ) c) analytic_on S"
   529   by (auto simp add: analytic_on_holomorphic)
   530 
   531 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on S"
   532   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   533 
   534 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on S"
   535   by (simp add: analytic_on_def gt_ex)
   536 
   537 lemma analytic_on_id [analytic_intros]: "id analytic_on S"
   538   unfolding id_def by (rule analytic_on_ident)
   539 
   540 lemma analytic_on_compose:
   541   assumes f: "f analytic_on S"
   542       and g: "g analytic_on (f ` S)"
   543     shows "(g o f) analytic_on S"
   544 unfolding analytic_on_def
   545 proof (intro ballI)
   546   fix x
   547   assume x: "x \<in> S"
   548   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   549     by (metis analytic_on_def)
   550   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   551     by (metis analytic_on_def g image_eqI x)
   552   have "isCont f x"
   553     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   554   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   555      by (auto simp: continuous_at_ball)
   556   have "g \<circ> f holomorphic_on ball x (min d e)"
   557     apply (rule holomorphic_on_compose)
   558     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   559     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   560   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   561     by (metis d e min_less_iff_conj)
   562 qed
   563 
   564 lemma analytic_on_compose_gen:
   565   "f analytic_on S \<Longrightarrow> g analytic_on T \<Longrightarrow> (\<And>z. z \<in> S \<Longrightarrow> f z \<in> T)
   566              \<Longrightarrow> g o f analytic_on S"
   567 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   568 
   569 lemma analytic_on_neg [analytic_intros]:
   570   "f analytic_on S \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on S"
   571 by (metis analytic_on_holomorphic holomorphic_on_minus)
   572 
   573 lemma analytic_on_add [analytic_intros]:
   574   assumes f: "f analytic_on S"
   575       and g: "g analytic_on S"
   576     shows "(\<lambda>z. f z + g z) analytic_on S"
   577 unfolding analytic_on_def
   578 proof (intro ballI)
   579   fix z
   580   assume z: "z \<in> S"
   581   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   582     by (metis analytic_on_def)
   583   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   584     by (metis analytic_on_def g z)
   585   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   586     apply (rule holomorphic_on_add)
   587     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   588     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   589   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   590     by (metis e e' min_less_iff_conj)
   591 qed
   592 
   593 lemma analytic_on_diff [analytic_intros]:
   594   assumes f: "f analytic_on S"
   595       and g: "g analytic_on S"
   596     shows "(\<lambda>z. f z - g z) analytic_on S"
   597 unfolding analytic_on_def
   598 proof (intro ballI)
   599   fix z
   600   assume z: "z \<in> S"
   601   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   602     by (metis analytic_on_def)
   603   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   604     by (metis analytic_on_def g z)
   605   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   606     apply (rule holomorphic_on_diff)
   607     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   608     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   609   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   610     by (metis e e' min_less_iff_conj)
   611 qed
   612 
   613 lemma analytic_on_mult [analytic_intros]:
   614   assumes f: "f analytic_on S"
   615       and g: "g analytic_on S"
   616     shows "(\<lambda>z. f z * g z) analytic_on S"
   617 unfolding analytic_on_def
   618 proof (intro ballI)
   619   fix z
   620   assume z: "z \<in> S"
   621   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   622     by (metis analytic_on_def)
   623   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   624     by (metis analytic_on_def g z)
   625   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   626     apply (rule holomorphic_on_mult)
   627     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   628     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   629   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   630     by (metis e e' min_less_iff_conj)
   631 qed
   632 
   633 lemma analytic_on_inverse [analytic_intros]:
   634   assumes f: "f analytic_on S"
   635       and nz: "(\<And>z. z \<in> S \<Longrightarrow> f z \<noteq> 0)"
   636     shows "(\<lambda>z. inverse (f z)) analytic_on S"
   637 unfolding analytic_on_def
   638 proof (intro ballI)
   639   fix z
   640   assume z: "z \<in> S"
   641   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   642     by (metis analytic_on_def)
   643   have "continuous_on (ball z e) f"
   644     by (metis fh holomorphic_on_imp_continuous_on)
   645   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   646     by (metis open_ball centre_in_ball continuous_on_open_avoid e z nz)
   647   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   648     apply (rule holomorphic_on_inverse)
   649     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   650     by (metis nz' mem_ball min_less_iff_conj)
   651   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   652     by (metis e e' min_less_iff_conj)
   653 qed
   654 
   655 lemma analytic_on_divide [analytic_intros]:
   656   assumes f: "f analytic_on S"
   657       and g: "g analytic_on S"
   658       and nz: "(\<And>z. z \<in> S \<Longrightarrow> g z \<noteq> 0)"
   659     shows "(\<lambda>z. f z / g z) analytic_on S"
   660 unfolding divide_inverse
   661 by (metis analytic_on_inverse analytic_on_mult f g nz)
   662 
   663 lemma analytic_on_power [analytic_intros]:
   664   "f analytic_on S \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on S"
   665 by (induct n) (auto simp: analytic_on_mult)
   666 
   667 lemma analytic_on_sum [analytic_intros]:
   668   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on S) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on S"
   669   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   670 
   671 lemma deriv_left_inverse:
   672   assumes "f holomorphic_on S" and "g holomorphic_on T"
   673       and "open S" and "open T"
   674       and "f ` S \<subseteq> T"
   675       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   676       and "w \<in> S"
   677     shows "deriv f w * deriv g (f w) = 1"
   678 proof -
   679   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   680     by (simp add: algebra_simps)
   681   also have "... = deriv (g o f) w"
   682     using assms
   683     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   684   also have "... = deriv id w"
   685   proof (rule complex_derivative_transform_within_open [where s=S])
   686     show "g \<circ> f holomorphic_on S"
   687       by (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   688   qed (use assms in auto)
   689   also have "... = 1"
   690     by simp
   691   finally show ?thesis .
   692 qed
   693 
   694 subsection\<open>analyticity at a point\<close>
   695 
   696 lemma analytic_at_ball:
   697   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   698 by (metis analytic_on_def singleton_iff)
   699 
   700 lemma analytic_at:
   701     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   702 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   703 
   704 lemma analytic_on_analytic_at:
   705     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   706 by (metis analytic_at_ball analytic_on_def)
   707 
   708 lemma analytic_at_two:
   709   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   710    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   711   (is "?lhs = ?rhs")
   712 proof
   713   assume ?lhs
   714   then obtain s t
   715     where st: "open s" "z \<in> s" "f holomorphic_on s"
   716               "open t" "z \<in> t" "g holomorphic_on t"
   717     by (auto simp: analytic_at)
   718   show ?rhs
   719     apply (rule_tac x="s \<inter> t" in exI)
   720     using st
   721     apply (auto simp: Diff_subset holomorphic_on_subset)
   722     done
   723 next
   724   assume ?rhs
   725   then show ?lhs
   726     by (force simp add: analytic_at)
   727 qed
   728 
   729 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   730 
   731 lemma
   732   assumes "f analytic_on {z}" "g analytic_on {z}"
   733   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   734     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   735     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   736            f z * deriv g z + deriv f z * g z"
   737 proof -
   738   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   739     using assms by (metis analytic_at_two)
   740   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   741     apply (rule DERIV_imp_deriv [OF DERIV_add])
   742     using s
   743     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   744     done
   745   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   746     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   747     using s
   748     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   749     done
   750   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   751     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   752     using s
   753     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   754     done
   755 qed
   756 
   757 lemma deriv_cmult_at:
   758   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   759 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   760 
   761 lemma deriv_cmult_right_at:
   762   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   763 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   764 
   765 subsection\<open>Complex differentiation of sequences and series\<close>
   766 
   767 (* TODO: Could probably be simplified using Uniform_Limit *)
   768 lemma has_complex_derivative_sequence:
   769   fixes S :: "complex set"
   770   assumes cvs: "convex S"
   771       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   772       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S \<longrightarrow> norm (f' n x - g' x) \<le> e"
   773       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   774     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   775                        (g has_field_derivative (g' x)) (at x within S)"
   776 proof -
   777   from assms obtain x l where x: "x \<in> S" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   778     by blast
   779   { fix e::real assume e: "e > 0"
   780     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> S \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   781       by (metis conv)
   782     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   783     proof (rule exI [of _ N], clarify)
   784       fix n y h
   785       assume "N \<le> n" "y \<in> S"
   786       then have "cmod (f' n y - g' y) \<le> e"
   787         by (metis N)
   788       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   789         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   790       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   791         by (simp add: norm_mult [symmetric] field_simps)
   792     qed
   793   } note ** = this
   794   show ?thesis
   795     unfolding has_field_derivative_def
   796   proof (rule has_derivative_sequence [OF cvs _ _ x])
   797     show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   798       by (rule tf)
   799   next show "\<And>e. e > 0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   800       unfolding eventually_sequentially by (blast intro: **)
   801   qed (metis has_field_derivative_def df)
   802 qed
   803 
   804 lemma has_complex_derivative_series:
   805   fixes S :: "complex set"
   806   assumes cvs: "convex S"
   807       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   808       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   809                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   810       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) sums l)"
   811     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within S))"
   812 proof -
   813   from assms obtain x l where x: "x \<in> S" and sf: "((\<lambda>n. f n x) sums l)"
   814     by blast
   815   { fix e::real assume e: "e > 0"
   816     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   817             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   818       by (metis conv)
   819     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   820     proof (rule exI [of _ N], clarify)
   821       fix n y h
   822       assume "N \<le> n" "y \<in> S"
   823       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   824         by (metis N)
   825       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   826         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   827       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   828         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   829     qed
   830   } note ** = this
   831   show ?thesis
   832   unfolding has_field_derivative_def
   833   proof (rule has_derivative_series [OF cvs _ _ x])
   834     fix n x
   835     assume "x \<in> S"
   836     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within S)"
   837       by (metis df has_field_derivative_def mult_commute_abs)
   838   next show " ((\<lambda>n. f n x) sums l)"
   839     by (rule sf)
   840   next show "\<And>e. e>0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   841       unfolding eventually_sequentially by (blast intro: **)
   842   qed
   843 qed
   844 
   845 
   846 lemma field_differentiable_series:
   847   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   848   assumes "convex S" "open S"
   849   assumes "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   850   assumes "uniformly_convergent_on S (\<lambda>n x. \<Sum>i<n. f' i x)"
   851   assumes "x0 \<in> S" "summable (\<lambda>n. f n x0)" and x: "x \<in> S"
   852   shows  "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   853 proof -
   854   from assms(4) obtain g' where A: "uniform_limit S (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   855     unfolding uniformly_convergent_on_def by blast
   856   from x and \<open>open S\<close> have S: "at x within S = at x" by (rule at_within_open)
   857   have "\<exists>g. \<forall>x\<in>S. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within S)"
   858     by (intro has_field_derivative_series[of S f f' g' x0] assms A has_field_derivative_at_within)
   859   then obtain g where g: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   860     "\<And>x. x \<in> S \<Longrightarrow> (g has_field_derivative g' x) (at x within S)" by blast
   861   from g(2)[OF x] have g': "(g has_derivative ( * ) (g' x)) (at x)"
   862     by (simp add: has_field_derivative_def S)
   863   have "((\<lambda>x. \<Sum>n. f n x) has_derivative ( * ) (g' x)) (at x)"
   864     by (rule has_derivative_transform_within_open[OF g' \<open>open S\<close> x])
   865        (insert g, auto simp: sums_iff)
   866   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   867     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   868 qed
   869 
   870 subsection\<open>Bound theorem\<close>
   871 
   872 lemma field_differentiable_bound:
   873   fixes S :: "'a::real_normed_field set"
   874   assumes cvs: "convex S"
   875       and df:  "\<And>z. z \<in> S \<Longrightarrow> (f has_field_derivative f' z) (at z within S)"
   876       and dn:  "\<And>z. z \<in> S \<Longrightarrow> norm (f' z) \<le> B"
   877       and "x \<in> S"  "y \<in> S"
   878     shows "norm(f x - f y) \<le> B * norm(x - y)"
   879   apply (rule differentiable_bound [OF cvs])
   880   apply (erule df [unfolded has_field_derivative_def])
   881   apply (rule onorm_le, simp_all add: norm_mult mult_right_mono assms)
   882   done
   883 
   884 subsection\<open>Inverse function theorem for complex derivatives\<close>
   885 
   886 lemma has_field_derivative_inverse_basic:
   887   shows "DERIV f (g y) :> f' \<Longrightarrow>
   888         f' \<noteq> 0 \<Longrightarrow>
   889         continuous (at y) g \<Longrightarrow>
   890         open t \<Longrightarrow>
   891         y \<in> t \<Longrightarrow>
   892         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   893         \<Longrightarrow> DERIV g y :> inverse (f')"
   894   unfolding has_field_derivative_def
   895   apply (rule has_derivative_inverse_basic)
   896   apply (auto simp:  bounded_linear_mult_right)
   897   done
   898 
   899 lemma has_field_derivative_inverse_strong:
   900   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   901   shows "DERIV f x :> f' \<Longrightarrow>
   902          f' \<noteq> 0 \<Longrightarrow>
   903          open S \<Longrightarrow>
   904          x \<in> S \<Longrightarrow>
   905          continuous_on S f \<Longrightarrow>
   906          (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   907          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   908   unfolding has_field_derivative_def
   909   apply (rule has_derivative_inverse_strong [of S x f g ])
   910   by auto
   911 
   912 lemma has_field_derivative_inverse_strong_x:
   913   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   914   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   915           f' \<noteq> 0 \<Longrightarrow>
   916           open S \<Longrightarrow>
   917           continuous_on S f \<Longrightarrow>
   918           g y \<in> S \<Longrightarrow> f(g y) = y \<Longrightarrow>
   919           (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   920           \<Longrightarrow> DERIV g y :> inverse (f')"
   921   unfolding has_field_derivative_def
   922   apply (rule has_derivative_inverse_strong_x [of S g y f])
   923   by auto
   924 
   925 subsection \<open>Taylor on Complex Numbers\<close>
   926 
   927 lemma sum_Suc_reindex:
   928   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   929     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   930 by (induct n) auto
   931 
   932 lemma field_taylor:
   933   assumes S: "convex S"
   934       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
   935       and B: "\<And>x. x \<in> S \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   936       and w: "w \<in> S"
   937       and z: "z \<in> S"
   938     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   939           \<le> B * norm(z - w)^(Suc n) / fact n"
   940 proof -
   941   have wzs: "closed_segment w z \<subseteq> S" using assms
   942     by (metis convex_contains_segment)
   943   { fix u
   944     assume "u \<in> closed_segment w z"
   945     then have "u \<in> S"
   946       by (metis wzs subsetD)
   947     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   948                       f (Suc i) u * (z-u)^i / (fact i)) =
   949               f (Suc n) u * (z-u) ^ n / (fact n)"
   950     proof (induction n)
   951       case 0 show ?case by simp
   952     next
   953       case (Suc n)
   954       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
   955                              f (Suc i) u * (z-u) ^ i / (fact i)) =
   956            f (Suc n) u * (z-u) ^ n / (fact n) +
   957            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
   958            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
   959         using Suc by simp
   960       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
   961       proof -
   962         have "(fact(Suc n)) *
   963              (f(Suc n) u *(z-u) ^ n / (fact n) +
   964                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
   965                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
   966             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
   967             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
   968             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
   969           by (simp add: algebra_simps del: fact_Suc)
   970         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
   971                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   972                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   973           by (simp del: fact_Suc)
   974         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
   975                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   976                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   977           by (simp only: fact_Suc of_nat_mult ac_simps) simp
   978         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
   979           by (simp add: algebra_simps)
   980         finally show ?thesis
   981         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
   982       qed
   983       finally show ?case .
   984     qed
   985     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
   986                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
   987                (at u within S)"
   988       apply (intro derivative_eq_intros)
   989       apply (blast intro: assms \<open>u \<in> S\<close>)
   990       apply (rule refl)+
   991       apply (auto simp: field_simps)
   992       done
   993   } note sum_deriv = this
   994   { fix u
   995     assume u: "u \<in> closed_segment w z"
   996     then have us: "u \<in> S"
   997       by (metis wzs subsetD)
   998     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
   999       by (metis norm_minus_commute order_refl)
  1000     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1001       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1002     also have "... \<le> B * norm (z - w) ^ n"
  1003       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1004     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1005   } note cmod_bound = this
  1006   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1007     by simp
  1008   also have "\<dots> = f 0 z / (fact 0)"
  1009     by (subst sum_zero_power) simp
  1010   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1011                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1012                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1013     by (simp add: norm_minus_commute)
  1014   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1015     apply (rule field_differentiable_bound
  1016       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1017          and S = "closed_segment w z", OF convex_closed_segment])
  1018     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1019                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1020     done
  1021   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1022     by (simp add: algebra_simps norm_minus_commute)
  1023   finally show ?thesis .
  1024 qed
  1025 
  1026 lemma complex_taylor:
  1027   assumes S: "convex S"
  1028       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
  1029       and B: "\<And>x. x \<in> S \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1030       and w: "w \<in> S"
  1031       and z: "z \<in> S"
  1032     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1033           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1034   using assms by (rule field_taylor)
  1035 
  1036 
  1037 text\<open>Something more like the traditional MVT for real components\<close>
  1038 
  1039 lemma complex_mvt_line:
  1040   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1041     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1042 proof -
  1043   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1044     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1045   note assms[unfolded has_field_derivative_def, derivative_intros]
  1046   show ?thesis
  1047     apply (cut_tac mvt_simple
  1048                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1049                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1050     apply auto
  1051     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1052     apply (auto simp: closed_segment_def twz) []
  1053     apply (intro derivative_eq_intros has_derivative_at_withinI, simp_all)
  1054     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1055     apply (force simp: twz closed_segment_def)
  1056     done
  1057 qed
  1058 
  1059 lemma complex_taylor_mvt:
  1060   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1061     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1062             Re (f 0 z) =
  1063             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1064                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1065 proof -
  1066   { fix u
  1067     assume u: "u \<in> closed_segment w z"
  1068     have "(\<Sum>i = 0..n.
  1069                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1070                (fact i)) =
  1071           f (Suc 0) u -
  1072              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1073              (fact (Suc n)) +
  1074              (\<Sum>i = 0..n.
  1075                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1076                  (fact (Suc i)))"
  1077        by (subst sum_Suc_reindex) simp
  1078     also have "... = f (Suc 0) u -
  1079              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1080              (fact (Suc n)) +
  1081              (\<Sum>i = 0..n.
  1082                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1083                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1084       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1085     also have "... = f (Suc 0) u -
  1086              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1087              (fact (Suc n)) +
  1088              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1089       by (subst sum_Suc_diff) auto
  1090     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1091       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1092     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1093                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1094                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1095     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1096                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1097       apply (intro derivative_eq_intros)+
  1098       apply (force intro: u assms)
  1099       apply (rule refl)+
  1100       apply (auto simp: ac_simps)
  1101       done
  1102   }
  1103   then show ?thesis
  1104     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1105                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1106     apply (auto simp add: intro: open_closed_segment)
  1107     done
  1108 qed
  1109 
  1110 
  1111 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1112 
  1113 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1114     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1115   assumes "0 < e"
  1116     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1117 proof (induct n)
  1118   case 0 with assms
  1119   show ?case
  1120     apply (rule_tac x="norm (c 0) / e" in exI)
  1121     apply (auto simp: field_simps)
  1122     done
  1123 next
  1124   case (Suc n)
  1125   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1126     using Suc assms by blast
  1127   show ?case
  1128   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1129     fix z::'a
  1130     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1131     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1132       using assms by (simp add: field_simps)
  1133     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1134       using M [OF z1] by simp
  1135     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1136       by simp
  1137     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1138       by (blast intro: norm_triangle_le elim: )
  1139     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1140       by (simp add: norm_power norm_mult algebra_simps)
  1141     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1142       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1143     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1144       by simp
  1145   qed
  1146 qed
  1147 
  1148 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1149     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1150   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1151     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1152 using kn
  1153 proof (induction n)
  1154   case 0
  1155   then show ?case
  1156     using k  by simp
  1157 next
  1158   case (Suc m)
  1159   let ?even = ?case
  1160   show ?even
  1161   proof (cases "c (Suc m) = 0")
  1162     case True
  1163     then show ?even using Suc k
  1164       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1165   next
  1166     case False
  1167     then obtain M where M:
  1168           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1169       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1170       by auto
  1171     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1172     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1173       fix z::'a
  1174       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1175          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1176       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1177         using False by (simp add: field_simps)
  1178       have nz: "norm z \<le> norm z ^ Suc m"
  1179         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1180       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1181         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1182       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1183             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1184         using M [of z] Suc z1  by auto
  1185       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1186         using nz by (simp add: mult_mono del: power_Suc)
  1187       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1188         using Suc.IH
  1189         apply (auto simp: eventually_at_infinity)
  1190         apply (rule *)
  1191         apply (simp add: field_simps norm_mult norm_power)
  1192         done
  1193     qed
  1194     then show ?even
  1195       by (simp add: eventually_at_infinity)
  1196   qed
  1197 qed
  1198 
  1199 end