src/HOL/Library/Cardinality.thy
author nipkow
Thu Jun 07 19:36:12 2018 +0200 (16 months ago)
changeset 68406 6beb45f6cf67
parent 68028 1f9f973eed2a
child 69593 3dda49e08b9d
permissions -rw-r--r--
utilize 'flip'
     1 (*  Title:      HOL/Library/Cardinality.thy
     2     Author:     Brian Huffman, Andreas Lochbihler
     3 *)
     4 
     5 section \<open>Cardinality of types\<close>
     6 
     7 theory Cardinality
     8 imports Phantom_Type
     9 begin
    10 
    11 subsection \<open>Preliminary lemmas\<close>
    12 (* These should be moved elsewhere *)
    13 
    14 lemma (in type_definition) univ:
    15   "UNIV = Abs ` A"
    16 proof
    17   show "Abs ` A \<subseteq> UNIV" by (rule subset_UNIV)
    18   show "UNIV \<subseteq> Abs ` A"
    19   proof
    20     fix x :: 'b
    21     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
    22     moreover have "Rep x \<in> A" by (rule Rep)
    23     ultimately show "x \<in> Abs ` A" by (rule image_eqI)
    24   qed
    25 qed
    26 
    27 lemma (in type_definition) card: "card (UNIV :: 'b set) = card A"
    28   by (simp add: univ card_image inj_on_def Abs_inject)
    29 
    30 
    31 subsection \<open>Cardinalities of types\<close>
    32 
    33 syntax "_type_card" :: "type => nat" ("(1CARD/(1'(_')))")
    34 
    35 translations "CARD('t)" => "CONST card (CONST UNIV :: 't set)"
    36 
    37 print_translation \<open>
    38   let
    39     fun card_univ_tr' ctxt [Const (@{const_syntax UNIV}, Type (_, [T]))] =
    40       Syntax.const @{syntax_const "_type_card"} $ Syntax_Phases.term_of_typ ctxt T
    41   in [(@{const_syntax card}, card_univ_tr')] end
    42 \<close>
    43 
    44 lemma card_prod [simp]: "CARD('a \<times> 'b) = CARD('a) * CARD('b)"
    45   unfolding UNIV_Times_UNIV [symmetric] by (simp only: card_cartesian_product)
    46 
    47 lemma card_UNIV_sum: "CARD('a + 'b) = (if CARD('a) \<noteq> 0 \<and> CARD('b) \<noteq> 0 then CARD('a) + CARD('b) else 0)"
    48 unfolding UNIV_Plus_UNIV[symmetric]
    49 by(auto simp add: card_eq_0_iff card_Plus simp del: UNIV_Plus_UNIV)
    50 
    51 lemma card_sum [simp]: "CARD('a + 'b) = CARD('a::finite) + CARD('b::finite)"
    52 by(simp add: card_UNIV_sum)
    53 
    54 lemma card_UNIV_option: "CARD('a option) = (if CARD('a) = 0 then 0 else CARD('a) + 1)"
    55 proof -
    56   have "(None :: 'a option) \<notin> range Some" by clarsimp
    57   thus ?thesis
    58     by (simp add: UNIV_option_conv card_eq_0_iff finite_range_Some card_image)
    59 qed
    60 
    61 lemma card_option [simp]: "CARD('a option) = Suc CARD('a::finite)"
    62 by(simp add: card_UNIV_option)
    63 
    64 lemma card_UNIV_set: "CARD('a set) = (if CARD('a) = 0 then 0 else 2 ^ CARD('a))"
    65 by(simp add: card_eq_0_iff card_Pow flip: Pow_UNIV)
    66 
    67 lemma card_set [simp]: "CARD('a set) = 2 ^ CARD('a::finite)"
    68 by(simp add: card_UNIV_set)
    69 
    70 lemma card_nat [simp]: "CARD(nat) = 0"
    71   by (simp add: card_eq_0_iff)
    72 
    73 lemma card_fun: "CARD('a \<Rightarrow> 'b) = (if CARD('a) \<noteq> 0 \<and> CARD('b) \<noteq> 0 \<or> CARD('b) = 1 then CARD('b) ^ CARD('a) else 0)"
    74 proof -
    75   {  assume "0 < CARD('a)" and "0 < CARD('b)"
    76     hence fina: "finite (UNIV :: 'a set)" and finb: "finite (UNIV :: 'b set)"
    77       by(simp_all only: card_ge_0_finite)
    78     from finite_distinct_list[OF finb] obtain bs 
    79       where bs: "set bs = (UNIV :: 'b set)" and distb: "distinct bs" by blast
    80     from finite_distinct_list[OF fina] obtain as
    81       where as: "set as = (UNIV :: 'a set)" and dista: "distinct as" by blast
    82     have cb: "CARD('b) = length bs"
    83       unfolding bs[symmetric] distinct_card[OF distb] ..
    84     have ca: "CARD('a) = length as"
    85       unfolding as[symmetric] distinct_card[OF dista] ..
    86     let ?xs = "map (\<lambda>ys. the \<circ> map_of (zip as ys)) (List.n_lists (length as) bs)"
    87     have "UNIV = set ?xs"
    88     proof(rule UNIV_eq_I)
    89       fix f :: "'a \<Rightarrow> 'b"
    90       from as have "f = the \<circ> map_of (zip as (map f as))"
    91         by(auto simp add: map_of_zip_map)
    92       thus "f \<in> set ?xs" using bs by(auto simp add: set_n_lists)
    93     qed
    94     moreover have "distinct ?xs" unfolding distinct_map
    95     proof(intro conjI distinct_n_lists distb inj_onI)
    96       fix xs ys :: "'b list"
    97       assume xs: "xs \<in> set (List.n_lists (length as) bs)"
    98         and ys: "ys \<in> set (List.n_lists (length as) bs)"
    99         and eq: "the \<circ> map_of (zip as xs) = the \<circ> map_of (zip as ys)"
   100       from xs ys have [simp]: "length xs = length as" "length ys = length as"
   101         by(simp_all add: length_n_lists_elem)
   102       have "map_of (zip as xs) = map_of (zip as ys)"
   103       proof
   104         fix x
   105         from as bs have "\<exists>y. map_of (zip as xs) x = Some y" "\<exists>y. map_of (zip as ys) x = Some y"
   106           by(simp_all add: map_of_zip_is_Some[symmetric])
   107         with eq show "map_of (zip as xs) x = map_of (zip as ys) x"
   108           by(auto dest: fun_cong[where x=x])
   109       qed
   110       with dista show "xs = ys" by(simp add: map_of_zip_inject)
   111     qed
   112     hence "card (set ?xs) = length ?xs" by(simp only: distinct_card)
   113     moreover have "length ?xs = length bs ^ length as" by(simp add: length_n_lists)
   114     ultimately have "CARD('a \<Rightarrow> 'b) = CARD('b) ^ CARD('a)" using cb ca by simp }
   115   moreover {
   116     assume cb: "CARD('b) = 1"
   117     then obtain b where b: "UNIV = {b :: 'b}" by(auto simp add: card_Suc_eq)
   118     have eq: "UNIV = {\<lambda>x :: 'a. b ::'b}"
   119     proof(rule UNIV_eq_I)
   120       fix x :: "'a \<Rightarrow> 'b"
   121       { fix y
   122         have "x y \<in> UNIV" ..
   123         hence "x y = b" unfolding b by simp }
   124       thus "x \<in> {\<lambda>x. b}" by(auto)
   125     qed
   126     have "CARD('a \<Rightarrow> 'b) = 1" unfolding eq by simp }
   127   ultimately show ?thesis
   128     by(auto simp del: One_nat_def)(auto simp add: card_eq_0_iff dest: finite_fun_UNIVD2 finite_fun_UNIVD1)
   129 qed
   130 
   131 corollary finite_UNIV_fun:
   132   "finite (UNIV :: ('a \<Rightarrow> 'b) set) \<longleftrightarrow>
   133    finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set) \<or> CARD('b) = 1"
   134   (is "?lhs \<longleftrightarrow> ?rhs")
   135 proof -
   136   have "?lhs \<longleftrightarrow> CARD('a \<Rightarrow> 'b) > 0" by(simp add: card_gt_0_iff)
   137   also have "\<dots> \<longleftrightarrow> CARD('a) > 0 \<and> CARD('b) > 0 \<or> CARD('b) = 1"
   138     by(simp add: card_fun)
   139   also have "\<dots> = ?rhs" by(simp add: card_gt_0_iff)
   140   finally show ?thesis .
   141 qed
   142 
   143 lemma card_literal: "CARD(String.literal) = 0"
   144 by(simp add: card_eq_0_iff infinite_literal)
   145 
   146 subsection \<open>Classes with at least 1 and 2\<close>
   147 
   148 text \<open>Class finite already captures "at least 1"\<close>
   149 
   150 lemma zero_less_card_finite [simp]: "0 < CARD('a::finite)"
   151   unfolding neq0_conv [symmetric] by simp
   152 
   153 lemma one_le_card_finite [simp]: "Suc 0 \<le> CARD('a::finite)"
   154   by (simp add: less_Suc_eq_le [symmetric])
   155 
   156 text \<open>Class for cardinality "at least 2"\<close>
   157 
   158 class card2 = finite + 
   159   assumes two_le_card: "2 \<le> CARD('a)"
   160 
   161 lemma one_less_card: "Suc 0 < CARD('a::card2)"
   162   using two_le_card [where 'a='a] by simp
   163 
   164 lemma one_less_int_card: "1 < int CARD('a::card2)"
   165   using one_less_card [where 'a='a] by simp
   166 
   167 
   168 subsection \<open>A type class for deciding finiteness of types\<close>
   169 
   170 type_synonym 'a finite_UNIV = "('a, bool) phantom"
   171 
   172 class finite_UNIV = 
   173   fixes finite_UNIV :: "('a, bool) phantom"
   174   assumes finite_UNIV: "finite_UNIV = Phantom('a) (finite (UNIV :: 'a set))"
   175 
   176 lemma finite_UNIV_code [code_unfold]:
   177   "finite (UNIV :: 'a :: finite_UNIV set)
   178   \<longleftrightarrow> of_phantom (finite_UNIV :: 'a finite_UNIV)"
   179 by(simp add: finite_UNIV)
   180 
   181 subsection \<open>A type class for computing the cardinality of types\<close>
   182 
   183 definition is_list_UNIV :: "'a list \<Rightarrow> bool"
   184 where "is_list_UNIV xs = (let c = CARD('a) in if c = 0 then False else size (remdups xs) = c)"
   185 
   186 lemma is_list_UNIV_iff: "is_list_UNIV xs \<longleftrightarrow> set xs = UNIV"
   187 by(auto simp add: is_list_UNIV_def Let_def card_eq_0_iff List.card_set[symmetric] 
   188    dest: subst[where P="finite", OF _ finite_set] card_eq_UNIV_imp_eq_UNIV)
   189 
   190 type_synonym 'a card_UNIV = "('a, nat) phantom"
   191 
   192 class card_UNIV = finite_UNIV +
   193   fixes card_UNIV :: "'a card_UNIV"
   194   assumes card_UNIV: "card_UNIV = Phantom('a) CARD('a)"
   195 
   196 subsection \<open>Instantiations for \<open>card_UNIV\<close>\<close>
   197 
   198 instantiation nat :: card_UNIV begin
   199 definition "finite_UNIV = Phantom(nat) False"
   200 definition "card_UNIV = Phantom(nat) 0"
   201 instance by intro_classes (simp_all add: finite_UNIV_nat_def card_UNIV_nat_def)
   202 end
   203 
   204 instantiation int :: card_UNIV begin
   205 definition "finite_UNIV = Phantom(int) False"
   206 definition "card_UNIV = Phantom(int) 0"
   207 instance by intro_classes (simp_all add: card_UNIV_int_def finite_UNIV_int_def infinite_UNIV_int)
   208 end
   209 
   210 instantiation natural :: card_UNIV begin
   211 definition "finite_UNIV = Phantom(natural) False"
   212 definition "card_UNIV = Phantom(natural) 0"
   213 instance
   214   by standard
   215     (auto simp add: finite_UNIV_natural_def card_UNIV_natural_def card_eq_0_iff
   216       type_definition.univ [OF type_definition_natural] natural_eq_iff
   217       dest!: finite_imageD intro: inj_onI)
   218 end
   219 
   220 instantiation integer :: card_UNIV begin
   221 definition "finite_UNIV = Phantom(integer) False"
   222 definition "card_UNIV = Phantom(integer) 0"
   223 instance
   224   by standard
   225     (auto simp add: finite_UNIV_integer_def card_UNIV_integer_def card_eq_0_iff
   226       type_definition.univ [OF type_definition_integer] infinite_UNIV_int
   227       dest!: finite_imageD intro: inj_onI)
   228 end
   229 
   230 instantiation list :: (type) card_UNIV begin
   231 definition "finite_UNIV = Phantom('a list) False"
   232 definition "card_UNIV = Phantom('a list) 0"
   233 instance by intro_classes (simp_all add: card_UNIV_list_def finite_UNIV_list_def infinite_UNIV_listI)
   234 end
   235 
   236 instantiation unit :: card_UNIV begin
   237 definition "finite_UNIV = Phantom(unit) True"
   238 definition "card_UNIV = Phantom(unit) 1"
   239 instance by intro_classes (simp_all add: card_UNIV_unit_def finite_UNIV_unit_def)
   240 end
   241 
   242 instantiation bool :: card_UNIV begin
   243 definition "finite_UNIV = Phantom(bool) True"
   244 definition "card_UNIV = Phantom(bool) 2"
   245 instance by(intro_classes)(simp_all add: card_UNIV_bool_def finite_UNIV_bool_def)
   246 end
   247 
   248 instantiation char :: card_UNIV begin
   249 definition "finite_UNIV = Phantom(char) True"
   250 definition "card_UNIV = Phantom(char) 256"
   251 instance by intro_classes (simp_all add: card_UNIV_char_def card_UNIV_char finite_UNIV_char_def)
   252 end
   253 
   254 instantiation prod :: (finite_UNIV, finite_UNIV) finite_UNIV begin
   255 definition "finite_UNIV = Phantom('a \<times> 'b) 
   256   (of_phantom (finite_UNIV :: 'a finite_UNIV) \<and> of_phantom (finite_UNIV :: 'b finite_UNIV))"
   257 instance by intro_classes (simp add: finite_UNIV_prod_def finite_UNIV finite_prod)
   258 end
   259 
   260 instantiation prod :: (card_UNIV, card_UNIV) card_UNIV begin
   261 definition "card_UNIV = Phantom('a \<times> 'b) 
   262   (of_phantom (card_UNIV :: 'a card_UNIV) * of_phantom (card_UNIV :: 'b card_UNIV))"
   263 instance by intro_classes (simp add: card_UNIV_prod_def card_UNIV)
   264 end
   265 
   266 instantiation sum :: (finite_UNIV, finite_UNIV) finite_UNIV begin
   267 definition "finite_UNIV = Phantom('a + 'b)
   268   (of_phantom (finite_UNIV :: 'a finite_UNIV) \<and> of_phantom (finite_UNIV :: 'b finite_UNIV))"
   269 instance
   270   by intro_classes (simp add: finite_UNIV_sum_def finite_UNIV)
   271 end
   272 
   273 instantiation sum :: (card_UNIV, card_UNIV) card_UNIV begin
   274 definition "card_UNIV = Phantom('a + 'b)
   275   (let ca = of_phantom (card_UNIV :: 'a card_UNIV); 
   276        cb = of_phantom (card_UNIV :: 'b card_UNIV)
   277    in if ca \<noteq> 0 \<and> cb \<noteq> 0 then ca + cb else 0)"
   278 instance by intro_classes (auto simp add: card_UNIV_sum_def card_UNIV card_UNIV_sum)
   279 end
   280 
   281 instantiation "fun" :: (finite_UNIV, card_UNIV) finite_UNIV begin
   282 definition "finite_UNIV = Phantom('a \<Rightarrow> 'b)
   283   (let cb = of_phantom (card_UNIV :: 'b card_UNIV)
   284    in cb = 1 \<or> of_phantom (finite_UNIV :: 'a finite_UNIV) \<and> cb \<noteq> 0)"
   285 instance
   286   by intro_classes (auto simp add: finite_UNIV_fun_def Let_def card_UNIV finite_UNIV finite_UNIV_fun card_gt_0_iff)
   287 end
   288 
   289 instantiation "fun" :: (card_UNIV, card_UNIV) card_UNIV begin
   290 definition "card_UNIV = Phantom('a \<Rightarrow> 'b)
   291   (let ca = of_phantom (card_UNIV :: 'a card_UNIV);
   292        cb = of_phantom (card_UNIV :: 'b card_UNIV)
   293    in if ca \<noteq> 0 \<and> cb \<noteq> 0 \<or> cb = 1 then cb ^ ca else 0)"
   294 instance by intro_classes (simp add: card_UNIV_fun_def card_UNIV Let_def card_fun)
   295 end
   296 
   297 instantiation option :: (finite_UNIV) finite_UNIV begin
   298 definition "finite_UNIV = Phantom('a option) (of_phantom (finite_UNIV :: 'a finite_UNIV))"
   299 instance by intro_classes (simp add: finite_UNIV_option_def finite_UNIV)
   300 end
   301 
   302 instantiation option :: (card_UNIV) card_UNIV begin
   303 definition "card_UNIV = Phantom('a option)
   304   (let c = of_phantom (card_UNIV :: 'a card_UNIV) in if c \<noteq> 0 then Suc c else 0)"
   305 instance by intro_classes (simp add: card_UNIV_option_def card_UNIV card_UNIV_option)
   306 end
   307 
   308 instantiation String.literal :: card_UNIV begin
   309 definition "finite_UNIV = Phantom(String.literal) False"
   310 definition "card_UNIV = Phantom(String.literal) 0"
   311 instance
   312   by intro_classes (simp_all add: card_UNIV_literal_def finite_UNIV_literal_def infinite_literal card_literal)
   313 end
   314 
   315 instantiation set :: (finite_UNIV) finite_UNIV begin
   316 definition "finite_UNIV = Phantom('a set) (of_phantom (finite_UNIV :: 'a finite_UNIV))"
   317 instance by intro_classes (simp add: finite_UNIV_set_def finite_UNIV Finite_Set.finite_set)
   318 end
   319 
   320 instantiation set :: (card_UNIV) card_UNIV begin
   321 definition "card_UNIV = Phantom('a set)
   322   (let c = of_phantom (card_UNIV :: 'a card_UNIV) in if c = 0 then 0 else 2 ^ c)"
   323 instance by intro_classes (simp add: card_UNIV_set_def card_UNIV_set card_UNIV)
   324 end
   325 
   326 lemma UNIV_finite_1: "UNIV = set [finite_1.a\<^sub>1]"
   327 by(auto intro: finite_1.exhaust)
   328 
   329 lemma UNIV_finite_2: "UNIV = set [finite_2.a\<^sub>1, finite_2.a\<^sub>2]"
   330 by(auto intro: finite_2.exhaust)
   331 
   332 lemma UNIV_finite_3: "UNIV = set [finite_3.a\<^sub>1, finite_3.a\<^sub>2, finite_3.a\<^sub>3]"
   333 by(auto intro: finite_3.exhaust)
   334 
   335 lemma UNIV_finite_4: "UNIV = set [finite_4.a\<^sub>1, finite_4.a\<^sub>2, finite_4.a\<^sub>3, finite_4.a\<^sub>4]"
   336 by(auto intro: finite_4.exhaust)
   337 
   338 lemma UNIV_finite_5:
   339   "UNIV = set [finite_5.a\<^sub>1, finite_5.a\<^sub>2, finite_5.a\<^sub>3, finite_5.a\<^sub>4, finite_5.a\<^sub>5]"
   340 by(auto intro: finite_5.exhaust)
   341 
   342 instantiation Enum.finite_1 :: card_UNIV begin
   343 definition "finite_UNIV = Phantom(Enum.finite_1) True"
   344 definition "card_UNIV = Phantom(Enum.finite_1) 1"
   345 instance
   346   by intro_classes (simp_all add: UNIV_finite_1 card_UNIV_finite_1_def finite_UNIV_finite_1_def)
   347 end
   348 
   349 instantiation Enum.finite_2 :: card_UNIV begin
   350 definition "finite_UNIV = Phantom(Enum.finite_2) True"
   351 definition "card_UNIV = Phantom(Enum.finite_2) 2"
   352 instance
   353   by intro_classes (simp_all add: UNIV_finite_2 card_UNIV_finite_2_def finite_UNIV_finite_2_def)
   354 end
   355 
   356 instantiation Enum.finite_3 :: card_UNIV begin
   357 definition "finite_UNIV = Phantom(Enum.finite_3) True"
   358 definition "card_UNIV = Phantom(Enum.finite_3) 3"
   359 instance
   360   by intro_classes (simp_all add: UNIV_finite_3 card_UNIV_finite_3_def finite_UNIV_finite_3_def)
   361 end
   362 
   363 instantiation Enum.finite_4 :: card_UNIV begin
   364 definition "finite_UNIV = Phantom(Enum.finite_4) True"
   365 definition "card_UNIV = Phantom(Enum.finite_4) 4"
   366 instance
   367   by intro_classes (simp_all add: UNIV_finite_4 card_UNIV_finite_4_def finite_UNIV_finite_4_def)
   368 end
   369 
   370 instantiation Enum.finite_5 :: card_UNIV begin
   371 definition "finite_UNIV = Phantom(Enum.finite_5) True"
   372 definition "card_UNIV = Phantom(Enum.finite_5) 5"
   373 instance
   374   by intro_classes (simp_all add: UNIV_finite_5 card_UNIV_finite_5_def finite_UNIV_finite_5_def)
   375 end
   376 
   377 subsection \<open>Code setup for sets\<close>
   378 
   379 text \<open>
   380   Implement @{term "CARD('a)"} via @{term card_UNIV} and provide
   381   implementations for @{term "finite"}, @{term "card"}, @{term "(\<subseteq>)"}, 
   382   and @{term "(=)"}if the calling context already provides @{class finite_UNIV}
   383   and @{class card_UNIV} instances. If we implemented the latter
   384   always via @{term card_UNIV}, we would require instances of essentially all 
   385   element types, i.e., a lot of instantiation proofs and -- at run time --
   386   possibly slow dictionary constructions.
   387 \<close>
   388 
   389 context
   390 begin
   391 
   392 qualified definition card_UNIV' :: "'a card_UNIV"
   393 where [code del]: "card_UNIV' = Phantom('a) CARD('a)"
   394 
   395 lemma CARD_code [code_unfold]:
   396   "CARD('a) = of_phantom (card_UNIV' :: 'a card_UNIV)"
   397 by(simp add: card_UNIV'_def)
   398 
   399 lemma card_UNIV'_code [code]:
   400   "card_UNIV' = card_UNIV"
   401 by(simp add: card_UNIV card_UNIV'_def)
   402 
   403 end
   404 
   405 lemma card_Compl:
   406   "finite A \<Longrightarrow> card (- A) = card (UNIV :: 'a set) - card (A :: 'a set)"
   407 by (metis Compl_eq_Diff_UNIV card_Diff_subset top_greatest)
   408 
   409 context fixes xs :: "'a :: finite_UNIV list"
   410 begin
   411 
   412 qualified definition finite' :: "'a set \<Rightarrow> bool"
   413 where [simp, code del, code_abbrev]: "finite' = finite"
   414 
   415 lemma finite'_code [code]:
   416   "finite' (set xs) \<longleftrightarrow> True"
   417   "finite' (List.coset xs) \<longleftrightarrow> of_phantom (finite_UNIV :: 'a finite_UNIV)"
   418 by(simp_all add: card_gt_0_iff finite_UNIV)
   419 
   420 end
   421 
   422 context fixes xs :: "'a :: card_UNIV list"
   423 begin
   424 
   425 qualified definition card' :: "'a set \<Rightarrow> nat" 
   426 where [simp, code del, code_abbrev]: "card' = card"
   427  
   428 lemma card'_code [code]:
   429   "card' (set xs) = length (remdups xs)"
   430   "card' (List.coset xs) = of_phantom (card_UNIV :: 'a card_UNIV) - length (remdups xs)"
   431 by(simp_all add: List.card_set card_Compl card_UNIV)
   432 
   433 
   434 qualified definition subset' :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool"
   435 where [simp, code del, code_abbrev]: "subset' = (\<subseteq>)"
   436 
   437 lemma subset'_code [code]:
   438   "subset' A (List.coset ys) \<longleftrightarrow> (\<forall>y \<in> set ys. y \<notin> A)"
   439   "subset' (set ys) B \<longleftrightarrow> (\<forall>y \<in> set ys. y \<in> B)"
   440   "subset' (List.coset xs) (set ys) \<longleftrightarrow> (let n = CARD('a) in n > 0 \<and> card(set (xs @ ys)) = n)"
   441 by(auto simp add: Let_def card_gt_0_iff dest: card_eq_UNIV_imp_eq_UNIV intro: arg_cong[where f=card])
   442   (metis finite_compl finite_set rev_finite_subset)
   443 
   444 qualified definition eq_set :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool"
   445 where [simp, code del, code_abbrev]: "eq_set = (=)"
   446 
   447 lemma eq_set_code [code]:
   448   fixes ys
   449   defines "rhs \<equiv> 
   450   let n = CARD('a)
   451   in if n = 0 then False else 
   452         let xs' = remdups xs; ys' = remdups ys 
   453         in length xs' + length ys' = n \<and> (\<forall>x \<in> set xs'. x \<notin> set ys') \<and> (\<forall>y \<in> set ys'. y \<notin> set xs')"
   454   shows "eq_set (List.coset xs) (set ys) \<longleftrightarrow> rhs"
   455   and "eq_set (set ys) (List.coset xs) \<longleftrightarrow> rhs"
   456   and "eq_set (set xs) (set ys) \<longleftrightarrow> (\<forall>x \<in> set xs. x \<in> set ys) \<and> (\<forall>y \<in> set ys. y \<in> set xs)"
   457   and "eq_set (List.coset xs) (List.coset ys) \<longleftrightarrow> (\<forall>x \<in> set xs. x \<in> set ys) \<and> (\<forall>y \<in> set ys. y \<in> set xs)"
   458 proof goal_cases
   459   {
   460     case 1
   461     show ?case (is "?lhs \<longleftrightarrow> ?rhs")
   462     proof
   463       show ?rhs if ?lhs
   464         using that
   465         by (auto simp add: rhs_def Let_def List.card_set[symmetric]
   466           card_Un_Int[where A="set xs" and B="- set xs"] card_UNIV
   467           Compl_partition card_gt_0_iff dest: sym)(metis finite_compl finite_set)
   468       show ?lhs if ?rhs
   469       proof - 
   470         have "\<lbrakk> \<forall>y\<in>set xs. y \<notin> set ys; \<forall>x\<in>set ys. x \<notin> set xs \<rbrakk> \<Longrightarrow> set xs \<inter> set ys = {}" by blast
   471         with that show ?thesis
   472           by (auto simp add: rhs_def Let_def List.card_set[symmetric]
   473             card_UNIV card_gt_0_iff card_Un_Int[where A="set xs" and B="set ys"]
   474             dest: card_eq_UNIV_imp_eq_UNIV split: if_split_asm)
   475       qed
   476     qed
   477   }
   478   moreover
   479   case 2
   480   ultimately show ?case unfolding eq_set_def by blast
   481 next
   482   case 3
   483   show ?case unfolding eq_set_def List.coset_def by blast
   484 next
   485   case 4
   486   show ?case unfolding eq_set_def List.coset_def by blast
   487 qed
   488 
   489 end
   490 
   491 text \<open>
   492   Provide more informative exceptions than Match for non-rewritten cases.
   493   If generated code raises one these exceptions, then a code equation calls
   494   the mentioned operator for an element type that is not an instance of
   495   @{class card_UNIV} and is therefore not implemented via @{term card_UNIV}.
   496   Constrain the element type with sort @{class card_UNIV} to change this.
   497 \<close>
   498 
   499 lemma card_coset_error [code]:
   500   "card (List.coset xs) = 
   501    Code.abort (STR ''card (List.coset _) requires type class instance card_UNIV'')
   502      (\<lambda>_. card (List.coset xs))"
   503 by(simp)
   504 
   505 lemma coset_subseteq_set_code [code]:
   506   "List.coset xs \<subseteq> set ys \<longleftrightarrow> 
   507   (if xs = [] \<and> ys = [] then False 
   508    else Code.abort
   509      (STR ''subset_eq (List.coset _) (List.set _) requires type class instance card_UNIV'')
   510      (\<lambda>_. List.coset xs \<subseteq> set ys))"
   511 by simp
   512 
   513 notepad begin \<comment> \<open>test code setup\<close>
   514 have "List.coset [True] = set [False] \<and> 
   515       List.coset [] \<subseteq> List.set [True, False] \<and> 
   516       finite (List.coset [True])"
   517   by eval
   518 end
   519 
   520 end