src/HOL/Map.thy
author haftmann
Sun Sep 21 16:56:11 2014 +0200 (2014-09-21)
changeset 58410 6d46ad54a2ab
parent 56545 8f1e7596deb7
child 58889 5b7a9633cfa8
permissions -rw-r--r--
explicit separation of signed and unsigned numerals using existing lexical categories num and xnum
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     6 *)
     7 
     8 header {* Maps *}
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 type_synonym ('a,'b) "map" = "'a => 'b option" (infixr "~=>" 0)
    15 
    16 type_notation (xsymbols)
    17   "map" (infixr "\<rightharpoonup>" 0)
    18 
    19 abbreviation
    20   empty :: "'a ~=> 'b" where
    21   "empty == %x. None"
    22 
    23 definition
    24   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    25   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    26 
    27 notation (xsymbols)
    28   map_comp  (infixl "\<circ>\<^sub>m" 55)
    29 
    30 definition
    31   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    32   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    33 
    34 definition
    35   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    36   "m|`A = (\<lambda>x. if x : A then m x else None)"
    37 
    38 notation (latex output)
    39   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    40 
    41 definition
    42   dom :: "('a ~=> 'b) => 'a set" where
    43   "dom m = {a. m a ~= None}"
    44 
    45 definition
    46   ran :: "('a ~=> 'b) => 'b set" where
    47   "ran m = {b. EX a. m a = Some b}"
    48 
    49 definition
    50   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    51   "(m\<^sub>1 \<subseteq>\<^sub>m m\<^sub>2) = (\<forall>a \<in> dom m\<^sub>1. m\<^sub>1 a = m\<^sub>2 a)"
    52 
    53 nonterminal maplets and maplet
    54 
    55 syntax
    56   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    57   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    58   ""         :: "maplet => maplets"             ("_")
    59   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    60   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    61   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    62 
    63 syntax (xsymbols)
    64   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    65   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    66 
    67 translations
    68   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    69   "_MapUpd m (_maplet  x y)"    == "m(x := CONST Some y)"
    70   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    71   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    72   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    73 
    74 primrec
    75   map_of :: "('a \<times> 'b) list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    76     "map_of [] = empty"
    77   | "map_of (p # ps) = (map_of ps)(fst p \<mapsto> snd p)"
    78 
    79 definition
    80   map_upds :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    81   "map_upds m xs ys = m ++ map_of (rev (zip xs ys))"
    82 
    83 translations
    84   "_MapUpd m (_maplets x y)"    == "CONST map_upds m x y"
    85 
    86 lemma map_of_Cons_code [code]: 
    87   "map_of [] k = None"
    88   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    89   by simp_all
    90 
    91 
    92 subsection {* @{term [source] empty} *}
    93 
    94 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    95 by (rule ext) simp
    96 
    97 
    98 subsection {* @{term [source] map_upd} *}
    99 
   100 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   101 by (rule ext) simp
   102 
   103 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   104 proof
   105   assume "t(k \<mapsto> x) = empty"
   106   then have "(t(k \<mapsto> x)) k = None" by simp
   107   then show False by simp
   108 qed
   109 
   110 lemma map_upd_eqD1:
   111   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   112   shows "x = y"
   113 proof -
   114   from assms have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   115   then show ?thesis by simp
   116 qed
   117 
   118 lemma map_upd_Some_unfold:
   119   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   120 by auto
   121 
   122 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   123 by auto
   124 
   125 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   126 unfolding image_def
   127 apply (simp (no_asm_use) add:full_SetCompr_eq)
   128 apply (rule finite_subset)
   129  prefer 2 apply assumption
   130 apply (auto)
   131 done
   132 
   133 
   134 subsection {* @{term [source] map_of} *}
   135 
   136 lemma map_of_eq_None_iff:
   137   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   138 by (induct xys) simp_all
   139 
   140 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   141 apply (induct xys)
   142  apply simp
   143 apply (clarsimp split: if_splits)
   144 done
   145 
   146 lemma map_of_eq_Some_iff [simp]:
   147   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   148 apply (induct xys)
   149  apply simp
   150 apply (auto simp: map_of_eq_None_iff [symmetric])
   151 done
   152 
   153 lemma Some_eq_map_of_iff [simp]:
   154   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   155 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   156 
   157 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   158     \<Longrightarrow> map_of xys x = Some y"
   159 apply (induct xys)
   160  apply simp
   161 apply force
   162 done
   163 
   164 lemma map_of_zip_is_None [simp]:
   165   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   166 by (induct rule: list_induct2) simp_all
   167 
   168 lemma map_of_zip_is_Some:
   169   assumes "length xs = length ys"
   170   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   171 using assms by (induct rule: list_induct2) simp_all
   172 
   173 lemma map_of_zip_upd:
   174   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   175   assumes "length ys = length xs"
   176     and "length zs = length xs"
   177     and "x \<notin> set xs"
   178     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   179   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   180 proof
   181   fix x' :: 'a
   182   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   183   proof (cases "x = x'")
   184     case True
   185     from assms True map_of_zip_is_None [of xs ys x']
   186       have "map_of (zip xs ys) x' = None" by simp
   187     moreover from assms True map_of_zip_is_None [of xs zs x']
   188       have "map_of (zip xs zs) x' = None" by simp
   189     ultimately show ?thesis by simp
   190   next
   191     case False from assms
   192       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   193     with False show ?thesis by simp
   194   qed
   195 qed
   196 
   197 lemma map_of_zip_inject:
   198   assumes "length ys = length xs"
   199     and "length zs = length xs"
   200     and dist: "distinct xs"
   201     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   202   shows "ys = zs"
   203 using assms(1) assms(2)[symmetric] using dist map_of proof (induct ys xs zs rule: list_induct3)
   204   case Nil show ?case by simp
   205 next
   206   case (Cons y ys x xs z zs)
   207   from `map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))`
   208     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   209   from Cons have "length ys = length xs" and "length zs = length xs"
   210     and "x \<notin> set xs" by simp_all
   211   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   212   with Cons.hyps `distinct (x # xs)` have "ys = zs" by simp
   213   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   214   ultimately show ?case by simp
   215 qed
   216 
   217 lemma map_of_zip_map:
   218   "map_of (zip xs (map f xs)) = (\<lambda>x. if x \<in> set xs then Some (f x) else None)"
   219   by (induct xs) (simp_all add: fun_eq_iff)
   220 
   221 lemma finite_range_map_of: "finite (range (map_of xys))"
   222 apply (induct xys)
   223  apply (simp_all add: image_constant)
   224 apply (rule finite_subset)
   225  prefer 2 apply assumption
   226 apply auto
   227 done
   228 
   229 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   230 by (induct xs) (simp, atomize (full), auto)
   231 
   232 lemma map_of_mapk_SomeI:
   233   "inj f ==> map_of t k = Some x ==>
   234    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   235 by (induct t) (auto simp add: inj_eq)
   236 
   237 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   238 by (induct l) auto
   239 
   240 lemma map_of_filter_in:
   241   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   242 by (induct xs) auto
   243 
   244 lemma map_of_map:
   245   "map_of (map (\<lambda>(k, v). (k, f v)) xs) = map_option f \<circ> map_of xs"
   246   by (induct xs) (auto simp add: fun_eq_iff)
   247 
   248 lemma dom_map_option:
   249   "dom (\<lambda>k. map_option (f k) (m k)) = dom m"
   250   by (simp add: dom_def)
   251 
   252 lemma dom_map_option_comp [simp]:
   253   "dom (map_option g \<circ> m) = dom m"
   254   using dom_map_option [of "\<lambda>_. g" m] by (simp add: comp_def)
   255 
   256 
   257 subsection {* @{const map_option} related *}
   258 
   259 lemma map_option_o_empty [simp]: "map_option f o empty = empty"
   260 by (rule ext) simp
   261 
   262 lemma map_option_o_map_upd [simp]:
   263   "map_option f o m(a|->b) = (map_option f o m)(a|->f b)"
   264 by (rule ext) simp
   265 
   266 
   267 subsection {* @{term [source] map_comp} related *}
   268 
   269 lemma map_comp_empty [simp]:
   270   "m \<circ>\<^sub>m empty = empty"
   271   "empty \<circ>\<^sub>m m = empty"
   272 by (auto simp add: map_comp_def split: option.splits)
   273 
   274 lemma map_comp_simps [simp]:
   275   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   276   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   277 by (auto simp add: map_comp_def)
   278 
   279 lemma map_comp_Some_iff:
   280   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   281 by (auto simp add: map_comp_def split: option.splits)
   282 
   283 lemma map_comp_None_iff:
   284   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   285 by (auto simp add: map_comp_def split: option.splits)
   286 
   287 
   288 subsection {* @{text "++"} *}
   289 
   290 lemma map_add_empty[simp]: "m ++ empty = m"
   291 by(simp add: map_add_def)
   292 
   293 lemma empty_map_add[simp]: "empty ++ m = m"
   294 by (rule ext) (simp add: map_add_def split: option.split)
   295 
   296 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   297 by (rule ext) (simp add: map_add_def split: option.split)
   298 
   299 lemma map_add_Some_iff:
   300   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   301 by (simp add: map_add_def split: option.split)
   302 
   303 lemma map_add_SomeD [dest!]:
   304   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   305 by (rule map_add_Some_iff [THEN iffD1])
   306 
   307 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   308 by (subst map_add_Some_iff) fast
   309 
   310 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   311 by (simp add: map_add_def split: option.split)
   312 
   313 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   314 by (rule ext) (simp add: map_add_def)
   315 
   316 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   317 by (simp add: map_upds_def)
   318 
   319 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   320 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   321 
   322 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   323 unfolding map_add_def
   324 apply (induct xs)
   325  apply simp
   326 apply (rule ext)
   327 apply (simp split add: option.split)
   328 done
   329 
   330 lemma finite_range_map_of_map_add:
   331   "finite (range f) ==> finite (range (f ++ map_of l))"
   332 apply (induct l)
   333  apply (auto simp del: fun_upd_apply)
   334 apply (erule finite_range_updI)
   335 done
   336 
   337 lemma inj_on_map_add_dom [iff]:
   338   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   339 by (fastforce simp: map_add_def dom_def inj_on_def split: option.splits)
   340 
   341 lemma map_upds_fold_map_upd:
   342   "m(ks[\<mapsto>]vs) = foldl (\<lambda>m (k, v). m(k \<mapsto> v)) m (zip ks vs)"
   343 unfolding map_upds_def proof (rule sym, rule zip_obtain_same_length)
   344   fix ks :: "'a list" and vs :: "'b list"
   345   assume "length ks = length vs"
   346   then show "foldl (\<lambda>m (k, v). m(k\<mapsto>v)) m (zip ks vs) = m ++ map_of (rev (zip ks vs))"
   347     by(induct arbitrary: m rule: list_induct2) simp_all
   348 qed
   349 
   350 lemma map_add_map_of_foldr:
   351   "m ++ map_of ps = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) ps m"
   352   by (induct ps) (auto simp add: fun_eq_iff map_add_def)
   353 
   354 
   355 subsection {* @{term [source] restrict_map} *}
   356 
   357 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   358 by (simp add: restrict_map_def)
   359 
   360 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   361 by (auto simp add: restrict_map_def)
   362 
   363 lemma restrict_map_empty [simp]: "empty|`D = empty"
   364 by (simp add: restrict_map_def)
   365 
   366 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   367 by (simp add: restrict_map_def)
   368 
   369 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   370 by (simp add: restrict_map_def)
   371 
   372 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   373 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   374 
   375 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   376 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   377 
   378 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   379 by (rule ext) (auto simp: restrict_map_def)
   380 
   381 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   382 by (rule ext) (auto simp: restrict_map_def)
   383 
   384 lemma restrict_fun_upd [simp]:
   385   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   386 by (simp add: restrict_map_def fun_eq_iff)
   387 
   388 lemma fun_upd_None_restrict [simp]:
   389   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   390 by (simp add: restrict_map_def fun_eq_iff)
   391 
   392 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   393 by (simp add: restrict_map_def fun_eq_iff)
   394 
   395 lemma fun_upd_restrict_conv [simp]:
   396   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   397 by (simp add: restrict_map_def fun_eq_iff)
   398 
   399 lemma map_of_map_restrict:
   400   "map_of (map (\<lambda>k. (k, f k)) ks) = (Some \<circ> f) |` set ks"
   401   by (induct ks) (simp_all add: fun_eq_iff restrict_map_insert)
   402 
   403 lemma restrict_complement_singleton_eq:
   404   "f |` (- {x}) = f(x := None)"
   405   by (simp add: restrict_map_def fun_eq_iff)
   406 
   407 
   408 subsection {* @{term [source] map_upds} *}
   409 
   410 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   411 by (simp add: map_upds_def)
   412 
   413 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   414 by (simp add:map_upds_def)
   415 
   416 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   417 by (simp add:map_upds_def)
   418 
   419 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   420   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   421 apply(induct xs)
   422  apply (clarsimp simp add: neq_Nil_conv)
   423 apply (case_tac ys)
   424  apply simp
   425 apply simp
   426 done
   427 
   428 lemma map_upds_list_update2_drop [simp]:
   429   "size xs \<le> i \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   430 apply (induct xs arbitrary: m ys i)
   431  apply simp
   432 apply (case_tac ys)
   433  apply simp
   434 apply (simp split: nat.split)
   435 done
   436 
   437 lemma map_upd_upds_conv_if:
   438   "(f(x|->y))(xs [|->] ys) =
   439    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   440                                     else (f(xs [|->] ys))(x|->y))"
   441 apply (induct xs arbitrary: x y ys f)
   442  apply simp
   443 apply (case_tac ys)
   444  apply (auto split: split_if simp: fun_upd_twist)
   445 done
   446 
   447 lemma map_upds_twist [simp]:
   448   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   449 using set_take_subset by (fastforce simp add: map_upd_upds_conv_if)
   450 
   451 lemma map_upds_apply_nontin [simp]:
   452   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   453 apply (induct xs arbitrary: ys)
   454  apply simp
   455 apply (case_tac ys)
   456  apply (auto simp: map_upd_upds_conv_if)
   457 done
   458 
   459 lemma fun_upds_append_drop [simp]:
   460   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   461 apply (induct xs arbitrary: m ys)
   462  apply simp
   463 apply (case_tac ys)
   464  apply simp_all
   465 done
   466 
   467 lemma fun_upds_append2_drop [simp]:
   468   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   469 apply (induct xs arbitrary: m ys)
   470  apply simp
   471 apply (case_tac ys)
   472  apply simp_all
   473 done
   474 
   475 
   476 lemma restrict_map_upds[simp]:
   477   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   478     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   479 apply (induct xs arbitrary: m ys)
   480  apply simp
   481 apply (case_tac ys)
   482  apply simp
   483 apply (simp add: Diff_insert [symmetric] insert_absorb)
   484 apply (simp add: map_upd_upds_conv_if)
   485 done
   486 
   487 
   488 subsection {* @{term [source] dom} *}
   489 
   490 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   491   by (auto simp: dom_def)
   492 
   493 lemma domI: "m a = Some b ==> a : dom m"
   494 by(simp add:dom_def)
   495 (* declare domI [intro]? *)
   496 
   497 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   498 by (cases "m a") (auto simp add: dom_def)
   499 
   500 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   501 by(simp add:dom_def)
   502 
   503 lemma dom_empty [simp]: "dom empty = {}"
   504 by(simp add:dom_def)
   505 
   506 lemma dom_fun_upd [simp]:
   507   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   508 by(auto simp add:dom_def)
   509 
   510 lemma dom_if:
   511   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   512   by (auto split: if_splits)
   513 
   514 lemma dom_map_of_conv_image_fst:
   515   "dom (map_of xys) = fst ` set xys"
   516   by (induct xys) (auto simp add: dom_if)
   517 
   518 lemma dom_map_of_zip [simp]: "length xs = length ys ==> dom (map_of (zip xs ys)) = set xs"
   519 by (induct rule: list_induct2) (auto simp add: dom_if)
   520 
   521 lemma finite_dom_map_of: "finite (dom (map_of l))"
   522 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   523 
   524 lemma dom_map_upds [simp]:
   525   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   526 apply (induct xs arbitrary: m ys)
   527  apply simp
   528 apply (case_tac ys)
   529  apply auto
   530 done
   531 
   532 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   533 by(auto simp:dom_def)
   534 
   535 lemma dom_override_on [simp]:
   536   "dom(override_on f g A) =
   537     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   538 by(auto simp: dom_def override_on_def)
   539 
   540 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   541 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   542 
   543 lemma map_add_dom_app_simps:
   544   "\<lbrakk> m\<in>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   545   "\<lbrakk> m\<notin>dom l1 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   546   "\<lbrakk> m\<notin>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l1 m"
   547 by (auto simp add: map_add_def split: option.split_asm)
   548 
   549 lemma dom_const [simp]:
   550   "dom (\<lambda>x. Some (f x)) = UNIV"
   551   by auto
   552 
   553 (* Due to John Matthews - could be rephrased with dom *)
   554 lemma finite_map_freshness:
   555   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   556    \<exists>x. f x = None"
   557 by(bestsimp dest:ex_new_if_finite)
   558 
   559 lemma dom_minus:
   560   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   561   unfolding dom_def by simp
   562 
   563 lemma insert_dom:
   564   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   565   unfolding dom_def by auto
   566 
   567 lemma map_of_map_keys:
   568   "set xs = dom m \<Longrightarrow> map_of (map (\<lambda>k. (k, the (m k))) xs) = m"
   569   by (rule ext) (auto simp add: map_of_map_restrict restrict_map_def)
   570 
   571 lemma map_of_eqI:
   572   assumes set_eq: "set (map fst xs) = set (map fst ys)"
   573   assumes map_eq: "\<forall>k\<in>set (map fst xs). map_of xs k = map_of ys k"
   574   shows "map_of xs = map_of ys"
   575 proof (rule ext)
   576   fix k show "map_of xs k = map_of ys k"
   577   proof (cases "map_of xs k")
   578     case None then have "k \<notin> set (map fst xs)" by (simp add: map_of_eq_None_iff)
   579     with set_eq have "k \<notin> set (map fst ys)" by simp
   580     then have "map_of ys k = None" by (simp add: map_of_eq_None_iff)
   581     with None show ?thesis by simp
   582   next
   583     case (Some v) then have "k \<in> set (map fst xs)" by (auto simp add: dom_map_of_conv_image_fst [symmetric])
   584     with map_eq show ?thesis by auto
   585   qed
   586 qed
   587 
   588 lemma map_of_eq_dom:
   589   assumes "map_of xs = map_of ys"
   590   shows "fst ` set xs = fst ` set ys"
   591 proof -
   592   from assms have "dom (map_of xs) = dom (map_of ys)" by simp
   593   then show ?thesis by (simp add: dom_map_of_conv_image_fst)
   594 qed
   595 
   596 lemma finite_set_of_finite_maps:
   597 assumes "finite A" "finite B"
   598 shows  "finite {m. dom m = A \<and> ran m \<subseteq> B}" (is "finite ?S")
   599 proof -
   600   let ?S' = "{m. \<forall>x. (x \<in> A \<longrightarrow> m x \<in> Some ` B) \<and> (x \<notin> A \<longrightarrow> m x = None)}"
   601   have "?S = ?S'"
   602   proof
   603     show "?S \<subseteq> ?S'" by(auto simp: dom_def ran_def image_def)
   604     show "?S' \<subseteq> ?S"
   605     proof
   606       fix m assume "m \<in> ?S'"
   607       hence 1: "dom m = A" by force
   608       hence 2: "ran m \<subseteq> B" using `m \<in> ?S'` by(auto simp: dom_def ran_def)
   609       from 1 2 show "m \<in> ?S" by blast
   610     qed
   611   qed
   612   with assms show ?thesis by(simp add: finite_set_of_finite_funs)
   613 qed
   614 
   615 subsection {* @{term [source] ran} *}
   616 
   617 lemma ranI: "m a = Some b ==> b : ran m"
   618 by(auto simp: ran_def)
   619 (* declare ranI [intro]? *)
   620 
   621 lemma ran_empty [simp]: "ran empty = {}"
   622 by(auto simp: ran_def)
   623 
   624 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   625 unfolding ran_def
   626 apply auto
   627 apply (subgoal_tac "aa ~= a")
   628  apply auto
   629 done
   630 
   631 lemma ran_distinct: 
   632   assumes dist: "distinct (map fst al)" 
   633   shows "ran (map_of al) = snd ` set al"
   634 using assms proof (induct al)
   635   case Nil then show ?case by simp
   636 next
   637   case (Cons kv al)
   638   then have "ran (map_of al) = snd ` set al" by simp
   639   moreover from Cons.prems have "map_of al (fst kv) = None"
   640     by (simp add: map_of_eq_None_iff)
   641   ultimately show ?case by (simp only: map_of.simps ran_map_upd) simp
   642 qed
   643 
   644 
   645 subsection {* @{text "map_le"} *}
   646 
   647 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   648 by (simp add: map_le_def)
   649 
   650 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   651 by (force simp add: map_le_def)
   652 
   653 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   654 by (fastforce simp add: map_le_def)
   655 
   656 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   657 by (force simp add: map_le_def)
   658 
   659 lemma map_le_upds [simp]:
   660   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   661 apply (induct as arbitrary: f g bs)
   662  apply simp
   663 apply (case_tac bs)
   664  apply auto
   665 done
   666 
   667 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   668 by (fastforce simp add: map_le_def dom_def)
   669 
   670 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   671 by (simp add: map_le_def)
   672 
   673 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   674 by (auto simp add: map_le_def dom_def)
   675 
   676 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   677 unfolding map_le_def
   678 apply (rule ext)
   679 apply (case_tac "x \<in> dom f", simp)
   680 apply (case_tac "x \<in> dom g", simp, fastforce)
   681 done
   682 
   683 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   684 by (fastforce simp add: map_le_def)
   685 
   686 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   687 by(fastforce simp: map_add_def map_le_def fun_eq_iff split: option.splits)
   688 
   689 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   690 by (fastforce simp add: map_le_def map_add_def dom_def)
   691 
   692 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   693 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   694 
   695 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   696 proof(rule iffI)
   697   assume "\<exists>v. f = [x \<mapsto> v]"
   698   thus "dom f = {x}" by(auto split: split_if_asm)
   699 next
   700   assume "dom f = {x}"
   701   then obtain v where "f x = Some v" by auto
   702   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   703   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using `dom f = {x}` `f x = Some v`
   704     by(auto simp add: map_le_def)
   705   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   706   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   707 qed
   708 
   709 
   710 subsection {* Various *}
   711 
   712 lemma set_map_of_compr:
   713   assumes distinct: "distinct (map fst xs)"
   714   shows "set xs = {(k, v). map_of xs k = Some v}"
   715 using assms proof (induct xs)
   716   case Nil then show ?case by simp
   717 next
   718   case (Cons x xs)
   719   obtain k v where "x = (k, v)" by (cases x) blast
   720   with Cons.prems have "k \<notin> dom (map_of xs)"
   721     by (simp add: dom_map_of_conv_image_fst)
   722   then have *: "insert (k, v) {(k, v). map_of xs k = Some v} =
   723     {(k', v'). (map_of xs(k \<mapsto> v)) k' = Some v'}"
   724     by (auto split: if_splits)
   725   from Cons have "set xs = {(k, v). map_of xs k = Some v}" by simp
   726   with * `x = (k, v)` show ?case by simp
   727 qed
   728 
   729 lemma map_of_inject_set:
   730   assumes distinct: "distinct (map fst xs)" "distinct (map fst ys)"
   731   shows "map_of xs = map_of ys \<longleftrightarrow> set xs = set ys" (is "?lhs \<longleftrightarrow> ?rhs")
   732 proof
   733   assume ?lhs
   734   moreover from `distinct (map fst xs)` have "set xs = {(k, v). map_of xs k = Some v}"
   735     by (rule set_map_of_compr)
   736   moreover from `distinct (map fst ys)` have "set ys = {(k, v). map_of ys k = Some v}"
   737     by (rule set_map_of_compr)
   738   ultimately show ?rhs by simp
   739 next
   740   assume ?rhs show ?lhs
   741   proof
   742     fix k
   743     show "map_of xs k = map_of ys k" proof (cases "map_of xs k")
   744       case None
   745       with `?rhs` have "map_of ys k = None"
   746         by (simp add: map_of_eq_None_iff)
   747       with None show ?thesis by simp
   748     next
   749       case (Some v)
   750       with distinct `?rhs` have "map_of ys k = Some v"
   751         by simp
   752       with Some show ?thesis by simp
   753     qed
   754   qed
   755 qed
   756 
   757 end