src/HOL/Orderings.thy
author wenzelm
Wed Sep 17 21:27:14 2008 +0200 (2008-09-17)
changeset 28263 69eaa97e7e96
parent 27823 52971512d1a2
child 28516 e6fdcaaadbd3
permissions -rw-r--r--
moved global ML bindings to global place;
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Abstract orderings *}
     7 
     8 theory Orderings
     9 imports Code_Setup
    10 uses
    11   "~~/src/Provers/order.ML"
    12 begin
    13 
    14 subsection {* Quasi orders *}
    15 
    16 class preorder = ord +
    17   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
    18   and order_refl [iff]: "x \<le> x"
    19   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
    20 begin
    21 
    22 text {* Reflexivity. *}
    23 
    24 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
    25     -- {* This form is useful with the classical reasoner. *}
    26 by (erule ssubst) (rule order_refl)
    27 
    28 lemma less_irrefl [iff]: "\<not> x < x"
    29 by (simp add: less_le_not_le)
    30 
    31 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
    32 unfolding less_le_not_le by blast
    33 
    34 
    35 text {* Asymmetry. *}
    36 
    37 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
    38 by (simp add: less_le_not_le)
    39 
    40 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
    41 by (drule less_not_sym, erule contrapos_np) simp
    42 
    43 
    44 text {* Transitivity. *}
    45 
    46 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    47 by (auto simp add: less_le_not_le intro: order_trans) 
    48 
    49 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
    50 by (auto simp add: less_le_not_le intro: order_trans) 
    51 
    52 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
    53 by (auto simp add: less_le_not_le intro: order_trans) 
    54 
    55 
    56 text {* Useful for simplification, but too risky to include by default. *}
    57 
    58 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
    59 by (blast elim: less_asym)
    60 
    61 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
    62 by (blast elim: less_asym)
    63 
    64 
    65 text {* Transitivity rules for calculational reasoning *}
    66 
    67 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
    68 by (rule less_asym)
    69 
    70 
    71 text {* Dual order *}
    72 
    73 lemma dual_preorder:
    74   "preorder (op \<ge>) (op >)"
    75 by unfold_locales (auto simp add: less_le_not_le intro: order_trans)
    76 
    77 end
    78 
    79 
    80 subsection {* Partial orders *}
    81 
    82 class order = preorder +
    83   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
    84 begin
    85 
    86 text {* Reflexivity. *}
    87 
    88 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
    89 by (auto simp add: less_le_not_le intro: antisym)
    90 
    91 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
    92     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    93 by (simp add: less_le) blast
    94 
    95 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
    96 unfolding less_le by blast
    97 
    98 
    99 text {* Useful for simplification, but too risky to include by default. *}
   100 
   101 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   102 by auto
   103 
   104 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   105 by auto
   106 
   107 
   108 text {* Transitivity rules for calculational reasoning *}
   109 
   110 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   111 by (simp add: less_le)
   112 
   113 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   114 by (simp add: less_le)
   115 
   116 
   117 text {* Asymmetry. *}
   118 
   119 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   120 by (blast intro: antisym)
   121 
   122 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   123 by (blast intro: antisym)
   124 
   125 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   126 by (erule contrapos_pn, erule subst, rule less_irrefl)
   127 
   128 
   129 text {* Least value operator *}
   130 
   131 definition (in ord)
   132   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   133   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   134 
   135 lemma Least_equality:
   136   assumes "P x"
   137     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   138   shows "Least P = x"
   139 unfolding Least_def by (rule the_equality)
   140   (blast intro: assms antisym)+
   141 
   142 lemma LeastI2_order:
   143   assumes "P x"
   144     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   145     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   146   shows "Q (Least P)"
   147 unfolding Least_def by (rule theI2)
   148   (blast intro: assms antisym)+
   149 
   150 
   151 text {* Dual order *}
   152 
   153 lemma dual_order:
   154   "order (op \<ge>) (op >)"
   155 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   156 
   157 end
   158 
   159 
   160 subsection {* Linear (total) orders *}
   161 
   162 class linorder = order +
   163   assumes linear: "x \<le> y \<or> y \<le> x"
   164 begin
   165 
   166 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   167 unfolding less_le using less_le linear by blast
   168 
   169 lemma le_less_linear: "x \<le> y \<or> y < x"
   170 by (simp add: le_less less_linear)
   171 
   172 lemma le_cases [case_names le ge]:
   173   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   174 using linear by blast
   175 
   176 lemma linorder_cases [case_names less equal greater]:
   177   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   178 using less_linear by blast
   179 
   180 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   181 apply (simp add: less_le)
   182 using linear apply (blast intro: antisym)
   183 done
   184 
   185 lemma not_less_iff_gr_or_eq:
   186  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   187 apply(simp add:not_less le_less)
   188 apply blast
   189 done
   190 
   191 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   192 apply (simp add: less_le)
   193 using linear apply (blast intro: antisym)
   194 done
   195 
   196 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   197 by (cut_tac x = x and y = y in less_linear, auto)
   198 
   199 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   200 by (simp add: neq_iff) blast
   201 
   202 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   203 by (blast intro: antisym dest: not_less [THEN iffD1])
   204 
   205 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   206 by (blast intro: antisym dest: not_less [THEN iffD1])
   207 
   208 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   209 by (blast intro: antisym dest: not_less [THEN iffD1])
   210 
   211 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   212 unfolding not_less .
   213 
   214 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   215 unfolding not_less .
   216 
   217 (*FIXME inappropriate name (or delete altogether)*)
   218 lemma not_leE: "\<not> y \<le> x \<Longrightarrow> x < y"
   219 unfolding not_le .
   220 
   221 
   222 text {* Dual order *}
   223 
   224 lemma dual_linorder:
   225   "linorder (op \<ge>) (op >)"
   226 by (rule linorder.intro, rule dual_order) (unfold_locales, rule linear)
   227 
   228 
   229 text {* min/max *}
   230 
   231 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   232   [code unfold, code inline del]: "min a b = (if a \<le> b then a else b)"
   233 
   234 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   235   [code unfold, code inline del]: "max a b = (if a \<le> b then b else a)"
   236 
   237 lemma min_le_iff_disj:
   238   "min x y \<le> z \<longleftrightarrow> x \<le> z \<or> y \<le> z"
   239 unfolding min_def using linear by (auto intro: order_trans)
   240 
   241 lemma le_max_iff_disj:
   242   "z \<le> max x y \<longleftrightarrow> z \<le> x \<or> z \<le> y"
   243 unfolding max_def using linear by (auto intro: order_trans)
   244 
   245 lemma min_less_iff_disj:
   246   "min x y < z \<longleftrightarrow> x < z \<or> y < z"
   247 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   248 
   249 lemma less_max_iff_disj:
   250   "z < max x y \<longleftrightarrow> z < x \<or> z < y"
   251 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   252 
   253 lemma min_less_iff_conj [simp]:
   254   "z < min x y \<longleftrightarrow> z < x \<and> z < y"
   255 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   256 
   257 lemma max_less_iff_conj [simp]:
   258   "max x y < z \<longleftrightarrow> x < z \<and> y < z"
   259 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   260 
   261 lemma split_min [noatp]:
   262   "P (min i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P i) \<and> (\<not> i \<le> j \<longrightarrow> P j)"
   263 by (simp add: min_def)
   264 
   265 lemma split_max [noatp]:
   266   "P (max i j) \<longleftrightarrow> (i \<le> j \<longrightarrow> P j) \<and> (\<not> i \<le> j \<longrightarrow> P i)"
   267 by (simp add: max_def)
   268 
   269 end
   270 
   271 
   272 subsection {* Reasoning tools setup *}
   273 
   274 ML {*
   275 
   276 signature ORDERS =
   277 sig
   278   val print_structures: Proof.context -> unit
   279   val setup: theory -> theory
   280   val order_tac: thm list -> Proof.context -> int -> tactic
   281 end;
   282 
   283 structure Orders: ORDERS =
   284 struct
   285 
   286 (** Theory and context data **)
   287 
   288 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   289   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   290 
   291 structure Data = GenericDataFun
   292 (
   293   type T = ((string * term list) * Order_Tac.less_arith) list;
   294     (* Order structures:
   295        identifier of the structure, list of operations and record of theorems
   296        needed to set up the transitivity reasoner,
   297        identifier and operations identify the structure uniquely. *)
   298   val empty = [];
   299   val extend = I;
   300   fun merge _ = AList.join struct_eq (K fst);
   301 );
   302 
   303 fun print_structures ctxt =
   304   let
   305     val structs = Data.get (Context.Proof ctxt);
   306     fun pretty_term t = Pretty.block
   307       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   308         Pretty.str "::", Pretty.brk 1,
   309         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   310     fun pretty_struct ((s, ts), _) = Pretty.block
   311       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   312        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   313   in
   314     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   315   end;
   316 
   317 
   318 (** Method **)
   319 
   320 fun struct_tac ((s, [eq, le, less]), thms) prems =
   321   let
   322     fun decomp thy (Trueprop $ t) =
   323       let
   324         fun excluded t =
   325           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   326           let val T = type_of t
   327           in
   328 	    T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   329           end;
   330 	fun rel (bin_op $ t1 $ t2) =
   331               if excluded t1 then NONE
   332               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   333               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   334               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   335               else NONE
   336 	  | rel _ = NONE;
   337 	fun dec (Const (@{const_name Not}, _) $ t) = (case rel t
   338 	      of NONE => NONE
   339 	       | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   340           | dec x = rel x;
   341       in dec t end;
   342   in
   343     case s of
   344       "order" => Order_Tac.partial_tac decomp thms prems
   345     | "linorder" => Order_Tac.linear_tac decomp thms prems
   346     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   347   end
   348 
   349 fun order_tac prems ctxt =
   350   FIRST' (map (fn s => CHANGED o struct_tac s prems) (Data.get (Context.Proof ctxt)));
   351 
   352 
   353 (** Attribute **)
   354 
   355 fun add_struct_thm s tag =
   356   Thm.declaration_attribute
   357     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   358 fun del_struct s =
   359   Thm.declaration_attribute
   360     (fn _ => Data.map (AList.delete struct_eq s));
   361 
   362 val attribute = Attrib.syntax
   363      (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) ||
   364           Args.del >> K NONE) --| Args.colon (* FIXME ||
   365         Scan.succeed true *) ) -- Scan.lift Args.name --
   366       Scan.repeat Args.term
   367       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   368            | ((NONE, n), ts) => del_struct (n, ts)));
   369 
   370 
   371 (** Diagnostic command **)
   372 
   373 val print = Toplevel.unknown_context o
   374   Toplevel.keep (Toplevel.node_case
   375     (Context.cases (print_structures o ProofContext.init) print_structures)
   376     (print_structures o Proof.context_of));
   377 
   378 val _ =
   379   OuterSyntax.improper_command "print_orders"
   380     "print order structures available to transitivity reasoner" OuterKeyword.diag
   381     (Scan.succeed (Toplevel.no_timing o print));
   382 
   383 
   384 (** Setup **)
   385 
   386 val setup =
   387   Method.add_methods
   388     [("order", Method.ctxt_args (Method.SIMPLE_METHOD' o order_tac []), "transitivity reasoner")] #>
   389   Attrib.add_attributes [("order", attribute, "theorems controlling transitivity reasoner")];
   390 
   391 end;
   392 
   393 *}
   394 
   395 setup Orders.setup
   396 
   397 
   398 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   399 
   400 context order
   401 begin
   402 
   403 (* The type constraint on @{term op =} below is necessary since the operation
   404    is not a parameter of the locale. *)
   405 
   406 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   407   
   408 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   409   
   410 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   411   
   412 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   413 
   414 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   415 
   416 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   417 
   418 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   419   
   420 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   421   
   422 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   423 
   424 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   425 
   426 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   427 
   428 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   429 
   430 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   431 
   432 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   433 
   434 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   435 
   436 end
   437 
   438 context linorder
   439 begin
   440 
   441 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   442 
   443 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   444 
   445 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   446 
   447 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   448 
   449 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   450 
   451 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   452 
   453 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   454 
   455 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   456 
   457 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   458 
   459 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   460 
   461 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   462 
   463 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   464 
   465 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   466 
   467 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   468 
   469 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   470 
   471 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   472 
   473 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   474 
   475 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   476 
   477 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   478 
   479 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   480 
   481 end
   482 
   483 
   484 setup {*
   485 let
   486 
   487 fun prp t thm = (#prop (rep_thm thm) = t);
   488 
   489 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   490   let val prems = prems_of_ss ss;
   491       val less = Const (@{const_name less}, T);
   492       val t = HOLogic.mk_Trueprop(le $ s $ r);
   493   in case find_first (prp t) prems of
   494        NONE =>
   495          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   496          in case find_first (prp t) prems of
   497               NONE => NONE
   498             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   499          end
   500      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   501   end
   502   handle THM _ => NONE;
   503 
   504 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   505   let val prems = prems_of_ss ss;
   506       val le = Const (@{const_name less_eq}, T);
   507       val t = HOLogic.mk_Trueprop(le $ r $ s);
   508   in case find_first (prp t) prems of
   509        NONE =>
   510          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   511          in case find_first (prp t) prems of
   512               NONE => NONE
   513             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   514          end
   515      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   516   end
   517   handle THM _ => NONE;
   518 
   519 fun add_simprocs procs thy =
   520   Simplifier.map_simpset (fn ss => ss
   521     addsimprocs (map (fn (name, raw_ts, proc) =>
   522       Simplifier.simproc thy name raw_ts proc) procs)) thy;
   523 fun add_solver name tac =
   524   Simplifier.map_simpset (fn ss => ss addSolver
   525     mk_solver' name (fn ss => tac (Simplifier.prems_of_ss ss) (Simplifier.the_context ss)));
   526 
   527 in
   528   add_simprocs [
   529        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   530        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   531      ]
   532   #> add_solver "Transitivity" Orders.order_tac
   533   (* Adding the transitivity reasoners also as safe solvers showed a slight
   534      speed up, but the reasoning strength appears to be not higher (at least
   535      no breaking of additional proofs in the entire HOL distribution, as
   536      of 5 March 2004, was observed). *)
   537 end
   538 *}
   539 
   540 
   541 subsection {* Name duplicates *}
   542 
   543 lemmas order_less_le = less_le
   544 lemmas order_eq_refl = preorder_class.eq_refl
   545 lemmas order_less_irrefl = preorder_class.less_irrefl
   546 lemmas order_le_less = order_class.le_less
   547 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   548 lemmas order_less_imp_le = preorder_class.less_imp_le
   549 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   550 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   551 lemmas order_neq_le_trans = order_class.neq_le_trans
   552 lemmas order_le_neq_trans = order_class.le_neq_trans
   553 
   554 lemmas order_antisym = antisym
   555 lemmas order_less_not_sym = preorder_class.less_not_sym
   556 lemmas order_less_asym = preorder_class.less_asym
   557 lemmas order_eq_iff = order_class.eq_iff
   558 lemmas order_antisym_conv = order_class.antisym_conv
   559 lemmas order_less_trans = preorder_class.less_trans
   560 lemmas order_le_less_trans = preorder_class.le_less_trans
   561 lemmas order_less_le_trans = preorder_class.less_le_trans
   562 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
   563 lemmas order_less_imp_triv = preorder_class.less_imp_triv
   564 lemmas order_less_asym' = preorder_class.less_asym'
   565 
   566 lemmas linorder_linear = linear
   567 lemmas linorder_less_linear = linorder_class.less_linear
   568 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   569 lemmas linorder_le_cases = linorder_class.le_cases
   570 lemmas linorder_not_less = linorder_class.not_less
   571 lemmas linorder_not_le = linorder_class.not_le
   572 lemmas linorder_neq_iff = linorder_class.neq_iff
   573 lemmas linorder_neqE = linorder_class.neqE
   574 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   575 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   576 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   577 
   578 
   579 subsection {* Bounded quantifiers *}
   580 
   581 syntax
   582   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   583   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   584   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   585   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   586 
   587   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   588   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   589   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   590   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   591 
   592 syntax (xsymbols)
   593   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   594   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   595   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   596   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   597 
   598   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   599   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   600   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   601   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   602 
   603 syntax (HOL)
   604   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   605   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   606   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   607   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   608 
   609 syntax (HTML output)
   610   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   611   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   612   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   613   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   614 
   615   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   616   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   617   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   618   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   619 
   620 translations
   621   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   622   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   623   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   624   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   625   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   626   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   627   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   628   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   629 
   630 print_translation {*
   631 let
   632   val All_binder = Syntax.binder_name @{const_syntax All};
   633   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   634   val impl = @{const_syntax "op -->"};
   635   val conj = @{const_syntax "op &"};
   636   val less = @{const_syntax less};
   637   val less_eq = @{const_syntax less_eq};
   638 
   639   val trans =
   640    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   641     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   642     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   643     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   644 
   645   fun matches_bound v t = 
   646      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   647               | _ => false
   648   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   649   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   650 
   651   fun tr' q = (q,
   652     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   653       (case AList.lookup (op =) trans (q, c, d) of
   654         NONE => raise Match
   655       | SOME (l, g) =>
   656           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   657           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   658           else raise Match)
   659      | _ => raise Match);
   660 in [tr' All_binder, tr' Ex_binder] end
   661 *}
   662 
   663 
   664 subsection {* Transitivity reasoning *}
   665 
   666 context ord
   667 begin
   668 
   669 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   670   by (rule subst)
   671 
   672 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   673   by (rule ssubst)
   674 
   675 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   676   by (rule subst)
   677 
   678 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   679   by (rule ssubst)
   680 
   681 end
   682 
   683 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   684   (!!x y. x < y ==> f x < f y) ==> f a < c"
   685 proof -
   686   assume r: "!!x y. x < y ==> f x < f y"
   687   assume "a < b" hence "f a < f b" by (rule r)
   688   also assume "f b < c"
   689   finally (order_less_trans) show ?thesis .
   690 qed
   691 
   692 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   693   (!!x y. x < y ==> f x < f y) ==> a < f c"
   694 proof -
   695   assume r: "!!x y. x < y ==> f x < f y"
   696   assume "a < f b"
   697   also assume "b < c" hence "f b < f c" by (rule r)
   698   finally (order_less_trans) show ?thesis .
   699 qed
   700 
   701 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   702   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   703 proof -
   704   assume r: "!!x y. x <= y ==> f x <= f y"
   705   assume "a <= b" hence "f a <= f b" by (rule r)
   706   also assume "f b < c"
   707   finally (order_le_less_trans) show ?thesis .
   708 qed
   709 
   710 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   711   (!!x y. x < y ==> f x < f y) ==> a < f c"
   712 proof -
   713   assume r: "!!x y. x < y ==> f x < f y"
   714   assume "a <= f b"
   715   also assume "b < c" hence "f b < f c" by (rule r)
   716   finally (order_le_less_trans) show ?thesis .
   717 qed
   718 
   719 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   720   (!!x y. x < y ==> f x < f y) ==> f a < c"
   721 proof -
   722   assume r: "!!x y. x < y ==> f x < f y"
   723   assume "a < b" hence "f a < f b" by (rule r)
   724   also assume "f b <= c"
   725   finally (order_less_le_trans) show ?thesis .
   726 qed
   727 
   728 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   729   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   730 proof -
   731   assume r: "!!x y. x <= y ==> f x <= f y"
   732   assume "a < f b"
   733   also assume "b <= c" hence "f b <= f c" by (rule r)
   734   finally (order_less_le_trans) show ?thesis .
   735 qed
   736 
   737 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   738   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   739 proof -
   740   assume r: "!!x y. x <= y ==> f x <= f y"
   741   assume "a <= f b"
   742   also assume "b <= c" hence "f b <= f c" by (rule r)
   743   finally (order_trans) show ?thesis .
   744 qed
   745 
   746 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   747   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   748 proof -
   749   assume r: "!!x y. x <= y ==> f x <= f y"
   750   assume "a <= b" hence "f a <= f b" by (rule r)
   751   also assume "f b <= c"
   752   finally (order_trans) show ?thesis .
   753 qed
   754 
   755 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   756   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   757 proof -
   758   assume r: "!!x y. x <= y ==> f x <= f y"
   759   assume "a <= b" hence "f a <= f b" by (rule r)
   760   also assume "f b = c"
   761   finally (ord_le_eq_trans) show ?thesis .
   762 qed
   763 
   764 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   765   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   766 proof -
   767   assume r: "!!x y. x <= y ==> f x <= f y"
   768   assume "a = f b"
   769   also assume "b <= c" hence "f b <= f c" by (rule r)
   770   finally (ord_eq_le_trans) show ?thesis .
   771 qed
   772 
   773 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   774   (!!x y. x < y ==> f x < f y) ==> f a < c"
   775 proof -
   776   assume r: "!!x y. x < y ==> f x < f y"
   777   assume "a < b" hence "f a < f b" by (rule r)
   778   also assume "f b = c"
   779   finally (ord_less_eq_trans) show ?thesis .
   780 qed
   781 
   782 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   783   (!!x y. x < y ==> f x < f y) ==> a < f c"
   784 proof -
   785   assume r: "!!x y. x < y ==> f x < f y"
   786   assume "a = f b"
   787   also assume "b < c" hence "f b < f c" by (rule r)
   788   finally (ord_eq_less_trans) show ?thesis .
   789 qed
   790 
   791 text {*
   792   Note that this list of rules is in reverse order of priorities.
   793 *}
   794 
   795 lemmas [trans] =
   796   order_less_subst2
   797   order_less_subst1
   798   order_le_less_subst2
   799   order_le_less_subst1
   800   order_less_le_subst2
   801   order_less_le_subst1
   802   order_subst2
   803   order_subst1
   804   ord_le_eq_subst
   805   ord_eq_le_subst
   806   ord_less_eq_subst
   807   ord_eq_less_subst
   808   forw_subst
   809   back_subst
   810   rev_mp
   811   mp
   812 
   813 lemmas (in order) [trans] =
   814   neq_le_trans
   815   le_neq_trans
   816 
   817 lemmas (in preorder) [trans] =
   818   less_trans
   819   less_asym'
   820   le_less_trans
   821   less_le_trans
   822   order_trans
   823 
   824 lemmas (in order) [trans] =
   825   antisym
   826 
   827 lemmas (in ord) [trans] =
   828   ord_le_eq_trans
   829   ord_eq_le_trans
   830   ord_less_eq_trans
   831   ord_eq_less_trans
   832 
   833 lemmas [trans] =
   834   trans
   835 
   836 lemmas order_trans_rules =
   837   order_less_subst2
   838   order_less_subst1
   839   order_le_less_subst2
   840   order_le_less_subst1
   841   order_less_le_subst2
   842   order_less_le_subst1
   843   order_subst2
   844   order_subst1
   845   ord_le_eq_subst
   846   ord_eq_le_subst
   847   ord_less_eq_subst
   848   ord_eq_less_subst
   849   forw_subst
   850   back_subst
   851   rev_mp
   852   mp
   853   neq_le_trans
   854   le_neq_trans
   855   less_trans
   856   less_asym'
   857   le_less_trans
   858   less_le_trans
   859   order_trans
   860   antisym
   861   ord_le_eq_trans
   862   ord_eq_le_trans
   863   ord_less_eq_trans
   864   ord_eq_less_trans
   865   trans
   866 
   867 (* FIXME cleanup *)
   868 
   869 text {* These support proving chains of decreasing inequalities
   870     a >= b >= c ... in Isar proofs. *}
   871 
   872 lemma xt1:
   873   "a = b ==> b > c ==> a > c"
   874   "a > b ==> b = c ==> a > c"
   875   "a = b ==> b >= c ==> a >= c"
   876   "a >= b ==> b = c ==> a >= c"
   877   "(x::'a::order) >= y ==> y >= x ==> x = y"
   878   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   879   "(x::'a::order) > y ==> y >= z ==> x > z"
   880   "(x::'a::order) >= y ==> y > z ==> x > z"
   881   "(a::'a::order) > b ==> b > a ==> P"
   882   "(x::'a::order) > y ==> y > z ==> x > z"
   883   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   884   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   885   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   886   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   887   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   888   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   889   by auto
   890 
   891 lemma xt2:
   892   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   893 by (subgoal_tac "f b >= f c", force, force)
   894 
   895 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   896     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   897 by (subgoal_tac "f a >= f b", force, force)
   898 
   899 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   900   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   901 by (subgoal_tac "f b >= f c", force, force)
   902 
   903 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   904     (!!x y. x > y ==> f x > f y) ==> f a > c"
   905 by (subgoal_tac "f a > f b", force, force)
   906 
   907 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   908     (!!x y. x > y ==> f x > f y) ==> a > f c"
   909 by (subgoal_tac "f b > f c", force, force)
   910 
   911 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   912     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   913 by (subgoal_tac "f a >= f b", force, force)
   914 
   915 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   916     (!!x y. x > y ==> f x > f y) ==> a > f c"
   917 by (subgoal_tac "f b > f c", force, force)
   918 
   919 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   920     (!!x y. x > y ==> f x > f y) ==> f a > c"
   921 by (subgoal_tac "f a > f b", force, force)
   922 
   923 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   924 
   925 (* 
   926   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   927   for the wrong thing in an Isar proof.
   928 
   929   The extra transitivity rules can be used as follows: 
   930 
   931 lemma "(a::'a::order) > z"
   932 proof -
   933   have "a >= b" (is "_ >= ?rhs")
   934     sorry
   935   also have "?rhs >= c" (is "_ >= ?rhs")
   936     sorry
   937   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   938     sorry
   939   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   940     sorry
   941   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   942     sorry
   943   also (xtrans) have "?rhs > z"
   944     sorry
   945   finally (xtrans) show ?thesis .
   946 qed
   947 
   948   Alternatively, one can use "declare xtrans [trans]" and then
   949   leave out the "(xtrans)" above.
   950 *)
   951 
   952 subsection {* Order on bool *}
   953 
   954 instantiation bool :: order
   955 begin
   956 
   957 definition
   958   le_bool_def [code func del]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
   959 
   960 definition
   961   less_bool_def [code func del]: "(P\<Colon>bool) < Q \<longleftrightarrow> P \<le> Q \<and> P \<noteq> Q"
   962 
   963 instance
   964   by intro_classes (auto simp add: le_bool_def less_bool_def)
   965 
   966 end
   967 
   968 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   969 by (simp add: le_bool_def)
   970 
   971 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   972 by (simp add: le_bool_def)
   973 
   974 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   975 by (simp add: le_bool_def)
   976 
   977 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   978 by (simp add: le_bool_def)
   979 
   980 lemma [code func]:
   981   "False \<le> b \<longleftrightarrow> True"
   982   "True \<le> b \<longleftrightarrow> b"
   983   "False < b \<longleftrightarrow> b"
   984   "True < b \<longleftrightarrow> False"
   985   unfolding le_bool_def less_bool_def by simp_all
   986 
   987 
   988 subsection {* Order on functions *}
   989 
   990 instantiation "fun" :: (type, ord) ord
   991 begin
   992 
   993 definition
   994   le_fun_def [code func del]: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
   995 
   996 definition
   997   less_fun_def [code func del]: "(f\<Colon>'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> f \<noteq> g"
   998 
   999 instance ..
  1000 
  1001 end
  1002 
  1003 instance "fun" :: (type, order) order
  1004   by default
  1005     (auto simp add: le_fun_def less_fun_def
  1006        intro: order_trans order_antisym intro!: ext)
  1007 
  1008 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1009   unfolding le_fun_def by simp
  1010 
  1011 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1012   unfolding le_fun_def by simp
  1013 
  1014 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1015   unfolding le_fun_def by simp
  1016 
  1017 text {*
  1018   Handy introduction and elimination rules for @{text "\<le>"}
  1019   on unary and binary predicates
  1020 *}
  1021 
  1022 lemma predicate1I:
  1023   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1024   shows "P \<le> Q"
  1025   apply (rule le_funI)
  1026   apply (rule le_boolI)
  1027   apply (rule PQ)
  1028   apply assumption
  1029   done
  1030 
  1031 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1032   apply (erule le_funE)
  1033   apply (erule le_boolE)
  1034   apply assumption+
  1035   done
  1036 
  1037 lemma predicate2I [Pure.intro!, intro!]:
  1038   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1039   shows "P \<le> Q"
  1040   apply (rule le_funI)+
  1041   apply (rule le_boolI)
  1042   apply (rule PQ)
  1043   apply assumption
  1044   done
  1045 
  1046 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1047   apply (erule le_funE)+
  1048   apply (erule le_boolE)
  1049   apply assumption+
  1050   done
  1051 
  1052 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
  1053   by (rule predicate1D)
  1054 
  1055 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
  1056   by (rule predicate2D)
  1057 
  1058 
  1059 subsection {* Monotonicity, least value operator and min/max *}
  1060 
  1061 context order
  1062 begin
  1063 
  1064 definition
  1065   mono :: "('a \<Rightarrow> 'b\<Colon>order) \<Rightarrow> bool"
  1066 where
  1067   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
  1068 
  1069 lemma monoI [intro?]:
  1070   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1071   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
  1072   unfolding mono_def by iprover
  1073 
  1074 lemma monoD [dest?]:
  1075   fixes f :: "'a \<Rightarrow> 'b\<Colon>order"
  1076   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1077   unfolding mono_def by iprover
  1078 
  1079 end
  1080 
  1081 context linorder
  1082 begin
  1083 
  1084 lemma min_of_mono:
  1085   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1086   shows "mono f \<Longrightarrow> min (f m) (f n) = f (min m n)"
  1087   by (auto simp: mono_def Orderings.min_def min_def intro: Orderings.antisym)
  1088 
  1089 lemma max_of_mono:
  1090   fixes f :: "'a \<Rightarrow> 'b\<Colon>linorder"
  1091   shows "mono f \<Longrightarrow> max (f m) (f n) = f (max m n)"
  1092   by (auto simp: mono_def Orderings.max_def max_def intro: Orderings.antisym)
  1093 
  1094 end
  1095 
  1096 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
  1097 by (simp add: min_def)
  1098 
  1099 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
  1100 by (simp add: max_def)
  1101 
  1102 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
  1103 apply (simp add: min_def)
  1104 apply (blast intro: order_antisym)
  1105 done
  1106 
  1107 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
  1108 apply (simp add: max_def)
  1109 apply (blast intro: order_antisym)
  1110 done
  1111 
  1112 
  1113 subsection {* Dense orders *}
  1114 
  1115 class dense_linear_order = linorder + 
  1116   assumes gt_ex: "\<exists>y. x < y" 
  1117   and lt_ex: "\<exists>y. y < x"
  1118   and dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1119   (*see further theory Dense_Linear_Order*)
  1120 
  1121 
  1122 subsection {* Wellorders *}
  1123 
  1124 class wellorder = linorder +
  1125   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1126 begin
  1127 
  1128 lemma wellorder_Least_lemma:
  1129   fixes k :: 'a
  1130   assumes "P k"
  1131   shows "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k"
  1132 proof -
  1133   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1134   using assms proof (induct k rule: less_induct)
  1135     case (less x) then have "P x" by simp
  1136     show ?case proof (rule classical)
  1137       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1138       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1139       proof (rule classical)
  1140         fix y
  1141         assume "P y" and "\<not> x \<le> y" 
  1142         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1143           by (auto simp add: not_le)
  1144         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1145           by auto
  1146         then show "x \<le> y" by auto
  1147       qed
  1148       with `P x` have Least: "(LEAST a. P a) = x"
  1149         by (rule Least_equality)
  1150       with `P x` show ?thesis by simp
  1151     qed
  1152   qed
  1153   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1154 qed
  1155 
  1156 lemmas LeastI   = wellorder_Least_lemma(1)
  1157 lemmas Least_le = wellorder_Least_lemma(2)
  1158 
  1159 -- "The following 3 lemmas are due to Brian Huffman"
  1160 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1161   by (erule exE) (erule LeastI)
  1162 
  1163 lemma LeastI2:
  1164   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1165   by (blast intro: LeastI)
  1166 
  1167 lemma LeastI2_ex:
  1168   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1169   by (blast intro: LeastI_ex)
  1170 
  1171 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1172 apply (simp (no_asm_use) add: not_le [symmetric])
  1173 apply (erule contrapos_nn)
  1174 apply (erule Least_le)
  1175 done
  1176 
  1177 end  
  1178 
  1179 end