src/HOL/IntDiv.thy
 author wenzelm Wed Sep 17 21:27:14 2008 +0200 (2008-09-17) changeset 28263 69eaa97e7e96 parent 28262 aa7ca36d67fd child 28562 4e74209f113e permissions -rw-r--r--
moved global ML bindings to global place;
     1 (*  Title:      HOL/IntDiv.thy

     2     ID:         $Id$

     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory

     4     Copyright   1999  University of Cambridge

     5

     6 *)

     7

     8 header{*The Division Operators div and mod; the Divides Relation dvd*}

     9

    10 theory IntDiv

    11 imports Int Divides FunDef

    12 begin

    13

    14 constdefs

    15   quorem :: "(int*int) * (int*int) => bool"

    16     --{*definition of quotient and remainder*}

    17     [code func]: "quorem == %((a,b), (q,r)).

    18                       a = b*q + r &

    19                       (if 0 < b then 0\<le>r & r<b else b<r & r \<le> 0)"

    20

    21   adjust :: "[int, int*int] => int*int"

    22     --{*for the division algorithm*}

    23     [code func]: "adjust b == %(q,r). if 0 \<le> r-b then (2*q + 1, r-b)

    24                          else (2*q, r)"

    25

    26 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}

    27 function

    28   posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int"

    29 where

    30   "posDivAlg a b =

    31      (if (a<b | b\<le>0) then (0,a)

    32         else adjust b (posDivAlg a (2*b)))"

    33 by auto

    34 termination by (relation "measure (%(a,b). nat(a - b + 1))") auto

    35

    36 text{*algorithm for the case @{text "a<0, b>0"}*}

    37 function

    38   negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int"

    39 where

    40   "negDivAlg a b  =

    41      (if (0\<le>a+b | b\<le>0) then (-1,a+b)

    42       else adjust b (negDivAlg a (2*b)))"

    43 by auto

    44 termination by (relation "measure (%(a,b). nat(- a - b))") auto

    45

    46 text{*algorithm for the general case @{term "b\<noteq>0"}*}

    47 constdefs

    48   negateSnd :: "int*int => int*int"

    49     [code func]: "negateSnd == %(q,r). (q,-r)"

    50

    51 definition

    52   divAlg :: "int \<times> int \<Rightarrow> int \<times> int"

    53     --{*The full division algorithm considers all possible signs for a, b

    54        including the special case @{text "a=0, b<0"} because

    55        @{term negDivAlg} requires @{term "a<0"}.*}

    56 where

    57   "divAlg = (\<lambda>(a, b). (if 0\<le>a then

    58                   if 0\<le>b then posDivAlg a b

    59                   else if a=0 then (0, 0)

    60                        else negateSnd (negDivAlg (-a) (-b))

    61                else

    62                   if 0<b then negDivAlg a b

    63                   else negateSnd (posDivAlg (-a) (-b))))"

    64

    65 instantiation int :: Divides.div

    66 begin

    67

    68 definition

    69   div_def: "a div b = fst (divAlg (a, b))"

    70

    71 definition

    72   mod_def: "a mod b = snd (divAlg (a, b))"

    73

    74 instance ..

    75

    76 end

    77

    78 lemma divAlg_mod_div:

    79   "divAlg (p, q) = (p div q, p mod q)"

    80   by (auto simp add: div_def mod_def)

    81

    82 text{*

    83 Here is the division algorithm in ML:

    84

    85 \begin{verbatim}

    86     fun posDivAlg (a,b) =

    87       if a<b then (0,a)

    88       else let val (q,r) = posDivAlg(a, 2*b)

    89 	       in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)

    90 	   end

    91

    92     fun negDivAlg (a,b) =

    93       if 0\<le>a+b then (~1,a+b)

    94       else let val (q,r) = negDivAlg(a, 2*b)

    95 	       in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)

    96 	   end;

    97

    98     fun negateSnd (q,r:int) = (q,~r);

    99

   100     fun divAlg (a,b) = if 0\<le>a then

   101 			  if b>0 then posDivAlg (a,b)

   102 			   else if a=0 then (0,0)

   103 				else negateSnd (negDivAlg (~a,~b))

   104 		       else

   105 			  if 0<b then negDivAlg (a,b)

   106 			  else        negateSnd (posDivAlg (~a,~b));

   107 \end{verbatim}

   108 *}

   109

   110

   111

   112 subsection{*Uniqueness and Monotonicity of Quotients and Remainders*}

   113

   114 lemma unique_quotient_lemma:

   115      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]

   116       ==> q' \<le> (q::int)"

   117 apply (subgoal_tac "r' + b * (q'-q) \<le> r")

   118  prefer 2 apply (simp add: right_diff_distrib)

   119 apply (subgoal_tac "0 < b * (1 + q - q') ")

   120 apply (erule_tac [2] order_le_less_trans)

   121  prefer 2 apply (simp add: right_diff_distrib right_distrib)

   122 apply (subgoal_tac "b * q' < b * (1 + q) ")

   123  prefer 2 apply (simp add: right_diff_distrib right_distrib)

   124 apply (simp add: mult_less_cancel_left)

   125 done

   126

   127 lemma unique_quotient_lemma_neg:

   128      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]

   129       ==> q \<le> (q'::int)"

   130 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma,

   131     auto)

   132

   133 lemma unique_quotient:

   134      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  b \<noteq> 0 |]

   135       ==> q = q'"

   136 apply (simp add: quorem_def linorder_neq_iff split: split_if_asm)

   137 apply (blast intro: order_antisym

   138              dest: order_eq_refl [THEN unique_quotient_lemma]

   139              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+

   140 done

   141

   142

   143 lemma unique_remainder:

   144      "[| quorem ((a,b), (q,r));  quorem ((a,b), (q',r'));  b \<noteq> 0 |]

   145       ==> r = r'"

   146 apply (subgoal_tac "q = q'")

   147  apply (simp add: quorem_def)

   148 apply (blast intro: unique_quotient)

   149 done

   150

   151

   152 subsection{*Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends*}

   153

   154 text{*And positive divisors*}

   155

   156 lemma adjust_eq [simp]:

   157      "adjust b (q,r) =

   158       (let diff = r-b in

   159 	if 0 \<le> diff then (2*q + 1, diff)

   160                      else (2*q, r))"

   161 by (simp add: Let_def adjust_def)

   162

   163 declare posDivAlg.simps [simp del]

   164

   165 text{*use with a simproc to avoid repeatedly proving the premise*}

   166 lemma posDivAlg_eqn:

   167      "0 < b ==>

   168       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"

   169 by (rule posDivAlg.simps [THEN trans], simp)

   170

   171 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}

   172 theorem posDivAlg_correct:

   173   assumes "0 \<le> a" and "0 < b"

   174   shows "quorem ((a, b), posDivAlg a b)"

   175 using prems apply (induct a b rule: posDivAlg.induct)

   176 apply auto

   177 apply (simp add: quorem_def)

   178 apply (subst posDivAlg_eqn, simp add: right_distrib)

   179 apply (case_tac "a < b")

   180 apply simp_all

   181 apply (erule splitE)

   182 apply (auto simp add: right_distrib Let_def)

   183 done

   184

   185

   186 subsection{*Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends*}

   187

   188 text{*And positive divisors*}

   189

   190 declare negDivAlg.simps [simp del]

   191

   192 text{*use with a simproc to avoid repeatedly proving the premise*}

   193 lemma negDivAlg_eqn:

   194      "0 < b ==>

   195       negDivAlg a b =

   196        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"

   197 by (rule negDivAlg.simps [THEN trans], simp)

   198

   199 (*Correctness of negDivAlg: it computes quotients correctly

   200   It doesn't work if a=0 because the 0/b equals 0, not -1*)

   201 lemma negDivAlg_correct:

   202   assumes "a < 0" and "b > 0"

   203   shows "quorem ((a, b), negDivAlg a b)"

   204 using prems apply (induct a b rule: negDivAlg.induct)

   205 apply (auto simp add: linorder_not_le)

   206 apply (simp add: quorem_def)

   207 apply (subst negDivAlg_eqn, assumption)

   208 apply (case_tac "a + b < (0\<Colon>int)")

   209 apply simp_all

   210 apply (erule splitE)

   211 apply (auto simp add: right_distrib Let_def)

   212 done

   213

   214

   215 subsection{*Existence Shown by Proving the Division Algorithm to be Correct*}

   216

   217 (*the case a=0*)

   218 lemma quorem_0: "b \<noteq> 0 ==> quorem ((0,b), (0,0))"

   219 by (auto simp add: quorem_def linorder_neq_iff)

   220

   221 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"

   222 by (subst posDivAlg.simps, auto)

   223

   224 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"

   225 by (subst negDivAlg.simps, auto)

   226

   227 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"

   228 by (simp add: negateSnd_def)

   229

   230 lemma quorem_neg: "quorem ((-a,-b), qr) ==> quorem ((a,b), negateSnd qr)"

   231 by (auto simp add: split_ifs quorem_def)

   232

   233 lemma divAlg_correct: "b \<noteq> 0 ==> quorem ((a,b), divAlg (a, b))"

   234 by (force simp add: linorder_neq_iff quorem_0 divAlg_def quorem_neg

   235                     posDivAlg_correct negDivAlg_correct)

   236

   237 text{*Arbitrary definitions for division by zero.  Useful to simplify

   238     certain equations.*}

   239

   240 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"

   241 by (simp add: div_def mod_def divAlg_def posDivAlg.simps)

   242

   243

   244 text{*Basic laws about division and remainder*}

   245

   246 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"

   247 apply (case_tac "b = 0", simp)

   248 apply (cut_tac a = a and b = b in divAlg_correct)

   249 apply (auto simp add: quorem_def div_def mod_def)

   250 done

   251

   252 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"

   253 by(simp add: zmod_zdiv_equality[symmetric])

   254

   255 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"

   256 by(simp add: mult_commute zmod_zdiv_equality[symmetric])

   257

   258 text {* Tool setup *}

   259

   260 ML {*

   261 local

   262

   263 structure CancelDivMod = CancelDivModFun(

   264 struct

   265   val div_name = @{const_name Divides.div};

   266   val mod_name = @{const_name Divides.mod};

   267   val mk_binop = HOLogic.mk_binop;

   268   val mk_sum = Int_Numeral_Simprocs.mk_sum HOLogic.intT;

   269   val dest_sum = Int_Numeral_Simprocs.dest_sum;

   270   val div_mod_eqs =

   271     map mk_meta_eq [@{thm zdiv_zmod_equality},

   272       @{thm zdiv_zmod_equality2}];

   273   val trans = trans;

   274   val prove_eq_sums =

   275     let

   276       val simps = @{thm diff_int_def} :: Int_Numeral_Simprocs.add_0s @ @{thms zadd_ac}

   277     in ArithData.prove_conv all_tac (ArithData.simp_all_tac simps) end;

   278 end)

   279

   280 in

   281

   282 val cancel_zdiv_zmod_proc = Simplifier.simproc (the_context ())

   283   "cancel_zdiv_zmod" ["(m::int) + n"] (K CancelDivMod.proc)

   284

   285 end;

   286

   287 Addsimprocs [cancel_zdiv_zmod_proc]

   288 *}

   289

   290 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"

   291 apply (cut_tac a = a and b = b in divAlg_correct)

   292 apply (auto simp add: quorem_def mod_def)

   293 done

   294

   295 lemmas pos_mod_sign  [simp] = pos_mod_conj [THEN conjunct1, standard]

   296    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2, standard]

   297

   298 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"

   299 apply (cut_tac a = a and b = b in divAlg_correct)

   300 apply (auto simp add: quorem_def div_def mod_def)

   301 done

   302

   303 lemmas neg_mod_sign  [simp] = neg_mod_conj [THEN conjunct1, standard]

   304    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2, standard]

   305

   306

   307

   308 subsection{*General Properties of div and mod*}

   309

   310 lemma quorem_div_mod: "b \<noteq> 0 ==> quorem ((a, b), (a div b, a mod b))"

   311 apply (cut_tac a = a and b = b in zmod_zdiv_equality)

   312 apply (force simp add: quorem_def linorder_neq_iff)

   313 done

   314

   315 lemma quorem_div: "[| quorem((a,b),(q,r));  b \<noteq> 0 |] ==> a div b = q"

   316 by (simp add: quorem_div_mod [THEN unique_quotient])

   317

   318 lemma quorem_mod: "[| quorem((a,b),(q,r));  b \<noteq> 0 |] ==> a mod b = r"

   319 by (simp add: quorem_div_mod [THEN unique_remainder])

   320

   321 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"

   322 apply (rule quorem_div)

   323 apply (auto simp add: quorem_def)

   324 done

   325

   326 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"

   327 apply (rule quorem_div)

   328 apply (auto simp add: quorem_def)

   329 done

   330

   331 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"

   332 apply (rule quorem_div)

   333 apply (auto simp add: quorem_def)

   334 done

   335

   336 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)

   337

   338 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"

   339 apply (rule_tac q = 0 in quorem_mod)

   340 apply (auto simp add: quorem_def)

   341 done

   342

   343 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"

   344 apply (rule_tac q = 0 in quorem_mod)

   345 apply (auto simp add: quorem_def)

   346 done

   347

   348 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"

   349 apply (rule_tac q = "-1" in quorem_mod)

   350 apply (auto simp add: quorem_def)

   351 done

   352

   353 text{*There is no @{text mod_neg_pos_trivial}.*}

   354

   355

   356 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)

   357 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"

   358 apply (case_tac "b = 0", simp)

   359 apply (simp add: quorem_div_mod [THEN quorem_neg, simplified,

   360                                  THEN quorem_div, THEN sym])

   361

   362 done

   363

   364 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)

   365 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"

   366 apply (case_tac "b = 0", simp)

   367 apply (subst quorem_div_mod [THEN quorem_neg, simplified, THEN quorem_mod],

   368        auto)

   369 done

   370

   371

   372 subsection{*Laws for div and mod with Unary Minus*}

   373

   374 lemma zminus1_lemma:

   375      "quorem((a,b),(q,r))

   376       ==> quorem ((-a,b), (if r=0 then -q else -q - 1),

   377                           (if r=0 then 0 else b-r))"

   378 by (force simp add: split_ifs quorem_def linorder_neq_iff right_diff_distrib)

   379

   380

   381 lemma zdiv_zminus1_eq_if:

   382      "b \<noteq> (0::int)

   383       ==> (-a) div b =

   384           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"

   385 by (blast intro: quorem_div_mod [THEN zminus1_lemma, THEN quorem_div])

   386

   387 lemma zmod_zminus1_eq_if:

   388      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"

   389 apply (case_tac "b = 0", simp)

   390 apply (blast intro: quorem_div_mod [THEN zminus1_lemma, THEN quorem_mod])

   391 done

   392

   393 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"

   394 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)

   395

   396 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"

   397 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)

   398

   399 lemma zdiv_zminus2_eq_if:

   400      "b \<noteq> (0::int)

   401       ==> a div (-b) =

   402           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"

   403 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)

   404

   405 lemma zmod_zminus2_eq_if:

   406      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"

   407 by (simp add: zmod_zminus1_eq_if zmod_zminus2)

   408

   409

   410 subsection{*Division of a Number by Itself*}

   411

   412 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"

   413 apply (subgoal_tac "0 < a*q")

   414  apply (simp add: zero_less_mult_iff, arith)

   415 done

   416

   417 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"

   418 apply (subgoal_tac "0 \<le> a* (1-q) ")

   419  apply (simp add: zero_le_mult_iff)

   420 apply (simp add: right_diff_distrib)

   421 done

   422

   423 lemma self_quotient: "[| quorem((a,a),(q,r));  a \<noteq> (0::int) |] ==> q = 1"

   424 apply (simp add: split_ifs quorem_def linorder_neq_iff)

   425 apply (rule order_antisym, safe, simp_all)

   426 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)

   427 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)

   428 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+

   429 done

   430

   431 lemma self_remainder: "[| quorem((a,a),(q,r));  a \<noteq> (0::int) |] ==> r = 0"

   432 apply (frule self_quotient, assumption)

   433 apply (simp add: quorem_def)

   434 done

   435

   436 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"

   437 by (simp add: quorem_div_mod [THEN self_quotient])

   438

   439 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)

   440 lemma zmod_self [simp]: "a mod a = (0::int)"

   441 apply (case_tac "a = 0", simp)

   442 apply (simp add: quorem_div_mod [THEN self_remainder])

   443 done

   444

   445

   446 subsection{*Computation of Division and Remainder*}

   447

   448 lemma zdiv_zero [simp]: "(0::int) div b = 0"

   449 by (simp add: div_def divAlg_def)

   450

   451 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"

   452 by (simp add: div_def divAlg_def)

   453

   454 lemma zmod_zero [simp]: "(0::int) mod b = 0"

   455 by (simp add: mod_def divAlg_def)

   456

   457 lemma zdiv_minus1: "(0::int) < b ==> -1 div b = -1"

   458 by (simp add: div_def divAlg_def)

   459

   460 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"

   461 by (simp add: mod_def divAlg_def)

   462

   463 text{*a positive, b positive *}

   464

   465 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"

   466 by (simp add: div_def divAlg_def)

   467

   468 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"

   469 by (simp add: mod_def divAlg_def)

   470

   471 text{*a negative, b positive *}

   472

   473 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"

   474 by (simp add: div_def divAlg_def)

   475

   476 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"

   477 by (simp add: mod_def divAlg_def)

   478

   479 text{*a positive, b negative *}

   480

   481 lemma div_pos_neg:

   482      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"

   483 by (simp add: div_def divAlg_def)

   484

   485 lemma mod_pos_neg:

   486      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"

   487 by (simp add: mod_def divAlg_def)

   488

   489 text{*a negative, b negative *}

   490

   491 lemma div_neg_neg:

   492      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"

   493 by (simp add: div_def divAlg_def)

   494

   495 lemma mod_neg_neg:

   496      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"

   497 by (simp add: mod_def divAlg_def)

   498

   499 text {*Simplify expresions in which div and mod combine numerical constants*}

   500

   501 lemma quoremI:

   502   "\<lbrakk>a == b * q + r; if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0\<rbrakk>

   503     \<Longrightarrow> quorem ((a, b), (q, r))"

   504   unfolding quorem_def by simp

   505

   506 lemmas quorem_div_eq = quoremI [THEN quorem_div, THEN eq_reflection]

   507 lemmas quorem_mod_eq = quoremI [THEN quorem_mod, THEN eq_reflection]

   508 lemmas arithmetic_simps =

   509   arith_simps

   510   add_special

   511   OrderedGroup.add_0_left

   512   OrderedGroup.add_0_right

   513   mult_zero_left

   514   mult_zero_right

   515   mult_1_left

   516   mult_1_right

   517

   518 (* simprocs adapted from HOL/ex/Binary.thy *)

   519 ML {*

   520 local

   521   infix ==;

   522   val op == = Logic.mk_equals;

   523   fun plus m n = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"} $m$ n;

   524   fun mult m n = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"} $m$ n;

   525

   526   val binary_ss = HOL_basic_ss addsimps @{thms arithmetic_simps};

   527   fun prove ctxt prop =

   528     Goal.prove ctxt [] [] prop (fn _ => ALLGOALS (full_simp_tac binary_ss));

   529

   530   fun binary_proc proc ss ct =

   531     (case Thm.term_of ct of

   532       _ $t$ u =>

   533       (case try (pairself ((snd o HOLogic.dest_number))) (t, u) of

   534         SOME args => proc (Simplifier.the_context ss) args

   535       | NONE => NONE)

   536     | _ => NONE);

   537 in

   538

   539 fun divmod_proc rule = binary_proc (fn ctxt => fn ((m, t), (n, u)) =>

   540   if n = 0 then NONE

   541   else

   542     let val (k, l) = Integer.div_mod m n;

   543         fun mk_num x = HOLogic.mk_number HOLogic.intT x;

   544     in SOME (rule OF [prove ctxt (t == plus (mult u (mk_num k)) (mk_num l))])

   545     end);

   546

   547 end;

   548 *}

   549

   550 simproc_setup binary_int_div ("number_of m div number_of n :: int") =

   551   {* K (divmod_proc (@{thm quorem_div_eq})) *}

   552

   553 simproc_setup binary_int_mod ("number_of m mod number_of n :: int") =

   554   {* K (divmod_proc (@{thm quorem_mod_eq})) *}

   555

   556 (* The following 8 lemmas are made unnecessary by the above simprocs: *)

   557

   558 lemmas div_pos_pos_number_of =

   559     div_pos_pos [of "number_of v" "number_of w", standard]

   560

   561 lemmas div_neg_pos_number_of =

   562     div_neg_pos [of "number_of v" "number_of w", standard]

   563

   564 lemmas div_pos_neg_number_of =

   565     div_pos_neg [of "number_of v" "number_of w", standard]

   566

   567 lemmas div_neg_neg_number_of =

   568     div_neg_neg [of "number_of v" "number_of w", standard]

   569

   570

   571 lemmas mod_pos_pos_number_of =

   572     mod_pos_pos [of "number_of v" "number_of w", standard]

   573

   574 lemmas mod_neg_pos_number_of =

   575     mod_neg_pos [of "number_of v" "number_of w", standard]

   576

   577 lemmas mod_pos_neg_number_of =

   578     mod_pos_neg [of "number_of v" "number_of w", standard]

   579

   580 lemmas mod_neg_neg_number_of =

   581     mod_neg_neg [of "number_of v" "number_of w", standard]

   582

   583

   584 lemmas posDivAlg_eqn_number_of [simp] =

   585     posDivAlg_eqn [of "number_of v" "number_of w", standard]

   586

   587 lemmas negDivAlg_eqn_number_of [simp] =

   588     negDivAlg_eqn [of "number_of v" "number_of w", standard]

   589

   590

   591 text{*Special-case simplification *}

   592

   593 lemma zmod_1 [simp]: "a mod (1::int) = 0"

   594 apply (cut_tac a = a and b = 1 in pos_mod_sign)

   595 apply (cut_tac [2] a = a and b = 1 in pos_mod_bound)

   596 apply (auto simp del:pos_mod_bound pos_mod_sign)

   597 done

   598

   599 lemma zdiv_1 [simp]: "a div (1::int) = a"

   600 by (cut_tac a = a and b = 1 in zmod_zdiv_equality, auto)

   601

   602 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"

   603 apply (cut_tac a = a and b = "-1" in neg_mod_sign)

   604 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)

   605 apply (auto simp del: neg_mod_sign neg_mod_bound)

   606 done

   607

   608 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"

   609 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)

   610

   611 (** The last remaining special cases for constant arithmetic:

   612     1 div z and 1 mod z **)

   613

   614 lemmas div_pos_pos_1_number_of [simp] =

   615     div_pos_pos [OF int_0_less_1, of "number_of w", standard]

   616

   617 lemmas div_pos_neg_1_number_of [simp] =

   618     div_pos_neg [OF int_0_less_1, of "number_of w", standard]

   619

   620 lemmas mod_pos_pos_1_number_of [simp] =

   621     mod_pos_pos [OF int_0_less_1, of "number_of w", standard]

   622

   623 lemmas mod_pos_neg_1_number_of [simp] =

   624     mod_pos_neg [OF int_0_less_1, of "number_of w", standard]

   625

   626

   627 lemmas posDivAlg_eqn_1_number_of [simp] =

   628     posDivAlg_eqn [of concl: 1 "number_of w", standard]

   629

   630 lemmas negDivAlg_eqn_1_number_of [simp] =

   631     negDivAlg_eqn [of concl: 1 "number_of w", standard]

   632

   633

   634

   635 subsection{*Monotonicity in the First Argument (Dividend)*}

   636

   637 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"

   638 apply (cut_tac a = a and b = b in zmod_zdiv_equality)

   639 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)

   640 apply (rule unique_quotient_lemma)

   641 apply (erule subst)

   642 apply (erule subst, simp_all)

   643 done

   644

   645 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"

   646 apply (cut_tac a = a and b = b in zmod_zdiv_equality)

   647 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)

   648 apply (rule unique_quotient_lemma_neg)

   649 apply (erule subst)

   650 apply (erule subst, simp_all)

   651 done

   652

   653

   654 subsection{*Monotonicity in the Second Argument (Divisor)*}

   655

   656 lemma q_pos_lemma:

   657      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"

   658 apply (subgoal_tac "0 < b'* (q' + 1) ")

   659  apply (simp add: zero_less_mult_iff)

   660 apply (simp add: right_distrib)

   661 done

   662

   663 lemma zdiv_mono2_lemma:

   664      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';

   665          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]

   666       ==> q \<le> (q'::int)"

   667 apply (frule q_pos_lemma, assumption+)

   668 apply (subgoal_tac "b*q < b* (q' + 1) ")

   669  apply (simp add: mult_less_cancel_left)

   670 apply (subgoal_tac "b*q = r' - r + b'*q'")

   671  prefer 2 apply simp

   672 apply (simp (no_asm_simp) add: right_distrib)

   673 apply (subst add_commute, rule zadd_zless_mono, arith)

   674 apply (rule mult_right_mono, auto)

   675 done

   676

   677 lemma zdiv_mono2:

   678      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"

   679 apply (subgoal_tac "b \<noteq> 0")

   680  prefer 2 apply arith

   681 apply (cut_tac a = a and b = b in zmod_zdiv_equality)

   682 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)

   683 apply (rule zdiv_mono2_lemma)

   684 apply (erule subst)

   685 apply (erule subst, simp_all)

   686 done

   687

   688 lemma q_neg_lemma:

   689      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"

   690 apply (subgoal_tac "b'*q' < 0")

   691  apply (simp add: mult_less_0_iff, arith)

   692 done

   693

   694 lemma zdiv_mono2_neg_lemma:

   695      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;

   696          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]

   697       ==> q' \<le> (q::int)"

   698 apply (frule q_neg_lemma, assumption+)

   699 apply (subgoal_tac "b*q' < b* (q + 1) ")

   700  apply (simp add: mult_less_cancel_left)

   701 apply (simp add: right_distrib)

   702 apply (subgoal_tac "b*q' \<le> b'*q'")

   703  prefer 2 apply (simp add: mult_right_mono_neg, arith)

   704 done

   705

   706 lemma zdiv_mono2_neg:

   707      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"

   708 apply (cut_tac a = a and b = b in zmod_zdiv_equality)

   709 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)

   710 apply (rule zdiv_mono2_neg_lemma)

   711 apply (erule subst)

   712 apply (erule subst, simp_all)

   713 done

   714

   715

   716 subsection{*More Algebraic Laws for div and mod*}

   717

   718 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}

   719

   720 lemma zmult1_lemma:

   721      "[| quorem((b,c),(q,r));  c \<noteq> 0 |]

   722       ==> quorem ((a*b, c), (a*q + a*r div c, a*r mod c))"

   723 by (force simp add: split_ifs quorem_def linorder_neq_iff right_distrib)

   724

   725 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"

   726 apply (case_tac "c = 0", simp)

   727 apply (blast intro: quorem_div_mod [THEN zmult1_lemma, THEN quorem_div])

   728 done

   729

   730 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"

   731 apply (case_tac "c = 0", simp)

   732 apply (blast intro: quorem_div_mod [THEN zmult1_lemma, THEN quorem_mod])

   733 done

   734

   735 lemma zmod_zmult1_eq': "(a*b) mod (c::int) = ((a mod c) * b) mod c"

   736 apply (rule trans)

   737 apply (rule_tac s = "b*a mod c" in trans)

   738 apply (rule_tac [2] zmod_zmult1_eq)

   739 apply (simp_all add: mult_commute)

   740 done

   741

   742 lemma zmod_zmult_distrib: "(a*b) mod (c::int) = ((a mod c) * (b mod c)) mod c"

   743 apply (rule zmod_zmult1_eq' [THEN trans])

   744 apply (rule zmod_zmult1_eq)

   745 done

   746

   747 lemma zdiv_zmult_self1 [simp]: "b \<noteq> (0::int) ==> (a*b) div b = a"

   748 by (simp add: zdiv_zmult1_eq)

   749

   750 lemma mod_div_trivial [simp]: "(a mod b) div b = (0::int)"

   751 apply (case_tac "b = 0", simp)

   752 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)

   753 done

   754

   755 lemma mod_mod_trivial [simp]: "(a mod b) mod b = a mod (b::int)"

   756 apply (case_tac "b = 0", simp)

   757 apply (force simp add: linorder_neq_iff mod_pos_pos_trivial mod_neg_neg_trivial)

   758 done

   759

   760 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}

   761

   762 lemma zadd1_lemma:

   763      "[| quorem((a,c),(aq,ar));  quorem((b,c),(bq,br));  c \<noteq> 0 |]

   764       ==> quorem ((a+b, c), (aq + bq + (ar+br) div c, (ar+br) mod c))"

   765 by (force simp add: split_ifs quorem_def linorder_neq_iff right_distrib)

   766

   767 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)

   768 lemma zdiv_zadd1_eq:

   769      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"

   770 apply (case_tac "c = 0", simp)

   771 apply (blast intro: zadd1_lemma [OF quorem_div_mod quorem_div_mod] quorem_div)

   772 done

   773

   774 lemma zmod_zadd1_eq: "(a+b) mod (c::int) = (a mod c + b mod c) mod c"

   775 apply (case_tac "c = 0", simp)

   776 apply (blast intro: zadd1_lemma [OF quorem_div_mod quorem_div_mod] quorem_mod)

   777 done

   778

   779 lemma zdiv_zadd_self1[simp]: "a \<noteq> (0::int) ==> (a+b) div a = b div a + 1"

   780 by (simp add: zdiv_zadd1_eq)

   781

   782 lemma zdiv_zadd_self2[simp]: "a \<noteq> (0::int) ==> (b+a) div a = b div a + 1"

   783 by (simp add: zdiv_zadd1_eq)

   784

   785 instance int :: semiring_div

   786 proof

   787   fix a b c :: int

   788   assume not0: "b \<noteq> 0"

   789   show "(a + c * b) div b = c + a div b"

   790     unfolding zdiv_zadd1_eq [of a "c * b"] using not0

   791       by (simp add: zmod_zmult1_eq)

   792 qed auto

   793

   794 lemma zdiv_zmult_self2 [simp]: "b \<noteq> (0::int) ==> (b*a) div b = a"

   795 by (subst mult_commute, erule zdiv_zmult_self1)

   796

   797 lemma zmod_zmult_self1 [simp]: "(a*b) mod b = (0::int)"

   798 by (simp add: zmod_zmult1_eq)

   799

   800 lemma zmod_zmult_self2 [simp]: "(b*a) mod b = (0::int)"

   801 by (simp add: mult_commute zmod_zmult1_eq)

   802

   803 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"

   804 proof

   805   assume "m mod d = 0"

   806   with zmod_zdiv_equality[of m d] show "EX q::int. m = d*q" by auto

   807 next

   808   assume "EX q::int. m = d*q"

   809   thus "m mod d = 0" by auto

   810 qed

   811

   812 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]

   813

   814 lemma zmod_zadd_left_eq: "(a+b) mod (c::int) = ((a mod c) + b) mod c"

   815 apply (rule trans [symmetric])

   816 apply (rule zmod_zadd1_eq, simp)

   817 apply (rule zmod_zadd1_eq [symmetric])

   818 done

   819

   820 lemma zmod_zadd_right_eq: "(a+b) mod (c::int) = (a + (b mod c)) mod c"

   821 apply (rule trans [symmetric])

   822 apply (rule zmod_zadd1_eq, simp)

   823 apply (rule zmod_zadd1_eq [symmetric])

   824 done

   825

   826 lemma zmod_zadd_self1[simp]: "(a+b) mod a = b mod (a::int)"

   827 apply (case_tac "a = 0", simp)

   828 apply (simp add: zmod_zadd1_eq)

   829 done

   830

   831 lemma zmod_zadd_self2[simp]: "(b+a) mod a = b mod (a::int)"

   832 apply (case_tac "a = 0", simp)

   833 apply (simp add: zmod_zadd1_eq)

   834 done

   835

   836

   837 lemma zmod_zdiff1_eq: fixes a::int

   838   shows "(a - b) mod c = (a mod c - b mod c) mod c" (is "?l = ?r")

   839 proof -

   840   have "?l = (c + (a mod c - b mod c)) mod c"

   841     using zmod_zadd1_eq[of a "-b" c] by(simp add:ring_simps zmod_zminus1_eq_if)

   842   also have "\<dots> = ?r" by simp

   843   finally show ?thesis .

   844 qed

   845

   846 subsection{*Proving  @{term "a div (b*c) = (a div b) div c"} *}

   847

   848 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but

   849   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems

   850   to cause particular problems.*)

   851

   852 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}

   853

   854 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"

   855 apply (subgoal_tac "b * (c - q mod c) < r * 1")

   856 apply (simp add: right_diff_distrib)

   857 apply (rule order_le_less_trans)

   858 apply (erule_tac [2] mult_strict_right_mono)

   859 apply (rule mult_left_mono_neg)

   860 apply (auto simp add: compare_rls add_commute [of 1]

   861                       add1_zle_eq pos_mod_bound)

   862 done

   863

   864 lemma zmult2_lemma_aux2:

   865      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"

   866 apply (subgoal_tac "b * (q mod c) \<le> 0")

   867  apply arith

   868 apply (simp add: mult_le_0_iff)

   869 done

   870

   871 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"

   872 apply (subgoal_tac "0 \<le> b * (q mod c) ")

   873 apply arith

   874 apply (simp add: zero_le_mult_iff)

   875 done

   876

   877 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"

   878 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")

   879 apply (simp add: right_diff_distrib)

   880 apply (rule order_less_le_trans)

   881 apply (erule mult_strict_right_mono)

   882 apply (rule_tac [2] mult_left_mono)

   883 apply (auto simp add: compare_rls add_commute [of 1]

   884                       add1_zle_eq pos_mod_bound)

   885 done

   886

   887 lemma zmult2_lemma: "[| quorem ((a,b), (q,r));  b \<noteq> 0;  0 < c |]

   888       ==> quorem ((a, b*c), (q div c, b*(q mod c) + r))"

   889 by (auto simp add: mult_ac quorem_def linorder_neq_iff

   890                    zero_less_mult_iff right_distrib [symmetric]

   891                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)

   892

   893 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"

   894 apply (case_tac "b = 0", simp)

   895 apply (force simp add: quorem_div_mod [THEN zmult2_lemma, THEN quorem_div])

   896 done

   897

   898 lemma zmod_zmult2_eq:

   899      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"

   900 apply (case_tac "b = 0", simp)

   901 apply (force simp add: quorem_div_mod [THEN zmult2_lemma, THEN quorem_mod])

   902 done

   903

   904

   905 subsection{*Cancellation of Common Factors in div*}

   906

   907 lemma zdiv_zmult_zmult1_aux1:

   908      "[| (0::int) < b;  c \<noteq> 0 |] ==> (c*a) div (c*b) = a div b"

   909 by (subst zdiv_zmult2_eq, auto)

   910

   911 lemma zdiv_zmult_zmult1_aux2:

   912      "[| b < (0::int);  c \<noteq> 0 |] ==> (c*a) div (c*b) = a div b"

   913 apply (subgoal_tac " (c * (-a)) div (c * (-b)) = (-a) div (-b) ")

   914 apply (rule_tac [2] zdiv_zmult_zmult1_aux1, auto)

   915 done

   916

   917 lemma zdiv_zmult_zmult1: "c \<noteq> (0::int) ==> (c*a) div (c*b) = a div b"

   918 apply (case_tac "b = 0", simp)

   919 apply (auto simp add: linorder_neq_iff zdiv_zmult_zmult1_aux1 zdiv_zmult_zmult1_aux2)

   920 done

   921

   922 lemma zdiv_zmult_zmult1_if[simp]:

   923   "(k*m) div (k*n) = (if k = (0::int) then 0 else m div n)"

   924 by (simp add:zdiv_zmult_zmult1)

   925

   926 (*

   927 lemma zdiv_zmult_zmult2: "c \<noteq> (0::int) ==> (a*c) div (b*c) = a div b"

   928 apply (drule zdiv_zmult_zmult1)

   929 apply (auto simp add: mult_commute)

   930 done

   931 *)

   932

   933

   934 subsection{*Distribution of Factors over mod*}

   935

   936 lemma zmod_zmult_zmult1_aux1:

   937      "[| (0::int) < b;  c \<noteq> 0 |] ==> (c*a) mod (c*b) = c * (a mod b)"

   938 by (subst zmod_zmult2_eq, auto)

   939

   940 lemma zmod_zmult_zmult1_aux2:

   941      "[| b < (0::int);  c \<noteq> 0 |] ==> (c*a) mod (c*b) = c * (a mod b)"

   942 apply (subgoal_tac " (c * (-a)) mod (c * (-b)) = c * ((-a) mod (-b))")

   943 apply (rule_tac [2] zmod_zmult_zmult1_aux1, auto)

   944 done

   945

   946 lemma zmod_zmult_zmult1: "(c*a) mod (c*b) = (c::int) * (a mod b)"

   947 apply (case_tac "b = 0", simp)

   948 apply (case_tac "c = 0", simp)

   949 apply (auto simp add: linorder_neq_iff zmod_zmult_zmult1_aux1 zmod_zmult_zmult1_aux2)

   950 done

   951

   952 lemma zmod_zmult_zmult2: "(a*c) mod (b*c) = (a mod b) * (c::int)"

   953 apply (cut_tac c = c in zmod_zmult_zmult1)

   954 apply (auto simp add: mult_commute)

   955 done

   956

   957 lemma zmod_zmod_cancel:

   958 assumes "n dvd m" shows "(k::int) mod m mod n = k mod n"

   959 proof -

   960   from n dvd m obtain r where "m = n*r" by(auto simp:dvd_def)

   961   have "k mod n = (m * (k div m) + k mod m) mod n"

   962     using zmod_zdiv_equality[of k m] by simp

   963   also have "\<dots> = (m * (k div m) mod n + k mod m mod n) mod n"

   964     by(subst zmod_zadd1_eq, rule refl)

   965   also have "m * (k div m) mod n = 0" using m = n*r

   966     by(simp add:mult_ac)

   967   finally show ?thesis by simp

   968 qed

   969

   970

   971 subsection {*Splitting Rules for div and mod*}

   972

   973 text{*The proofs of the two lemmas below are essentially identical*}

   974

   975 lemma split_pos_lemma:

   976  "0<k ==>

   977     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"

   978 apply (rule iffI, clarify)

   979  apply (erule_tac P="P ?x ?y" in rev_mp)

   980  apply (subst zmod_zadd1_eq)

   981  apply (subst zdiv_zadd1_eq)

   982  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)

   983 txt{*converse direction*}

   984 apply (drule_tac x = "n div k" in spec)

   985 apply (drule_tac x = "n mod k" in spec, simp)

   986 done

   987

   988 lemma split_neg_lemma:

   989  "k<0 ==>

   990     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"

   991 apply (rule iffI, clarify)

   992  apply (erule_tac P="P ?x ?y" in rev_mp)

   993  apply (subst zmod_zadd1_eq)

   994  apply (subst zdiv_zadd1_eq)

   995  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)

   996 txt{*converse direction*}

   997 apply (drule_tac x = "n div k" in spec)

   998 apply (drule_tac x = "n mod k" in spec, simp)

   999 done

  1000

  1001 lemma split_zdiv:

  1002  "P(n div k :: int) =

  1003   ((k = 0 --> P 0) &

  1004    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) &

  1005    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"

  1006 apply (case_tac "k=0", simp)

  1007 apply (simp only: linorder_neq_iff)

  1008 apply (erule disjE)

  1009  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"]

  1010                       split_neg_lemma [of concl: "%x y. P x"])

  1011 done

  1012

  1013 lemma split_zmod:

  1014  "P(n mod k :: int) =

  1015   ((k = 0 --> P n) &

  1016    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) &

  1017    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"

  1018 apply (case_tac "k=0", simp)

  1019 apply (simp only: linorder_neq_iff)

  1020 apply (erule disjE)

  1021  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"]

  1022                       split_neg_lemma [of concl: "%x y. P y"])

  1023 done

  1024

  1025 (* Enable arith to deal with div 2 and mod 2: *)

  1026 declare split_zdiv [of _ _ "number_of k", simplified, standard, arith_split]

  1027 declare split_zmod [of _ _ "number_of k", simplified, standard, arith_split]

  1028

  1029

  1030 subsection{*Speeding up the Division Algorithm with Shifting*}

  1031

  1032 text{*computing div by shifting *}

  1033

  1034 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"

  1035 proof cases

  1036   assume "a=0"

  1037     thus ?thesis by simp

  1038 next

  1039   assume "a\<noteq>0" and le_a: "0\<le>a"

  1040   hence a_pos: "1 \<le> a" by arith

  1041   hence one_less_a2: "1 < 2*a" by arith

  1042   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"

  1043     by (simp add: mult_le_cancel_left add_commute [of 1] add1_zle_eq)

  1044   with a_pos have "0 \<le> b mod a" by simp

  1045   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"

  1046     by (simp add: mod_pos_pos_trivial one_less_a2)

  1047   with  le_2a

  1048   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"

  1049     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2

  1050                   right_distrib)

  1051   thus ?thesis

  1052     by (subst zdiv_zadd1_eq,

  1053         simp add: zdiv_zmult_zmult1 zmod_zmult_zmult1 one_less_a2

  1054                   div_pos_pos_trivial)

  1055 qed

  1056

  1057 lemma neg_zdiv_mult_2: "a \<le> (0::int) ==> (1 + 2*b) div (2*a) = (b+1) div a"

  1058 apply (subgoal_tac " (1 + 2* (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a) ")

  1059 apply (rule_tac [2] pos_zdiv_mult_2)

  1060 apply (auto simp add: minus_mult_right [symmetric] right_diff_distrib)

  1061 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")

  1062 apply (simp only: zdiv_zminus_zminus diff_minus minus_add_distrib [symmetric],

  1063        simp)

  1064 done

  1065

  1066 (*Not clear why this must be proved separately; probably number_of causes

  1067   simplification problems*)

  1068 lemma not_0_le_lemma: "~ 0 \<le> x ==> x \<le> (0::int)"

  1069 by auto

  1070

  1071 lemma zdiv_number_of_Bit0 [simp]:

  1072      "number_of (Int.Bit0 v) div number_of (Int.Bit0 w) =

  1073           number_of v div (number_of w :: int)"

  1074 by (simp only: number_of_eq numeral_simps) simp

  1075

  1076 lemma zdiv_number_of_Bit1 [simp]:

  1077      "number_of (Int.Bit1 v) div number_of (Int.Bit0 w) =

  1078           (if (0::int) \<le> number_of w

  1079            then number_of v div (number_of w)

  1080            else (number_of v + (1::int)) div (number_of w))"

  1081 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if)

  1082 apply (simp add: zdiv_zmult_zmult1 pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac)

  1083 done

  1084

  1085

  1086 subsection{*Computing mod by Shifting (proofs resemble those for div)*}

  1087

  1088 lemma pos_zmod_mult_2:

  1089      "(0::int) \<le> a ==> (1 + 2*b) mod (2*a) = 1 + 2 * (b mod a)"

  1090 apply (case_tac "a = 0", simp)

  1091 apply (subgoal_tac "1 < a * 2")

  1092  prefer 2 apply arith

  1093 apply (subgoal_tac "2* (1 + b mod a) \<le> 2*a")

  1094  apply (rule_tac [2] mult_left_mono)

  1095 apply (auto simp add: add_commute [of 1] mult_commute add1_zle_eq

  1096                       pos_mod_bound)

  1097 apply (subst zmod_zadd1_eq)

  1098 apply (simp add: zmod_zmult_zmult2 mod_pos_pos_trivial)

  1099 apply (rule mod_pos_pos_trivial)

  1100 apply (auto simp add: mod_pos_pos_trivial ring_distribs)

  1101 apply (subgoal_tac "0 \<le> b mod a", arith, simp)

  1102 done

  1103

  1104 lemma neg_zmod_mult_2:

  1105      "a \<le> (0::int) ==> (1 + 2*b) mod (2*a) = 2 * ((b+1) mod a) - 1"

  1106 apply (subgoal_tac "(1 + 2* (-b - 1)) mod (2* (-a)) =

  1107                     1 + 2* ((-b - 1) mod (-a))")

  1108 apply (rule_tac [2] pos_zmod_mult_2)

  1109 apply (auto simp add: minus_mult_right [symmetric] right_diff_distrib)

  1110 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")

  1111  prefer 2 apply simp

  1112 apply (simp only: zmod_zminus_zminus diff_minus minus_add_distrib [symmetric])

  1113 done

  1114

  1115 lemma zmod_number_of_Bit0 [simp]:

  1116      "number_of (Int.Bit0 v) mod number_of (Int.Bit0 w) =

  1117       (2::int) * (number_of v mod number_of w)"

  1118 apply (simp only: number_of_eq numeral_simps)

  1119 apply (simp add: zmod_zmult_zmult1 pos_zmod_mult_2

  1120                  not_0_le_lemma neg_zmod_mult_2 add_ac)

  1121 done

  1122

  1123 lemma zmod_number_of_Bit1 [simp]:

  1124      "number_of (Int.Bit1 v) mod number_of (Int.Bit0 w) =

  1125       (if (0::int) \<le> number_of w

  1126                 then 2 * (number_of v mod number_of w) + 1

  1127                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"

  1128 apply (simp only: number_of_eq numeral_simps)

  1129 apply (simp add: zmod_zmult_zmult1 pos_zmod_mult_2

  1130                  not_0_le_lemma neg_zmod_mult_2 add_ac)

  1131 done

  1132

  1133

  1134 subsection{*Quotients of Signs*}

  1135

  1136 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"

  1137 apply (subgoal_tac "a div b \<le> -1", force)

  1138 apply (rule order_trans)

  1139 apply (rule_tac a' = "-1" in zdiv_mono1)

  1140 apply (auto simp add: zdiv_minus1)

  1141 done

  1142

  1143 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a;  b < 0 |] ==> a div b \<le> 0"

  1144 by (drule zdiv_mono1_neg, auto)

  1145

  1146 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"

  1147 apply auto

  1148 apply (drule_tac [2] zdiv_mono1)

  1149 apply (auto simp add: linorder_neq_iff)

  1150 apply (simp (no_asm_use) add: linorder_not_less [symmetric])

  1151 apply (blast intro: div_neg_pos_less0)

  1152 done

  1153

  1154 lemma neg_imp_zdiv_nonneg_iff:

  1155      "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"

  1156 apply (subst zdiv_zminus_zminus [symmetric])

  1157 apply (subst pos_imp_zdiv_nonneg_iff, auto)

  1158 done

  1159

  1160 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)

  1161 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"

  1162 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)

  1163

  1164 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)

  1165 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"

  1166 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)

  1167

  1168

  1169 subsection {* The Divides Relation *}

  1170

  1171 lemma zdvd_iff_zmod_eq_0: "(m dvd n) = (n mod m = (0::int))"

  1172   by (simp add: dvd_def zmod_eq_0_iff)

  1173

  1174 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =

  1175   zdvd_iff_zmod_eq_0 [of "number_of x" "number_of y", standard]

  1176

  1177 lemma zdvd_0_right [iff]: "(m::int) dvd 0"

  1178   by (simp add: dvd_def)

  1179

  1180 lemma zdvd_0_left [iff,noatp]: "(0 dvd (m::int)) = (m = 0)"

  1181   by (simp add: dvd_def)

  1182

  1183 lemma zdvd_1_left [iff]: "1 dvd (m::int)"

  1184   by (simp add: dvd_def)

  1185

  1186 lemma zdvd_refl [simp]: "m dvd (m::int)"

  1187   by (auto simp add: dvd_def intro: zmult_1_right [symmetric])

  1188

  1189 lemma zdvd_trans: "m dvd n ==> n dvd k ==> m dvd (k::int)"

  1190   by (auto simp add: dvd_def intro: mult_assoc)

  1191

  1192 lemma zdvd_zminus_iff: "m dvd -n \<longleftrightarrow> m dvd (n::int)"

  1193 proof

  1194   assume "m dvd - n"

  1195   then obtain k where "- n = m * k" ..

  1196   then have "n = m * - k" by simp

  1197   then show "m dvd n" ..

  1198 next

  1199   assume "m dvd n"

  1200   then have "m dvd n * -1" by (rule dvd_mult2)

  1201   then show "m dvd - n" by simp

  1202 qed

  1203

  1204 lemma zdvd_zminus2_iff: "-m dvd n \<longleftrightarrow> m dvd (n::int)"

  1205 proof

  1206   assume "- m dvd n"

  1207   then obtain k where "n = - m * k" ..

  1208   then have "n = m * - k" by simp

  1209   then show "m dvd n" ..

  1210 next

  1211   assume "m dvd n"

  1212   then obtain k where "n = m * k" ..

  1213   then have "n = - m * - k" by simp

  1214   then show "- m dvd n" ..

  1215 qed

  1216

  1217 lemma zdvd_abs1: "( \<bar>i::int\<bar> dvd j) = (i dvd j)"

  1218   by (cases "i > 0") (simp_all add: zdvd_zminus2_iff)

  1219

  1220 lemma zdvd_abs2: "( (i::int) dvd \<bar>j\<bar>) = (i dvd j)"

  1221   by (cases "j > 0") (simp_all add: zdvd_zminus_iff)

  1222

  1223 lemma zdvd_anti_sym:

  1224     "0 < m ==> 0 < n ==> m dvd n ==> n dvd m ==> m = (n::int)"

  1225   apply (simp add: dvd_def, auto)

  1226   apply (simp add: mult_assoc zero_less_mult_iff zmult_eq_1_iff)

  1227   done

  1228

  1229 lemma zdvd_zadd: "k dvd m ==> k dvd n ==> k dvd (m + n :: int)"

  1230   apply (simp add: dvd_def)

  1231   apply (blast intro: right_distrib [symmetric])

  1232   done

  1233

  1234 lemma zdvd_dvd_eq: assumes anz:"a \<noteq> 0" and ab: "(a::int) dvd b" and ba:"b dvd a"

  1235   shows "\<bar>a\<bar> = \<bar>b\<bar>"

  1236 proof-

  1237   from ab obtain k where k:"b = a*k" unfolding dvd_def by blast

  1238   from ba obtain k' where k':"a = b*k'" unfolding dvd_def by blast

  1239   from k k' have "a = a*k*k'" by simp

  1240   with mult_cancel_left1[where c="a" and b="k*k'"]

  1241   have kk':"k*k' = 1" using anz by (simp add: mult_assoc)

  1242   hence "k = 1 \<and> k' = 1 \<or> k = -1 \<and> k' = -1" by (simp add: zmult_eq_1_iff)

  1243   thus ?thesis using k k' by auto

  1244 qed

  1245

  1246 lemma zdvd_zdiff: "k dvd m ==> k dvd n ==> k dvd (m - n :: int)"

  1247   apply (simp add: dvd_def)

  1248   apply (blast intro: right_diff_distrib [symmetric])

  1249   done

  1250

  1251 lemma zdvd_zdiffD: "k dvd m - n ==> k dvd n ==> k dvd (m::int)"

  1252   apply (subgoal_tac "m = n + (m - n)")

  1253    apply (erule ssubst)

  1254    apply (blast intro: zdvd_zadd, simp)

  1255   done

  1256

  1257 lemma zdvd_zmult: "k dvd (n::int) ==> k dvd m * n"

  1258   apply (simp add: dvd_def)

  1259   apply (blast intro: mult_left_commute)

  1260   done

  1261

  1262 lemma zdvd_zmult2: "k dvd (m::int) ==> k dvd m * n"

  1263   apply (subst mult_commute)

  1264   apply (erule zdvd_zmult)

  1265   done

  1266

  1267 lemma zdvd_triv_right [iff]: "(k::int) dvd m * k"

  1268   apply (rule zdvd_zmult)

  1269   apply (rule zdvd_refl)

  1270   done

  1271

  1272 lemma zdvd_triv_left [iff]: "(k::int) dvd k * m"

  1273   apply (rule zdvd_zmult2)

  1274   apply (rule zdvd_refl)

  1275   done

  1276

  1277 lemma zdvd_zmultD2: "j * k dvd n ==> j dvd (n::int)"

  1278   apply (simp add: dvd_def)

  1279   apply (simp add: mult_assoc, blast)

  1280   done

  1281

  1282 lemma zdvd_zmultD: "j * k dvd n ==> k dvd (n::int)"

  1283   apply (rule zdvd_zmultD2)

  1284   apply (subst mult_commute, assumption)

  1285   done

  1286

  1287 lemma zdvd_zmult_mono: "i dvd m ==> j dvd (n::int) ==> i * j dvd m * n"

  1288   by (rule mult_dvd_mono)

  1289

  1290 lemma zdvd_reduce: "(k dvd n + k * m) = (k dvd (n::int))"

  1291   apply (rule iffI)

  1292    apply (erule_tac [2] zdvd_zadd)

  1293    apply (subgoal_tac "n = (n + k * m) - k * m")

  1294     apply (erule ssubst)

  1295     apply (erule zdvd_zdiff, simp_all)

  1296   done

  1297

  1298 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"

  1299   apply (simp add: dvd_def)

  1300   apply (auto simp add: zmod_zmult_zmult1)

  1301   done

  1302

  1303 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"

  1304   apply (subgoal_tac "k dvd n * (m div n) + m mod n")

  1305    apply (simp add: zmod_zdiv_equality [symmetric])

  1306   apply (simp only: zdvd_zadd zdvd_zmult2)

  1307   done

  1308

  1309 lemma zdvd_not_zless: "0 < m ==> m < n ==> \<not> n dvd (m::int)"

  1310   apply (auto elim!: dvdE)

  1311   apply (subgoal_tac "0 < n")

  1312    prefer 2

  1313    apply (blast intro: order_less_trans)

  1314   apply (simp add: zero_less_mult_iff)

  1315   apply (subgoal_tac "n * k < n * 1")

  1316    apply (drule mult_less_cancel_left [THEN iffD1], auto)

  1317   done

  1318

  1319 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"

  1320   using zmod_zdiv_equality[where a="m" and b="n"]

  1321   by (simp add: ring_simps)

  1322

  1323 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"

  1324 apply (subgoal_tac "m mod n = 0")

  1325  apply (simp add: zmult_div_cancel)

  1326 apply (simp only: zdvd_iff_zmod_eq_0)

  1327 done

  1328

  1329 lemma zdvd_mult_cancel: assumes d:"k * m dvd k * n" and kz:"k \<noteq> (0::int)"

  1330   shows "m dvd n"

  1331 proof-

  1332   from d obtain h where h: "k*n = k*m * h" unfolding dvd_def by blast

  1333   {assume "n \<noteq> m*h" hence "k* n \<noteq> k* (m*h)" using kz by simp

  1334     with h have False by (simp add: mult_assoc)}

  1335   hence "n = m * h" by blast

  1336   thus ?thesis by blast

  1337 qed

  1338

  1339 lemma zdvd_zmult_cancel_disj[simp]:

  1340   "(k*m) dvd (k*n) = (k=0 | m dvd (n::int))"

  1341 by (auto simp: zdvd_zmult_mono dest: zdvd_mult_cancel)

  1342

  1343

  1344 theorem ex_nat: "(\<exists>x::nat. P x) = (\<exists>x::int. 0 <= x \<and> P (nat x))"

  1345 apply (simp split add: split_nat)

  1346 apply (rule iffI)

  1347 apply (erule exE)

  1348 apply (rule_tac x = "int x" in exI)

  1349 apply simp

  1350 apply (erule exE)

  1351 apply (rule_tac x = "nat x" in exI)

  1352 apply (erule conjE)

  1353 apply (erule_tac x = "nat x" in allE)

  1354 apply simp

  1355 done

  1356

  1357 theorem zdvd_int: "(x dvd y) = (int x dvd int y)"

  1358 proof -

  1359   have "\<And>k. int y = int x * k \<Longrightarrow> x dvd y"

  1360   proof -

  1361     fix k

  1362     assume A: "int y = int x * k"

  1363     then show "x dvd y" proof (cases k)

  1364       case (1 n) with A have "y = x * n" by (simp add: zmult_int)

  1365       then show ?thesis ..

  1366     next

  1367       case (2 n) with A have "int y = int x * (- int (Suc n))" by simp

  1368       also have "\<dots> = - (int x * int (Suc n))" by (simp only: mult_minus_right)

  1369       also have "\<dots> = - int (x * Suc n)" by (simp only: zmult_int)

  1370       finally have "- int (x * Suc n) = int y" ..

  1371       then show ?thesis by (simp only: negative_eq_positive) auto

  1372     qed

  1373   qed

  1374   then show ?thesis by (auto elim!: dvdE simp only: zmult_int [symmetric])

  1375 qed

  1376

  1377 lemma zdvd1_eq[simp]: "(x::int) dvd 1 = ( \<bar>x\<bar> = 1)"

  1378 proof

  1379   assume d: "x dvd 1" hence "int (nat \<bar>x\<bar>) dvd int (nat 1)" by (simp add: zdvd_abs1)

  1380   hence "nat \<bar>x\<bar> dvd 1" by (simp add: zdvd_int)

  1381   hence "nat \<bar>x\<bar> = 1"  by simp

  1382   thus "\<bar>x\<bar> = 1" by (cases "x < 0", auto)

  1383 next

  1384   assume "\<bar>x\<bar>=1" thus "x dvd 1"

  1385     by(cases "x < 0",simp_all add: minus_equation_iff zdvd_iff_zmod_eq_0)

  1386 qed

  1387 lemma zdvd_mult_cancel1:

  1388   assumes mp:"m \<noteq>(0::int)" shows "(m * n dvd m) = (\<bar>n\<bar> = 1)"

  1389 proof

  1390   assume n1: "\<bar>n\<bar> = 1" thus "m * n dvd m"

  1391     by (cases "n >0", auto simp add: zdvd_zminus2_iff minus_equation_iff)

  1392 next

  1393   assume H: "m * n dvd m" hence H2: "m * n dvd m * 1" by simp

  1394   from zdvd_mult_cancel[OF H2 mp] show "\<bar>n\<bar> = 1" by (simp only: zdvd1_eq)

  1395 qed

  1396

  1397 lemma int_dvd_iff: "(int m dvd z) = (m dvd nat (abs z))"

  1398   unfolding zdvd_int by (cases "z \<ge> 0") (simp_all add: zdvd_zminus_iff)

  1399

  1400 lemma dvd_int_iff: "(z dvd int m) = (nat (abs z) dvd m)"

  1401   unfolding zdvd_int by (cases "z \<ge> 0") (simp_all add: zdvd_zminus2_iff)

  1402

  1403 lemma nat_dvd_iff: "(nat z dvd m) = (if 0 \<le> z then (z dvd int m) else m = 0)"

  1404   by (auto simp add: dvd_int_iff)

  1405

  1406 lemma zminus_dvd_iff [iff]: "(-z dvd w) = (z dvd (w::int))"

  1407   by (simp add: zdvd_zminus2_iff)

  1408

  1409 lemma dvd_zminus_iff [iff]: "(z dvd -w) = (z dvd (w::int))"

  1410   by (simp add: zdvd_zminus_iff)

  1411

  1412 lemma zdvd_imp_le: "[| z dvd n; 0 < n |] ==> z \<le> (n::int)"

  1413   apply (rule_tac z=n in int_cases)

  1414   apply (auto simp add: dvd_int_iff)

  1415   apply (rule_tac z=z in int_cases)

  1416   apply (auto simp add: dvd_imp_le)

  1417   done

  1418

  1419 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"

  1420 apply (induct "y", auto)

  1421 apply (rule zmod_zmult1_eq [THEN trans])

  1422 apply (simp (no_asm_simp))

  1423 apply (rule zmod_zmult_distrib [symmetric])

  1424 done

  1425

  1426 lemma zdiv_int: "int (a div b) = (int a) div (int b)"

  1427 apply (subst split_div, auto)

  1428 apply (subst split_zdiv, auto)

  1429 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in IntDiv.unique_quotient)

  1430 apply (auto simp add: IntDiv.quorem_def of_nat_mult)

  1431 done

  1432

  1433 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"

  1434 apply (subst split_mod, auto)

  1435 apply (subst split_zmod, auto)

  1436 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia

  1437        in unique_remainder)

  1438 apply (auto simp add: IntDiv.quorem_def of_nat_mult)

  1439 done

  1440

  1441 text{*Suggested by Matthias Daum*}

  1442 lemma int_power_div_base:

  1443      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"

  1444 apply (subgoal_tac "k ^ m = k ^ ((m - 1) + 1)")

  1445  apply (erule ssubst)

  1446  apply (simp only: power_add)

  1447  apply simp_all

  1448 done

  1449

  1450 text {* by Brian Huffman *}

  1451 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"

  1452 by (simp only: zmod_zminus1_eq_if mod_mod_trivial)

  1453

  1454 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"

  1455 by (simp only: diff_def zmod_zadd_left_eq [symmetric])

  1456

  1457 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"

  1458 proof -

  1459   have "(x + - (y mod m) mod m) mod m = (x + - y mod m) mod m"

  1460     by (simp only: zminus_zmod)

  1461   hence "(x + - (y mod m)) mod m = (x + - y) mod m"

  1462     by (simp only: zmod_zadd_right_eq [symmetric])

  1463   thus "(x - y mod m) mod m = (x - y) mod m"

  1464     by (simp only: diff_def)

  1465 qed

  1466

  1467 lemmas zmod_simps =

  1468   IntDiv.zmod_zadd_left_eq  [symmetric]

  1469   IntDiv.zmod_zadd_right_eq [symmetric]

  1470   IntDiv.zmod_zmult1_eq     [symmetric]

  1471   IntDiv.zmod_zmult1_eq'    [symmetric]

  1472   IntDiv.zpower_zmod

  1473   zminus_zmod zdiff_zmod_left zdiff_zmod_right

  1474

  1475 text {* code generator setup *}

  1476

  1477 context ring_1

  1478 begin

  1479

  1480 lemma of_int_num [code func]:

  1481   "of_int k = (if k = 0 then 0 else if k < 0 then

  1482      - of_int (- k) else let

  1483        (l, m) = divAlg (k, 2);

  1484        l' = of_int l

  1485      in if m = 0 then l' + l' else l' + l' + 1)"

  1486 proof -

  1487   have aux1: "k mod (2\<Colon>int) \<noteq> (0\<Colon>int) \<Longrightarrow>

  1488     of_int k = of_int (k div 2 * 2 + 1)"

  1489   proof -

  1490     have "k mod 2 < 2" by (auto intro: pos_mod_bound)

  1491     moreover have "0 \<le> k mod 2" by (auto intro: pos_mod_sign)

  1492     moreover assume "k mod 2 \<noteq> 0"

  1493     ultimately have "k mod 2 = 1" by arith

  1494     moreover have "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp

  1495     ultimately show ?thesis by auto

  1496   qed

  1497   have aux2: "\<And>x. of_int 2 * x = x + x"

  1498   proof -

  1499     fix x

  1500     have int2: "(2::int) = 1 + 1" by arith

  1501     show "of_int 2 * x = x + x"

  1502     unfolding int2 of_int_add left_distrib by simp

  1503   qed

  1504   have aux3: "\<And>x. x * of_int 2 = x + x"

  1505   proof -

  1506     fix x

  1507     have int2: "(2::int) = 1 + 1" by arith

  1508     show "x * of_int 2 = x + x"

  1509     unfolding int2 of_int_add right_distrib by simp

  1510   qed

  1511   from aux1 show ?thesis by (auto simp add: divAlg_mod_div Let_def aux2 aux3)

  1512 qed

  1513

  1514 end

  1515

  1516 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"

  1517 proof

  1518   assume H: "x mod n = y mod n"

  1519   hence "x mod n - y mod n = 0" by simp

  1520   hence "(x mod n - y mod n) mod n = 0" by simp

  1521   hence "(x - y) mod n = 0" by (simp add: zmod_zdiff1_eq[symmetric])

  1522   thus "n dvd x - y" by (simp add: zdvd_iff_zmod_eq_0)

  1523 next

  1524   assume H: "n dvd x - y"

  1525   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast

  1526   hence "x = n*k + y" by simp

  1527   hence "x mod n = (n*k + y) mod n" by simp

  1528   thus "x mod n = y mod n" by (simp add: zmod_zadd_left_eq)

  1529 qed

  1530

  1531 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"

  1532   shows "\<exists>q. x = y + n * q"

  1533 proof-

  1534   from xy have th: "int x - int y = int (x - y)" by simp

  1535   from xyn have "int x mod int n = int y mod int n"

  1536     by (simp add: zmod_int[symmetric])

  1537   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric])

  1538   hence "n dvd x - y" by (simp add: th zdvd_int)

  1539   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith

  1540 qed

  1541

  1542 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)"

  1543   (is "?lhs = ?rhs")

  1544 proof

  1545   assume H: "x mod n = y mod n"

  1546   {assume xy: "x \<le> y"

  1547     from H have th: "y mod n = x mod n" by simp

  1548     from nat_mod_eq_lemma[OF th xy] have ?rhs

  1549       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}

  1550   moreover

  1551   {assume xy: "y \<le> x"

  1552     from nat_mod_eq_lemma[OF H xy] have ?rhs

  1553       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}

  1554   ultimately  show ?rhs using linear[of x y] by blast

  1555 next

  1556   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast

  1557   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp

  1558   thus  ?lhs by simp

  1559 qed

  1560

  1561 code_modulename SML

  1562   IntDiv Integer

  1563

  1564 code_modulename OCaml

  1565   IntDiv Integer

  1566

  1567 code_modulename Haskell

  1568   IntDiv Integer

  1569

  1570 end
`