src/HOL/Relation.thy
author wenzelm
Wed Sep 17 21:27:14 2008 +0200 (2008-09-17)
changeset 28263 69eaa97e7e96
parent 28008 f945f8d9ad4d
child 29609 a010aab5bed0
permissions -rw-r--r--
moved global ML bindings to global place;
     1 (*  Title:      HOL/Relation.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 *)
     6 
     7 header {* Relations *}
     8 
     9 theory Relation
    10 imports Product_Type
    11 begin
    12 
    13 subsection {* Definitions *}
    14 
    15 definition
    16   converse :: "('a * 'b) set => ('b * 'a) set"
    17     ("(_^-1)" [1000] 999) where
    18   "r^-1 == {(y, x). (x, y) : r}"
    19 
    20 notation (xsymbols)
    21   converse  ("(_\<inverse>)" [1000] 999)
    22 
    23 definition
    24   rel_comp  :: "[('b * 'c) set, ('a * 'b) set] => ('a * 'c) set"
    25     (infixr "O" 75) where
    26   "r O s == {(x,z). EX y. (x, y) : s & (y, z) : r}"
    27 
    28 definition
    29   Image :: "[('a * 'b) set, 'a set] => 'b set"
    30     (infixl "``" 90) where
    31   "r `` s == {y. EX x:s. (x,y):r}"
    32 
    33 definition
    34   Id :: "('a * 'a) set" where -- {* the identity relation *}
    35   "Id == {p. EX x. p = (x,x)}"
    36 
    37 definition
    38   diag  :: "'a set => ('a * 'a) set" where -- {* diagonal: identity over a set *}
    39   "diag A == \<Union>x\<in>A. {(x,x)}"
    40 
    41 definition
    42   Domain :: "('a * 'b) set => 'a set" where
    43   "Domain r == {x. EX y. (x,y):r}"
    44 
    45 definition
    46   Range  :: "('a * 'b) set => 'b set" where
    47   "Range r == Domain(r^-1)"
    48 
    49 definition
    50   Field :: "('a * 'a) set => 'a set" where
    51   "Field r == Domain r \<union> Range r"
    52 
    53 definition
    54   refl :: "['a set, ('a * 'a) set] => bool" where -- {* reflexivity over a set *}
    55   "refl A r == r \<subseteq> A \<times> A & (ALL x: A. (x,x) : r)"
    56 
    57 abbreviation
    58   reflexive :: "('a * 'a) set => bool" where -- {* reflexivity over a type *}
    59   "reflexive == refl UNIV"
    60 
    61 definition
    62   sym :: "('a * 'a) set => bool" where -- {* symmetry predicate *}
    63   "sym r == ALL x y. (x,y): r --> (y,x): r"
    64 
    65 definition
    66   antisym :: "('a * 'a) set => bool" where -- {* antisymmetry predicate *}
    67   "antisym r == ALL x y. (x,y):r --> (y,x):r --> x=y"
    68 
    69 definition
    70   trans :: "('a * 'a) set => bool" where -- {* transitivity predicate *}
    71   "trans r == (ALL x y z. (x,y):r --> (y,z):r --> (x,z):r)"
    72 
    73 definition
    74   single_valued :: "('a * 'b) set => bool" where
    75   "single_valued r == ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z)"
    76 
    77 definition
    78   inv_image :: "('b * 'b) set => ('a => 'b) => ('a * 'a) set" where
    79   "inv_image r f == {(x, y). (f x, f y) : r}"
    80 
    81 
    82 subsection {* The identity relation *}
    83 
    84 lemma IdI [intro]: "(a, a) : Id"
    85 by (simp add: Id_def)
    86 
    87 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
    88 by (unfold Id_def) (iprover elim: CollectE)
    89 
    90 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
    91 by (unfold Id_def) blast
    92 
    93 lemma reflexive_Id: "reflexive Id"
    94 by (simp add: refl_def)
    95 
    96 lemma antisym_Id: "antisym Id"
    97   -- {* A strange result, since @{text Id} is also symmetric. *}
    98 by (simp add: antisym_def)
    99 
   100 lemma sym_Id: "sym Id"
   101 by (simp add: sym_def)
   102 
   103 lemma trans_Id: "trans Id"
   104 by (simp add: trans_def)
   105 
   106 
   107 subsection {* Diagonal: identity over a set *}
   108 
   109 lemma diag_empty [simp]: "diag {} = {}"
   110 by (simp add: diag_def) 
   111 
   112 lemma diag_eqI: "a = b ==> a : A ==> (a, b) : diag A"
   113 by (simp add: diag_def)
   114 
   115 lemma diagI [intro!,noatp]: "a : A ==> (a, a) : diag A"
   116 by (rule diag_eqI) (rule refl)
   117 
   118 lemma diagE [elim!]:
   119   "c : diag A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   120   -- {* The general elimination rule. *}
   121 by (unfold diag_def) (iprover elim!: UN_E singletonE)
   122 
   123 lemma diag_iff: "((x, y) : diag A) = (x = y & x : A)"
   124 by blast
   125 
   126 lemma diag_subset_Times: "diag A \<subseteq> A \<times> A"
   127 by blast
   128 
   129 
   130 subsection {* Composition of two relations *}
   131 
   132 lemma rel_compI [intro]:
   133   "(a, b) : s ==> (b, c) : r ==> (a, c) : r O s"
   134 by (unfold rel_comp_def) blast
   135 
   136 lemma rel_compE [elim!]: "xz : r O s ==>
   137   (!!x y z. xz = (x, z) ==> (x, y) : s ==> (y, z) : r  ==> P) ==> P"
   138 by (unfold rel_comp_def) (iprover elim!: CollectE splitE exE conjE)
   139 
   140 lemma rel_compEpair:
   141   "(a, c) : r O s ==> (!!y. (a, y) : s ==> (y, c) : r ==> P) ==> P"
   142 by (iprover elim: rel_compE Pair_inject ssubst)
   143 
   144 lemma R_O_Id [simp]: "R O Id = R"
   145 by fast
   146 
   147 lemma Id_O_R [simp]: "Id O R = R"
   148 by fast
   149 
   150 lemma rel_comp_empty1[simp]: "{} O R = {}"
   151 by blast
   152 
   153 lemma rel_comp_empty2[simp]: "R O {} = {}"
   154 by blast
   155 
   156 lemma O_assoc: "(R O S) O T = R O (S O T)"
   157 by blast
   158 
   159 lemma trans_O_subset: "trans r ==> r O r \<subseteq> r"
   160 by (unfold trans_def) blast
   161 
   162 lemma rel_comp_mono: "r' \<subseteq> r ==> s' \<subseteq> s ==> (r' O s') \<subseteq> (r O s)"
   163 by blast
   164 
   165 lemma rel_comp_subset_Sigma:
   166     "s \<subseteq> A \<times> B ==> r \<subseteq> B \<times> C ==> (r O s) \<subseteq> A \<times> C"
   167 by blast
   168 
   169 lemma rel_comp_distrib[simp]: "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   170 by auto
   171 
   172 lemma rel_comp_distrib2[simp]: "(S \<union> T) O R = (S O R) \<union> (T O R)"
   173 by auto
   174 
   175 
   176 subsection {* Reflexivity *}
   177 
   178 lemma reflI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl A r"
   179 by (unfold refl_def) (iprover intro!: ballI)
   180 
   181 lemma reflD: "refl A r ==> a : A ==> (a, a) : r"
   182 by (unfold refl_def) blast
   183 
   184 lemma reflD1: "refl A r ==> (x, y) : r ==> x : A"
   185 by (unfold refl_def) blast
   186 
   187 lemma reflD2: "refl A r ==> (x, y) : r ==> y : A"
   188 by (unfold refl_def) blast
   189 
   190 lemma refl_Int: "refl A r ==> refl B s ==> refl (A \<inter> B) (r \<inter> s)"
   191 by (unfold refl_def) blast
   192 
   193 lemma refl_Un: "refl A r ==> refl B s ==> refl (A \<union> B) (r \<union> s)"
   194 by (unfold refl_def) blast
   195 
   196 lemma refl_INTER:
   197   "ALL x:S. refl (A x) (r x) ==> refl (INTER S A) (INTER S r)"
   198 by (unfold refl_def) fast
   199 
   200 lemma refl_UNION:
   201   "ALL x:S. refl (A x) (r x) \<Longrightarrow> refl (UNION S A) (UNION S r)"
   202 by (unfold refl_def) blast
   203 
   204 lemma refl_empty[simp]: "refl {} {}"
   205 by(simp add:refl_def)
   206 
   207 lemma refl_diag: "refl A (diag A)"
   208 by (rule reflI [OF diag_subset_Times diagI])
   209 
   210 
   211 subsection {* Antisymmetry *}
   212 
   213 lemma antisymI:
   214   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   215 by (unfold antisym_def) iprover
   216 
   217 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   218 by (unfold antisym_def) iprover
   219 
   220 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   221 by (unfold antisym_def) blast
   222 
   223 lemma antisym_empty [simp]: "antisym {}"
   224 by (unfold antisym_def) blast
   225 
   226 lemma antisym_diag [simp]: "antisym (diag A)"
   227 by (unfold antisym_def) blast
   228 
   229 
   230 subsection {* Symmetry *}
   231 
   232 lemma symI: "(!!a b. (a, b) : r ==> (b, a) : r) ==> sym r"
   233 by (unfold sym_def) iprover
   234 
   235 lemma symD: "sym r ==> (a, b) : r ==> (b, a) : r"
   236 by (unfold sym_def, blast)
   237 
   238 lemma sym_Int: "sym r ==> sym s ==> sym (r \<inter> s)"
   239 by (fast intro: symI dest: symD)
   240 
   241 lemma sym_Un: "sym r ==> sym s ==> sym (r \<union> s)"
   242 by (fast intro: symI dest: symD)
   243 
   244 lemma sym_INTER: "ALL x:S. sym (r x) ==> sym (INTER S r)"
   245 by (fast intro: symI dest: symD)
   246 
   247 lemma sym_UNION: "ALL x:S. sym (r x) ==> sym (UNION S r)"
   248 by (fast intro: symI dest: symD)
   249 
   250 lemma sym_diag [simp]: "sym (diag A)"
   251 by (rule symI) clarify
   252 
   253 
   254 subsection {* Transitivity *}
   255 
   256 lemma transI:
   257   "(!!x y z. (x, y) : r ==> (y, z) : r ==> (x, z) : r) ==> trans r"
   258 by (unfold trans_def) iprover
   259 
   260 lemma transD: "trans r ==> (a, b) : r ==> (b, c) : r ==> (a, c) : r"
   261 by (unfold trans_def) iprover
   262 
   263 lemma trans_Int: "trans r ==> trans s ==> trans (r \<inter> s)"
   264 by (fast intro: transI elim: transD)
   265 
   266 lemma trans_INTER: "ALL x:S. trans (r x) ==> trans (INTER S r)"
   267 by (fast intro: transI elim: transD)
   268 
   269 lemma trans_diag [simp]: "trans (diag A)"
   270 by (fast intro: transI elim: transD)
   271 
   272 
   273 subsection {* Converse *}
   274 
   275 lemma converse_iff [iff]: "((a,b): r^-1) = ((b,a) : r)"
   276 by (simp add: converse_def)
   277 
   278 lemma converseI[sym]: "(a, b) : r ==> (b, a) : r^-1"
   279 by (simp add: converse_def)
   280 
   281 lemma converseD[sym]: "(a,b) : r^-1 ==> (b, a) : r"
   282 by (simp add: converse_def)
   283 
   284 lemma converseE [elim!]:
   285   "yx : r^-1 ==> (!!x y. yx = (y, x) ==> (x, y) : r ==> P) ==> P"
   286     -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   287 by (unfold converse_def) (iprover elim!: CollectE splitE bexE)
   288 
   289 lemma converse_converse [simp]: "(r^-1)^-1 = r"
   290 by (unfold converse_def) blast
   291 
   292 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   293 by blast
   294 
   295 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   296 by blast
   297 
   298 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   299 by blast
   300 
   301 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   302 by fast
   303 
   304 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   305 by blast
   306 
   307 lemma converse_Id [simp]: "Id^-1 = Id"
   308 by blast
   309 
   310 lemma converse_diag [simp]: "(diag A)^-1 = diag A"
   311 by blast
   312 
   313 lemma refl_converse [simp]: "refl A (converse r) = refl A r"
   314 by (unfold refl_def) auto
   315 
   316 lemma sym_converse [simp]: "sym (converse r) = sym r"
   317 by (unfold sym_def) blast
   318 
   319 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   320 by (unfold antisym_def) blast
   321 
   322 lemma trans_converse [simp]: "trans (converse r) = trans r"
   323 by (unfold trans_def) blast
   324 
   325 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   326 by (unfold sym_def) fast
   327 
   328 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   329 by (unfold sym_def) blast
   330 
   331 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   332 by (unfold sym_def) blast
   333 
   334 
   335 subsection {* Domain *}
   336 
   337 declare Domain_def [noatp]
   338 
   339 lemma Domain_iff: "(a : Domain r) = (EX y. (a, y) : r)"
   340 by (unfold Domain_def) blast
   341 
   342 lemma DomainI [intro]: "(a, b) : r ==> a : Domain r"
   343 by (iprover intro!: iffD2 [OF Domain_iff])
   344 
   345 lemma DomainE [elim!]:
   346   "a : Domain r ==> (!!y. (a, y) : r ==> P) ==> P"
   347 by (iprover dest!: iffD1 [OF Domain_iff])
   348 
   349 lemma Domain_empty [simp]: "Domain {} = {}"
   350 by blast
   351 
   352 lemma Domain_insert: "Domain (insert (a, b) r) = insert a (Domain r)"
   353 by blast
   354 
   355 lemma Domain_Id [simp]: "Domain Id = UNIV"
   356 by blast
   357 
   358 lemma Domain_diag [simp]: "Domain (diag A) = A"
   359 by blast
   360 
   361 lemma Domain_Un_eq: "Domain(A \<union> B) = Domain(A) \<union> Domain(B)"
   362 by blast
   363 
   364 lemma Domain_Int_subset: "Domain(A \<inter> B) \<subseteq> Domain(A) \<inter> Domain(B)"
   365 by blast
   366 
   367 lemma Domain_Diff_subset: "Domain(A) - Domain(B) \<subseteq> Domain(A - B)"
   368 by blast
   369 
   370 lemma Domain_Union: "Domain (Union S) = (\<Union>A\<in>S. Domain A)"
   371 by blast
   372 
   373 lemma Domain_converse[simp]: "Domain(r^-1) = Range r"
   374 by(auto simp:Range_def)
   375 
   376 lemma Domain_mono: "r \<subseteq> s ==> Domain r \<subseteq> Domain s"
   377 by blast
   378 
   379 lemma fst_eq_Domain: "fst ` R = Domain R";
   380 by (auto intro!:image_eqI)
   381 
   382 
   383 subsection {* Range *}
   384 
   385 lemma Range_iff: "(a : Range r) = (EX y. (y, a) : r)"
   386 by (simp add: Domain_def Range_def)
   387 
   388 lemma RangeI [intro]: "(a, b) : r ==> b : Range r"
   389 by (unfold Range_def) (iprover intro!: converseI DomainI)
   390 
   391 lemma RangeE [elim!]: "b : Range r ==> (!!x. (x, b) : r ==> P) ==> P"
   392 by (unfold Range_def) (iprover elim!: DomainE dest!: converseD)
   393 
   394 lemma Range_empty [simp]: "Range {} = {}"
   395 by blast
   396 
   397 lemma Range_insert: "Range (insert (a, b) r) = insert b (Range r)"
   398 by blast
   399 
   400 lemma Range_Id [simp]: "Range Id = UNIV"
   401 by blast
   402 
   403 lemma Range_diag [simp]: "Range (diag A) = A"
   404 by auto
   405 
   406 lemma Range_Un_eq: "Range(A \<union> B) = Range(A) \<union> Range(B)"
   407 by blast
   408 
   409 lemma Range_Int_subset: "Range(A \<inter> B) \<subseteq> Range(A) \<inter> Range(B)"
   410 by blast
   411 
   412 lemma Range_Diff_subset: "Range(A) - Range(B) \<subseteq> Range(A - B)"
   413 by blast
   414 
   415 lemma Range_Union: "Range (Union S) = (\<Union>A\<in>S. Range A)"
   416 by blast
   417 
   418 lemma Range_converse[simp]: "Range(r^-1) = Domain r"
   419 by blast
   420 
   421 lemma snd_eq_Range: "snd ` R = Range R";
   422 by (auto intro!:image_eqI)
   423 
   424 
   425 subsection {* Field *}
   426 
   427 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   428 by(auto simp:Field_def Domain_def Range_def)
   429 
   430 lemma Field_empty[simp]: "Field {} = {}"
   431 by(auto simp:Field_def)
   432 
   433 lemma Field_insert[simp]: "Field (insert (a,b) r) = {a,b} \<union> Field r"
   434 by(auto simp:Field_def)
   435 
   436 lemma Field_Un[simp]: "Field (r \<union> s) = Field r \<union> Field s"
   437 by(auto simp:Field_def)
   438 
   439 lemma Field_Union[simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   440 by(auto simp:Field_def)
   441 
   442 lemma Field_converse[simp]: "Field(r^-1) = Field r"
   443 by(auto simp:Field_def)
   444 
   445 
   446 subsection {* Image of a set under a relation *}
   447 
   448 declare Image_def [noatp]
   449 
   450 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   451 by (simp add: Image_def)
   452 
   453 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   454 by (simp add: Image_def)
   455 
   456 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   457 by (rule Image_iff [THEN trans]) simp
   458 
   459 lemma ImageI [intro,noatp]: "(a, b) : r ==> a : A ==> b : r``A"
   460 by (unfold Image_def) blast
   461 
   462 lemma ImageE [elim!]:
   463     "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   464 by (unfold Image_def) (iprover elim!: CollectE bexE)
   465 
   466 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   467   -- {* This version's more effective when we already have the required @{text a} *}
   468 by blast
   469 
   470 lemma Image_empty [simp]: "R``{} = {}"
   471 by blast
   472 
   473 lemma Image_Id [simp]: "Id `` A = A"
   474 by blast
   475 
   476 lemma Image_diag [simp]: "diag A `` B = A \<inter> B"
   477 by blast
   478 
   479 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   480 by blast
   481 
   482 lemma Image_Int_eq:
   483      "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   484 by (simp add: single_valued_def, blast) 
   485 
   486 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   487 by blast
   488 
   489 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   490 by blast
   491 
   492 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   493 by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   494 
   495 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   496   -- {* NOT suitable for rewriting *}
   497 by blast
   498 
   499 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   500 by blast
   501 
   502 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   503 by blast
   504 
   505 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   506 by blast
   507 
   508 text{*Converse inclusion requires some assumptions*}
   509 lemma Image_INT_eq:
   510      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   511 apply (rule equalityI)
   512  apply (rule Image_INT_subset) 
   513 apply  (simp add: single_valued_def, blast)
   514 done
   515 
   516 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   517 by blast
   518 
   519 
   520 subsection {* Single valued relations *}
   521 
   522 lemma single_valuedI:
   523   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   524 by (unfold single_valued_def)
   525 
   526 lemma single_valuedD:
   527   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   528 by (simp add: single_valued_def)
   529 
   530 lemma single_valued_rel_comp:
   531   "single_valued r ==> single_valued s ==> single_valued (r O s)"
   532 by (unfold single_valued_def) blast
   533 
   534 lemma single_valued_subset:
   535   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   536 by (unfold single_valued_def) blast
   537 
   538 lemma single_valued_Id [simp]: "single_valued Id"
   539 by (unfold single_valued_def) blast
   540 
   541 lemma single_valued_diag [simp]: "single_valued (diag A)"
   542 by (unfold single_valued_def) blast
   543 
   544 
   545 subsection {* Graphs given by @{text Collect} *}
   546 
   547 lemma Domain_Collect_split [simp]: "Domain{(x,y). P x y} = {x. EX y. P x y}"
   548 by auto
   549 
   550 lemma Range_Collect_split [simp]: "Range{(x,y). P x y} = {y. EX x. P x y}"
   551 by auto
   552 
   553 lemma Image_Collect_split [simp]: "{(x,y). P x y} `` A = {y. EX x:A. P x y}"
   554 by auto
   555 
   556 
   557 subsection {* Inverse image *}
   558 
   559 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
   560 by (unfold sym_def inv_image_def) blast
   561 
   562 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
   563   apply (unfold trans_def inv_image_def)
   564   apply (simp (no_asm))
   565   apply blast
   566   done
   567 
   568 
   569 subsection {* Version of @{text lfp_induct} for binary relations *}
   570 
   571 lemmas lfp_induct2 = 
   572   lfp_induct_set [of "(a, b)", split_format (complete)]
   573 
   574 end