src/HOL/Power.thy
author haftmann
Sat Jun 28 09:16:42 2014 +0200 (2014-06-28)
changeset 57418 6ab1c7cb0b8d
parent 56544 b60d5d119489
child 57512 cc97b347b301
permissions -rw-r--r--
fact consolidation
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 header {* Exponentiation *}
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 subsection {* Powers for Arbitrary Monoids *}
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    18     power_0: "a ^ 0 = 1"
    19   | power_Suc: "a ^ Suc n = a * a ^ n"
    20 
    21 notation (latex output)
    22   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    23 
    24 notation (HTML output)
    25   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    26 
    27 text {* Special syntax for squares. *}
    28 
    29 abbreviation (xsymbols)
    30   power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999) where
    31   "x\<^sup>2 \<equiv> x ^ 2"
    32 
    33 notation (latex output)
    34   power2  ("(_\<^sup>2)" [1000] 999)
    35 
    36 notation (HTML output)
    37   power2  ("(_\<^sup>2)" [1000] 999)
    38 
    39 end
    40 
    41 context monoid_mult
    42 begin
    43 
    44 subclass power .
    45 
    46 lemma power_one [simp]:
    47   "1 ^ n = 1"
    48   by (induct n) simp_all
    49 
    50 lemma power_one_right [simp]:
    51   "a ^ 1 = a"
    52   by simp
    53 
    54 lemma power_commutes:
    55   "a ^ n * a = a * a ^ n"
    56   by (induct n) (simp_all add: mult_assoc)
    57 
    58 lemma power_Suc2:
    59   "a ^ Suc n = a ^ n * a"
    60   by (simp add: power_commutes)
    61 
    62 lemma power_add:
    63   "a ^ (m + n) = a ^ m * a ^ n"
    64   by (induct m) (simp_all add: algebra_simps)
    65 
    66 lemma power_mult:
    67   "a ^ (m * n) = (a ^ m) ^ n"
    68   by (induct n) (simp_all add: power_add)
    69 
    70 lemma power2_eq_square: "a\<^sup>2 = a * a"
    71   by (simp add: numeral_2_eq_2)
    72 
    73 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    74   by (simp add: numeral_3_eq_3 mult_assoc)
    75 
    76 lemma power_even_eq:
    77   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    78   by (subst mult_commute) (simp add: power_mult)
    79 
    80 lemma power_odd_eq:
    81   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    82   by (simp add: power_even_eq)
    83 
    84 lemma power_numeral_even:
    85   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    86   unfolding numeral_Bit0 power_add Let_def ..
    87 
    88 lemma power_numeral_odd:
    89   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    90   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    91   unfolding power_Suc power_add Let_def mult_assoc ..
    92 
    93 lemma funpow_times_power:
    94   "(times x ^^ f x) = times (x ^ f x)"
    95 proof (induct "f x" arbitrary: f)
    96   case 0 then show ?case by (simp add: fun_eq_iff)
    97 next
    98   case (Suc n)
    99   def g \<equiv> "\<lambda>x. f x - 1"
   100   with Suc have "n = g x" by simp
   101   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   102   moreover from Suc g_def have "f x = g x + 1" by simp
   103   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult_assoc)
   104 qed
   105 
   106 end
   107 
   108 context comm_monoid_mult
   109 begin
   110 
   111 lemma power_mult_distrib [field_simps]:
   112   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   113   by (induct n) (simp_all add: mult_ac)
   114 
   115 end
   116 
   117 context semiring_numeral
   118 begin
   119 
   120 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   121   by (simp only: sqr_conv_mult numeral_mult)
   122 
   123 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   124   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   125     numeral_sqr numeral_mult power_add power_one_right)
   126 
   127 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   128   by (rule numeral_pow [symmetric])
   129 
   130 end
   131 
   132 context semiring_1
   133 begin
   134 
   135 lemma of_nat_power:
   136   "of_nat (m ^ n) = of_nat m ^ n"
   137   by (induct n) (simp_all add: of_nat_mult)
   138 
   139 lemma power_zero_numeral [simp]: "(0::'a) ^ numeral k = 0"
   140   by (simp add: numeral_eq_Suc)
   141 
   142 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   143   by (rule power_zero_numeral)
   144 
   145 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   146   by (rule power_one)
   147 
   148 end
   149 
   150 context comm_semiring_1
   151 begin
   152 
   153 text {* The divides relation *}
   154 
   155 lemma le_imp_power_dvd:
   156   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   157 proof
   158   have "a ^ n = a ^ (m + (n - m))"
   159     using `m \<le> n` by simp
   160   also have "\<dots> = a ^ m * a ^ (n - m)"
   161     by (rule power_add)
   162   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   163 qed
   164 
   165 lemma power_le_dvd:
   166   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   167   by (rule dvd_trans [OF le_imp_power_dvd])
   168 
   169 lemma dvd_power_same:
   170   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   171   by (induct n) (auto simp add: mult_dvd_mono)
   172 
   173 lemma dvd_power_le:
   174   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   175   by (rule power_le_dvd [OF dvd_power_same])
   176 
   177 lemma dvd_power [simp]:
   178   assumes "n > (0::nat) \<or> x = 1"
   179   shows "x dvd (x ^ n)"
   180 using assms proof
   181   assume "0 < n"
   182   then have "x ^ n = x ^ Suc (n - 1)" by simp
   183   then show "x dvd (x ^ n)" by simp
   184 next
   185   assume "x = 1"
   186   then show "x dvd (x ^ n)" by simp
   187 qed
   188 
   189 end
   190 
   191 context ring_1
   192 begin
   193 
   194 lemma power_minus:
   195   "(- a) ^ n = (- 1) ^ n * a ^ n"
   196 proof (induct n)
   197   case 0 show ?case by simp
   198 next
   199   case (Suc n) then show ?case
   200     by (simp del: power_Suc add: power_Suc2 mult_assoc)
   201 qed
   202 
   203 lemma power_minus_Bit0:
   204   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   205   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   206     power_one_right mult_minus_left mult_minus_right minus_minus)
   207 
   208 lemma power_minus_Bit1:
   209   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   210   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   211 
   212 lemma power2_minus [simp]:
   213   "(- a)\<^sup>2 = a\<^sup>2"
   214   by (rule power_minus_Bit0)
   215 
   216 lemma power_minus1_even [simp]:
   217   "-1 ^ (2*n) = 1"
   218 proof (induct n)
   219   case 0 show ?case by simp
   220 next
   221   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   222 qed
   223 
   224 lemma power_minus1_odd:
   225   "-1 ^ Suc (2*n) = -1"
   226   by simp
   227 
   228 lemma power_minus_even [simp]:
   229   "(-a) ^ (2*n) = a ^ (2*n)"
   230   by (simp add: power_minus [of a])
   231 
   232 end
   233 
   234 context ring_1_no_zero_divisors
   235 begin
   236 
   237 lemma field_power_not_zero:
   238   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   239   by (induct n) auto
   240 
   241 lemma zero_eq_power2 [simp]:
   242   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   243   unfolding power2_eq_square by simp
   244 
   245 lemma power2_eq_1_iff:
   246   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   247   unfolding power2_eq_square by (rule square_eq_1_iff)
   248 
   249 end
   250 
   251 context idom
   252 begin
   253 
   254 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   255   unfolding power2_eq_square by (rule square_eq_iff)
   256 
   257 end
   258 
   259 context division_ring
   260 begin
   261 
   262 text {* FIXME reorient or rename to @{text nonzero_inverse_power} *}
   263 lemma nonzero_power_inverse:
   264   "a \<noteq> 0 \<Longrightarrow> inverse (a ^ n) = (inverse a) ^ n"
   265   by (induct n)
   266     (simp_all add: nonzero_inverse_mult_distrib power_commutes field_power_not_zero)
   267 
   268 end
   269 
   270 context field
   271 begin
   272 
   273 lemma nonzero_power_divide:
   274   "b \<noteq> 0 \<Longrightarrow> (a / b) ^ n = a ^ n / b ^ n"
   275   by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   276 
   277 end
   278 
   279 
   280 subsection {* Exponentiation on ordered types *}
   281 
   282 context linordered_ring (* TODO: move *)
   283 begin
   284 
   285 lemma sum_squares_ge_zero:
   286   "0 \<le> x * x + y * y"
   287   by (intro add_nonneg_nonneg zero_le_square)
   288 
   289 lemma not_sum_squares_lt_zero:
   290   "\<not> x * x + y * y < 0"
   291   by (simp add: not_less sum_squares_ge_zero)
   292 
   293 end
   294 
   295 context linordered_semidom
   296 begin
   297 
   298 lemma zero_less_power [simp]:
   299   "0 < a \<Longrightarrow> 0 < a ^ n"
   300   by (induct n) simp_all
   301 
   302 lemma zero_le_power [simp]:
   303   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   304   by (induct n) simp_all
   305 
   306 lemma power_mono:
   307   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   308   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   309 
   310 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   311   using power_mono [of 1 a n] by simp
   312 
   313 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   314   using power_mono [of a 1 n] by simp
   315 
   316 lemma power_gt1_lemma:
   317   assumes gt1: "1 < a"
   318   shows "1 < a * a ^ n"
   319 proof -
   320   from gt1 have "0 \<le> a"
   321     by (fact order_trans [OF zero_le_one less_imp_le])
   322   have "1 * 1 < a * 1" using gt1 by simp
   323   also have "\<dots> \<le> a * a ^ n" using gt1
   324     by (simp only: mult_mono `0 \<le> a` one_le_power order_less_imp_le
   325         zero_le_one order_refl)
   326   finally show ?thesis by simp
   327 qed
   328 
   329 lemma power_gt1:
   330   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   331   by (simp add: power_gt1_lemma)
   332 
   333 lemma one_less_power [simp]:
   334   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   335   by (cases n) (simp_all add: power_gt1_lemma)
   336 
   337 lemma power_le_imp_le_exp:
   338   assumes gt1: "1 < a"
   339   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   340 proof (induct m arbitrary: n)
   341   case 0
   342   show ?case by simp
   343 next
   344   case (Suc m)
   345   show ?case
   346   proof (cases n)
   347     case 0
   348     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   349     with gt1 show ?thesis
   350       by (force simp only: power_gt1_lemma
   351           not_less [symmetric])
   352   next
   353     case (Suc n)
   354     with Suc.prems Suc.hyps show ?thesis
   355       by (force dest: mult_left_le_imp_le
   356           simp add: less_trans [OF zero_less_one gt1])
   357   qed
   358 qed
   359 
   360 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   361 lemma power_inject_exp [simp]:
   362   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   363   by (force simp add: order_antisym power_le_imp_le_exp)
   364 
   365 text{*Can relax the first premise to @{term "0<a"} in the case of the
   366 natural numbers.*}
   367 lemma power_less_imp_less_exp:
   368   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   369   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   370     power_le_imp_le_exp)
   371 
   372 lemma power_strict_mono [rule_format]:
   373   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   374   by (induct n)
   375    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   376 
   377 text{*Lemma for @{text power_strict_decreasing}*}
   378 lemma power_Suc_less:
   379   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   380   by (induct n)
   381     (auto simp add: mult_strict_left_mono)
   382 
   383 lemma power_strict_decreasing [rule_format]:
   384   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   385 proof (induct N)
   386   case 0 then show ?case by simp
   387 next
   388   case (Suc N) then show ?case 
   389   apply (auto simp add: power_Suc_less less_Suc_eq)
   390   apply (subgoal_tac "a * a^N < 1 * a^n")
   391   apply simp
   392   apply (rule mult_strict_mono) apply auto
   393   done
   394 qed
   395 
   396 text{*Proof resembles that of @{text power_strict_decreasing}*}
   397 lemma power_decreasing [rule_format]:
   398   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   399 proof (induct N)
   400   case 0 then show ?case by simp
   401 next
   402   case (Suc N) then show ?case 
   403   apply (auto simp add: le_Suc_eq)
   404   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   405   apply (rule mult_mono) apply auto
   406   done
   407 qed
   408 
   409 lemma power_Suc_less_one:
   410   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   411   using power_strict_decreasing [of 0 "Suc n" a] by simp
   412 
   413 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   414 lemma power_increasing [rule_format]:
   415   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   416 proof (induct N)
   417   case 0 then show ?case by simp
   418 next
   419   case (Suc N) then show ?case 
   420   apply (auto simp add: le_Suc_eq)
   421   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   422   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   423   done
   424 qed
   425 
   426 text{*Lemma for @{text power_strict_increasing}*}
   427 lemma power_less_power_Suc:
   428   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   429   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   430 
   431 lemma power_strict_increasing [rule_format]:
   432   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   433 proof (induct N)
   434   case 0 then show ?case by simp
   435 next
   436   case (Suc N) then show ?case 
   437   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   438   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   439   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   440   done
   441 qed
   442 
   443 lemma power_increasing_iff [simp]:
   444   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   445   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   446 
   447 lemma power_strict_increasing_iff [simp]:
   448   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   449 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   450 
   451 lemma power_le_imp_le_base:
   452   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   453     and ynonneg: "0 \<le> b"
   454   shows "a \<le> b"
   455 proof (rule ccontr)
   456   assume "~ a \<le> b"
   457   then have "b < a" by (simp only: linorder_not_le)
   458   then have "b ^ Suc n < a ^ Suc n"
   459     by (simp only: assms power_strict_mono)
   460   from le and this show False
   461     by (simp add: linorder_not_less [symmetric])
   462 qed
   463 
   464 lemma power_less_imp_less_base:
   465   assumes less: "a ^ n < b ^ n"
   466   assumes nonneg: "0 \<le> b"
   467   shows "a < b"
   468 proof (rule contrapos_pp [OF less])
   469   assume "~ a < b"
   470   hence "b \<le> a" by (simp only: linorder_not_less)
   471   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   472   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   473 qed
   474 
   475 lemma power_inject_base:
   476   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   477 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   478 
   479 lemma power_eq_imp_eq_base:
   480   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   481   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   482 
   483 lemma power2_le_imp_le:
   484   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   485   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   486 
   487 lemma power2_less_imp_less:
   488   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   489   by (rule power_less_imp_less_base)
   490 
   491 lemma power2_eq_imp_eq:
   492   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   493   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   494 
   495 end
   496 
   497 context linordered_ring_strict
   498 begin
   499 
   500 lemma sum_squares_eq_zero_iff:
   501   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   502   by (simp add: add_nonneg_eq_0_iff)
   503 
   504 lemma sum_squares_le_zero_iff:
   505   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   506   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   507 
   508 lemma sum_squares_gt_zero_iff:
   509   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   510   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   511 
   512 end
   513 
   514 context linordered_idom
   515 begin
   516 
   517 lemma power_abs:
   518   "abs (a ^ n) = abs a ^ n"
   519   by (induct n) (auto simp add: abs_mult)
   520 
   521 lemma abs_power_minus [simp]:
   522   "abs ((-a) ^ n) = abs (a ^ n)"
   523   by (simp add: power_abs)
   524 
   525 lemma zero_less_power_abs_iff [simp]:
   526   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   527 proof (induct n)
   528   case 0 show ?case by simp
   529 next
   530   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   531 qed
   532 
   533 lemma zero_le_power_abs [simp]:
   534   "0 \<le> abs a ^ n"
   535   by (rule zero_le_power [OF abs_ge_zero])
   536 
   537 lemma zero_le_power2 [simp]:
   538   "0 \<le> a\<^sup>2"
   539   by (simp add: power2_eq_square)
   540 
   541 lemma zero_less_power2 [simp]:
   542   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   543   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   544 
   545 lemma power2_less_0 [simp]:
   546   "\<not> a\<^sup>2 < 0"
   547   by (force simp add: power2_eq_square mult_less_0_iff)
   548 
   549 lemma abs_power2 [simp]:
   550   "abs (a\<^sup>2) = a\<^sup>2"
   551   by (simp add: power2_eq_square abs_mult abs_mult_self)
   552 
   553 lemma power2_abs [simp]:
   554   "(abs a)\<^sup>2 = a\<^sup>2"
   555   by (simp add: power2_eq_square abs_mult_self)
   556 
   557 lemma odd_power_less_zero:
   558   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   559 proof (induct n)
   560   case 0
   561   then show ?case by simp
   562 next
   563   case (Suc n)
   564   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   565     by (simp add: mult_ac power_add power2_eq_square)
   566   thus ?case
   567     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   568 qed
   569 
   570 lemma odd_0_le_power_imp_0_le:
   571   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   572   using odd_power_less_zero [of a n]
   573     by (force simp add: linorder_not_less [symmetric]) 
   574 
   575 lemma zero_le_even_power'[simp]:
   576   "0 \<le> a ^ (2*n)"
   577 proof (induct n)
   578   case 0
   579     show ?case by simp
   580 next
   581   case (Suc n)
   582     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)" 
   583       by (simp add: mult_ac power_add power2_eq_square)
   584     thus ?case
   585       by (simp add: Suc zero_le_mult_iff)
   586 qed
   587 
   588 lemma sum_power2_ge_zero:
   589   "0 \<le> x\<^sup>2 + y\<^sup>2"
   590   by (intro add_nonneg_nonneg zero_le_power2)
   591 
   592 lemma not_sum_power2_lt_zero:
   593   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   594   unfolding not_less by (rule sum_power2_ge_zero)
   595 
   596 lemma sum_power2_eq_zero_iff:
   597   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   598   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   599 
   600 lemma sum_power2_le_zero_iff:
   601   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   602   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   603 
   604 lemma sum_power2_gt_zero_iff:
   605   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   606   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   607 
   608 end
   609 
   610 
   611 subsection {* Miscellaneous rules *}
   612 
   613 lemma self_le_power:
   614   fixes x::"'a::linordered_semidom" 
   615   shows "1 \<le> x \<Longrightarrow> 0 < n \<Longrightarrow> x \<le> x ^ n"
   616   using power_increasing[of 1 n x] power_one_right[of x] by auto
   617 
   618 lemma power_eq_if: "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   619   unfolding One_nat_def by (cases m) simp_all
   620 
   621 lemma power2_sum:
   622   fixes x y :: "'a::comm_semiring_1"
   623   shows "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   624   by (simp add: algebra_simps power2_eq_square mult_2_right)
   625 
   626 lemma power2_diff:
   627   fixes x y :: "'a::comm_ring_1"
   628   shows "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   629   by (simp add: ring_distribs power2_eq_square mult_2) (rule mult_commute)
   630 
   631 lemma power_0_Suc [simp]:
   632   "(0::'a::{power, semiring_0}) ^ Suc n = 0"
   633   by simp
   634 
   635 text{*It looks plausible as a simprule, but its effect can be strange.*}
   636 lemma power_0_left:
   637   "0 ^ n = (if n = 0 then 1 else (0::'a::{power, semiring_0}))"
   638   by (induct n) simp_all
   639 
   640 lemma power_eq_0_iff [simp]:
   641   "a ^ n = 0 \<longleftrightarrow>
   642      a = (0::'a::{mult_zero,zero_neq_one,no_zero_divisors,power}) \<and> n \<noteq> 0"
   643   by (induct n)
   644     (auto simp add: no_zero_divisors elim: contrapos_pp)
   645 
   646 lemma (in field) power_diff:
   647   assumes nz: "a \<noteq> 0"
   648   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   649   by (induct m n rule: diff_induct) (simp_all add: nz field_power_not_zero)
   650 
   651 text{*Perhaps these should be simprules.*}
   652 lemma power_inverse:
   653   fixes a :: "'a::division_ring_inverse_zero"
   654   shows "inverse (a ^ n) = inverse a ^ n"
   655 apply (cases "a = 0")
   656 apply (simp add: power_0_left)
   657 apply (simp add: nonzero_power_inverse)
   658 done (* TODO: reorient or rename to inverse_power *)
   659 
   660 lemma power_one_over:
   661   "1 / (a::'a::{field_inverse_zero, power}) ^ n =  (1 / a) ^ n"
   662   by (simp add: divide_inverse) (rule power_inverse)
   663 
   664 lemma power_divide [field_simps, divide_simps]:
   665   "(a / b) ^ n = (a::'a::field_inverse_zero) ^ n / b ^ n"
   666 apply (cases "b = 0")
   667 apply (simp add: power_0_left)
   668 apply (rule nonzero_power_divide)
   669 apply assumption
   670 done
   671 
   672 text {* Simprules for comparisons where common factors can be cancelled. *}
   673 
   674 lemmas zero_compare_simps =
   675     add_strict_increasing add_strict_increasing2 add_increasing
   676     zero_le_mult_iff zero_le_divide_iff 
   677     zero_less_mult_iff zero_less_divide_iff 
   678     mult_le_0_iff divide_le_0_iff 
   679     mult_less_0_iff divide_less_0_iff 
   680     zero_le_power2 power2_less_0
   681 
   682 
   683 subsection {* Exponentiation for the Natural Numbers *}
   684 
   685 lemma nat_one_le_power [simp]:
   686   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   687   by (rule one_le_power [of i n, unfolded One_nat_def])
   688 
   689 lemma nat_zero_less_power_iff [simp]:
   690   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   691   by (induct n) auto
   692 
   693 lemma nat_power_eq_Suc_0_iff [simp]: 
   694   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   695   by (induct m) auto
   696 
   697 lemma power_Suc_0 [simp]:
   698   "Suc 0 ^ n = Suc 0"
   699   by simp
   700 
   701 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   702 Premises cannot be weakened: consider the case where @{term "i=0"},
   703 @{term "m=1"} and @{term "n=0"}.*}
   704 lemma nat_power_less_imp_less:
   705   assumes nonneg: "0 < (i\<Colon>nat)"
   706   assumes less: "i ^ m < i ^ n"
   707   shows "m < n"
   708 proof (cases "i = 1")
   709   case True with less power_one [where 'a = nat] show ?thesis by simp
   710 next
   711   case False with nonneg have "1 < i" by auto
   712   from power_strict_increasing_iff [OF this] less show ?thesis ..
   713 qed
   714 
   715 lemma power_dvd_imp_le:
   716   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   717   apply (rule power_le_imp_le_exp, assumption)
   718   apply (erule dvd_imp_le, simp)
   719   done
   720 
   721 lemma power2_nat_le_eq_le:
   722   fixes m n :: nat
   723   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   724   by (auto intro: power2_le_imp_le power_mono)
   725 
   726 lemma power2_nat_le_imp_le:
   727   fixes m n :: nat
   728   assumes "m\<^sup>2 \<le> n"
   729   shows "m \<le> n"
   730 proof (cases m)
   731   case 0 then show ?thesis by simp
   732 next
   733   case (Suc k)
   734   show ?thesis
   735   proof (rule ccontr)
   736     assume "\<not> m \<le> n"
   737     then have "n < m" by simp
   738     with assms Suc show False
   739       by (auto simp add: algebra_simps) (simp add: power2_eq_square)
   740   qed
   741 qed
   742 
   743 subsubsection {* Cardinality of the Powerset *}
   744 
   745 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   746   unfolding UNIV_bool by simp
   747 
   748 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   749 proof (induct rule: finite_induct)
   750   case empty 
   751     show ?case by auto
   752 next
   753   case (insert x A)
   754   then have "inj_on (insert x) (Pow A)" 
   755     unfolding inj_on_def by (blast elim!: equalityE)
   756   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A" 
   757     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   758   then show ?case using insert
   759     apply (simp add: Pow_insert)
   760     apply (subst card_Un_disjoint, auto)
   761     done
   762 qed
   763 
   764 
   765 subsubsection {* Generalized sum over a set *}
   766 
   767 lemma setsum_zero_power [simp]:
   768   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   769   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   770 apply (cases "finite A")
   771   by (induction A rule: finite_induct) auto
   772 
   773 lemma setsum_zero_power' [simp]:
   774   fixes c :: "nat \<Rightarrow> 'a::field"
   775   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   776   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   777   by auto
   778 
   779 
   780 subsubsection {* Generalized product over a set *}
   781 
   782 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   783 apply (erule finite_induct)
   784 apply auto
   785 done
   786 
   787 lemma setprod_power_distrib:
   788   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   789   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   790 proof (cases "finite A") 
   791   case True then show ?thesis 
   792     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   793 next
   794   case False then show ?thesis 
   795     by simp
   796 qed
   797 
   798 lemma setprod_gen_delta:
   799   assumes fS: "finite S"
   800   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   801 proof-
   802   let ?f = "(\<lambda>k. if k=a then b k else c)"
   803   {assume a: "a \<notin> S"
   804     hence "\<forall> k\<in> S. ?f k = c" by simp
   805     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   806   moreover 
   807   {assume a: "a \<in> S"
   808     let ?A = "S - {a}"
   809     let ?B = "{a}"
   810     have eq: "S = ?A \<union> ?B" using a by blast 
   811     have dj: "?A \<inter> ?B = {}" by simp
   812     from fS have fAB: "finite ?A" "finite ?B" by auto  
   813     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   814       apply (rule setprod.cong) by auto
   815     have cA: "card ?A = card S - 1" using fS a by auto
   816     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   817     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   818       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   819       by simp
   820     then have ?thesis using a cA
   821       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   822   ultimately show ?thesis by blast
   823 qed
   824 
   825 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   826   by auto
   827 
   828 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   829   by auto
   830 
   831 subsection {* Code generator tweak *}
   832 
   833 lemma power_power_power [code]:
   834   "power = power.power (1::'a::{power}) (op *)"
   835   unfolding power_def power.power_def ..
   836 
   837 declare power.power.simps [code]
   838 
   839 code_identifier
   840   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   841 
   842 end
   843