src/Pure/drule.ML
author berghofe
Sun Jun 29 21:28:13 2003 +0200 (2003-06-29)
changeset 14081 6c0f67e2f8d5
parent 13659 3cf622f6b0b2
child 14340 bc93ffa674cc
permissions -rw-r--r--
Added functions for renaming bound variables.
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val strip_imp_prems   : cterm -> cterm list
    18   val strip_imp_concl   : cterm -> cterm
    19   val cprems_of         : thm -> cterm list
    20   val read_insts        :
    21           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    22                   -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> string list -> (string*string)list
    24                   -> (indexname*ctyp)list * (cterm*cterm)list
    25   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    26   val strip_shyps_warning : thm -> thm
    27   val forall_intr_list  : cterm list -> thm -> thm
    28   val forall_intr_frees : thm -> thm
    29   val forall_intr_vars  : thm -> thm
    30   val forall_elim_list  : cterm list -> thm -> thm
    31   val forall_elim_var   : int -> thm -> thm
    32   val forall_elim_vars  : int -> thm -> thm
    33   val gen_all           : thm -> thm
    34   val freeze_thaw       : thm -> thm * (thm -> thm)
    35   val implies_elim_list : thm -> thm list -> thm
    36   val implies_intr_list : cterm list -> thm -> thm
    37   val instantiate       :
    38     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    39   val zero_var_indexes  : thm -> thm
    40   val standard          : thm -> thm
    41   val standard'         : thm -> thm
    42   val rotate_prems      : int -> thm -> thm
    43   val rearrange_prems   : int list -> thm -> thm
    44   val assume_ax         : theory -> string -> thm
    45   val RSN               : thm * (int * thm) -> thm
    46   val RS                : thm * thm -> thm
    47   val RLN               : thm list * (int * thm list) -> thm list
    48   val RL                : thm list * thm list -> thm list
    49   val MRS               : thm list * thm -> thm
    50   val MRL               : thm list list * thm list -> thm list
    51   val OF                : thm * thm list -> thm
    52   val compose           : thm * int * thm -> thm list
    53   val COMP              : thm * thm -> thm
    54   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    55   val read_instantiate  : (string*string)list -> thm -> thm
    56   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    57   val eq_thm_sg         : thm * thm -> bool
    58   val eq_thm_prop	: thm * thm -> bool
    59   val weak_eq_thm       : thm * thm -> bool
    60   val size_of_thm       : thm -> int
    61   val reflexive_thm     : thm
    62   val symmetric_thm     : thm
    63   val transitive_thm    : thm
    64   val refl_implies      : thm
    65   val symmetric_fun     : thm -> thm
    66   val extensional       : thm -> thm
    67   val imp_cong          : thm
    68   val swap_prems_eq     : thm
    69   val equal_abs_elim    : cterm  -> thm -> thm
    70   val equal_abs_elim_list: cterm list -> thm -> thm
    71   val asm_rl            : thm
    72   val cut_rl            : thm
    73   val revcut_rl         : thm
    74   val thin_rl           : thm
    75   val triv_forall_equality: thm
    76   val swap_prems_rl     : thm
    77   val equal_intr_rule   : thm
    78   val equal_elim_rule1  : thm
    79   val inst              : string -> string -> thm -> thm
    80   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    81   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    82 end;
    83 
    84 signature DRULE =
    85 sig
    86   include BASIC_DRULE
    87   val strip_comb: cterm -> cterm * cterm list
    88   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    89   val tag_rule: tag -> thm -> thm
    90   val untag_rule: string -> thm -> thm
    91   val tag: tag -> 'a attribute
    92   val untag: string -> 'a attribute
    93   val get_kind: thm -> string
    94   val kind: string -> 'a attribute
    95   val theoremK: string
    96   val lemmaK: string
    97   val corollaryK: string
    98   val internalK: string
    99   val kind_internal: 'a attribute
   100   val has_internal: tag list -> bool
   101   val impose_hyps: cterm list -> thm -> thm
   102   val satisfy_hyps: thm list -> thm -> thm
   103   val close_derivation: thm -> thm
   104   val local_standard: thm -> thm
   105   val compose_single: thm * int * thm -> thm
   106   val add_rule: thm -> thm list -> thm list
   107   val del_rule: thm -> thm list -> thm list
   108   val add_rules: thm list -> thm list -> thm list
   109   val del_rules: thm list -> thm list -> thm list
   110   val merge_rules: thm list * thm list -> thm list
   111   val norm_hhf_eq: thm
   112   val is_norm_hhf: term -> bool
   113   val norm_hhf: Sign.sg -> term -> term
   114   val triv_goal: thm
   115   val rev_triv_goal: thm
   116   val implies_intr_goals: cterm list -> thm -> thm
   117   val freeze_all: thm -> thm
   118   val mk_triv_goal: cterm -> thm
   119   val tvars_of_terms: term list -> (indexname * sort) list
   120   val vars_of_terms: term list -> (indexname * typ) list
   121   val tvars_of: thm -> (indexname * sort) list
   122   val vars_of: thm -> (indexname * typ) list
   123   val rename_bvars: (string * string) list -> thm -> thm
   124   val rename_bvars': string option list -> thm -> thm
   125   val unvarifyT: thm -> thm
   126   val unvarify: thm -> thm
   127   val tvars_intr_list: string list -> thm -> thm * (string * indexname) list
   128   val remdups_rl: thm
   129   val conj_intr: thm -> thm -> thm
   130   val conj_intr_list: thm list -> thm
   131   val conj_elim: thm -> thm * thm
   132   val conj_elim_list: thm -> thm list
   133   val conj_elim_precise: int -> thm -> thm list
   134   val conj_intr_thm: thm
   135   val abs_def: thm -> thm
   136 end;
   137 
   138 structure Drule: DRULE =
   139 struct
   140 
   141 
   142 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   143 
   144 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   145 
   146 (*dest_implies for cterms. Note T=prop below*)
   147 fun dest_implies ct =
   148     case term_of ct of
   149         (Const("==>", _) $ _ $ _) =>
   150             let val (ct1,ct2) = Thm.dest_comb ct
   151             in  (#2 (Thm.dest_comb ct1), ct2)  end
   152       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   153 
   154 fun dest_equals ct =
   155     case term_of ct of
   156         (Const("==", _) $ _ $ _) =>
   157             let val (ct1,ct2) = Thm.dest_comb ct
   158             in  (#2 (Thm.dest_comb ct1), ct2)  end
   159       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   160 
   161 
   162 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   163 fun strip_imp_prems ct =
   164     let val (cA,cB) = dest_implies ct
   165     in  cA :: strip_imp_prems cB  end
   166     handle TERM _ => [];
   167 
   168 (* A1==>...An==>B  goes to B, where B is not an implication *)
   169 fun strip_imp_concl ct =
   170     case term_of ct of (Const("==>", _) $ _ $ _) =>
   171         strip_imp_concl (#2 (Thm.dest_comb ct))
   172   | _ => ct;
   173 
   174 (*The premises of a theorem, as a cterm list*)
   175 val cprems_of = strip_imp_prems o cprop_of;
   176 
   177 val proto_sign = Theory.sign_of ProtoPure.thy;
   178 
   179 val implies = cterm_of proto_sign Term.implies;
   180 
   181 (*cterm version of mk_implies*)
   182 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   183 
   184 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   185 fun list_implies([], B) = B
   186   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   187 
   188 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   189 fun strip_comb ct = 
   190   let
   191     fun stripc (p as (ct, cts)) =
   192       let val (ct1, ct2) = Thm.dest_comb ct
   193       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   194   in stripc (ct, []) end;
   195 
   196 
   197 (** reading of instantiations **)
   198 
   199 fun absent ixn =
   200   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   201 
   202 fun inst_failure ixn =
   203   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   204 
   205 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   206 let
   207     fun split([],tvs,vs) = (tvs,vs)
   208       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   209                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   210                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   211     val (tvs,vs) = split(insts,[],[]);
   212     fun readT((a,i),st) =
   213         let val ixn = ("'" ^ a,i);
   214             val S = case rsorts ixn of Some S => S | None => absent ixn;
   215             val T = Sign.read_typ (sign,sorts) st;
   216         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   217            else inst_failure ixn
   218         end
   219     val tye = map readT tvs;
   220     fun mkty(ixn,st) = (case rtypes ixn of
   221                           Some T => (ixn,(st,typ_subst_TVars tye T))
   222                         | None => absent ixn);
   223     val ixnsTs = map mkty vs;
   224     val ixns = map fst ixnsTs
   225     and sTs  = map snd ixnsTs
   226     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   227     fun mkcVar(ixn,T) =
   228         let val U = typ_subst_TVars tye2 T
   229         in cterm_of sign (Var(ixn,U)) end
   230     val ixnTs = ListPair.zip(ixns, map snd sTs)
   231 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   232     ListPair.zip(map mkcVar ixnTs,cts))
   233 end;
   234 
   235 
   236 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   237      Used for establishing default types (of variables) and sorts (of
   238      type variables) when reading another term.
   239      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   240 ***)
   241 
   242 fun types_sorts thm =
   243     let val {prop,hyps,...} = rep_thm thm;
   244         val big = list_comb(prop,hyps); (* bogus term! *)
   245         val vars = map dest_Var (term_vars big);
   246         val frees = map dest_Free (term_frees big);
   247         val tvars = term_tvars big;
   248         val tfrees = term_tfrees big;
   249         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   250         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   251     in (typ,sort) end;
   252 
   253 
   254 
   255 (** basic attributes **)
   256 
   257 (* dependent rules *)
   258 
   259 fun rule_attribute f (x, thm) = (x, (f x thm));
   260 
   261 
   262 (* add / delete tags *)
   263 
   264 fun map_tags f thm =
   265   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   266 
   267 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   268 fun untag_rule s = map_tags (filter_out (equal s o #1));
   269 
   270 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   271 fun untag s x = rule_attribute (K (untag_rule s)) x;
   272 
   273 fun simple_tag name x = tag (name, []) x;
   274 
   275 
   276 (* theorem kinds *)
   277 
   278 val theoremK = "theorem";
   279 val lemmaK = "lemma";
   280 val corollaryK = "corollary";
   281 val internalK = "internal";
   282 
   283 fun get_kind thm =
   284   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   285     Some (k :: _) => k
   286   | _ => "unknown");
   287 
   288 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   289 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   290 fun kind_internal x = kind internalK x;
   291 fun has_internal tags = exists (equal internalK o fst) tags;
   292 
   293 
   294 
   295 (** Standardization of rules **)
   296 
   297 (*Strip extraneous shyps as far as possible*)
   298 fun strip_shyps_warning thm =
   299   let
   300     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   301     val thm' = Thm.strip_shyps thm;
   302     val xshyps = Thm.extra_shyps thm';
   303   in
   304     if null xshyps then ()
   305     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   306     thm'
   307   end;
   308 
   309 (*Generalization over a list of variables, IGNORING bad ones*)
   310 fun forall_intr_list [] th = th
   311   | forall_intr_list (y::ys) th =
   312         let val gth = forall_intr_list ys th
   313         in  forall_intr y gth   handle THM _ =>  gth  end;
   314 
   315 (*Generalization over all suitable Free variables*)
   316 fun forall_intr_frees th =
   317     let val {prop,sign,...} = rep_thm th
   318     in  forall_intr_list
   319          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   320          th
   321     end;
   322 
   323 val forall_elim_var = PureThy.forall_elim_var;
   324 val forall_elim_vars = PureThy.forall_elim_vars;
   325 
   326 fun gen_all thm =
   327   let
   328     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   329     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   330     val vs = Term.strip_all_vars prop;
   331   in foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   332 
   333 (*Specialization over a list of cterms*)
   334 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   335 
   336 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   337 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   338 
   339 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   340 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   341 
   342 (* maps |- B to A1,...,An |- B *)
   343 fun impose_hyps chyps th =
   344   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   345   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   346 
   347 (* maps A1,...,An and A1,...,An |- B to |- B *)
   348 fun satisfy_hyps ths th =
   349   implies_elim_list (implies_intr_list (map (#prop o Thm.crep_thm) ths) th) ths;
   350 
   351 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   352 fun zero_var_indexes th =
   353     let val {prop,sign,...} = rep_thm th;
   354         val vars = term_vars prop
   355         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   356         val inrs = add_term_tvars(prop,[]);
   357         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   358         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   359                      (inrs, nms')
   360         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   361         fun varpairs([],[]) = []
   362           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   363                 let val T' = typ_subst_TVars tye T
   364                 in (cterm_of sign (Var(v,T')),
   365                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   366                 end
   367           | varpairs _ = raise TERM("varpairs", []);
   368     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   369 
   370 
   371 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   372     all generality expressed by Vars having index 0.*)
   373 
   374 fun close_derivation thm =
   375   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   376   else thm;
   377 
   378 fun standard' th =
   379   let val {maxidx,...} = rep_thm th in
   380     th
   381     |> implies_intr_hyps
   382     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   383     |> strip_shyps_warning
   384     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   385   end;
   386 
   387 val standard = close_derivation o standard';
   388 
   389 fun local_standard th =
   390   th |> strip_shyps |> zero_var_indexes
   391   |> Thm.compress |> close_derivation;
   392 
   393 
   394 (*Convert all Vars in a theorem to Frees.  Also return a function for
   395   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   396   Similar code in type/freeze_thaw*)
   397 fun freeze_thaw th =
   398  let val fth = freezeT th
   399      val {prop, tpairs, sign, ...} = rep_thm fth
   400  in
   401    case foldr add_term_vars (prop :: Thm.terms_of_tpairs tpairs, []) of
   402        [] => (fth, fn x => x)
   403      | vars =>
   404          let fun newName (Var(ix,_), (pairs,used)) =
   405                    let val v = variant used (string_of_indexname ix)
   406                    in  ((ix,v)::pairs, v::used)  end;
   407              val (alist, _) = foldr newName (vars, ([], foldr add_term_names
   408                (prop :: Thm.terms_of_tpairs tpairs, [])))
   409              fun mk_inst (Var(v,T)) =
   410                  (cterm_of sign (Var(v,T)),
   411                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   412              val insts = map mk_inst vars
   413              fun thaw th' =
   414                  th' |> forall_intr_list (map #2 insts)
   415                      |> forall_elim_list (map #1 insts)
   416          in  (Thm.instantiate ([],insts) fth, thaw)  end
   417  end;
   418 
   419 
   420 (*Rotates a rule's premises to the left by k*)
   421 val rotate_prems = permute_prems 0;
   422 
   423 (* permute prems, where the i-th position in the argument list (counting from 0)
   424    gives the position within the original thm to be transferred to position i.
   425    Any remaining trailing positions are left unchanged. *)
   426 val rearrange_prems = let
   427   fun rearr new []      thm = thm
   428   |   rearr new (p::ps) thm = rearr (new+1)
   429      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   430      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   431   in rearr 0 end;
   432 
   433 (*Assume a new formula, read following the same conventions as axioms.
   434   Generalizes over Free variables,
   435   creates the assumption, and then strips quantifiers.
   436   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   437              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   438 fun assume_ax thy sP =
   439     let val sign = Theory.sign_of thy
   440         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   441     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   442 
   443 (*Resolution: exactly one resolvent must be produced.*)
   444 fun tha RSN (i,thb) =
   445   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   446       ([th],_) => th
   447     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   448     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   449 
   450 (*resolution: P==>Q, Q==>R gives P==>R. *)
   451 fun tha RS thb = tha RSN (1,thb);
   452 
   453 (*For joining lists of rules*)
   454 fun thas RLN (i,thbs) =
   455   let val resolve = biresolution false (map (pair false) thas) i
   456       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   457   in  List.concat (map resb thbs)  end;
   458 
   459 fun thas RL thbs = thas RLN (1,thbs);
   460 
   461 (*Resolve a list of rules against bottom_rl from right to left;
   462   makes proof trees*)
   463 fun rls MRS bottom_rl =
   464   let fun rs_aux i [] = bottom_rl
   465         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   466   in  rs_aux 1 rls  end;
   467 
   468 (*As above, but for rule lists*)
   469 fun rlss MRL bottom_rls =
   470   let fun rs_aux i [] = bottom_rls
   471         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   472   in  rs_aux 1 rlss  end;
   473 
   474 (*A version of MRS with more appropriate argument order*)
   475 fun bottom_rl OF rls = rls MRS bottom_rl;
   476 
   477 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   478   with no lifting or renaming!  Q may contain ==> or meta-quants
   479   ALWAYS deletes premise i *)
   480 fun compose(tha,i,thb) =
   481     Seq.list_of (bicompose false (false,tha,0) i thb);
   482 
   483 fun compose_single (tha,i,thb) =
   484   (case compose (tha,i,thb) of
   485     [th] => th
   486   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   487 
   488 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   489 fun tha COMP thb =
   490     case compose(tha,1,thb) of
   491         [th] => th
   492       | _ =>   raise THM("COMP", 1, [tha,thb]);
   493 
   494 
   495 (** theorem equality **)
   496 
   497 (*True if the two theorems have the same signature.*)
   498 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   499 
   500 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   501 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   502 
   503 (*Useful "distance" function for BEST_FIRST*)
   504 val size_of_thm = size_of_term o prop_of;
   505 
   506 (*maintain lists of theorems --- preserving canonical order*)
   507 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   508 fun add_rules rs rules = rs @ del_rules rs rules;
   509 val del_rule = del_rules o single;
   510 val add_rule = add_rules o single;
   511 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   512 
   513 
   514 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   515     (some) type variable renaming **)
   516 
   517  (* Can't use term_vars, because it sorts the resulting list of variable names.
   518     We instead need the unique list noramlised by the order of appearance
   519     in the term. *)
   520 fun term_vars' (t as Var(v,T)) = [t]
   521   | term_vars' (Abs(_,_,b)) = term_vars' b
   522   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   523   | term_vars' _ = [];
   524 
   525 fun forall_intr_vars th =
   526   let val {prop,sign,...} = rep_thm th;
   527       val vars = distinct (term_vars' prop);
   528   in forall_intr_list (map (cterm_of sign) vars) th end;
   529 
   530 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   531 
   532 
   533 (*** Meta-Rewriting Rules ***)
   534 
   535 fun read_prop s = read_cterm proto_sign (s, propT);
   536 
   537 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   538 fun store_standard_thm name thm = store_thm name (standard thm);
   539 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   540 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   541 
   542 val reflexive_thm =
   543   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   544   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   545 
   546 val symmetric_thm =
   547   let val xy = read_prop "x::'a::logic == y"
   548   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   549 
   550 val transitive_thm =
   551   let val xy = read_prop "x::'a::logic == y"
   552       val yz = read_prop "y::'a::logic == z"
   553       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   554   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   555 
   556 fun symmetric_fun thm = thm RS symmetric_thm;
   557 
   558 fun extensional eq =
   559   let val eq' =
   560     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   561   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   562 
   563 val imp_cong =
   564   let
   565     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   566     val AB = read_prop "PROP A ==> PROP B"
   567     val AC = read_prop "PROP A ==> PROP C"
   568     val A = read_prop "PROP A"
   569   in
   570     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   571       (implies_intr AB (implies_intr A
   572         (equal_elim (implies_elim (assume ABC) (assume A))
   573           (implies_elim (assume AB) (assume A)))))
   574       (implies_intr AC (implies_intr A
   575         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   576           (implies_elim (assume AC) (assume A)))))))
   577   end;
   578 
   579 val swap_prems_eq =
   580   let
   581     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   582     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   583     val A = read_prop "PROP A"
   584     val B = read_prop "PROP B"
   585   in
   586     store_standard_thm_open "swap_prems_eq" (equal_intr
   587       (implies_intr ABC (implies_intr B (implies_intr A
   588         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   589       (implies_intr BAC (implies_intr A (implies_intr B
   590         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   591   end;
   592 
   593 val refl_implies = reflexive implies;
   594 
   595 fun abs_def thm =
   596   let
   597     val (_, cvs) = strip_comb (fst (dest_equals (cprop_of thm)));
   598     val thm' = foldr (fn (ct, thm) => Thm.abstract_rule
   599       (case term_of ct of Var ((a, _), _) => a | Free (a, _) => a | _ => "x")
   600         ct thm) (cvs, thm)
   601   in transitive
   602     (symmetric (eta_conversion (fst (dest_equals (cprop_of thm'))))) thm'
   603   end;
   604 
   605 
   606 (*** Some useful meta-theorems ***)
   607 
   608 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   609 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   610 val _ = store_thm "_" asm_rl;
   611 
   612 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   613 val cut_rl =
   614   store_standard_thm_open "cut_rl"
   615     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   616 
   617 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   618      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   619 val revcut_rl =
   620   let val V = read_prop "PROP V"
   621       and VW = read_prop "PROP V ==> PROP W";
   622   in
   623     store_standard_thm_open "revcut_rl"
   624       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   625   end;
   626 
   627 (*for deleting an unwanted assumption*)
   628 val thin_rl =
   629   let val V = read_prop "PROP V"
   630       and W = read_prop "PROP W";
   631   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   632 
   633 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   634 val triv_forall_equality =
   635   let val V  = read_prop "PROP V"
   636       and QV = read_prop "!!x::'a. PROP V"
   637       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   638   in
   639     store_standard_thm_open "triv_forall_equality"
   640       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   641         (implies_intr V  (forall_intr x (assume V))))
   642   end;
   643 
   644 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   645    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   646    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   647 *)
   648 val swap_prems_rl =
   649   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   650       val major = assume cmajor;
   651       val cminor1 = read_prop "PROP PhiA";
   652       val minor1 = assume cminor1;
   653       val cminor2 = read_prop "PROP PhiB";
   654       val minor2 = assume cminor2;
   655   in store_standard_thm_open "swap_prems_rl"
   656        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   657          (implies_elim (implies_elim major minor1) minor2))))
   658   end;
   659 
   660 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   661    ==> PROP ?phi == PROP ?psi
   662    Introduction rule for == as a meta-theorem.
   663 *)
   664 val equal_intr_rule =
   665   let val PQ = read_prop "PROP phi ==> PROP psi"
   666       and QP = read_prop "PROP psi ==> PROP phi"
   667   in
   668     store_standard_thm_open "equal_intr_rule"
   669       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   670   end;
   671 
   672 (* [| PROP ?phi == PROP ?psi; PROP ?phi |] ==> PROP ?psi *)
   673 val equal_elim_rule1 =
   674   let val eq = read_prop "PROP phi == PROP psi"
   675       and P = read_prop "PROP phi"
   676   in store_standard_thm_open "equal_elim_rule1"
   677     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   678   end;
   679 
   680 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   681 
   682 val remdups_rl =
   683   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   684   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   685 
   686 
   687 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   688   Rewrite rule for HHF normalization.*)
   689 
   690 val norm_hhf_eq =
   691   let
   692     val cert = Thm.cterm_of proto_sign;
   693     val aT = TFree ("'a", Term.logicS);
   694     val all = Term.all aT;
   695     val x = Free ("x", aT);
   696     val phi = Free ("phi", propT);
   697     val psi = Free ("psi", aT --> propT);
   698 
   699     val cx = cert x;
   700     val cphi = cert phi;
   701     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   702     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   703   in
   704     Thm.equal_intr
   705       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   706         |> Thm.forall_elim cx
   707         |> Thm.implies_intr cphi
   708         |> Thm.forall_intr cx
   709         |> Thm.implies_intr lhs)
   710       (Thm.implies_elim
   711           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   712         |> Thm.forall_intr cx
   713         |> Thm.implies_intr cphi
   714         |> Thm.implies_intr rhs)
   715     |> store_standard_thm_open "norm_hhf_eq"
   716   end;
   717 
   718 fun is_norm_hhf tm =
   719   let
   720     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   721       | is_norm (t $ u) = is_norm t andalso is_norm u
   722       | is_norm (Abs (_, _, t)) = is_norm t
   723       | is_norm _ = true;
   724   in is_norm (Pattern.beta_eta_contract tm) end;
   725 
   726 fun norm_hhf sg t =
   727   if is_norm_hhf t then t
   728   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] [] t;
   729 
   730 
   731 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   732 
   733 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   734 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   735 
   736 fun read_instantiate_sg sg sinsts th =
   737     let val ts = types_sorts th;
   738         val used = add_term_tvarnames (prop_of th, []);
   739     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   740 
   741 (*Instantiate theorem th, reading instantiations under theory of th*)
   742 fun read_instantiate sinsts th =
   743     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   744 
   745 
   746 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   747   Instantiates distinct Vars by terms, inferring type instantiations. *)
   748 local
   749   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   750     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   751         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   752         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   753         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   754         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) (tye, maxi) (T, U)
   755           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   756     in  (sign', tye', maxi')  end;
   757 in
   758 fun cterm_instantiate ctpairs0 th =
   759   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   760       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   761                          in (cterm_fun inst ct, cterm_fun inst cu) end
   762       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   763   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   764   handle TERM _ =>
   765            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   766        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   767 end;
   768 
   769 
   770 (** Derived rules mainly for METAHYPS **)
   771 
   772 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   773 fun equal_abs_elim ca eqth =
   774   let val {sign=signa, t=a, ...} = rep_cterm ca
   775       and combth = combination eqth (reflexive ca)
   776       val {sign,prop,...} = rep_thm eqth
   777       val (abst,absu) = Logic.dest_equals prop
   778       val cterm = cterm_of (Sign.merge (sign,signa))
   779   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   780            (transitive combth (beta_conversion false (cterm (absu$a))))
   781   end
   782   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   783 
   784 (*Calling equal_abs_elim with multiple terms*)
   785 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   786 
   787 
   788 (*** Goal (PROP A) <==> PROP A ***)
   789 
   790 local
   791   val cert = Thm.cterm_of proto_sign;
   792   val A = Free ("A", propT);
   793   val G = Logic.mk_goal A;
   794   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   795 in
   796   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   797       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   798   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   799       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   800 end;
   801 
   802 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   803 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   804 
   805 fun implies_intr_goals cprops thm =
   806   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   807   |> implies_intr_list (map mk_cgoal cprops);
   808 
   809 
   810 
   811 (** variations on instantiate **)
   812 
   813 (*shorthand for instantiating just one variable in the current theory*)
   814 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   815 
   816 
   817 (* collect vars in left-to-right order *)
   818 
   819 fun tvars_of_terms ts = rev (foldl Term.add_tvars ([], ts));
   820 fun vars_of_terms ts = rev (foldl Term.add_vars ([], ts));
   821 
   822 fun tvars_of thm = tvars_of_terms [prop_of thm];
   823 fun vars_of thm = vars_of_terms [prop_of thm];
   824 
   825 
   826 (* instantiate by left-to-right occurrence of variables *)
   827 
   828 fun instantiate' cTs cts thm =
   829   let
   830     fun err msg =
   831       raise TYPE ("instantiate': " ^ msg,
   832         mapfilter (apsome Thm.typ_of) cTs,
   833         mapfilter (apsome Thm.term_of) cts);
   834 
   835     fun inst_of (v, ct) =
   836       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   837         handle TYPE (msg, _, _) => err msg;
   838 
   839     fun zip_vars _ [] = []
   840       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   841       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   842       | zip_vars [] _ = err "more instantiations than variables in thm";
   843 
   844     (*instantiate types first!*)
   845     val thm' =
   846       if forall is_none cTs then thm
   847       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   848     in
   849       if forall is_none cts then thm'
   850       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   851     end;
   852 
   853 
   854 
   855 (** renaming of bound variables **)
   856 
   857 (* replace bound variables x_i in thm by y_i *)
   858 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   859 
   860 fun rename_bvars [] thm = thm
   861   | rename_bvars vs thm =
   862     let
   863       val {sign, prop, ...} = rep_thm thm;
   864       fun ren (Abs (x, T, t)) = Abs (if_none (assoc (vs, x)) x, T, ren t)
   865         | ren (t $ u) = ren t $ ren u
   866         | ren t = t;
   867     in equal_elim (reflexive (cterm_of sign (ren prop))) thm end;
   868 
   869 
   870 (* renaming in left-to-right order *)
   871 
   872 fun rename_bvars' xs thm =
   873   let
   874     val {sign, prop, ...} = rep_thm thm;
   875     fun rename [] t = ([], t)
   876       | rename (x' :: xs) (Abs (x, T, t)) =
   877           let val (xs', t') = rename xs t
   878           in (xs', Abs (if_none x' x, T, t')) end
   879       | rename xs (t $ u) =
   880           let
   881             val (xs', t') = rename xs t;
   882             val (xs'', u') = rename xs' u
   883           in (xs'', t' $ u') end
   884       | rename xs t = (xs, t);
   885   in case rename xs prop of
   886       ([], prop') => equal_elim (reflexive (cterm_of sign prop')) thm
   887     | _ => error "More names than abstractions in theorem"
   888   end;
   889 
   890 
   891 
   892 (* unvarify(T) *)
   893 
   894 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   895 
   896 fun unvarifyT thm =
   897   let
   898     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   899     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   900   in instantiate' tfrees [] thm end;
   901 
   902 fun unvarify raw_thm =
   903   let
   904     val thm = unvarifyT raw_thm;
   905     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   906     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   907   in instantiate' [] frees thm end;
   908 
   909 
   910 (* tvars_intr_list *)
   911 
   912 fun tfrees_of thm =
   913   let val {hyps, prop, ...} = Thm.rep_thm thm
   914   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   915 
   916 fun tvars_intr_list tfrees thm =
   917   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   918 
   919 
   920 (* increment var indexes *)
   921 
   922 fun incr_indexes_wrt is cTs cts thms =
   923   let
   924     val maxidx =
   925       foldl Int.max (~1, is @
   926         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   927         map (#maxidx o Thm.rep_cterm) cts @
   928         map (#maxidx o Thm.rep_thm) thms);
   929   in Thm.incr_indexes (maxidx + 1) end;
   930 
   931 
   932 (* freeze_all *)
   933 
   934 (*freeze all (T)Vars; assumes thm in standard form*)
   935 
   936 fun freeze_all_TVars thm =
   937   (case tvars_of thm of
   938     [] => thm
   939   | tvars =>
   940       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   941       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   942 
   943 fun freeze_all_Vars thm =
   944   (case vars_of thm of
   945     [] => thm
   946   | vars =>
   947       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   948       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   949 
   950 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   951 
   952 
   953 (* mk_triv_goal *)
   954 
   955 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   956 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   957 
   958 
   959 
   960 (** meta-level conjunction **)
   961 
   962 local
   963   val A = read_prop "PROP A";
   964   val B = read_prop "PROP B";
   965   val C = read_prop "PROP C";
   966   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   967 
   968   val proj1 =
   969     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   970     |> forall_elim_vars 0;
   971 
   972   val proj2 =
   973     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   974     |> forall_elim_vars 0;
   975 
   976   val conj_intr_rule =
   977     forall_intr_list [A, B] (implies_intr_list [A, B]
   978       (Thm.forall_intr C (Thm.implies_intr ABC
   979         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   980     |> forall_elim_vars 0;
   981 
   982   val incr = incr_indexes_wrt [] [] [];
   983 in
   984 
   985 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   986 
   987 fun conj_intr_list [] = asm_rl
   988   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
   989 
   990 fun conj_elim th =
   991   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
   992   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
   993 
   994 fun conj_elim_list th =
   995   let val (th1, th2) = conj_elim th
   996   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
   997 
   998 fun conj_elim_precise 0 _ = []
   999   | conj_elim_precise 1 th = [th]
  1000   | conj_elim_precise n th =
  1001       let val (th1, th2) = conj_elim th
  1002       in th1 :: conj_elim_precise (n - 1) th2 end;
  1003 
  1004 val conj_intr_thm = store_standard_thm_open "conjunctionI"
  1005   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
  1006 
  1007 end;
  1008 
  1009 end;
  1010 
  1011 structure BasicDrule: BASIC_DRULE = Drule;
  1012 open BasicDrule;