src/HOL/Lim.thy
author haftmann
Mon Dec 29 14:08:08 2008 +0100 (2008-12-29)
changeset 29197 6d4cb27ed19c
parent 28952 15a4b2cf8c34
child 29667 53103fc8ffa3
permissions -rw-r--r--
adapted HOL source structure to distribution layout
     1 (*  Title       : Lim.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5 *)
     6 
     7 header{* Limits and Continuity *}
     8 
     9 theory Lim
    10 imports SEQ
    11 begin
    12 
    13 text{*Standard Definitions*}
    14 
    15 definition
    16   LIM :: "['a::real_normed_vector => 'b::real_normed_vector, 'a, 'b] => bool"
    17         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
    18   [code del]: "f -- a --> L =
    19      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & norm (x - a) < s
    20         --> norm (f x - L) < r)"
    21 
    22 definition
    23   isCont :: "['a::real_normed_vector => 'b::real_normed_vector, 'a] => bool" where
    24   "isCont f a = (f -- a --> (f a))"
    25 
    26 definition
    27   isUCont :: "['a::real_normed_vector => 'b::real_normed_vector] => bool" where
    28   [code del]: "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r)"
    29 
    30 
    31 subsection {* Limits of Functions *}
    32 
    33 subsubsection {* Purely standard proofs *}
    34 
    35 lemma LIM_eq:
    36      "f -- a --> L =
    37      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
    38 by (simp add: LIM_def diff_minus)
    39 
    40 lemma LIM_I:
    41      "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
    42       ==> f -- a --> L"
    43 by (simp add: LIM_eq)
    44 
    45 lemma LIM_D:
    46      "[| f -- a --> L; 0<r |]
    47       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
    48 by (simp add: LIM_eq)
    49 
    50 lemma LIM_offset: "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
    51 apply (rule LIM_I)
    52 apply (drule_tac r="r" in LIM_D, safe)
    53 apply (rule_tac x="s" in exI, safe)
    54 apply (drule_tac x="x + k" in spec)
    55 apply (simp add: compare_rls)
    56 done
    57 
    58 lemma LIM_offset_zero: "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
    59 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
    60 
    61 lemma LIM_offset_zero_cancel: "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
    62 by (drule_tac k="- a" in LIM_offset, simp)
    63 
    64 lemma LIM_const [simp]: "(%x. k) -- x --> k"
    65 by (simp add: LIM_def)
    66 
    67 lemma LIM_add:
    68   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
    69   assumes f: "f -- a --> L" and g: "g -- a --> M"
    70   shows "(%x. f x + g(x)) -- a --> (L + M)"
    71 proof (rule LIM_I)
    72   fix r :: real
    73   assume r: "0 < r"
    74   from LIM_D [OF f half_gt_zero [OF r]]
    75   obtain fs
    76     where fs:    "0 < fs"
    77       and fs_lt: "\<forall>x. x \<noteq> a & norm (x-a) < fs --> norm (f x - L) < r/2"
    78   by blast
    79   from LIM_D [OF g half_gt_zero [OF r]]
    80   obtain gs
    81     where gs:    "0 < gs"
    82       and gs_lt: "\<forall>x. x \<noteq> a & norm (x-a) < gs --> norm (g x - M) < r/2"
    83   by blast
    84   show "\<exists>s>0.\<forall>x. x \<noteq> a \<and> norm (x-a) < s \<longrightarrow> norm (f x + g x - (L + M)) < r"
    85   proof (intro exI conjI strip)
    86     show "0 < min fs gs"  by (simp add: fs gs)
    87     fix x :: 'a
    88     assume "x \<noteq> a \<and> norm (x-a) < min fs gs"
    89     hence "x \<noteq> a \<and> norm (x-a) < fs \<and> norm (x-a) < gs" by simp
    90     with fs_lt gs_lt
    91     have "norm (f x - L) < r/2" and "norm (g x - M) < r/2" by blast+
    92     hence "norm (f x - L) + norm (g x - M) < r" by arith
    93     thus "norm (f x + g x - (L + M)) < r"
    94       by (blast intro: norm_diff_triangle_ineq order_le_less_trans)
    95   qed
    96 qed
    97 
    98 lemma LIM_add_zero:
    99   "\<lbrakk>f -- a --> 0; g -- a --> 0\<rbrakk> \<Longrightarrow> (\<lambda>x. f x + g x) -- a --> 0"
   100 by (drule (1) LIM_add, simp)
   101 
   102 lemma minus_diff_minus:
   103   fixes a b :: "'a::ab_group_add"
   104   shows "(- a) - (- b) = - (a - b)"
   105 by simp
   106 
   107 lemma LIM_minus: "f -- a --> L ==> (%x. -f(x)) -- a --> -L"
   108 by (simp only: LIM_eq minus_diff_minus norm_minus_cancel)
   109 
   110 lemma LIM_add_minus:
   111     "[| f -- x --> l; g -- x --> m |] ==> (%x. f(x) + -g(x)) -- x --> (l + -m)"
   112 by (intro LIM_add LIM_minus)
   113 
   114 lemma LIM_diff:
   115     "[| f -- x --> l; g -- x --> m |] ==> (%x. f(x) - g(x)) -- x --> l-m"
   116 by (simp only: diff_minus LIM_add LIM_minus)
   117 
   118 lemma LIM_zero: "f -- a --> l \<Longrightarrow> (\<lambda>x. f x - l) -- a --> 0"
   119 by (simp add: LIM_def)
   120 
   121 lemma LIM_zero_cancel: "(\<lambda>x. f x - l) -- a --> 0 \<Longrightarrow> f -- a --> l"
   122 by (simp add: LIM_def)
   123 
   124 lemma LIM_zero_iff: "(\<lambda>x. f x - l) -- a --> 0 = f -- a --> l"
   125 by (simp add: LIM_def)
   126 
   127 lemma LIM_imp_LIM:
   128   assumes f: "f -- a --> l"
   129   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
   130   shows "g -- a --> m"
   131 apply (rule LIM_I, drule LIM_D [OF f], safe)
   132 apply (rule_tac x="s" in exI, safe)
   133 apply (drule_tac x="x" in spec, safe)
   134 apply (erule (1) order_le_less_trans [OF le])
   135 done
   136 
   137 lemma LIM_norm: "f -- a --> l \<Longrightarrow> (\<lambda>x. norm (f x)) -- a --> norm l"
   138 by (erule LIM_imp_LIM, simp add: norm_triangle_ineq3)
   139 
   140 lemma LIM_norm_zero: "f -- a --> 0 \<Longrightarrow> (\<lambda>x. norm (f x)) -- a --> 0"
   141 by (drule LIM_norm, simp)
   142 
   143 lemma LIM_norm_zero_cancel: "(\<lambda>x. norm (f x)) -- a --> 0 \<Longrightarrow> f -- a --> 0"
   144 by (erule LIM_imp_LIM, simp)
   145 
   146 lemma LIM_norm_zero_iff: "(\<lambda>x. norm (f x)) -- a --> 0 = f -- a --> 0"
   147 by (rule iffI [OF LIM_norm_zero_cancel LIM_norm_zero])
   148 
   149 lemma LIM_rabs: "f -- a --> (l::real) \<Longrightarrow> (\<lambda>x. \<bar>f x\<bar>) -- a --> \<bar>l\<bar>"
   150 by (fold real_norm_def, rule LIM_norm)
   151 
   152 lemma LIM_rabs_zero: "f -- a --> (0::real) \<Longrightarrow> (\<lambda>x. \<bar>f x\<bar>) -- a --> 0"
   153 by (fold real_norm_def, rule LIM_norm_zero)
   154 
   155 lemma LIM_rabs_zero_cancel: "(\<lambda>x. \<bar>f x\<bar>) -- a --> (0::real) \<Longrightarrow> f -- a --> 0"
   156 by (fold real_norm_def, rule LIM_norm_zero_cancel)
   157 
   158 lemma LIM_rabs_zero_iff: "(\<lambda>x. \<bar>f x\<bar>) -- a --> (0::real) = f -- a --> 0"
   159 by (fold real_norm_def, rule LIM_norm_zero_iff)
   160 
   161 lemma LIM_const_not_eq:
   162   fixes a :: "'a::real_normed_algebra_1"
   163   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
   164 apply (simp add: LIM_eq)
   165 apply (rule_tac x="norm (k - L)" in exI, simp, safe)
   166 apply (rule_tac x="a + of_real (s/2)" in exI, simp add: norm_of_real)
   167 done
   168 
   169 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
   170 
   171 lemma LIM_const_eq:
   172   fixes a :: "'a::real_normed_algebra_1"
   173   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
   174 apply (rule ccontr)
   175 apply (blast dest: LIM_const_not_eq)
   176 done
   177 
   178 lemma LIM_unique:
   179   fixes a :: "'a::real_normed_algebra_1"
   180   shows "\<lbrakk>f -- a --> L; f -- a --> M\<rbrakk> \<Longrightarrow> L = M"
   181 apply (drule (1) LIM_diff)
   182 apply (auto dest!: LIM_const_eq)
   183 done
   184 
   185 lemma LIM_ident [simp]: "(\<lambda>x. x) -- a --> a"
   186 by (auto simp add: LIM_def)
   187 
   188 text{*Limits are equal for functions equal except at limit point*}
   189 lemma LIM_equal:
   190      "[| \<forall>x. x \<noteq> a --> (f x = g x) |] ==> (f -- a --> l) = (g -- a --> l)"
   191 by (simp add: LIM_def)
   192 
   193 lemma LIM_cong:
   194   "\<lbrakk>a = b; \<And>x. x \<noteq> b \<Longrightarrow> f x = g x; l = m\<rbrakk>
   195    \<Longrightarrow> ((\<lambda>x. f x) -- a --> l) = ((\<lambda>x. g x) -- b --> m)"
   196 by (simp add: LIM_def)
   197 
   198 lemma LIM_equal2:
   199   assumes 1: "0 < R"
   200   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
   201   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
   202 apply (unfold LIM_def, safe)
   203 apply (drule_tac x="r" in spec, safe)
   204 apply (rule_tac x="min s R" in exI, safe)
   205 apply (simp add: 1)
   206 apply (simp add: 2)
   207 done
   208 
   209 text{*Two uses in Hyperreal/Transcendental.ML*}
   210 lemma LIM_trans:
   211      "[| (%x. f(x) + -g(x)) -- a --> 0;  g -- a --> l |] ==> f -- a --> l"
   212 apply (drule LIM_add, assumption)
   213 apply (auto simp add: add_assoc)
   214 done
   215 
   216 lemma LIM_compose:
   217   assumes g: "g -- l --> g l"
   218   assumes f: "f -- a --> l"
   219   shows "(\<lambda>x. g (f x)) -- a --> g l"
   220 proof (rule LIM_I)
   221   fix r::real assume r: "0 < r"
   222   obtain s where s: "0 < s"
   223     and less_r: "\<And>y. \<lbrakk>y \<noteq> l; norm (y - l) < s\<rbrakk> \<Longrightarrow> norm (g y - g l) < r"
   224     using LIM_D [OF g r] by fast
   225   obtain t where t: "0 < t"
   226     and less_s: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < t\<rbrakk> \<Longrightarrow> norm (f x - l) < s"
   227     using LIM_D [OF f s] by fast
   228 
   229   show "\<exists>t>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < t \<longrightarrow> norm (g (f x) - g l) < r"
   230   proof (rule exI, safe)
   231     show "0 < t" using t .
   232   next
   233     fix x assume "x \<noteq> a" and "norm (x - a) < t"
   234     hence "norm (f x - l) < s" by (rule less_s)
   235     thus "norm (g (f x) - g l) < r"
   236       using r less_r by (case_tac "f x = l", simp_all)
   237   qed
   238 qed
   239 
   240 lemma LIM_compose2:
   241   assumes f: "f -- a --> b"
   242   assumes g: "g -- b --> c"
   243   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
   244   shows "(\<lambda>x. g (f x)) -- a --> c"
   245 proof (rule LIM_I)
   246   fix r :: real
   247   assume r: "0 < r"
   248   obtain s where s: "0 < s"
   249     and less_r: "\<And>y. \<lbrakk>y \<noteq> b; norm (y - b) < s\<rbrakk> \<Longrightarrow> norm (g y - c) < r"
   250     using LIM_D [OF g r] by fast
   251   obtain t where t: "0 < t"
   252     and less_s: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < t\<rbrakk> \<Longrightarrow> norm (f x - b) < s"
   253     using LIM_D [OF f s] by fast
   254   obtain d where d: "0 < d"
   255     and neq_b: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < d\<rbrakk> \<Longrightarrow> f x \<noteq> b"
   256     using inj by fast
   257 
   258   show "\<exists>t>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < t \<longrightarrow> norm (g (f x) - c) < r"
   259   proof (safe intro!: exI)
   260     show "0 < min d t" using d t by simp
   261   next
   262     fix x
   263     assume "x \<noteq> a" and "norm (x - a) < min d t"
   264     hence "f x \<noteq> b" and "norm (f x - b) < s"
   265       using neq_b less_s by simp_all
   266     thus "norm (g (f x) - c) < r"
   267       by (rule less_r)
   268   qed
   269 qed
   270 
   271 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
   272 unfolding o_def by (rule LIM_compose)
   273 
   274 lemma real_LIM_sandwich_zero:
   275   fixes f g :: "'a::real_normed_vector \<Rightarrow> real"
   276   assumes f: "f -- a --> 0"
   277   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
   278   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
   279   shows "g -- a --> 0"
   280 proof (rule LIM_imp_LIM [OF f])
   281   fix x assume x: "x \<noteq> a"
   282   have "norm (g x - 0) = g x" by (simp add: 1 x)
   283   also have "g x \<le> f x" by (rule 2 [OF x])
   284   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
   285   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
   286   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
   287 qed
   288 
   289 text {* Bounded Linear Operators *}
   290 
   291 lemma (in bounded_linear) cont: "f -- a --> f a"
   292 proof (rule LIM_I)
   293   fix r::real assume r: "0 < r"
   294   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
   295     using pos_bounded by fast
   296   show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - f a) < r"
   297   proof (rule exI, safe)
   298     from r K show "0 < r / K" by (rule divide_pos_pos)
   299   next
   300     fix x assume x: "norm (x - a) < r / K"
   301     have "norm (f x - f a) = norm (f (x - a))" by (simp only: diff)
   302     also have "\<dots> \<le> norm (x - a) * K" by (rule norm_le)
   303     also from K x have "\<dots> < r" by (simp only: pos_less_divide_eq)
   304     finally show "norm (f x - f a) < r" .
   305   qed
   306 qed
   307 
   308 lemma (in bounded_linear) LIM:
   309   "g -- a --> l \<Longrightarrow> (\<lambda>x. f (g x)) -- a --> f l"
   310 by (rule LIM_compose [OF cont])
   311 
   312 lemma (in bounded_linear) LIM_zero:
   313   "g -- a --> 0 \<Longrightarrow> (\<lambda>x. f (g x)) -- a --> 0"
   314 by (drule LIM, simp only: zero)
   315 
   316 text {* Bounded Bilinear Operators *}
   317 
   318 lemma (in bounded_bilinear) LIM_prod_zero:
   319   assumes f: "f -- a --> 0"
   320   assumes g: "g -- a --> 0"
   321   shows "(\<lambda>x. f x ** g x) -- a --> 0"
   322 proof (rule LIM_I)
   323   fix r::real assume r: "0 < r"
   324   obtain K where K: "0 < K"
   325     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   326     using pos_bounded by fast
   327   from K have K': "0 < inverse K"
   328     by (rule positive_imp_inverse_positive)
   329   obtain s where s: "0 < s"
   330     and norm_f: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < s\<rbrakk> \<Longrightarrow> norm (f x) < r"
   331     using LIM_D [OF f r] by auto
   332   obtain t where t: "0 < t"
   333     and norm_g: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < t\<rbrakk> \<Longrightarrow> norm (g x) < inverse K"
   334     using LIM_D [OF g K'] by auto
   335   show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x ** g x - 0) < r"
   336   proof (rule exI, safe)
   337     from s t show "0 < min s t" by simp
   338   next
   339     fix x assume x: "x \<noteq> a"
   340     assume "norm (x - a) < min s t"
   341     hence xs: "norm (x - a) < s" and xt: "norm (x - a) < t" by simp_all
   342     from x xs have 1: "norm (f x) < r" by (rule norm_f)
   343     from x xt have 2: "norm (g x) < inverse K" by (rule norm_g)
   344     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K" by (rule norm_le)
   345     also from 1 2 K have "\<dots> < r * inverse K * K"
   346       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero)
   347     also from K have "r * inverse K * K = r" by simp
   348     finally show "norm (f x ** g x - 0) < r" by simp
   349   qed
   350 qed
   351 
   352 lemma (in bounded_bilinear) LIM_left_zero:
   353   "f -- a --> 0 \<Longrightarrow> (\<lambda>x. f x ** c) -- a --> 0"
   354 by (rule bounded_linear.LIM_zero [OF bounded_linear_left])
   355 
   356 lemma (in bounded_bilinear) LIM_right_zero:
   357   "f -- a --> 0 \<Longrightarrow> (\<lambda>x. c ** f x) -- a --> 0"
   358 by (rule bounded_linear.LIM_zero [OF bounded_linear_right])
   359 
   360 lemma (in bounded_bilinear) LIM:
   361   "\<lbrakk>f -- a --> L; g -- a --> M\<rbrakk> \<Longrightarrow> (\<lambda>x. f x ** g x) -- a --> L ** M"
   362 apply (drule LIM_zero)
   363 apply (drule LIM_zero)
   364 apply (rule LIM_zero_cancel)
   365 apply (subst prod_diff_prod)
   366 apply (rule LIM_add_zero)
   367 apply (rule LIM_add_zero)
   368 apply (erule (1) LIM_prod_zero)
   369 apply (erule LIM_left_zero)
   370 apply (erule LIM_right_zero)
   371 done
   372 
   373 lemmas LIM_mult = mult.LIM
   374 
   375 lemmas LIM_mult_zero = mult.LIM_prod_zero
   376 
   377 lemmas LIM_mult_left_zero = mult.LIM_left_zero
   378 
   379 lemmas LIM_mult_right_zero = mult.LIM_right_zero
   380 
   381 lemmas LIM_scaleR = scaleR.LIM
   382 
   383 lemmas LIM_of_real = of_real.LIM
   384 
   385 lemma LIM_power:
   386   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::{recpower,real_normed_algebra}"
   387   assumes f: "f -- a --> l"
   388   shows "(\<lambda>x. f x ^ n) -- a --> l ^ n"
   389 by (induct n, simp, simp add: power_Suc LIM_mult f)
   390 
   391 subsubsection {* Derived theorems about @{term LIM} *}
   392 
   393 lemma LIM_inverse_lemma:
   394   fixes x :: "'a::real_normed_div_algebra"
   395   assumes r: "0 < r"
   396   assumes x: "norm (x - 1) < min (1/2) (r/2)"
   397   shows "norm (inverse x - 1) < r"
   398 proof -
   399   from r have r2: "0 < r/2" by simp
   400   from x have 0: "x \<noteq> 0" by clarsimp
   401   from x have x': "norm (1 - x) < min (1/2) (r/2)"
   402     by (simp only: norm_minus_commute)
   403   hence less1: "norm (1 - x) < r/2" by simp
   404   have "norm (1::'a) - norm x \<le> norm (1 - x)" by (rule norm_triangle_ineq2)
   405   also from x' have "norm (1 - x) < 1/2" by simp
   406   finally have "1/2 < norm x" by simp
   407   hence "inverse (norm x) < inverse (1/2)"
   408     by (rule less_imp_inverse_less, simp)
   409   hence less2: "norm (inverse x) < 2"
   410     by (simp add: nonzero_norm_inverse 0)
   411   from less1 less2 r2 norm_ge_zero
   412   have "norm (1 - x) * norm (inverse x) < (r/2) * 2"
   413     by (rule mult_strict_mono)
   414   thus "norm (inverse x - 1) < r"
   415     by (simp only: norm_mult [symmetric] left_diff_distrib, simp add: 0)
   416 qed
   417 
   418 lemma LIM_inverse_fun:
   419   assumes a: "a \<noteq> (0::'a::real_normed_div_algebra)"
   420   shows "inverse -- a --> inverse a"
   421 proof (rule LIM_equal2)
   422   from a show "0 < norm a" by simp
   423 next
   424   fix x assume "norm (x - a) < norm a"
   425   hence "x \<noteq> 0" by auto
   426   with a show "inverse x = inverse (inverse a * x) * inverse a"
   427     by (simp add: nonzero_inverse_mult_distrib
   428                   nonzero_imp_inverse_nonzero
   429                   nonzero_inverse_inverse_eq mult_assoc)
   430 next
   431   have 1: "inverse -- 1 --> inverse (1::'a)"
   432     apply (rule LIM_I)
   433     apply (rule_tac x="min (1/2) (r/2)" in exI)
   434     apply (simp add: LIM_inverse_lemma)
   435     done
   436   have "(\<lambda>x. inverse a * x) -- a --> inverse a * a"
   437     by (intro LIM_mult LIM_ident LIM_const)
   438   hence "(\<lambda>x. inverse a * x) -- a --> 1"
   439     by (simp add: a)
   440   with 1 have "(\<lambda>x. inverse (inverse a * x)) -- a --> inverse 1"
   441     by (rule LIM_compose)
   442   hence "(\<lambda>x. inverse (inverse a * x)) -- a --> 1"
   443     by simp
   444   hence "(\<lambda>x. inverse (inverse a * x) * inverse a) -- a --> 1 * inverse a"
   445     by (intro LIM_mult LIM_const)
   446   thus "(\<lambda>x. inverse (inverse a * x) * inverse a) -- a --> inverse a"
   447     by simp
   448 qed
   449 
   450 lemma LIM_inverse:
   451   fixes L :: "'a::real_normed_div_algebra"
   452   shows "\<lbrakk>f -- a --> L; L \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>x. inverse (f x)) -- a --> inverse L"
   453 by (rule LIM_inverse_fun [THEN LIM_compose])
   454 
   455 
   456 subsection {* Continuity *}
   457 
   458 subsubsection {* Purely standard proofs *}
   459 
   460 lemma LIM_isCont_iff: "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
   461 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
   462 
   463 lemma isCont_iff: "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
   464 by (simp add: isCont_def LIM_isCont_iff)
   465 
   466 lemma isCont_ident [simp]: "isCont (\<lambda>x. x) a"
   467   unfolding isCont_def by (rule LIM_ident)
   468 
   469 lemma isCont_const [simp]: "isCont (\<lambda>x. k) a"
   470   unfolding isCont_def by (rule LIM_const)
   471 
   472 lemma isCont_norm: "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
   473   unfolding isCont_def by (rule LIM_norm)
   474 
   475 lemma isCont_rabs: "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x :: real\<bar>) a"
   476   unfolding isCont_def by (rule LIM_rabs)
   477 
   478 lemma isCont_add: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
   479   unfolding isCont_def by (rule LIM_add)
   480 
   481 lemma isCont_minus: "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
   482   unfolding isCont_def by (rule LIM_minus)
   483 
   484 lemma isCont_diff: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
   485   unfolding isCont_def by (rule LIM_diff)
   486 
   487 lemma isCont_mult:
   488   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   489   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
   490   unfolding isCont_def by (rule LIM_mult)
   491 
   492 lemma isCont_inverse:
   493   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_div_algebra"
   494   shows "\<lbrakk>isCont f a; f a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. inverse (f x)) a"
   495   unfolding isCont_def by (rule LIM_inverse)
   496 
   497 lemma isCont_LIM_compose:
   498   "\<lbrakk>isCont g l; f -- a --> l\<rbrakk> \<Longrightarrow> (\<lambda>x. g (f x)) -- a --> g l"
   499   unfolding isCont_def by (rule LIM_compose)
   500 
   501 lemma isCont_LIM_compose2:
   502   assumes f [unfolded isCont_def]: "isCont f a"
   503   assumes g: "g -- f a --> l"
   504   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
   505   shows "(\<lambda>x. g (f x)) -- a --> l"
   506 by (rule LIM_compose2 [OF f g inj])
   507 
   508 lemma isCont_o2: "\<lbrakk>isCont f a; isCont g (f a)\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
   509   unfolding isCont_def by (rule LIM_compose)
   510 
   511 lemma isCont_o: "\<lbrakk>isCont f a; isCont g (f a)\<rbrakk> \<Longrightarrow> isCont (g o f) a"
   512   unfolding o_def by (rule isCont_o2)
   513 
   514 lemma (in bounded_linear) isCont: "isCont f a"
   515   unfolding isCont_def by (rule cont)
   516 
   517 lemma (in bounded_bilinear) isCont:
   518   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
   519   unfolding isCont_def by (rule LIM)
   520 
   521 lemmas isCont_scaleR = scaleR.isCont
   522 
   523 lemma isCont_of_real:
   524   "isCont f a \<Longrightarrow> isCont (\<lambda>x. of_real (f x)) a"
   525   unfolding isCont_def by (rule LIM_of_real)
   526 
   527 lemma isCont_power:
   528   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::{recpower,real_normed_algebra}"
   529   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
   530   unfolding isCont_def by (rule LIM_power)
   531 
   532 lemma isCont_abs [simp]: "isCont abs (a::real)"
   533 by (rule isCont_rabs [OF isCont_ident])
   534 
   535 
   536 subsection {* Uniform Continuity *}
   537 
   538 lemma isUCont_isCont: "isUCont f ==> isCont f x"
   539 by (simp add: isUCont_def isCont_def LIM_def, force)
   540 
   541 lemma isUCont_Cauchy:
   542   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
   543 unfolding isUCont_def
   544 apply (rule CauchyI)
   545 apply (drule_tac x=e in spec, safe)
   546 apply (drule_tac e=s in CauchyD, safe)
   547 apply (rule_tac x=M in exI, simp)
   548 done
   549 
   550 lemma (in bounded_linear) isUCont: "isUCont f"
   551 unfolding isUCont_def
   552 proof (intro allI impI)
   553   fix r::real assume r: "0 < r"
   554   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
   555     using pos_bounded by fast
   556   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
   557   proof (rule exI, safe)
   558     from r K show "0 < r / K" by (rule divide_pos_pos)
   559   next
   560     fix x y :: 'a
   561     assume xy: "norm (x - y) < r / K"
   562     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
   563     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
   564     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
   565     finally show "norm (f x - f y) < r" .
   566   qed
   567 qed
   568 
   569 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
   570 by (rule isUCont [THEN isUCont_Cauchy])
   571 
   572 
   573 subsection {* Relation of LIM and LIMSEQ *}
   574 
   575 lemma LIMSEQ_SEQ_conv1:
   576   fixes a :: "'a::real_normed_vector"
   577   assumes X: "X -- a --> L"
   578   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
   579 proof (safe intro!: LIMSEQ_I)
   580   fix S :: "nat \<Rightarrow> 'a"
   581   fix r :: real
   582   assume rgz: "0 < r"
   583   assume as: "\<forall>n. S n \<noteq> a"
   584   assume S: "S ----> a"
   585   from LIM_D [OF X rgz] obtain s
   586     where sgz: "0 < s"
   587     and aux: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < s\<rbrakk> \<Longrightarrow> norm (X x - L) < r"
   588     by fast
   589   from LIMSEQ_D [OF S sgz]
   590   obtain no where "\<forall>n\<ge>no. norm (S n - a) < s" by blast
   591   hence "\<forall>n\<ge>no. norm (X (S n) - L) < r" by (simp add: aux as)
   592   thus "\<exists>no. \<forall>n\<ge>no. norm (X (S n) - L) < r" ..
   593 qed
   594 
   595 lemma LIMSEQ_SEQ_conv2:
   596   fixes a :: real
   597   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
   598   shows "X -- a --> L"
   599 proof (rule ccontr)
   600   assume "\<not> (X -- a --> L)"
   601   hence "\<not> (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & norm (x - a) < s --> norm (X x - L) < r)" by (unfold LIM_def)
   602   hence "\<exists>r > 0. \<forall>s > 0. \<exists>x. \<not>(x \<noteq> a \<and> \<bar>x - a\<bar> < s --> norm (X x - L) < r)" by simp
   603   hence "\<exists>r > 0. \<forall>s > 0. \<exists>x. (x \<noteq> a \<and> \<bar>x - a\<bar> < s \<and> norm (X x - L) \<ge> r)" by (simp add: linorder_not_less)
   604   then obtain r where rdef: "r > 0 \<and> (\<forall>s > 0. \<exists>x. (x \<noteq> a \<and> \<bar>x - a\<bar> < s \<and> norm (X x - L) \<ge> r))" by auto
   605 
   606   let ?F = "\<lambda>n::nat. SOME x. x\<noteq>a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> norm (X x - L) \<ge> r"
   607   have "\<And>n. \<exists>x. x\<noteq>a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> norm (X x - L) \<ge> r"
   608     using rdef by simp
   609   hence F: "\<And>n. ?F n \<noteq> a \<and> \<bar>?F n - a\<bar> < inverse (real (Suc n)) \<and> norm (X (?F n) - L) \<ge> r"
   610     by (rule someI_ex)
   611   hence F1: "\<And>n. ?F n \<noteq> a"
   612     and F2: "\<And>n. \<bar>?F n - a\<bar> < inverse (real (Suc n))"
   613     and F3: "\<And>n. norm (X (?F n) - L) \<ge> r"
   614     by fast+
   615 
   616   have "?F ----> a"
   617   proof (rule LIMSEQ_I, unfold real_norm_def)
   618       fix e::real
   619       assume "0 < e"
   620         (* choose no such that inverse (real (Suc n)) < e *)
   621       then have "\<exists>no. inverse (real (Suc no)) < e" by (rule reals_Archimedean)
   622       then obtain m where nodef: "inverse (real (Suc m)) < e" by auto
   623       show "\<exists>no. \<forall>n. no \<le> n --> \<bar>?F n - a\<bar> < e"
   624       proof (intro exI allI impI)
   625         fix n
   626         assume mlen: "m \<le> n"
   627         have "\<bar>?F n - a\<bar> < inverse (real (Suc n))"
   628           by (rule F2)
   629         also have "inverse (real (Suc n)) \<le> inverse (real (Suc m))"
   630           using mlen by auto
   631         also from nodef have
   632           "inverse (real (Suc m)) < e" .
   633         finally show "\<bar>?F n - a\<bar> < e" .
   634       qed
   635   qed
   636   
   637   moreover have "\<forall>n. ?F n \<noteq> a"
   638     by (rule allI) (rule F1)
   639 
   640   moreover from prems have "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L" by simp
   641   ultimately have "(\<lambda>n. X (?F n)) ----> L" by simp
   642   
   643   moreover have "\<not> ((\<lambda>n. X (?F n)) ----> L)"
   644   proof -
   645     {
   646       fix no::nat
   647       obtain n where "n = no + 1" by simp
   648       then have nolen: "no \<le> n" by simp
   649         (* We prove this by showing that for any m there is an n\<ge>m such that |X (?F n) - L| \<ge> r *)
   650       have "norm (X (?F n) - L) \<ge> r"
   651         by (rule F3)
   652       with nolen have "\<exists>n. no \<le> n \<and> norm (X (?F n) - L) \<ge> r" by fast
   653     }
   654     then have "(\<forall>no. \<exists>n. no \<le> n \<and> norm (X (?F n) - L) \<ge> r)" by simp
   655     with rdef have "\<exists>e>0. (\<forall>no. \<exists>n. no \<le> n \<and> norm (X (?F n) - L) \<ge> e)" by auto
   656     thus ?thesis by (unfold LIMSEQ_def, auto simp add: linorder_not_less)
   657   qed
   658   ultimately show False by simp
   659 qed
   660 
   661 lemma LIMSEQ_SEQ_conv:
   662   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::real) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
   663    (X -- a --> L)"
   664 proof
   665   assume "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
   666   thus "X -- a --> L" by (rule LIMSEQ_SEQ_conv2)
   667 next
   668   assume "(X -- a --> L)"
   669   thus "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L" by (rule LIMSEQ_SEQ_conv1)
   670 qed
   671 
   672 end