src/HOL/Nat.thy
author haftmann
Sun Sep 21 16:56:11 2014 +0200 (2014-09-21)
changeset 58410 6d46ad54a2ab
parent 58389 ee1f45ca0d73
child 58647 fce800afeec7
permissions -rw-r--r--
explicit separation of signed and unsigned numerals using existing lexical categories num and xnum
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 
    16 named_theorems arith "arith facts -- only ground formulas"
    17 ML_file "Tools/arith_data.ML"
    18 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    19 
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    26   -- {* the axiom of infinity in 2 parts *}
    27   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    28   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    29 
    30 subsection {* Type nat *}
    31 
    32 text {* Type definition *}
    33 
    34 inductive Nat :: "ind \<Rightarrow> bool" where
    35   Zero_RepI: "Nat Zero_Rep"
    36 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    37 
    38 typedef nat = "{n. Nat n}"
    39   morphisms Rep_Nat Abs_Nat
    40   using Nat.Zero_RepI by auto
    41 
    42 lemma Nat_Rep_Nat:
    43   "Nat (Rep_Nat n)"
    44   using Rep_Nat by simp
    45 
    46 lemma Nat_Abs_Nat_inverse:
    47   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    48   using Abs_Nat_inverse by simp
    49 
    50 lemma Nat_Abs_Nat_inject:
    51   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    52   using Abs_Nat_inject by simp
    53 
    54 instantiation nat :: zero
    55 begin
    56 
    57 definition Zero_nat_def:
    58   "0 = Abs_Nat Zero_Rep"
    59 
    60 instance ..
    61 
    62 end
    63 
    64 definition Suc :: "nat \<Rightarrow> nat" where
    65   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    66 
    67 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    68   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    74   by (rule iffI, rule Suc_Rep_inject) simp_all
    75 
    76 lemma nat_induct0:
    77   fixes n
    78   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    79   shows "P n"
    80 using assms
    81 apply (unfold Zero_nat_def Suc_def)
    82 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    83 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    84 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    85 done
    86 
    87 free_constructors case_nat for
    88     "0 \<Colon> nat"
    89   | Suc pred
    90 where
    91   "pred (0 \<Colon> nat) = (0 \<Colon> nat)"
    92     apply atomize_elim
    93     apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    94    apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI Suc_Rep_inject'
    95      Rep_Nat_inject)
    96   apply (simp only: Suc_not_Zero)
    97   done
    98 
    99 -- {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
   100 setup {* Sign.mandatory_path "old" *}
   101 
   102 old_rep_datatype "0 \<Colon> nat" Suc
   103   apply (erule nat_induct0, assumption)
   104  apply (rule nat.inject)
   105 apply (rule nat.distinct(1))
   106 done
   107 
   108 setup {* Sign.parent_path *}
   109 
   110 -- {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   111 setup {* Sign.mandatory_path "nat" *}
   112 
   113 declare
   114   old.nat.inject[iff del]
   115   old.nat.distinct(1)[simp del, induct_simp del]
   116 
   117 lemmas induct = old.nat.induct
   118 lemmas inducts = old.nat.inducts
   119 lemmas rec = old.nat.rec
   120 lemmas simps = nat.inject nat.distinct nat.case nat.rec
   121 
   122 setup {* Sign.parent_path *}
   123 
   124 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   125   "rec_nat \<equiv> old.rec_nat"
   126 
   127 declare nat.sel[code del]
   128 
   129 hide_const (open) Nat.pred -- {* hide everything related to the selector *}
   130 hide_fact
   131   nat.case_eq_if
   132   nat.collapse
   133   nat.expand
   134   nat.sel
   135   nat.exhaust_sel
   136   nat.split_sel
   137   nat.split_sel_asm
   138 
   139 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   140   -- {* for backward compatibility -- names of variables differ *}
   141   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   142 by (rule old.nat.exhaust)
   143 
   144 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   145   -- {* for backward compatibility -- names of variables differ *}
   146   fixes n
   147   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   148   shows "P n"
   149 using assms by (rule nat.induct)
   150 
   151 hide_fact
   152   nat_exhaust
   153   nat_induct0
   154 
   155 ML {*
   156 val nat_basic_lfp_sugar =
   157   let
   158     val ctr_sugar = the (Ctr_Sugar.ctr_sugar_of_global @{theory} @{type_name nat});
   159     val recx = Logic.varify_types_global @{term rec_nat};
   160     val C = body_type (fastype_of recx);
   161   in
   162     {T = HOLogic.natT, fp_res_index = 0, C = C, fun_arg_Tsss = [[], [[HOLogic.natT, C]]],
   163      ctr_sugar = ctr_sugar, recx = recx, rec_thms = @{thms nat.rec}}
   164   end;
   165 *}
   166 
   167 setup {*
   168 let
   169   fun basic_lfp_sugars_of _ [@{typ nat}] _ _ ctxt =
   170       ([], [0], [nat_basic_lfp_sugar], [], [], TrueI (*dummy*), [], false, ctxt)
   171     | basic_lfp_sugars_of bs arg_Ts callers callssss ctxt =
   172       BNF_LFP_Rec_Sugar.default_basic_lfp_sugars_of bs arg_Ts callers callssss ctxt;
   173 in
   174   BNF_LFP_Rec_Sugar.register_lfp_rec_extension
   175     {nested_simps = [], is_new_datatype = K (K true), basic_lfp_sugars_of = basic_lfp_sugars_of,
   176      rewrite_nested_rec_call = NONE}
   177 end
   178 *}
   179 
   180 text {* Injectiveness and distinctness lemmas *}
   181 
   182 lemma inj_Suc[simp]: "inj_on Suc N"
   183   by (simp add: inj_on_def)
   184 
   185 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   186 by (rule notE, rule Suc_not_Zero)
   187 
   188 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   189 by (rule Suc_neq_Zero, erule sym)
   190 
   191 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   192 by (rule inj_Suc [THEN injD])
   193 
   194 lemma n_not_Suc_n: "n \<noteq> Suc n"
   195 by (induct n) simp_all
   196 
   197 lemma Suc_n_not_n: "Suc n \<noteq> n"
   198 by (rule not_sym, rule n_not_Suc_n)
   199 
   200 text {* A special form of induction for reasoning
   201   about @{term "m < n"} and @{term "m - n"} *}
   202 
   203 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   204     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   205   apply (rule_tac x = m in spec)
   206   apply (induct n)
   207   prefer 2
   208   apply (rule allI)
   209   apply (induct_tac x, iprover+)
   210   done
   211 
   212 
   213 subsection {* Arithmetic operators *}
   214 
   215 instantiation nat :: comm_monoid_diff
   216 begin
   217 
   218 primrec plus_nat where
   219   add_0:      "0 + n = (n\<Colon>nat)"
   220 | add_Suc:  "Suc m + n = Suc (m + n)"
   221 
   222 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   223   by (induct m) simp_all
   224 
   225 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   226   by (induct m) simp_all
   227 
   228 declare add_0 [code]
   229 
   230 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   231   by simp
   232 
   233 primrec minus_nat where
   234   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   235 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   236 
   237 declare diff_Suc [simp del]
   238 
   239 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   240   by (induct n) (simp_all add: diff_Suc)
   241 
   242 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   243   by (induct n) (simp_all add: diff_Suc)
   244 
   245 instance proof
   246   fix n m q :: nat
   247   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   248   show "n + m = m + n" by (induct n) simp_all
   249   show "0 + n = n" by simp
   250   show "n - 0 = n" by simp
   251   show "0 - n = 0" by simp
   252   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   253   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   254 qed
   255 
   256 end
   257 
   258 hide_fact (open) add_0 add_0_right diff_0
   259 
   260 instantiation nat :: comm_semiring_1_cancel
   261 begin
   262 
   263 definition
   264   One_nat_def [simp]: "1 = Suc 0"
   265 
   266 primrec times_nat where
   267   mult_0:     "0 * n = (0\<Colon>nat)"
   268 | mult_Suc: "Suc m * n = n + (m * n)"
   269 
   270 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   271   by (induct m) simp_all
   272 
   273 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   274   by (induct m) (simp_all add: add.left_commute)
   275 
   276 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   277   by (induct m) (simp_all add: add.assoc)
   278 
   279 instance proof
   280   fix n m q :: nat
   281   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   282   show "1 * n = n" unfolding One_nat_def by simp
   283   show "n * m = m * n" by (induct n) simp_all
   284   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   285   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   286   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   287 qed
   288 
   289 end
   290 
   291 subsubsection {* Addition *}
   292 
   293 lemma nat_add_left_cancel:
   294   fixes k m n :: nat
   295   shows "k + m = k + n \<longleftrightarrow> m = n"
   296   by (fact add_left_cancel)
   297 
   298 lemma nat_add_right_cancel:
   299   fixes k m n :: nat
   300   shows "m + k = n + k \<longleftrightarrow> m = n"
   301   by (fact add_right_cancel)
   302 
   303 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   304 
   305 lemma add_is_0 [iff]:
   306   fixes m n :: nat
   307   shows "(m + n = 0) = (m = 0 & n = 0)"
   308   by (cases m) simp_all
   309 
   310 lemma add_is_1:
   311   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   312   by (cases m) simp_all
   313 
   314 lemma one_is_add:
   315   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   316   by (rule trans, rule eq_commute, rule add_is_1)
   317 
   318 lemma add_eq_self_zero:
   319   fixes m n :: nat
   320   shows "m + n = m \<Longrightarrow> n = 0"
   321   by (induct m) simp_all
   322 
   323 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   324   apply (induct k)
   325    apply simp
   326   apply(drule comp_inj_on[OF _ inj_Suc])
   327   apply (simp add:o_def)
   328   done
   329 
   330 lemma Suc_eq_plus1: "Suc n = n + 1"
   331   unfolding One_nat_def by simp
   332 
   333 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   334   unfolding One_nat_def by simp
   335 
   336 
   337 subsubsection {* Difference *}
   338 
   339 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   340   by (fact diff_cancel)
   341 
   342 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   343   by (fact diff_diff_add)
   344 
   345 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   346   by (simp add: diff_diff_left)
   347 
   348 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   349   by (fact diff_right_commute)
   350 
   351 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   352   by (fact add_diff_cancel_left')
   353 
   354 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   355   by (fact add_diff_cancel_right')
   356 
   357 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   358   by (fact comm_monoid_diff_class.add_diff_cancel_left)
   359 
   360 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   361   by (fact add_diff_cancel_right)
   362 
   363 lemma diff_add_0: "n - (n + m) = (0::nat)"
   364   by (fact diff_add_zero)
   365 
   366 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   367   unfolding One_nat_def by simp
   368 
   369 text {* Difference distributes over multiplication *}
   370 
   371 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   372 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   373 
   374 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   375 by (simp add: diff_mult_distrib mult.commute [of k])
   376   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   377 
   378 
   379 subsubsection {* Multiplication *}
   380 
   381 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   382   by (fact distrib_left)
   383 
   384 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   385   by (induct m) auto
   386 
   387 lemmas nat_distrib =
   388   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   389 
   390 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   391   apply (induct m)
   392    apply simp
   393   apply (induct n)
   394    apply auto
   395   done
   396 
   397 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   398   apply (rule trans)
   399   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   400   done
   401 
   402 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   403   unfolding One_nat_def by (rule mult_eq_1_iff)
   404 
   405 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   406   unfolding One_nat_def by (rule one_eq_mult_iff)
   407 
   408 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   409 proof -
   410   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   411   proof (induct n arbitrary: m)
   412     case 0 then show "m = 0" by simp
   413   next
   414     case (Suc n) then show "m = Suc n"
   415       by (cases m) (simp_all add: eq_commute [of "0"])
   416   qed
   417   then show ?thesis by auto
   418 qed
   419 
   420 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   421   by (simp add: mult.commute)
   422 
   423 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   424   by (subst mult_cancel1) simp
   425 
   426 
   427 subsection {* Orders on @{typ nat} *}
   428 
   429 subsubsection {* Operation definition *}
   430 
   431 instantiation nat :: linorder
   432 begin
   433 
   434 primrec less_eq_nat where
   435   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   436 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   437 
   438 declare less_eq_nat.simps [simp del]
   439 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   440 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   441 
   442 definition less_nat where
   443   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   444 
   445 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   446   by (simp add: less_eq_nat.simps(2))
   447 
   448 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   449   unfolding less_eq_Suc_le ..
   450 
   451 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   452   by (induct n) (simp_all add: less_eq_nat.simps(2))
   453 
   454 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   455   by (simp add: less_eq_Suc_le)
   456 
   457 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   458   by simp
   459 
   460 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   461   by (simp add: less_eq_Suc_le)
   462 
   463 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   464   by (simp add: less_eq_Suc_le)
   465 
   466 lemma Suc_less_eq2: "Suc n < m \<longleftrightarrow> (\<exists>m'. m = Suc m' \<and> n < m')"
   467   by (cases m) auto
   468 
   469 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   470   by (induct m arbitrary: n)
   471     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   472 
   473 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   474   by (cases n) (auto intro: le_SucI)
   475 
   476 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   477   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   478 
   479 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   480   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   481 
   482 instance
   483 proof
   484   fix n m :: nat
   485   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   486   proof (induct n arbitrary: m)
   487     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   488   next
   489     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   490   qed
   491 next
   492   fix n :: nat show "n \<le> n" by (induct n) simp_all
   493 next
   494   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   495   then show "n = m"
   496     by (induct n arbitrary: m)
   497       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   498 next
   499   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   500   then show "n \<le> q"
   501   proof (induct n arbitrary: m q)
   502     case 0 show ?case by simp
   503   next
   504     case (Suc n) then show ?case
   505       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   506         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   507         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   508   qed
   509 next
   510   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   511     by (induct n arbitrary: m)
   512       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   513 qed
   514 
   515 end
   516 
   517 instantiation nat :: order_bot
   518 begin
   519 
   520 definition bot_nat :: nat where
   521   "bot_nat = 0"
   522 
   523 instance proof
   524 qed (simp add: bot_nat_def)
   525 
   526 end
   527 
   528 instance nat :: no_top
   529   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   530 
   531 
   532 subsubsection {* Introduction properties *}
   533 
   534 lemma lessI [iff]: "n < Suc n"
   535   by (simp add: less_Suc_eq_le)
   536 
   537 lemma zero_less_Suc [iff]: "0 < Suc n"
   538   by (simp add: less_Suc_eq_le)
   539 
   540 
   541 subsubsection {* Elimination properties *}
   542 
   543 lemma less_not_refl: "~ n < (n::nat)"
   544   by (rule order_less_irrefl)
   545 
   546 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   547   by (rule not_sym) (rule less_imp_neq) 
   548 
   549 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   550   by (rule less_imp_neq)
   551 
   552 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   553   by (rule notE, rule less_not_refl)
   554 
   555 lemma less_zeroE: "(n::nat) < 0 ==> R"
   556   by (rule notE) (rule not_less0)
   557 
   558 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   559   unfolding less_Suc_eq_le le_less ..
   560 
   561 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   562   by (simp add: less_Suc_eq)
   563 
   564 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   565   unfolding One_nat_def by (rule less_Suc0)
   566 
   567 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   568   by simp
   569 
   570 text {* "Less than" is antisymmetric, sort of *}
   571 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   572   unfolding not_less less_Suc_eq_le by (rule antisym)
   573 
   574 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   575   by (rule linorder_neq_iff)
   576 
   577 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   578   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   579   shows "P n m"
   580   apply (rule less_linear [THEN disjE])
   581   apply (erule_tac [2] disjE)
   582   apply (erule lessCase)
   583   apply (erule sym [THEN eqCase])
   584   apply (erule major)
   585   done
   586 
   587 
   588 subsubsection {* Inductive (?) properties *}
   589 
   590 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   591   unfolding less_eq_Suc_le [of m] le_less by simp 
   592 
   593 lemma lessE:
   594   assumes major: "i < k"
   595   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   596   shows P
   597 proof -
   598   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   599     unfolding less_eq_Suc_le by (induct k) simp_all
   600   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   601     by (clarsimp simp add: less_le)
   602   with p1 p2 show P by auto
   603 qed
   604 
   605 lemma less_SucE: assumes major: "m < Suc n"
   606   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   607   apply (rule major [THEN lessE])
   608   apply (rule eq, blast)
   609   apply (rule less, blast)
   610   done
   611 
   612 lemma Suc_lessE: assumes major: "Suc i < k"
   613   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   614   apply (rule major [THEN lessE])
   615   apply (erule lessI [THEN minor])
   616   apply (erule Suc_lessD [THEN minor], assumption)
   617   done
   618 
   619 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   620   by simp
   621 
   622 lemma less_trans_Suc:
   623   assumes le: "i < j" shows "j < k ==> Suc i < k"
   624   apply (induct k, simp_all)
   625   apply (insert le)
   626   apply (simp add: less_Suc_eq)
   627   apply (blast dest: Suc_lessD)
   628   done
   629 
   630 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   631 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   632   unfolding not_less less_Suc_eq_le ..
   633 
   634 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   635   unfolding not_le Suc_le_eq ..
   636 
   637 text {* Properties of "less than or equal" *}
   638 
   639 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   640   unfolding less_Suc_eq_le .
   641 
   642 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   643   unfolding not_le less_Suc_eq_le ..
   644 
   645 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   646   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   647 
   648 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   649   by (drule le_Suc_eq [THEN iffD1], iprover+)
   650 
   651 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   652   unfolding Suc_le_eq .
   653 
   654 text {* Stronger version of @{text Suc_leD} *}
   655 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   656   unfolding Suc_le_eq .
   657 
   658 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   659   unfolding less_eq_Suc_le by (rule Suc_leD)
   660 
   661 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   662 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   663 
   664 
   665 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   666 
   667 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   668   unfolding le_less .
   669 
   670 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   671   by (rule le_less)
   672 
   673 text {* Useful with @{text blast}. *}
   674 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   675   by auto
   676 
   677 lemma le_refl: "n \<le> (n::nat)"
   678   by simp
   679 
   680 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   681   by (rule order_trans)
   682 
   683 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   684   by (rule antisym)
   685 
   686 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   687   by (rule less_le)
   688 
   689 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   690   unfolding less_le ..
   691 
   692 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   693   by (rule linear)
   694 
   695 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   696 
   697 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   698   unfolding less_Suc_eq_le by auto
   699 
   700 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   701   unfolding not_less by (rule le_less_Suc_eq)
   702 
   703 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   704 
   705 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   706 by (cases n) simp_all
   707 
   708 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   709 by (cases n) simp_all
   710 
   711 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   712 by (cases n) simp_all
   713 
   714 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   715 by (cases n) simp_all
   716 
   717 text {* This theorem is useful with @{text blast} *}
   718 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   719 by (rule neq0_conv[THEN iffD1], iprover)
   720 
   721 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   722 by (fast intro: not0_implies_Suc)
   723 
   724 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   725 using neq0_conv by blast
   726 
   727 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   728 by (induct m') simp_all
   729 
   730 text {* Useful in certain inductive arguments *}
   731 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   732 by (cases m) simp_all
   733 
   734 
   735 subsubsection {* Monotonicity of Addition *}
   736 
   737 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   738 by (simp add: diff_Suc split: nat.split)
   739 
   740 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   741 unfolding One_nat_def by (rule Suc_pred)
   742 
   743 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   744 by (induct k) simp_all
   745 
   746 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   747 by (induct k) simp_all
   748 
   749 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   750 by(auto dest:gr0_implies_Suc)
   751 
   752 text {* strict, in 1st argument *}
   753 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   754 by (induct k) simp_all
   755 
   756 text {* strict, in both arguments *}
   757 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   758   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   759   apply (induct j, simp_all)
   760   done
   761 
   762 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   763 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   764   apply (induct n)
   765   apply (simp_all add: order_le_less)
   766   apply (blast elim!: less_SucE
   767                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   768   done
   769 
   770 lemma le_Suc_ex: "(k::nat) \<le> l \<Longrightarrow> (\<exists>n. l = k + n)"
   771   by (auto simp: less_Suc_eq_le[symmetric] dest: less_imp_Suc_add)
   772 
   773 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   774 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   775 apply(auto simp: gr0_conv_Suc)
   776 apply (induct_tac m)
   777 apply (simp_all add: add_less_mono)
   778 done
   779 
   780 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   781 instance nat :: linordered_semidom
   782 proof
   783   show "0 < (1::nat)" by simp
   784   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   785   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   786 qed
   787 
   788 instance nat :: no_zero_divisors
   789 proof
   790   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   791 qed
   792 
   793 
   794 subsubsection {* @{term min} and @{term max} *}
   795 
   796 lemma mono_Suc: "mono Suc"
   797 by (rule monoI) simp
   798 
   799 lemma min_0L [simp]: "min 0 n = (0::nat)"
   800 by (rule min_absorb1) simp
   801 
   802 lemma min_0R [simp]: "min n 0 = (0::nat)"
   803 by (rule min_absorb2) simp
   804 
   805 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   806 by (simp add: mono_Suc min_of_mono)
   807 
   808 lemma min_Suc1:
   809    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   810 by (simp split: nat.split)
   811 
   812 lemma min_Suc2:
   813    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   814 by (simp split: nat.split)
   815 
   816 lemma max_0L [simp]: "max 0 n = (n::nat)"
   817 by (rule max_absorb2) simp
   818 
   819 lemma max_0R [simp]: "max n 0 = (n::nat)"
   820 by (rule max_absorb1) simp
   821 
   822 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   823 by (simp add: mono_Suc max_of_mono)
   824 
   825 lemma max_Suc1:
   826    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   827 by (simp split: nat.split)
   828 
   829 lemma max_Suc2:
   830    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   831 by (simp split: nat.split)
   832 
   833 lemma nat_mult_min_left:
   834   fixes m n q :: nat
   835   shows "min m n * q = min (m * q) (n * q)"
   836   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   837 
   838 lemma nat_mult_min_right:
   839   fixes m n q :: nat
   840   shows "m * min n q = min (m * n) (m * q)"
   841   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   842 
   843 lemma nat_add_max_left:
   844   fixes m n q :: nat
   845   shows "max m n + q = max (m + q) (n + q)"
   846   by (simp add: max_def)
   847 
   848 lemma nat_add_max_right:
   849   fixes m n q :: nat
   850   shows "m + max n q = max (m + n) (m + q)"
   851   by (simp add: max_def)
   852 
   853 lemma nat_mult_max_left:
   854   fixes m n q :: nat
   855   shows "max m n * q = max (m * q) (n * q)"
   856   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   857 
   858 lemma nat_mult_max_right:
   859   fixes m n q :: nat
   860   shows "m * max n q = max (m * n) (m * q)"
   861   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   862 
   863 
   864 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   865 
   866 text {* Complete induction, aka course-of-values induction *}
   867 
   868 instance nat :: wellorder proof
   869   fix P and n :: nat
   870   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   871   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   872   proof (induct n)
   873     case (0 n)
   874     have "P 0" by (rule step) auto
   875     thus ?case using 0 by auto
   876   next
   877     case (Suc m n)
   878     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   879     thus ?case
   880     proof
   881       assume "n \<le> m" thus "P n" by (rule Suc(1))
   882     next
   883       assume n: "n = Suc m"
   884       show "P n"
   885         by (rule step) (rule Suc(1), simp add: n le_simps)
   886     qed
   887   qed
   888   then show "P n" by auto
   889 qed
   890 
   891 
   892 lemma Least_eq_0[simp]: "P(0::nat) \<Longrightarrow> Least P = 0"
   893 by (rule Least_equality[OF _ le0])
   894 
   895 lemma Least_Suc:
   896      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   897   apply (cases n, auto)
   898   apply (frule LeastI)
   899   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   900   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   901   apply (erule_tac [2] Least_le)
   902   apply (cases "LEAST x. P x", auto)
   903   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   904   apply (blast intro: order_antisym)
   905   done
   906 
   907 lemma Least_Suc2:
   908    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   909   apply (erule (1) Least_Suc [THEN ssubst])
   910   apply simp
   911   done
   912 
   913 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   914   apply (cases n)
   915    apply blast
   916   apply (rule_tac x="LEAST k. P(k)" in exI)
   917   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   918   done
   919 
   920 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   921   unfolding One_nat_def
   922   apply (cases n)
   923    apply blast
   924   apply (frule (1) ex_least_nat_le)
   925   apply (erule exE)
   926   apply (case_tac k)
   927    apply simp
   928   apply (rename_tac k1)
   929   apply (rule_tac x=k1 in exI)
   930   apply (auto simp add: less_eq_Suc_le)
   931   done
   932 
   933 lemma nat_less_induct:
   934   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   935   using assms less_induct by blast
   936 
   937 lemma measure_induct_rule [case_names less]:
   938   fixes f :: "'a \<Rightarrow> nat"
   939   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   940   shows "P a"
   941 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   942 
   943 text {* old style induction rules: *}
   944 lemma measure_induct:
   945   fixes f :: "'a \<Rightarrow> nat"
   946   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   947   by (rule measure_induct_rule [of f P a]) iprover
   948 
   949 lemma full_nat_induct:
   950   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   951   shows "P n"
   952   by (rule less_induct) (auto intro: step simp:le_simps)
   953 
   954 text{*An induction rule for estabilishing binary relations*}
   955 lemma less_Suc_induct:
   956   assumes less:  "i < j"
   957      and  step:  "!!i. P i (Suc i)"
   958      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   959   shows "P i j"
   960 proof -
   961   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   962   have "P i (Suc (i + k))"
   963   proof (induct k)
   964     case 0
   965     show ?case by (simp add: step)
   966   next
   967     case (Suc k)
   968     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   969     hence "i < Suc (i + k)" by (simp add: add.commute)
   970     from trans[OF this lessI Suc step]
   971     show ?case by simp
   972   qed
   973   thus "P i j" by (simp add: j)
   974 qed
   975 
   976 text {* The method of infinite descent, frequently used in number theory.
   977 Provided by Roelof Oosterhuis.
   978 $P(n)$ is true for all $n\in\mathbb{N}$ if
   979 \begin{itemize}
   980   \item case ``0'': given $n=0$ prove $P(n)$,
   981   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   982         a smaller integer $m$ such that $\neg P(m)$.
   983 \end{itemize} *}
   984 
   985 text{* A compact version without explicit base case: *}
   986 lemma infinite_descent:
   987   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   988 by (induct n rule: less_induct) auto
   989 
   990 lemma infinite_descent0[case_names 0 smaller]: 
   991   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   992 by (rule infinite_descent) (case_tac "n>0", auto)
   993 
   994 text {*
   995 Infinite descent using a mapping to $\mathbb{N}$:
   996 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   997 \begin{itemize}
   998 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   999 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
  1000 \end{itemize}
  1001 NB: the proof also shows how to use the previous lemma. *}
  1002 
  1003 corollary infinite_descent0_measure [case_names 0 smaller]:
  1004   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
  1005     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
  1006   shows "P x"
  1007 proof -
  1008   obtain n where "n = V x" by auto
  1009   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
  1010   proof (induct n rule: infinite_descent0)
  1011     case 0 -- "i.e. $V(x) = 0$"
  1012     with A0 show "P x" by auto
  1013   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
  1014     case (smaller n)
  1015     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
  1016     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
  1017     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
  1018     then show ?case by auto
  1019   qed
  1020   ultimately show "P x" by auto
  1021 qed
  1022 
  1023 text{* Again, without explicit base case: *}
  1024 lemma infinite_descent_measure:
  1025 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
  1026 proof -
  1027   from assms obtain n where "n = V x" by auto
  1028   moreover have "!!x. V x = n \<Longrightarrow> P x"
  1029   proof (induct n rule: infinite_descent, auto)
  1030     fix x assume "\<not> P x"
  1031     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1032   qed
  1033   ultimately show "P x" by auto
  1034 qed
  1035 
  1036 text {* A [clumsy] way of lifting @{text "<"}
  1037   monotonicity to @{text "\<le>"} monotonicity *}
  1038 lemma less_mono_imp_le_mono:
  1039   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1040 by (simp add: order_le_less) (blast)
  1041 
  1042 
  1043 text {* non-strict, in 1st argument *}
  1044 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1045 by (rule add_right_mono)
  1046 
  1047 text {* non-strict, in both arguments *}
  1048 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1049 by (rule add_mono)
  1050 
  1051 lemma le_add2: "n \<le> ((m + n)::nat)"
  1052 by (insert add_right_mono [of 0 m n], simp)
  1053 
  1054 lemma le_add1: "n \<le> ((n + m)::nat)"
  1055 by (simp add: add.commute, rule le_add2)
  1056 
  1057 lemma less_add_Suc1: "i < Suc (i + m)"
  1058 by (rule le_less_trans, rule le_add1, rule lessI)
  1059 
  1060 lemma less_add_Suc2: "i < Suc (m + i)"
  1061 by (rule le_less_trans, rule le_add2, rule lessI)
  1062 
  1063 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1064 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1065 
  1066 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1067 by (rule le_trans, assumption, rule le_add1)
  1068 
  1069 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1070 by (rule le_trans, assumption, rule le_add2)
  1071 
  1072 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1073 by (rule less_le_trans, assumption, rule le_add1)
  1074 
  1075 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1076 by (rule less_le_trans, assumption, rule le_add2)
  1077 
  1078 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1079 apply (rule le_less_trans [of _ "i+j"])
  1080 apply (simp_all add: le_add1)
  1081 done
  1082 
  1083 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1084 apply (rule notI)
  1085 apply (drule add_lessD1)
  1086 apply (erule less_irrefl [THEN notE])
  1087 done
  1088 
  1089 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1090 by (simp add: add.commute)
  1091 
  1092 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1093 apply (rule order_trans [of _ "m+k"])
  1094 apply (simp_all add: le_add1)
  1095 done
  1096 
  1097 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1098 apply (simp add: add.commute)
  1099 apply (erule add_leD1)
  1100 done
  1101 
  1102 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1103 by (blast dest: add_leD1 add_leD2)
  1104 
  1105 text {* needs @{text "!!k"} for @{text ac_simps} to work *}
  1106 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1107 by (force simp del: add_Suc_right
  1108     simp add: less_iff_Suc_add add_Suc_right [symmetric] ac_simps)
  1109 
  1110 
  1111 subsubsection {* More results about difference *}
  1112 
  1113 text {* Addition is the inverse of subtraction:
  1114   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1115 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1116 by (induct m n rule: diff_induct) simp_all
  1117 
  1118 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1119 by (simp add: add_diff_inverse linorder_not_less)
  1120 
  1121 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1122 by (simp add: add.commute)
  1123 
  1124 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1125 by (induct m n rule: diff_induct) simp_all
  1126 
  1127 lemma diff_less_Suc: "m - n < Suc m"
  1128 apply (induct m n rule: diff_induct)
  1129 apply (erule_tac [3] less_SucE)
  1130 apply (simp_all add: less_Suc_eq)
  1131 done
  1132 
  1133 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1134 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1135 
  1136 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1137   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1138 
  1139 instance nat :: ordered_cancel_comm_monoid_diff
  1140 proof
  1141   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1142 qed
  1143 
  1144 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1145 by (rule le_less_trans, rule diff_le_self)
  1146 
  1147 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1148 by (cases n) (auto simp add: le_simps)
  1149 
  1150 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1151 by (induct j k rule: diff_induct) simp_all
  1152 
  1153 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1154 by (simp add: add.commute diff_add_assoc)
  1155 
  1156 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1157 by (auto simp add: diff_add_inverse2)
  1158 
  1159 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1160 by (induct m n rule: diff_induct) simp_all
  1161 
  1162 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1163 by (rule iffD2, rule diff_is_0_eq)
  1164 
  1165 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1166 by (induct m n rule: diff_induct) simp_all
  1167 
  1168 lemma less_imp_add_positive:
  1169   assumes "i < j"
  1170   shows "\<exists>k::nat. 0 < k & i + k = j"
  1171 proof
  1172   from assms show "0 < j - i & i + (j - i) = j"
  1173     by (simp add: order_less_imp_le)
  1174 qed
  1175 
  1176 text {* a nice rewrite for bounded subtraction *}
  1177 lemma nat_minus_add_max:
  1178   fixes n m :: nat
  1179   shows "n - m + m = max n m"
  1180     by (simp add: max_def not_le order_less_imp_le)
  1181 
  1182 lemma nat_diff_split:
  1183   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1184     -- {* elimination of @{text -} on @{text nat} *}
  1185 by (cases "a < b")
  1186   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1187     not_less le_less dest!: add_eq_self_zero add_eq_self_zero[OF sym])
  1188 
  1189 lemma nat_diff_split_asm:
  1190   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1191     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1192 by (auto split: nat_diff_split)
  1193 
  1194 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1195   by simp
  1196 
  1197 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1198   unfolding One_nat_def by (cases m) simp_all
  1199 
  1200 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1201   unfolding One_nat_def by (cases m) simp_all
  1202 
  1203 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1204   unfolding One_nat_def by (cases n) simp_all
  1205 
  1206 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1207   unfolding One_nat_def by (cases m) simp_all
  1208 
  1209 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1210   by (fact Let_def)
  1211 
  1212 
  1213 subsubsection {* Monotonicity of multiplication *}
  1214 
  1215 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1216 by (simp add: mult_right_mono)
  1217 
  1218 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1219 by (simp add: mult_left_mono)
  1220 
  1221 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1222 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1223 by (simp add: mult_mono)
  1224 
  1225 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1226 by (simp add: mult_strict_right_mono)
  1227 
  1228 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1229       there are no negative numbers.*}
  1230 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1231   apply (induct m)
  1232    apply simp
  1233   apply (case_tac n)
  1234    apply simp_all
  1235   done
  1236 
  1237 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1238   apply (induct m)
  1239    apply simp
  1240   apply (case_tac n)
  1241    apply simp_all
  1242   done
  1243 
  1244 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1245   apply (safe intro!: mult_less_mono1)
  1246   apply (cases k, auto)
  1247   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1248   apply (blast intro: mult_le_mono1)
  1249   done
  1250 
  1251 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1252 by (simp add: mult.commute [of k])
  1253 
  1254 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1255 by (simp add: linorder_not_less [symmetric], auto)
  1256 
  1257 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1258 by (simp add: linorder_not_less [symmetric], auto)
  1259 
  1260 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1261 by (subst mult_less_cancel1) simp
  1262 
  1263 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1264 by (subst mult_le_cancel1) simp
  1265 
  1266 lemma le_square: "m \<le> m * (m::nat)"
  1267   by (cases m) (auto intro: le_add1)
  1268 
  1269 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1270   by (cases m) (auto intro: le_add1)
  1271 
  1272 text {* Lemma for @{text gcd} *}
  1273 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1274   apply (drule sym)
  1275   apply (rule disjCI)
  1276   apply (rule nat_less_cases, erule_tac [2] _)
  1277    apply (drule_tac [2] mult_less_mono2)
  1278     apply (auto)
  1279   done
  1280 
  1281 lemma mono_times_nat:
  1282   fixes n :: nat
  1283   assumes "n > 0"
  1284   shows "mono (times n)"
  1285 proof
  1286   fix m q :: nat
  1287   assume "m \<le> q"
  1288   with assms show "n * m \<le> n * q" by simp
  1289 qed
  1290 
  1291 text {* the lattice order on @{typ nat} *}
  1292 
  1293 instantiation nat :: distrib_lattice
  1294 begin
  1295 
  1296 definition
  1297   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1298 
  1299 definition
  1300   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1301 
  1302 instance by intro_classes
  1303   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1304     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1305 
  1306 end
  1307 
  1308 
  1309 subsection {* Natural operation of natural numbers on functions *}
  1310 
  1311 text {*
  1312   We use the same logical constant for the power operations on
  1313   functions and relations, in order to share the same syntax.
  1314 *}
  1315 
  1316 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1317 
  1318 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1319   "f ^^ n \<equiv> compow n f"
  1320 
  1321 notation (latex output)
  1322   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1323 
  1324 notation (HTML output)
  1325   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1326 
  1327 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1328 
  1329 overloading
  1330   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1331 begin
  1332 
  1333 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1334   "funpow 0 f = id"
  1335 | "funpow (Suc n) f = f o funpow n f"
  1336 
  1337 end
  1338 
  1339 lemma funpow_Suc_right:
  1340   "f ^^ Suc n = f ^^ n \<circ> f"
  1341 proof (induct n)
  1342   case 0 then show ?case by simp
  1343 next
  1344   fix n
  1345   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1346   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1347     by (simp add: o_assoc)
  1348 qed
  1349 
  1350 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1351 
  1352 text {* for code generation *}
  1353 
  1354 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1355   funpow_code_def [code_abbrev]: "funpow = compow"
  1356 
  1357 lemma [code]:
  1358   "funpow (Suc n) f = f o funpow n f"
  1359   "funpow 0 f = id"
  1360   by (simp_all add: funpow_code_def)
  1361 
  1362 hide_const (open) funpow
  1363 
  1364 lemma funpow_add:
  1365   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1366   by (induct m) simp_all
  1367 
  1368 lemma funpow_mult:
  1369   fixes f :: "'a \<Rightarrow> 'a"
  1370   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1371   by (induct n) (simp_all add: funpow_add)
  1372 
  1373 lemma funpow_swap1:
  1374   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1375 proof -
  1376   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1377   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1378   also have "\<dots> = (f ^^ n) (f x)" by simp
  1379   finally show ?thesis .
  1380 qed
  1381 
  1382 lemma comp_funpow:
  1383   fixes f :: "'a \<Rightarrow> 'a"
  1384   shows "comp f ^^ n = comp (f ^^ n)"
  1385   by (induct n) simp_all
  1386 
  1387 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1388   by (induct n) simp_all
  1389 
  1390 lemma id_funpow[simp]: "id ^^ n = id"
  1391   by (induct n) simp_all
  1392 
  1393 subsection {* Kleene iteration *}
  1394 
  1395 lemma Kleene_iter_lpfp:
  1396 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1397 proof(induction k)
  1398   case 0 show ?case by simp
  1399 next
  1400   case Suc
  1401   from monoD[OF assms(1) Suc] assms(2)
  1402   show ?case by simp
  1403 qed
  1404 
  1405 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1406 shows "lfp f = (f^^k) bot"
  1407 proof(rule antisym)
  1408   show "lfp f \<le> (f^^k) bot"
  1409   proof(rule lfp_lowerbound)
  1410     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1411   qed
  1412 next
  1413   show "(f^^k) bot \<le> lfp f"
  1414     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1415 qed
  1416 
  1417 
  1418 subsection {* Embedding of the naturals into any @{text semiring_1}: @{term of_nat} *}
  1419 
  1420 context semiring_1
  1421 begin
  1422 
  1423 definition of_nat :: "nat \<Rightarrow> 'a" where
  1424   "of_nat n = (plus 1 ^^ n) 0"
  1425 
  1426 lemma of_nat_simps [simp]:
  1427   shows of_nat_0: "of_nat 0 = 0"
  1428     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1429   by (simp_all add: of_nat_def)
  1430 
  1431 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1432   by (simp add: of_nat_def)
  1433 
  1434 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1435   by (induct m) (simp_all add: ac_simps)
  1436 
  1437 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1438   by (induct m) (simp_all add: ac_simps distrib_right)
  1439 
  1440 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1441   "of_nat_aux inc 0 i = i"
  1442 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1443 
  1444 lemma of_nat_code:
  1445   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1446 proof (induct n)
  1447   case 0 then show ?case by simp
  1448 next
  1449   case (Suc n)
  1450   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1451     by (induct n) simp_all
  1452   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1453     by simp
  1454   with Suc show ?case by (simp add: add.commute)
  1455 qed
  1456 
  1457 end
  1458 
  1459 declare of_nat_code [code]
  1460 
  1461 text{*Class for unital semirings with characteristic zero.
  1462  Includes non-ordered rings like the complex numbers.*}
  1463 
  1464 class semiring_char_0 = semiring_1 +
  1465   assumes inj_of_nat: "inj of_nat"
  1466 begin
  1467 
  1468 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1469   by (auto intro: inj_of_nat injD)
  1470 
  1471 text{*Special cases where either operand is zero*}
  1472 
  1473 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1474   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1475 
  1476 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1477   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1478 
  1479 end
  1480 
  1481 context linordered_semidom
  1482 begin
  1483 
  1484 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1485   by (induct n) simp_all
  1486 
  1487 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1488   by (simp add: not_less)
  1489 
  1490 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1491   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1492 
  1493 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1494   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1495 
  1496 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1497   by simp
  1498 
  1499 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1500   by simp
  1501 
  1502 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1503 
  1504 subclass semiring_char_0 proof
  1505 qed (auto intro!: injI simp add: eq_iff)
  1506 
  1507 text{*Special cases where either operand is zero*}
  1508 
  1509 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1510   by (rule of_nat_le_iff [of _ 0, simplified])
  1511 
  1512 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1513   by (rule of_nat_less_iff [of 0, simplified])
  1514 
  1515 end
  1516 
  1517 context ring_1
  1518 begin
  1519 
  1520 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1521 by (simp add: algebra_simps of_nat_add [symmetric])
  1522 
  1523 end
  1524 
  1525 context linordered_idom
  1526 begin
  1527 
  1528 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1529   unfolding abs_if by auto
  1530 
  1531 end
  1532 
  1533 lemma of_nat_id [simp]: "of_nat n = n"
  1534   by (induct n) simp_all
  1535 
  1536 lemma of_nat_eq_id [simp]: "of_nat = id"
  1537   by (auto simp add: fun_eq_iff)
  1538 
  1539 
  1540 subsection {* The set of natural numbers *}
  1541 
  1542 context semiring_1
  1543 begin
  1544 
  1545 definition Nats  :: "'a set" where
  1546   "Nats = range of_nat"
  1547 
  1548 notation (xsymbols)
  1549   Nats  ("\<nat>")
  1550 
  1551 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1552   by (simp add: Nats_def)
  1553 
  1554 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1555 apply (simp add: Nats_def)
  1556 apply (rule range_eqI)
  1557 apply (rule of_nat_0 [symmetric])
  1558 done
  1559 
  1560 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1561 apply (simp add: Nats_def)
  1562 apply (rule range_eqI)
  1563 apply (rule of_nat_1 [symmetric])
  1564 done
  1565 
  1566 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1567 apply (auto simp add: Nats_def)
  1568 apply (rule range_eqI)
  1569 apply (rule of_nat_add [symmetric])
  1570 done
  1571 
  1572 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1573 apply (auto simp add: Nats_def)
  1574 apply (rule range_eqI)
  1575 apply (rule of_nat_mult [symmetric])
  1576 done
  1577 
  1578 lemma Nats_cases [cases set: Nats]:
  1579   assumes "x \<in> \<nat>"
  1580   obtains (of_nat) n where "x = of_nat n"
  1581   unfolding Nats_def
  1582 proof -
  1583   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1584   then obtain n where "x = of_nat n" ..
  1585   then show thesis ..
  1586 qed
  1587 
  1588 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1589   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1590   by (rule Nats_cases) auto
  1591 
  1592 end
  1593 
  1594 
  1595 subsection {* Further arithmetic facts concerning the natural numbers *}
  1596 
  1597 lemma subst_equals:
  1598   assumes 1: "t = s" and 2: "u = t"
  1599   shows "u = s"
  1600   using 2 1 by (rule trans)
  1601 
  1602 setup Arith_Data.setup
  1603 
  1604 ML_file "Tools/nat_arith.ML"
  1605 
  1606 simproc_setup nateq_cancel_sums
  1607   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1608   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1609 
  1610 simproc_setup natless_cancel_sums
  1611   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1612   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1613 
  1614 simproc_setup natle_cancel_sums
  1615   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1616   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1617 
  1618 simproc_setup natdiff_cancel_sums
  1619   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1620   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1621 
  1622 ML_file "Tools/lin_arith.ML"
  1623 setup {* Lin_Arith.global_setup *}
  1624 declaration {* K Lin_Arith.setup *}
  1625 
  1626 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1627   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1628 (* Because of this simproc, the arithmetic solver is really only
  1629 useful to detect inconsistencies among the premises for subgoals which are
  1630 *not* themselves (in)equalities, because the latter activate
  1631 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1632 solver all the time rather than add the additional check. *)
  1633 
  1634 
  1635 lemmas [arith_split] = nat_diff_split split_min split_max
  1636 
  1637 context order
  1638 begin
  1639 
  1640 lemma lift_Suc_mono_le:
  1641   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1642   shows "f n \<le> f n'"
  1643 proof (cases "n < n'")
  1644   case True
  1645   then show ?thesis
  1646     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1647 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1648 
  1649 lemma lift_Suc_antimono_le:
  1650   assumes mono: "\<And>n. f n \<ge> f (Suc n)" and "n \<le> n'"
  1651   shows "f n \<ge> f n'"
  1652 proof (cases "n < n'")
  1653   case True
  1654   then show ?thesis
  1655     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1656 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1657 
  1658 lemma lift_Suc_mono_less:
  1659   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1660   shows "f n < f n'"
  1661 using `n < n'`
  1662 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1663 
  1664 lemma lift_Suc_mono_less_iff:
  1665   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1666   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1667     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1668 
  1669 end
  1670 
  1671 lemma mono_iff_le_Suc:
  1672   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1673   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1674 
  1675 lemma antimono_iff_le_Suc:
  1676   "antimono f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1677   unfolding antimono_def by (auto intro: lift_Suc_antimono_le [of f])
  1678 
  1679 lemma mono_nat_linear_lb:
  1680   fixes f :: "nat \<Rightarrow> nat"
  1681   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1682   shows "f m + k \<le> f (m + k)"
  1683 proof (induct k)
  1684   case 0 then show ?case by simp
  1685 next
  1686   case (Suc k)
  1687   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1688   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1689     by (simp add: Suc_le_eq)
  1690   finally show ?case by simp
  1691 qed
  1692 
  1693 
  1694 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1695 
  1696 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1697 by arith
  1698 
  1699 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1700 by arith
  1701 
  1702 lemma less_diff_conv2:
  1703   fixes j k i :: nat
  1704   assumes "k \<le> j"
  1705   shows "j - k < i \<longleftrightarrow> j < i + k"
  1706   using assms by arith
  1707 
  1708 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1709 by arith
  1710 
  1711 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1712   by (fact le_diff_conv2) -- {* FIXME delete *}
  1713 
  1714 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1715 by arith
  1716 
  1717 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1718   by (fact le_add_diff) -- {* FIXME delete *}
  1719 
  1720 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1721   second premise n\<le>m*)
  1722 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1723 by arith
  1724 
  1725 text {* Simplification of relational expressions involving subtraction *}
  1726 
  1727 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1728 by (simp split add: nat_diff_split)
  1729 
  1730 hide_fact (open) diff_diff_eq
  1731 
  1732 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1733 by (auto split add: nat_diff_split)
  1734 
  1735 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1736 by (auto split add: nat_diff_split)
  1737 
  1738 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1739 by (auto split add: nat_diff_split)
  1740 
  1741 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1742 
  1743 (* Monotonicity of subtraction in first argument *)
  1744 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1745 by (simp split add: nat_diff_split)
  1746 
  1747 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1748 by (simp split add: nat_diff_split)
  1749 
  1750 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1751 by (simp split add: nat_diff_split)
  1752 
  1753 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1754 by (simp split add: nat_diff_split)
  1755 
  1756 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1757 by auto
  1758 
  1759 lemma inj_on_diff_nat: 
  1760   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1761   shows "inj_on (\<lambda>n. n - k) N"
  1762 proof (rule inj_onI)
  1763   fix x y
  1764   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1765   with k_le_n have "x - k + k = y - k + k" by auto
  1766   with a k_le_n show "x = y" by auto
  1767 qed
  1768 
  1769 text{*Rewriting to pull differences out*}
  1770 
  1771 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1772 by arith
  1773 
  1774 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1775 by arith
  1776 
  1777 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1778 by arith
  1779 
  1780 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1781 by simp
  1782 
  1783 (*The others are
  1784       i - j - k = i - (j + k),
  1785       k \<le> j ==> j - k + i = j + i - k,
  1786       k \<le> j ==> i + (j - k) = i + j - k *)
  1787 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1788 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1789 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1790 
  1791 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1792 Least_Suc}, since there appears to be no need.*}
  1793 
  1794 text{*Lemmas for ex/Factorization*}
  1795 
  1796 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1797 by (cases m) auto
  1798 
  1799 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1800 by (cases m) auto
  1801 
  1802 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1803 by (cases m) auto
  1804 
  1805 text {* Specialized induction principles that work "backwards": *}
  1806 
  1807 lemma inc_induct[consumes 1, case_names base step]:
  1808   assumes less: "i \<le> j"
  1809   assumes base: "P j"
  1810   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1811   shows "P i"
  1812   using less step
  1813 proof (induct d\<equiv>"j - i" arbitrary: i)
  1814   case (0 i)
  1815   hence "i = j" by simp
  1816   with base show ?case by simp
  1817 next
  1818   case (Suc d n)
  1819   hence "n \<le> n" "n < j" "P (Suc n)"
  1820     by simp_all
  1821   then show "P n" by fact
  1822 qed
  1823 
  1824 lemma strict_inc_induct[consumes 1, case_names base step]:
  1825   assumes less: "i < j"
  1826   assumes base: "!!i. j = Suc i ==> P i"
  1827   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1828   shows "P i"
  1829   using less
  1830 proof (induct d=="j - i - 1" arbitrary: i)
  1831   case (0 i)
  1832   with `i < j` have "j = Suc i" by simp
  1833   with base show ?case by simp
  1834 next
  1835   case (Suc d i)
  1836   hence "i < j" "P (Suc i)"
  1837     by simp_all
  1838   thus "P i" by (rule step)
  1839 qed
  1840 
  1841 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1842   using inc_induct[of "k - i" k P, simplified] by blast
  1843 
  1844 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1845   using inc_induct[of 0 k P] by blast
  1846 
  1847 text {* Further induction rule similar to @{thm inc_induct} *}
  1848 
  1849 lemma dec_induct[consumes 1, case_names base step]:
  1850   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1851   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1852  
  1853 
  1854 subsection {* The divides relation on @{typ nat} *}
  1855 
  1856 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1857 unfolding dvd_def by simp
  1858 
  1859 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1860 by (simp add: dvd_def)
  1861 
  1862 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1863 by (simp add: dvd_def)
  1864 
  1865 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1866   unfolding dvd_def
  1867   by (force dest: mult_eq_self_implies_10 simp add: mult.assoc)
  1868 
  1869 text {* @{term "op dvd"} is a partial order *}
  1870 
  1871 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1872   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1873 
  1874 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1875 unfolding dvd_def
  1876 by (blast intro: diff_mult_distrib2 [symmetric])
  1877 
  1878 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1879   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1880   apply (blast intro: dvd_add)
  1881   done
  1882 
  1883 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1884 by (drule_tac m = m in dvd_diff_nat, auto)
  1885 
  1886 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1887   apply (rule iffI)
  1888    apply (erule_tac [2] dvd_add)
  1889    apply (rule_tac [2] dvd_refl)
  1890   apply (subgoal_tac "n = (n+k) -k")
  1891    prefer 2 apply simp
  1892   apply (erule ssubst)
  1893   apply (erule dvd_diff_nat)
  1894   apply (rule dvd_refl)
  1895   done
  1896 
  1897 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1898   unfolding dvd_def
  1899   apply (erule exE)
  1900   apply (simp add: ac_simps)
  1901   done
  1902 
  1903 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1904   apply auto
  1905    apply (subgoal_tac "m*n dvd m*1")
  1906    apply (drule dvd_mult_cancel, auto)
  1907   done
  1908 
  1909 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1910   apply (subst mult.commute)
  1911   apply (erule dvd_mult_cancel1)
  1912   done
  1913 
  1914 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1915 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1916 
  1917 lemma nat_dvd_not_less:
  1918   fixes m n :: nat
  1919   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1920 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1921 
  1922 lemma dvd_plusE:
  1923   fixes m n q :: nat
  1924   assumes "m dvd n + q" "m dvd n"
  1925   obtains "m dvd q"
  1926 proof (cases "m = 0")
  1927   case True with assms that show thesis by simp
  1928 next
  1929   case False then have "m > 0" by simp
  1930   from assms obtain r s where "n = m * r" and "n + q = m * s" by (blast elim: dvdE)
  1931   then have *: "m * r + q = m * s" by simp
  1932   show thesis proof (cases "r \<le> s")
  1933     case False then have "s < r" by (simp add: not_le)
  1934     with * have "m * r + q - m * s = m * s - m * s" by simp
  1935     then have "m * r + q - m * s = 0" by simp
  1936     with `m > 0` `s < r` have "m * r - m * s + q = 0" by (unfold less_le_not_le) auto
  1937     then have "m * (r - s) + q = 0" by auto
  1938     then have "m * (r - s) = 0" by simp
  1939     then have "m = 0 \<or> r - s = 0" by simp
  1940     with `s < r` have "m = 0" by (simp add: less_le_not_le)
  1941     with `m > 0` show thesis by auto
  1942   next
  1943     case True with * have "m * r + q - m * r = m * s - m * r" by simp
  1944     with `m > 0` `r \<le> s` have "m * r - m * r + q = m * s - m * r" by simp
  1945     then have "q = m * (s - r)" by (simp add: diff_mult_distrib2)
  1946     with assms that show thesis by (auto intro: dvdI)
  1947   qed
  1948 qed
  1949 
  1950 lemma dvd_plus_eq_right:
  1951   fixes m n q :: nat
  1952   assumes "m dvd n"
  1953   shows "m dvd n + q \<longleftrightarrow> m dvd q"
  1954   using assms by (auto elim: dvd_plusE)
  1955 
  1956 lemma dvd_plus_eq_left:
  1957   fixes m n q :: nat
  1958   assumes "m dvd q"
  1959   shows "m dvd n + q \<longleftrightarrow> m dvd n"
  1960   using assms by (simp add: dvd_plus_eq_right add.commute [of n])
  1961 
  1962 lemma less_eq_dvd_minus:
  1963   fixes m n :: nat
  1964   assumes "m \<le> n"
  1965   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1966 proof -
  1967   from assms have "n = m + (n - m)" by simp
  1968   then obtain q where "n = m + q" ..
  1969   then show ?thesis by (simp add: dvd_reduce add.commute [of m])
  1970 qed
  1971 
  1972 lemma dvd_minus_self:
  1973   fixes m n :: nat
  1974   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1975   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1976 
  1977 lemma dvd_minus_add:
  1978   fixes m n q r :: nat
  1979   assumes "q \<le> n" "q \<le> r * m"
  1980   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1981 proof -
  1982   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1983     by (auto elim: dvd_plusE)
  1984   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1985   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1986   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add.commute)
  1987   finally show ?thesis .
  1988 qed
  1989 
  1990 
  1991 subsection {* Aliases *}
  1992 
  1993 lemma nat_mult_1: "(1::nat) * n = n"
  1994   by (rule mult_1_left)
  1995  
  1996 lemma nat_mult_1_right: "n * (1::nat) = n"
  1997   by (rule mult_1_right)
  1998 
  1999 
  2000 subsection {* Size of a datatype value *}
  2001 
  2002 class size =
  2003   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  2004 
  2005 instantiation nat :: size
  2006 begin
  2007 
  2008 definition size_nat where
  2009   [simp, code]: "size (n \<Colon> nat) = n"
  2010 
  2011 instance ..
  2012 
  2013 end
  2014 
  2015 
  2016 subsection {* Code module namespace *}
  2017 
  2018 code_identifier
  2019   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  2020 
  2021 hide_const (open) of_nat_aux
  2022 
  2023 end