src/HOL/Nat.thy
author wenzelm
Wed Sep 17 21:27:14 2008 +0200 (2008-09-17)
changeset 28263 69eaa97e7e96
parent 27823 52971512d1a2
child 28514 da83a614c454
permissions -rw-r--r--
moved global ML bindings to global place;
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat
    47   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc ::   "nat => nat"
    51   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   apply (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    67     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    68   done
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 rep_datatype "0 \<Colon> nat" Suc
    74   apply (unfold Zero_nat_def Suc_def)
    75      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    76      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    77      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    78     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    79       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    80       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    81       inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    82   done
    83 
    84 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    85   -- {* for backward compatibility -- naming of variables differs *}
    86   fixes n
    87   assumes "P 0"
    88     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    89   shows "P n"
    90   using assms by (rule nat.induct) 
    91 
    92 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    93 
    94 lemmas nat_rec_0 = nat.recs(1)
    95   and nat_rec_Suc = nat.recs(2)
    96 
    97 lemmas nat_case_0 = nat.cases(1)
    98   and nat_case_Suc = nat.cases(2)
    99    
   100 
   101 text {* Injectiveness and distinctness lemmas *}
   102 
   103 lemma inj_Suc[simp]: "inj_on Suc N"
   104   by (simp add: inj_on_def)
   105 
   106 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   107 by (rule notE, rule Suc_not_Zero)
   108 
   109 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   110 by (rule Suc_neq_Zero, erule sym)
   111 
   112 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   113 by (rule inj_Suc [THEN injD])
   114 
   115 lemma n_not_Suc_n: "n \<noteq> Suc n"
   116 by (induct n) simp_all
   117 
   118 lemma Suc_n_not_n: "Suc n \<noteq> n"
   119 by (rule not_sym, rule n_not_Suc_n)
   120 
   121 text {* A special form of induction for reasoning
   122   about @{term "m < n"} and @{term "m - n"} *}
   123 
   124 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   125     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   126   apply (rule_tac x = m in spec)
   127   apply (induct n)
   128   prefer 2
   129   apply (rule allI)
   130   apply (induct_tac x, iprover+)
   131   done
   132 
   133 
   134 subsection {* Arithmetic operators *}
   135 
   136 instantiation nat :: "{minus, comm_monoid_add}"
   137 begin
   138 
   139 primrec plus_nat
   140 where
   141   add_0:      "0 + n = (n\<Colon>nat)"
   142   | add_Suc:  "Suc m + n = Suc (m + n)"
   143 
   144 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   145   by (induct m) simp_all
   146 
   147 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   148   by (induct m) simp_all
   149 
   150 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   151   by simp
   152 
   153 primrec minus_nat
   154 where
   155   diff_0:     "m - 0 = (m\<Colon>nat)"
   156   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   157 
   158 declare diff_Suc [simp del, code del]
   159 
   160 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   161   by (induct n) (simp_all add: diff_Suc)
   162 
   163 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   164   by (induct n) (simp_all add: diff_Suc)
   165 
   166 instance proof
   167   fix n m q :: nat
   168   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   169   show "n + m = m + n" by (induct n) simp_all
   170   show "0 + n = n" by simp
   171 qed
   172 
   173 end
   174 
   175 instantiation nat :: comm_semiring_1_cancel
   176 begin
   177 
   178 definition
   179   One_nat_def [simp]: "1 = Suc 0"
   180 
   181 primrec times_nat
   182 where
   183   mult_0:     "0 * n = (0\<Colon>nat)"
   184   | mult_Suc: "Suc m * n = n + (m * n)"
   185 
   186 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   187   by (induct m) simp_all
   188 
   189 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   190   by (induct m) (simp_all add: add_left_commute)
   191 
   192 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   193   by (induct m) (simp_all add: add_assoc)
   194 
   195 instance proof
   196   fix n m q :: nat
   197   show "0 \<noteq> (1::nat)" by simp
   198   show "1 * n = n" by simp
   199   show "n * m = m * n" by (induct n) simp_all
   200   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   201   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   202   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   203 qed
   204 
   205 end
   206 
   207 subsubsection {* Addition *}
   208 
   209 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   210   by (rule add_assoc)
   211 
   212 lemma nat_add_commute: "m + n = n + (m::nat)"
   213   by (rule add_commute)
   214 
   215 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   216   by (rule add_left_commute)
   217 
   218 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   219   by (rule add_left_cancel)
   220 
   221 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   222   by (rule add_right_cancel)
   223 
   224 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   225 
   226 lemma add_is_0 [iff]:
   227   fixes m n :: nat
   228   shows "(m + n = 0) = (m = 0 & n = 0)"
   229   by (cases m) simp_all
   230 
   231 lemma add_is_1:
   232   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   233   by (cases m) simp_all
   234 
   235 lemma one_is_add:
   236   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   237   by (rule trans, rule eq_commute, rule add_is_1)
   238 
   239 lemma add_eq_self_zero:
   240   fixes m n :: nat
   241   shows "m + n = m \<Longrightarrow> n = 0"
   242   by (induct m) simp_all
   243 
   244 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   245   apply (induct k)
   246    apply simp
   247   apply(drule comp_inj_on[OF _ inj_Suc])
   248   apply (simp add:o_def)
   249   done
   250 
   251 
   252 subsubsection {* Difference *}
   253 
   254 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   255   by (induct m) simp_all
   256 
   257 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   258   by (induct i j rule: diff_induct) simp_all
   259 
   260 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   261   by (simp add: diff_diff_left)
   262 
   263 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   264   by (simp add: diff_diff_left add_commute)
   265 
   266 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   267   by (induct n) simp_all
   268 
   269 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   270   by (simp add: diff_add_inverse add_commute [of m n])
   271 
   272 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   273   by (induct k) simp_all
   274 
   275 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   276   by (simp add: diff_cancel add_commute)
   277 
   278 lemma diff_add_0: "n - (n + m) = (0::nat)"
   279   by (induct n) simp_all
   280 
   281 text {* Difference distributes over multiplication *}
   282 
   283 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   284 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   285 
   286 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   287 by (simp add: diff_mult_distrib mult_commute [of k])
   288   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   289 
   290 
   291 subsubsection {* Multiplication *}
   292 
   293 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   294   by (rule mult_assoc)
   295 
   296 lemma nat_mult_commute: "m * n = n * (m::nat)"
   297   by (rule mult_commute)
   298 
   299 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   300   by (rule right_distrib)
   301 
   302 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   303   by (induct m) auto
   304 
   305 lemmas nat_distrib =
   306   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   307 
   308 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   309   apply (induct m)
   310    apply simp
   311   apply (induct n)
   312    apply auto
   313   done
   314 
   315 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   316   apply (rule trans)
   317   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   318   done
   319 
   320 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   321 proof -
   322   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   323   proof (induct n arbitrary: m)
   324     case 0 then show "m = 0" by simp
   325   next
   326     case (Suc n) then show "m = Suc n"
   327       by (cases m) (simp_all add: eq_commute [of "0"])
   328   qed
   329   then show ?thesis by auto
   330 qed
   331 
   332 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   333   by (simp add: mult_commute)
   334 
   335 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   336   by (subst mult_cancel1) simp
   337 
   338 
   339 subsection {* Orders on @{typ nat} *}
   340 
   341 subsubsection {* Operation definition *}
   342 
   343 instantiation nat :: linorder
   344 begin
   345 
   346 primrec less_eq_nat where
   347   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   348   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   349 
   350 declare less_eq_nat.simps [simp del, code del]
   351 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   352 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   353 
   354 definition less_nat where
   355   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   356 
   357 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   358   by (simp add: less_eq_nat.simps(2))
   359 
   360 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   361   unfolding less_eq_Suc_le ..
   362 
   363 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   364   by (induct n) (simp_all add: less_eq_nat.simps(2))
   365 
   366 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   367   by (simp add: less_eq_Suc_le)
   368 
   369 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   370   by simp
   371 
   372 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   373   by (simp add: less_eq_Suc_le)
   374 
   375 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   376   by (simp add: less_eq_Suc_le)
   377 
   378 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   379   by (induct m arbitrary: n)
   380     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   381 
   382 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   383   by (cases n) (auto intro: le_SucI)
   384 
   385 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   386   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   387 
   388 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   389   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   390 
   391 instance
   392 proof
   393   fix n m :: nat
   394   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   395   proof (induct n arbitrary: m)
   396     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   397   next
   398     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   399   qed
   400 next
   401   fix n :: nat show "n \<le> n" by (induct n) simp_all
   402 next
   403   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   404   then show "n = m"
   405     by (induct n arbitrary: m)
   406       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   407 next
   408   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   409   then show "n \<le> q"
   410   proof (induct n arbitrary: m q)
   411     case 0 show ?case by simp
   412   next
   413     case (Suc n) then show ?case
   414       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   415         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   416         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   417   qed
   418 next
   419   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   420     by (induct n arbitrary: m)
   421       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   422 qed
   423 
   424 end
   425 
   426 subsubsection {* Introduction properties *}
   427 
   428 lemma lessI [iff]: "n < Suc n"
   429   by (simp add: less_Suc_eq_le)
   430 
   431 lemma zero_less_Suc [iff]: "0 < Suc n"
   432   by (simp add: less_Suc_eq_le)
   433 
   434 
   435 subsubsection {* Elimination properties *}
   436 
   437 lemma less_not_refl: "~ n < (n::nat)"
   438   by (rule order_less_irrefl)
   439 
   440 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   441   by (rule not_sym) (rule less_imp_neq) 
   442 
   443 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   444   by (rule less_imp_neq)
   445 
   446 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   447   by (rule notE, rule less_not_refl)
   448 
   449 lemma less_zeroE: "(n::nat) < 0 ==> R"
   450   by (rule notE) (rule not_less0)
   451 
   452 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   453   unfolding less_Suc_eq_le le_less ..
   454 
   455 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   456   by (simp add: less_Suc_eq)
   457 
   458 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   459   by (simp add: less_Suc_eq)
   460 
   461 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   462   by simp
   463 
   464 text {* "Less than" is antisymmetric, sort of *}
   465 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   466   unfolding not_less less_Suc_eq_le by (rule antisym)
   467 
   468 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   469   by (rule linorder_neq_iff)
   470 
   471 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   472   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   473   shows "P n m"
   474   apply (rule less_linear [THEN disjE])
   475   apply (erule_tac [2] disjE)
   476   apply (erule lessCase)
   477   apply (erule sym [THEN eqCase])
   478   apply (erule major)
   479   done
   480 
   481 
   482 subsubsection {* Inductive (?) properties *}
   483 
   484 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   485   unfolding less_eq_Suc_le [of m] le_less by simp 
   486 
   487 lemma lessE:
   488   assumes major: "i < k"
   489   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   490   shows P
   491 proof -
   492   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   493     unfolding less_eq_Suc_le by (induct k) simp_all
   494   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   495     by (clarsimp simp add: less_le)
   496   with p1 p2 show P by auto
   497 qed
   498 
   499 lemma less_SucE: assumes major: "m < Suc n"
   500   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   501   apply (rule major [THEN lessE])
   502   apply (rule eq, blast)
   503   apply (rule less, blast)
   504   done
   505 
   506 lemma Suc_lessE: assumes major: "Suc i < k"
   507   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   508   apply (rule major [THEN lessE])
   509   apply (erule lessI [THEN minor])
   510   apply (erule Suc_lessD [THEN minor], assumption)
   511   done
   512 
   513 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   514   by simp
   515 
   516 lemma less_trans_Suc:
   517   assumes le: "i < j" shows "j < k ==> Suc i < k"
   518   apply (induct k, simp_all)
   519   apply (insert le)
   520   apply (simp add: less_Suc_eq)
   521   apply (blast dest: Suc_lessD)
   522   done
   523 
   524 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   525 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   526   unfolding not_less less_Suc_eq_le ..
   527 
   528 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   529   unfolding not_le Suc_le_eq ..
   530 
   531 text {* Properties of "less than or equal" *}
   532 
   533 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   534   unfolding less_Suc_eq_le .
   535 
   536 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   537   unfolding not_le less_Suc_eq_le ..
   538 
   539 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   540   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   541 
   542 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   543   by (drule le_Suc_eq [THEN iffD1], iprover+)
   544 
   545 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   546   unfolding Suc_le_eq .
   547 
   548 text {* Stronger version of @{text Suc_leD} *}
   549 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   550   unfolding Suc_le_eq .
   551 
   552 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   553   unfolding less_eq_Suc_le by (rule Suc_leD)
   554 
   555 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   556 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   557 
   558 
   559 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   560 
   561 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   562   unfolding le_less .
   563 
   564 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   565   by (rule le_less)
   566 
   567 text {* Useful with @{text blast}. *}
   568 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   569   by auto
   570 
   571 lemma le_refl: "n \<le> (n::nat)"
   572   by simp
   573 
   574 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   575   by (rule order_trans)
   576 
   577 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   578   by (rule antisym)
   579 
   580 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   581   by (rule less_le)
   582 
   583 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   584   unfolding less_le ..
   585 
   586 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   587   by (rule linear)
   588 
   589 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   590 
   591 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   592   unfolding less_Suc_eq_le by auto
   593 
   594 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   595   unfolding not_less by (rule le_less_Suc_eq)
   596 
   597 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   598 
   599 text {* These two rules ease the use of primitive recursion.
   600 NOTE USE OF @{text "=="} *}
   601 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   602 by simp
   603 
   604 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   605 by simp
   606 
   607 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   608 by (cases n) simp_all
   609 
   610 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   611 by (cases n) simp_all
   612 
   613 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   614 by (cases n) simp_all
   615 
   616 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   617 by (cases n) simp_all
   618 
   619 text {* This theorem is useful with @{text blast} *}
   620 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   621 by (rule neq0_conv[THEN iffD1], iprover)
   622 
   623 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   624 by (fast intro: not0_implies_Suc)
   625 
   626 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   627 using neq0_conv by blast
   628 
   629 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   630 by (induct m') simp_all
   631 
   632 text {* Useful in certain inductive arguments *}
   633 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   634 by (cases m) simp_all
   635 
   636 
   637 subsubsection {* @{term min} and @{term max} *}
   638 
   639 lemma mono_Suc: "mono Suc"
   640 by (rule monoI) simp
   641 
   642 lemma min_0L [simp]: "min 0 n = (0::nat)"
   643 by (rule min_leastL) simp
   644 
   645 lemma min_0R [simp]: "min n 0 = (0::nat)"
   646 by (rule min_leastR) simp
   647 
   648 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   649 by (simp add: mono_Suc min_of_mono)
   650 
   651 lemma min_Suc1:
   652    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   653 by (simp split: nat.split)
   654 
   655 lemma min_Suc2:
   656    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   657 by (simp split: nat.split)
   658 
   659 lemma max_0L [simp]: "max 0 n = (n::nat)"
   660 by (rule max_leastL) simp
   661 
   662 lemma max_0R [simp]: "max n 0 = (n::nat)"
   663 by (rule max_leastR) simp
   664 
   665 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   666 by (simp add: mono_Suc max_of_mono)
   667 
   668 lemma max_Suc1:
   669    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   670 by (simp split: nat.split)
   671 
   672 lemma max_Suc2:
   673    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   674 by (simp split: nat.split)
   675 
   676 
   677 subsubsection {* Monotonicity of Addition *}
   678 
   679 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   680 by (simp add: diff_Suc split: nat.split)
   681 
   682 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   683 by (induct k) simp_all
   684 
   685 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   686 by (induct k) simp_all
   687 
   688 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   689 by(auto dest:gr0_implies_Suc)
   690 
   691 text {* strict, in 1st argument *}
   692 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   693 by (induct k) simp_all
   694 
   695 text {* strict, in both arguments *}
   696 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   697   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   698   apply (induct j, simp_all)
   699   done
   700 
   701 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   702 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   703   apply (induct n)
   704   apply (simp_all add: order_le_less)
   705   apply (blast elim!: less_SucE
   706                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   707   done
   708 
   709 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   710 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   711 apply(auto simp: gr0_conv_Suc)
   712 apply (induct_tac m)
   713 apply (simp_all add: add_less_mono)
   714 done
   715 
   716 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   717 instance nat :: ordered_semidom
   718 proof
   719   fix i j k :: nat
   720   show "0 < (1::nat)" by simp
   721   show "i \<le> j ==> k + i \<le> k + j" by simp
   722   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   723 qed
   724 
   725 lemma nat_mult_1: "(1::nat) * n = n"
   726 by simp
   727 
   728 lemma nat_mult_1_right: "n * (1::nat) = n"
   729 by simp
   730 
   731 
   732 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   733 
   734 text {* Complete induction, aka course-of-values induction *}
   735 
   736 instance nat :: wellorder proof
   737   fix P and n :: nat
   738   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   739   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   740   proof (induct n)
   741     case (0 n)
   742     have "P 0" by (rule step) auto
   743     thus ?case using 0 by auto
   744   next
   745     case (Suc m n)
   746     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   747     thus ?case
   748     proof
   749       assume "n \<le> m" thus "P n" by (rule Suc(1))
   750     next
   751       assume n: "n = Suc m"
   752       show "P n"
   753         by (rule step) (rule Suc(1), simp add: n le_simps)
   754     qed
   755   qed
   756   then show "P n" by auto
   757 qed
   758 
   759 lemma Least_Suc:
   760      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   761   apply (case_tac "n", auto)
   762   apply (frule LeastI)
   763   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   764   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   765   apply (erule_tac [2] Least_le)
   766   apply (case_tac "LEAST x. P x", auto)
   767   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   768   apply (blast intro: order_antisym)
   769   done
   770 
   771 lemma Least_Suc2:
   772    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   773   apply (erule (1) Least_Suc [THEN ssubst])
   774   apply simp
   775   done
   776 
   777 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   778   apply (cases n)
   779    apply blast
   780   apply (rule_tac x="LEAST k. P(k)" in exI)
   781   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   782   done
   783 
   784 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   785   apply (cases n)
   786    apply blast
   787   apply (frule (1) ex_least_nat_le)
   788   apply (erule exE)
   789   apply (case_tac k)
   790    apply simp
   791   apply (rename_tac k1)
   792   apply (rule_tac x=k1 in exI)
   793   apply (auto simp add: less_eq_Suc_le)
   794   done
   795 
   796 lemma nat_less_induct:
   797   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   798   using assms less_induct by blast
   799 
   800 lemma measure_induct_rule [case_names less]:
   801   fixes f :: "'a \<Rightarrow> nat"
   802   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   803   shows "P a"
   804 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   805 
   806 text {* old style induction rules: *}
   807 lemma measure_induct:
   808   fixes f :: "'a \<Rightarrow> nat"
   809   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   810   by (rule measure_induct_rule [of f P a]) iprover
   811 
   812 lemma full_nat_induct:
   813   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   814   shows "P n"
   815   by (rule less_induct) (auto intro: step simp:le_simps)
   816 
   817 text{*An induction rule for estabilishing binary relations*}
   818 lemma less_Suc_induct:
   819   assumes less:  "i < j"
   820      and  step:  "!!i. P i (Suc i)"
   821      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   822   shows "P i j"
   823 proof -
   824   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   825   have "P i (Suc (i + k))"
   826   proof (induct k)
   827     case 0
   828     show ?case by (simp add: step)
   829   next
   830     case (Suc k)
   831     thus ?case by (auto intro: assms)
   832   qed
   833   thus "P i j" by (simp add: j)
   834 qed
   835 
   836 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   837   apply (rule nat_less_induct)
   838   apply (case_tac n)
   839   apply (case_tac [2] nat)
   840   apply (blast intro: less_trans)+
   841   done
   842 
   843 text {* The method of infinite descent, frequently used in number theory.
   844 Provided by Roelof Oosterhuis.
   845 $P(n)$ is true for all $n\in\mathbb{N}$ if
   846 \begin{itemize}
   847   \item case ``0'': given $n=0$ prove $P(n)$,
   848   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   849         a smaller integer $m$ such that $\neg P(m)$.
   850 \end{itemize} *}
   851 
   852 text{* A compact version without explicit base case: *}
   853 lemma infinite_descent:
   854   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   855 by (induct n rule: less_induct, auto)
   856 
   857 lemma infinite_descent0[case_names 0 smaller]: 
   858   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   859 by (rule infinite_descent) (case_tac "n>0", auto)
   860 
   861 text {*
   862 Infinite descent using a mapping to $\mathbb{N}$:
   863 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   864 \begin{itemize}
   865 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   866 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   867 \end{itemize}
   868 NB: the proof also shows how to use the previous lemma. *}
   869 
   870 corollary infinite_descent0_measure [case_names 0 smaller]:
   871   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   872     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   873   shows "P x"
   874 proof -
   875   obtain n where "n = V x" by auto
   876   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   877   proof (induct n rule: infinite_descent0)
   878     case 0 -- "i.e. $V(x) = 0$"
   879     with A0 show "P x" by auto
   880   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   881     case (smaller n)
   882     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   883     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   884     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   885     then show ?case by auto
   886   qed
   887   ultimately show "P x" by auto
   888 qed
   889 
   890 text{* Again, without explicit base case: *}
   891 lemma infinite_descent_measure:
   892 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   893 proof -
   894   from assms obtain n where "n = V x" by auto
   895   moreover have "!!x. V x = n \<Longrightarrow> P x"
   896   proof (induct n rule: infinite_descent, auto)
   897     fix x assume "\<not> P x"
   898     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   899   qed
   900   ultimately show "P x" by auto
   901 qed
   902 
   903 text {* A [clumsy] way of lifting @{text "<"}
   904   monotonicity to @{text "\<le>"} monotonicity *}
   905 lemma less_mono_imp_le_mono:
   906   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   907 by (simp add: order_le_less) (blast)
   908 
   909 
   910 text {* non-strict, in 1st argument *}
   911 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   912 by (rule add_right_mono)
   913 
   914 text {* non-strict, in both arguments *}
   915 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   916 by (rule add_mono)
   917 
   918 lemma le_add2: "n \<le> ((m + n)::nat)"
   919 by (insert add_right_mono [of 0 m n], simp)
   920 
   921 lemma le_add1: "n \<le> ((n + m)::nat)"
   922 by (simp add: add_commute, rule le_add2)
   923 
   924 lemma less_add_Suc1: "i < Suc (i + m)"
   925 by (rule le_less_trans, rule le_add1, rule lessI)
   926 
   927 lemma less_add_Suc2: "i < Suc (m + i)"
   928 by (rule le_less_trans, rule le_add2, rule lessI)
   929 
   930 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   931 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   932 
   933 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   934 by (rule le_trans, assumption, rule le_add1)
   935 
   936 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   937 by (rule le_trans, assumption, rule le_add2)
   938 
   939 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   940 by (rule less_le_trans, assumption, rule le_add1)
   941 
   942 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   943 by (rule less_le_trans, assumption, rule le_add2)
   944 
   945 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   946 apply (rule le_less_trans [of _ "i+j"])
   947 apply (simp_all add: le_add1)
   948 done
   949 
   950 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   951 apply (rule notI)
   952 apply (drule add_lessD1)
   953 apply (erule less_irrefl [THEN notE])
   954 done
   955 
   956 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   957 by (simp add: add_commute)
   958 
   959 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   960 apply (rule order_trans [of _ "m+k"])
   961 apply (simp_all add: le_add1)
   962 done
   963 
   964 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   965 apply (simp add: add_commute)
   966 apply (erule add_leD1)
   967 done
   968 
   969 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   970 by (blast dest: add_leD1 add_leD2)
   971 
   972 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   973 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   974 by (force simp del: add_Suc_right
   975     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   976 
   977 
   978 subsubsection {* More results about difference *}
   979 
   980 text {* Addition is the inverse of subtraction:
   981   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   982 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   983 by (induct m n rule: diff_induct) simp_all
   984 
   985 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   986 by (simp add: add_diff_inverse linorder_not_less)
   987 
   988 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   989 by (simp add: add_commute)
   990 
   991 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   992 by (induct m n rule: diff_induct) simp_all
   993 
   994 lemma diff_less_Suc: "m - n < Suc m"
   995 apply (induct m n rule: diff_induct)
   996 apply (erule_tac [3] less_SucE)
   997 apply (simp_all add: less_Suc_eq)
   998 done
   999 
  1000 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1001 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1002 
  1003 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1004   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1005 
  1006 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1007 by (rule le_less_trans, rule diff_le_self)
  1008 
  1009 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1010 by (cases n) (auto simp add: le_simps)
  1011 
  1012 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1013 by (induct j k rule: diff_induct) simp_all
  1014 
  1015 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1016 by (simp add: add_commute diff_add_assoc)
  1017 
  1018 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1019 by (auto simp add: diff_add_inverse2)
  1020 
  1021 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1022 by (induct m n rule: diff_induct) simp_all
  1023 
  1024 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1025 by (rule iffD2, rule diff_is_0_eq)
  1026 
  1027 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1028 by (induct m n rule: diff_induct) simp_all
  1029 
  1030 lemma less_imp_add_positive:
  1031   assumes "i < j"
  1032   shows "\<exists>k::nat. 0 < k & i + k = j"
  1033 proof
  1034   from assms show "0 < j - i & i + (j - i) = j"
  1035     by (simp add: order_less_imp_le)
  1036 qed
  1037 
  1038 text {* a nice rewrite for bounded subtraction *}
  1039 lemma nat_minus_add_max:
  1040   fixes n m :: nat
  1041   shows "n - m + m = max n m"
  1042     by (simp add: max_def not_le order_less_imp_le)
  1043 
  1044 lemma nat_diff_split:
  1045   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1046     -- {* elimination of @{text -} on @{text nat} *}
  1047 by (cases "a < b")
  1048   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1049     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1050 
  1051 lemma nat_diff_split_asm:
  1052   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1053     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1054 by (auto split: nat_diff_split)
  1055 
  1056 
  1057 subsubsection {* Monotonicity of Multiplication *}
  1058 
  1059 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1060 by (simp add: mult_right_mono)
  1061 
  1062 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1063 by (simp add: mult_left_mono)
  1064 
  1065 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1066 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1067 by (simp add: mult_mono)
  1068 
  1069 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1070 by (simp add: mult_strict_right_mono)
  1071 
  1072 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1073       there are no negative numbers.*}
  1074 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1075   apply (induct m)
  1076    apply simp
  1077   apply (case_tac n)
  1078    apply simp_all
  1079   done
  1080 
  1081 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
  1082   apply (induct m)
  1083    apply simp
  1084   apply (case_tac n)
  1085    apply simp_all
  1086   done
  1087 
  1088 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1089   apply (safe intro!: mult_less_mono1)
  1090   apply (case_tac k, auto)
  1091   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1092   apply (blast intro: mult_le_mono1)
  1093   done
  1094 
  1095 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1096 by (simp add: mult_commute [of k])
  1097 
  1098 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1099 by (simp add: linorder_not_less [symmetric], auto)
  1100 
  1101 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1102 by (simp add: linorder_not_less [symmetric], auto)
  1103 
  1104 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1105 by (subst mult_less_cancel1) simp
  1106 
  1107 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1108 by (subst mult_le_cancel1) simp
  1109 
  1110 lemma le_square: "m \<le> m * (m::nat)"
  1111   by (cases m) (auto intro: le_add1)
  1112 
  1113 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1114   by (cases m) (auto intro: le_add1)
  1115 
  1116 text {* Lemma for @{text gcd} *}
  1117 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1118   apply (drule sym)
  1119   apply (rule disjCI)
  1120   apply (rule nat_less_cases, erule_tac [2] _)
  1121    apply (drule_tac [2] mult_less_mono2)
  1122     apply (auto)
  1123   done
  1124 
  1125 text {* the lattice order on @{typ nat} *}
  1126 
  1127 instantiation nat :: distrib_lattice
  1128 begin
  1129 
  1130 definition
  1131   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1132 
  1133 definition
  1134   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1135 
  1136 instance by intro_classes
  1137   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1138     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1139 
  1140 end
  1141 
  1142 
  1143 subsection {* Embedding of the Naturals into any
  1144   @{text semiring_1}: @{term of_nat} *}
  1145 
  1146 context semiring_1
  1147 begin
  1148 
  1149 primrec
  1150   of_nat :: "nat \<Rightarrow> 'a"
  1151 where
  1152   of_nat_0:     "of_nat 0 = 0"
  1153   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1154 
  1155 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1156   by simp
  1157 
  1158 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1159   by (induct m) (simp_all add: add_ac)
  1160 
  1161 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1162   by (induct m) (simp_all add: add_ac left_distrib)
  1163 
  1164 definition
  1165   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1166 where
  1167   [code func del]: "of_nat_aux n i = of_nat n + i"
  1168 
  1169 lemma of_nat_aux_code [code]:
  1170   "of_nat_aux 0 i = i"
  1171   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1172   by (simp_all add: of_nat_aux_def add_ac)
  1173 
  1174 lemma of_nat_code [code]:
  1175   "of_nat n = of_nat_aux n 0"
  1176   by (simp add: of_nat_aux_def)
  1177 
  1178 end
  1179 
  1180 text{*Class for unital semirings with characteristic zero.
  1181  Includes non-ordered rings like the complex numbers.*}
  1182 
  1183 class semiring_char_0 = semiring_1 +
  1184   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1185 begin
  1186 
  1187 text{*Special cases where either operand is zero*}
  1188 
  1189 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1190   by (rule of_nat_eq_iff [of 0, simplified])
  1191 
  1192 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1193   by (rule of_nat_eq_iff [of _ 0, simplified])
  1194 
  1195 lemma inj_of_nat: "inj of_nat"
  1196   by (simp add: inj_on_def)
  1197 
  1198 end
  1199 
  1200 context ordered_semidom
  1201 begin
  1202 
  1203 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1204   apply (induct m, simp_all)
  1205   apply (erule order_trans)
  1206   apply (rule ord_le_eq_trans [OF _ add_commute])
  1207   apply (rule less_add_one [THEN less_imp_le])
  1208   done
  1209 
  1210 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1211   apply (induct m n rule: diff_induct, simp_all)
  1212   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1213   done
  1214 
  1215 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1216   apply (induct m n rule: diff_induct, simp_all)
  1217   apply (insert zero_le_imp_of_nat)
  1218   apply (force simp add: not_less [symmetric])
  1219   done
  1220 
  1221 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1222   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1223 
  1224 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1225   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1226 
  1227 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1228 
  1229 subclass semiring_char_0
  1230   by unfold_locales (simp add: eq_iff order_eq_iff)
  1231 
  1232 text{*Special cases where either operand is zero*}
  1233 
  1234 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1235   by (rule of_nat_le_iff [of 0, simplified])
  1236 
  1237 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1238   by (rule of_nat_le_iff [of _ 0, simplified])
  1239 
  1240 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1241   by (rule of_nat_less_iff [of 0, simplified])
  1242 
  1243 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1244   by (rule of_nat_less_iff [of _ 0, simplified])
  1245 
  1246 end
  1247 
  1248 context ring_1
  1249 begin
  1250 
  1251 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1252   by (simp add: compare_rls of_nat_add [symmetric])
  1253 
  1254 end
  1255 
  1256 context ordered_idom
  1257 begin
  1258 
  1259 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1260   unfolding abs_if by auto
  1261 
  1262 end
  1263 
  1264 lemma of_nat_id [simp]: "of_nat n = n"
  1265   by (induct n) auto
  1266 
  1267 lemma of_nat_eq_id [simp]: "of_nat = id"
  1268   by (auto simp add: expand_fun_eq)
  1269 
  1270 
  1271 subsection {* The Set of Natural Numbers *}
  1272 
  1273 context semiring_1
  1274 begin
  1275 
  1276 definition
  1277   Nats  :: "'a set" where
  1278   [code func del]: "Nats = range of_nat"
  1279 
  1280 notation (xsymbols)
  1281   Nats  ("\<nat>")
  1282 
  1283 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1284   by (simp add: Nats_def)
  1285 
  1286 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1287 apply (simp add: Nats_def)
  1288 apply (rule range_eqI)
  1289 apply (rule of_nat_0 [symmetric])
  1290 done
  1291 
  1292 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1293 apply (simp add: Nats_def)
  1294 apply (rule range_eqI)
  1295 apply (rule of_nat_1 [symmetric])
  1296 done
  1297 
  1298 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1299 apply (auto simp add: Nats_def)
  1300 apply (rule range_eqI)
  1301 apply (rule of_nat_add [symmetric])
  1302 done
  1303 
  1304 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1305 apply (auto simp add: Nats_def)
  1306 apply (rule range_eqI)
  1307 apply (rule of_nat_mult [symmetric])
  1308 done
  1309 
  1310 end
  1311 
  1312 
  1313 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1314 
  1315 lemma subst_equals:
  1316   assumes 1: "t = s" and 2: "u = t"
  1317   shows "u = s"
  1318   using 2 1 by (rule trans)
  1319 
  1320 use "arith_data.ML"
  1321 declaration {* K ArithData.setup *}
  1322 
  1323 use "Tools/lin_arith.ML"
  1324 declaration {* K LinArith.setup *}
  1325 
  1326 lemmas [arith_split] = nat_diff_split split_min split_max
  1327 
  1328 
  1329 context order
  1330 begin
  1331 
  1332 lemma lift_Suc_mono_le:
  1333   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1334   shows "f n \<le> f n'"
  1335 proof (cases "n < n'")
  1336   case True
  1337   thus ?thesis
  1338     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1339 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1340 
  1341 lemma lift_Suc_mono_less:
  1342   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1343   shows "f n < f n'"
  1344 using `n < n'`
  1345 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1346 
  1347 lemma lift_Suc_mono_less_iff:
  1348   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1349 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1350          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1351 
  1352 end
  1353 
  1354 
  1355 lemma mono_nat_linear_lb:
  1356   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1357 apply(induct_tac k)
  1358  apply simp
  1359 apply(erule_tac x="m+n" in meta_allE)
  1360 apply(erule_tac x="m+n+1" in meta_allE)
  1361 apply simp
  1362 done
  1363 
  1364 
  1365 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1366 
  1367 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1368 by arith
  1369 
  1370 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1371 by arith
  1372 
  1373 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1374 by arith
  1375 
  1376 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1377 by arith
  1378 
  1379 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1380 by arith
  1381 
  1382 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1383 by arith
  1384 
  1385 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1386   second premise n\<le>m*)
  1387 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1388 by arith
  1389 
  1390 text {* Simplification of relational expressions involving subtraction *}
  1391 
  1392 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1393 by (simp split add: nat_diff_split)
  1394 
  1395 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1396 by (auto split add: nat_diff_split)
  1397 
  1398 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1399 by (auto split add: nat_diff_split)
  1400 
  1401 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1402 by (auto split add: nat_diff_split)
  1403 
  1404 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1405 
  1406 (* Monotonicity of subtraction in first argument *)
  1407 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1408 by (simp split add: nat_diff_split)
  1409 
  1410 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1411 by (simp split add: nat_diff_split)
  1412 
  1413 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1414 by (simp split add: nat_diff_split)
  1415 
  1416 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1417 by (simp split add: nat_diff_split)
  1418 
  1419 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1420 unfolding min_def by auto
  1421 
  1422 lemma inj_on_diff_nat: 
  1423   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1424   shows "inj_on (\<lambda>n. n - k) N"
  1425 proof (rule inj_onI)
  1426   fix x y
  1427   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1428   with k_le_n have "x - k + k = y - k + k" by auto
  1429   with a k_le_n show "x = y" by auto
  1430 qed
  1431 
  1432 text{*Rewriting to pull differences out*}
  1433 
  1434 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1435 by arith
  1436 
  1437 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1438 by arith
  1439 
  1440 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1441 by arith
  1442 
  1443 text{*Lemmas for ex/Factorization*}
  1444 
  1445 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1446 by (cases m) auto
  1447 
  1448 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1449 by (cases m) auto
  1450 
  1451 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1452 by (cases m) auto
  1453 
  1454 text {* Specialized induction principles that work "backwards": *}
  1455 
  1456 lemma inc_induct[consumes 1, case_names base step]:
  1457   assumes less: "i <= j"
  1458   assumes base: "P j"
  1459   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1460   shows "P i"
  1461   using less
  1462 proof (induct d=="j - i" arbitrary: i)
  1463   case (0 i)
  1464   hence "i = j" by simp
  1465   with base show ?case by simp
  1466 next
  1467   case (Suc d i)
  1468   hence "i < j" "P (Suc i)"
  1469     by simp_all
  1470   thus "P i" by (rule step)
  1471 qed
  1472 
  1473 lemma strict_inc_induct[consumes 1, case_names base step]:
  1474   assumes less: "i < j"
  1475   assumes base: "!!i. j = Suc i ==> P i"
  1476   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1477   shows "P i"
  1478   using less
  1479 proof (induct d=="j - i - 1" arbitrary: i)
  1480   case (0 i)
  1481   with `i < j` have "j = Suc i" by simp
  1482   with base show ?case by simp
  1483 next
  1484   case (Suc d i)
  1485   hence "i < j" "P (Suc i)"
  1486     by simp_all
  1487   thus "P i" by (rule step)
  1488 qed
  1489 
  1490 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1491   using inc_induct[of "k - i" k P, simplified] by blast
  1492 
  1493 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1494   using inc_induct[of 0 k P] by blast
  1495 
  1496 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1497   by auto
  1498 
  1499 (*The others are
  1500       i - j - k = i - (j + k),
  1501       k \<le> j ==> j - k + i = j + i - k,
  1502       k \<le> j ==> i + (j - k) = i + j - k *)
  1503 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1504 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1505 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1506 
  1507 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1508 Least_Suc}, since there appears to be no need.*}
  1509 
  1510 
  1511 subsection {* size of a datatype value *}
  1512 
  1513 class size = type +
  1514   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1515 
  1516 end