src/HOL/Analysis/Finite_Cartesian_Product.thy
author hoelzl
Mon Aug 08 14:13:14 2016 +0200 (2016-08-08)
changeset 63627 6ddb43c6b711
parent 63040 src/HOL/Multivariate_Analysis/Finite_Cartesian_Product.thy@eb4ddd18d635
child 63918 6bf55e6e0b75
permissions -rw-r--r--
rename HOL-Multivariate_Analysis to HOL-Analysis.
     1 (*  Title:      HOL/Analysis/Finite_Cartesian_Product.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>Definition of finite Cartesian product types.\<close>
     6 
     7 theory Finite_Cartesian_Product
     8 imports
     9   Euclidean_Space
    10   L2_Norm
    11   "~~/src/HOL/Library/Numeral_Type"
    12 begin
    13 
    14 subsection \<open>Finite Cartesian products, with indexing and lambdas.\<close>
    15 
    16 typedef ('a, 'b) vec = "UNIV :: (('b::finite) \<Rightarrow> 'a) set"
    17   morphisms vec_nth vec_lambda ..
    18 
    19 notation
    20   vec_nth (infixl "$" 90) and
    21   vec_lambda (binder "\<chi>" 10)
    22 
    23 (*
    24   Translate "'b ^ 'n" into "'b ^ ('n :: finite)". When 'n has already more than
    25   the finite type class write "vec 'b 'n"
    26 *)
    27 
    28 syntax "_finite_vec" :: "type \<Rightarrow> type \<Rightarrow> type" ("(_ ^/ _)" [15, 16] 15)
    29 
    30 parse_translation \<open>
    31   let
    32     fun vec t u = Syntax.const @{type_syntax vec} $ t $ u;
    33     fun finite_vec_tr [t, u] =
    34       (case Term_Position.strip_positions u of
    35         v as Free (x, _) =>
    36           if Lexicon.is_tid x then
    37             vec t (Syntax.const @{syntax_const "_ofsort"} $ v $
    38               Syntax.const @{class_syntax finite})
    39           else vec t u
    40       | _ => vec t u)
    41   in
    42     [(@{syntax_const "_finite_vec"}, K finite_vec_tr)]
    43   end
    44 \<close>
    45 
    46 lemma vec_eq_iff: "(x = y) \<longleftrightarrow> (\<forall>i. x$i = y$i)"
    47   by (simp add: vec_nth_inject [symmetric] fun_eq_iff)
    48 
    49 lemma vec_lambda_beta [simp]: "vec_lambda g $ i = g i"
    50   by (simp add: vec_lambda_inverse)
    51 
    52 lemma vec_lambda_unique: "(\<forall>i. f$i = g i) \<longleftrightarrow> vec_lambda g = f"
    53   by (auto simp add: vec_eq_iff)
    54 
    55 lemma vec_lambda_eta: "(\<chi> i. (g$i)) = g"
    56   by (simp add: vec_eq_iff)
    57 
    58 
    59 subsection \<open>Group operations and class instances\<close>
    60 
    61 instantiation vec :: (zero, finite) zero
    62 begin
    63   definition "0 \<equiv> (\<chi> i. 0)"
    64   instance ..
    65 end
    66 
    67 instantiation vec :: (plus, finite) plus
    68 begin
    69   definition "op + \<equiv> (\<lambda> x y. (\<chi> i. x$i + y$i))"
    70   instance ..
    71 end
    72 
    73 instantiation vec :: (minus, finite) minus
    74 begin
    75   definition "op - \<equiv> (\<lambda> x y. (\<chi> i. x$i - y$i))"
    76   instance ..
    77 end
    78 
    79 instantiation vec :: (uminus, finite) uminus
    80 begin
    81   definition "uminus \<equiv> (\<lambda> x. (\<chi> i. - (x$i)))"
    82   instance ..
    83 end
    84 
    85 lemma zero_index [simp]: "0 $ i = 0"
    86   unfolding zero_vec_def by simp
    87 
    88 lemma vector_add_component [simp]: "(x + y)$i = x$i + y$i"
    89   unfolding plus_vec_def by simp
    90 
    91 lemma vector_minus_component [simp]: "(x - y)$i = x$i - y$i"
    92   unfolding minus_vec_def by simp
    93 
    94 lemma vector_uminus_component [simp]: "(- x)$i = - (x$i)"
    95   unfolding uminus_vec_def by simp
    96 
    97 instance vec :: (semigroup_add, finite) semigroup_add
    98   by standard (simp add: vec_eq_iff add.assoc)
    99 
   100 instance vec :: (ab_semigroup_add, finite) ab_semigroup_add
   101   by standard (simp add: vec_eq_iff add.commute)
   102 
   103 instance vec :: (monoid_add, finite) monoid_add
   104   by standard (simp_all add: vec_eq_iff)
   105 
   106 instance vec :: (comm_monoid_add, finite) comm_monoid_add
   107   by standard (simp add: vec_eq_iff)
   108 
   109 instance vec :: (cancel_semigroup_add, finite) cancel_semigroup_add
   110   by standard (simp_all add: vec_eq_iff)
   111 
   112 instance vec :: (cancel_ab_semigroup_add, finite) cancel_ab_semigroup_add
   113   by standard (simp_all add: vec_eq_iff diff_diff_eq)
   114 
   115 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   116 
   117 instance vec :: (group_add, finite) group_add
   118   by standard (simp_all add: vec_eq_iff)
   119 
   120 instance vec :: (ab_group_add, finite) ab_group_add
   121   by standard (simp_all add: vec_eq_iff)
   122 
   123 
   124 subsection \<open>Real vector space\<close>
   125 
   126 instantiation vec :: (real_vector, finite) real_vector
   127 begin
   128 
   129 definition "scaleR \<equiv> (\<lambda> r x. (\<chi> i. scaleR r (x$i)))"
   130 
   131 lemma vector_scaleR_component [simp]: "(scaleR r x)$i = scaleR r (x$i)"
   132   unfolding scaleR_vec_def by simp
   133 
   134 instance
   135   by standard (simp_all add: vec_eq_iff scaleR_left_distrib scaleR_right_distrib)
   136 
   137 end
   138 
   139 
   140 subsection \<open>Topological space\<close>
   141 
   142 instantiation vec :: (topological_space, finite) topological_space
   143 begin
   144 
   145 definition [code del]:
   146   "open (S :: ('a ^ 'b) set) \<longleftrightarrow>
   147     (\<forall>x\<in>S. \<exists>A. (\<forall>i. open (A i) \<and> x$i \<in> A i) \<and>
   148       (\<forall>y. (\<forall>i. y$i \<in> A i) \<longrightarrow> y \<in> S))"
   149 
   150 instance proof
   151   show "open (UNIV :: ('a ^ 'b) set)"
   152     unfolding open_vec_def by auto
   153 next
   154   fix S T :: "('a ^ 'b) set"
   155   assume "open S" "open T" thus "open (S \<inter> T)"
   156     unfolding open_vec_def
   157     apply clarify
   158     apply (drule (1) bspec)+
   159     apply (clarify, rename_tac Sa Ta)
   160     apply (rule_tac x="\<lambda>i. Sa i \<inter> Ta i" in exI)
   161     apply (simp add: open_Int)
   162     done
   163 next
   164   fix K :: "('a ^ 'b) set set"
   165   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   166     unfolding open_vec_def
   167     apply clarify
   168     apply (drule (1) bspec)
   169     apply (drule (1) bspec)
   170     apply clarify
   171     apply (rule_tac x=A in exI)
   172     apply fast
   173     done
   174 qed
   175 
   176 end
   177 
   178 lemma open_vector_box: "\<forall>i. open (S i) \<Longrightarrow> open {x. \<forall>i. x $ i \<in> S i}"
   179   unfolding open_vec_def by auto
   180 
   181 lemma open_vimage_vec_nth: "open S \<Longrightarrow> open ((\<lambda>x. x $ i) -` S)"
   182   unfolding open_vec_def
   183   apply clarify
   184   apply (rule_tac x="\<lambda>k. if k = i then S else UNIV" in exI, simp)
   185   done
   186 
   187 lemma closed_vimage_vec_nth: "closed S \<Longrightarrow> closed ((\<lambda>x. x $ i) -` S)"
   188   unfolding closed_open vimage_Compl [symmetric]
   189   by (rule open_vimage_vec_nth)
   190 
   191 lemma closed_vector_box: "\<forall>i. closed (S i) \<Longrightarrow> closed {x. \<forall>i. x $ i \<in> S i}"
   192 proof -
   193   have "{x. \<forall>i. x $ i \<in> S i} = (\<Inter>i. (\<lambda>x. x $ i) -` S i)" by auto
   194   thus "\<forall>i. closed (S i) \<Longrightarrow> closed {x. \<forall>i. x $ i \<in> S i}"
   195     by (simp add: closed_INT closed_vimage_vec_nth)
   196 qed
   197 
   198 lemma tendsto_vec_nth [tendsto_intros]:
   199   assumes "((\<lambda>x. f x) \<longlongrightarrow> a) net"
   200   shows "((\<lambda>x. f x $ i) \<longlongrightarrow> a $ i) net"
   201 proof (rule topological_tendstoI)
   202   fix S assume "open S" "a $ i \<in> S"
   203   then have "open ((\<lambda>y. y $ i) -` S)" "a \<in> ((\<lambda>y. y $ i) -` S)"
   204     by (simp_all add: open_vimage_vec_nth)
   205   with assms have "eventually (\<lambda>x. f x \<in> (\<lambda>y. y $ i) -` S) net"
   206     by (rule topological_tendstoD)
   207   then show "eventually (\<lambda>x. f x $ i \<in> S) net"
   208     by simp
   209 qed
   210 
   211 lemma isCont_vec_nth [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x $ i) a"
   212   unfolding isCont_def by (rule tendsto_vec_nth)
   213 
   214 lemma vec_tendstoI:
   215   assumes "\<And>i. ((\<lambda>x. f x $ i) \<longlongrightarrow> a $ i) net"
   216   shows "((\<lambda>x. f x) \<longlongrightarrow> a) net"
   217 proof (rule topological_tendstoI)
   218   fix S assume "open S" and "a \<in> S"
   219   then obtain A where A: "\<And>i. open (A i)" "\<And>i. a $ i \<in> A i"
   220     and S: "\<And>y. \<forall>i. y $ i \<in> A i \<Longrightarrow> y \<in> S"
   221     unfolding open_vec_def by metis
   222   have "\<And>i. eventually (\<lambda>x. f x $ i \<in> A i) net"
   223     using assms A by (rule topological_tendstoD)
   224   hence "eventually (\<lambda>x. \<forall>i. f x $ i \<in> A i) net"
   225     by (rule eventually_all_finite)
   226   thus "eventually (\<lambda>x. f x \<in> S) net"
   227     by (rule eventually_mono, simp add: S)
   228 qed
   229 
   230 lemma tendsto_vec_lambda [tendsto_intros]:
   231   assumes "\<And>i. ((\<lambda>x. f x i) \<longlongrightarrow> a i) net"
   232   shows "((\<lambda>x. \<chi> i. f x i) \<longlongrightarrow> (\<chi> i. a i)) net"
   233   using assms by (simp add: vec_tendstoI)
   234 
   235 lemma open_image_vec_nth: assumes "open S" shows "open ((\<lambda>x. x $ i) ` S)"
   236 proof (rule openI)
   237   fix a assume "a \<in> (\<lambda>x. x $ i) ` S"
   238   then obtain z where "a = z $ i" and "z \<in> S" ..
   239   then obtain A where A: "\<forall>i. open (A i) \<and> z $ i \<in> A i"
   240     and S: "\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S"
   241     using \<open>open S\<close> unfolding open_vec_def by auto
   242   hence "A i \<subseteq> (\<lambda>x. x $ i) ` S"
   243     by (clarsimp, rule_tac x="\<chi> j. if j = i then x else z $ j" in image_eqI,
   244       simp_all)
   245   hence "open (A i) \<and> a \<in> A i \<and> A i \<subseteq> (\<lambda>x. x $ i) ` S"
   246     using A \<open>a = z $ i\<close> by simp
   247   then show "\<exists>T. open T \<and> a \<in> T \<and> T \<subseteq> (\<lambda>x. x $ i) ` S" by - (rule exI)
   248 qed
   249 
   250 instance vec :: (perfect_space, finite) perfect_space
   251 proof
   252   fix x :: "'a ^ 'b" show "\<not> open {x}"
   253   proof
   254     assume "open {x}"
   255     hence "\<forall>i. open ((\<lambda>x. x $ i) ` {x})" by (fast intro: open_image_vec_nth)
   256     hence "\<forall>i. open {x $ i}" by simp
   257     thus "False" by (simp add: not_open_singleton)
   258   qed
   259 qed
   260 
   261 
   262 subsection \<open>Metric space\<close>
   263 (* TODO: Product of uniform spaces and compatibility with metric_spaces! *)
   264 
   265 instantiation vec :: (metric_space, finite) dist
   266 begin
   267 
   268 definition
   269   "dist x y = setL2 (\<lambda>i. dist (x$i) (y$i)) UNIV"
   270 
   271 instance ..
   272 end
   273 
   274 instantiation vec :: (metric_space, finite) uniformity_dist
   275 begin
   276 
   277 definition [code del]:
   278   "(uniformity :: (('a, 'b) vec \<times> ('a, 'b) vec) filter) =
   279     (INF e:{0 <..}. principal {(x, y). dist x y < e})"
   280 
   281 instance
   282   by standard (rule uniformity_vec_def)
   283 end
   284 
   285 declare uniformity_Abort[where 'a="'a :: metric_space ^ 'b :: finite", code]
   286 
   287 instantiation vec :: (metric_space, finite) metric_space
   288 begin
   289 
   290 lemma dist_vec_nth_le: "dist (x $ i) (y $ i) \<le> dist x y"
   291   unfolding dist_vec_def by (rule member_le_setL2) simp_all
   292 
   293 instance proof
   294   fix x y :: "'a ^ 'b"
   295   show "dist x y = 0 \<longleftrightarrow> x = y"
   296     unfolding dist_vec_def
   297     by (simp add: setL2_eq_0_iff vec_eq_iff)
   298 next
   299   fix x y z :: "'a ^ 'b"
   300   show "dist x y \<le> dist x z + dist y z"
   301     unfolding dist_vec_def
   302     apply (rule order_trans [OF _ setL2_triangle_ineq])
   303     apply (simp add: setL2_mono dist_triangle2)
   304     done
   305 next
   306   fix S :: "('a ^ 'b) set"
   307   have *: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   308   proof
   309     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   310     proof
   311       fix x assume "x \<in> S"
   312       obtain A where A: "\<forall>i. open (A i)" "\<forall>i. x $ i \<in> A i"
   313         and S: "\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S"
   314         using \<open>open S\<close> and \<open>x \<in> S\<close> unfolding open_vec_def by metis
   315       have "\<forall>i\<in>UNIV. \<exists>r>0. \<forall>y. dist y (x $ i) < r \<longrightarrow> y \<in> A i"
   316         using A unfolding open_dist by simp
   317       hence "\<exists>r. \<forall>i\<in>UNIV. 0 < r i \<and> (\<forall>y. dist y (x $ i) < r i \<longrightarrow> y \<in> A i)"
   318         by (rule finite_set_choice [OF finite])
   319       then obtain r where r1: "\<forall>i. 0 < r i"
   320         and r2: "\<forall>i y. dist y (x $ i) < r i \<longrightarrow> y \<in> A i" by fast
   321       have "0 < Min (range r) \<and> (\<forall>y. dist y x < Min (range r) \<longrightarrow> y \<in> S)"
   322         by (simp add: r1 r2 S le_less_trans [OF dist_vec_nth_le])
   323       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
   324     qed
   325   next
   326     assume *: "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" show "open S"
   327     proof (unfold open_vec_def, rule)
   328       fix x assume "x \<in> S"
   329       then obtain e where "0 < e" and S: "\<forall>y. dist y x < e \<longrightarrow> y \<in> S"
   330         using * by fast
   331       define r where [abs_def]: "r i = e / sqrt (of_nat CARD('b))" for i :: 'b
   332       from \<open>0 < e\<close> have r: "\<forall>i. 0 < r i"
   333         unfolding r_def by simp_all
   334       from \<open>0 < e\<close> have e: "e = setL2 r UNIV"
   335         unfolding r_def by (simp add: setL2_constant)
   336       define A where "A i = {y. dist (x $ i) y < r i}" for i
   337       have "\<forall>i. open (A i) \<and> x $ i \<in> A i"
   338         unfolding A_def by (simp add: open_ball r)
   339       moreover have "\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S"
   340         by (simp add: A_def S dist_vec_def e setL2_strict_mono dist_commute)
   341       ultimately show "\<exists>A. (\<forall>i. open (A i) \<and> x $ i \<in> A i) \<and>
   342         (\<forall>y. (\<forall>i. y $ i \<in> A i) \<longrightarrow> y \<in> S)" by metis
   343     qed
   344   qed
   345   show "open S = (\<forall>x\<in>S. \<forall>\<^sub>F (x', y) in uniformity. x' = x \<longrightarrow> y \<in> S)"
   346     unfolding * eventually_uniformity_metric
   347     by (simp del: split_paired_All add: dist_vec_def dist_commute)
   348 qed
   349 
   350 end
   351 
   352 lemma Cauchy_vec_nth:
   353   "Cauchy (\<lambda>n. X n) \<Longrightarrow> Cauchy (\<lambda>n. X n $ i)"
   354   unfolding Cauchy_def by (fast intro: le_less_trans [OF dist_vec_nth_le])
   355 
   356 lemma vec_CauchyI:
   357   fixes X :: "nat \<Rightarrow> 'a::metric_space ^ 'n"
   358   assumes X: "\<And>i. Cauchy (\<lambda>n. X n $ i)"
   359   shows "Cauchy (\<lambda>n. X n)"
   360 proof (rule metric_CauchyI)
   361   fix r :: real assume "0 < r"
   362   hence "0 < r / of_nat CARD('n)" (is "0 < ?s") by simp
   363   define N where "N i = (LEAST N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m $ i) (X n $ i) < ?s)" for i
   364   define M where "M = Max (range N)"
   365   have "\<And>i. \<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m $ i) (X n $ i) < ?s"
   366     using X \<open>0 < ?s\<close> by (rule metric_CauchyD)
   367   hence "\<And>i. \<forall>m\<ge>N i. \<forall>n\<ge>N i. dist (X m $ i) (X n $ i) < ?s"
   368     unfolding N_def by (rule LeastI_ex)
   369   hence M: "\<And>i. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m $ i) (X n $ i) < ?s"
   370     unfolding M_def by simp
   371   {
   372     fix m n :: nat
   373     assume "M \<le> m" "M \<le> n"
   374     have "dist (X m) (X n) = setL2 (\<lambda>i. dist (X m $ i) (X n $ i)) UNIV"
   375       unfolding dist_vec_def ..
   376     also have "\<dots> \<le> setsum (\<lambda>i. dist (X m $ i) (X n $ i)) UNIV"
   377       by (rule setL2_le_setsum [OF zero_le_dist])
   378     also have "\<dots> < setsum (\<lambda>i::'n. ?s) UNIV"
   379       by (rule setsum_strict_mono, simp_all add: M \<open>M \<le> m\<close> \<open>M \<le> n\<close>)
   380     also have "\<dots> = r"
   381       by simp
   382     finally have "dist (X m) (X n) < r" .
   383   }
   384   hence "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < r"
   385     by simp
   386   then show "\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < r" ..
   387 qed
   388 
   389 instance vec :: (complete_space, finite) complete_space
   390 proof
   391   fix X :: "nat \<Rightarrow> 'a ^ 'b" assume "Cauchy X"
   392   have "\<And>i. (\<lambda>n. X n $ i) \<longlonglongrightarrow> lim (\<lambda>n. X n $ i)"
   393     using Cauchy_vec_nth [OF \<open>Cauchy X\<close>]
   394     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   395   hence "X \<longlonglongrightarrow> vec_lambda (\<lambda>i. lim (\<lambda>n. X n $ i))"
   396     by (simp add: vec_tendstoI)
   397   then show "convergent X"
   398     by (rule convergentI)
   399 qed
   400 
   401 
   402 subsection \<open>Normed vector space\<close>
   403 
   404 instantiation vec :: (real_normed_vector, finite) real_normed_vector
   405 begin
   406 
   407 definition "norm x = setL2 (\<lambda>i. norm (x$i)) UNIV"
   408 
   409 definition "sgn (x::'a^'b) = scaleR (inverse (norm x)) x"
   410 
   411 instance proof
   412   fix a :: real and x y :: "'a ^ 'b"
   413   show "norm x = 0 \<longleftrightarrow> x = 0"
   414     unfolding norm_vec_def
   415     by (simp add: setL2_eq_0_iff vec_eq_iff)
   416   show "norm (x + y) \<le> norm x + norm y"
   417     unfolding norm_vec_def
   418     apply (rule order_trans [OF _ setL2_triangle_ineq])
   419     apply (simp add: setL2_mono norm_triangle_ineq)
   420     done
   421   show "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   422     unfolding norm_vec_def
   423     by (simp add: setL2_right_distrib)
   424   show "sgn x = scaleR (inverse (norm x)) x"
   425     by (rule sgn_vec_def)
   426   show "dist x y = norm (x - y)"
   427     unfolding dist_vec_def norm_vec_def
   428     by (simp add: dist_norm)
   429 qed
   430 
   431 end
   432 
   433 lemma norm_nth_le: "norm (x $ i) \<le> norm x"
   434 unfolding norm_vec_def
   435 by (rule member_le_setL2) simp_all
   436 
   437 lemma bounded_linear_vec_nth: "bounded_linear (\<lambda>x. x $ i)"
   438 apply standard
   439 apply (rule vector_add_component)
   440 apply (rule vector_scaleR_component)
   441 apply (rule_tac x="1" in exI, simp add: norm_nth_le)
   442 done
   443 
   444 instance vec :: (banach, finite) banach ..
   445 
   446 
   447 subsection \<open>Inner product space\<close>
   448 
   449 instantiation vec :: (real_inner, finite) real_inner
   450 begin
   451 
   452 definition "inner x y = setsum (\<lambda>i. inner (x$i) (y$i)) UNIV"
   453 
   454 instance proof
   455   fix r :: real and x y z :: "'a ^ 'b"
   456   show "inner x y = inner y x"
   457     unfolding inner_vec_def
   458     by (simp add: inner_commute)
   459   show "inner (x + y) z = inner x z + inner y z"
   460     unfolding inner_vec_def
   461     by (simp add: inner_add_left setsum.distrib)
   462   show "inner (scaleR r x) y = r * inner x y"
   463     unfolding inner_vec_def
   464     by (simp add: setsum_right_distrib)
   465   show "0 \<le> inner x x"
   466     unfolding inner_vec_def
   467     by (simp add: setsum_nonneg)
   468   show "inner x x = 0 \<longleftrightarrow> x = 0"
   469     unfolding inner_vec_def
   470     by (simp add: vec_eq_iff setsum_nonneg_eq_0_iff)
   471   show "norm x = sqrt (inner x x)"
   472     unfolding inner_vec_def norm_vec_def setL2_def
   473     by (simp add: power2_norm_eq_inner)
   474 qed
   475 
   476 end
   477 
   478 
   479 subsection \<open>Euclidean space\<close>
   480 
   481 text \<open>Vectors pointing along a single axis.\<close>
   482 
   483 definition "axis k x = (\<chi> i. if i = k then x else 0)"
   484 
   485 lemma axis_nth [simp]: "axis i x $ i = x"
   486   unfolding axis_def by simp
   487 
   488 lemma axis_eq_axis: "axis i x = axis j y \<longleftrightarrow> x = y \<and> i = j \<or> x = 0 \<and> y = 0"
   489   unfolding axis_def vec_eq_iff by auto
   490 
   491 lemma inner_axis_axis:
   492   "inner (axis i x) (axis j y) = (if i = j then inner x y else 0)"
   493   unfolding inner_vec_def
   494   apply (cases "i = j")
   495   apply clarsimp
   496   apply (subst setsum.remove [of _ j], simp_all)
   497   apply (rule setsum.neutral, simp add: axis_def)
   498   apply (rule setsum.neutral, simp add: axis_def)
   499   done
   500 
   501 lemma setsum_single:
   502   assumes "finite A" and "k \<in> A" and "f k = y"
   503   assumes "\<And>i. i \<in> A \<Longrightarrow> i \<noteq> k \<Longrightarrow> f i = 0"
   504   shows "(\<Sum>i\<in>A. f i) = y"
   505   apply (subst setsum.remove [OF assms(1,2)])
   506   apply (simp add: setsum.neutral assms(3,4))
   507   done
   508 
   509 lemma inner_axis: "inner x (axis i y) = inner (x $ i) y"
   510   unfolding inner_vec_def
   511   apply (rule_tac k=i in setsum_single)
   512   apply simp_all
   513   apply (simp add: axis_def)
   514   done
   515 
   516 instantiation vec :: (euclidean_space, finite) euclidean_space
   517 begin
   518 
   519 definition "Basis = (\<Union>i. \<Union>u\<in>Basis. {axis i u})"
   520 
   521 instance proof
   522   show "(Basis :: ('a ^ 'b) set) \<noteq> {}"
   523     unfolding Basis_vec_def by simp
   524 next
   525   show "finite (Basis :: ('a ^ 'b) set)"
   526     unfolding Basis_vec_def by simp
   527 next
   528   fix u v :: "'a ^ 'b"
   529   assume "u \<in> Basis" and "v \<in> Basis"
   530   thus "inner u v = (if u = v then 1 else 0)"
   531     unfolding Basis_vec_def
   532     by (auto simp add: inner_axis_axis axis_eq_axis inner_Basis)
   533 next
   534   fix x :: "'a ^ 'b"
   535   show "(\<forall>u\<in>Basis. inner x u = 0) \<longleftrightarrow> x = 0"
   536     unfolding Basis_vec_def
   537     by (simp add: inner_axis euclidean_all_zero_iff vec_eq_iff)
   538 qed
   539 
   540 lemma DIM_cart[simp]: "DIM('a^'b) = CARD('b) * DIM('a)"
   541   apply (simp add: Basis_vec_def)
   542   apply (subst card_UN_disjoint)
   543      apply simp
   544     apply simp
   545    apply (auto simp: axis_eq_axis) [1]
   546   apply (subst card_UN_disjoint)
   547      apply (auto simp: axis_eq_axis)
   548   done
   549 
   550 end
   551 
   552 lemma cart_eq_inner_axis: "a $ i = inner a (axis i 1)"
   553   by (simp add: inner_axis)
   554 
   555 lemma axis_in_Basis: "a \<in> Basis \<Longrightarrow> axis i a \<in> Basis"
   556   by (auto simp add: Basis_vec_def axis_eq_axis)
   557 
   558 end