src/HOL/Lattices.thy
author wenzelm
Wed Sep 17 21:27:14 2008 +0200 (2008-09-17)
changeset 28263 69eaa97e7e96
parent 27682 25aceefd4786
child 28562 4e74209f113e
permissions -rw-r--r--
moved global ML bindings to global place;
     1 (*  Title:      HOL/Lattices.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* Abstract lattices *}
     7 
     8 theory Lattices
     9 imports Fun
    10 begin
    11 
    12 subsection{* Lattices *}
    13 
    14 notation
    15   less_eq  (infix "\<sqsubseteq>" 50) and
    16   less  (infix "\<sqsubset>" 50)
    17 
    18 class lower_semilattice = order +
    19   fixes inf :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<sqinter>" 70)
    20   assumes inf_le1 [simp]: "x \<sqinter> y \<sqsubseteq> x"
    21   and inf_le2 [simp]: "x \<sqinter> y \<sqsubseteq> y"
    22   and inf_greatest: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<sqinter> z"
    23 
    24 class upper_semilattice = order +
    25   fixes sup :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<squnion>" 65)
    26   assumes sup_ge1 [simp]: "x \<sqsubseteq> x \<squnion> y"
    27   and sup_ge2 [simp]: "y \<sqsubseteq> x \<squnion> y"
    28   and sup_least: "y \<sqsubseteq> x \<Longrightarrow> z \<sqsubseteq> x \<Longrightarrow> y \<squnion> z \<sqsubseteq> x"
    29 begin
    30 
    31 text {* Dual lattice *}
    32 
    33 lemma dual_lattice:
    34   "lower_semilattice (op \<ge>) (op >) sup"
    35 by (rule lower_semilattice.intro, rule dual_order)
    36   (unfold_locales, simp_all add: sup_least)
    37 
    38 end
    39 
    40 class lattice = lower_semilattice + upper_semilattice
    41 
    42 
    43 subsubsection{* Intro and elim rules*}
    44 
    45 context lower_semilattice
    46 begin
    47 
    48 lemma le_infI1[intro]:
    49   assumes "a \<sqsubseteq> x"
    50   shows "a \<sqinter> b \<sqsubseteq> x"
    51 proof (rule order_trans)
    52   from assms show "a \<sqsubseteq> x" .
    53   show "a \<sqinter> b \<sqsubseteq> a" by simp 
    54 qed
    55 lemmas (in -) [rule del] = le_infI1
    56 
    57 lemma le_infI2[intro]:
    58   assumes "b \<sqsubseteq> x"
    59   shows "a \<sqinter> b \<sqsubseteq> x"
    60 proof (rule order_trans)
    61   from assms show "b \<sqsubseteq> x" .
    62   show "a \<sqinter> b \<sqsubseteq> b" by simp
    63 qed
    64 lemmas (in -) [rule del] = le_infI2
    65 
    66 lemma le_infI[intro!]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<sqinter> b"
    67 by(blast intro: inf_greatest)
    68 lemmas (in -) [rule del] = le_infI
    69 
    70 lemma le_infE [elim!]: "x \<sqsubseteq> a \<sqinter> b \<Longrightarrow> (x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> P) \<Longrightarrow> P"
    71   by (blast intro: order_trans)
    72 lemmas (in -) [rule del] = le_infE
    73 
    74 lemma le_inf_iff [simp]:
    75   "x \<sqsubseteq> y \<sqinter> z = (x \<sqsubseteq> y \<and> x \<sqsubseteq> z)"
    76 by blast
    77 
    78 lemma le_iff_inf: "(x \<sqsubseteq> y) = (x \<sqinter> y = x)"
    79   by (blast intro: antisym dest: eq_iff [THEN iffD1])
    80 
    81 lemma mono_inf:
    82   fixes f :: "'a \<Rightarrow> 'b\<Colon>lower_semilattice"
    83   shows "mono f \<Longrightarrow> f (A \<sqinter> B) \<le> f A \<sqinter> f B"
    84   by (auto simp add: mono_def intro: Lattices.inf_greatest)
    85 
    86 end
    87 
    88 context upper_semilattice
    89 begin
    90 
    91 lemma le_supI1[intro]: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    92   by (rule order_trans) auto
    93 lemmas (in -) [rule del] = le_supI1
    94 
    95 lemma le_supI2[intro]: "x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    96   by (rule order_trans) auto 
    97 lemmas (in -) [rule del] = le_supI2
    98 
    99 lemma le_supI[intro!]: "a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> a \<squnion> b \<sqsubseteq> x"
   100   by (blast intro: sup_least)
   101 lemmas (in -) [rule del] = le_supI
   102 
   103 lemma le_supE[elim!]: "a \<squnion> b \<sqsubseteq> x \<Longrightarrow> (a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> P) \<Longrightarrow> P"
   104   by (blast intro: order_trans)
   105 lemmas (in -) [rule del] = le_supE
   106 
   107 lemma ge_sup_conv[simp]:
   108   "x \<squnion> y \<sqsubseteq> z = (x \<sqsubseteq> z \<and> y \<sqsubseteq> z)"
   109 by blast
   110 
   111 lemma le_iff_sup: "(x \<sqsubseteq> y) = (x \<squnion> y = y)"
   112   by (blast intro: antisym dest: eq_iff [THEN iffD1])
   113 
   114 lemma mono_sup:
   115   fixes f :: "'a \<Rightarrow> 'b\<Colon>upper_semilattice"
   116   shows "mono f \<Longrightarrow> f A \<squnion> f B \<le> f (A \<squnion> B)"
   117   by (auto simp add: mono_def intro: Lattices.sup_least)
   118 
   119 end
   120 
   121 
   122 subsubsection{* Equational laws *}
   123 
   124 context lower_semilattice
   125 begin
   126 
   127 lemma inf_commute: "(x \<sqinter> y) = (y \<sqinter> x)"
   128   by (blast intro: antisym)
   129 
   130 lemma inf_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
   131   by (blast intro: antisym)
   132 
   133 lemma inf_idem[simp]: "x \<sqinter> x = x"
   134   by (blast intro: antisym)
   135 
   136 lemma inf_left_idem[simp]: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
   137   by (blast intro: antisym)
   138 
   139 lemma inf_absorb1: "x \<sqsubseteq> y \<Longrightarrow> x \<sqinter> y = x"
   140   by (blast intro: antisym)
   141 
   142 lemma inf_absorb2: "y \<sqsubseteq> x \<Longrightarrow> x \<sqinter> y = y"
   143   by (blast intro: antisym)
   144 
   145 lemma inf_left_commute: "x \<sqinter> (y \<sqinter> z) = y \<sqinter> (x \<sqinter> z)"
   146   by (blast intro: antisym)
   147 
   148 lemmas inf_ACI = inf_commute inf_assoc inf_left_commute inf_left_idem
   149 
   150 end
   151 
   152 
   153 context upper_semilattice
   154 begin
   155 
   156 lemma sup_commute: "(x \<squnion> y) = (y \<squnion> x)"
   157   by (blast intro: antisym)
   158 
   159 lemma sup_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
   160   by (blast intro: antisym)
   161 
   162 lemma sup_idem[simp]: "x \<squnion> x = x"
   163   by (blast intro: antisym)
   164 
   165 lemma sup_left_idem[simp]: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
   166   by (blast intro: antisym)
   167 
   168 lemma sup_absorb1: "y \<sqsubseteq> x \<Longrightarrow> x \<squnion> y = x"
   169   by (blast intro: antisym)
   170 
   171 lemma sup_absorb2: "x \<sqsubseteq> y \<Longrightarrow> x \<squnion> y = y"
   172   by (blast intro: antisym)
   173 
   174 lemma sup_left_commute: "x \<squnion> (y \<squnion> z) = y \<squnion> (x \<squnion> z)"
   175   by (blast intro: antisym)
   176 
   177 lemmas sup_ACI = sup_commute sup_assoc sup_left_commute sup_left_idem
   178 
   179 end
   180 
   181 context lattice
   182 begin
   183 
   184 lemma inf_sup_absorb: "x \<sqinter> (x \<squnion> y) = x"
   185   by (blast intro: antisym inf_le1 inf_greatest sup_ge1)
   186 
   187 lemma sup_inf_absorb: "x \<squnion> (x \<sqinter> y) = x"
   188   by (blast intro: antisym sup_ge1 sup_least inf_le1)
   189 
   190 lemmas ACI = inf_ACI sup_ACI
   191 
   192 lemmas inf_sup_ord = inf_le1 inf_le2 sup_ge1 sup_ge2
   193 
   194 text{* Towards distributivity *}
   195 
   196 lemma distrib_sup_le: "x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   197   by blast
   198 
   199 lemma distrib_inf_le: "(x \<sqinter> y) \<squnion> (x \<sqinter> z) \<sqsubseteq> x \<sqinter> (y \<squnion> z)"
   200   by blast
   201 
   202 
   203 text{* If you have one of them, you have them all. *}
   204 
   205 lemma distrib_imp1:
   206 assumes D: "!!x y z. x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   207 shows "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   208 proof-
   209   have "x \<squnion> (y \<sqinter> z) = (x \<squnion> (x \<sqinter> z)) \<squnion> (y \<sqinter> z)" by(simp add:sup_inf_absorb)
   210   also have "\<dots> = x \<squnion> (z \<sqinter> (x \<squnion> y))" by(simp add:D inf_commute sup_assoc)
   211   also have "\<dots> = ((x \<squnion> y) \<sqinter> x) \<squnion> ((x \<squnion> y) \<sqinter> z)"
   212     by(simp add:inf_sup_absorb inf_commute)
   213   also have "\<dots> = (x \<squnion> y) \<sqinter> (x \<squnion> z)" by(simp add:D)
   214   finally show ?thesis .
   215 qed
   216 
   217 lemma distrib_imp2:
   218 assumes D: "!!x y z. x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   219 shows "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   220 proof-
   221   have "x \<sqinter> (y \<squnion> z) = (x \<sqinter> (x \<squnion> z)) \<sqinter> (y \<squnion> z)" by(simp add:inf_sup_absorb)
   222   also have "\<dots> = x \<sqinter> (z \<squnion> (x \<sqinter> y))" by(simp add:D sup_commute inf_assoc)
   223   also have "\<dots> = ((x \<sqinter> y) \<squnion> x) \<sqinter> ((x \<sqinter> y) \<squnion> z)"
   224     by(simp add:sup_inf_absorb sup_commute)
   225   also have "\<dots> = (x \<sqinter> y) \<squnion> (x \<sqinter> z)" by(simp add:D)
   226   finally show ?thesis .
   227 qed
   228 
   229 (* seems unused *)
   230 lemma modular_le: "x \<sqsubseteq> z \<Longrightarrow> x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> z"
   231 by blast
   232 
   233 end
   234 
   235 
   236 subsection {* Distributive lattices *}
   237 
   238 class distrib_lattice = lattice +
   239   assumes sup_inf_distrib1: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   240 
   241 context distrib_lattice
   242 begin
   243 
   244 lemma sup_inf_distrib2:
   245  "(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
   246 by(simp add:ACI sup_inf_distrib1)
   247 
   248 lemma inf_sup_distrib1:
   249  "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   250 by(rule distrib_imp2[OF sup_inf_distrib1])
   251 
   252 lemma inf_sup_distrib2:
   253  "(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
   254 by(simp add:ACI inf_sup_distrib1)
   255 
   256 lemmas distrib =
   257   sup_inf_distrib1 sup_inf_distrib2 inf_sup_distrib1 inf_sup_distrib2
   258 
   259 end
   260 
   261 
   262 subsection {* Uniqueness of inf and sup *}
   263 
   264 lemma (in lower_semilattice) inf_unique:
   265   fixes f (infixl "\<triangle>" 70)
   266   assumes le1: "\<And>x y. x \<triangle> y \<le> x" and le2: "\<And>x y. x \<triangle> y \<le> y"
   267   and greatest: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z"
   268   shows "x \<sqinter> y = x \<triangle> y"
   269 proof (rule antisym)
   270   show "x \<triangle> y \<le> x \<sqinter> y" by (rule le_infI) (rule le1, rule le2)
   271 next
   272   have leI: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z" by (blast intro: greatest)
   273   show "x \<sqinter> y \<le> x \<triangle> y" by (rule leI) simp_all
   274 qed
   275 
   276 lemma (in upper_semilattice) sup_unique:
   277   fixes f (infixl "\<nabla>" 70)
   278   assumes ge1 [simp]: "\<And>x y. x \<le> x \<nabla> y" and ge2: "\<And>x y. y \<le> x \<nabla> y"
   279   and least: "\<And>x y z. y \<le> x \<Longrightarrow> z \<le> x \<Longrightarrow> y \<nabla> z \<le> x"
   280   shows "x \<squnion> y = x \<nabla> y"
   281 proof (rule antisym)
   282   show "x \<squnion> y \<le> x \<nabla> y" by (rule le_supI) (rule ge1, rule ge2)
   283 next
   284   have leI: "\<And>x y z. x \<le> z \<Longrightarrow> y \<le> z \<Longrightarrow> x \<nabla> y \<le> z" by (blast intro: least)
   285   show "x \<nabla> y \<le> x \<squnion> y" by (rule leI) simp_all
   286 qed
   287   
   288 
   289 subsection {* @{const min}/@{const max} on linear orders as
   290   special case of @{const inf}/@{const sup} *}
   291 
   292 lemma (in linorder) distrib_lattice_min_max:
   293   "distrib_lattice (op \<le>) (op <) min max"
   294 proof unfold_locales
   295   have aux: "\<And>x y \<Colon> 'a. x < y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   296     by (auto simp add: less_le antisym)
   297   fix x y z
   298   show "max x (min y z) = min (max x y) (max x z)"
   299   unfolding min_def max_def
   300   by auto
   301 qed (auto simp add: min_def max_def not_le less_imp_le)
   302 
   303 interpretation min_max:
   304   distrib_lattice ["op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool" "op <" min max]
   305   by (rule distrib_lattice_min_max)
   306 
   307 lemma inf_min: "inf = (min \<Colon> 'a\<Colon>{lower_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   308   by (rule ext)+ (auto intro: antisym)
   309 
   310 lemma sup_max: "sup = (max \<Colon> 'a\<Colon>{upper_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   311   by (rule ext)+ (auto intro: antisym)
   312 
   313 lemmas le_maxI1 = min_max.sup_ge1
   314 lemmas le_maxI2 = min_max.sup_ge2
   315  
   316 lemmas max_ac = min_max.sup_assoc min_max.sup_commute
   317   mk_left_commute [of max, OF min_max.sup_assoc min_max.sup_commute]
   318 
   319 lemmas min_ac = min_max.inf_assoc min_max.inf_commute
   320   mk_left_commute [of min, OF min_max.inf_assoc min_max.inf_commute]
   321 
   322 text {*
   323   Now we have inherited antisymmetry as an intro-rule on all
   324   linear orders. This is a problem because it applies to bool, which is
   325   undesirable.
   326 *}
   327 
   328 lemmas [rule del] = min_max.le_infI min_max.le_supI
   329   min_max.le_supE min_max.le_infE min_max.le_supI1 min_max.le_supI2
   330   min_max.le_infI1 min_max.le_infI2
   331 
   332 
   333 subsection {* Complete lattices *}
   334 
   335 class complete_lattice = lattice +
   336   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
   337     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
   338   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   339      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   340   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   341      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   342 begin
   343 
   344 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<le> a}"
   345   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   346 
   347 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<le> b}"
   348   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   349 
   350 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
   351   unfolding Sup_Inf by auto
   352 
   353 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
   354   unfolding Inf_Sup by auto
   355 
   356 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   357   by (auto intro: antisym Inf_greatest Inf_lower)
   358 
   359 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   360   by (auto intro: antisym Sup_least Sup_upper)
   361 
   362 lemma Inf_singleton [simp]:
   363   "\<Sqinter>{a} = a"
   364   by (auto intro: antisym Inf_lower Inf_greatest)
   365 
   366 lemma Sup_singleton [simp]:
   367   "\<Squnion>{a} = a"
   368   by (auto intro: antisym Sup_upper Sup_least)
   369 
   370 lemma Inf_insert_simp:
   371   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
   372   by (cases "A = {}") (simp_all, simp add: Inf_insert)
   373 
   374 lemma Sup_insert_simp:
   375   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
   376   by (cases "A = {}") (simp_all, simp add: Sup_insert)
   377 
   378 lemma Inf_binary:
   379   "\<Sqinter>{a, b} = a \<sqinter> b"
   380   by (simp add: Inf_insert_simp)
   381 
   382 lemma Sup_binary:
   383   "\<Squnion>{a, b} = a \<squnion> b"
   384   by (simp add: Sup_insert_simp)
   385 
   386 definition
   387   top :: 'a where
   388   "top = \<Sqinter>{}"
   389 
   390 definition
   391   bot :: 'a where
   392   "bot = \<Squnion>{}"
   393 
   394 lemma top_greatest [simp]: "x \<le> top"
   395   by (unfold top_def, rule Inf_greatest, simp)
   396 
   397 lemma bot_least [simp]: "bot \<le> x"
   398   by (unfold bot_def, rule Sup_least, simp)
   399 
   400 definition
   401   SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a"
   402 where
   403   "SUPR A f == \<Squnion> (f ` A)"
   404 
   405 definition
   406   INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a"
   407 where
   408   "INFI A f == \<Sqinter> (f ` A)"
   409 
   410 end
   411 
   412 syntax
   413   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
   414   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
   415   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
   416   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
   417 
   418 translations
   419   "SUP x y. B"   == "SUP x. SUP y. B"
   420   "SUP x. B"     == "CONST SUPR UNIV (%x. B)"
   421   "SUP x. B"     == "SUP x:UNIV. B"
   422   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   423   "INF x y. B"   == "INF x. INF y. B"
   424   "INF x. B"     == "CONST INFI UNIV (%x. B)"
   425   "INF x. B"     == "INF x:UNIV. B"
   426   "INF x:A. B"   == "CONST INFI A (%x. B)"
   427 
   428 (* To avoid eta-contraction of body: *)
   429 print_translation {*
   430 let
   431   fun btr' syn (A :: Abs abs :: ts) =
   432     let val (x,t) = atomic_abs_tr' abs
   433     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
   434   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
   435 in
   436 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
   437 end
   438 *}
   439 
   440 context complete_lattice
   441 begin
   442 
   443 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
   444   by (auto simp add: SUPR_def intro: Sup_upper)
   445 
   446 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
   447   by (auto simp add: SUPR_def intro: Sup_least)
   448 
   449 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
   450   by (auto simp add: INFI_def intro: Inf_lower)
   451 
   452 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
   453   by (auto simp add: INFI_def intro: Inf_greatest)
   454 
   455 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   456   by (auto intro: antisym SUP_leI le_SUPI)
   457 
   458 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   459   by (auto intro: antisym INF_leI le_INFI)
   460 
   461 end
   462 
   463 
   464 subsection {* Bool as lattice *}
   465 
   466 instantiation bool :: distrib_lattice
   467 begin
   468 
   469 definition
   470   inf_bool_eq: "P \<sqinter> Q \<longleftrightarrow> P \<and> Q"
   471 
   472 definition
   473   sup_bool_eq: "P \<squnion> Q \<longleftrightarrow> P \<or> Q"
   474 
   475 instance
   476   by intro_classes (auto simp add: inf_bool_eq sup_bool_eq le_bool_def)
   477 
   478 end
   479 
   480 instantiation bool :: complete_lattice
   481 begin
   482 
   483 definition
   484   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   485 
   486 definition
   487   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   488 
   489 instance
   490   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   491 
   492 end
   493 
   494 lemma Inf_empty_bool [simp]:
   495   "\<Sqinter>{}"
   496   unfolding Inf_bool_def by auto
   497 
   498 lemma not_Sup_empty_bool [simp]:
   499   "\<not> Sup {}"
   500   unfolding Sup_bool_def by auto
   501 
   502 lemma top_bool_eq: "top = True"
   503   by (iprover intro!: order_antisym le_boolI top_greatest)
   504 
   505 lemma bot_bool_eq: "bot = False"
   506   by (iprover intro!: order_antisym le_boolI bot_least)
   507 
   508 
   509 subsection {* Fun as lattice *}
   510 
   511 instantiation "fun" :: (type, lattice) lattice
   512 begin
   513 
   514 definition
   515   inf_fun_eq [code func del]: "f \<sqinter> g = (\<lambda>x. f x \<sqinter> g x)"
   516 
   517 definition
   518   sup_fun_eq [code func del]: "f \<squnion> g = (\<lambda>x. f x \<squnion> g x)"
   519 
   520 instance
   521 apply intro_classes
   522 unfolding inf_fun_eq sup_fun_eq
   523 apply (auto intro: le_funI)
   524 apply (rule le_funI)
   525 apply (auto dest: le_funD)
   526 apply (rule le_funI)
   527 apply (auto dest: le_funD)
   528 done
   529 
   530 end
   531 
   532 instance "fun" :: (type, distrib_lattice) distrib_lattice
   533   by default (auto simp add: inf_fun_eq sup_fun_eq sup_inf_distrib1)
   534 
   535 instantiation "fun" :: (type, complete_lattice) complete_lattice
   536 begin
   537 
   538 definition
   539   Inf_fun_def [code func del]: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   540 
   541 definition
   542   Sup_fun_def [code func del]: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   543 
   544 instance
   545   by intro_classes
   546     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
   547       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   548 
   549 end
   550 
   551 lemma Inf_empty_fun:
   552   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
   553   by rule (auto simp add: Inf_fun_def)
   554 
   555 lemma Sup_empty_fun:
   556   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
   557   by rule (auto simp add: Sup_fun_def)
   558 
   559 lemma top_fun_eq: "top = (\<lambda>x. top)"
   560   by (iprover intro!: order_antisym le_funI top_greatest)
   561 
   562 lemma bot_fun_eq: "bot = (\<lambda>x. bot)"
   563   by (iprover intro!: order_antisym le_funI bot_least)
   564 
   565 
   566 subsection {* Set as lattice *}
   567 
   568 lemma inf_set_eq: "A \<sqinter> B = A \<inter> B"
   569   apply (rule subset_antisym)
   570   apply (rule Int_greatest)
   571   apply (rule inf_le1)
   572   apply (rule inf_le2)
   573   apply (rule inf_greatest)
   574   apply (rule Int_lower1)
   575   apply (rule Int_lower2)
   576   done
   577 
   578 lemma sup_set_eq: "A \<squnion> B = A \<union> B"
   579   apply (rule subset_antisym)
   580   apply (rule sup_least)
   581   apply (rule Un_upper1)
   582   apply (rule Un_upper2)
   583   apply (rule Un_least)
   584   apply (rule sup_ge1)
   585   apply (rule sup_ge2)
   586   done
   587 
   588 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
   589   apply (fold inf_set_eq sup_set_eq)
   590   apply (erule mono_inf)
   591   done
   592 
   593 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
   594   apply (fold inf_set_eq sup_set_eq)
   595   apply (erule mono_sup)
   596   done
   597 
   598 lemma Inf_set_eq: "\<Sqinter>S = \<Inter>S"
   599   apply (rule subset_antisym)
   600   apply (rule Inter_greatest)
   601   apply (erule Inf_lower)
   602   apply (rule Inf_greatest)
   603   apply (erule Inter_lower)
   604   done
   605 
   606 lemma Sup_set_eq: "\<Squnion>S = \<Union>S"
   607   apply (rule subset_antisym)
   608   apply (rule Sup_least)
   609   apply (erule Union_upper)
   610   apply (rule Union_least)
   611   apply (erule Sup_upper)
   612   done
   613   
   614 lemma top_set_eq: "top = UNIV"
   615   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
   616 
   617 lemma bot_set_eq: "bot = {}"
   618   by (iprover intro!: subset_antisym empty_subsetI bot_least)
   619 
   620 
   621 text {* redundant bindings *}
   622 
   623 lemmas inf_aci = inf_ACI
   624 lemmas sup_aci = sup_ACI
   625 
   626 no_notation
   627   less_eq  (infix "\<sqsubseteq>" 50) and
   628   less (infix "\<sqsubset>" 50) and
   629   inf  (infixl "\<sqinter>" 70) and
   630   sup  (infixl "\<squnion>" 65) and
   631   Inf  ("\<Sqinter>_" [900] 900) and
   632   Sup  ("\<Squnion>_" [900] 900)
   633 
   634 end