src/Pure/sign.ML
author wenzelm
Thu Mar 19 13:28:55 2009 +0100 (2009-03-19)
changeset 30585 6b2ba4666336
parent 30522 e26b80647189
child 31946 99ac0321cd47
permissions -rw-r--r--
use Name.of_binding for basic logical entities without name space (fixes, case names etc.);
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: NameSpace.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val naming_of: theory -> NameSpace.naming
    16   val full_name: theory -> binding -> string
    17   val full_name_path: theory -> string -> binding -> string
    18   val full_bname: theory -> bstring -> string
    19   val full_bname_path: theory -> string -> bstring -> string
    20   val syn_of: theory -> Syntax.syntax
    21   val tsig_of: theory -> Type.tsig
    22   val classes_of: theory -> Sorts.algebra
    23   val all_classes: theory -> class list
    24   val super_classes: theory -> class -> class list
    25   val minimize_sort: theory -> sort -> sort
    26   val complete_sort: theory -> sort -> sort
    27   val defaultS: theory -> sort
    28   val subsort: theory -> sort * sort -> bool
    29   val of_sort: theory -> typ * sort -> bool
    30   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    31   val is_logtype: theory -> string -> bool
    32   val typ_instance: theory -> typ * typ -> bool
    33   val typ_equiv: theory -> typ * typ -> bool
    34   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    35   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    36   val consts_of: theory -> Consts.T
    37   val the_const_constraint: theory -> string -> typ
    38   val const_type: theory -> string -> typ option
    39   val the_const_type: theory -> string -> typ
    40   val declared_tyname: theory -> string -> bool
    41   val declared_const: theory -> string -> bool
    42   val const_monomorphic: theory -> string -> bool
    43   val const_syntax_name: theory -> string -> string
    44   val const_typargs: theory -> string * typ -> typ list
    45   val const_instance: theory -> string * typ list -> typ
    46   val mk_const: theory -> string * typ list -> term
    47   val class_space: theory -> NameSpace.T
    48   val type_space: theory -> NameSpace.T
    49   val const_space: theory -> NameSpace.T
    50   val intern_class: theory -> xstring -> string
    51   val extern_class: theory -> string -> xstring
    52   val intern_type: theory -> xstring -> string
    53   val extern_type: theory -> string -> xstring
    54   val intern_const: theory -> xstring -> string
    55   val extern_const: theory -> string -> xstring
    56   val intern_sort: theory -> sort -> sort
    57   val extern_sort: theory -> sort -> sort
    58   val intern_typ: theory -> typ -> typ
    59   val extern_typ: theory -> typ -> typ
    60   val intern_term: theory -> term -> term
    61   val extern_term: (string -> xstring) -> theory -> term -> term
    62   val intern_tycons: theory -> typ -> typ
    63   val arity_number: theory -> string -> int
    64   val arity_sorts: theory -> string -> sort -> sort list
    65   val certify_class: theory -> class -> class
    66   val certify_sort: theory -> sort -> sort
    67   val certify_typ: theory -> typ -> typ
    68   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    69   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    70   val certify_term: theory -> term -> term * typ * int
    71   val certify_prop: theory -> term -> term * typ * int
    72   val cert_term: theory -> term -> term
    73   val cert_prop: theory -> term -> term
    74   val no_frees: Pretty.pp -> term -> term
    75   val no_vars: Pretty.pp -> term -> term
    76   val cert_def: Proof.context -> term -> (string * typ) * term
    77   val read_class: theory -> xstring -> class
    78   val read_arity: theory -> xstring * string list * string -> arity
    79   val cert_arity: theory -> arity -> arity
    80   val add_defsort: string -> theory -> theory
    81   val add_defsort_i: sort -> theory -> theory
    82   val add_types: (binding * int * mixfix) list -> theory -> theory
    83   val add_nonterminals: binding list -> theory -> theory
    84   val add_tyabbrs: (binding * string list * string * mixfix) list -> theory -> theory
    85   val add_tyabbrs_i: (binding * string list * typ * mixfix) list -> theory -> theory
    86   val add_syntax: (string * string * mixfix) list -> theory -> theory
    87   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    88   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    89   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    90   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    91   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    92   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    93   val declare_const: Properties.T -> (binding * typ) * mixfix -> theory -> term * theory
    94   val add_consts: (binding * string * mixfix) list -> theory -> theory
    95   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    96   val add_abbrev: string -> Properties.T -> binding * term -> theory -> (term * term) * theory
    97   val revert_abbrev: string -> string -> theory -> theory
    98   val add_const_constraint: string * typ option -> theory -> theory
    99   val primitive_class: binding * class list -> theory -> theory
   100   val primitive_classrel: class * class -> theory -> theory
   101   val primitive_arity: arity -> theory -> theory
   102   val add_trfuns:
   103     (string * (ast list -> ast)) list *
   104     (string * (term list -> term)) list *
   105     (string * (term list -> term)) list *
   106     (string * (ast list -> ast)) list -> theory -> theory
   107   val add_trfunsT:
   108     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   109   val add_advanced_trfuns:
   110     (string * (Proof.context -> ast list -> ast)) list *
   111     (string * (Proof.context -> term list -> term)) list *
   112     (string * (Proof.context -> term list -> term)) list *
   113     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   114   val add_advanced_trfunsT:
   115     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   116   val add_tokentrfuns:
   117     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   118   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   119     -> theory -> theory
   120   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   121   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   122   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   123   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   124   val add_path: string -> theory -> theory
   125   val root_path: theory -> theory
   126   val parent_path: theory -> theory
   127   val mandatory_path: string -> theory -> theory
   128   val local_path: theory -> theory
   129   val restore_naming: theory -> theory -> theory
   130   val hide_class: bool -> string -> theory -> theory
   131   val hide_type: bool -> string -> theory -> theory
   132   val hide_const: bool -> string -> theory -> theory
   133 end
   134 
   135 structure Sign: SIGN =
   136 struct
   137 
   138 (** datatype sign **)
   139 
   140 datatype sign = Sign of
   141  {naming: NameSpace.naming,     (*common naming conventions*)
   142   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   143   tsig: Type.tsig,              (*order-sorted signature of types*)
   144   consts: Consts.T};            (*polymorphic constants*)
   145 
   146 fun make_sign (naming, syn, tsig, consts) =
   147   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   148 
   149 structure SignData = TheoryDataFun
   150 (
   151   type T = sign;
   152   val copy = I;
   153   fun extend (Sign {syn, tsig, consts, ...}) =
   154     make_sign (NameSpace.default_naming, syn, tsig, consts);
   155 
   156   val empty =
   157     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   158 
   159   fun merge pp (sign1, sign2) =
   160     let
   161       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   162       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   163 
   164       val naming = NameSpace.default_naming;
   165       val syn = Syntax.merge_syntaxes syn1 syn2;
   166       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   167       val consts = Consts.merge (consts1, consts2);
   168     in make_sign (naming, syn, tsig, consts) end;
   169 );
   170 
   171 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   172 
   173 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   174   make_sign (f (naming, syn, tsig, consts)));
   175 
   176 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   177 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   178 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   179 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   180 
   181 
   182 (* naming *)
   183 
   184 val naming_of = #naming o rep_sg;
   185 
   186 val full_name = NameSpace.full_name o naming_of;
   187 fun full_name_path thy path = NameSpace.full_name (NameSpace.add_path path (naming_of thy));
   188 
   189 fun full_bname thy = NameSpace.full_name (naming_of thy) o Binding.name;
   190 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   191 
   192 
   193 (* syntax *)
   194 
   195 val syn_of = #syn o rep_sg;
   196 
   197 
   198 (* type signature *)
   199 
   200 val tsig_of = #tsig o rep_sg;
   201 
   202 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   203 val all_classes = Sorts.all_classes o classes_of;
   204 val super_classes = Sorts.super_classes o classes_of;
   205 val minimize_sort = Sorts.minimize_sort o classes_of;
   206 val complete_sort = Sorts.complete_sort o classes_of;
   207 
   208 val defaultS = Type.defaultS o tsig_of;
   209 val subsort = Type.subsort o tsig_of;
   210 val of_sort = Type.of_sort o tsig_of;
   211 val witness_sorts = Type.witness_sorts o tsig_of;
   212 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   213 
   214 val typ_instance = Type.typ_instance o tsig_of;
   215 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   216 val typ_match = Type.typ_match o tsig_of;
   217 val typ_unify = Type.unify o tsig_of;
   218 
   219 
   220 (* polymorphic constants *)
   221 
   222 val consts_of = #consts o rep_sg;
   223 val the_const_constraint = Consts.the_constraint o consts_of;
   224 val the_const_type = Consts.the_type o consts_of;
   225 val const_type = try o the_const_type;
   226 val const_monomorphic = Consts.is_monomorphic o consts_of;
   227 val const_syntax_name = Consts.syntax_name o consts_of;
   228 val const_typargs = Consts.typargs o consts_of;
   229 val const_instance = Consts.instance o consts_of;
   230 
   231 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   232 
   233 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   234 val declared_const = can o the_const_constraint;
   235 
   236 
   237 
   238 (** intern / extern names **)
   239 
   240 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   241 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   242 val const_space = Consts.space_of o consts_of;
   243 
   244 val intern_class = NameSpace.intern o class_space;
   245 val extern_class = NameSpace.extern o class_space;
   246 val intern_type = NameSpace.intern o type_space;
   247 val extern_type = NameSpace.extern o type_space;
   248 val intern_const = NameSpace.intern o const_space;
   249 val extern_const = NameSpace.extern o const_space;
   250 
   251 val intern_sort = map o intern_class;
   252 val extern_sort = map o extern_class;
   253 
   254 local
   255 
   256 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   257   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   258   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   259 
   260 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   261   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   262   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   263   | map_term _ _ _ (t as Bound _) = t
   264   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   265   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   266 
   267 val add_classesT = Term.fold_atyps
   268   (fn TFree (_, S) => fold (insert (op =)) S
   269     | TVar (_, S) => fold (insert (op =)) S
   270     | _ => I);
   271 
   272 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   273   | add_tyconsT _ = I;
   274 
   275 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   276 
   277 fun mapping add_names f t =
   278   let
   279     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   280     val tab = map_filter f' (add_names t []);
   281     fun get x = the_default x (AList.lookup (op =) tab x);
   282   in get end;
   283 
   284 fun typ_mapping f g thy T =
   285   T |> map_typ
   286     (mapping add_classesT (f thy) T)
   287     (mapping add_tyconsT (g thy) T);
   288 
   289 fun term_mapping f g h thy t =
   290   t |> map_term
   291     (mapping (Term.fold_types add_classesT) (f thy) t)
   292     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   293     (mapping add_consts (h thy) t);
   294 
   295 in
   296 
   297 val intern_typ = typ_mapping intern_class intern_type;
   298 val extern_typ = typ_mapping extern_class extern_type;
   299 val intern_term = term_mapping intern_class intern_type intern_const;
   300 fun extern_term h = term_mapping extern_class extern_type (K h);
   301 val intern_tycons = typ_mapping (K I) intern_type;
   302 
   303 end;
   304 
   305 
   306 
   307 (** certify entities **)    (*exception TYPE*)
   308 
   309 (* certify wrt. type signature *)
   310 
   311 val arity_number = Type.arity_number o tsig_of;
   312 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   313 
   314 val certify_class         = Type.cert_class o tsig_of;
   315 val certify_sort          = Type.cert_sort o tsig_of;
   316 val certify_typ           = Type.cert_typ o tsig_of;
   317 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   318 
   319 
   320 (* certify term/prop *)
   321 
   322 local
   323 
   324 fun type_check pp tm =
   325   let
   326     fun err_appl why bs t T u U =
   327       let
   328         val xs = map Free bs;           (*we do not rename here*)
   329         val t' = subst_bounds (xs, t);
   330         val u' = subst_bounds (xs, u);
   331         val msg = cat_lines
   332           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   333       in raise TYPE (msg, [T, U], [t', u']) end;
   334 
   335     fun typ_of (_, Const (_, T)) = T
   336       | typ_of (_, Free  (_, T)) = T
   337       | typ_of (_, Var (_, T)) = T
   338       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   339           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   340       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   341       | typ_of (bs, t $ u) =
   342           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   343             (case T of
   344               Type ("fun", [T1, T2]) =>
   345                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   346             | _ => err_appl "Operator not of function type" bs t T u U)
   347           end;
   348   in typ_of ([], tm) end;
   349 
   350 fun err msg = raise TYPE (msg, [], []);
   351 
   352 fun check_vars (t $ u) = (check_vars t; check_vars u)
   353   | check_vars (Abs (_, _, t)) = check_vars t
   354   | check_vars (Free (x, _)) =
   355       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   356   | check_vars (Var (xi as (_, i), _)) =
   357       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   358   | check_vars _ = ();
   359 
   360 in
   361 
   362 fun certify' prop pp do_expand consts thy tm =
   363   let
   364     val _ = check_vars tm;
   365     val tm' = Term.map_types (certify_typ thy) tm;
   366     val T = type_check pp tm';
   367     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   368     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   369   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   370 
   371 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   372 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   373 
   374 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   375 val cert_term = #1 oo certify_term;
   376 val cert_prop = #1 oo certify_prop;
   377 
   378 end;
   379 
   380 
   381 (* specifications *)
   382 
   383 fun no_variables kind add addT mk mkT pp tm =
   384   (case (add tm [], addT tm []) of
   385     ([], []) => tm
   386   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   387       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   388        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   389 
   390 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   391 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   392 
   393 fun cert_def ctxt tm =
   394   let val ((lhs, rhs), _) = tm
   395     |> no_vars (Syntax.pp ctxt)
   396     |> Logic.strip_imp_concl
   397     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   398   in (Term.dest_Const (Term.head_of lhs), rhs) end
   399   handle TERM (msg, _) => error msg;
   400 
   401 
   402 
   403 (** read and certify entities **)    (*exception ERROR*)
   404 
   405 (* classes *)
   406 
   407 fun read_class thy c = certify_class thy (intern_class thy c)
   408   handle TYPE (msg, _, _) => error msg;
   409 
   410 
   411 (* type arities *)
   412 
   413 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   414   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   415   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   416 
   417 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   418 val cert_arity = prep_arity (K I) certify_sort;
   419 
   420 
   421 
   422 (** signature extension functions **)  (*exception ERROR/TYPE*)
   423 
   424 (* add default sort *)
   425 
   426 fun gen_add_defsort prep_sort s thy =
   427   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   428 
   429 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   430 val add_defsort_i = gen_add_defsort certify_sort;
   431 
   432 
   433 (* add type constructors *)
   434 
   435 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   436   let
   437     val syn' = Syntax.update_type_gram (map (fn (a, n, mx) => (Name.of_binding a, n, mx)) types) syn;
   438     val decls = map (fn (a, n, mx) => (Binding.map_name (Syntax.type_name mx) a, n)) types;
   439     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   440     val tsig' = fold (Type.add_type naming tags) decls tsig;
   441   in (naming, syn', tsig', consts) end);
   442 
   443 
   444 (* add nonterminals *)
   445 
   446 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   447   let
   448     val syn' = Syntax.update_consts (map Name.of_binding ns) syn;
   449     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   450   in (naming, syn', tsig', consts) end);
   451 
   452 
   453 (* add type abbreviations *)
   454 
   455 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   456   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   457     let
   458       val ctxt = ProofContext.init thy;
   459       val syn' = Syntax.update_type_gram [(Name.of_binding a, length vs, mx)] syn;
   460       val b = Binding.map_name (Syntax.type_name mx) a;
   461       val abbr = (b, vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   462         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote (Binding.str_of b));
   463       val tsig' = Type.add_abbrev naming [] abbr tsig;
   464     in (naming, syn', tsig', consts) end);
   465 
   466 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   467 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   468 
   469 
   470 (* modify syntax *)
   471 
   472 fun gen_syntax change_gram parse_typ mode args thy =
   473   let
   474     val ctxt = ProofContext.init thy;
   475     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   476       handle ERROR msg =>
   477         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name mx c));
   478   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   479 
   480 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   481 
   482 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   483 val add_modesyntax_i = gen_add_syntax (K I);
   484 val add_syntax = add_modesyntax Syntax.mode_default;
   485 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   486 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   487 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   488 
   489 fun notation add mode args thy =
   490   let
   491     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   492     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   493       | const_syntax _ = NONE;
   494   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   495 
   496 
   497 (* add constants *)
   498 
   499 local
   500 
   501 fun gen_add_consts parse_typ authentic tags raw_args thy =
   502   let
   503     val ctxt = ProofContext.init thy;
   504     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   505     fun prep (raw_b, raw_T, raw_mx) =
   506       let
   507         val (mx_name, mx) = Syntax.const_mixfix (Name.of_binding raw_b) raw_mx;
   508         val b = Binding.map_name (K mx_name) raw_b;
   509         val c = full_name thy b;
   510         val c_syn = if authentic then Syntax.constN ^ c else Name.of_binding b;
   511         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   512           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   513         val T' = Logic.varifyT T;
   514       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   515     val args = map prep raw_args;
   516     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   517   in
   518     thy
   519     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   520     |> add_syntax_i (map #2 args)
   521     |> pair (map #3 args)
   522   end;
   523 
   524 in
   525 
   526 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false [] args;
   527 fun add_consts_i args = snd o gen_add_consts (K I) false [] args;
   528 
   529 fun declare_const tags ((b, T), mx) thy =
   530   let
   531     val pos = Binding.pos_of b;
   532     val tags' = Position.default_properties pos tags;
   533     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true tags' [(b, T, mx)] thy;
   534     val _ = Position.report (Markup.const_decl c) pos;
   535   in (const, thy') end;
   536 
   537 end;
   538 
   539 
   540 (* abbreviations *)
   541 
   542 fun add_abbrev mode tags (b, raw_t) thy =
   543   let
   544     val pp = Syntax.pp_global thy;
   545     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   546     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   547       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   548     val (res, consts') = consts_of thy
   549       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (b, t);
   550   in (res, thy |> map_consts (K consts')) end;
   551 
   552 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   553 
   554 
   555 (* add constraints *)
   556 
   557 fun add_const_constraint (c, opt_T) thy =
   558   let
   559     fun prepT raw_T =
   560       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   561       in cert_term thy (Const (c, T)); T end
   562       handle TYPE (msg, _, _) => error msg;
   563   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   564 
   565 
   566 (* primitive classes and arities *)
   567 
   568 fun primitive_class (bclass, classes) thy =
   569   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   570     let
   571       val syn' = Syntax.update_consts [Name.of_binding bclass] syn;
   572       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   573     in (naming, syn', tsig', consts) end)
   574   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   575 
   576 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   577 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   578 
   579 
   580 (* add translation functions *)
   581 
   582 local
   583 
   584 fun mk trs = map Syntax.mk_trfun trs;
   585 
   586 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   587   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   588 
   589 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   590 
   591 in
   592 
   593 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   594 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   595 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   596 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   597 
   598 end;
   599 
   600 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   601 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   602 
   603 
   604 (* translation rules *)
   605 
   606 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   607   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   608   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   609 
   610 val add_trrules = gen_trrules Syntax.update_trrules;
   611 val del_trrules = gen_trrules Syntax.remove_trrules;
   612 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   613 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   614 
   615 
   616 (* naming *)
   617 
   618 val add_path = map_naming o NameSpace.add_path;
   619 val root_path = map_naming NameSpace.root_path;
   620 val parent_path = map_naming NameSpace.parent_path;
   621 val mandatory_path = map_naming o NameSpace.mandatory_path;
   622 
   623 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   624 
   625 val restore_naming = map_naming o K o naming_of;
   626 
   627 
   628 (* hide names *)
   629 
   630 val hide_class = map_tsig oo Type.hide_class;
   631 val hide_type = map_tsig oo Type.hide_type;
   632 val hide_const = map_consts oo Consts.hide;
   633 
   634 end;