src/HOL/Limits.thy
author haftmann
Sun Sep 21 16:56:11 2014 +0200 (2014-09-21)
changeset 58410 6d46ad54a2ab
parent 57512 cc97b347b301
child 58729 e8ecc79aee43
permissions -rw-r--r--
explicit separation of signed and unsigned numerals using existing lexical categories num and xnum
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 header {* Limits on Real Vector Spaces *}
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection {* Filter going to infinity norm *}
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 lemma at_infinity_eq_at_top_bot:
    25   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    26   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    27                    eventually_at_top_linorder eventually_at_bot_linorder)
    28   apply safe
    29   apply (rule_tac x="b" in exI, simp)
    30   apply (rule_tac x="- b" in exI, simp)
    31   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    32   done
    33 
    34 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    35   unfolding at_infinity_eq_at_top_bot by simp
    36 
    37 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    38   unfolding at_infinity_eq_at_top_bot by simp
    39 
    40 lemma filterlim_at_top_imp_at_infinity:
    41   fixes f :: "_ \<Rightarrow> real"
    42   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    43   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    44 
    45 subsubsection {* Boundedness *}
    46 
    47 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    48   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    49 
    50 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    51   "Bseq X \<equiv> Bfun X sequentially"
    52 
    53 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    54 
    55 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    56   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    57 
    58 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    59   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    60 
    61 lemma Bfun_def:
    62   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    63   unfolding Bfun_metric_def norm_conv_dist
    64 proof safe
    65   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    66   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    67     by (intro always_eventually) (metis dist_commute dist_triangle)
    68   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    69     by eventually_elim auto
    70   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    71     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    72 qed auto
    73 
    74 lemma BfunI:
    75   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    76 unfolding Bfun_def
    77 proof (intro exI conjI allI)
    78   show "0 < max K 1" by simp
    79 next
    80   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    81     using K by (rule eventually_elim1, simp)
    82 qed
    83 
    84 lemma BfunE:
    85   assumes "Bfun f F"
    86   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    87 using assms unfolding Bfun_def by fast
    88 
    89 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
    90   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
    91   apply (erule_tac x=1 in allE)
    92   apply simp
    93   apply safe
    94   apply (rule_tac x="X M" in exI)
    95   apply (rule_tac x=1 in exI)
    96   apply (erule_tac x=M in allE)
    97   apply simp
    98   apply (rule_tac x=M in exI)
    99   apply (auto simp: dist_commute)
   100   done
   101 
   102 
   103 subsubsection {* Bounded Sequences *}
   104 
   105 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   106   by (intro BfunI) (auto simp: eventually_sequentially)
   107 
   108 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   109   by (intro BfunI) (auto simp: eventually_sequentially)
   110 
   111 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   112   unfolding Bfun_def eventually_sequentially
   113 proof safe
   114   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   115   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   116     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   117        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   118 qed auto
   119 
   120 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   121 unfolding Bseq_def by auto
   122 
   123 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   124 by (simp add: Bseq_def)
   125 
   126 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   127 by (auto simp add: Bseq_def)
   128 
   129 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   130 proof (elim BseqE, intro bdd_aboveI2)
   131   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   132     by (auto elim!: allE[of _ n])
   133 qed
   134 
   135 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   136 proof (elim BseqE, intro bdd_belowI2)
   137   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   138     by (auto elim!: allE[of _ n])
   139 qed
   140 
   141 lemma lemma_NBseq_def:
   142   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   143 proof safe
   144   fix K :: real
   145   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   146   then have "K \<le> real (Suc n)" by auto
   147   moreover assume "\<forall>m. norm (X m) \<le> K"
   148   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   149     by (blast intro: order_trans)
   150   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   151 qed (force simp add: real_of_nat_Suc)
   152 
   153 text{* alternative definition for Bseq *}
   154 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   155 apply (simp add: Bseq_def)
   156 apply (simp (no_asm) add: lemma_NBseq_def)
   157 done
   158 
   159 lemma lemma_NBseq_def2:
   160      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   161 apply (subst lemma_NBseq_def, auto)
   162 apply (rule_tac x = "Suc N" in exI)
   163 apply (rule_tac [2] x = N in exI)
   164 apply (auto simp add: real_of_nat_Suc)
   165  prefer 2 apply (blast intro: order_less_imp_le)
   166 apply (drule_tac x = n in spec, simp)
   167 done
   168 
   169 (* yet another definition for Bseq *)
   170 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   171 by (simp add: Bseq_def lemma_NBseq_def2)
   172 
   173 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   174 
   175 text{*alternative formulation for boundedness*}
   176 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   177 apply (unfold Bseq_def, safe)
   178 apply (rule_tac [2] x = "k + norm x" in exI)
   179 apply (rule_tac x = K in exI, simp)
   180 apply (rule exI [where x = 0], auto)
   181 apply (erule order_less_le_trans, simp)
   182 apply (drule_tac x=n in spec)
   183 apply (drule order_trans [OF norm_triangle_ineq2])
   184 apply simp
   185 done
   186 
   187 text{*alternative formulation for boundedness*}
   188 lemma Bseq_iff3:
   189   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   190 proof
   191   assume ?P
   192   then obtain K
   193     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   194   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   195   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   196     by (auto intro: order_trans norm_triangle_ineq4)
   197   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   198     by simp
   199   with `0 < K + norm (X 0)` show ?Q by blast
   200 next
   201   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   202 qed
   203 
   204 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   205 apply (simp add: Bseq_def)
   206 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   207 apply (drule_tac x = n in spec, arith)
   208 done
   209 
   210 
   211 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   212 
   213 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   214   by (simp add: Bseq_def)
   215 
   216 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   217   apply (simp add: subset_eq)
   218   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   219   apply (erule_tac x=n in allE)
   220   apply auto
   221   done
   222 
   223 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   224   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   225 
   226 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   227   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   228 
   229 subsection {* Bounded Monotonic Sequences *}
   230 
   231 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   232 
   233 (* TODO: delete *)
   234 (* FIXME: one use in NSA/HSEQ.thy *)
   235 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   236   apply (rule_tac x="X m" in exI)
   237   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   238   unfolding eventually_sequentially
   239   apply blast
   240   done
   241 
   242 subsection {* Convergence to Zero *}
   243 
   244 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   245   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   246 
   247 lemma ZfunI:
   248   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   249   unfolding Zfun_def by simp
   250 
   251 lemma ZfunD:
   252   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   253   unfolding Zfun_def by simp
   254 
   255 lemma Zfun_ssubst:
   256   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   257   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   258 
   259 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   260   unfolding Zfun_def by simp
   261 
   262 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   263   unfolding Zfun_def by simp
   264 
   265 lemma Zfun_imp_Zfun:
   266   assumes f: "Zfun f F"
   267   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   268   shows "Zfun (\<lambda>x. g x) F"
   269 proof (cases)
   270   assume K: "0 < K"
   271   show ?thesis
   272   proof (rule ZfunI)
   273     fix r::real assume "0 < r"
   274     hence "0 < r / K" using K by simp
   275     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   276       using ZfunD [OF f] by fast
   277     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   278     proof eventually_elim
   279       case (elim x)
   280       hence "norm (f x) * K < r"
   281         by (simp add: pos_less_divide_eq K)
   282       thus ?case
   283         by (simp add: order_le_less_trans [OF elim(1)])
   284     qed
   285   qed
   286 next
   287   assume "\<not> 0 < K"
   288   hence K: "K \<le> 0" by (simp only: not_less)
   289   show ?thesis
   290   proof (rule ZfunI)
   291     fix r :: real
   292     assume "0 < r"
   293     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   294     proof eventually_elim
   295       case (elim x)
   296       also have "norm (f x) * K \<le> norm (f x) * 0"
   297         using K norm_ge_zero by (rule mult_left_mono)
   298       finally show ?case
   299         using `0 < r` by simp
   300     qed
   301   qed
   302 qed
   303 
   304 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   305   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   306 
   307 lemma Zfun_add:
   308   assumes f: "Zfun f F" and g: "Zfun g F"
   309   shows "Zfun (\<lambda>x. f x + g x) F"
   310 proof (rule ZfunI)
   311   fix r::real assume "0 < r"
   312   hence r: "0 < r / 2" by simp
   313   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   314     using f r by (rule ZfunD)
   315   moreover
   316   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   317     using g r by (rule ZfunD)
   318   ultimately
   319   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   320   proof eventually_elim
   321     case (elim x)
   322     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   323       by (rule norm_triangle_ineq)
   324     also have "\<dots> < r/2 + r/2"
   325       using elim by (rule add_strict_mono)
   326     finally show ?case
   327       by simp
   328   qed
   329 qed
   330 
   331 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   332   unfolding Zfun_def by simp
   333 
   334 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   335   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   336 
   337 lemma (in bounded_linear) Zfun:
   338   assumes g: "Zfun g F"
   339   shows "Zfun (\<lambda>x. f (g x)) F"
   340 proof -
   341   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   342     using bounded by fast
   343   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   344     by simp
   345   with g show ?thesis
   346     by (rule Zfun_imp_Zfun)
   347 qed
   348 
   349 lemma (in bounded_bilinear) Zfun:
   350   assumes f: "Zfun f F"
   351   assumes g: "Zfun g F"
   352   shows "Zfun (\<lambda>x. f x ** g x) F"
   353 proof (rule ZfunI)
   354   fix r::real assume r: "0 < r"
   355   obtain K where K: "0 < K"
   356     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   357     using pos_bounded by fast
   358   from K have K': "0 < inverse K"
   359     by (rule positive_imp_inverse_positive)
   360   have "eventually (\<lambda>x. norm (f x) < r) F"
   361     using f r by (rule ZfunD)
   362   moreover
   363   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   364     using g K' by (rule ZfunD)
   365   ultimately
   366   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   367   proof eventually_elim
   368     case (elim x)
   369     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   370       by (rule norm_le)
   371     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   372       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   373     also from K have "r * inverse K * K = r"
   374       by simp
   375     finally show ?case .
   376   qed
   377 qed
   378 
   379 lemma (in bounded_bilinear) Zfun_left:
   380   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   381   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   382 
   383 lemma (in bounded_bilinear) Zfun_right:
   384   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   385   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   386 
   387 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   388 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   389 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   390 
   391 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   392   by (simp only: tendsto_iff Zfun_def dist_norm)
   393 
   394 lemma tendsto_0_le: "\<lbrakk>(f ---> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk> 
   395                      \<Longrightarrow> (g ---> 0) F"
   396   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   397 
   398 subsubsection {* Distance and norms *}
   399 
   400 lemma tendsto_dist [tendsto_intros]:
   401   fixes l m :: "'a :: metric_space"
   402   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   403   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   404 proof (rule tendstoI)
   405   fix e :: real assume "0 < e"
   406   hence e2: "0 < e/2" by simp
   407   from tendstoD [OF f e2] tendstoD [OF g e2]
   408   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   409   proof (eventually_elim)
   410     case (elim x)
   411     then show "dist (dist (f x) (g x)) (dist l m) < e"
   412       unfolding dist_real_def
   413       using dist_triangle2 [of "f x" "g x" "l"]
   414       using dist_triangle2 [of "g x" "l" "m"]
   415       using dist_triangle3 [of "l" "m" "f x"]
   416       using dist_triangle [of "f x" "m" "g x"]
   417       by arith
   418   qed
   419 qed
   420 
   421 lemma continuous_dist[continuous_intros]:
   422   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   423   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   424   unfolding continuous_def by (rule tendsto_dist)
   425 
   426 lemma continuous_on_dist[continuous_intros]:
   427   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   428   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   429   unfolding continuous_on_def by (auto intro: tendsto_dist)
   430 
   431 lemma tendsto_norm [tendsto_intros]:
   432   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   433   unfolding norm_conv_dist by (intro tendsto_intros)
   434 
   435 lemma continuous_norm [continuous_intros]:
   436   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   437   unfolding continuous_def by (rule tendsto_norm)
   438 
   439 lemma continuous_on_norm [continuous_intros]:
   440   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   441   unfolding continuous_on_def by (auto intro: tendsto_norm)
   442 
   443 lemma tendsto_norm_zero:
   444   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   445   by (drule tendsto_norm, simp)
   446 
   447 lemma tendsto_norm_zero_cancel:
   448   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   449   unfolding tendsto_iff dist_norm by simp
   450 
   451 lemma tendsto_norm_zero_iff:
   452   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   453   unfolding tendsto_iff dist_norm by simp
   454 
   455 lemma tendsto_rabs [tendsto_intros]:
   456   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   457   by (fold real_norm_def, rule tendsto_norm)
   458 
   459 lemma continuous_rabs [continuous_intros]:
   460   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   461   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   462 
   463 lemma continuous_on_rabs [continuous_intros]:
   464   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   465   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   466 
   467 lemma tendsto_rabs_zero:
   468   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   469   by (fold real_norm_def, rule tendsto_norm_zero)
   470 
   471 lemma tendsto_rabs_zero_cancel:
   472   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   473   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   474 
   475 lemma tendsto_rabs_zero_iff:
   476   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   477   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   478 
   479 subsubsection {* Addition and subtraction *}
   480 
   481 lemma tendsto_add [tendsto_intros]:
   482   fixes a b :: "'a::real_normed_vector"
   483   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   484   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   485 
   486 lemma continuous_add [continuous_intros]:
   487   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   488   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   489   unfolding continuous_def by (rule tendsto_add)
   490 
   491 lemma continuous_on_add [continuous_intros]:
   492   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   493   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   494   unfolding continuous_on_def by (auto intro: tendsto_add)
   495 
   496 lemma tendsto_add_zero:
   497   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   498   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   499   by (drule (1) tendsto_add, simp)
   500 
   501 lemma tendsto_minus [tendsto_intros]:
   502   fixes a :: "'a::real_normed_vector"
   503   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   504   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   505 
   506 lemma continuous_minus [continuous_intros]:
   507   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   508   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   509   unfolding continuous_def by (rule tendsto_minus)
   510 
   511 lemma continuous_on_minus [continuous_intros]:
   512   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   513   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   514   unfolding continuous_on_def by (auto intro: tendsto_minus)
   515 
   516 lemma tendsto_minus_cancel:
   517   fixes a :: "'a::real_normed_vector"
   518   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   519   by (drule tendsto_minus, simp)
   520 
   521 lemma tendsto_minus_cancel_left:
   522     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   523   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   524   by auto
   525 
   526 lemma tendsto_diff [tendsto_intros]:
   527   fixes a b :: "'a::real_normed_vector"
   528   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   529   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   530 
   531 lemma continuous_diff [continuous_intros]:
   532   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   533   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   534   unfolding continuous_def by (rule tendsto_diff)
   535 
   536 lemma continuous_on_diff [continuous_intros]:
   537   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   538   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   539   unfolding continuous_on_def by (auto intro: tendsto_diff)
   540 
   541 lemma tendsto_setsum [tendsto_intros]:
   542   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   543   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   544   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   545 proof (cases "finite S")
   546   assume "finite S" thus ?thesis using assms
   547     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   548 next
   549   assume "\<not> finite S" thus ?thesis
   550     by (simp add: tendsto_const)
   551 qed
   552 
   553 lemma continuous_setsum [continuous_intros]:
   554   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   555   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   556   unfolding continuous_def by (rule tendsto_setsum)
   557 
   558 lemma continuous_on_setsum [continuous_intros]:
   559   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   560   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   561   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   562 
   563 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   564 
   565 subsubsection {* Linear operators and multiplication *}
   566 
   567 lemma (in bounded_linear) tendsto:
   568   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   569   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   570 
   571 lemma (in bounded_linear) continuous:
   572   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   573   using tendsto[of g _ F] by (auto simp: continuous_def)
   574 
   575 lemma (in bounded_linear) continuous_on:
   576   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   577   using tendsto[of g] by (auto simp: continuous_on_def)
   578 
   579 lemma (in bounded_linear) tendsto_zero:
   580   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   581   by (drule tendsto, simp only: zero)
   582 
   583 lemma (in bounded_bilinear) tendsto:
   584   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   585   by (simp only: tendsto_Zfun_iff prod_diff_prod
   586                  Zfun_add Zfun Zfun_left Zfun_right)
   587 
   588 lemma (in bounded_bilinear) continuous:
   589   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   590   using tendsto[of f _ F g] by (auto simp: continuous_def)
   591 
   592 lemma (in bounded_bilinear) continuous_on:
   593   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   594   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   595 
   596 lemma (in bounded_bilinear) tendsto_zero:
   597   assumes f: "(f ---> 0) F"
   598   assumes g: "(g ---> 0) F"
   599   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   600   using tendsto [OF f g] by (simp add: zero_left)
   601 
   602 lemma (in bounded_bilinear) tendsto_left_zero:
   603   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   604   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   605 
   606 lemma (in bounded_bilinear) tendsto_right_zero:
   607   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   608   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   609 
   610 lemmas tendsto_of_real [tendsto_intros] =
   611   bounded_linear.tendsto [OF bounded_linear_of_real]
   612 
   613 lemmas tendsto_scaleR [tendsto_intros] =
   614   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   615 
   616 lemmas tendsto_mult [tendsto_intros] =
   617   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   618 
   619 lemmas continuous_of_real [continuous_intros] =
   620   bounded_linear.continuous [OF bounded_linear_of_real]
   621 
   622 lemmas continuous_scaleR [continuous_intros] =
   623   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   624 
   625 lemmas continuous_mult [continuous_intros] =
   626   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   627 
   628 lemmas continuous_on_of_real [continuous_intros] =
   629   bounded_linear.continuous_on [OF bounded_linear_of_real]
   630 
   631 lemmas continuous_on_scaleR [continuous_intros] =
   632   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   633 
   634 lemmas continuous_on_mult [continuous_intros] =
   635   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   636 
   637 lemmas tendsto_mult_zero =
   638   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   639 
   640 lemmas tendsto_mult_left_zero =
   641   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   642 
   643 lemmas tendsto_mult_right_zero =
   644   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   645 
   646 lemma tendsto_power [tendsto_intros]:
   647   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   648   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   649   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   650 
   651 lemma continuous_power [continuous_intros]:
   652   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   653   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   654   unfolding continuous_def by (rule tendsto_power)
   655 
   656 lemma continuous_on_power [continuous_intros]:
   657   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   658   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   659   unfolding continuous_on_def by (auto intro: tendsto_power)
   660 
   661 lemma tendsto_setprod [tendsto_intros]:
   662   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   663   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   664   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   665 proof (cases "finite S")
   666   assume "finite S" thus ?thesis using assms
   667     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   668 next
   669   assume "\<not> finite S" thus ?thesis
   670     by (simp add: tendsto_const)
   671 qed
   672 
   673 lemma continuous_setprod [continuous_intros]:
   674   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   675   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   676   unfolding continuous_def by (rule tendsto_setprod)
   677 
   678 lemma continuous_on_setprod [continuous_intros]:
   679   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   680   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   681   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   682 
   683 subsubsection {* Inverse and division *}
   684 
   685 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   686   assumes f: "Zfun f F"
   687   assumes g: "Bfun g F"
   688   shows "Zfun (\<lambda>x. f x ** g x) F"
   689 proof -
   690   obtain K where K: "0 \<le> K"
   691     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   692     using nonneg_bounded by fast
   693   obtain B where B: "0 < B"
   694     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   695     using g by (rule BfunE)
   696   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   697   using norm_g proof eventually_elim
   698     case (elim x)
   699     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   700       by (rule norm_le)
   701     also have "\<dots> \<le> norm (f x) * B * K"
   702       by (intro mult_mono' order_refl norm_g norm_ge_zero
   703                 mult_nonneg_nonneg K elim)
   704     also have "\<dots> = norm (f x) * (B * K)"
   705       by (rule mult.assoc)
   706     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   707   qed
   708   with f show ?thesis
   709     by (rule Zfun_imp_Zfun)
   710 qed
   711 
   712 lemma (in bounded_bilinear) flip:
   713   "bounded_bilinear (\<lambda>x y. y ** x)"
   714   apply default
   715   apply (rule add_right)
   716   apply (rule add_left)
   717   apply (rule scaleR_right)
   718   apply (rule scaleR_left)
   719   apply (subst mult.commute)
   720   using bounded by fast
   721 
   722 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   723   assumes f: "Bfun f F"
   724   assumes g: "Zfun g F"
   725   shows "Zfun (\<lambda>x. f x ** g x) F"
   726   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   727 
   728 lemma Bfun_inverse_lemma:
   729   fixes x :: "'a::real_normed_div_algebra"
   730   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   731   apply (subst nonzero_norm_inverse, clarsimp)
   732   apply (erule (1) le_imp_inverse_le)
   733   done
   734 
   735 lemma Bfun_inverse:
   736   fixes a :: "'a::real_normed_div_algebra"
   737   assumes f: "(f ---> a) F"
   738   assumes a: "a \<noteq> 0"
   739   shows "Bfun (\<lambda>x. inverse (f x)) F"
   740 proof -
   741   from a have "0 < norm a" by simp
   742   hence "\<exists>r>0. r < norm a" by (rule dense)
   743   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   744   have "eventually (\<lambda>x. dist (f x) a < r) F"
   745     using tendstoD [OF f r1] by fast
   746   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   747   proof eventually_elim
   748     case (elim x)
   749     hence 1: "norm (f x - a) < r"
   750       by (simp add: dist_norm)
   751     hence 2: "f x \<noteq> 0" using r2 by auto
   752     hence "norm (inverse (f x)) = inverse (norm (f x))"
   753       by (rule nonzero_norm_inverse)
   754     also have "\<dots> \<le> inverse (norm a - r)"
   755     proof (rule le_imp_inverse_le)
   756       show "0 < norm a - r" using r2 by simp
   757     next
   758       have "norm a - norm (f x) \<le> norm (a - f x)"
   759         by (rule norm_triangle_ineq2)
   760       also have "\<dots> = norm (f x - a)"
   761         by (rule norm_minus_commute)
   762       also have "\<dots> < r" using 1 .
   763       finally show "norm a - r \<le> norm (f x)" by simp
   764     qed
   765     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   766   qed
   767   thus ?thesis by (rule BfunI)
   768 qed
   769 
   770 lemma tendsto_inverse [tendsto_intros]:
   771   fixes a :: "'a::real_normed_div_algebra"
   772   assumes f: "(f ---> a) F"
   773   assumes a: "a \<noteq> 0"
   774   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   775 proof -
   776   from a have "0 < norm a" by simp
   777   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   778     by (rule tendstoD)
   779   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   780     unfolding dist_norm by (auto elim!: eventually_elim1)
   781   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   782     - (inverse (f x) * (f x - a) * inverse a)) F"
   783     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   784   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   785     by (intro Zfun_minus Zfun_mult_left
   786       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   787       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   788   ultimately show ?thesis
   789     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   790 qed
   791 
   792 lemma continuous_inverse:
   793   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   794   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   795   shows "continuous F (\<lambda>x. inverse (f x))"
   796   using assms unfolding continuous_def by (rule tendsto_inverse)
   797 
   798 lemma continuous_at_within_inverse[continuous_intros]:
   799   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   800   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   801   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   802   using assms unfolding continuous_within by (rule tendsto_inverse)
   803 
   804 lemma isCont_inverse[continuous_intros, simp]:
   805   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   806   assumes "isCont f a" and "f a \<noteq> 0"
   807   shows "isCont (\<lambda>x. inverse (f x)) a"
   808   using assms unfolding continuous_at by (rule tendsto_inverse)
   809 
   810 lemma continuous_on_inverse[continuous_intros]:
   811   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   812   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   813   shows "continuous_on s (\<lambda>x. inverse (f x))"
   814   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   815 
   816 lemma tendsto_divide [tendsto_intros]:
   817   fixes a b :: "'a::real_normed_field"
   818   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   819     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   820   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   821 
   822 lemma continuous_divide:
   823   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   824   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   825   shows "continuous F (\<lambda>x. (f x) / (g x))"
   826   using assms unfolding continuous_def by (rule tendsto_divide)
   827 
   828 lemma continuous_at_within_divide[continuous_intros]:
   829   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   830   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   831   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   832   using assms unfolding continuous_within by (rule tendsto_divide)
   833 
   834 lemma isCont_divide[continuous_intros, simp]:
   835   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   836   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   837   shows "isCont (\<lambda>x. (f x) / g x) a"
   838   using assms unfolding continuous_at by (rule tendsto_divide)
   839 
   840 lemma continuous_on_divide[continuous_intros]:
   841   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   842   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   843   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   844   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   845 
   846 lemma tendsto_sgn [tendsto_intros]:
   847   fixes l :: "'a::real_normed_vector"
   848   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   849   unfolding sgn_div_norm by (simp add: tendsto_intros)
   850 
   851 lemma continuous_sgn:
   852   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   853   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   854   shows "continuous F (\<lambda>x. sgn (f x))"
   855   using assms unfolding continuous_def by (rule tendsto_sgn)
   856 
   857 lemma continuous_at_within_sgn[continuous_intros]:
   858   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   859   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   860   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   861   using assms unfolding continuous_within by (rule tendsto_sgn)
   862 
   863 lemma isCont_sgn[continuous_intros]:
   864   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   865   assumes "isCont f a" and "f a \<noteq> 0"
   866   shows "isCont (\<lambda>x. sgn (f x)) a"
   867   using assms unfolding continuous_at by (rule tendsto_sgn)
   868 
   869 lemma continuous_on_sgn[continuous_intros]:
   870   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   871   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   872   shows "continuous_on s (\<lambda>x. sgn (f x))"
   873   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   874 
   875 lemma filterlim_at_infinity:
   876   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   877   assumes "0 \<le> c"
   878   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   879   unfolding filterlim_iff eventually_at_infinity
   880 proof safe
   881   fix P :: "'a \<Rightarrow> bool" and b
   882   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   883     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   884   have "max b (c + 1) > c" by auto
   885   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   886     by auto
   887   then show "eventually (\<lambda>x. P (f x)) F"
   888   proof eventually_elim
   889     fix x assume "max b (c + 1) \<le> norm (f x)"
   890     with P show "P (f x)" by auto
   891   qed
   892 qed force
   893 
   894 
   895 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   896 
   897 text {*
   898 
   899 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   900 @{term "at_right x"} and also @{term "at_right 0"}.
   901 
   902 *}
   903 
   904 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   905 
   906 lemma filtermap_homeomorph:
   907   assumes f: "continuous (at a) f"
   908   assumes g: "continuous (at (f a)) g"
   909   assumes bij1: "\<forall>x. f (g x) = x" and bij2: "\<forall>x. g (f x) = x"
   910   shows "filtermap f (nhds a) = nhds (f a)"
   911   unfolding filter_eq_iff eventually_filtermap eventually_nhds
   912 proof safe
   913   fix P S assume S: "open S" "f a \<in> S" and P: "\<forall>x\<in>S. P x"
   914   from continuous_within_topological[THEN iffD1, rule_format, OF f S] P
   915   show "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P (f x))" by auto
   916 next
   917   fix P S assume S: "open S" "a \<in> S" and P: "\<forall>x\<in>S. P (f x)"
   918   with continuous_within_topological[THEN iffD1, rule_format, OF g, of S] bij2
   919   obtain A where "open A" "f a \<in> A" "(\<forall>y\<in>A. g y \<in> S)"
   920     by (metis UNIV_I)
   921   with P bij1 show "\<exists>S. open S \<and> f a \<in> S \<and> (\<forall>x\<in>S. P x)"
   922     by (force intro!: exI[of _ A])
   923 qed
   924 
   925 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   926   by (rule filtermap_homeomorph[where g="\<lambda>x. x + d"]) (auto intro: continuous_intros)
   927 
   928 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   929   by (rule filtermap_homeomorph[where g=uminus]) (auto intro: continuous_minus)
   930 
   931 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   932   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   933 
   934 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   935   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   936 
   937 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   938   using filtermap_at_right_shift[of "-a" 0] by simp
   939 
   940 lemma filterlim_at_right_to_0:
   941   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   942   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   943 
   944 lemma eventually_at_right_to_0:
   945   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   946   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   947 
   948 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   949   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   950 
   951 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   952   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   953 
   954 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   955   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   956 
   957 lemma filterlim_at_left_to_right:
   958   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   959   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   960 
   961 lemma eventually_at_left_to_right:
   962   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   963   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   964 
   965 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   966   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   967   by (metis le_minus_iff minus_minus)
   968 
   969 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   970   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   971 
   972 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   973   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   974 
   975 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   976   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   977 
   978 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   979   unfolding filterlim_at_top eventually_at_bot_dense
   980   by (metis leI minus_less_iff order_less_asym)
   981 
   982 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   983   unfolding filterlim_at_bot eventually_at_top_dense
   984   by (metis leI less_minus_iff order_less_asym)
   985 
   986 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   987   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   988   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   989   by auto
   990 
   991 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   992   unfolding filterlim_uminus_at_top by simp
   993 
   994 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   995   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
   996 proof safe
   997   fix Z :: real assume [arith]: "0 < Z"
   998   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   999     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1000   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1001     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1002 qed
  1003 
  1004 lemma filterlim_inverse_at_top:
  1005   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1006   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1007      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1008 
  1009 lemma filterlim_inverse_at_bot_neg:
  1010   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1011   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1012 
  1013 lemma filterlim_inverse_at_bot:
  1014   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1015   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1016   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1017 
  1018 lemma tendsto_inverse_0:
  1019   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1020   shows "(inverse ---> (0::'a)) at_infinity"
  1021   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1022 proof safe
  1023   fix r :: real assume "0 < r"
  1024   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1025   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1026     fix x :: 'a
  1027     from `0 < r` have "0 < inverse (r / 2)" by simp
  1028     also assume *: "inverse (r / 2) \<le> norm x"
  1029     finally show "norm (inverse x) < r"
  1030       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1031   qed
  1032 qed
  1033 
  1034 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1035 proof (rule antisym)
  1036   have "(inverse ---> (0::real)) at_top"
  1037     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1038   then show "filtermap inverse at_top \<le> at_right (0::real)"
  1039     by (simp add: le_principal eventually_filtermap eventually_gt_at_top filterlim_def at_within_def)
  1040 next
  1041   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
  1042     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
  1043   then show "at_right (0::real) \<le> filtermap inverse at_top"
  1044     by (simp add: filtermap_ident filtermap_filtermap)
  1045 qed
  1046 
  1047 lemma eventually_at_right_to_top:
  1048   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1049   unfolding at_right_to_top eventually_filtermap ..
  1050 
  1051 lemma filterlim_at_right_to_top:
  1052   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1053   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1054 
  1055 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1056   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1057 
  1058 lemma eventually_at_top_to_right:
  1059   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1060   unfolding at_top_to_right eventually_filtermap ..
  1061 
  1062 lemma filterlim_at_top_to_right:
  1063   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1064   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1065 
  1066 lemma filterlim_inverse_at_infinity:
  1067   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1068   shows "filterlim inverse at_infinity (at (0::'a))"
  1069   unfolding filterlim_at_infinity[OF order_refl]
  1070 proof safe
  1071   fix r :: real assume "0 < r"
  1072   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1073     unfolding eventually_at norm_inverse
  1074     by (intro exI[of _ "inverse r"])
  1075        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1076 qed
  1077 
  1078 lemma filterlim_inverse_at_iff:
  1079   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1080   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1081   unfolding filterlim_def filtermap_filtermap[symmetric]
  1082 proof
  1083   assume "filtermap g F \<le> at_infinity"
  1084   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1085     by (rule filtermap_mono)
  1086   also have "\<dots> \<le> at 0"
  1087     using tendsto_inverse_0[where 'a='b]
  1088     by (auto intro!: exI[of _ 1]
  1089              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1090   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1091 next
  1092   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1093   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1094     by (rule filtermap_mono)
  1095   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1096     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1097 qed
  1098 
  1099 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1100  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1101 
  1102 text {*
  1103 
  1104 We only show rules for multiplication and addition when the functions are either against a real
  1105 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1106 
  1107 *}
  1108 
  1109 lemma filterlim_tendsto_pos_mult_at_top: 
  1110   assumes f: "(f ---> c) F" and c: "0 < c"
  1111   assumes g: "LIM x F. g x :> at_top"
  1112   shows "LIM x F. (f x * g x :: real) :> at_top"
  1113   unfolding filterlim_at_top_gt[where c=0]
  1114 proof safe
  1115   fix Z :: real assume "0 < Z"
  1116   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1117     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1118              simp: dist_real_def abs_real_def split: split_if_asm)
  1119   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1120     unfolding filterlim_at_top by auto
  1121   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1122   proof eventually_elim
  1123     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1124     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1125       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1126     with `0 < c` show "Z \<le> f x * g x"
  1127        by simp
  1128   qed
  1129 qed
  1130 
  1131 lemma filterlim_at_top_mult_at_top: 
  1132   assumes f: "LIM x F. f x :> at_top"
  1133   assumes g: "LIM x F. g x :> at_top"
  1134   shows "LIM x F. (f x * g x :: real) :> at_top"
  1135   unfolding filterlim_at_top_gt[where c=0]
  1136 proof safe
  1137   fix Z :: real assume "0 < Z"
  1138   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1139     unfolding filterlim_at_top by auto
  1140   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1141     unfolding filterlim_at_top by auto
  1142   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1143   proof eventually_elim
  1144     fix x assume "1 \<le> f x" "Z \<le> g x"
  1145     with `0 < Z` have "1 * Z \<le> f x * g x"
  1146       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1147     then show "Z \<le> f x * g x"
  1148        by simp
  1149   qed
  1150 qed
  1151 
  1152 lemma filterlim_tendsto_pos_mult_at_bot:
  1153   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1154   shows "LIM x F. f x * g x :> at_bot"
  1155   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1156   unfolding filterlim_uminus_at_bot by simp
  1157 
  1158 lemma filterlim_pow_at_top:
  1159   fixes f :: "real \<Rightarrow> real"
  1160   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1161   shows "LIM x F. (f x)^n :: real :> at_top"
  1162 using `0 < n` proof (induct n)
  1163   case (Suc n) with f show ?case
  1164     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1165 qed simp
  1166 
  1167 lemma filterlim_pow_at_bot_even:
  1168   fixes f :: "real \<Rightarrow> real"
  1169   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1170   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1171 
  1172 lemma filterlim_pow_at_bot_odd:
  1173   fixes f :: "real \<Rightarrow> real"
  1174   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1175   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1176 
  1177 lemma filterlim_tendsto_add_at_top: 
  1178   assumes f: "(f ---> c) F"
  1179   assumes g: "LIM x F. g x :> at_top"
  1180   shows "LIM x F. (f x + g x :: real) :> at_top"
  1181   unfolding filterlim_at_top_gt[where c=0]
  1182 proof safe
  1183   fix Z :: real assume "0 < Z"
  1184   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1185     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1186   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1187     unfolding filterlim_at_top by auto
  1188   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1189     by eventually_elim simp
  1190 qed
  1191 
  1192 lemma LIM_at_top_divide:
  1193   fixes f g :: "'a \<Rightarrow> real"
  1194   assumes f: "(f ---> a) F" "0 < a"
  1195   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1196   shows "LIM x F. f x / g x :> at_top"
  1197   unfolding divide_inverse
  1198   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1199 
  1200 lemma filterlim_at_top_add_at_top: 
  1201   assumes f: "LIM x F. f x :> at_top"
  1202   assumes g: "LIM x F. g x :> at_top"
  1203   shows "LIM x F. (f x + g x :: real) :> at_top"
  1204   unfolding filterlim_at_top_gt[where c=0]
  1205 proof safe
  1206   fix Z :: real assume "0 < Z"
  1207   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1208     unfolding filterlim_at_top by auto
  1209   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1210     unfolding filterlim_at_top by auto
  1211   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1212     by eventually_elim simp
  1213 qed
  1214 
  1215 lemma tendsto_divide_0:
  1216   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1217   assumes f: "(f ---> c) F"
  1218   assumes g: "LIM x F. g x :> at_infinity"
  1219   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1220   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1221 
  1222 lemma linear_plus_1_le_power:
  1223   fixes x :: real
  1224   assumes x: "0 \<le> x"
  1225   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1226 proof (induct n)
  1227   case (Suc n)
  1228   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1229     by (simp add: field_simps real_of_nat_Suc x)
  1230   also have "\<dots> \<le> (x + 1)^Suc n"
  1231     using Suc x by (simp add: mult_left_mono)
  1232   finally show ?case .
  1233 qed simp
  1234 
  1235 lemma filterlim_realpow_sequentially_gt1:
  1236   fixes x :: "'a :: real_normed_div_algebra"
  1237   assumes x[arith]: "1 < norm x"
  1238   shows "LIM n sequentially. x ^ n :> at_infinity"
  1239 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1240   fix y :: real assume "0 < y"
  1241   have "0 < norm x - 1" by simp
  1242   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1243   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1244   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1245   also have "\<dots> = norm x ^ N" by simp
  1246   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1247     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1248   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1249     unfolding eventually_sequentially
  1250     by (auto simp: norm_power)
  1251 qed simp
  1252 
  1253 
  1254 subsection {* Limits of Sequences *}
  1255 
  1256 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1257   by simp
  1258 
  1259 lemma LIMSEQ_iff:
  1260   fixes L :: "'a::real_normed_vector"
  1261   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1262 unfolding LIMSEQ_def dist_norm ..
  1263 
  1264 lemma LIMSEQ_I:
  1265   fixes L :: "'a::real_normed_vector"
  1266   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1267 by (simp add: LIMSEQ_iff)
  1268 
  1269 lemma LIMSEQ_D:
  1270   fixes L :: "'a::real_normed_vector"
  1271   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1272 by (simp add: LIMSEQ_iff)
  1273 
  1274 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1275   unfolding tendsto_def eventually_sequentially
  1276   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1277 
  1278 lemma Bseq_inverse_lemma:
  1279   fixes x :: "'a::real_normed_div_algebra"
  1280   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1281 apply (subst nonzero_norm_inverse, clarsimp)
  1282 apply (erule (1) le_imp_inverse_le)
  1283 done
  1284 
  1285 lemma Bseq_inverse:
  1286   fixes a :: "'a::real_normed_div_algebra"
  1287   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1288   by (rule Bfun_inverse)
  1289 
  1290 lemma LIMSEQ_diff_approach_zero:
  1291   fixes L :: "'a::real_normed_vector"
  1292   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1293   by (drule (1) tendsto_add, simp)
  1294 
  1295 lemma LIMSEQ_diff_approach_zero2:
  1296   fixes L :: "'a::real_normed_vector"
  1297   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1298   by (drule (1) tendsto_diff, simp)
  1299 
  1300 text{*An unbounded sequence's inverse tends to 0*}
  1301 
  1302 lemma LIMSEQ_inverse_zero:
  1303   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1304   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1305   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1306   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1307   done
  1308 
  1309 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1310 
  1311 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1312   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1313             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1314 
  1315 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1316 infinity is now easily proved*}
  1317 
  1318 lemma LIMSEQ_inverse_real_of_nat_add:
  1319      "(%n. r + inverse(real(Suc n))) ----> r"
  1320   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1321 
  1322 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1323      "(%n. r + -inverse(real(Suc n))) ----> r"
  1324   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1325   by auto
  1326 
  1327 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1328      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1329   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1330   by auto
  1331 
  1332 subsection {* Convergence on sequences *}
  1333 
  1334 lemma convergent_add:
  1335   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1336   assumes "convergent (\<lambda>n. X n)"
  1337   assumes "convergent (\<lambda>n. Y n)"
  1338   shows "convergent (\<lambda>n. X n + Y n)"
  1339   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1340 
  1341 lemma convergent_setsum:
  1342   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1343   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1344   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1345 proof (cases "finite A")
  1346   case True from this and assms show ?thesis
  1347     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1348 qed (simp add: convergent_const)
  1349 
  1350 lemma (in bounded_linear) convergent:
  1351   assumes "convergent (\<lambda>n. X n)"
  1352   shows "convergent (\<lambda>n. f (X n))"
  1353   using assms unfolding convergent_def by (fast intro: tendsto)
  1354 
  1355 lemma (in bounded_bilinear) convergent:
  1356   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1357   shows "convergent (\<lambda>n. X n ** Y n)"
  1358   using assms unfolding convergent_def by (fast intro: tendsto)
  1359 
  1360 lemma convergent_minus_iff:
  1361   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1362   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1363 apply (simp add: convergent_def)
  1364 apply (auto dest: tendsto_minus)
  1365 apply (drule tendsto_minus, auto)
  1366 done
  1367 
  1368 
  1369 text {* A monotone sequence converges to its least upper bound. *}
  1370 
  1371 lemma LIMSEQ_incseq_SUP:
  1372   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1373   assumes u: "bdd_above (range X)"
  1374   assumes X: "incseq X"
  1375   shows "X ----> (SUP i. X i)"
  1376   by (rule order_tendstoI)
  1377      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1378 
  1379 lemma LIMSEQ_decseq_INF:
  1380   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1381   assumes u: "bdd_below (range X)"
  1382   assumes X: "decseq X"
  1383   shows "X ----> (INF i. X i)"
  1384   by (rule order_tendstoI)
  1385      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1386 
  1387 text{*Main monotonicity theorem*}
  1388 
  1389 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1390   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1391 
  1392 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1393   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1394 
  1395 lemma Cauchy_iff:
  1396   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1397   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1398   unfolding Cauchy_def dist_norm ..
  1399 
  1400 lemma CauchyI:
  1401   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1402   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1403 by (simp add: Cauchy_iff)
  1404 
  1405 lemma CauchyD:
  1406   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1407   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1408 by (simp add: Cauchy_iff)
  1409 
  1410 lemma incseq_convergent:
  1411   fixes X :: "nat \<Rightarrow> real"
  1412   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1413   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1414 proof atomize_elim
  1415   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1416   obtain L where "X ----> L"
  1417     by (auto simp: convergent_def monoseq_def incseq_def)
  1418   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1419     by (auto intro!: exI[of _ L] incseq_le)
  1420 qed
  1421 
  1422 lemma decseq_convergent:
  1423   fixes X :: "nat \<Rightarrow> real"
  1424   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1425   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1426 proof atomize_elim
  1427   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1428   obtain L where "X ----> L"
  1429     by (auto simp: convergent_def monoseq_def decseq_def)
  1430   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1431     by (auto intro!: exI[of _ L] decseq_le)
  1432 qed
  1433 
  1434 subsubsection {* Cauchy Sequences are Bounded *}
  1435 
  1436 text{*A Cauchy sequence is bounded -- this is the standard
  1437   proof mechanization rather than the nonstandard proof*}
  1438 
  1439 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1440           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1441 apply (clarify, drule spec, drule (1) mp)
  1442 apply (simp only: norm_minus_commute)
  1443 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1444 apply simp
  1445 done
  1446 
  1447 subsection {* Power Sequences *}
  1448 
  1449 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1450 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1451   also fact that bounded and monotonic sequence converges.*}
  1452 
  1453 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1454 apply (simp add: Bseq_def)
  1455 apply (rule_tac x = 1 in exI)
  1456 apply (simp add: power_abs)
  1457 apply (auto dest: power_mono)
  1458 done
  1459 
  1460 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1461 apply (clarify intro!: mono_SucI2)
  1462 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1463 done
  1464 
  1465 lemma convergent_realpow:
  1466   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1467 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1468 
  1469 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1470   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1471 
  1472 lemma LIMSEQ_realpow_zero:
  1473   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1474 proof cases
  1475   assume "0 \<le> x" and "x \<noteq> 0"
  1476   hence x0: "0 < x" by simp
  1477   assume x1: "x < 1"
  1478   from x0 x1 have "1 < inverse x"
  1479     by (rule one_less_inverse)
  1480   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1481     by (rule LIMSEQ_inverse_realpow_zero)
  1482   thus ?thesis by (simp add: power_inverse)
  1483 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1484 
  1485 lemma LIMSEQ_power_zero:
  1486   fixes x :: "'a::{real_normed_algebra_1}"
  1487   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1488 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1489 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1490 apply (simp add: power_abs norm_power_ineq)
  1491 done
  1492 
  1493 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1494   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1495 
  1496 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1497 
  1498 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1499   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1500 
  1501 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1502   by (rule LIMSEQ_power_zero) simp
  1503 
  1504 
  1505 subsection {* Limits of Functions *}
  1506 
  1507 lemma LIM_eq:
  1508   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1509   shows "f -- a --> L =
  1510      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1511 by (simp add: LIM_def dist_norm)
  1512 
  1513 lemma LIM_I:
  1514   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1515   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1516       ==> f -- a --> L"
  1517 by (simp add: LIM_eq)
  1518 
  1519 lemma LIM_D:
  1520   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1521   shows "[| f -- a --> L; 0<r |]
  1522       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1523 by (simp add: LIM_eq)
  1524 
  1525 lemma LIM_offset:
  1526   fixes a :: "'a::real_normed_vector"
  1527   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1528   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1529 
  1530 lemma LIM_offset_zero:
  1531   fixes a :: "'a::real_normed_vector"
  1532   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1533 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1534 
  1535 lemma LIM_offset_zero_cancel:
  1536   fixes a :: "'a::real_normed_vector"
  1537   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1538 by (drule_tac k="- a" in LIM_offset, simp)
  1539 
  1540 lemma LIM_offset_zero_iff:
  1541   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1542   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1543   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1544 
  1545 lemma LIM_zero:
  1546   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1547   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1548 unfolding tendsto_iff dist_norm by simp
  1549 
  1550 lemma LIM_zero_cancel:
  1551   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1552   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1553 unfolding tendsto_iff dist_norm by simp
  1554 
  1555 lemma LIM_zero_iff:
  1556   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1557   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1558 unfolding tendsto_iff dist_norm by simp
  1559 
  1560 lemma LIM_imp_LIM:
  1561   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1562   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1563   assumes f: "f -- a --> l"
  1564   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1565   shows "g -- a --> m"
  1566   by (rule metric_LIM_imp_LIM [OF f],
  1567     simp add: dist_norm le)
  1568 
  1569 lemma LIM_equal2:
  1570   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1571   assumes 1: "0 < R"
  1572   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1573   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1574 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1575 
  1576 lemma LIM_compose2:
  1577   fixes a :: "'a::real_normed_vector"
  1578   assumes f: "f -- a --> b"
  1579   assumes g: "g -- b --> c"
  1580   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1581   shows "(\<lambda>x. g (f x)) -- a --> c"
  1582 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1583 
  1584 lemma real_LIM_sandwich_zero:
  1585   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1586   assumes f: "f -- a --> 0"
  1587   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1588   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1589   shows "g -- a --> 0"
  1590 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1591   fix x assume x: "x \<noteq> a"
  1592   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1593   also have "g x \<le> f x" by (rule 2 [OF x])
  1594   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1595   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1596   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1597 qed
  1598 
  1599 
  1600 subsection {* Continuity *}
  1601 
  1602 lemma LIM_isCont_iff:
  1603   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1604   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1605 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1606 
  1607 lemma isCont_iff:
  1608   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1609   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1610 by (simp add: isCont_def LIM_isCont_iff)
  1611 
  1612 lemma isCont_LIM_compose2:
  1613   fixes a :: "'a::real_normed_vector"
  1614   assumes f [unfolded isCont_def]: "isCont f a"
  1615   assumes g: "g -- f a --> l"
  1616   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1617   shows "(\<lambda>x. g (f x)) -- a --> l"
  1618 by (rule LIM_compose2 [OF f g inj])
  1619 
  1620 
  1621 lemma isCont_norm [simp]:
  1622   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1623   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1624   by (fact continuous_norm)
  1625 
  1626 lemma isCont_rabs [simp]:
  1627   fixes f :: "'a::t2_space \<Rightarrow> real"
  1628   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1629   by (fact continuous_rabs)
  1630 
  1631 lemma isCont_add [simp]:
  1632   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1633   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1634   by (fact continuous_add)
  1635 
  1636 lemma isCont_minus [simp]:
  1637   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1638   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1639   by (fact continuous_minus)
  1640 
  1641 lemma isCont_diff [simp]:
  1642   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1643   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1644   by (fact continuous_diff)
  1645 
  1646 lemma isCont_mult [simp]:
  1647   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1648   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1649   by (fact continuous_mult)
  1650 
  1651 lemma (in bounded_linear) isCont:
  1652   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1653   by (fact continuous)
  1654 
  1655 lemma (in bounded_bilinear) isCont:
  1656   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1657   by (fact continuous)
  1658 
  1659 lemmas isCont_scaleR [simp] = 
  1660   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1661 
  1662 lemmas isCont_of_real [simp] =
  1663   bounded_linear.isCont [OF bounded_linear_of_real]
  1664 
  1665 lemma isCont_power [simp]:
  1666   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1667   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1668   by (fact continuous_power)
  1669 
  1670 lemma isCont_setsum [simp]:
  1671   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1672   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1673   by (auto intro: continuous_setsum)
  1674 
  1675 subsection {* Uniform Continuity *}
  1676 
  1677 definition
  1678   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1679   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1680 
  1681 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1682 by (simp add: isUCont_def isCont_def LIM_def, force)
  1683 
  1684 lemma isUCont_Cauchy:
  1685   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1686 unfolding isUCont_def
  1687 apply (rule metric_CauchyI)
  1688 apply (drule_tac x=e in spec, safe)
  1689 apply (drule_tac e=s in metric_CauchyD, safe)
  1690 apply (rule_tac x=M in exI, simp)
  1691 done
  1692 
  1693 lemma (in bounded_linear) isUCont: "isUCont f"
  1694 unfolding isUCont_def dist_norm
  1695 proof (intro allI impI)
  1696   fix r::real assume r: "0 < r"
  1697   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1698     using pos_bounded by fast
  1699   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1700   proof (rule exI, safe)
  1701     from r K show "0 < r / K" by simp
  1702   next
  1703     fix x y :: 'a
  1704     assume xy: "norm (x - y) < r / K"
  1705     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1706     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1707     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1708     finally show "norm (f x - f y) < r" .
  1709   qed
  1710 qed
  1711 
  1712 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1713 by (rule isUCont [THEN isUCont_Cauchy])
  1714 
  1715 lemma LIM_less_bound: 
  1716   fixes f :: "real \<Rightarrow> real"
  1717   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1718   shows "0 \<le> f x"
  1719 proof (rule tendsto_le_const)
  1720   show "(f ---> f x) (at_left x)"
  1721     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1722   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1723     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1724 qed simp
  1725 
  1726 
  1727 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1728 
  1729 lemma nested_sequence_unique:
  1730   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1731   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1732 proof -
  1733   have "incseq f" unfolding incseq_Suc_iff by fact
  1734   have "decseq g" unfolding decseq_Suc_iff by fact
  1735 
  1736   { fix n
  1737     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1738     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1739   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1740     using incseq_convergent[OF `incseq f`] by auto
  1741   moreover
  1742   { fix n
  1743     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1744     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1745   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1746     using decseq_convergent[OF `decseq g`] by auto
  1747   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1748   ultimately show ?thesis by auto
  1749 qed
  1750 
  1751 lemma Bolzano[consumes 1, case_names trans local]:
  1752   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1753   assumes [arith]: "a \<le> b"
  1754   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1755   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1756   shows "P a b"
  1757 proof -
  1758   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1759   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1760   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1761     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1762     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1763 
  1764   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1765 
  1766   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1767   proof (safe intro!: nested_sequence_unique)
  1768     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1769   next
  1770     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1771     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1772   qed fact
  1773   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1774   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1775     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1776 
  1777   show "P a b"
  1778   proof (rule ccontr)
  1779     assume "\<not> P a b" 
  1780     { fix n have "\<not> P (l n) (u n)"
  1781       proof (induct n)
  1782         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1783       qed (simp add: `\<not> P a b`) }
  1784     moreover
  1785     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1786         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1787       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1788         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1789       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1790       proof eventually_elim
  1791         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1792         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1793         with x show "P (l n) (u n)" by (rule d)
  1794       qed }
  1795     ultimately show False by simp
  1796   qed
  1797 qed
  1798 
  1799 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1800 proof (cases "a \<le> b", rule compactI)
  1801   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1802   def T == "{a .. b}"
  1803   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1804   proof (induct rule: Bolzano)
  1805     case (trans a b c)
  1806     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1807     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1808       by (auto simp: *)
  1809     with trans show ?case
  1810       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1811   next
  1812     case (local x)
  1813     then have "x \<in> \<Union>C" using C by auto
  1814     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1815     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1816       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1817     with `c \<in> C` show ?case
  1818       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1819   qed
  1820 qed simp
  1821 
  1822 
  1823 lemma continuous_image_closed_interval:
  1824   fixes a b and f :: "real \<Rightarrow> real"
  1825   defines "S \<equiv> {a..b}"
  1826   assumes "a \<le> b" and f: "continuous_on S f"
  1827   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  1828 proof -
  1829   have S: "compact S" "S \<noteq> {}"
  1830     using `a \<le> b` by (auto simp: S_def)
  1831   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  1832     using continuous_attains_sup[OF S f] by auto
  1833   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  1834     using continuous_attains_inf[OF S f] by auto
  1835   moreover have "connected (f`S)"
  1836     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  1837   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  1838     by (auto simp: connected_iff_interval)
  1839   then show ?thesis
  1840     by auto
  1841 qed
  1842 
  1843 subsection {* Boundedness of continuous functions *}
  1844 
  1845 text{*By bisection, function continuous on closed interval is bounded above*}
  1846 
  1847 lemma isCont_eq_Ub:
  1848   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1849   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1850     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1851   using continuous_attains_sup[of "{a .. b}" f]
  1852   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1853 
  1854 lemma isCont_eq_Lb:
  1855   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1856   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1857     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1858   using continuous_attains_inf[of "{a .. b}" f]
  1859   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1860 
  1861 lemma isCont_bounded:
  1862   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1863   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1864   using isCont_eq_Ub[of a b f] by auto
  1865 
  1866 lemma isCont_has_Ub:
  1867   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1868   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1869     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1870   using isCont_eq_Ub[of a b f] by auto
  1871 
  1872 (*HOL style here: object-level formulations*)
  1873 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1874       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1875       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1876   by (blast intro: IVT)
  1877 
  1878 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1879       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1880       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1881   by (blast intro: IVT2)
  1882 
  1883 lemma isCont_Lb_Ub:
  1884   fixes f :: "real \<Rightarrow> real"
  1885   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1886   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and> 
  1887                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  1888 proof -
  1889   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  1890     using isCont_eq_Ub[OF assms] by auto
  1891   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  1892     using isCont_eq_Lb[OF assms] by auto
  1893   show ?thesis
  1894     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  1895     apply (rule_tac x="f L" in exI)
  1896     apply (rule_tac x="f M" in exI)
  1897     apply (cases "L \<le> M")
  1898     apply (simp, metis order_trans)
  1899     apply (simp, metis order_trans)
  1900     done
  1901 qed
  1902 
  1903 
  1904 text{*Continuity of inverse function*}
  1905 
  1906 lemma isCont_inverse_function:
  1907   fixes f g :: "real \<Rightarrow> real"
  1908   assumes d: "0 < d"
  1909       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  1910       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  1911   shows "isCont g (f x)"
  1912 proof -
  1913   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  1914 
  1915   have f: "continuous_on ?D f"
  1916     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  1917   then have g: "continuous_on (f`?D) g"
  1918     using inj by (intro continuous_on_inv) auto
  1919 
  1920   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  1921     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  1922   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  1923     by (rule continuous_on_subset)
  1924   moreover
  1925   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  1926     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  1927   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  1928     by auto
  1929   ultimately
  1930   show ?thesis
  1931     by (simp add: continuous_on_eq_continuous_at)
  1932 qed
  1933 
  1934 lemma isCont_inverse_function2:
  1935   fixes f g :: "real \<Rightarrow> real" shows
  1936   "\<lbrakk>a < x; x < b;
  1937     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  1938     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  1939    \<Longrightarrow> isCont g (f x)"
  1940 apply (rule isCont_inverse_function
  1941        [where f=f and d="min (x - a) (b - x)"])
  1942 apply (simp_all add: abs_le_iff)
  1943 done
  1944 
  1945 (* need to rename second isCont_inverse *)
  1946 
  1947 lemma isCont_inv_fun:
  1948   fixes f g :: "real \<Rightarrow> real"
  1949   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1950          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1951       ==> isCont g (f x)"
  1952 by (rule isCont_inverse_function)
  1953 
  1954 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1955 lemma LIM_fun_gt_zero:
  1956   fixes f :: "real \<Rightarrow> real"
  1957   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  1958 apply (drule (1) LIM_D, clarify)
  1959 apply (rule_tac x = s in exI)
  1960 apply (simp add: abs_less_iff)
  1961 done
  1962 
  1963 lemma LIM_fun_less_zero:
  1964   fixes f :: "real \<Rightarrow> real"
  1965   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  1966 apply (drule LIM_D [where r="-l"], simp, clarify)
  1967 apply (rule_tac x = s in exI)
  1968 apply (simp add: abs_less_iff)
  1969 done
  1970 
  1971 lemma LIM_fun_not_zero:
  1972   fixes f :: "real \<Rightarrow> real"
  1973   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  1974   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  1975 
  1976 end
  1977