src/HOL/SetInterval.thy
author wenzelm
Wed Sep 17 21:27:14 2008 +0200 (2008-09-17)
changeset 28263 69eaa97e7e96
parent 28068 f6b2d1995171
child 28853 69eb69659bf3
permissions -rw-r--r--
moved global ML bindings to global place;
     1 (*  Title:      HOL/SetInterval.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Clemens Ballarin
     4                 Additions by Jeremy Avigad in March 2004
     5     Copyright   2000  TU Muenchen
     6 
     7 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     8 *)
     9 
    10 header {* Set intervals *}
    11 
    12 theory SetInterval
    13 imports Int
    14 begin
    15 
    16 context ord
    17 begin
    18 definition
    19   lessThan    :: "'a => 'a set"	("(1{..<_})") where
    20   "{..<u} == {x. x < u}"
    21 
    22 definition
    23   atMost      :: "'a => 'a set"	("(1{.._})") where
    24   "{..u} == {x. x \<le> u}"
    25 
    26 definition
    27   greaterThan :: "'a => 'a set"	("(1{_<..})") where
    28   "{l<..} == {x. l<x}"
    29 
    30 definition
    31   atLeast     :: "'a => 'a set"	("(1{_..})") where
    32   "{l..} == {x. l\<le>x}"
    33 
    34 definition
    35   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    36   "{l<..<u} == {l<..} Int {..<u}"
    37 
    38 definition
    39   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    40   "{l..<u} == {l..} Int {..<u}"
    41 
    42 definition
    43   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    44   "{l<..u} == {l<..} Int {..u}"
    45 
    46 definition
    47   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    48   "{l..u} == {l..} Int {..u}"
    49 
    50 end
    51 
    52 
    53 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    54 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    55 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    56 
    57 syntax
    58   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    59   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    60   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    61   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    62 
    63 syntax (input)
    64   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    65   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    66   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    67   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    68 
    69 syntax (xsymbols)
    70   "@UNION_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    71   "@UNION_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    72   "@INTER_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    73   "@INTER_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    74 
    75 translations
    76   "UN i<=n. A"  == "UN i:{..n}. A"
    77   "UN i<n. A"   == "UN i:{..<n}. A"
    78   "INT i<=n. A" == "INT i:{..n}. A"
    79   "INT i<n. A"  == "INT i:{..<n}. A"
    80 
    81 
    82 subsection {* Various equivalences *}
    83 
    84 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    85 by (simp add: lessThan_def)
    86 
    87 lemma Compl_lessThan [simp]:
    88     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    89 apply (auto simp add: lessThan_def atLeast_def)
    90 done
    91 
    92 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    93 by auto
    94 
    95 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
    96 by (simp add: greaterThan_def)
    97 
    98 lemma Compl_greaterThan [simp]:
    99     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   100   by (auto simp add: greaterThan_def atMost_def)
   101 
   102 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   103 apply (subst Compl_greaterThan [symmetric])
   104 apply (rule double_complement)
   105 done
   106 
   107 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   108 by (simp add: atLeast_def)
   109 
   110 lemma Compl_atLeast [simp]:
   111     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   112   by (auto simp add: lessThan_def atLeast_def)
   113 
   114 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   115 by (simp add: atMost_def)
   116 
   117 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   118 by (blast intro: order_antisym)
   119 
   120 
   121 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   122 
   123 lemma atLeast_subset_iff [iff]:
   124      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   125 by (blast intro: order_trans)
   126 
   127 lemma atLeast_eq_iff [iff]:
   128      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   129 by (blast intro: order_antisym order_trans)
   130 
   131 lemma greaterThan_subset_iff [iff]:
   132      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   133 apply (auto simp add: greaterThan_def)
   134  apply (subst linorder_not_less [symmetric], blast)
   135 done
   136 
   137 lemma greaterThan_eq_iff [iff]:
   138      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   139 apply (rule iffI)
   140  apply (erule equalityE)
   141  apply (simp_all add: greaterThan_subset_iff)
   142 done
   143 
   144 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   145 by (blast intro: order_trans)
   146 
   147 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   148 by (blast intro: order_antisym order_trans)
   149 
   150 lemma lessThan_subset_iff [iff]:
   151      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   152 apply (auto simp add: lessThan_def)
   153  apply (subst linorder_not_less [symmetric], blast)
   154 done
   155 
   156 lemma lessThan_eq_iff [iff]:
   157      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   158 apply (rule iffI)
   159  apply (erule equalityE)
   160  apply (simp_all add: lessThan_subset_iff)
   161 done
   162 
   163 
   164 subsection {*Two-sided intervals*}
   165 
   166 context ord
   167 begin
   168 
   169 lemma greaterThanLessThan_iff [simp,noatp]:
   170   "(i : {l<..<u}) = (l < i & i < u)"
   171 by (simp add: greaterThanLessThan_def)
   172 
   173 lemma atLeastLessThan_iff [simp,noatp]:
   174   "(i : {l..<u}) = (l <= i & i < u)"
   175 by (simp add: atLeastLessThan_def)
   176 
   177 lemma greaterThanAtMost_iff [simp,noatp]:
   178   "(i : {l<..u}) = (l < i & i <= u)"
   179 by (simp add: greaterThanAtMost_def)
   180 
   181 lemma atLeastAtMost_iff [simp,noatp]:
   182   "(i : {l..u}) = (l <= i & i <= u)"
   183 by (simp add: atLeastAtMost_def)
   184 
   185 text {* The above four lemmas could be declared as iffs.
   186   If we do so, a call to blast in Hyperreal/Star.ML, lemma @{text STAR_Int}
   187   seems to take forever (more than one hour). *}
   188 end
   189 
   190 subsubsection{* Emptyness and singletons *}
   191 
   192 context order
   193 begin
   194 
   195 lemma atLeastAtMost_empty [simp]: "n < m ==> {m..n} = {}";
   196 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   197 
   198 lemma atLeastLessThan_empty[simp]: "n \<le> m ==> {m..<n} = {}"
   199 by (auto simp add: atLeastLessThan_def)
   200 
   201 lemma greaterThanAtMost_empty[simp]:"l \<le> k ==> {k<..l} = {}"
   202 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   203 
   204 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..l} = {}"
   205 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   206 
   207 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   208 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   209 
   210 end
   211 
   212 subsection {* Intervals of natural numbers *}
   213 
   214 subsubsection {* The Constant @{term lessThan} *}
   215 
   216 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   217 by (simp add: lessThan_def)
   218 
   219 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   220 by (simp add: lessThan_def less_Suc_eq, blast)
   221 
   222 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   223 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   224 
   225 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   226 by blast
   227 
   228 subsubsection {* The Constant @{term greaterThan} *}
   229 
   230 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   231 apply (simp add: greaterThan_def)
   232 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   233 done
   234 
   235 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   236 apply (simp add: greaterThan_def)
   237 apply (auto elim: linorder_neqE)
   238 done
   239 
   240 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   241 by blast
   242 
   243 subsubsection {* The Constant @{term atLeast} *}
   244 
   245 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   246 by (unfold atLeast_def UNIV_def, simp)
   247 
   248 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   249 apply (simp add: atLeast_def)
   250 apply (simp add: Suc_le_eq)
   251 apply (simp add: order_le_less, blast)
   252 done
   253 
   254 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   255   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   256 
   257 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   258 by blast
   259 
   260 subsubsection {* The Constant @{term atMost} *}
   261 
   262 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   263 by (simp add: atMost_def)
   264 
   265 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   266 apply (simp add: atMost_def)
   267 apply (simp add: less_Suc_eq order_le_less, blast)
   268 done
   269 
   270 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   271 by blast
   272 
   273 subsubsection {* The Constant @{term atLeastLessThan} *}
   274 
   275 text{*The orientation of the following 2 rules is tricky. The lhs is
   276 defined in terms of the rhs.  Hence the chosen orientation makes sense
   277 in this theory --- the reverse orientation complicates proofs (eg
   278 nontermination). But outside, when the definition of the lhs is rarely
   279 used, the opposite orientation seems preferable because it reduces a
   280 specific concept to a more general one. *}
   281 
   282 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   283 by(simp add:lessThan_def atLeastLessThan_def)
   284 
   285 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   286 by(simp add:atMost_def atLeastAtMost_def)
   287 
   288 declare atLeast0LessThan[symmetric, code unfold]
   289         atLeast0AtMost[symmetric, code unfold]
   290 
   291 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   292 by (simp add: atLeastLessThan_def)
   293 
   294 subsubsection {* Intervals of nats with @{term Suc} *}
   295 
   296 text{*Not a simprule because the RHS is too messy.*}
   297 lemma atLeastLessThanSuc:
   298     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   299 by (auto simp add: atLeastLessThan_def)
   300 
   301 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   302 by (auto simp add: atLeastLessThan_def)
   303 (*
   304 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   305 by (induct k, simp_all add: atLeastLessThanSuc)
   306 
   307 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   308 by (auto simp add: atLeastLessThan_def)
   309 *)
   310 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   311   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   312 
   313 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   314   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   315     greaterThanAtMost_def)
   316 
   317 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   318   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   319     greaterThanLessThan_def)
   320 
   321 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   322 by (auto simp add: atLeastAtMost_def)
   323 
   324 subsubsection {* Image *}
   325 
   326 lemma image_add_atLeastAtMost:
   327   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   328 proof
   329   show "?A \<subseteq> ?B" by auto
   330 next
   331   show "?B \<subseteq> ?A"
   332   proof
   333     fix n assume a: "n : ?B"
   334     hence "n - k : {i..j}" by auto
   335     moreover have "n = (n - k) + k" using a by auto
   336     ultimately show "n : ?A" by blast
   337   qed
   338 qed
   339 
   340 lemma image_add_atLeastLessThan:
   341   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   342 proof
   343   show "?A \<subseteq> ?B" by auto
   344 next
   345   show "?B \<subseteq> ?A"
   346   proof
   347     fix n assume a: "n : ?B"
   348     hence "n - k : {i..<j}" by auto
   349     moreover have "n = (n - k) + k" using a by auto
   350     ultimately show "n : ?A" by blast
   351   qed
   352 qed
   353 
   354 corollary image_Suc_atLeastAtMost[simp]:
   355   "Suc ` {i..j} = {Suc i..Suc j}"
   356 using image_add_atLeastAtMost[where k=1] by simp
   357 
   358 corollary image_Suc_atLeastLessThan[simp]:
   359   "Suc ` {i..<j} = {Suc i..<Suc j}"
   360 using image_add_atLeastLessThan[where k=1] by simp
   361 
   362 lemma image_add_int_atLeastLessThan:
   363     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   364   apply (auto simp add: image_def)
   365   apply (rule_tac x = "x - l" in bexI)
   366   apply auto
   367   done
   368 
   369 
   370 subsubsection {* Finiteness *}
   371 
   372 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   373   by (induct k) (simp_all add: lessThan_Suc)
   374 
   375 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   376   by (induct k) (simp_all add: atMost_Suc)
   377 
   378 lemma finite_greaterThanLessThan [iff]:
   379   fixes l :: nat shows "finite {l<..<u}"
   380 by (simp add: greaterThanLessThan_def)
   381 
   382 lemma finite_atLeastLessThan [iff]:
   383   fixes l :: nat shows "finite {l..<u}"
   384 by (simp add: atLeastLessThan_def)
   385 
   386 lemma finite_greaterThanAtMost [iff]:
   387   fixes l :: nat shows "finite {l<..u}"
   388 by (simp add: greaterThanAtMost_def)
   389 
   390 lemma finite_atLeastAtMost [iff]:
   391   fixes l :: nat shows "finite {l..u}"
   392 by (simp add: atLeastAtMost_def)
   393 
   394 text {* A bounded set of natural numbers is finite. *}
   395 lemma bounded_nat_set_is_finite:
   396   "(ALL i:N. i < (n::nat)) ==> finite N"
   397 apply (rule finite_subset)
   398  apply (rule_tac [2] finite_lessThan, auto)
   399 done
   400 
   401 lemma finite_less_ub:
   402      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
   403 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
   404 
   405 text{* Any subset of an interval of natural numbers the size of the
   406 subset is exactly that interval. *}
   407 
   408 lemma subset_card_intvl_is_intvl:
   409   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   410 proof cases
   411   assume "finite A"
   412   thus "PROP ?P"
   413   proof(induct A rule:finite_linorder_induct)
   414     case empty thus ?case by auto
   415   next
   416     case (insert A b)
   417     moreover hence "b ~: A" by auto
   418     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   419       using `b ~: A` insert by fastsimp+
   420     ultimately show ?case by auto
   421   qed
   422 next
   423   assume "~finite A" thus "PROP ?P" by simp
   424 qed
   425 
   426 
   427 subsubsection {* Cardinality *}
   428 
   429 lemma card_lessThan [simp]: "card {..<u} = u"
   430   by (induct u, simp_all add: lessThan_Suc)
   431 
   432 lemma card_atMost [simp]: "card {..u} = Suc u"
   433   by (simp add: lessThan_Suc_atMost [THEN sym])
   434 
   435 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   436   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   437   apply (erule ssubst, rule card_lessThan)
   438   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   439   apply (erule subst)
   440   apply (rule card_image)
   441   apply (simp add: inj_on_def)
   442   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   443   apply (rule_tac x = "x - l" in exI)
   444   apply arith
   445   done
   446 
   447 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   448   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   449 
   450 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   451   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   452 
   453 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   454   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   455 
   456 
   457 lemma ex_bij_betw_nat_finite:
   458   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   459 apply(drule finite_imp_nat_seg_image_inj_on)
   460 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   461 done
   462 
   463 lemma ex_bij_betw_finite_nat:
   464   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   465 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   466 
   467 
   468 subsection {* Intervals of integers *}
   469 
   470 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   471   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   472 
   473 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   474   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   475 
   476 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   477     "{l+1..<u} = {l<..<u::int}"
   478   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   479 
   480 subsubsection {* Finiteness *}
   481 
   482 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   483     {(0::int)..<u} = int ` {..<nat u}"
   484   apply (unfold image_def lessThan_def)
   485   apply auto
   486   apply (rule_tac x = "nat x" in exI)
   487   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   488   done
   489 
   490 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   491   apply (case_tac "0 \<le> u")
   492   apply (subst image_atLeastZeroLessThan_int, assumption)
   493   apply (rule finite_imageI)
   494   apply auto
   495   done
   496 
   497 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   498   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   499   apply (erule subst)
   500   apply (rule finite_imageI)
   501   apply (rule finite_atLeastZeroLessThan_int)
   502   apply (rule image_add_int_atLeastLessThan)
   503   done
   504 
   505 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   506   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   507 
   508 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   509   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   510 
   511 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   512   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   513 
   514 
   515 subsubsection {* Cardinality *}
   516 
   517 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   518   apply (case_tac "0 \<le> u")
   519   apply (subst image_atLeastZeroLessThan_int, assumption)
   520   apply (subst card_image)
   521   apply (auto simp add: inj_on_def)
   522   done
   523 
   524 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   525   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   526   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   527   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   528   apply (erule subst)
   529   apply (rule card_image)
   530   apply (simp add: inj_on_def)
   531   apply (rule image_add_int_atLeastLessThan)
   532   done
   533 
   534 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   535   apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   536   apply (auto simp add: compare_rls)
   537   done
   538 
   539 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   540   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   541 
   542 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   543   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   544 
   545 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   546 proof -
   547   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   548   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   549 qed
   550 
   551 lemma card_less:
   552 assumes zero_in_M: "0 \<in> M"
   553 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   554 proof -
   555   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   556   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   557 qed
   558 
   559 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   560 apply (rule card_bij_eq [of "Suc" _ _ "\<lambda>x. x - 1"])
   561 apply simp
   562 apply fastsimp
   563 apply auto
   564 apply (rule inj_on_diff_nat)
   565 apply auto
   566 apply (case_tac x)
   567 apply auto
   568 apply (case_tac xa)
   569 apply auto
   570 apply (case_tac xa)
   571 apply auto
   572 apply (auto simp add: finite_M_bounded_by_nat)
   573 done
   574 
   575 lemma card_less_Suc:
   576   assumes zero_in_M: "0 \<in> M"
   577     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   578 proof -
   579   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   580   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   581     by (auto simp only: insert_Diff)
   582   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   583   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   584     apply (subst card_insert)
   585     apply simp_all
   586     apply (subst b)
   587     apply (subst card_less_Suc2[symmetric])
   588     apply simp_all
   589     done
   590   with c show ?thesis by simp
   591 qed
   592 
   593 
   594 subsection {*Lemmas useful with the summation operator setsum*}
   595 
   596 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   597 
   598 subsubsection {* Disjoint Unions *}
   599 
   600 text {* Singletons and open intervals *}
   601 
   602 lemma ivl_disj_un_singleton:
   603   "{l::'a::linorder} Un {l<..} = {l..}"
   604   "{..<u} Un {u::'a::linorder} = {..u}"
   605   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   606   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   607   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   608   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   609 by auto
   610 
   611 text {* One- and two-sided intervals *}
   612 
   613 lemma ivl_disj_un_one:
   614   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   615   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   616   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   617   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   618   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   619   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   620   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   621   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   622 by auto
   623 
   624 text {* Two- and two-sided intervals *}
   625 
   626 lemma ivl_disj_un_two:
   627   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   628   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   629   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   630   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   631   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   632   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   633   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   634   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   635 by auto
   636 
   637 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   638 
   639 subsubsection {* Disjoint Intersections *}
   640 
   641 text {* Singletons and open intervals *}
   642 
   643 lemma ivl_disj_int_singleton:
   644   "{l::'a::order} Int {l<..} = {}"
   645   "{..<u} Int {u} = {}"
   646   "{l} Int {l<..<u} = {}"
   647   "{l<..<u} Int {u} = {}"
   648   "{l} Int {l<..u} = {}"
   649   "{l..<u} Int {u} = {}"
   650   by simp+
   651 
   652 text {* One- and two-sided intervals *}
   653 
   654 lemma ivl_disj_int_one:
   655   "{..l::'a::order} Int {l<..<u} = {}"
   656   "{..<l} Int {l..<u} = {}"
   657   "{..l} Int {l<..u} = {}"
   658   "{..<l} Int {l..u} = {}"
   659   "{l<..u} Int {u<..} = {}"
   660   "{l<..<u} Int {u..} = {}"
   661   "{l..u} Int {u<..} = {}"
   662   "{l..<u} Int {u..} = {}"
   663   by auto
   664 
   665 text {* Two- and two-sided intervals *}
   666 
   667 lemma ivl_disj_int_two:
   668   "{l::'a::order<..<m} Int {m..<u} = {}"
   669   "{l<..m} Int {m<..<u} = {}"
   670   "{l..<m} Int {m..<u} = {}"
   671   "{l..m} Int {m<..<u} = {}"
   672   "{l<..<m} Int {m..u} = {}"
   673   "{l<..m} Int {m<..u} = {}"
   674   "{l..<m} Int {m..u} = {}"
   675   "{l..m} Int {m<..u} = {}"
   676   by auto
   677 
   678 lemmas ivl_disj_int = ivl_disj_int_singleton ivl_disj_int_one ivl_disj_int_two
   679 
   680 subsubsection {* Some Differences *}
   681 
   682 lemma ivl_diff[simp]:
   683  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   684 by(auto)
   685 
   686 
   687 subsubsection {* Some Subset Conditions *}
   688 
   689 lemma ivl_subset [simp,noatp]:
   690  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   691 apply(auto simp:linorder_not_le)
   692 apply(rule ccontr)
   693 apply(insert linorder_le_less_linear[of i n])
   694 apply(clarsimp simp:linorder_not_le)
   695 apply(fastsimp)
   696 done
   697 
   698 
   699 subsection {* Summation indexed over intervals *}
   700 
   701 syntax
   702   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   703   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   704   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   705   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   706 syntax (xsymbols)
   707   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   708   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   709   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   710   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   711 syntax (HTML output)
   712   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   713   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   714   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   715   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   716 syntax (latex_sum output)
   717   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   718  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   719   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   720  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   721   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   722  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   723   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   724  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   725 
   726 translations
   727   "\<Sum>x=a..b. t" == "setsum (%x. t) {a..b}"
   728   "\<Sum>x=a..<b. t" == "setsum (%x. t) {a..<b}"
   729   "\<Sum>i\<le>n. t" == "setsum (\<lambda>i. t) {..n}"
   730   "\<Sum>i<n. t" == "setsum (\<lambda>i. t) {..<n}"
   731 
   732 text{* The above introduces some pretty alternative syntaxes for
   733 summation over intervals:
   734 \begin{center}
   735 \begin{tabular}{lll}
   736 Old & New & \LaTeX\\
   737 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   738 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   739 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   740 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   741 \end{tabular}
   742 \end{center}
   743 The left column shows the term before introduction of the new syntax,
   744 the middle column shows the new (default) syntax, and the right column
   745 shows a special syntax. The latter is only meaningful for latex output
   746 and has to be activated explicitly by setting the print mode to
   747 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   748 antiquotations). It is not the default \LaTeX\ output because it only
   749 works well with italic-style formulae, not tt-style.
   750 
   751 Note that for uniformity on @{typ nat} it is better to use
   752 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   753 not provide all lemmas available for @{term"{m..<n}"} also in the
   754 special form for @{term"{..<n}"}. *}
   755 
   756 text{* This congruence rule should be used for sums over intervals as
   757 the standard theorem @{text[source]setsum_cong} does not work well
   758 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   759 the context. *}
   760 
   761 lemma setsum_ivl_cong:
   762  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   763  setsum f {a..<b} = setsum g {c..<d}"
   764 by(rule setsum_cong, simp_all)
   765 
   766 (* FIXME why are the following simp rules but the corresponding eqns
   767 on intervals are not? *)
   768 
   769 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   770 by (simp add:atMost_Suc add_ac)
   771 
   772 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   773 by (simp add:lessThan_Suc add_ac)
   774 
   775 lemma setsum_cl_ivl_Suc[simp]:
   776   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   777 by (auto simp:add_ac atLeastAtMostSuc_conv)
   778 
   779 lemma setsum_op_ivl_Suc[simp]:
   780   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   781 by (auto simp:add_ac atLeastLessThanSuc)
   782 (*
   783 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   784     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   785 by (auto simp:add_ac atLeastAtMostSuc_conv)
   786 *)
   787 
   788 lemma setsum_head:
   789   fixes n :: nat
   790   assumes mn: "m <= n" 
   791   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   792 proof -
   793   from mn
   794   have "{m..n} = {m} \<union> {m<..n}"
   795     by (auto intro: ivl_disj_un_singleton)
   796   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   797     by (simp add: atLeast0LessThan)
   798   also have "\<dots> = ?rhs" by simp
   799   finally show ?thesis .
   800 qed
   801 
   802 lemma setsum_head_Suc:
   803   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
   804 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
   805 
   806 lemma setsum_head_upt_Suc:
   807   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
   808 apply(insert setsum_head_Suc[of m "n - 1" f])
   809 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] ring_simps)
   810 done
   811 
   812 
   813 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   814   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   815 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   816 
   817 lemma setsum_diff_nat_ivl:
   818 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   819 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   820   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   821 using setsum_add_nat_ivl [of m n p f,symmetric]
   822 apply (simp add: add_ac)
   823 done
   824 
   825 
   826 subsection{* Shifting bounds *}
   827 
   828 lemma setsum_shift_bounds_nat_ivl:
   829   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   830 by (induct "n", auto simp:atLeastLessThanSuc)
   831 
   832 lemma setsum_shift_bounds_cl_nat_ivl:
   833   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
   834 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
   835 apply (simp add:image_add_atLeastAtMost o_def)
   836 done
   837 
   838 corollary setsum_shift_bounds_cl_Suc_ivl:
   839   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
   840 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k=1,simplified])
   841 
   842 corollary setsum_shift_bounds_Suc_ivl:
   843   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
   844 by (simp add:setsum_shift_bounds_nat_ivl[where k=1,simplified])
   845 
   846 lemma setsum_shift_lb_Suc0_0:
   847   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
   848 by(simp add:setsum_head_Suc)
   849 
   850 lemma setsum_shift_lb_Suc0_0_upt:
   851   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
   852 apply(cases k)apply simp
   853 apply(simp add:setsum_head_upt_Suc)
   854 done
   855 
   856 subsection {* The formula for geometric sums *}
   857 
   858 lemma geometric_sum:
   859   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
   860   (x ^ n - 1) / (x - 1::'a::{field, recpower})"
   861 by (induct "n") (simp_all add:field_simps power_Suc)
   862 
   863 subsection {* The formula for arithmetic sums *}
   864 
   865 lemma gauss_sum:
   866   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
   867    of_nat n*((of_nat n)+1)"
   868 proof (induct n)
   869   case 0
   870   show ?case by simp
   871 next
   872   case (Suc n)
   873   then show ?case by (simp add: ring_simps)
   874 qed
   875 
   876 theorem arith_series_general:
   877   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   878   of_nat n * (a + (a + of_nat(n - 1)*d))"
   879 proof cases
   880   assume ngt1: "n > 1"
   881   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
   882   have
   883     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
   884      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
   885     by (rule setsum_addf)
   886   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
   887   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
   888     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt mult_ac)
   889   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
   890     by (simp add: left_distrib right_distrib)
   891   also from ngt1 have "{1..<n} = {1..n - 1}"
   892     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
   893   also from ngt1
   894   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
   895     by (simp only: mult_ac gauss_sum [of "n - 1"])
   896        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
   897   finally show ?thesis by (simp add: mult_ac add_ac right_distrib)
   898 next
   899   assume "\<not>(n > 1)"
   900   hence "n = 1 \<or> n = 0" by auto
   901   thus ?thesis by (auto simp: mult_ac right_distrib)
   902 qed
   903 
   904 lemma arith_series_nat:
   905   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
   906 proof -
   907   have
   908     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
   909     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
   910     by (rule arith_series_general)
   911   thus ?thesis by (auto simp add: of_nat_id)
   912 qed
   913 
   914 lemma arith_series_int:
   915   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   916   of_nat n * (a + (a + of_nat(n - 1)*d))"
   917 proof -
   918   have
   919     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   920     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
   921     by (rule arith_series_general)
   922   thus ?thesis by simp
   923 qed
   924 
   925 lemma sum_diff_distrib:
   926   fixes P::"nat\<Rightarrow>nat"
   927   shows
   928   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
   929   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
   930 proof (induct n)
   931   case 0 show ?case by simp
   932 next
   933   case (Suc n)
   934 
   935   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
   936   let ?rhs = "\<Sum>x<n. P x - Q x"
   937 
   938   from Suc have "?lhs = ?rhs" by simp
   939   moreover
   940   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
   941   moreover
   942   from Suc have
   943     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
   944     by (subst diff_diff_left[symmetric],
   945         subst diff_add_assoc2)
   946        (auto simp: diff_add_assoc2 intro: setsum_mono)
   947   ultimately
   948   show ?case by simp
   949 qed
   950 
   951 end