src/Pure/variable.ML
author wenzelm
Tue Nov 14 22:17:00 2006 +0100 (2006-11-14)
changeset 21369 6cca4865e388
parent 21355 5c1b1ae737e1
child 21522 bd641d927437
permissions -rw-r--r--
removed fix_frees interface;
added auto_fixes (depends on body mode);
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val is_fixed: Proof.context -> string -> bool
    19   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    20   val default_type: Proof.context -> string -> typ option
    21   val def_type: Proof.context -> bool -> indexname -> typ option
    22   val def_sort: Proof.context -> indexname -> sort option
    23   val declare_constraints: term -> Proof.context -> Proof.context
    24   val declare_internal: term -> Proof.context -> Proof.context
    25   val declare_term: term -> Proof.context -> Proof.context
    26   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    27   val declare_thm: thm -> Proof.context -> Proof.context
    28   val thm_context: thm -> Proof.context
    29   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    30   val hidden_polymorphism: term -> typ -> (indexname * sort) list
    31   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    32   val expand_binds: Proof.context -> term -> term
    33   val add_fixes: string list -> Proof.context -> string list * Proof.context
    34   val add_fixes_direct: string list -> Proof.context -> Proof.context
    35   val auto_fixes: term -> Proof.context -> Proof.context
    36   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    37   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    38   val export_inst: Proof.context -> Proof.context -> string list * string list
    39   val exportT_inst: Proof.context -> Proof.context -> string list
    40   val export_terms: Proof.context -> Proof.context -> term list -> term list
    41   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    42   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    43   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    44   val export: Proof.context -> Proof.context -> thm list -> thm list
    45   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    46   val import_inst: bool -> term list -> Proof.context ->
    47     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    48   val importT_terms: term list -> Proof.context -> term list * Proof.context
    49   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    50   val importT: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    51   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    52   val import: bool -> thm list -> Proof.context ->
    53     ((ctyp list * cterm list) * thm list) * Proof.context
    54   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    55   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    56   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    57   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    58   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    59   val polymorphic: Proof.context -> term list -> term list
    60 end;
    61 
    62 structure Variable: VARIABLE =
    63 struct
    64 
    65 (** local context data **)
    66 
    67 datatype data = Data of
    68  {is_body: bool,                        (*inner body mode*)
    69   names: Name.context,                  (*type/term variable names*)
    70   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    71   binds: (typ * term) Vartab.table,     (*term bindings*)
    72   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    73   constraints:
    74     typ Vartab.table *                  (*type constraints*)
    75     sort Vartab.table};                 (*default sorts*)
    76 
    77 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    78   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    79     type_occs = type_occs, constraints = constraints};
    80 
    81 structure Data = ProofDataFun
    82 (
    83   val name = "Pure/variable";
    84   type T = data;
    85   fun init thy =
    86     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    87   fun print _ _ = ();
    88 );
    89 
    90 val _ = Context.add_setup Data.init;
    91 
    92 fun map_data f =
    93   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    94     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    95 
    96 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    97   (is_body, f names, fixes, binds, type_occs, constraints));
    98 
    99 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   100   (is_body, names, f fixes, binds, type_occs, constraints));
   101 
   102 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   103   (is_body, names, fixes, f binds, type_occs, constraints));
   104 
   105 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   106   (is_body, names, fixes, binds, f type_occs, constraints));
   107 
   108 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   109   (is_body, names, fixes, binds, type_occs, f constraints));
   110 
   111 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   112 
   113 val is_body = #is_body o rep_data;
   114 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   115   (b, names, fixes, binds, type_occs, constraints));
   116 fun restore_body ctxt = set_body (is_body ctxt);
   117 
   118 val names_of = #names o rep_data;
   119 val fixes_of = #fixes o rep_data;
   120 val binds_of = #binds o rep_data;
   121 val type_occs_of = #type_occs o rep_data;
   122 val constraints_of = #constraints o rep_data;
   123 
   124 val is_declared = Name.is_declared o names_of;
   125 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   126 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   127 
   128 
   129 
   130 (** declarations **)
   131 
   132 (* default sorts and types *)
   133 
   134 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   135 
   136 fun def_type ctxt pattern xi =
   137   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   138     (case Vartab.lookup types xi of
   139       NONE =>
   140         if pattern then NONE
   141         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   142     | some => some)
   143   end;
   144 
   145 val def_sort = Vartab.lookup o #2 o constraints_of;
   146 
   147 
   148 (* names *)
   149 
   150 val declare_type_names = map_names o
   151   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   152 
   153 fun declare_names t =
   154   declare_type_names t #>
   155   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   156 
   157 
   158 (* type occurrences *)
   159 
   160 val declare_type_occs = map_type_occs o fold_term_types
   161   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   162     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   163 
   164 
   165 (* constraints *)
   166 
   167 fun redeclare_skolems ctxt = ctxt |> map_constraints (apfst (fn types =>
   168   let
   169     fun decl (x, x') =
   170       (case default_type ctxt x' of
   171         SOME T => Vartab.update ((x, ~1), T)
   172       | NONE => I);
   173   in fold_rev decl (fixes_of ctxt) types end));
   174 
   175 fun constrain_tvar (xi, S) =
   176   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   177 
   178 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   179   let
   180     val types' = fold_aterms
   181       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   182         | Var v => Vartab.update v
   183         | _ => I) t types;
   184     val sorts' = fold_types (fold_atyps
   185       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   186         | TVar v => constrain_tvar v
   187         | _ => I)) t sorts;
   188   in (types', sorts') end)
   189   #> declare_type_names t
   190   #> redeclare_skolems;
   191 
   192 
   193 (* common declarations *)
   194 
   195 fun declare_internal t =
   196   declare_names t #>
   197   declare_type_occs t;
   198 
   199 fun declare_term t =
   200   declare_internal t #>
   201   declare_constraints t;
   202 
   203 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   204 
   205 val declare_thm = Drule.fold_terms declare_internal;
   206 fun thm_context th = declare_thm th (Context.init_proof (Thm.theory_of_thm th));
   207 
   208 
   209 (* renaming term/type frees *)
   210 
   211 fun variant_frees ctxt ts frees =
   212   let
   213     val names = names_of (fold declare_names ts ctxt);
   214     val xs = fst (Name.variants (map #1 frees) names);
   215   in xs ~~ map snd frees end;
   216 
   217 
   218 
   219 (** term bindings **)
   220 
   221 fun hidden_polymorphism t T =
   222   let
   223     val tvarsT = Term.add_tvarsT T [];
   224     val extra_tvars = Term.fold_types (Term.fold_atyps
   225       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   226   in extra_tvars end;
   227 
   228 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   229   | add_bind ((x, i), SOME t) =
   230       let
   231         val T = Term.fastype_of t;
   232         val t' =
   233           if null (hidden_polymorphism t T) then t
   234           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   235       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   236 
   237 val add_binds = fold add_bind;
   238 
   239 fun expand_binds ctxt =
   240   let
   241     val binds = binds_of ctxt;
   242     fun expand (t as Var (xi, T)) =
   243           (case Vartab.lookup binds xi of
   244             SOME u => Envir.expand_atom T u
   245           | NONE => t)
   246       | expand t = t;
   247   in Envir.beta_norm o Term.map_aterms expand end;
   248 
   249 
   250 
   251 (** fixes **)
   252 
   253 local
   254 
   255 fun no_dups [] = ()
   256   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   257 
   258 fun new_fixes names' xs xs' =
   259   map_names (K names') #>
   260   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   261   fold (declare_constraints o Syntax.free) xs' #>
   262   pair xs';
   263 
   264 in
   265 
   266 fun add_fixes xs ctxt =
   267   let
   268     val _ =
   269       (case filter (can Name.dest_skolem) xs of [] => ()
   270       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   271     val _ = no_dups (duplicates (op =) xs);
   272     val (ys, zs) = split_list (fixes_of ctxt);
   273     val names = names_of ctxt;
   274     val (xs', names') =
   275       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   276       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   277         (xs, fold Name.declare xs names));
   278   in ctxt |> new_fixes names' xs xs' end;
   279 
   280 fun variant_fixes raw_xs ctxt =
   281   let
   282     val names = names_of ctxt;
   283     val xs = map Name.clean raw_xs;
   284     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   285   in ctxt |> new_fixes names' xs xs' end;
   286 
   287 end;
   288 
   289 
   290 fun add_fixes_direct xs ctxt = ctxt
   291   |> set_body false
   292   |> (snd o add_fixes xs)
   293   |> restore_body ctxt;
   294 
   295 fun fix_frees t ctxt = ctxt
   296   |> add_fixes_direct
   297       (rev (fold_aterms (fn Free (x, _) =>
   298         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   299 
   300 fun auto_fixes t ctxt =
   301   (if is_body ctxt then ctxt else fix_frees t ctxt)
   302   |> declare_term t;
   303 
   304 fun invent_types Ss ctxt =
   305   let
   306     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   307     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   308   in (tfrees, ctxt') end;
   309 
   310 
   311 
   312 (** export -- generalize type/term variables **)
   313 
   314 fun export_inst inner outer =
   315   let
   316     val declared_outer = is_declared outer;
   317     val fixes_inner = fixes_of inner;
   318     val fixes_outer = fixes_of outer;
   319 
   320     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   321     val still_fixed = not o member (op =) gen_fixes;
   322     val gen_fixesT =
   323       Symtab.fold (fn (a, xs) =>
   324         if declared_outer a orelse exists still_fixed xs
   325         then I else cons a) (type_occs_of inner) [];
   326   in (gen_fixesT, gen_fixes) end;
   327 
   328 fun exportT_inst inner outer = #1 (export_inst inner outer);
   329 
   330 fun exportT_terms inner outer ts =
   331   map (TermSubst.generalize (exportT_inst (fold declare_type_occs ts inner) outer, [])
   332     (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1)) ts;
   333 
   334 fun export_terms inner outer ts =
   335   map (TermSubst.generalize (export_inst (fold declare_type_occs ts inner) outer)
   336     (fold Term.maxidx_term ts ~1 + 1)) ts;
   337 
   338 fun export_prf inner outer prf =
   339   let
   340     val insts = export_inst (declare_prf prf inner) outer;
   341     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   342     val gen_term = TermSubst.generalize_option insts idx;
   343     val gen_typ = TermSubst.generalizeT_option (#1 insts) idx;
   344   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   345 
   346 fun gen_export inst inner outer ths =
   347   let
   348     val inner' = fold (declare_type_occs o Thm.full_prop_of) ths inner;
   349   in map (Thm.generalize (inst inner' outer) (fold Thm.maxidx_thm ths ~1 + 1)) ths end;
   350 
   351 val exportT = gen_export (rpair [] oo exportT_inst);
   352 val export = gen_export export_inst;
   353 
   354 
   355 
   356 (** import -- fix schematic type/term variables **)
   357 
   358 fun importT_inst ts ctxt =
   359   let
   360     val tvars = rev (fold Term.add_tvars ts []);
   361     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   362   in (tvars ~~ map TFree tfrees, ctxt') end;
   363 
   364 fun import_inst is_open ts ctxt =
   365   let
   366     val ren = if is_open then I else Name.internal;
   367     val (instT, ctxt') = importT_inst ts ctxt;
   368     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   369     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   370     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   371   in ((instT, inst), ctxt'') end;
   372 
   373 fun importT_terms ts ctxt =
   374   let val (instT, ctxt') = importT_inst ts ctxt
   375   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   376 
   377 fun import_terms is_open ts ctxt =
   378   let val (inst, ctxt') = import_inst is_open ts ctxt
   379   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   380 
   381 fun importT ths ctxt =
   382   let
   383     val thy = Context.theory_of_proof ctxt;
   384     val certT = Thm.ctyp_of thy;
   385     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   386     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   387     val ths' = map (Thm.instantiate (instT', [])) ths;
   388   in ((map #2 instT', ths'), ctxt') end;
   389 
   390 fun import_prf is_open prf ctxt =
   391   let
   392     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   393     val (insts, ctxt') = import_inst is_open ts ctxt;
   394   in (Proofterm.instantiate insts prf, ctxt') end;
   395 
   396 fun import is_open ths ctxt =
   397   let
   398     val thy = Context.theory_of_proof ctxt;
   399     val cert = Thm.cterm_of thy;
   400     val certT = Thm.ctyp_of thy;
   401     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   402     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   403     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   404     val ths' = map (Thm.instantiate (instT', inst')) ths;
   405   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   406 
   407 
   408 (* import/export *)
   409 
   410 fun gen_trade imp exp f ctxt ths =
   411   let val ((_, ths'), ctxt') = imp ths ctxt
   412   in exp ctxt' ctxt (f ctxt' ths') end;
   413 
   414 val tradeT = gen_trade importT exportT;
   415 val trade = gen_trade (import true) export;
   416 
   417 
   418 (* focus on outermost parameters *)
   419 
   420 fun forall_elim_prop t prop =
   421   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   422   |> Thm.cprop_of |> Thm.dest_arg;
   423 
   424 fun focus goal ctxt =
   425   let
   426     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   427     val t = Thm.term_of goal;
   428     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   429     val (xs, Ts) = split_list ps;
   430     val (xs', ctxt') = variant_fixes xs ctxt;
   431     val ps' = ListPair.map (cert o Free) (xs', Ts);
   432     val goal' = fold forall_elim_prop ps' goal;
   433   in ((ps', goal'), ctxt') end;
   434 
   435 fun focus_subgoal i st =
   436   let
   437     val all_vars = Drule.fold_terms Term.add_vars st [];
   438     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   439   in
   440     add_binds no_binds #>
   441     fold (declare_constraints o Var) all_vars #>
   442     focus (Thm.cprem_of st i)
   443   end;
   444 
   445 
   446 
   447 (** implicit polymorphism **)
   448 
   449 (* warn_extra_tfrees *)
   450 
   451 fun warn_extra_tfrees ctxt1 ctxt2 =
   452   let
   453     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   454     fun occs_free a x =
   455       (case def_type ctxt1 false (x, ~1) of
   456         SOME T => if occs_typ a T then I else cons (a, x)
   457       | NONE => cons (a, x));
   458 
   459     val occs1 = type_occs_of ctxt1;
   460     val occs2 = type_occs_of ctxt2;
   461     val extras = Symtab.fold (fn (a, xs) =>
   462       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   463     val tfrees = map #1 extras |> sort_distinct string_ord;
   464     val frees = map #2 extras |> sort_distinct string_ord;
   465   in
   466     if null extras then ()
   467     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   468       space_implode " or " (map quote frees))
   469   end;
   470 
   471 
   472 (* polymorphic terms *)
   473 
   474 fun polymorphic ctxt ts =
   475   let
   476     val ctxt' = fold declare_term ts ctxt;
   477     val occs = type_occs_of ctxt;
   478     val occs' = type_occs_of ctxt';
   479     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   480     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   481   in map (TermSubst.generalize (types, []) idx) ts end;
   482 
   483 end;