src/HOL/Analysis/Measure_Space.thy
author hoelzl
Mon Aug 08 14:13:14 2016 +0200 (2016-08-08)
changeset 63627 6ddb43c6b711
parent 63626 src/HOL/Multivariate_Analysis/Measure_Space.thy@44ce6b524ff3
child 63657 3663157ee197
permissions -rw-r--r--
rename HOL-Multivariate_Analysis to HOL-Analysis.
     1 (*  Title:      HOL/Analysis/Measure_Space.thy
     2     Author:     Lawrence C Paulson
     3     Author:     Johannes Hölzl, TU München
     4     Author:     Armin Heller, TU München
     5 *)
     6 
     7 section \<open>Measure spaces and their properties\<close>
     8 
     9 theory Measure_Space
    10 imports
    11   Measurable "~~/src/HOL/Library/Extended_Nonnegative_Real"
    12 begin
    13 
    14 subsection "Relate extended reals and the indicator function"
    15 
    16 lemma suminf_cmult_indicator:
    17   fixes f :: "nat \<Rightarrow> ennreal"
    18   assumes "disjoint_family A" "x \<in> A i"
    19   shows "(\<Sum>n. f n * indicator (A n) x) = f i"
    20 proof -
    21   have **: "\<And>n. f n * indicator (A n) x = (if n = i then f n else 0 :: ennreal)"
    22     using \<open>x \<in> A i\<close> assms unfolding disjoint_family_on_def indicator_def by auto
    23   then have "\<And>n. (\<Sum>j<n. f j * indicator (A j) x) = (if i < n then f i else 0 :: ennreal)"
    24     by (auto simp: setsum.If_cases)
    25   moreover have "(SUP n. if i < n then f i else 0) = (f i :: ennreal)"
    26   proof (rule SUP_eqI)
    27     fix y :: ennreal assume "\<And>n. n \<in> UNIV \<Longrightarrow> (if i < n then f i else 0) \<le> y"
    28     from this[of "Suc i"] show "f i \<le> y" by auto
    29   qed (insert assms, simp)
    30   ultimately show ?thesis using assms
    31     by (subst suminf_eq_SUP) (auto simp: indicator_def)
    32 qed
    33 
    34 lemma suminf_indicator:
    35   assumes "disjoint_family A"
    36   shows "(\<Sum>n. indicator (A n) x :: ennreal) = indicator (\<Union>i. A i) x"
    37 proof cases
    38   assume *: "x \<in> (\<Union>i. A i)"
    39   then obtain i where "x \<in> A i" by auto
    40   from suminf_cmult_indicator[OF assms(1), OF \<open>x \<in> A i\<close>, of "\<lambda>k. 1"]
    41   show ?thesis using * by simp
    42 qed simp
    43 
    44 lemma setsum_indicator_disjoint_family:
    45   fixes f :: "'d \<Rightarrow> 'e::semiring_1"
    46   assumes d: "disjoint_family_on A P" and "x \<in> A j" and "finite P" and "j \<in> P"
    47   shows "(\<Sum>i\<in>P. f i * indicator (A i) x) = f j"
    48 proof -
    49   have "P \<inter> {i. x \<in> A i} = {j}"
    50     using d \<open>x \<in> A j\<close> \<open>j \<in> P\<close> unfolding disjoint_family_on_def
    51     by auto
    52   thus ?thesis
    53     unfolding indicator_def
    54     by (simp add: if_distrib setsum.If_cases[OF \<open>finite P\<close>])
    55 qed
    56 
    57 text \<open>
    58   The type for emeasure spaces is already defined in @{theory Sigma_Algebra}, as it is also used to
    59   represent sigma algebras (with an arbitrary emeasure).
    60 \<close>
    61 
    62 subsection "Extend binary sets"
    63 
    64 lemma LIMSEQ_binaryset:
    65   assumes f: "f {} = 0"
    66   shows  "(\<lambda>n. \<Sum>i<n. f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    67 proof -
    68   have "(\<lambda>n. \<Sum>i < Suc (Suc n). f (binaryset A B i)) = (\<lambda>n. f A + f B)"
    69     proof
    70       fix n
    71       show "(\<Sum>i < Suc (Suc n). f (binaryset A B i)) = f A + f B"
    72         by (induct n)  (auto simp add: binaryset_def f)
    73     qed
    74   moreover
    75   have "... \<longlonglongrightarrow> f A + f B" by (rule tendsto_const)
    76   ultimately
    77   have "(\<lambda>n. \<Sum>i< Suc (Suc n). f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    78     by metis
    79   hence "(\<lambda>n. \<Sum>i< n+2. f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    80     by simp
    81   thus ?thesis by (rule LIMSEQ_offset [where k=2])
    82 qed
    83 
    84 lemma binaryset_sums:
    85   assumes f: "f {} = 0"
    86   shows  "(\<lambda>n. f (binaryset A B n)) sums (f A + f B)"
    87     by (simp add: sums_def LIMSEQ_binaryset [where f=f, OF f] atLeast0LessThan)
    88 
    89 lemma suminf_binaryset_eq:
    90   fixes f :: "'a set \<Rightarrow> 'b::{comm_monoid_add, t2_space}"
    91   shows "f {} = 0 \<Longrightarrow> (\<Sum>n. f (binaryset A B n)) = f A + f B"
    92   by (metis binaryset_sums sums_unique)
    93 
    94 subsection \<open>Properties of a premeasure @{term \<mu>}\<close>
    95 
    96 text \<open>
    97   The definitions for @{const positive} and @{const countably_additive} should be here, by they are
    98   necessary to define @{typ "'a measure"} in @{theory Sigma_Algebra}.
    99 \<close>
   100 
   101 definition subadditive where
   102   "subadditive M f \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> f (x \<union> y) \<le> f x + f y)"
   103 
   104 lemma subadditiveD: "subadditive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) \<le> f x + f y"
   105   by (auto simp add: subadditive_def)
   106 
   107 definition countably_subadditive where
   108   "countably_subadditive M f \<longleftrightarrow>
   109     (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (f (\<Union>i. A i) \<le> (\<Sum>i. f (A i))))"
   110 
   111 lemma (in ring_of_sets) countably_subadditive_subadditive:
   112   fixes f :: "'a set \<Rightarrow> ennreal"
   113   assumes f: "positive M f" and cs: "countably_subadditive M f"
   114   shows  "subadditive M f"
   115 proof (auto simp add: subadditive_def)
   116   fix x y
   117   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   118   hence "disjoint_family (binaryset x y)"
   119     by (auto simp add: disjoint_family_on_def binaryset_def)
   120   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   121          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   122          f (\<Union>i. binaryset x y i) \<le> (\<Sum> n. f (binaryset x y n))"
   123     using cs by (auto simp add: countably_subadditive_def)
   124   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   125          f (x \<union> y) \<le> (\<Sum> n. f (binaryset x y n))"
   126     by (simp add: range_binaryset_eq UN_binaryset_eq)
   127   thus "f (x \<union> y) \<le>  f x + f y" using f x y
   128     by (auto simp add: Un o_def suminf_binaryset_eq positive_def)
   129 qed
   130 
   131 definition additive where
   132   "additive M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> \<mu> (x \<union> y) = \<mu> x + \<mu> y)"
   133 
   134 definition increasing where
   135   "increasing M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<subseteq> y \<longrightarrow> \<mu> x \<le> \<mu> y)"
   136 
   137 lemma positiveD1: "positive M f \<Longrightarrow> f {} = 0" by (auto simp: positive_def)
   138 
   139 lemma positiveD_empty:
   140   "positive M f \<Longrightarrow> f {} = 0"
   141   by (auto simp add: positive_def)
   142 
   143 lemma additiveD:
   144   "additive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) = f x + f y"
   145   by (auto simp add: additive_def)
   146 
   147 lemma increasingD:
   148   "increasing M f \<Longrightarrow> x \<subseteq> y \<Longrightarrow> x\<in>M \<Longrightarrow> y\<in>M \<Longrightarrow> f x \<le> f y"
   149   by (auto simp add: increasing_def)
   150 
   151 lemma countably_additiveI[case_names countably]:
   152   "(\<And>A. range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i. A i) \<in> M \<Longrightarrow> (\<Sum>i. f (A i)) = f (\<Union>i. A i))
   153   \<Longrightarrow> countably_additive M f"
   154   by (simp add: countably_additive_def)
   155 
   156 lemma (in ring_of_sets) disjointed_additive:
   157   assumes f: "positive M f" "additive M f" and A: "range A \<subseteq> M" "incseq A"
   158   shows "(\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   159 proof (induct n)
   160   case (Suc n)
   161   then have "(\<Sum>i\<le>Suc n. f (disjointed A i)) = f (A n) + f (disjointed A (Suc n))"
   162     by simp
   163   also have "\<dots> = f (A n \<union> disjointed A (Suc n))"
   164     using A by (subst f(2)[THEN additiveD]) (auto simp: disjointed_mono)
   165   also have "A n \<union> disjointed A (Suc n) = A (Suc n)"
   166     using \<open>incseq A\<close> by (auto dest: incseq_SucD simp: disjointed_mono)
   167   finally show ?case .
   168 qed simp
   169 
   170 lemma (in ring_of_sets) additive_sum:
   171   fixes A:: "'i \<Rightarrow> 'a set"
   172   assumes f: "positive M f" and ad: "additive M f" and "finite S"
   173       and A: "A`S \<subseteq> M"
   174       and disj: "disjoint_family_on A S"
   175   shows  "(\<Sum>i\<in>S. f (A i)) = f (\<Union>i\<in>S. A i)"
   176   using \<open>finite S\<close> disj A
   177 proof induct
   178   case empty show ?case using f by (simp add: positive_def)
   179 next
   180   case (insert s S)
   181   then have "A s \<inter> (\<Union>i\<in>S. A i) = {}"
   182     by (auto simp add: disjoint_family_on_def neq_iff)
   183   moreover
   184   have "A s \<in> M" using insert by blast
   185   moreover have "(\<Union>i\<in>S. A i) \<in> M"
   186     using insert \<open>finite S\<close> by auto
   187   ultimately have "f (A s \<union> (\<Union>i\<in>S. A i)) = f (A s) + f(\<Union>i\<in>S. A i)"
   188     using ad UNION_in_sets A by (auto simp add: additive_def)
   189   with insert show ?case using ad disjoint_family_on_mono[of S "insert s S" A]
   190     by (auto simp add: additive_def subset_insertI)
   191 qed
   192 
   193 lemma (in ring_of_sets) additive_increasing:
   194   fixes f :: "'a set \<Rightarrow> ennreal"
   195   assumes posf: "positive M f" and addf: "additive M f"
   196   shows "increasing M f"
   197 proof (auto simp add: increasing_def)
   198   fix x y
   199   assume xy: "x \<in> M" "y \<in> M" "x \<subseteq> y"
   200   then have "y - x \<in> M" by auto
   201   then have "f x + 0 \<le> f x + f (y-x)" by (intro add_left_mono zero_le)
   202   also have "... = f (x \<union> (y-x))" using addf
   203     by (auto simp add: additive_def) (metis Diff_disjoint Un_Diff_cancel Diff xy(1,2))
   204   also have "... = f y"
   205     by (metis Un_Diff_cancel Un_absorb1 xy(3))
   206   finally show "f x \<le> f y" by simp
   207 qed
   208 
   209 lemma (in ring_of_sets) subadditive:
   210   fixes f :: "'a set \<Rightarrow> ennreal"
   211   assumes f: "positive M f" "additive M f" and A: "A`S \<subseteq> M" and S: "finite S"
   212   shows "f (\<Union>i\<in>S. A i) \<le> (\<Sum>i\<in>S. f (A i))"
   213 using S A
   214 proof (induct S)
   215   case empty thus ?case using f by (auto simp: positive_def)
   216 next
   217   case (insert x F)
   218   hence in_M: "A x \<in> M" "(\<Union>i\<in>F. A i) \<in> M" "(\<Union>i\<in>F. A i) - A x \<in> M" using A by force+
   219   have subs: "(\<Union>i\<in>F. A i) - A x \<subseteq> (\<Union>i\<in>F. A i)" by auto
   220   have "(\<Union>i\<in>(insert x F). A i) = A x \<union> ((\<Union>i\<in>F. A i) - A x)" by auto
   221   hence "f (\<Union>i\<in>(insert x F). A i) = f (A x \<union> ((\<Union>i\<in>F. A i) - A x))"
   222     by simp
   223   also have "\<dots> = f (A x) + f ((\<Union>i\<in>F. A i) - A x)"
   224     using f(2) by (rule additiveD) (insert in_M, auto)
   225   also have "\<dots> \<le> f (A x) + f (\<Union>i\<in>F. A i)"
   226     using additive_increasing[OF f] in_M subs by (auto simp: increasing_def intro: add_left_mono)
   227   also have "\<dots> \<le> f (A x) + (\<Sum>i\<in>F. f (A i))" using insert by (auto intro: add_left_mono)
   228   finally show "f (\<Union>i\<in>(insert x F). A i) \<le> (\<Sum>i\<in>(insert x F). f (A i))" using insert by simp
   229 qed
   230 
   231 lemma (in ring_of_sets) countably_additive_additive:
   232   fixes f :: "'a set \<Rightarrow> ennreal"
   233   assumes posf: "positive M f" and ca: "countably_additive M f"
   234   shows "additive M f"
   235 proof (auto simp add: additive_def)
   236   fix x y
   237   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   238   hence "disjoint_family (binaryset x y)"
   239     by (auto simp add: disjoint_family_on_def binaryset_def)
   240   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   241          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   242          f (\<Union>i. binaryset x y i) = (\<Sum> n. f (binaryset x y n))"
   243     using ca
   244     by (simp add: countably_additive_def)
   245   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   246          f (x \<union> y) = (\<Sum>n. f (binaryset x y n))"
   247     by (simp add: range_binaryset_eq UN_binaryset_eq)
   248   thus "f (x \<union> y) = f x + f y" using posf x y
   249     by (auto simp add: Un suminf_binaryset_eq positive_def)
   250 qed
   251 
   252 lemma (in algebra) increasing_additive_bound:
   253   fixes A:: "nat \<Rightarrow> 'a set" and  f :: "'a set \<Rightarrow> ennreal"
   254   assumes f: "positive M f" and ad: "additive M f"
   255       and inc: "increasing M f"
   256       and A: "range A \<subseteq> M"
   257       and disj: "disjoint_family A"
   258   shows  "(\<Sum>i. f (A i)) \<le> f \<Omega>"
   259 proof (safe intro!: suminf_le_const)
   260   fix N
   261   note disj_N = disjoint_family_on_mono[OF _ disj, of "{..<N}"]
   262   have "(\<Sum>i<N. f (A i)) = f (\<Union>i\<in>{..<N}. A i)"
   263     using A by (intro additive_sum [OF f ad _ _]) (auto simp: disj_N)
   264   also have "... \<le> f \<Omega>" using space_closed A
   265     by (intro increasingD[OF inc] finite_UN) auto
   266   finally show "(\<Sum>i<N. f (A i)) \<le> f \<Omega>" by simp
   267 qed (insert f A, auto simp: positive_def)
   268 
   269 lemma (in ring_of_sets) countably_additiveI_finite:
   270   fixes \<mu> :: "'a set \<Rightarrow> ennreal"
   271   assumes "finite \<Omega>" "positive M \<mu>" "additive M \<mu>"
   272   shows "countably_additive M \<mu>"
   273 proof (rule countably_additiveI)
   274   fix F :: "nat \<Rightarrow> 'a set" assume F: "range F \<subseteq> M" "(\<Union>i. F i) \<in> M" and disj: "disjoint_family F"
   275 
   276   have "\<forall>i\<in>{i. F i \<noteq> {}}. \<exists>x. x \<in> F i" by auto
   277   from bchoice[OF this] obtain f where f: "\<And>i. F i \<noteq> {} \<Longrightarrow> f i \<in> F i" by auto
   278 
   279   have inj_f: "inj_on f {i. F i \<noteq> {}}"
   280   proof (rule inj_onI, simp)
   281     fix i j a b assume *: "f i = f j" "F i \<noteq> {}" "F j \<noteq> {}"
   282     then have "f i \<in> F i" "f j \<in> F j" using f by force+
   283     with disj * show "i = j" by (auto simp: disjoint_family_on_def)
   284   qed
   285   have "finite (\<Union>i. F i)"
   286     by (metis F(2) assms(1) infinite_super sets_into_space)
   287 
   288   have F_subset: "{i. \<mu> (F i) \<noteq> 0} \<subseteq> {i. F i \<noteq> {}}"
   289     by (auto simp: positiveD_empty[OF \<open>positive M \<mu>\<close>])
   290   moreover have fin_not_empty: "finite {i. F i \<noteq> {}}"
   291   proof (rule finite_imageD)
   292     from f have "f`{i. F i \<noteq> {}} \<subseteq> (\<Union>i. F i)" by auto
   293     then show "finite (f`{i. F i \<noteq> {}})"
   294       by (rule finite_subset) fact
   295   qed fact
   296   ultimately have fin_not_0: "finite {i. \<mu> (F i) \<noteq> 0}"
   297     by (rule finite_subset)
   298 
   299   have disj_not_empty: "disjoint_family_on F {i. F i \<noteq> {}}"
   300     using disj by (auto simp: disjoint_family_on_def)
   301 
   302   from fin_not_0 have "(\<Sum>i. \<mu> (F i)) = (\<Sum>i | \<mu> (F i) \<noteq> 0. \<mu> (F i))"
   303     by (rule suminf_finite) auto
   304   also have "\<dots> = (\<Sum>i | F i \<noteq> {}. \<mu> (F i))"
   305     using fin_not_empty F_subset by (rule setsum.mono_neutral_left) auto
   306   also have "\<dots> = \<mu> (\<Union>i\<in>{i. F i \<noteq> {}}. F i)"
   307     using \<open>positive M \<mu>\<close> \<open>additive M \<mu>\<close> fin_not_empty disj_not_empty F by (intro additive_sum) auto
   308   also have "\<dots> = \<mu> (\<Union>i. F i)"
   309     by (rule arg_cong[where f=\<mu>]) auto
   310   finally show "(\<Sum>i. \<mu> (F i)) = \<mu> (\<Union>i. F i)" .
   311 qed
   312 
   313 lemma (in ring_of_sets) countably_additive_iff_continuous_from_below:
   314   fixes f :: "'a set \<Rightarrow> ennreal"
   315   assumes f: "positive M f" "additive M f"
   316   shows "countably_additive M f \<longleftrightarrow>
   317     (\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i))"
   318   unfolding countably_additive_def
   319 proof safe
   320   assume count_sum: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> UNION UNIV A \<in> M \<longrightarrow> (\<Sum>i. f (A i)) = f (UNION UNIV A)"
   321   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   322   then have dA: "range (disjointed A) \<subseteq> M" by (auto simp: range_disjointed_sets)
   323   with count_sum[THEN spec, of "disjointed A"] A(3)
   324   have f_UN: "(\<Sum>i. f (disjointed A i)) = f (\<Union>i. A i)"
   325     by (auto simp: UN_disjointed_eq disjoint_family_disjointed)
   326   moreover have "(\<lambda>n. (\<Sum>i<n. f (disjointed A i))) \<longlonglongrightarrow> (\<Sum>i. f (disjointed A i))"
   327     using f(1)[unfolded positive_def] dA
   328     by (auto intro!: summable_LIMSEQ)
   329   from LIMSEQ_Suc[OF this]
   330   have "(\<lambda>n. (\<Sum>i\<le>n. f (disjointed A i))) \<longlonglongrightarrow> (\<Sum>i. f (disjointed A i))"
   331     unfolding lessThan_Suc_atMost .
   332   moreover have "\<And>n. (\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   333     using disjointed_additive[OF f A(1,2)] .
   334   ultimately show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)" by simp
   335 next
   336   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   337   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "disjoint_family A" "(\<Union>i. A i) \<in> M"
   338   have *: "(\<Union>n. (\<Union>i<n. A i)) = (\<Union>i. A i)" by auto
   339   have "(\<lambda>n. f (\<Union>i<n. A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   340   proof (unfold *[symmetric], intro cont[rule_format])
   341     show "range (\<lambda>i. \<Union>i<i. A i) \<subseteq> M" "(\<Union>i. \<Union>i<i. A i) \<in> M"
   342       using A * by auto
   343   qed (force intro!: incseq_SucI)
   344   moreover have "\<And>n. f (\<Union>i<n. A i) = (\<Sum>i<n. f (A i))"
   345     using A
   346     by (intro additive_sum[OF f, of _ A, symmetric])
   347        (auto intro: disjoint_family_on_mono[where B=UNIV])
   348   ultimately
   349   have "(\<lambda>i. f (A i)) sums f (\<Union>i. A i)"
   350     unfolding sums_def by simp
   351   from sums_unique[OF this]
   352   show "(\<Sum>i. f (A i)) = f (\<Union>i. A i)" by simp
   353 qed
   354 
   355 lemma (in ring_of_sets) continuous_from_above_iff_empty_continuous:
   356   fixes f :: "'a set \<Rightarrow> ennreal"
   357   assumes f: "positive M f" "additive M f"
   358   shows "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i))
   359      \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0)"
   360 proof safe
   361   assume cont: "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i))"
   362   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) = {}" "\<forall>i. f (A i) \<noteq> \<infinity>"
   363   with cont[THEN spec, of A] show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   364     using \<open>positive M f\<close>[unfolded positive_def] by auto
   365 next
   366   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   367   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) \<in> M" "\<forall>i. f (A i) \<noteq> \<infinity>"
   368 
   369   have f_mono: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<subseteq> b \<Longrightarrow> f a \<le> f b"
   370     using additive_increasing[OF f] unfolding increasing_def by simp
   371 
   372   have decseq_fA: "decseq (\<lambda>i. f (A i))"
   373     using A by (auto simp: decseq_def intro!: f_mono)
   374   have decseq: "decseq (\<lambda>i. A i - (\<Inter>i. A i))"
   375     using A by (auto simp: decseq_def)
   376   then have decseq_f: "decseq (\<lambda>i. f (A i - (\<Inter>i. A i)))"
   377     using A unfolding decseq_def by (auto intro!: f_mono Diff)
   378   have "f (\<Inter>x. A x) \<le> f (A 0)"
   379     using A by (auto intro!: f_mono)
   380   then have f_Int_fin: "f (\<Inter>x. A x) \<noteq> \<infinity>"
   381     using A by (auto simp: top_unique)
   382   { fix i
   383     have "f (A i - (\<Inter>i. A i)) \<le> f (A i)" using A by (auto intro!: f_mono)
   384     then have "f (A i - (\<Inter>i. A i)) \<noteq> \<infinity>"
   385       using A by (auto simp: top_unique) }
   386   note f_fin = this
   387   have "(\<lambda>i. f (A i - (\<Inter>i. A i))) \<longlonglongrightarrow> 0"
   388   proof (intro cont[rule_format, OF _ decseq _ f_fin])
   389     show "range (\<lambda>i. A i - (\<Inter>i. A i)) \<subseteq> M" "(\<Inter>i. A i - (\<Inter>i. A i)) = {}"
   390       using A by auto
   391   qed
   392   from INF_Lim_ereal[OF decseq_f this]
   393   have "(INF n. f (A n - (\<Inter>i. A i))) = 0" .
   394   moreover have "(INF n. f (\<Inter>i. A i)) = f (\<Inter>i. A i)"
   395     by auto
   396   ultimately have "(INF n. f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i)) = 0 + f (\<Inter>i. A i)"
   397     using A(4) f_fin f_Int_fin
   398     by (subst INF_ennreal_add_const) (auto simp: decseq_f)
   399   moreover {
   400     fix n
   401     have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f ((A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i))"
   402       using A by (subst f(2)[THEN additiveD]) auto
   403     also have "(A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i) = A n"
   404       by auto
   405     finally have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f (A n)" . }
   406   ultimately have "(INF n. f (A n)) = f (\<Inter>i. A i)"
   407     by simp
   408   with LIMSEQ_INF[OF decseq_fA]
   409   show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i)" by simp
   410 qed
   411 
   412 lemma (in ring_of_sets) empty_continuous_imp_continuous_from_below:
   413   fixes f :: "'a set \<Rightarrow> ennreal"
   414   assumes f: "positive M f" "additive M f" "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   415   assumes cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   416   assumes A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   417   shows "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   418 proof -
   419   from A have "(\<lambda>i. f ((\<Union>i. A i) - A i)) \<longlonglongrightarrow> 0"
   420     by (intro cont[rule_format]) (auto simp: decseq_def incseq_def)
   421   moreover
   422   { fix i
   423     have "f ((\<Union>i. A i) - A i \<union> A i) = f ((\<Union>i. A i) - A i) + f (A i)"
   424       using A by (intro f(2)[THEN additiveD]) auto
   425     also have "((\<Union>i. A i) - A i) \<union> A i = (\<Union>i. A i)"
   426       by auto
   427     finally have "f ((\<Union>i. A i) - A i) = f (\<Union>i. A i) - f (A i)"
   428       using f(3)[rule_format, of "A i"] A by (auto simp: ennreal_add_diff_cancel subset_eq) }
   429   moreover have "\<forall>\<^sub>F i in sequentially. f (A i) \<le> f (\<Union>i. A i)"
   430     using increasingD[OF additive_increasing[OF f(1, 2)], of "A _" "\<Union>i. A i"] A
   431     by (auto intro!: always_eventually simp: subset_eq)
   432   ultimately show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   433     by (auto intro: ennreal_tendsto_const_minus)
   434 qed
   435 
   436 lemma (in ring_of_sets) empty_continuous_imp_countably_additive:
   437   fixes f :: "'a set \<Rightarrow> ennreal"
   438   assumes f: "positive M f" "additive M f" and fin: "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   439   assumes cont: "\<And>A. range A \<subseteq> M \<Longrightarrow> decseq A \<Longrightarrow> (\<Inter>i. A i) = {} \<Longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   440   shows "countably_additive M f"
   441   using countably_additive_iff_continuous_from_below[OF f]
   442   using empty_continuous_imp_continuous_from_below[OF f fin] cont
   443   by blast
   444 
   445 subsection \<open>Properties of @{const emeasure}\<close>
   446 
   447 lemma emeasure_positive: "positive (sets M) (emeasure M)"
   448   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   449 
   450 lemma emeasure_empty[simp, intro]: "emeasure M {} = 0"
   451   using emeasure_positive[of M] by (simp add: positive_def)
   452 
   453 lemma emeasure_single_in_space: "emeasure M {x} \<noteq> 0 \<Longrightarrow> x \<in> space M"
   454   using emeasure_notin_sets[of "{x}" M] by (auto dest: sets.sets_into_space zero_less_iff_neq_zero[THEN iffD2])
   455 
   456 lemma emeasure_countably_additive: "countably_additive (sets M) (emeasure M)"
   457   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   458 
   459 lemma suminf_emeasure:
   460   "range A \<subseteq> sets M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
   461   using sets.countable_UN[of A UNIV M] emeasure_countably_additive[of M]
   462   by (simp add: countably_additive_def)
   463 
   464 lemma sums_emeasure:
   465   "disjoint_family F \<Longrightarrow> (\<And>i. F i \<in> sets M) \<Longrightarrow> (\<lambda>i. emeasure M (F i)) sums emeasure M (\<Union>i. F i)"
   466   unfolding sums_iff by (intro conjI suminf_emeasure) auto
   467 
   468 lemma emeasure_additive: "additive (sets M) (emeasure M)"
   469   by (metis sets.countably_additive_additive emeasure_positive emeasure_countably_additive)
   470 
   471 lemma plus_emeasure:
   472   "a \<in> sets M \<Longrightarrow> b \<in> sets M \<Longrightarrow> a \<inter> b = {} \<Longrightarrow> emeasure M a + emeasure M b = emeasure M (a \<union> b)"
   473   using additiveD[OF emeasure_additive] ..
   474 
   475 lemma setsum_emeasure:
   476   "F`I \<subseteq> sets M \<Longrightarrow> disjoint_family_on F I \<Longrightarrow> finite I \<Longrightarrow>
   477     (\<Sum>i\<in>I. emeasure M (F i)) = emeasure M (\<Union>i\<in>I. F i)"
   478   by (metis sets.additive_sum emeasure_positive emeasure_additive)
   479 
   480 lemma emeasure_mono:
   481   "a \<subseteq> b \<Longrightarrow> b \<in> sets M \<Longrightarrow> emeasure M a \<le> emeasure M b"
   482   by (metis zero_le sets.additive_increasing emeasure_additive emeasure_notin_sets emeasure_positive increasingD)
   483 
   484 lemma emeasure_space:
   485   "emeasure M A \<le> emeasure M (space M)"
   486   by (metis emeasure_mono emeasure_notin_sets sets.sets_into_space sets.top zero_le)
   487 
   488 lemma emeasure_Diff:
   489   assumes finite: "emeasure M B \<noteq> \<infinity>"
   490   and [measurable]: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
   491   shows "emeasure M (A - B) = emeasure M A - emeasure M B"
   492 proof -
   493   have "(A - B) \<union> B = A" using \<open>B \<subseteq> A\<close> by auto
   494   then have "emeasure M A = emeasure M ((A - B) \<union> B)" by simp
   495   also have "\<dots> = emeasure M (A - B) + emeasure M B"
   496     by (subst plus_emeasure[symmetric]) auto
   497   finally show "emeasure M (A - B) = emeasure M A - emeasure M B"
   498     using finite by simp
   499 qed
   500 
   501 lemma emeasure_compl:
   502   "s \<in> sets M \<Longrightarrow> emeasure M s \<noteq> \<infinity> \<Longrightarrow> emeasure M (space M - s) = emeasure M (space M) - emeasure M s"
   503   by (rule emeasure_Diff) (auto dest: sets.sets_into_space)
   504 
   505 lemma Lim_emeasure_incseq:
   506   "range A \<subseteq> sets M \<Longrightarrow> incseq A \<Longrightarrow> (\<lambda>i. (emeasure M (A i))) \<longlonglongrightarrow> emeasure M (\<Union>i. A i)"
   507   using emeasure_countably_additive
   508   by (auto simp add: sets.countably_additive_iff_continuous_from_below emeasure_positive
   509     emeasure_additive)
   510 
   511 lemma incseq_emeasure:
   512   assumes "range B \<subseteq> sets M" "incseq B"
   513   shows "incseq (\<lambda>i. emeasure M (B i))"
   514   using assms by (auto simp: incseq_def intro!: emeasure_mono)
   515 
   516 lemma SUP_emeasure_incseq:
   517   assumes A: "range A \<subseteq> sets M" "incseq A"
   518   shows "(SUP n. emeasure M (A n)) = emeasure M (\<Union>i. A i)"
   519   using LIMSEQ_SUP[OF incseq_emeasure, OF A] Lim_emeasure_incseq[OF A]
   520   by (simp add: LIMSEQ_unique)
   521 
   522 lemma decseq_emeasure:
   523   assumes "range B \<subseteq> sets M" "decseq B"
   524   shows "decseq (\<lambda>i. emeasure M (B i))"
   525   using assms by (auto simp: decseq_def intro!: emeasure_mono)
   526 
   527 lemma INF_emeasure_decseq:
   528   assumes A: "range A \<subseteq> sets M" and "decseq A"
   529   and finite: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   530   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   531 proof -
   532   have le_MI: "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
   533     using A by (auto intro!: emeasure_mono)
   534   hence *: "emeasure M (\<Inter>i. A i) \<noteq> \<infinity>" using finite[of 0] by (auto simp: top_unique)
   535 
   536   have "emeasure M (A 0) - (INF n. emeasure M (A n)) = (SUP n. emeasure M (A 0) - emeasure M (A n))"
   537     by (simp add: ennreal_INF_const_minus)
   538   also have "\<dots> = (SUP n. emeasure M (A 0 - A n))"
   539     using A finite \<open>decseq A\<close>[unfolded decseq_def] by (subst emeasure_Diff) auto
   540   also have "\<dots> = emeasure M (\<Union>i. A 0 - A i)"
   541   proof (rule SUP_emeasure_incseq)
   542     show "range (\<lambda>n. A 0 - A n) \<subseteq> sets M"
   543       using A by auto
   544     show "incseq (\<lambda>n. A 0 - A n)"
   545       using \<open>decseq A\<close> by (auto simp add: incseq_def decseq_def)
   546   qed
   547   also have "\<dots> = emeasure M (A 0) - emeasure M (\<Inter>i. A i)"
   548     using A finite * by (simp, subst emeasure_Diff) auto
   549   finally show ?thesis
   550     by (rule ennreal_minus_cancel[rotated 3])
   551        (insert finite A, auto intro: INF_lower emeasure_mono)
   552 qed
   553 
   554 lemma emeasure_INT_decseq_subset:
   555   fixes F :: "nat \<Rightarrow> 'a set"
   556   assumes I: "I \<noteq> {}" and F: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> i \<le> j \<Longrightarrow> F j \<subseteq> F i"
   557   assumes F_sets[measurable]: "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M"
   558     and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (F i) \<noteq> \<infinity>"
   559   shows "emeasure M (\<Inter>i\<in>I. F i) = (INF i:I. emeasure M (F i))"
   560 proof cases
   561   assume "finite I"
   562   have "(\<Inter>i\<in>I. F i) = F (Max I)"
   563     using I \<open>finite I\<close> by (intro antisym INF_lower INF_greatest F) auto
   564   moreover have "(INF i:I. emeasure M (F i)) = emeasure M (F (Max I))"
   565     using I \<open>finite I\<close> by (intro antisym INF_lower INF_greatest F emeasure_mono) auto
   566   ultimately show ?thesis
   567     by simp
   568 next
   569   assume "infinite I"
   570   define L where "L n = (LEAST i. i \<in> I \<and> i \<ge> n)" for n
   571   have L: "L n \<in> I \<and> n \<le> L n" for n
   572     unfolding L_def
   573   proof (rule LeastI_ex)
   574     show "\<exists>x. x \<in> I \<and> n \<le> x"
   575       using \<open>infinite I\<close> finite_subset[of I "{..< n}"]
   576       by (rule_tac ccontr) (auto simp: not_le)
   577   qed
   578   have L_eq[simp]: "i \<in> I \<Longrightarrow> L i = i" for i
   579     unfolding L_def by (intro Least_equality) auto
   580   have L_mono: "i \<le> j \<Longrightarrow> L i \<le> L j" for i j
   581     using L[of j] unfolding L_def by (intro Least_le) (auto simp: L_def)
   582 
   583   have "emeasure M (\<Inter>i. F (L i)) = (INF i. emeasure M (F (L i)))"
   584   proof (intro INF_emeasure_decseq[symmetric])
   585     show "decseq (\<lambda>i. F (L i))"
   586       using L by (intro antimonoI F L_mono) auto
   587   qed (insert L fin, auto)
   588   also have "\<dots> = (INF i:I. emeasure M (F i))"
   589   proof (intro antisym INF_greatest)
   590     show "i \<in> I \<Longrightarrow> (INF i. emeasure M (F (L i))) \<le> emeasure M (F i)" for i
   591       by (intro INF_lower2[of i]) auto
   592   qed (insert L, auto intro: INF_lower)
   593   also have "(\<Inter>i. F (L i)) = (\<Inter>i\<in>I. F i)"
   594   proof (intro antisym INF_greatest)
   595     show "i \<in> I \<Longrightarrow> (\<Inter>i. F (L i)) \<subseteq> F i" for i
   596       by (intro INF_lower2[of i]) auto
   597   qed (insert L, auto)
   598   finally show ?thesis .
   599 qed
   600 
   601 lemma Lim_emeasure_decseq:
   602   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   603   shows "(\<lambda>i. emeasure M (A i)) \<longlonglongrightarrow> emeasure M (\<Inter>i. A i)"
   604   using LIMSEQ_INF[OF decseq_emeasure, OF A]
   605   using INF_emeasure_decseq[OF A fin] by simp
   606 
   607 lemma emeasure_lfp'[consumes 1, case_names cont measurable]:
   608   assumes "P M"
   609   assumes cont: "sup_continuous F"
   610   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
   611   shows "emeasure M {x\<in>space M. lfp F x} = (SUP i. emeasure M {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   612 proof -
   613   have "emeasure M {x\<in>space M. lfp F x} = emeasure M (\<Union>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   614     using sup_continuous_lfp[OF cont] by (auto simp add: bot_fun_def intro!: arg_cong2[where f=emeasure])
   615   moreover { fix i from \<open>P M\<close> have "{x\<in>space M. (F ^^ i) (\<lambda>x. False) x} \<in> sets M"
   616     by (induct i arbitrary: M) (auto simp add: pred_def[symmetric] intro: *) }
   617   moreover have "incseq (\<lambda>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   618   proof (rule incseq_SucI)
   619     fix i
   620     have "(F ^^ i) (\<lambda>x. False) \<le> (F ^^ (Suc i)) (\<lambda>x. False)"
   621     proof (induct i)
   622       case 0 show ?case by (simp add: le_fun_def)
   623     next
   624       case Suc thus ?case using monoD[OF sup_continuous_mono[OF cont] Suc] by auto
   625     qed
   626     then show "{x \<in> space M. (F ^^ i) (\<lambda>x. False) x} \<subseteq> {x \<in> space M. (F ^^ Suc i) (\<lambda>x. False) x}"
   627       by auto
   628   qed
   629   ultimately show ?thesis
   630     by (subst SUP_emeasure_incseq) auto
   631 qed
   632 
   633 lemma emeasure_lfp:
   634   assumes [simp]: "\<And>s. sets (M s) = sets N"
   635   assumes cont: "sup_continuous F" "sup_continuous f"
   636   assumes meas: "\<And>P. Measurable.pred N P \<Longrightarrow> Measurable.pred N (F P)"
   637   assumes iter: "\<And>P s. Measurable.pred N P \<Longrightarrow> P \<le> lfp F \<Longrightarrow> emeasure (M s) {x\<in>space N. F P x} = f (\<lambda>s. emeasure (M s) {x\<in>space N. P x}) s"
   638   shows "emeasure (M s) {x\<in>space N. lfp F x} = lfp f s"
   639 proof (subst lfp_transfer_bounded[where \<alpha>="\<lambda>F s. emeasure (M s) {x\<in>space N. F x}" and g=f and f=F and P="Measurable.pred N", symmetric])
   640   fix C assume "incseq C" "\<And>i. Measurable.pred N (C i)"
   641   then show "(\<lambda>s. emeasure (M s) {x \<in> space N. (SUP i. C i) x}) = (SUP i. (\<lambda>s. emeasure (M s) {x \<in> space N. C i x}))"
   642     unfolding SUP_apply[abs_def]
   643     by (subst SUP_emeasure_incseq) (auto simp: mono_def fun_eq_iff intro!: arg_cong2[where f=emeasure])
   644 qed (auto simp add: iter le_fun_def SUP_apply[abs_def] intro!: meas cont)
   645 
   646 lemma emeasure_subadditive_finite:
   647   "finite I \<Longrightarrow> A ` I \<subseteq> sets M \<Longrightarrow> emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
   648   by (rule sets.subadditive[OF emeasure_positive emeasure_additive]) auto
   649 
   650 lemma emeasure_subadditive:
   651   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   652   using emeasure_subadditive_finite[of "{True, False}" "\<lambda>True \<Rightarrow> A | False \<Rightarrow> B" M] by simp
   653 
   654 lemma emeasure_subadditive_countably:
   655   assumes "range f \<subseteq> sets M"
   656   shows "emeasure M (\<Union>i. f i) \<le> (\<Sum>i. emeasure M (f i))"
   657 proof -
   658   have "emeasure M (\<Union>i. f i) = emeasure M (\<Union>i. disjointed f i)"
   659     unfolding UN_disjointed_eq ..
   660   also have "\<dots> = (\<Sum>i. emeasure M (disjointed f i))"
   661     using sets.range_disjointed_sets[OF assms] suminf_emeasure[of "disjointed f"]
   662     by (simp add:  disjoint_family_disjointed comp_def)
   663   also have "\<dots> \<le> (\<Sum>i. emeasure M (f i))"
   664     using sets.range_disjointed_sets[OF assms] assms
   665     by (auto intro!: suminf_le emeasure_mono disjointed_subset)
   666   finally show ?thesis .
   667 qed
   668 
   669 lemma emeasure_insert:
   670   assumes sets: "{x} \<in> sets M" "A \<in> sets M" and "x \<notin> A"
   671   shows "emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   672 proof -
   673   have "{x} \<inter> A = {}" using \<open>x \<notin> A\<close> by auto
   674   from plus_emeasure[OF sets this] show ?thesis by simp
   675 qed
   676 
   677 lemma emeasure_insert_ne:
   678   "A \<noteq> {} \<Longrightarrow> {x} \<in> sets M \<Longrightarrow> A \<in> sets M \<Longrightarrow> x \<notin> A \<Longrightarrow> emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   679   by (rule emeasure_insert)
   680 
   681 lemma emeasure_eq_setsum_singleton:
   682   assumes "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
   683   shows "emeasure M S = (\<Sum>x\<in>S. emeasure M {x})"
   684   using setsum_emeasure[of "\<lambda>x. {x}" S M] assms
   685   by (auto simp: disjoint_family_on_def subset_eq)
   686 
   687 lemma setsum_emeasure_cover:
   688   assumes "finite S" and "A \<in> sets M" and br_in_M: "B ` S \<subseteq> sets M"
   689   assumes A: "A \<subseteq> (\<Union>i\<in>S. B i)"
   690   assumes disj: "disjoint_family_on B S"
   691   shows "emeasure M A = (\<Sum>i\<in>S. emeasure M (A \<inter> (B i)))"
   692 proof -
   693   have "(\<Sum>i\<in>S. emeasure M (A \<inter> (B i))) = emeasure M (\<Union>i\<in>S. A \<inter> (B i))"
   694   proof (rule setsum_emeasure)
   695     show "disjoint_family_on (\<lambda>i. A \<inter> B i) S"
   696       using \<open>disjoint_family_on B S\<close>
   697       unfolding disjoint_family_on_def by auto
   698   qed (insert assms, auto)
   699   also have "(\<Union>i\<in>S. A \<inter> (B i)) = A"
   700     using A by auto
   701   finally show ?thesis by simp
   702 qed
   703 
   704 lemma emeasure_eq_0:
   705   "N \<in> sets M \<Longrightarrow> emeasure M N = 0 \<Longrightarrow> K \<subseteq> N \<Longrightarrow> emeasure M K = 0"
   706   by (metis emeasure_mono order_eq_iff zero_le)
   707 
   708 lemma emeasure_UN_eq_0:
   709   assumes "\<And>i::nat. emeasure M (N i) = 0" and "range N \<subseteq> sets M"
   710   shows "emeasure M (\<Union>i. N i) = 0"
   711 proof -
   712   have "emeasure M (\<Union>i. N i) \<le> 0"
   713     using emeasure_subadditive_countably[OF assms(2)] assms(1) by simp
   714   then show ?thesis
   715     by (auto intro: antisym zero_le)
   716 qed
   717 
   718 lemma measure_eqI_finite:
   719   assumes [simp]: "sets M = Pow A" "sets N = Pow A" and "finite A"
   720   assumes eq: "\<And>a. a \<in> A \<Longrightarrow> emeasure M {a} = emeasure N {a}"
   721   shows "M = N"
   722 proof (rule measure_eqI)
   723   fix X assume "X \<in> sets M"
   724   then have X: "X \<subseteq> A" by auto
   725   then have "emeasure M X = (\<Sum>a\<in>X. emeasure M {a})"
   726     using \<open>finite A\<close> by (subst emeasure_eq_setsum_singleton) (auto dest: finite_subset)
   727   also have "\<dots> = (\<Sum>a\<in>X. emeasure N {a})"
   728     using X eq by (auto intro!: setsum.cong)
   729   also have "\<dots> = emeasure N X"
   730     using X \<open>finite A\<close> by (subst emeasure_eq_setsum_singleton) (auto dest: finite_subset)
   731   finally show "emeasure M X = emeasure N X" .
   732 qed simp
   733 
   734 lemma measure_eqI_generator_eq:
   735   fixes M N :: "'a measure" and E :: "'a set set" and A :: "nat \<Rightarrow> 'a set"
   736   assumes "Int_stable E" "E \<subseteq> Pow \<Omega>"
   737   and eq: "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   738   and M: "sets M = sigma_sets \<Omega> E"
   739   and N: "sets N = sigma_sets \<Omega> E"
   740   and A: "range A \<subseteq> E" "(\<Union>i. A i) = \<Omega>" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   741   shows "M = N"
   742 proof -
   743   let ?\<mu>  = "emeasure M" and ?\<nu> = "emeasure N"
   744   interpret S: sigma_algebra \<Omega> "sigma_sets \<Omega> E" by (rule sigma_algebra_sigma_sets) fact
   745   have "space M = \<Omega>"
   746     using sets.top[of M] sets.space_closed[of M] S.top S.space_closed \<open>sets M = sigma_sets \<Omega> E\<close>
   747     by blast
   748 
   749   { fix F D assume "F \<in> E" and "?\<mu> F \<noteq> \<infinity>"
   750     then have [intro]: "F \<in> sigma_sets \<Omega> E" by auto
   751     have "?\<nu> F \<noteq> \<infinity>" using \<open>?\<mu> F \<noteq> \<infinity>\<close> \<open>F \<in> E\<close> eq by simp
   752     assume "D \<in> sets M"
   753     with \<open>Int_stable E\<close> \<open>E \<subseteq> Pow \<Omega>\<close> have "emeasure M (F \<inter> D) = emeasure N (F \<inter> D)"
   754       unfolding M
   755     proof (induct rule: sigma_sets_induct_disjoint)
   756       case (basic A)
   757       then have "F \<inter> A \<in> E" using \<open>Int_stable E\<close> \<open>F \<in> E\<close> by (auto simp: Int_stable_def)
   758       then show ?case using eq by auto
   759     next
   760       case empty then show ?case by simp
   761     next
   762       case (compl A)
   763       then have **: "F \<inter> (\<Omega> - A) = F - (F \<inter> A)"
   764         and [intro]: "F \<inter> A \<in> sigma_sets \<Omega> E"
   765         using \<open>F \<in> E\<close> S.sets_into_space by (auto simp: M)
   766       have "?\<nu> (F \<inter> A) \<le> ?\<nu> F" by (auto intro!: emeasure_mono simp: M N)
   767       then have "?\<nu> (F \<inter> A) \<noteq> \<infinity>" using \<open>?\<nu> F \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   768       have "?\<mu> (F \<inter> A) \<le> ?\<mu> F" by (auto intro!: emeasure_mono simp: M N)
   769       then have "?\<mu> (F \<inter> A) \<noteq> \<infinity>" using \<open>?\<mu> F \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   770       then have "?\<mu> (F \<inter> (\<Omega> - A)) = ?\<mu> F - ?\<mu> (F \<inter> A)" unfolding **
   771         using \<open>F \<inter> A \<in> sigma_sets \<Omega> E\<close> by (auto intro!: emeasure_Diff simp: M N)
   772       also have "\<dots> = ?\<nu> F - ?\<nu> (F \<inter> A)" using eq \<open>F \<in> E\<close> compl by simp
   773       also have "\<dots> = ?\<nu> (F \<inter> (\<Omega> - A))" unfolding **
   774         using \<open>F \<inter> A \<in> sigma_sets \<Omega> E\<close> \<open>?\<nu> (F \<inter> A) \<noteq> \<infinity>\<close>
   775         by (auto intro!: emeasure_Diff[symmetric] simp: M N)
   776       finally show ?case
   777         using \<open>space M = \<Omega>\<close> by auto
   778     next
   779       case (union A)
   780       then have "?\<mu> (\<Union>x. F \<inter> A x) = ?\<nu> (\<Union>x. F \<inter> A x)"
   781         by (subst (1 2) suminf_emeasure[symmetric]) (auto simp: disjoint_family_on_def subset_eq M N)
   782       with A show ?case
   783         by auto
   784     qed }
   785   note * = this
   786   show "M = N"
   787   proof (rule measure_eqI)
   788     show "sets M = sets N"
   789       using M N by simp
   790     have [simp, intro]: "\<And>i. A i \<in> sets M"
   791       using A(1) by (auto simp: subset_eq M)
   792     fix F assume "F \<in> sets M"
   793     let ?D = "disjointed (\<lambda>i. F \<inter> A i)"
   794     from \<open>space M = \<Omega>\<close> have F_eq: "F = (\<Union>i. ?D i)"
   795       using \<open>F \<in> sets M\<close>[THEN sets.sets_into_space] A(2)[symmetric] by (auto simp: UN_disjointed_eq)
   796     have [simp, intro]: "\<And>i. ?D i \<in> sets M"
   797       using sets.range_disjointed_sets[of "\<lambda>i. F \<inter> A i" M] \<open>F \<in> sets M\<close>
   798       by (auto simp: subset_eq)
   799     have "disjoint_family ?D"
   800       by (auto simp: disjoint_family_disjointed)
   801     moreover
   802     have "(\<Sum>i. emeasure M (?D i)) = (\<Sum>i. emeasure N (?D i))"
   803     proof (intro arg_cong[where f=suminf] ext)
   804       fix i
   805       have "A i \<inter> ?D i = ?D i"
   806         by (auto simp: disjointed_def)
   807       then show "emeasure M (?D i) = emeasure N (?D i)"
   808         using *[of "A i" "?D i", OF _ A(3)] A(1) by auto
   809     qed
   810     ultimately show "emeasure M F = emeasure N F"
   811       by (simp add: image_subset_iff \<open>sets M = sets N\<close>[symmetric] F_eq[symmetric] suminf_emeasure)
   812   qed
   813 qed
   814 
   815 lemma measure_of_of_measure: "measure_of (space M) (sets M) (emeasure M) = M"
   816 proof (intro measure_eqI emeasure_measure_of_sigma)
   817   show "sigma_algebra (space M) (sets M)" ..
   818   show "positive (sets M) (emeasure M)"
   819     by (simp add: positive_def)
   820   show "countably_additive (sets M) (emeasure M)"
   821     by (simp add: emeasure_countably_additive)
   822 qed simp_all
   823 
   824 subsection \<open>\<open>\<mu>\<close>-null sets\<close>
   825 
   826 definition null_sets :: "'a measure \<Rightarrow> 'a set set" where
   827   "null_sets M = {N\<in>sets M. emeasure M N = 0}"
   828 
   829 lemma null_setsD1[dest]: "A \<in> null_sets M \<Longrightarrow> emeasure M A = 0"
   830   by (simp add: null_sets_def)
   831 
   832 lemma null_setsD2[dest]: "A \<in> null_sets M \<Longrightarrow> A \<in> sets M"
   833   unfolding null_sets_def by simp
   834 
   835 lemma null_setsI[intro]: "emeasure M A = 0 \<Longrightarrow> A \<in> sets M \<Longrightarrow> A \<in> null_sets M"
   836   unfolding null_sets_def by simp
   837 
   838 interpretation null_sets: ring_of_sets "space M" "null_sets M" for M
   839 proof (rule ring_of_setsI)
   840   show "null_sets M \<subseteq> Pow (space M)"
   841     using sets.sets_into_space by auto
   842   show "{} \<in> null_sets M"
   843     by auto
   844   fix A B assume null_sets: "A \<in> null_sets M" "B \<in> null_sets M"
   845   then have sets: "A \<in> sets M" "B \<in> sets M"
   846     by auto
   847   then have *: "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   848     "emeasure M (A - B) \<le> emeasure M A"
   849     by (auto intro!: emeasure_subadditive emeasure_mono)
   850   then have "emeasure M B = 0" "emeasure M A = 0"
   851     using null_sets by auto
   852   with sets * show "A - B \<in> null_sets M" "A \<union> B \<in> null_sets M"
   853     by (auto intro!: antisym zero_le)
   854 qed
   855 
   856 lemma UN_from_nat_into:
   857   assumes I: "countable I" "I \<noteq> {}"
   858   shows "(\<Union>i\<in>I. N i) = (\<Union>i. N (from_nat_into I i))"
   859 proof -
   860   have "(\<Union>i\<in>I. N i) = \<Union>(N ` range (from_nat_into I))"
   861     using I by simp
   862   also have "\<dots> = (\<Union>i. (N \<circ> from_nat_into I) i)"
   863     by simp
   864   finally show ?thesis by simp
   865 qed
   866 
   867 lemma null_sets_UN':
   868   assumes "countable I"
   869   assumes "\<And>i. i \<in> I \<Longrightarrow> N i \<in> null_sets M"
   870   shows "(\<Union>i\<in>I. N i) \<in> null_sets M"
   871 proof cases
   872   assume "I = {}" then show ?thesis by simp
   873 next
   874   assume "I \<noteq> {}"
   875   show ?thesis
   876   proof (intro conjI CollectI null_setsI)
   877     show "(\<Union>i\<in>I. N i) \<in> sets M"
   878       using assms by (intro sets.countable_UN') auto
   879     have "emeasure M (\<Union>i\<in>I. N i) \<le> (\<Sum>n. emeasure M (N (from_nat_into I n)))"
   880       unfolding UN_from_nat_into[OF \<open>countable I\<close> \<open>I \<noteq> {}\<close>]
   881       using assms \<open>I \<noteq> {}\<close> by (intro emeasure_subadditive_countably) (auto intro: from_nat_into)
   882     also have "(\<lambda>n. emeasure M (N (from_nat_into I n))) = (\<lambda>_. 0)"
   883       using assms \<open>I \<noteq> {}\<close> by (auto intro: from_nat_into)
   884     finally show "emeasure M (\<Union>i\<in>I. N i) = 0"
   885       by (intro antisym zero_le) simp
   886   qed
   887 qed
   888 
   889 lemma null_sets_UN[intro]:
   890   "(\<And>i::'i::countable. N i \<in> null_sets M) \<Longrightarrow> (\<Union>i. N i) \<in> null_sets M"
   891   by (rule null_sets_UN') auto
   892 
   893 lemma null_set_Int1:
   894   assumes "B \<in> null_sets M" "A \<in> sets M" shows "A \<inter> B \<in> null_sets M"
   895 proof (intro CollectI conjI null_setsI)
   896   show "emeasure M (A \<inter> B) = 0" using assms
   897     by (intro emeasure_eq_0[of B _ "A \<inter> B"]) auto
   898 qed (insert assms, auto)
   899 
   900 lemma null_set_Int2:
   901   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B \<inter> A \<in> null_sets M"
   902   using assms by (subst Int_commute) (rule null_set_Int1)
   903 
   904 lemma emeasure_Diff_null_set:
   905   assumes "B \<in> null_sets M" "A \<in> sets M"
   906   shows "emeasure M (A - B) = emeasure M A"
   907 proof -
   908   have *: "A - B = (A - (A \<inter> B))" by auto
   909   have "A \<inter> B \<in> null_sets M" using assms by (rule null_set_Int1)
   910   then show ?thesis
   911     unfolding * using assms
   912     by (subst emeasure_Diff) auto
   913 qed
   914 
   915 lemma null_set_Diff:
   916   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B - A \<in> null_sets M"
   917 proof (intro CollectI conjI null_setsI)
   918   show "emeasure M (B - A) = 0" using assms by (intro emeasure_eq_0[of B _ "B - A"]) auto
   919 qed (insert assms, auto)
   920 
   921 lemma emeasure_Un_null_set:
   922   assumes "A \<in> sets M" "B \<in> null_sets M"
   923   shows "emeasure M (A \<union> B) = emeasure M A"
   924 proof -
   925   have *: "A \<union> B = A \<union> (B - A)" by auto
   926   have "B - A \<in> null_sets M" using assms(2,1) by (rule null_set_Diff)
   927   then show ?thesis
   928     unfolding * using assms
   929     by (subst plus_emeasure[symmetric]) auto
   930 qed
   931 
   932 subsection \<open>The almost everywhere filter (i.e.\ quantifier)\<close>
   933 
   934 definition ae_filter :: "'a measure \<Rightarrow> 'a filter" where
   935   "ae_filter M = (INF N:null_sets M. principal (space M - N))"
   936 
   937 abbreviation almost_everywhere :: "'a measure \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   938   "almost_everywhere M P \<equiv> eventually P (ae_filter M)"
   939 
   940 syntax
   941   "_almost_everywhere" :: "pttrn \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool" ("AE _ in _. _" [0,0,10] 10)
   942 
   943 translations
   944   "AE x in M. P" \<rightleftharpoons> "CONST almost_everywhere M (\<lambda>x. P)"
   945 
   946 lemma eventually_ae_filter: "eventually P (ae_filter M) \<longleftrightarrow> (\<exists>N\<in>null_sets M. {x \<in> space M. \<not> P x} \<subseteq> N)"
   947   unfolding ae_filter_def by (subst eventually_INF_base) (auto simp: eventually_principal subset_eq)
   948 
   949 lemma AE_I':
   950   "N \<in> null_sets M \<Longrightarrow> {x\<in>space M. \<not> P x} \<subseteq> N \<Longrightarrow> (AE x in M. P x)"
   951   unfolding eventually_ae_filter by auto
   952 
   953 lemma AE_iff_null:
   954   assumes "{x\<in>space M. \<not> P x} \<in> sets M" (is "?P \<in> sets M")
   955   shows "(AE x in M. P x) \<longleftrightarrow> {x\<in>space M. \<not> P x} \<in> null_sets M"
   956 proof
   957   assume "AE x in M. P x" then obtain N where N: "N \<in> sets M" "?P \<subseteq> N" "emeasure M N = 0"
   958     unfolding eventually_ae_filter by auto
   959   have "emeasure M ?P \<le> emeasure M N"
   960     using assms N(1,2) by (auto intro: emeasure_mono)
   961   then have "emeasure M ?P = 0"
   962     unfolding \<open>emeasure M N = 0\<close> by auto
   963   then show "?P \<in> null_sets M" using assms by auto
   964 next
   965   assume "?P \<in> null_sets M" with assms show "AE x in M. P x" by (auto intro: AE_I')
   966 qed
   967 
   968 lemma AE_iff_null_sets:
   969   "N \<in> sets M \<Longrightarrow> N \<in> null_sets M \<longleftrightarrow> (AE x in M. x \<notin> N)"
   970   using Int_absorb1[OF sets.sets_into_space, of N M]
   971   by (subst AE_iff_null) (auto simp: Int_def[symmetric])
   972 
   973 lemma AE_not_in:
   974   "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
   975   by (metis AE_iff_null_sets null_setsD2)
   976 
   977 lemma AE_iff_measurable:
   978   "N \<in> sets M \<Longrightarrow> {x\<in>space M. \<not> P x} = N \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> emeasure M N = 0"
   979   using AE_iff_null[of _ P] by auto
   980 
   981 lemma AE_E[consumes 1]:
   982   assumes "AE x in M. P x"
   983   obtains N where "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
   984   using assms unfolding eventually_ae_filter by auto
   985 
   986 lemma AE_E2:
   987   assumes "AE x in M. P x" "{x\<in>space M. P x} \<in> sets M"
   988   shows "emeasure M {x\<in>space M. \<not> P x} = 0" (is "emeasure M ?P = 0")
   989 proof -
   990   have "{x\<in>space M. \<not> P x} = space M - {x\<in>space M. P x}" by auto
   991   with AE_iff_null[of M P] assms show ?thesis by auto
   992 qed
   993 
   994 lemma AE_I:
   995   assumes "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
   996   shows "AE x in M. P x"
   997   using assms unfolding eventually_ae_filter by auto
   998 
   999 lemma AE_mp[elim!]:
  1000   assumes AE_P: "AE x in M. P x" and AE_imp: "AE x in M. P x \<longrightarrow> Q x"
  1001   shows "AE x in M. Q x"
  1002 proof -
  1003   from AE_P obtain A where P: "{x\<in>space M. \<not> P x} \<subseteq> A"
  1004     and A: "A \<in> sets M" "emeasure M A = 0"
  1005     by (auto elim!: AE_E)
  1006 
  1007   from AE_imp obtain B where imp: "{x\<in>space M. P x \<and> \<not> Q x} \<subseteq> B"
  1008     and B: "B \<in> sets M" "emeasure M B = 0"
  1009     by (auto elim!: AE_E)
  1010 
  1011   show ?thesis
  1012   proof (intro AE_I)
  1013     have "emeasure M (A \<union> B) \<le> 0"
  1014       using emeasure_subadditive[of A M B] A B by auto
  1015     then show "A \<union> B \<in> sets M" "emeasure M (A \<union> B) = 0"
  1016       using A B by auto
  1017     show "{x\<in>space M. \<not> Q x} \<subseteq> A \<union> B"
  1018       using P imp by auto
  1019   qed
  1020 qed
  1021 
  1022 (* depricated replace by laws about eventually *)
  1023 lemma
  1024   shows AE_iffI: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1025     and AE_disjI1: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<or> Q x"
  1026     and AE_disjI2: "AE x in M. Q x \<Longrightarrow> AE x in M. P x \<or> Q x"
  1027     and AE_conjI: "AE x in M. P x \<Longrightarrow> AE x in M. Q x \<Longrightarrow> AE x in M. P x \<and> Q x"
  1028     and AE_conj_iff[simp]: "(AE x in M. P x \<and> Q x) \<longleftrightarrow> (AE x in M. P x) \<and> (AE x in M. Q x)"
  1029   by auto
  1030 
  1031 lemma AE_impI:
  1032   "(P \<Longrightarrow> AE x in M. Q x) \<Longrightarrow> AE x in M. P \<longrightarrow> Q x"
  1033   by (cases P) auto
  1034 
  1035 lemma AE_measure:
  1036   assumes AE: "AE x in M. P x" and sets: "{x\<in>space M. P x} \<in> sets M" (is "?P \<in> sets M")
  1037   shows "emeasure M {x\<in>space M. P x} = emeasure M (space M)"
  1038 proof -
  1039   from AE_E[OF AE] guess N . note N = this
  1040   with sets have "emeasure M (space M) \<le> emeasure M (?P \<union> N)"
  1041     by (intro emeasure_mono) auto
  1042   also have "\<dots> \<le> emeasure M ?P + emeasure M N"
  1043     using sets N by (intro emeasure_subadditive) auto
  1044   also have "\<dots> = emeasure M ?P" using N by simp
  1045   finally show "emeasure M ?P = emeasure M (space M)"
  1046     using emeasure_space[of M "?P"] by auto
  1047 qed
  1048 
  1049 lemma AE_space: "AE x in M. x \<in> space M"
  1050   by (rule AE_I[where N="{}"]) auto
  1051 
  1052 lemma AE_I2[simp, intro]:
  1053   "(\<And>x. x \<in> space M \<Longrightarrow> P x) \<Longrightarrow> AE x in M. P x"
  1054   using AE_space by force
  1055 
  1056 lemma AE_Ball_mp:
  1057   "\<forall>x\<in>space M. P x \<Longrightarrow> AE x in M. P x \<longrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1058   by auto
  1059 
  1060 lemma AE_cong[cong]:
  1061   "(\<And>x. x \<in> space M \<Longrightarrow> P x \<longleftrightarrow> Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in M. Q x)"
  1062   by auto
  1063 
  1064 lemma AE_all_countable:
  1065   "(AE x in M. \<forall>i. P i x) \<longleftrightarrow> (\<forall>i::'i::countable. AE x in M. P i x)"
  1066 proof
  1067   assume "\<forall>i. AE x in M. P i x"
  1068   from this[unfolded eventually_ae_filter Bex_def, THEN choice]
  1069   obtain N where N: "\<And>i. N i \<in> null_sets M" "\<And>i. {x\<in>space M. \<not> P i x} \<subseteq> N i" by auto
  1070   have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. {x\<in>space M. \<not> P i x})" by auto
  1071   also have "\<dots> \<subseteq> (\<Union>i. N i)" using N by auto
  1072   finally have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. N i)" .
  1073   moreover from N have "(\<Union>i. N i) \<in> null_sets M"
  1074     by (intro null_sets_UN) auto
  1075   ultimately show "AE x in M. \<forall>i. P i x"
  1076     unfolding eventually_ae_filter by auto
  1077 qed auto
  1078 
  1079 lemma AE_ball_countable:
  1080   assumes [intro]: "countable X"
  1081   shows "(AE x in M. \<forall>y\<in>X. P x y) \<longleftrightarrow> (\<forall>y\<in>X. AE x in M. P x y)"
  1082 proof
  1083   assume "\<forall>y\<in>X. AE x in M. P x y"
  1084   from this[unfolded eventually_ae_filter Bex_def, THEN bchoice]
  1085   obtain N where N: "\<And>y. y \<in> X \<Longrightarrow> N y \<in> null_sets M" "\<And>y. y \<in> X \<Longrightarrow> {x\<in>space M. \<not> P x y} \<subseteq> N y"
  1086     by auto
  1087   have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. {x\<in>space M. \<not> P x y})"
  1088     by auto
  1089   also have "\<dots> \<subseteq> (\<Union>y\<in>X. N y)"
  1090     using N by auto
  1091   finally have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. N y)" .
  1092   moreover from N have "(\<Union>y\<in>X. N y) \<in> null_sets M"
  1093     by (intro null_sets_UN') auto
  1094   ultimately show "AE x in M. \<forall>y\<in>X. P x y"
  1095     unfolding eventually_ae_filter by auto
  1096 qed auto
  1097 
  1098 lemma AE_discrete_difference:
  1099   assumes X: "countable X"
  1100   assumes null: "\<And>x. x \<in> X \<Longrightarrow> emeasure M {x} = 0"
  1101   assumes sets: "\<And>x. x \<in> X \<Longrightarrow> {x} \<in> sets M"
  1102   shows "AE x in M. x \<notin> X"
  1103 proof -
  1104   have "(\<Union>x\<in>X. {x}) \<in> null_sets M"
  1105     using assms by (intro null_sets_UN') auto
  1106   from AE_not_in[OF this] show "AE x in M. x \<notin> X"
  1107     by auto
  1108 qed
  1109 
  1110 lemma AE_finite_all:
  1111   assumes f: "finite S" shows "(AE x in M. \<forall>i\<in>S. P i x) \<longleftrightarrow> (\<forall>i\<in>S. AE x in M. P i x)"
  1112   using f by induct auto
  1113 
  1114 lemma AE_finite_allI:
  1115   assumes "finite S"
  1116   shows "(\<And>s. s \<in> S \<Longrightarrow> AE x in M. Q s x) \<Longrightarrow> AE x in M. \<forall>s\<in>S. Q s x"
  1117   using AE_finite_all[OF \<open>finite S\<close>] by auto
  1118 
  1119 lemma emeasure_mono_AE:
  1120   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B"
  1121     and B: "B \<in> sets M"
  1122   shows "emeasure M A \<le> emeasure M B"
  1123 proof cases
  1124   assume A: "A \<in> sets M"
  1125   from imp obtain N where N: "{x\<in>space M. \<not> (x \<in> A \<longrightarrow> x \<in> B)} \<subseteq> N" "N \<in> null_sets M"
  1126     by (auto simp: eventually_ae_filter)
  1127   have "emeasure M A = emeasure M (A - N)"
  1128     using N A by (subst emeasure_Diff_null_set) auto
  1129   also have "emeasure M (A - N) \<le> emeasure M (B - N)"
  1130     using N A B sets.sets_into_space by (auto intro!: emeasure_mono)
  1131   also have "emeasure M (B - N) = emeasure M B"
  1132     using N B by (subst emeasure_Diff_null_set) auto
  1133   finally show ?thesis .
  1134 qed (simp add: emeasure_notin_sets)
  1135 
  1136 lemma emeasure_eq_AE:
  1137   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1138   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1139   shows "emeasure M A = emeasure M B"
  1140   using assms by (safe intro!: antisym emeasure_mono_AE) auto
  1141 
  1142 lemma emeasure_Collect_eq_AE:
  1143   "AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> Measurable.pred M Q \<Longrightarrow> Measurable.pred M P \<Longrightarrow>
  1144    emeasure M {x\<in>space M. P x} = emeasure M {x\<in>space M. Q x}"
  1145    by (intro emeasure_eq_AE) auto
  1146 
  1147 lemma emeasure_eq_0_AE: "AE x in M. \<not> P x \<Longrightarrow> emeasure M {x\<in>space M. P x} = 0"
  1148   using AE_iff_measurable[OF _ refl, of M "\<lambda>x. \<not> P x"]
  1149   by (cases "{x\<in>space M. P x} \<in> sets M") (simp_all add: emeasure_notin_sets)
  1150 
  1151 lemma emeasure_add_AE:
  1152   assumes [measurable]: "A \<in> sets M" "B \<in> sets M" "C \<in> sets M"
  1153   assumes 1: "AE x in M. x \<in> C \<longleftrightarrow> x \<in> A \<or> x \<in> B"
  1154   assumes 2: "AE x in M. \<not> (x \<in> A \<and> x \<in> B)"
  1155   shows "emeasure M C = emeasure M A + emeasure M B"
  1156 proof -
  1157   have "emeasure M C = emeasure M (A \<union> B)"
  1158     by (rule emeasure_eq_AE) (insert 1, auto)
  1159   also have "\<dots> = emeasure M A + emeasure M (B - A)"
  1160     by (subst plus_emeasure) auto
  1161   also have "emeasure M (B - A) = emeasure M B"
  1162     by (rule emeasure_eq_AE) (insert 2, auto)
  1163   finally show ?thesis .
  1164 qed
  1165 
  1166 subsection \<open>\<open>\<sigma>\<close>-finite Measures\<close>
  1167 
  1168 locale sigma_finite_measure =
  1169   fixes M :: "'a measure"
  1170   assumes sigma_finite_countable:
  1171     "\<exists>A::'a set set. countable A \<and> A \<subseteq> sets M \<and> (\<Union>A) = space M \<and> (\<forall>a\<in>A. emeasure M a \<noteq> \<infinity>)"
  1172 
  1173 lemma (in sigma_finite_measure) sigma_finite:
  1174   obtains A :: "nat \<Rightarrow> 'a set"
  1175   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1176 proof -
  1177   obtain A :: "'a set set" where
  1178     [simp]: "countable A" and
  1179     A: "A \<subseteq> sets M" "(\<Union>A) = space M" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  1180     using sigma_finite_countable by metis
  1181   show thesis
  1182   proof cases
  1183     assume "A = {}" with \<open>(\<Union>A) = space M\<close> show thesis
  1184       by (intro that[of "\<lambda>_. {}"]) auto
  1185   next
  1186     assume "A \<noteq> {}"
  1187     show thesis
  1188     proof
  1189       show "range (from_nat_into A) \<subseteq> sets M"
  1190         using \<open>A \<noteq> {}\<close> A by auto
  1191       have "(\<Union>i. from_nat_into A i) = \<Union>A"
  1192         using range_from_nat_into[OF \<open>A \<noteq> {}\<close> \<open>countable A\<close>] by auto
  1193       with A show "(\<Union>i. from_nat_into A i) = space M"
  1194         by auto
  1195     qed (intro A from_nat_into \<open>A \<noteq> {}\<close>)
  1196   qed
  1197 qed
  1198 
  1199 lemma (in sigma_finite_measure) sigma_finite_disjoint:
  1200   obtains A :: "nat \<Rightarrow> 'a set"
  1201   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "disjoint_family A"
  1202 proof -
  1203   obtain A :: "nat \<Rightarrow> 'a set" where
  1204     range: "range A \<subseteq> sets M" and
  1205     space: "(\<Union>i. A i) = space M" and
  1206     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1207     using sigma_finite by blast
  1208   show thesis
  1209   proof (rule that[of "disjointed A"])
  1210     show "range (disjointed A) \<subseteq> sets M"
  1211       by (rule sets.range_disjointed_sets[OF range])
  1212     show "(\<Union>i. disjointed A i) = space M"
  1213       and "disjoint_family (disjointed A)"
  1214       using disjoint_family_disjointed UN_disjointed_eq[of A] space range
  1215       by auto
  1216     show "emeasure M (disjointed A i) \<noteq> \<infinity>" for i
  1217     proof -
  1218       have "emeasure M (disjointed A i) \<le> emeasure M (A i)"
  1219         using range disjointed_subset[of A i] by (auto intro!: emeasure_mono)
  1220       then show ?thesis using measure[of i] by (auto simp: top_unique)
  1221     qed
  1222   qed
  1223 qed
  1224 
  1225 lemma (in sigma_finite_measure) sigma_finite_incseq:
  1226   obtains A :: "nat \<Rightarrow> 'a set"
  1227   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "incseq A"
  1228 proof -
  1229   obtain F :: "nat \<Rightarrow> 'a set" where
  1230     F: "range F \<subseteq> sets M" "(\<Union>i. F i) = space M" "\<And>i. emeasure M (F i) \<noteq> \<infinity>"
  1231     using sigma_finite by blast
  1232   show thesis
  1233   proof (rule that[of "\<lambda>n. \<Union>i\<le>n. F i"])
  1234     show "range (\<lambda>n. \<Union>i\<le>n. F i) \<subseteq> sets M"
  1235       using F by (force simp: incseq_def)
  1236     show "(\<Union>n. \<Union>i\<le>n. F i) = space M"
  1237     proof -
  1238       from F have "\<And>x. x \<in> space M \<Longrightarrow> \<exists>i. x \<in> F i" by auto
  1239       with F show ?thesis by fastforce
  1240     qed
  1241     show "emeasure M (\<Union>i\<le>n. F i) \<noteq> \<infinity>" for n
  1242     proof -
  1243       have "emeasure M (\<Union>i\<le>n. F i) \<le> (\<Sum>i\<le>n. emeasure M (F i))"
  1244         using F by (auto intro!: emeasure_subadditive_finite)
  1245       also have "\<dots> < \<infinity>"
  1246         using F by (auto simp: setsum_Pinfty less_top)
  1247       finally show ?thesis by simp
  1248     qed
  1249     show "incseq (\<lambda>n. \<Union>i\<le>n. F i)"
  1250       by (force simp: incseq_def)
  1251   qed
  1252 qed
  1253 
  1254 subsection \<open>Measure space induced by distribution of @{const measurable}-functions\<close>
  1255 
  1256 definition distr :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b measure" where
  1257   "distr M N f = measure_of (space N) (sets N) (\<lambda>A. emeasure M (f -` A \<inter> space M))"
  1258 
  1259 lemma
  1260   shows sets_distr[simp, measurable_cong]: "sets (distr M N f) = sets N"
  1261     and space_distr[simp]: "space (distr M N f) = space N"
  1262   by (auto simp: distr_def)
  1263 
  1264 lemma
  1265   shows measurable_distr_eq1[simp]: "measurable (distr Mf Nf f) Mf' = measurable Nf Mf'"
  1266     and measurable_distr_eq2[simp]: "measurable Mg' (distr Mg Ng g) = measurable Mg' Ng"
  1267   by (auto simp: measurable_def)
  1268 
  1269 lemma distr_cong:
  1270   "M = K \<Longrightarrow> sets N = sets L \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> distr M N f = distr K L g"
  1271   using sets_eq_imp_space_eq[of N L] by (simp add: distr_def Int_def cong: rev_conj_cong)
  1272 
  1273 lemma emeasure_distr:
  1274   fixes f :: "'a \<Rightarrow> 'b"
  1275   assumes f: "f \<in> measurable M N" and A: "A \<in> sets N"
  1276   shows "emeasure (distr M N f) A = emeasure M (f -` A \<inter> space M)" (is "_ = ?\<mu> A")
  1277   unfolding distr_def
  1278 proof (rule emeasure_measure_of_sigma)
  1279   show "positive (sets N) ?\<mu>"
  1280     by (auto simp: positive_def)
  1281 
  1282   show "countably_additive (sets N) ?\<mu>"
  1283   proof (intro countably_additiveI)
  1284     fix A :: "nat \<Rightarrow> 'b set" assume "range A \<subseteq> sets N" "disjoint_family A"
  1285     then have A: "\<And>i. A i \<in> sets N" "(\<Union>i. A i) \<in> sets N" by auto
  1286     then have *: "range (\<lambda>i. f -` (A i) \<inter> space M) \<subseteq> sets M"
  1287       using f by (auto simp: measurable_def)
  1288     moreover have "(\<Union>i. f -`  A i \<inter> space M) \<in> sets M"
  1289       using * by blast
  1290     moreover have **: "disjoint_family (\<lambda>i. f -` A i \<inter> space M)"
  1291       using \<open>disjoint_family A\<close> by (auto simp: disjoint_family_on_def)
  1292     ultimately show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)"
  1293       using suminf_emeasure[OF _ **] A f
  1294       by (auto simp: comp_def vimage_UN)
  1295   qed
  1296   show "sigma_algebra (space N) (sets N)" ..
  1297 qed fact
  1298 
  1299 lemma emeasure_Collect_distr:
  1300   assumes X[measurable]: "X \<in> measurable M N" "Measurable.pred N P"
  1301   shows "emeasure (distr M N X) {x\<in>space N. P x} = emeasure M {x\<in>space M. P (X x)}"
  1302   by (subst emeasure_distr)
  1303      (auto intro!: arg_cong2[where f=emeasure] X(1)[THEN measurable_space])
  1304 
  1305 lemma emeasure_lfp2[consumes 1, case_names cont f measurable]:
  1306   assumes "P M"
  1307   assumes cont: "sup_continuous F"
  1308   assumes f: "\<And>M. P M \<Longrightarrow> f \<in> measurable M' M"
  1309   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
  1310   shows "emeasure M' {x\<in>space M'. lfp F (f x)} = (SUP i. emeasure M' {x\<in>space M'. (F ^^ i) (\<lambda>x. False) (f x)})"
  1311 proof (subst (1 2) emeasure_Collect_distr[symmetric, where X=f])
  1312   show "f \<in> measurable M' M"  "f \<in> measurable M' M"
  1313     using f[OF \<open>P M\<close>] by auto
  1314   { fix i show "Measurable.pred M ((F ^^ i) (\<lambda>x. False))"
  1315     using \<open>P M\<close> by (induction i arbitrary: M) (auto intro!: *) }
  1316   show "Measurable.pred M (lfp F)"
  1317     using \<open>P M\<close> cont * by (rule measurable_lfp_coinduct[of P])
  1318 
  1319   have "emeasure (distr M' M f) {x \<in> space (distr M' M f). lfp F x} =
  1320     (SUP i. emeasure (distr M' M f) {x \<in> space (distr M' M f). (F ^^ i) (\<lambda>x. False) x})"
  1321     using \<open>P M\<close>
  1322   proof (coinduction arbitrary: M rule: emeasure_lfp')
  1323     case (measurable A N) then have "\<And>N. P N \<Longrightarrow> Measurable.pred (distr M' N f) A"
  1324       by metis
  1325     then have "\<And>N. P N \<Longrightarrow> Measurable.pred N A"
  1326       by simp
  1327     with \<open>P N\<close>[THEN *] show ?case
  1328       by auto
  1329   qed fact
  1330   then show "emeasure (distr M' M f) {x \<in> space M. lfp F x} =
  1331     (SUP i. emeasure (distr M' M f) {x \<in> space M. (F ^^ i) (\<lambda>x. False) x})"
  1332    by simp
  1333 qed
  1334 
  1335 lemma distr_id[simp]: "distr N N (\<lambda>x. x) = N"
  1336   by (rule measure_eqI) (auto simp: emeasure_distr)
  1337 
  1338 lemma measure_distr:
  1339   "f \<in> measurable M N \<Longrightarrow> S \<in> sets N \<Longrightarrow> measure (distr M N f) S = measure M (f -` S \<inter> space M)"
  1340   by (simp add: emeasure_distr measure_def)
  1341 
  1342 lemma distr_cong_AE:
  1343   assumes 1: "M = K" "sets N = sets L" and
  1344     2: "(AE x in M. f x = g x)" and "f \<in> measurable M N" and "g \<in> measurable K L"
  1345   shows "distr M N f = distr K L g"
  1346 proof (rule measure_eqI)
  1347   fix A assume "A \<in> sets (distr M N f)"
  1348   with assms show "emeasure (distr M N f) A = emeasure (distr K L g) A"
  1349     by (auto simp add: emeasure_distr intro!: emeasure_eq_AE measurable_sets)
  1350 qed (insert 1, simp)
  1351 
  1352 lemma AE_distrD:
  1353   assumes f: "f \<in> measurable M M'"
  1354     and AE: "AE x in distr M M' f. P x"
  1355   shows "AE x in M. P (f x)"
  1356 proof -
  1357   from AE[THEN AE_E] guess N .
  1358   with f show ?thesis
  1359     unfolding eventually_ae_filter
  1360     by (intro bexI[of _ "f -` N \<inter> space M"])
  1361        (auto simp: emeasure_distr measurable_def)
  1362 qed
  1363 
  1364 lemma AE_distr_iff:
  1365   assumes f[measurable]: "f \<in> measurable M N" and P[measurable]: "{x \<in> space N. P x} \<in> sets N"
  1366   shows "(AE x in distr M N f. P x) \<longleftrightarrow> (AE x in M. P (f x))"
  1367 proof (subst (1 2) AE_iff_measurable[OF _ refl])
  1368   have "f -` {x\<in>space N. \<not> P x} \<inter> space M = {x \<in> space M. \<not> P (f x)}"
  1369     using f[THEN measurable_space] by auto
  1370   then show "(emeasure (distr M N f) {x \<in> space (distr M N f). \<not> P x} = 0) =
  1371     (emeasure M {x \<in> space M. \<not> P (f x)} = 0)"
  1372     by (simp add: emeasure_distr)
  1373 qed auto
  1374 
  1375 lemma null_sets_distr_iff:
  1376   "f \<in> measurable M N \<Longrightarrow> A \<in> null_sets (distr M N f) \<longleftrightarrow> f -` A \<inter> space M \<in> null_sets M \<and> A \<in> sets N"
  1377   by (auto simp add: null_sets_def emeasure_distr)
  1378 
  1379 lemma distr_distr:
  1380   "g \<in> measurable N L \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> distr (distr M N f) L g = distr M L (g \<circ> f)"
  1381   by (auto simp add: emeasure_distr measurable_space
  1382            intro!: arg_cong[where f="emeasure M"] measure_eqI)
  1383 
  1384 subsection \<open>Real measure values\<close>
  1385 
  1386 lemma ring_of_finite_sets: "ring_of_sets (space M) {A\<in>sets M. emeasure M A \<noteq> top}"
  1387 proof (rule ring_of_setsI)
  1388   show "a \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow> b \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow>
  1389     a \<union> b \<in> {A \<in> sets M. emeasure M A \<noteq> top}" for a b
  1390     using emeasure_subadditive[of a M b] by (auto simp: top_unique)
  1391 
  1392   show "a \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow> b \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow>
  1393     a - b \<in> {A \<in> sets M. emeasure M A \<noteq> top}" for a b
  1394     using emeasure_mono[of "a - b" a M] by (auto simp: Diff_subset top_unique)
  1395 qed (auto dest: sets.sets_into_space)
  1396 
  1397 lemma measure_nonneg[simp]: "0 \<le> measure M A"
  1398   unfolding measure_def by auto
  1399 
  1400 lemma zero_less_measure_iff: "0 < measure M A \<longleftrightarrow> measure M A \<noteq> 0"
  1401   using measure_nonneg[of M A] by (auto simp add: le_less)
  1402 
  1403 lemma measure_le_0_iff: "measure M X \<le> 0 \<longleftrightarrow> measure M X = 0"
  1404   using measure_nonneg[of M X] by linarith
  1405 
  1406 lemma measure_empty[simp]: "measure M {} = 0"
  1407   unfolding measure_def by (simp add: zero_ennreal.rep_eq)
  1408 
  1409 lemma emeasure_eq_ennreal_measure:
  1410   "emeasure M A \<noteq> top \<Longrightarrow> emeasure M A = ennreal (measure M A)"
  1411   by (cases "emeasure M A" rule: ennreal_cases) (auto simp: measure_def)
  1412 
  1413 lemma measure_zero_top: "emeasure M A = top \<Longrightarrow> measure M A = 0"
  1414   by (simp add: measure_def enn2ereal_top)
  1415 
  1416 lemma measure_eq_emeasure_eq_ennreal: "0 \<le> x \<Longrightarrow> emeasure M A = ennreal x \<Longrightarrow> measure M A = x"
  1417   using emeasure_eq_ennreal_measure[of M A]
  1418   by (cases "A \<in> M") (auto simp: measure_notin_sets emeasure_notin_sets)
  1419 
  1420 lemma enn2real_plus:"a < top \<Longrightarrow> b < top \<Longrightarrow> enn2real (a + b) = enn2real a + enn2real b"
  1421   by (simp add: enn2real_def plus_ennreal.rep_eq real_of_ereal_add less_top
  1422            del: real_of_ereal_enn2ereal)
  1423 
  1424 lemma measure_Union:
  1425   "emeasure M A \<noteq> \<infinity> \<Longrightarrow> emeasure M B \<noteq> \<infinity> \<Longrightarrow> A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> A \<inter> B = {} \<Longrightarrow>
  1426     measure M (A \<union> B) = measure M A + measure M B"
  1427   by (simp add: measure_def plus_emeasure[symmetric] enn2real_plus less_top)
  1428 
  1429 lemma disjoint_family_on_insert:
  1430   "i \<notin> I \<Longrightarrow> disjoint_family_on A (insert i I) \<longleftrightarrow> A i \<inter> (\<Union>i\<in>I. A i) = {} \<and> disjoint_family_on A I"
  1431   by (fastforce simp: disjoint_family_on_def)
  1432 
  1433 lemma measure_finite_Union:
  1434   "finite S \<Longrightarrow> A`S \<subseteq> sets M \<Longrightarrow> disjoint_family_on A S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>) \<Longrightarrow>
  1435     measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1436   by (induction S rule: finite_induct)
  1437      (auto simp: disjoint_family_on_insert measure_Union setsum_emeasure[symmetric] sets.countable_UN'[OF countable_finite])
  1438 
  1439 lemma measure_Diff:
  1440   assumes finite: "emeasure M A \<noteq> \<infinity>"
  1441   and measurable: "A \<in> sets M" "B \<in> sets M" "B \<subseteq> A"
  1442   shows "measure M (A - B) = measure M A - measure M B"
  1443 proof -
  1444   have "emeasure M (A - B) \<le> emeasure M A" "emeasure M B \<le> emeasure M A"
  1445     using measurable by (auto intro!: emeasure_mono)
  1446   hence "measure M ((A - B) \<union> B) = measure M (A - B) + measure M B"
  1447     using measurable finite by (rule_tac measure_Union) (auto simp: top_unique)
  1448   thus ?thesis using \<open>B \<subseteq> A\<close> by (auto simp: Un_absorb2)
  1449 qed
  1450 
  1451 lemma measure_UNION:
  1452   assumes measurable: "range A \<subseteq> sets M" "disjoint_family A"
  1453   assumes finite: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1454   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1455 proof -
  1456   have "(\<lambda>i. emeasure M (A i)) sums (emeasure M (\<Union>i. A i))"
  1457     unfolding suminf_emeasure[OF measurable, symmetric] by (simp add: summable_sums)
  1458   moreover
  1459   { fix i
  1460     have "emeasure M (A i) \<le> emeasure M (\<Union>i. A i)"
  1461       using measurable by (auto intro!: emeasure_mono)
  1462     then have "emeasure M (A i) = ennreal ((measure M (A i)))"
  1463       using finite by (intro emeasure_eq_ennreal_measure) (auto simp: top_unique) }
  1464   ultimately show ?thesis using finite
  1465     by (subst (asm) (2) emeasure_eq_ennreal_measure) simp_all
  1466 qed
  1467 
  1468 lemma measure_subadditive:
  1469   assumes measurable: "A \<in> sets M" "B \<in> sets M"
  1470   and fin: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1471   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1472 proof -
  1473   have "emeasure M (A \<union> B) \<noteq> \<infinity>"
  1474     using emeasure_subadditive[OF measurable] fin by (auto simp: top_unique)
  1475   then show "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1476     using emeasure_subadditive[OF measurable] fin
  1477     apply simp
  1478     apply (subst (asm) (2 3 4) emeasure_eq_ennreal_measure)
  1479     apply (auto simp add: ennreal_plus[symmetric] simp del: ennreal_plus)
  1480     done
  1481 qed
  1482 
  1483 lemma measure_subadditive_finite:
  1484   assumes A: "finite I" "A`I \<subseteq> sets M" and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1485   shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1486 proof -
  1487   { have "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
  1488       using emeasure_subadditive_finite[OF A] .
  1489     also have "\<dots> < \<infinity>"
  1490       using fin by (simp add: less_top A)
  1491     finally have "emeasure M (\<Union>i\<in>I. A i) \<noteq> top" by simp }
  1492   note * = this
  1493   show ?thesis
  1494     using emeasure_subadditive_finite[OF A] fin
  1495     unfolding emeasure_eq_ennreal_measure[OF *]
  1496     by (simp_all add: setsum_nonneg emeasure_eq_ennreal_measure)
  1497 qed
  1498 
  1499 lemma measure_subadditive_countably:
  1500   assumes A: "range A \<subseteq> sets M" and fin: "(\<Sum>i. emeasure M (A i)) \<noteq> \<infinity>"
  1501   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1502 proof -
  1503   from fin have **: "\<And>i. emeasure M (A i) \<noteq> top"
  1504     using ennreal_suminf_lessD[of "\<lambda>i. emeasure M (A i)"] by (simp add: less_top)
  1505   { have "emeasure M (\<Union>i. A i) \<le> (\<Sum>i. emeasure M (A i))"
  1506       using emeasure_subadditive_countably[OF A] .
  1507     also have "\<dots> < \<infinity>"
  1508       using fin by (simp add: less_top)
  1509     finally have "emeasure M (\<Union>i. A i) \<noteq> top" by simp }
  1510   then have "ennreal (measure M (\<Union>i. A i)) = emeasure M (\<Union>i. A i)"
  1511     by (rule emeasure_eq_ennreal_measure[symmetric])
  1512   also have "\<dots> \<le> (\<Sum>i. emeasure M (A i))"
  1513     using emeasure_subadditive_countably[OF A] .
  1514   also have "\<dots> = ennreal (\<Sum>i. measure M (A i))"
  1515     using fin unfolding emeasure_eq_ennreal_measure[OF **]
  1516     by (subst suminf_ennreal) (auto simp: **)
  1517   finally show ?thesis
  1518     apply (rule ennreal_le_iff[THEN iffD1, rotated])
  1519     apply (intro suminf_nonneg allI measure_nonneg summable_suminf_not_top)
  1520     using fin
  1521     apply (simp add: emeasure_eq_ennreal_measure[OF **])
  1522     done
  1523 qed
  1524 
  1525 lemma measure_eq_setsum_singleton:
  1526   "finite S \<Longrightarrow> (\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M) \<Longrightarrow> (\<And>x. x \<in> S \<Longrightarrow> emeasure M {x} \<noteq> \<infinity>) \<Longrightarrow>
  1527     measure M S = (\<Sum>x\<in>S. measure M {x})"
  1528   using emeasure_eq_setsum_singleton[of S M]
  1529   by (intro measure_eq_emeasure_eq_ennreal) (auto simp: setsum_nonneg emeasure_eq_ennreal_measure)
  1530 
  1531 lemma Lim_measure_incseq:
  1532   assumes A: "range A \<subseteq> sets M" "incseq A" and fin: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1533   shows "(\<lambda>i. measure M (A i)) \<longlonglongrightarrow> measure M (\<Union>i. A i)"
  1534 proof (rule tendsto_ennrealD)
  1535   have "ennreal (measure M (\<Union>i. A i)) = emeasure M (\<Union>i. A i)"
  1536     using fin by (auto simp: emeasure_eq_ennreal_measure)
  1537   moreover have "ennreal (measure M (A i)) = emeasure M (A i)" for i
  1538     using assms emeasure_mono[of "A _" "\<Union>i. A i" M]
  1539     by (intro emeasure_eq_ennreal_measure[symmetric]) (auto simp: less_top UN_upper intro: le_less_trans)
  1540   ultimately show "(\<lambda>x. ennreal (Sigma_Algebra.measure M (A x))) \<longlonglongrightarrow> ennreal (Sigma_Algebra.measure M (\<Union>i. A i))"
  1541     using A by (auto intro!: Lim_emeasure_incseq)
  1542 qed auto
  1543 
  1544 lemma Lim_measure_decseq:
  1545   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1546   shows "(\<lambda>n. measure M (A n)) \<longlonglongrightarrow> measure M (\<Inter>i. A i)"
  1547 proof (rule tendsto_ennrealD)
  1548   have "ennreal (measure M (\<Inter>i. A i)) = emeasure M (\<Inter>i. A i)"
  1549     using fin[of 0] A emeasure_mono[of "\<Inter>i. A i" "A 0" M]
  1550     by (auto intro!: emeasure_eq_ennreal_measure[symmetric] simp: INT_lower less_top intro: le_less_trans)
  1551   moreover have "ennreal (measure M (A i)) = emeasure M (A i)" for i
  1552     using A fin[of i] by (intro emeasure_eq_ennreal_measure[symmetric]) auto
  1553   ultimately show "(\<lambda>x. ennreal (Sigma_Algebra.measure M (A x))) \<longlonglongrightarrow> ennreal (Sigma_Algebra.measure M (\<Inter>i. A i))"
  1554     using fin A by (auto intro!: Lim_emeasure_decseq)
  1555 qed auto
  1556 
  1557 subsection \<open>Measure spaces with @{term "emeasure M (space M) < \<infinity>"}\<close>
  1558 
  1559 locale finite_measure = sigma_finite_measure M for M +
  1560   assumes finite_emeasure_space: "emeasure M (space M) \<noteq> top"
  1561 
  1562 lemma finite_measureI[Pure.intro!]:
  1563   "emeasure M (space M) \<noteq> \<infinity> \<Longrightarrow> finite_measure M"
  1564   proof qed (auto intro!: exI[of _ "{space M}"])
  1565 
  1566 lemma (in finite_measure) emeasure_finite[simp, intro]: "emeasure M A \<noteq> top"
  1567   using finite_emeasure_space emeasure_space[of M A] by (auto simp: top_unique)
  1568 
  1569 lemma (in finite_measure) emeasure_eq_measure: "emeasure M A = ennreal (measure M A)"
  1570   by (intro emeasure_eq_ennreal_measure) simp
  1571 
  1572 lemma (in finite_measure) emeasure_real: "\<exists>r. 0 \<le> r \<and> emeasure M A = ennreal r"
  1573   using emeasure_finite[of A] by (cases "emeasure M A" rule: ennreal_cases) auto
  1574 
  1575 lemma (in finite_measure) bounded_measure: "measure M A \<le> measure M (space M)"
  1576   using emeasure_space[of M A] emeasure_real[of A] emeasure_real[of "space M"] by (auto simp: measure_def)
  1577 
  1578 lemma (in finite_measure) finite_measure_Diff:
  1579   assumes sets: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
  1580   shows "measure M (A - B) = measure M A - measure M B"
  1581   using measure_Diff[OF _ assms] by simp
  1582 
  1583 lemma (in finite_measure) finite_measure_Union:
  1584   assumes sets: "A \<in> sets M" "B \<in> sets M" and "A \<inter> B = {}"
  1585   shows "measure M (A \<union> B) = measure M A + measure M B"
  1586   using measure_Union[OF _ _ assms] by simp
  1587 
  1588 lemma (in finite_measure) finite_measure_finite_Union:
  1589   assumes measurable: "finite S" "A`S \<subseteq> sets M" "disjoint_family_on A S"
  1590   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1591   using measure_finite_Union[OF assms] by simp
  1592 
  1593 lemma (in finite_measure) finite_measure_UNION:
  1594   assumes A: "range A \<subseteq> sets M" "disjoint_family A"
  1595   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1596   using measure_UNION[OF A] by simp
  1597 
  1598 lemma (in finite_measure) finite_measure_mono:
  1599   assumes "A \<subseteq> B" "B \<in> sets M" shows "measure M A \<le> measure M B"
  1600   using emeasure_mono[OF assms] emeasure_real[of A] emeasure_real[of B] by (auto simp: measure_def)
  1601 
  1602 lemma (in finite_measure) finite_measure_subadditive:
  1603   assumes m: "A \<in> sets M" "B \<in> sets M"
  1604   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1605   using measure_subadditive[OF m] by simp
  1606 
  1607 lemma (in finite_measure) finite_measure_subadditive_finite:
  1608   assumes "finite I" "A`I \<subseteq> sets M" shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1609   using measure_subadditive_finite[OF assms] by simp
  1610 
  1611 lemma (in finite_measure) finite_measure_subadditive_countably:
  1612   "range A \<subseteq> sets M \<Longrightarrow> summable (\<lambda>i. measure M (A i)) \<Longrightarrow> measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1613   by (rule measure_subadditive_countably)
  1614      (simp_all add: ennreal_suminf_neq_top emeasure_eq_measure)
  1615 
  1616 lemma (in finite_measure) finite_measure_eq_setsum_singleton:
  1617   assumes "finite S" and *: "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  1618   shows "measure M S = (\<Sum>x\<in>S. measure M {x})"
  1619   using measure_eq_setsum_singleton[OF assms] by simp
  1620 
  1621 lemma (in finite_measure) finite_Lim_measure_incseq:
  1622   assumes A: "range A \<subseteq> sets M" "incseq A"
  1623   shows "(\<lambda>i. measure M (A i)) \<longlonglongrightarrow> measure M (\<Union>i. A i)"
  1624   using Lim_measure_incseq[OF A] by simp
  1625 
  1626 lemma (in finite_measure) finite_Lim_measure_decseq:
  1627   assumes A: "range A \<subseteq> sets M" "decseq A"
  1628   shows "(\<lambda>n. measure M (A n)) \<longlonglongrightarrow> measure M (\<Inter>i. A i)"
  1629   using Lim_measure_decseq[OF A] by simp
  1630 
  1631 lemma (in finite_measure) finite_measure_compl:
  1632   assumes S: "S \<in> sets M"
  1633   shows "measure M (space M - S) = measure M (space M) - measure M S"
  1634   using measure_Diff[OF _ sets.top S sets.sets_into_space] S by simp
  1635 
  1636 lemma (in finite_measure) finite_measure_mono_AE:
  1637   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B" and B: "B \<in> sets M"
  1638   shows "measure M A \<le> measure M B"
  1639   using assms emeasure_mono_AE[OF imp B]
  1640   by (simp add: emeasure_eq_measure)
  1641 
  1642 lemma (in finite_measure) finite_measure_eq_AE:
  1643   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1644   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1645   shows "measure M A = measure M B"
  1646   using assms emeasure_eq_AE[OF assms] by (simp add: emeasure_eq_measure)
  1647 
  1648 lemma (in finite_measure) measure_increasing: "increasing M (measure M)"
  1649   by (auto intro!: finite_measure_mono simp: increasing_def)
  1650 
  1651 lemma (in finite_measure) measure_zero_union:
  1652   assumes "s \<in> sets M" "t \<in> sets M" "measure M t = 0"
  1653   shows "measure M (s \<union> t) = measure M s"
  1654 using assms
  1655 proof -
  1656   have "measure M (s \<union> t) \<le> measure M s"
  1657     using finite_measure_subadditive[of s t] assms by auto
  1658   moreover have "measure M (s \<union> t) \<ge> measure M s"
  1659     using assms by (blast intro: finite_measure_mono)
  1660   ultimately show ?thesis by simp
  1661 qed
  1662 
  1663 lemma (in finite_measure) measure_eq_compl:
  1664   assumes "s \<in> sets M" "t \<in> sets M"
  1665   assumes "measure M (space M - s) = measure M (space M - t)"
  1666   shows "measure M s = measure M t"
  1667   using assms finite_measure_compl by auto
  1668 
  1669 lemma (in finite_measure) measure_eq_bigunion_image:
  1670   assumes "range f \<subseteq> sets M" "range g \<subseteq> sets M"
  1671   assumes "disjoint_family f" "disjoint_family g"
  1672   assumes "\<And> n :: nat. measure M (f n) = measure M (g n)"
  1673   shows "measure M (\<Union>i. f i) = measure M (\<Union>i. g i)"
  1674 using assms
  1675 proof -
  1676   have a: "(\<lambda> i. measure M (f i)) sums (measure M (\<Union>i. f i))"
  1677     by (rule finite_measure_UNION[OF assms(1,3)])
  1678   have b: "(\<lambda> i. measure M (g i)) sums (measure M (\<Union>i. g i))"
  1679     by (rule finite_measure_UNION[OF assms(2,4)])
  1680   show ?thesis using sums_unique[OF b] sums_unique[OF a] assms by simp
  1681 qed
  1682 
  1683 lemma (in finite_measure) measure_countably_zero:
  1684   assumes "range c \<subseteq> sets M"
  1685   assumes "\<And> i. measure M (c i) = 0"
  1686   shows "measure M (\<Union>i :: nat. c i) = 0"
  1687 proof (rule antisym)
  1688   show "measure M (\<Union>i :: nat. c i) \<le> 0"
  1689     using finite_measure_subadditive_countably[OF assms(1)] by (simp add: assms(2))
  1690 qed simp
  1691 
  1692 lemma (in finite_measure) measure_space_inter:
  1693   assumes events:"s \<in> sets M" "t \<in> sets M"
  1694   assumes "measure M t = measure M (space M)"
  1695   shows "measure M (s \<inter> t) = measure M s"
  1696 proof -
  1697   have "measure M ((space M - s) \<union> (space M - t)) = measure M (space M - s)"
  1698     using events assms finite_measure_compl[of "t"] by (auto intro!: measure_zero_union)
  1699   also have "(space M - s) \<union> (space M - t) = space M - (s \<inter> t)"
  1700     by blast
  1701   finally show "measure M (s \<inter> t) = measure M s"
  1702     using events by (auto intro!: measure_eq_compl[of "s \<inter> t" s])
  1703 qed
  1704 
  1705 lemma (in finite_measure) measure_equiprobable_finite_unions:
  1706   assumes s: "finite s" "\<And>x. x \<in> s \<Longrightarrow> {x} \<in> sets M"
  1707   assumes "\<And> x y. \<lbrakk>x \<in> s; y \<in> s\<rbrakk> \<Longrightarrow> measure M {x} = measure M {y}"
  1708   shows "measure M s = real (card s) * measure M {SOME x. x \<in> s}"
  1709 proof cases
  1710   assume "s \<noteq> {}"
  1711   then have "\<exists> x. x \<in> s" by blast
  1712   from someI_ex[OF this] assms
  1713   have prob_some: "\<And> x. x \<in> s \<Longrightarrow> measure M {x} = measure M {SOME y. y \<in> s}" by blast
  1714   have "measure M s = (\<Sum> x \<in> s. measure M {x})"
  1715     using finite_measure_eq_setsum_singleton[OF s] by simp
  1716   also have "\<dots> = (\<Sum> x \<in> s. measure M {SOME y. y \<in> s})" using prob_some by auto
  1717   also have "\<dots> = real (card s) * measure M {(SOME x. x \<in> s)}"
  1718     using setsum_constant assms by simp
  1719   finally show ?thesis by simp
  1720 qed simp
  1721 
  1722 lemma (in finite_measure) measure_real_sum_image_fn:
  1723   assumes "e \<in> sets M"
  1724   assumes "\<And> x. x \<in> s \<Longrightarrow> e \<inter> f x \<in> sets M"
  1725   assumes "finite s"
  1726   assumes disjoint: "\<And> x y. \<lbrakk>x \<in> s ; y \<in> s ; x \<noteq> y\<rbrakk> \<Longrightarrow> f x \<inter> f y = {}"
  1727   assumes upper: "space M \<subseteq> (\<Union>i \<in> s. f i)"
  1728   shows "measure M e = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  1729 proof -
  1730   have "e \<subseteq> (\<Union>i\<in>s. f i)"
  1731     using \<open>e \<in> sets M\<close> sets.sets_into_space upper by blast
  1732   then have e: "e = (\<Union>i \<in> s. e \<inter> f i)"
  1733     by auto
  1734   hence "measure M e = measure M (\<Union>i \<in> s. e \<inter> f i)" by simp
  1735   also have "\<dots> = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  1736   proof (rule finite_measure_finite_Union)
  1737     show "finite s" by fact
  1738     show "(\<lambda>i. e \<inter> f i)`s \<subseteq> sets M" using assms(2) by auto
  1739     show "disjoint_family_on (\<lambda>i. e \<inter> f i) s"
  1740       using disjoint by (auto simp: disjoint_family_on_def)
  1741   qed
  1742   finally show ?thesis .
  1743 qed
  1744 
  1745 lemma (in finite_measure) measure_exclude:
  1746   assumes "A \<in> sets M" "B \<in> sets M"
  1747   assumes "measure M A = measure M (space M)" "A \<inter> B = {}"
  1748   shows "measure M B = 0"
  1749   using measure_space_inter[of B A] assms by (auto simp: ac_simps)
  1750 lemma (in finite_measure) finite_measure_distr:
  1751   assumes f: "f \<in> measurable M M'"
  1752   shows "finite_measure (distr M M' f)"
  1753 proof (rule finite_measureI)
  1754   have "f -` space M' \<inter> space M = space M" using f by (auto dest: measurable_space)
  1755   with f show "emeasure (distr M M' f) (space (distr M M' f)) \<noteq> \<infinity>" by (auto simp: emeasure_distr)
  1756 qed
  1757 
  1758 lemma emeasure_gfp[consumes 1, case_names cont measurable]:
  1759   assumes sets[simp]: "\<And>s. sets (M s) = sets N"
  1760   assumes "\<And>s. finite_measure (M s)"
  1761   assumes cont: "inf_continuous F" "inf_continuous f"
  1762   assumes meas: "\<And>P. Measurable.pred N P \<Longrightarrow> Measurable.pred N (F P)"
  1763   assumes iter: "\<And>P s. Measurable.pred N P \<Longrightarrow> emeasure (M s) {x\<in>space N. F P x} = f (\<lambda>s. emeasure (M s) {x\<in>space N. P x}) s"
  1764   assumes bound: "\<And>P. f P \<le> f (\<lambda>s. emeasure (M s) (space (M s)))"
  1765   shows "emeasure (M s) {x\<in>space N. gfp F x} = gfp f s"
  1766 proof (subst gfp_transfer_bounded[where \<alpha>="\<lambda>F s. emeasure (M s) {x\<in>space N. F x}" and g=f and f=F and
  1767     P="Measurable.pred N", symmetric])
  1768   interpret finite_measure "M s" for s by fact
  1769   fix C assume "decseq C" "\<And>i. Measurable.pred N (C i)"
  1770   then show "(\<lambda>s. emeasure (M s) {x \<in> space N. (INF i. C i) x}) = (INF i. (\<lambda>s. emeasure (M s) {x \<in> space N. C i x}))"
  1771     unfolding INF_apply[abs_def]
  1772     by (subst INF_emeasure_decseq) (auto simp: antimono_def fun_eq_iff intro!: arg_cong2[where f=emeasure])
  1773 next
  1774   show "f x \<le> (\<lambda>s. emeasure (M s) {x \<in> space N. F top x})" for x
  1775     using bound[of x] sets_eq_imp_space_eq[OF sets] by (simp add: iter)
  1776 qed (auto simp add: iter le_fun_def INF_apply[abs_def] intro!: meas cont)
  1777 
  1778 subsection \<open>Counting space\<close>
  1779 
  1780 lemma strict_monoI_Suc:
  1781   assumes ord [simp]: "(\<And>n. f n < f (Suc n))" shows "strict_mono f"
  1782   unfolding strict_mono_def
  1783 proof safe
  1784   fix n m :: nat assume "n < m" then show "f n < f m"
  1785     by (induct m) (auto simp: less_Suc_eq intro: less_trans ord)
  1786 qed
  1787 
  1788 lemma emeasure_count_space:
  1789   assumes "X \<subseteq> A" shows "emeasure (count_space A) X = (if finite X then of_nat (card X) else \<infinity>)"
  1790     (is "_ = ?M X")
  1791   unfolding count_space_def
  1792 proof (rule emeasure_measure_of_sigma)
  1793   show "X \<in> Pow A" using \<open>X \<subseteq> A\<close> by auto
  1794   show "sigma_algebra A (Pow A)" by (rule sigma_algebra_Pow)
  1795   show positive: "positive (Pow A) ?M"
  1796     by (auto simp: positive_def)
  1797   have additive: "additive (Pow A) ?M"
  1798     by (auto simp: card_Un_disjoint additive_def)
  1799 
  1800   interpret ring_of_sets A "Pow A"
  1801     by (rule ring_of_setsI) auto
  1802   show "countably_additive (Pow A) ?M"
  1803     unfolding countably_additive_iff_continuous_from_below[OF positive additive]
  1804   proof safe
  1805     fix F :: "nat \<Rightarrow> 'a set" assume "incseq F"
  1806     show "(\<lambda>i. ?M (F i)) \<longlonglongrightarrow> ?M (\<Union>i. F i)"
  1807     proof cases
  1808       assume "\<exists>i. \<forall>j\<ge>i. F i = F j"
  1809       then guess i .. note i = this
  1810       { fix j from i \<open>incseq F\<close> have "F j \<subseteq> F i"
  1811           by (cases "i \<le> j") (auto simp: incseq_def) }
  1812       then have eq: "(\<Union>i. F i) = F i"
  1813         by auto
  1814       with i show ?thesis
  1815         by (auto intro!: Lim_transform_eventually[OF _ tendsto_const] eventually_sequentiallyI[where c=i])
  1816     next
  1817       assume "\<not> (\<exists>i. \<forall>j\<ge>i. F i = F j)"
  1818       then obtain f where f: "\<And>i. i \<le> f i" "\<And>i. F i \<noteq> F (f i)" by metis
  1819       then have "\<And>i. F i \<subseteq> F (f i)" using \<open>incseq F\<close> by (auto simp: incseq_def)
  1820       with f have *: "\<And>i. F i \<subset> F (f i)" by auto
  1821 
  1822       have "incseq (\<lambda>i. ?M (F i))"
  1823         using \<open>incseq F\<close> unfolding incseq_def by (auto simp: card_mono dest: finite_subset)
  1824       then have "(\<lambda>i. ?M (F i)) \<longlonglongrightarrow> (SUP n. ?M (F n))"
  1825         by (rule LIMSEQ_SUP)
  1826 
  1827       moreover have "(SUP n. ?M (F n)) = top"
  1828       proof (rule ennreal_SUP_eq_top)
  1829         fix n :: nat show "\<exists>k::nat\<in>UNIV. of_nat n \<le> ?M (F k)"
  1830         proof (induct n)
  1831           case (Suc n)
  1832           then guess k .. note k = this
  1833           moreover have "finite (F k) \<Longrightarrow> finite (F (f k)) \<Longrightarrow> card (F k) < card (F (f k))"
  1834             using \<open>F k \<subset> F (f k)\<close> by (simp add: psubset_card_mono)
  1835           moreover have "finite (F (f k)) \<Longrightarrow> finite (F k)"
  1836             using \<open>k \<le> f k\<close> \<open>incseq F\<close> by (auto simp: incseq_def dest: finite_subset)
  1837           ultimately show ?case
  1838             by (auto intro!: exI[of _ "f k"] simp del: of_nat_Suc)
  1839         qed auto
  1840       qed
  1841 
  1842       moreover
  1843       have "inj (\<lambda>n. F ((f ^^ n) 0))"
  1844         by (intro strict_mono_imp_inj_on strict_monoI_Suc) (simp add: *)
  1845       then have 1: "infinite (range (\<lambda>i. F ((f ^^ i) 0)))"
  1846         by (rule range_inj_infinite)
  1847       have "infinite (Pow (\<Union>i. F i))"
  1848         by (rule infinite_super[OF _ 1]) auto
  1849       then have "infinite (\<Union>i. F i)"
  1850         by auto
  1851 
  1852       ultimately show ?thesis by auto
  1853     qed
  1854   qed
  1855 qed
  1856 
  1857 lemma distr_bij_count_space:
  1858   assumes f: "bij_betw f A B"
  1859   shows "distr (count_space A) (count_space B) f = count_space B"
  1860 proof (rule measure_eqI)
  1861   have f': "f \<in> measurable (count_space A) (count_space B)"
  1862     using f unfolding Pi_def bij_betw_def by auto
  1863   fix X assume "X \<in> sets (distr (count_space A) (count_space B) f)"
  1864   then have X: "X \<in> sets (count_space B)" by auto
  1865   moreover from X have "f -` X \<inter> A = the_inv_into A f ` X"
  1866     using f by (auto simp: bij_betw_def subset_image_iff image_iff the_inv_into_f_f intro: the_inv_into_f_f[symmetric])
  1867   moreover have "inj_on (the_inv_into A f) B"
  1868     using X f by (auto simp: bij_betw_def inj_on_the_inv_into)
  1869   with X have "inj_on (the_inv_into A f) X"
  1870     by (auto intro: subset_inj_on)
  1871   ultimately show "emeasure (distr (count_space A) (count_space B) f) X = emeasure (count_space B) X"
  1872     using f unfolding emeasure_distr[OF f' X]
  1873     by (subst (1 2) emeasure_count_space) (auto simp: card_image dest: finite_imageD)
  1874 qed simp
  1875 
  1876 lemma emeasure_count_space_finite[simp]:
  1877   "X \<subseteq> A \<Longrightarrow> finite X \<Longrightarrow> emeasure (count_space A) X = of_nat (card X)"
  1878   using emeasure_count_space[of X A] by simp
  1879 
  1880 lemma emeasure_count_space_infinite[simp]:
  1881   "X \<subseteq> A \<Longrightarrow> infinite X \<Longrightarrow> emeasure (count_space A) X = \<infinity>"
  1882   using emeasure_count_space[of X A] by simp
  1883 
  1884 lemma measure_count_space: "measure (count_space A) X = (if X \<subseteq> A then of_nat (card X) else 0)"
  1885   by (cases "finite X") (auto simp: measure_notin_sets ennreal_of_nat_eq_real_of_nat
  1886                                     measure_zero_top measure_eq_emeasure_eq_ennreal)
  1887 
  1888 lemma emeasure_count_space_eq_0:
  1889   "emeasure (count_space A) X = 0 \<longleftrightarrow> (X \<subseteq> A \<longrightarrow> X = {})"
  1890 proof cases
  1891   assume X: "X \<subseteq> A"
  1892   then show ?thesis
  1893   proof (intro iffI impI)
  1894     assume "emeasure (count_space A) X = 0"
  1895     with X show "X = {}"
  1896       by (subst (asm) emeasure_count_space) (auto split: if_split_asm)
  1897   qed simp
  1898 qed (simp add: emeasure_notin_sets)
  1899 
  1900 lemma space_empty: "space M = {} \<Longrightarrow> M = count_space {}"
  1901   by (rule measure_eqI) (simp_all add: space_empty_iff)
  1902 
  1903 lemma null_sets_count_space: "null_sets (count_space A) = { {} }"
  1904   unfolding null_sets_def by (auto simp add: emeasure_count_space_eq_0)
  1905 
  1906 lemma AE_count_space: "(AE x in count_space A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
  1907   unfolding eventually_ae_filter by (auto simp add: null_sets_count_space)
  1908 
  1909 lemma sigma_finite_measure_count_space_countable:
  1910   assumes A: "countable A"
  1911   shows "sigma_finite_measure (count_space A)"
  1912   proof qed (insert A, auto intro!: exI[of _ "(\<lambda>a. {a}) ` A"])
  1913 
  1914 lemma sigma_finite_measure_count_space:
  1915   fixes A :: "'a::countable set" shows "sigma_finite_measure (count_space A)"
  1916   by (rule sigma_finite_measure_count_space_countable) auto
  1917 
  1918 lemma finite_measure_count_space:
  1919   assumes [simp]: "finite A"
  1920   shows "finite_measure (count_space A)"
  1921   by rule simp
  1922 
  1923 lemma sigma_finite_measure_count_space_finite:
  1924   assumes A: "finite A" shows "sigma_finite_measure (count_space A)"
  1925 proof -
  1926   interpret finite_measure "count_space A" using A by (rule finite_measure_count_space)
  1927   show "sigma_finite_measure (count_space A)" ..
  1928 qed
  1929 
  1930 subsection \<open>Measure restricted to space\<close>
  1931 
  1932 lemma emeasure_restrict_space:
  1933   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  1934   shows "emeasure (restrict_space M \<Omega>) A = emeasure M A"
  1935 proof (cases "A \<in> sets M")
  1936   case True
  1937   show ?thesis
  1938   proof (rule emeasure_measure_of[OF restrict_space_def])
  1939     show "op \<inter> \<Omega> ` sets M \<subseteq> Pow (\<Omega> \<inter> space M)" "A \<in> sets (restrict_space M \<Omega>)"
  1940       using \<open>A \<subseteq> \<Omega>\<close> \<open>A \<in> sets M\<close> sets.space_closed by (auto simp: sets_restrict_space)
  1941     show "positive (sets (restrict_space M \<Omega>)) (emeasure M)"
  1942       by (auto simp: positive_def)
  1943     show "countably_additive (sets (restrict_space M \<Omega>)) (emeasure M)"
  1944     proof (rule countably_additiveI)
  1945       fix A :: "nat \<Rightarrow> _" assume "range A \<subseteq> sets (restrict_space M \<Omega>)" "disjoint_family A"
  1946       with assms have "\<And>i. A i \<in> sets M" "\<And>i. A i \<subseteq> space M" "disjoint_family A"
  1947         by (fastforce simp: sets_restrict_space_iff[OF assms(1)] image_subset_iff
  1948                       dest: sets.sets_into_space)+
  1949       then show "(\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
  1950         by (subst suminf_emeasure) (auto simp: disjoint_family_subset)
  1951     qed
  1952   qed
  1953 next
  1954   case False
  1955   with assms have "A \<notin> sets (restrict_space M \<Omega>)"
  1956     by (simp add: sets_restrict_space_iff)
  1957   with False show ?thesis
  1958     by (simp add: emeasure_notin_sets)
  1959 qed
  1960 
  1961 lemma measure_restrict_space:
  1962   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  1963   shows "measure (restrict_space M \<Omega>) A = measure M A"
  1964   using emeasure_restrict_space[OF assms] by (simp add: measure_def)
  1965 
  1966 lemma AE_restrict_space_iff:
  1967   assumes "\<Omega> \<inter> space M \<in> sets M"
  1968   shows "(AE x in restrict_space M \<Omega>. P x) \<longleftrightarrow> (AE x in M. x \<in> \<Omega> \<longrightarrow> P x)"
  1969 proof -
  1970   have ex_cong: "\<And>P Q f. (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> (\<And>x. Q x \<Longrightarrow> P (f x)) \<Longrightarrow> (\<exists>x. P x) \<longleftrightarrow> (\<exists>x. Q x)"
  1971     by auto
  1972   { fix X assume X: "X \<in> sets M" "emeasure M X = 0"
  1973     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) \<le> emeasure M X"
  1974       by (intro emeasure_mono) auto
  1975     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) = 0"
  1976       using X by (auto intro!: antisym) }
  1977   with assms show ?thesis
  1978     unfolding eventually_ae_filter
  1979     by (auto simp add: space_restrict_space null_sets_def sets_restrict_space_iff
  1980                        emeasure_restrict_space cong: conj_cong
  1981              intro!: ex_cong[where f="\<lambda>X. (\<Omega> \<inter> space M) \<inter> X"])
  1982 qed
  1983 
  1984 lemma restrict_restrict_space:
  1985   assumes "A \<inter> space M \<in> sets M" "B \<inter> space M \<in> sets M"
  1986   shows "restrict_space (restrict_space M A) B = restrict_space M (A \<inter> B)" (is "?l = ?r")
  1987 proof (rule measure_eqI[symmetric])
  1988   show "sets ?r = sets ?l"
  1989     unfolding sets_restrict_space image_comp by (intro image_cong) auto
  1990 next
  1991   fix X assume "X \<in> sets (restrict_space M (A \<inter> B))"
  1992   then obtain Y where "Y \<in> sets M" "X = Y \<inter> A \<inter> B"
  1993     by (auto simp: sets_restrict_space)
  1994   with assms sets.Int[OF assms] show "emeasure ?r X = emeasure ?l X"
  1995     by (subst (1 2) emeasure_restrict_space)
  1996        (auto simp: space_restrict_space sets_restrict_space_iff emeasure_restrict_space ac_simps)
  1997 qed
  1998 
  1999 lemma restrict_count_space: "restrict_space (count_space B) A = count_space (A \<inter> B)"
  2000 proof (rule measure_eqI)
  2001   show "sets (restrict_space (count_space B) A) = sets (count_space (A \<inter> B))"
  2002     by (subst sets_restrict_space) auto
  2003   moreover fix X assume "X \<in> sets (restrict_space (count_space B) A)"
  2004   ultimately have "X \<subseteq> A \<inter> B" by auto
  2005   then show "emeasure (restrict_space (count_space B) A) X = emeasure (count_space (A \<inter> B)) X"
  2006     by (cases "finite X") (auto simp add: emeasure_restrict_space)
  2007 qed
  2008 
  2009 lemma sigma_finite_measure_restrict_space:
  2010   assumes "sigma_finite_measure M"
  2011   and A: "A \<in> sets M"
  2012   shows "sigma_finite_measure (restrict_space M A)"
  2013 proof -
  2014   interpret sigma_finite_measure M by fact
  2015   from sigma_finite_countable obtain C
  2016     where C: "countable C" "C \<subseteq> sets M" "(\<Union>C) = space M" "\<forall>a\<in>C. emeasure M a \<noteq> \<infinity>"
  2017     by blast
  2018   let ?C = "op \<inter> A ` C"
  2019   from C have "countable ?C" "?C \<subseteq> sets (restrict_space M A)" "(\<Union>?C) = space (restrict_space M A)"
  2020     by(auto simp add: sets_restrict_space space_restrict_space)
  2021   moreover {
  2022     fix a
  2023     assume "a \<in> ?C"
  2024     then obtain a' where "a = A \<inter> a'" "a' \<in> C" ..
  2025     then have "emeasure (restrict_space M A) a \<le> emeasure M a'"
  2026       using A C by(auto simp add: emeasure_restrict_space intro: emeasure_mono)
  2027     also have "\<dots> < \<infinity>" using C(4)[rule_format, of a'] \<open>a' \<in> C\<close> by (simp add: less_top)
  2028     finally have "emeasure (restrict_space M A) a \<noteq> \<infinity>" by simp }
  2029   ultimately show ?thesis
  2030     by unfold_locales (rule exI conjI|assumption|blast)+
  2031 qed
  2032 
  2033 lemma finite_measure_restrict_space:
  2034   assumes "finite_measure M"
  2035   and A: "A \<in> sets M"
  2036   shows "finite_measure (restrict_space M A)"
  2037 proof -
  2038   interpret finite_measure M by fact
  2039   show ?thesis
  2040     by(rule finite_measureI)(simp add: emeasure_restrict_space A space_restrict_space)
  2041 qed
  2042 
  2043 lemma restrict_distr:
  2044   assumes [measurable]: "f \<in> measurable M N"
  2045   assumes [simp]: "\<Omega> \<inter> space N \<in> sets N" and restrict: "f \<in> space M \<rightarrow> \<Omega>"
  2046   shows "restrict_space (distr M N f) \<Omega> = distr M (restrict_space N \<Omega>) f"
  2047   (is "?l = ?r")
  2048 proof (rule measure_eqI)
  2049   fix A assume "A \<in> sets (restrict_space (distr M N f) \<Omega>)"
  2050   with restrict show "emeasure ?l A = emeasure ?r A"
  2051     by (subst emeasure_distr)
  2052        (auto simp: sets_restrict_space_iff emeasure_restrict_space emeasure_distr
  2053              intro!: measurable_restrict_space2)
  2054 qed (simp add: sets_restrict_space)
  2055 
  2056 lemma measure_eqI_restrict_generator:
  2057   assumes E: "Int_stable E" "E \<subseteq> Pow \<Omega>" "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
  2058   assumes sets_eq: "sets M = sets N" and \<Omega>: "\<Omega> \<in> sets M"
  2059   assumes "sets (restrict_space M \<Omega>) = sigma_sets \<Omega> E"
  2060   assumes "sets (restrict_space N \<Omega>) = sigma_sets \<Omega> E"
  2061   assumes ae: "AE x in M. x \<in> \<Omega>" "AE x in N. x \<in> \<Omega>"
  2062   assumes A: "countable A" "A \<noteq> {}" "A \<subseteq> E" "\<Union>A = \<Omega>" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  2063   shows "M = N"
  2064 proof (rule measure_eqI)
  2065   fix X assume X: "X \<in> sets M"
  2066   then have "emeasure M X = emeasure (restrict_space M \<Omega>) (X \<inter> \<Omega>)"
  2067     using ae \<Omega> by (auto simp add: emeasure_restrict_space intro!: emeasure_eq_AE)
  2068   also have "restrict_space M \<Omega> = restrict_space N \<Omega>"
  2069   proof (rule measure_eqI_generator_eq)
  2070     fix X assume "X \<in> E"
  2071     then show "emeasure (restrict_space M \<Omega>) X = emeasure (restrict_space N \<Omega>) X"
  2072       using E \<Omega> by (subst (1 2) emeasure_restrict_space) (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq])
  2073   next
  2074     show "range (from_nat_into A) \<subseteq> E" "(\<Union>i. from_nat_into A i) = \<Omega>"
  2075       using A by (auto cong del: strong_SUP_cong)
  2076   next
  2077     fix i
  2078     have "emeasure (restrict_space M \<Omega>) (from_nat_into A i) = emeasure M (from_nat_into A i)"
  2079       using A \<Omega> by (subst emeasure_restrict_space)
  2080                    (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq] intro: from_nat_into)
  2081     with A show "emeasure (restrict_space M \<Omega>) (from_nat_into A i) \<noteq> \<infinity>"
  2082       by (auto intro: from_nat_into)
  2083   qed fact+
  2084   also have "emeasure (restrict_space N \<Omega>) (X \<inter> \<Omega>) = emeasure N X"
  2085     using X ae \<Omega> by (auto simp add: emeasure_restrict_space sets_eq intro!: emeasure_eq_AE)
  2086   finally show "emeasure M X = emeasure N X" .
  2087 qed fact
  2088 
  2089 subsection \<open>Null measure\<close>
  2090 
  2091 definition "null_measure M = sigma (space M) (sets M)"
  2092 
  2093 lemma space_null_measure[simp]: "space (null_measure M) = space M"
  2094   by (simp add: null_measure_def)
  2095 
  2096 lemma sets_null_measure[simp, measurable_cong]: "sets (null_measure M) = sets M"
  2097   by (simp add: null_measure_def)
  2098 
  2099 lemma emeasure_null_measure[simp]: "emeasure (null_measure M) X = 0"
  2100   by (cases "X \<in> sets M", rule emeasure_measure_of)
  2101      (auto simp: positive_def countably_additive_def emeasure_notin_sets null_measure_def
  2102            dest: sets.sets_into_space)
  2103 
  2104 lemma measure_null_measure[simp]: "measure (null_measure M) X = 0"
  2105   by (intro measure_eq_emeasure_eq_ennreal) auto
  2106 
  2107 lemma null_measure_idem [simp]: "null_measure (null_measure M) = null_measure M"
  2108   by(rule measure_eqI) simp_all
  2109 
  2110 subsection \<open>Scaling a measure\<close>
  2111 
  2112 definition scale_measure :: "ennreal \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2113 where
  2114   "scale_measure r M = measure_of (space M) (sets M) (\<lambda>A. r * emeasure M A)"
  2115 
  2116 lemma space_scale_measure: "space (scale_measure r M) = space M"
  2117   by (simp add: scale_measure_def)
  2118 
  2119 lemma sets_scale_measure [simp, measurable_cong]: "sets (scale_measure r M) = sets M"
  2120   by (simp add: scale_measure_def)
  2121 
  2122 lemma emeasure_scale_measure [simp]:
  2123   "emeasure (scale_measure r M) A = r * emeasure M A"
  2124   (is "_ = ?\<mu> A")
  2125 proof(cases "A \<in> sets M")
  2126   case True
  2127   show ?thesis unfolding scale_measure_def
  2128   proof(rule emeasure_measure_of_sigma)
  2129     show "sigma_algebra (space M) (sets M)" ..
  2130     show "positive (sets M) ?\<mu>" by (simp add: positive_def)
  2131     show "countably_additive (sets M) ?\<mu>"
  2132     proof (rule countably_additiveI)
  2133       fix A :: "nat \<Rightarrow> _"  assume *: "range A \<subseteq> sets M" "disjoint_family A"
  2134       have "(\<Sum>i. ?\<mu> (A i)) = r * (\<Sum>i. emeasure M (A i))"
  2135         by simp
  2136       also have "\<dots> = ?\<mu> (\<Union>i. A i)" using * by(simp add: suminf_emeasure)
  2137       finally show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)" .
  2138     qed
  2139   qed(fact True)
  2140 qed(simp add: emeasure_notin_sets)
  2141 
  2142 lemma scale_measure_1 [simp]: "scale_measure 1 M = M"
  2143   by(rule measure_eqI) simp_all
  2144 
  2145 lemma scale_measure_0[simp]: "scale_measure 0 M = null_measure M"
  2146   by(rule measure_eqI) simp_all
  2147 
  2148 lemma measure_scale_measure [simp]: "0 \<le> r \<Longrightarrow> measure (scale_measure r M) A = r * measure M A"
  2149   using emeasure_scale_measure[of r M A]
  2150     emeasure_eq_ennreal_measure[of M A]
  2151     measure_eq_emeasure_eq_ennreal[of _ "scale_measure r M" A]
  2152   by (cases "emeasure (scale_measure r M) A = top")
  2153      (auto simp del: emeasure_scale_measure
  2154            simp: ennreal_top_eq_mult_iff ennreal_mult_eq_top_iff measure_zero_top ennreal_mult[symmetric])
  2155 
  2156 lemma scale_scale_measure [simp]:
  2157   "scale_measure r (scale_measure r' M) = scale_measure (r * r') M"
  2158   by (rule measure_eqI) (simp_all add: max_def mult.assoc)
  2159 
  2160 lemma scale_null_measure [simp]: "scale_measure r (null_measure M) = null_measure M"
  2161   by (rule measure_eqI) simp_all
  2162 
  2163 
  2164 subsection \<open>Complete lattice structure on measures\<close>
  2165 
  2166 lemma (in finite_measure) finite_measure_Diff':
  2167   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> measure M (A - B) = measure M A - measure M (A \<inter> B)"
  2168   using finite_measure_Diff[of A "A \<inter> B"] by (auto simp: Diff_Int)
  2169 
  2170 lemma (in finite_measure) finite_measure_Union':
  2171   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> measure M (A \<union> B) = measure M A + measure M (B - A)"
  2172   using finite_measure_Union[of A "B - A"] by auto
  2173 
  2174 lemma finite_unsigned_Hahn_decomposition:
  2175   assumes "finite_measure M" "finite_measure N" and [simp]: "sets N = sets M"
  2176   shows "\<exists>Y\<in>sets M. (\<forall>X\<in>sets M. X \<subseteq> Y \<longrightarrow> N X \<le> M X) \<and> (\<forall>X\<in>sets M. X \<inter> Y = {} \<longrightarrow> M X \<le> N X)"
  2177 proof -
  2178   interpret M: finite_measure M by fact
  2179   interpret N: finite_measure N by fact
  2180 
  2181   define d where "d X = measure M X - measure N X" for X
  2182 
  2183   have [intro]: "bdd_above (d`sets M)"
  2184     using sets.sets_into_space[of _ M]
  2185     by (intro bdd_aboveI[where M="measure M (space M)"])
  2186        (auto simp: d_def field_simps subset_eq intro!: add_increasing M.finite_measure_mono)
  2187 
  2188   define \<gamma> where "\<gamma> = (SUP X:sets M. d X)"
  2189   have le_\<gamma>[intro]: "X \<in> sets M \<Longrightarrow> d X \<le> \<gamma>" for X
  2190     by (auto simp: \<gamma>_def intro!: cSUP_upper)
  2191 
  2192   have "\<exists>f. \<forall>n. f n \<in> sets M \<and> d (f n) > \<gamma> - 1 / 2^n"
  2193   proof (intro choice_iff[THEN iffD1] allI)
  2194     fix n
  2195     have "\<exists>X\<in>sets M. \<gamma> - 1 / 2^n < d X"
  2196       unfolding \<gamma>_def by (intro less_cSUP_iff[THEN iffD1]) auto
  2197     then show "\<exists>y. y \<in> sets M \<and> \<gamma> - 1 / 2 ^ n < d y"
  2198       by auto
  2199   qed
  2200   then obtain E where [measurable]: "E n \<in> sets M" and E: "d (E n) > \<gamma> - 1 / 2^n" for n
  2201     by auto
  2202 
  2203   define F where "F m n = (if m \<le> n then \<Inter>i\<in>{m..n}. E i else space M)" for m n
  2204 
  2205   have [measurable]: "m \<le> n \<Longrightarrow> F m n \<in> sets M" for m n
  2206     by (auto simp: F_def)
  2207 
  2208   have 1: "\<gamma> - 2 / 2 ^ m + 1 / 2 ^ n \<le> d (F m n)" if "m \<le> n" for m n
  2209     using that
  2210   proof (induct rule: dec_induct)
  2211     case base with E[of m] show ?case
  2212       by (simp add: F_def field_simps)
  2213   next
  2214     case (step i)
  2215     have F_Suc: "F m (Suc i) = F m i \<inter> E (Suc i)"
  2216       using \<open>m \<le> i\<close> by (auto simp: F_def le_Suc_eq)
  2217 
  2218     have "\<gamma> + (\<gamma> - 2 / 2^m + 1 / 2 ^ Suc i) \<le> (\<gamma> - 1 / 2^Suc i) + (\<gamma> - 2 / 2^m + 1 / 2^i)"
  2219       by (simp add: field_simps)
  2220     also have "\<dots> \<le> d (E (Suc i)) + d (F m i)"
  2221       using E[of "Suc i"] by (intro add_mono step) auto
  2222     also have "\<dots> = d (E (Suc i)) + d (F m i - E (Suc i)) + d (F m (Suc i))"
  2223       using \<open>m \<le> i\<close> by (simp add: d_def field_simps F_Suc M.finite_measure_Diff' N.finite_measure_Diff')
  2224     also have "\<dots> = d (E (Suc i) \<union> F m i) + d (F m (Suc i))"
  2225       using \<open>m \<le> i\<close> by (simp add: d_def field_simps M.finite_measure_Union' N.finite_measure_Union')
  2226     also have "\<dots> \<le> \<gamma> + d (F m (Suc i))"
  2227       using \<open>m \<le> i\<close> by auto
  2228     finally show ?case
  2229       by auto
  2230   qed
  2231 
  2232   define F' where "F' m = (\<Inter>i\<in>{m..}. E i)" for m
  2233   have F'_eq: "F' m = (\<Inter>i. F m (i + m))" for m
  2234     by (fastforce simp: le_iff_add[of m] F'_def F_def)
  2235 
  2236   have [measurable]: "F' m \<in> sets M" for m
  2237     by (auto simp: F'_def)
  2238 
  2239   have \<gamma>_le: "\<gamma> - 0 \<le> d (\<Union>m. F' m)"
  2240   proof (rule LIMSEQ_le)
  2241     show "(\<lambda>n. \<gamma> - 2 / 2 ^ n) \<longlonglongrightarrow> \<gamma> - 0"
  2242       by (intro tendsto_intros LIMSEQ_divide_realpow_zero) auto
  2243     have "incseq F'"
  2244       by (auto simp: incseq_def F'_def)
  2245     then show "(\<lambda>m. d (F' m)) \<longlonglongrightarrow> d (\<Union>m. F' m)"
  2246       unfolding d_def
  2247       by (intro tendsto_diff M.finite_Lim_measure_incseq N.finite_Lim_measure_incseq) auto
  2248 
  2249     have "\<gamma> - 2 / 2 ^ m + 0 \<le> d (F' m)" for m
  2250     proof (rule LIMSEQ_le)
  2251       have *: "decseq (\<lambda>n. F m (n + m))"
  2252         by (auto simp: decseq_def F_def)
  2253       show "(\<lambda>n. d (F m n)) \<longlonglongrightarrow> d (F' m)"
  2254         unfolding d_def F'_eq
  2255         by (rule LIMSEQ_offset[where k=m])
  2256            (auto intro!: tendsto_diff M.finite_Lim_measure_decseq N.finite_Lim_measure_decseq *)
  2257       show "(\<lambda>n. \<gamma> - 2 / 2 ^ m + 1 / 2 ^ n) \<longlonglongrightarrow> \<gamma> - 2 / 2 ^ m + 0"
  2258         by (intro tendsto_add LIMSEQ_divide_realpow_zero tendsto_const) auto
  2259       show "\<exists>N. \<forall>n\<ge>N. \<gamma> - 2 / 2 ^ m + 1 / 2 ^ n \<le> d (F m n)"
  2260         using 1[of m] by (intro exI[of _ m]) auto
  2261     qed
  2262     then show "\<exists>N. \<forall>n\<ge>N. \<gamma> - 2 / 2 ^ n \<le> d (F' n)"
  2263       by auto
  2264   qed
  2265 
  2266   show ?thesis
  2267   proof (safe intro!: bexI[of _ "\<Union>m. F' m"])
  2268     fix X assume [measurable]: "X \<in> sets M" and X: "X \<subseteq> (\<Union>m. F' m)"
  2269     have "d (\<Union>m. F' m) - d X = d ((\<Union>m. F' m) - X)"
  2270       using X by (auto simp: d_def M.finite_measure_Diff N.finite_measure_Diff)
  2271     also have "\<dots> \<le> \<gamma>"
  2272       by auto
  2273     finally have "0 \<le> d X"
  2274       using \<gamma>_le by auto
  2275     then show "emeasure N X \<le> emeasure M X"
  2276       by (auto simp: d_def M.emeasure_eq_measure N.emeasure_eq_measure)
  2277   next
  2278     fix X assume [measurable]: "X \<in> sets M" and X: "X \<inter> (\<Union>m. F' m) = {}"
  2279     then have "d (\<Union>m. F' m) + d X = d (X \<union> (\<Union>m. F' m))"
  2280       by (auto simp: d_def M.finite_measure_Union N.finite_measure_Union)
  2281     also have "\<dots> \<le> \<gamma>"
  2282       by auto
  2283     finally have "d X \<le> 0"
  2284       using \<gamma>_le by auto
  2285     then show "emeasure M X \<le> emeasure N X"
  2286       by (auto simp: d_def M.emeasure_eq_measure N.emeasure_eq_measure)
  2287   qed auto
  2288 qed
  2289 
  2290 lemma unsigned_Hahn_decomposition:
  2291   assumes [simp]: "sets N = sets M" and [measurable]: "A \<in> sets M"
  2292     and [simp]: "emeasure M A \<noteq> top" "emeasure N A \<noteq> top"
  2293   shows "\<exists>Y\<in>sets M. Y \<subseteq> A \<and> (\<forall>X\<in>sets M. X \<subseteq> Y \<longrightarrow> N X \<le> M X) \<and> (\<forall>X\<in>sets M. X \<subseteq> A \<longrightarrow> X \<inter> Y = {} \<longrightarrow> M X \<le> N X)"
  2294 proof -
  2295   have "\<exists>Y\<in>sets (restrict_space M A).
  2296     (\<forall>X\<in>sets (restrict_space M A). X \<subseteq> Y \<longrightarrow> (restrict_space N A) X \<le> (restrict_space M A) X) \<and>
  2297     (\<forall>X\<in>sets (restrict_space M A). X \<inter> Y = {} \<longrightarrow> (restrict_space M A) X \<le> (restrict_space N A) X)"
  2298   proof (rule finite_unsigned_Hahn_decomposition)
  2299     show "finite_measure (restrict_space M A)" "finite_measure (restrict_space N A)"
  2300       by (auto simp: space_restrict_space emeasure_restrict_space less_top intro!: finite_measureI)
  2301   qed (simp add: sets_restrict_space)
  2302   then guess Y ..
  2303   then show ?thesis
  2304     apply (intro bexI[of _ Y] conjI ballI conjI)
  2305     apply (simp_all add: sets_restrict_space emeasure_restrict_space)
  2306     apply safe
  2307     subgoal for X Z
  2308       by (erule ballE[of _ _ X]) (auto simp add: Int_absorb1)
  2309     subgoal for X Z
  2310       by (erule ballE[of _ _ X])  (auto simp add: Int_absorb1 ac_simps)
  2311     apply auto
  2312     done
  2313 qed
  2314 
  2315 text \<open>
  2316   Define a lexicographical order on @{type measure}, in the order space, sets and measure. The parts
  2317   of the lexicographical order are point-wise ordered.
  2318 \<close>
  2319 
  2320 instantiation measure :: (type) order_bot
  2321 begin
  2322 
  2323 inductive less_eq_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
  2324   "space M \<subset> space N \<Longrightarrow> less_eq_measure M N"
  2325 | "space M = space N \<Longrightarrow> sets M \<subset> sets N \<Longrightarrow> less_eq_measure M N"
  2326 | "space M = space N \<Longrightarrow> sets M = sets N \<Longrightarrow> emeasure M \<le> emeasure N \<Longrightarrow> less_eq_measure M N"
  2327 
  2328 lemma le_measure_iff:
  2329   "M \<le> N \<longleftrightarrow> (if space M = space N then
  2330     if sets M = sets N then emeasure M \<le> emeasure N else sets M \<subseteq> sets N else space M \<subseteq> space N)"
  2331   by (auto elim: less_eq_measure.cases intro: less_eq_measure.intros)
  2332 
  2333 definition less_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
  2334   "less_measure M N \<longleftrightarrow> (M \<le> N \<and> \<not> N \<le> M)"
  2335 
  2336 definition bot_measure :: "'a measure" where
  2337   "bot_measure = sigma {} {}"
  2338 
  2339 lemma
  2340   shows space_bot[simp]: "space bot = {}"
  2341     and sets_bot[simp]: "sets bot = {{}}"
  2342     and emeasure_bot[simp]: "emeasure bot X = 0"
  2343   by (auto simp: bot_measure_def sigma_sets_empty_eq emeasure_sigma)
  2344 
  2345 instance
  2346 proof standard
  2347   show "bot \<le> a" for a :: "'a measure"
  2348     by (simp add: le_measure_iff bot_measure_def sigma_sets_empty_eq emeasure_sigma le_fun_def)
  2349 qed (auto simp: le_measure_iff less_measure_def split: if_split_asm intro: measure_eqI)
  2350 
  2351 end
  2352 
  2353 lemma le_measure: "sets M = sets N \<Longrightarrow> M \<le> N \<longleftrightarrow> (\<forall>A\<in>sets M. emeasure M A \<le> emeasure N A)"
  2354   apply (auto simp: le_measure_iff le_fun_def dest: sets_eq_imp_space_eq)
  2355   subgoal for X
  2356     by (cases "X \<in> sets M") (auto simp: emeasure_notin_sets)
  2357   done
  2358 
  2359 definition sup_measure' :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2360 where
  2361   "sup_measure' A B = measure_of (space A) (sets A) (\<lambda>X. SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2362 
  2363 lemma assumes [simp]: "sets B = sets A"
  2364   shows space_sup_measure'[simp]: "space (sup_measure' A B) = space A"
  2365     and sets_sup_measure'[simp]: "sets (sup_measure' A B) = sets A"
  2366   using sets_eq_imp_space_eq[OF assms] by (simp_all add: sup_measure'_def)
  2367 
  2368 lemma emeasure_sup_measure':
  2369   assumes sets_eq[simp]: "sets B = sets A" and [simp, intro]: "X \<in> sets A"
  2370   shows "emeasure (sup_measure' A B) X = (SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2371     (is "_ = ?S X")
  2372 proof -
  2373   note sets_eq_imp_space_eq[OF sets_eq, simp]
  2374   show ?thesis
  2375     using sup_measure'_def
  2376   proof (rule emeasure_measure_of)
  2377     let ?d = "\<lambda>X Y. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y)"
  2378     show "countably_additive (sets (sup_measure' A B)) (\<lambda>X. SUP Y : sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2379     proof (rule countably_additiveI, goal_cases)
  2380       case (1 X)
  2381       then have [measurable]: "\<And>i. X i \<in> sets A" and "disjoint_family X"
  2382         by auto
  2383       have "(\<Sum>i. ?S (X i)) = (SUP Y:sets A. \<Sum>i. ?d (X i) Y)"
  2384       proof (rule ennreal_suminf_SUP_eq_directed)
  2385         fix J :: "nat set" and a b assume "finite J" and [measurable]: "a \<in> sets A" "b \<in> sets A"
  2386         have "\<exists>c\<in>sets A. c \<subseteq> X i \<and> (\<forall>a\<in>sets A. ?d (X i) a \<le> ?d (X i) c)" for i
  2387         proof cases
  2388           assume "emeasure A (X i) = top \<or> emeasure B (X i) = top"
  2389           then show ?thesis
  2390           proof
  2391             assume "emeasure A (X i) = top" then show ?thesis
  2392               by (intro bexI[of _ "X i"]) auto
  2393           next
  2394             assume "emeasure B (X i) = top" then show ?thesis
  2395               by (intro bexI[of _ "{}"]) auto
  2396           qed
  2397         next
  2398           assume finite: "\<not> (emeasure A (X i) = top \<or> emeasure B (X i) = top)"
  2399           then have "\<exists>Y\<in>sets A. Y \<subseteq> X i \<and> (\<forall>C\<in>sets A. C \<subseteq> Y \<longrightarrow> B C \<le> A C) \<and> (\<forall>C\<in>sets A. C \<subseteq> X i \<longrightarrow> C \<inter> Y = {} \<longrightarrow> A C \<le> B C)"
  2400             using unsigned_Hahn_decomposition[of B A "X i"] by simp
  2401           then obtain Y where [measurable]: "Y \<in> sets A" and [simp]: "Y \<subseteq> X i"
  2402             and B_le_A: "\<And>C. C \<in> sets A \<Longrightarrow> C \<subseteq> Y \<Longrightarrow> B C \<le> A C"
  2403             and A_le_B: "\<And>C. C \<in> sets A \<Longrightarrow> C \<subseteq> X i \<Longrightarrow> C \<inter> Y = {} \<Longrightarrow> A C \<le> B C"
  2404             by auto
  2405 
  2406           show ?thesis
  2407           proof (intro bexI[of _ Y] ballI conjI)
  2408             fix a assume [measurable]: "a \<in> sets A"
  2409             have *: "(X i \<inter> a \<inter> Y \<union> (X i \<inter> a - Y)) = X i \<inter> a" "(X i - a) \<inter> Y \<union> (X i - a - Y) = X i \<inter> - a"
  2410               for a Y by auto
  2411             then have "?d (X i) a =
  2412               (A (X i \<inter> a \<inter> Y) + A (X i \<inter> a \<inter> - Y)) + (B (X i \<inter> - a \<inter> Y) + B (X i \<inter> - a \<inter> - Y))"
  2413               by (subst (1 2) plus_emeasure) (auto simp: Diff_eq[symmetric])
  2414             also have "\<dots> \<le> (A (X i \<inter> a \<inter> Y) + B (X i \<inter> a \<inter> - Y)) + (A (X i \<inter> - a \<inter> Y) + B (X i \<inter> - a \<inter> - Y))"
  2415               by (intro add_mono order_refl B_le_A A_le_B) (auto simp: Diff_eq[symmetric])
  2416             also have "\<dots> \<le> (A (X i \<inter> Y \<inter> a) + A (X i \<inter> Y \<inter> - a)) + (B (X i \<inter> - Y \<inter> a) + B (X i \<inter> - Y \<inter> - a))"
  2417               by (simp add: ac_simps)
  2418             also have "\<dots> \<le> A (X i \<inter> Y) + B (X i \<inter> - Y)"
  2419               by (subst (1 2) plus_emeasure) (auto simp: Diff_eq[symmetric] *)
  2420             finally show "?d (X i) a \<le> ?d (X i) Y" .
  2421           qed auto
  2422         qed
  2423         then obtain C where [measurable]: "C i \<in> sets A" and "C i \<subseteq> X i"
  2424           and C: "\<And>a. a \<in> sets A \<Longrightarrow> ?d (X i) a \<le> ?d (X i) (C i)" for i
  2425           by metis
  2426         have *: "X i \<inter> (\<Union>i. C i) = X i \<inter> C i" for i
  2427         proof safe
  2428           fix x j assume "x \<in> X i" "x \<in> C j"
  2429           moreover have "i = j \<or> X i \<inter> X j = {}"
  2430             using \<open>disjoint_family X\<close> by (auto simp: disjoint_family_on_def)
  2431           ultimately show "x \<in> C i"
  2432             using \<open>C i \<subseteq> X i\<close> \<open>C j \<subseteq> X j\<close> by auto
  2433         qed auto
  2434         have **: "X i \<inter> - (\<Union>i. C i) = X i \<inter> - C i" for i
  2435         proof safe
  2436           fix x j assume "x \<in> X i" "x \<notin> C i" "x \<in> C j"
  2437           moreover have "i = j \<or> X i \<inter> X j = {}"
  2438             using \<open>disjoint_family X\<close> by (auto simp: disjoint_family_on_def)
  2439           ultimately show False
  2440             using \<open>C i \<subseteq> X i\<close> \<open>C j \<subseteq> X j\<close> by auto
  2441         qed auto
  2442         show "\<exists>c\<in>sets A. \<forall>i\<in>J. ?d (X i) a \<le> ?d (X i) c \<and> ?d (X i) b \<le> ?d (X i) c"
  2443           apply (intro bexI[of _ "\<Union>i. C i"])
  2444           unfolding * **
  2445           apply (intro C ballI conjI)
  2446           apply auto
  2447           done
  2448       qed
  2449       also have "\<dots> = ?S (\<Union>i. X i)"
  2450         unfolding UN_extend_simps(4)
  2451         by (auto simp add: suminf_add[symmetric] Diff_eq[symmetric] simp del: UN_simps
  2452                  intro!: SUP_cong arg_cong2[where f="op +"] suminf_emeasure
  2453                          disjoint_family_on_bisimulation[OF \<open>disjoint_family X\<close>])
  2454       finally show "(\<Sum>i. ?S (X i)) = ?S (\<Union>i. X i)" .
  2455     qed
  2456   qed (auto dest: sets.sets_into_space simp: positive_def intro!: SUP_const)
  2457 qed
  2458 
  2459 lemma le_emeasure_sup_measure'1:
  2460   assumes "sets B = sets A" "X \<in> sets A" shows "emeasure A X \<le> emeasure (sup_measure' A B) X"
  2461   by (subst emeasure_sup_measure'[OF assms]) (auto intro!: SUP_upper2[of "X"] assms)
  2462 
  2463 lemma le_emeasure_sup_measure'2:
  2464   assumes "sets B = sets A" "X \<in> sets A" shows "emeasure B X \<le> emeasure (sup_measure' A B) X"
  2465   by (subst emeasure_sup_measure'[OF assms]) (auto intro!: SUP_upper2[of "{}"] assms)
  2466 
  2467 lemma emeasure_sup_measure'_le2:
  2468   assumes [simp]: "sets B = sets C" "sets A = sets C" and [measurable]: "X \<in> sets C"
  2469   assumes A: "\<And>Y. Y \<subseteq> X \<Longrightarrow> Y \<in> sets A \<Longrightarrow> emeasure A Y \<le> emeasure C Y"
  2470   assumes B: "\<And>Y. Y \<subseteq> X \<Longrightarrow> Y \<in> sets A \<Longrightarrow> emeasure B Y \<le> emeasure C Y"
  2471   shows "emeasure (sup_measure' A B) X \<le> emeasure C X"
  2472 proof (subst emeasure_sup_measure')
  2473   show "(SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y)) \<le> emeasure C X"
  2474     unfolding \<open>sets A = sets C\<close>
  2475   proof (intro SUP_least)
  2476     fix Y assume [measurable]: "Y \<in> sets C"
  2477     have [simp]: "X \<inter> Y \<union> (X - Y) = X"
  2478       by auto
  2479     have "emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y) \<le> emeasure C (X \<inter> Y) + emeasure C (X \<inter> - Y)"
  2480       by (intro add_mono A B) (auto simp: Diff_eq[symmetric])
  2481     also have "\<dots> = emeasure C X"
  2482       by (subst plus_emeasure) (auto simp: Diff_eq[symmetric])
  2483     finally show "emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y) \<le> emeasure C X" .
  2484   qed
  2485 qed simp_all
  2486 
  2487 definition sup_lexord :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b::order) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2488 where
  2489   "sup_lexord A B k s c =
  2490     (if k A = k B then c else if \<not> k A \<le> k B \<and> \<not> k B \<le> k A then s else if k B \<le> k A then A else B)"
  2491 
  2492 lemma sup_lexord:
  2493   "(k A < k B \<Longrightarrow> P B) \<Longrightarrow> (k B < k A \<Longrightarrow> P A) \<Longrightarrow> (k A = k B \<Longrightarrow> P c) \<Longrightarrow>
  2494     (\<not> k B \<le> k A \<Longrightarrow> \<not> k A \<le> k B \<Longrightarrow> P s) \<Longrightarrow> P (sup_lexord A B k s c)"
  2495   by (auto simp: sup_lexord_def)
  2496 
  2497 lemmas le_sup_lexord = sup_lexord[where P="\<lambda>a. c \<le> a" for c]
  2498 
  2499 lemma sup_lexord1: "k A = k B \<Longrightarrow> sup_lexord A B k s c = c"
  2500   by (simp add: sup_lexord_def)
  2501 
  2502 lemma sup_lexord_commute: "sup_lexord A B k s c = sup_lexord B A k s c"
  2503   by (auto simp: sup_lexord_def)
  2504 
  2505 lemma sigma_sets_le_sets_iff: "(sigma_sets (space x) \<A> \<subseteq> sets x) = (\<A> \<subseteq> sets x)"
  2506   using sets.sigma_sets_subset[of \<A> x] by auto
  2507 
  2508 lemma sigma_le_iff: "\<A> \<subseteq> Pow \<Omega> \<Longrightarrow> sigma \<Omega> \<A> \<le> x \<longleftrightarrow> (\<Omega> \<subseteq> space x \<and> (space x = \<Omega> \<longrightarrow> \<A> \<subseteq> sets x))"
  2509   by (cases "\<Omega> = space x")
  2510      (simp_all add: eq_commute[of _ "sets x"] le_measure_iff emeasure_sigma le_fun_def
  2511                     sigma_sets_superset_generator sigma_sets_le_sets_iff)
  2512 
  2513 instantiation measure :: (type) semilattice_sup
  2514 begin
  2515 
  2516 definition sup_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2517 where
  2518   "sup_measure A B =
  2519     sup_lexord A B space (sigma (space A \<union> space B) {})
  2520       (sup_lexord A B sets (sigma (space A) (sets A \<union> sets B)) (sup_measure' A B))"
  2521 
  2522 instance
  2523 proof
  2524   fix x y z :: "'a measure"
  2525   show "x \<le> sup x y"
  2526     unfolding sup_measure_def
  2527   proof (intro le_sup_lexord)
  2528     assume "space x = space y"
  2529     then have *: "sets x \<union> sets y \<subseteq> Pow (space x)"
  2530       using sets.space_closed by auto
  2531     assume "\<not> sets y \<subseteq> sets x" "\<not> sets x \<subseteq> sets y"
  2532     then have "sets x \<subset> sets x \<union> sets y"
  2533       by auto
  2534     also have "\<dots> \<le> sigma (space x) (sets x \<union> sets y)"
  2535       by (subst sets_measure_of[OF *]) (rule sigma_sets_superset_generator)
  2536     finally show "x \<le> sigma (space x) (sets x \<union> sets y)"
  2537       by (simp add: space_measure_of[OF *] less_eq_measure.intros(2))
  2538   next
  2539     assume "\<not> space y \<subseteq> space x" "\<not> space x \<subseteq> space y"
  2540     then show "x \<le> sigma (space x \<union> space y) {}"
  2541       by (intro less_eq_measure.intros) auto
  2542   next
  2543     assume "sets x = sets y" then show "x \<le> sup_measure' x y"
  2544       by (simp add: le_measure le_emeasure_sup_measure'1)
  2545   qed (auto intro: less_eq_measure.intros)
  2546   show "y \<le> sup x y"
  2547     unfolding sup_measure_def
  2548   proof (intro le_sup_lexord)
  2549     assume **: "space x = space y"
  2550     then have *: "sets x \<union> sets y \<subseteq> Pow (space y)"
  2551       using sets.space_closed by auto
  2552     assume "\<not> sets y \<subseteq> sets x" "\<not> sets x \<subseteq> sets y"
  2553     then have "sets y \<subset> sets x \<union> sets y"
  2554       by auto
  2555     also have "\<dots> \<le> sigma (space y) (sets x \<union> sets y)"
  2556       by (subst sets_measure_of[OF *]) (rule sigma_sets_superset_generator)
  2557     finally show "y \<le> sigma (space x) (sets x \<union> sets y)"
  2558       by (simp add: ** space_measure_of[OF *] less_eq_measure.intros(2))
  2559   next
  2560     assume "\<not> space y \<subseteq> space x" "\<not> space x \<subseteq> space y"
  2561     then show "y \<le> sigma (space x \<union> space y) {}"
  2562       by (intro less_eq_measure.intros) auto
  2563   next
  2564     assume "sets x = sets y" then show "y \<le> sup_measure' x y"
  2565       by (simp add: le_measure le_emeasure_sup_measure'2)
  2566   qed (auto intro: less_eq_measure.intros)
  2567   show "x \<le> y \<Longrightarrow> z \<le> y \<Longrightarrow> sup x z \<le> y"
  2568     unfolding sup_measure_def
  2569   proof (intro sup_lexord[where P="\<lambda>x. x \<le> y"])
  2570     assume "x \<le> y" "z \<le> y" and [simp]: "space x = space z" "sets x = sets z"
  2571     from \<open>x \<le> y\<close> show "sup_measure' x z \<le> y"
  2572     proof cases
  2573       case 1 then show ?thesis
  2574         by (intro less_eq_measure.intros(1)) simp
  2575     next
  2576       case 2 then show ?thesis
  2577         by (intro less_eq_measure.intros(2)) simp_all
  2578     next
  2579       case 3 with \<open>z \<le> y\<close> \<open>x \<le> y\<close> show ?thesis
  2580         by (auto simp add: le_measure intro!: emeasure_sup_measure'_le2)
  2581     qed
  2582   next
  2583     assume **: "x \<le> y" "z \<le> y" "space x = space z" "\<not> sets z \<subseteq> sets x" "\<not> sets x \<subseteq> sets z"
  2584     then have *: "sets x \<union> sets z \<subseteq> Pow (space x)"
  2585       using sets.space_closed by auto
  2586     show "sigma (space x) (sets x \<union> sets z) \<le> y"
  2587       unfolding sigma_le_iff[OF *] using ** by (auto simp: le_measure_iff split: if_split_asm)
  2588   next
  2589     assume "x \<le> y" "z \<le> y" "\<not> space z \<subseteq> space x" "\<not> space x \<subseteq> space z"
  2590     then have "space x \<subseteq> space y" "space z \<subseteq> space y"
  2591       by (auto simp: le_measure_iff split: if_split_asm)
  2592     then show "sigma (space x \<union> space z) {} \<le> y"
  2593       by (simp add: sigma_le_iff)
  2594   qed
  2595 qed
  2596 
  2597 end
  2598 
  2599 lemma space_empty_eq_bot: "space a = {} \<longleftrightarrow> a = bot"
  2600   using space_empty[of a] by (auto intro!: measure_eqI)
  2601 
  2602 interpretation sup_measure: comm_monoid_set sup "bot :: 'a measure"
  2603   proof qed (auto intro!: antisym)
  2604 
  2605 lemma sup_measure_F_mono':
  2606   "finite J \<Longrightarrow> finite I \<Longrightarrow> sup_measure.F id I \<le> sup_measure.F id (I \<union> J)"
  2607 proof (induction J rule: finite_induct)
  2608   case empty then show ?case
  2609     by simp
  2610 next
  2611   case (insert i J)
  2612   show ?case
  2613   proof cases
  2614     assume "i \<in> I" with insert show ?thesis
  2615       by (auto simp: insert_absorb)
  2616   next
  2617     assume "i \<notin> I"
  2618     have "sup_measure.F id I \<le> sup_measure.F id (I \<union> J)"
  2619       by (intro insert)
  2620     also have "\<dots> \<le> sup_measure.F id (insert i (I \<union> J))"
  2621       using insert \<open>i \<notin> I\<close> by (subst sup_measure.insert) auto
  2622     finally show ?thesis
  2623       by auto
  2624   qed
  2625 qed
  2626 
  2627 lemma sup_measure_F_mono: "finite I \<Longrightarrow> J \<subseteq> I \<Longrightarrow> sup_measure.F id J \<le> sup_measure.F id I"
  2628   using sup_measure_F_mono'[of I J] by (auto simp: finite_subset Un_absorb1)
  2629 
  2630 lemma sets_eq_iff_bounded: "A \<le> B \<Longrightarrow> B \<le> C \<Longrightarrow> sets A = sets C \<Longrightarrow> sets B = sets A"
  2631   by (auto dest: sets_eq_imp_space_eq simp add: le_measure_iff split: if_split_asm)
  2632 
  2633 lemma sets_sup: "sets A = sets M \<Longrightarrow> sets B = sets M \<Longrightarrow> sets (sup A B) = sets M"
  2634   by (auto simp add: sup_measure_def sup_lexord_def dest: sets_eq_imp_space_eq)
  2635 
  2636 lemma sets_sup_measure_F:
  2637   "finite I \<Longrightarrow> I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> sets i = sets M) \<Longrightarrow> sets (sup_measure.F id I) = sets M"
  2638   by (induction I rule: finite_ne_induct) (simp_all add: sets_sup)
  2639 
  2640 lemma le_measureD1: "A \<le> B \<Longrightarrow> space A \<le> space B"
  2641   by (auto simp: le_measure_iff split: if_split_asm)
  2642 
  2643 lemma le_measureD2: "A \<le> B \<Longrightarrow> space A = space B \<Longrightarrow> sets A \<le> sets B"
  2644   by (auto simp: le_measure_iff split: if_split_asm)
  2645 
  2646 lemma le_measureD3: "A \<le> B \<Longrightarrow> sets A = sets B \<Longrightarrow> emeasure A X \<le> emeasure B X"
  2647   by (auto simp: le_measure_iff le_fun_def dest: sets_eq_imp_space_eq split: if_split_asm)
  2648 
  2649 definition Sup_measure' :: "'a measure set \<Rightarrow> 'a measure"
  2650 where
  2651   "Sup_measure' M = measure_of (\<Union>a\<in>M. space a) (\<Union>a\<in>M. sets a)
  2652     (\<lambda>X. (SUP P:{P. finite P \<and> P \<subseteq> M }. sup_measure.F id P X))"
  2653 
  2654 lemma UN_space_closed: "UNION S sets \<subseteq> Pow (UNION S space)"
  2655   using sets.space_closed by auto
  2656 
  2657 lemma space_Sup_measure'2: "space (Sup_measure' M) = (\<Union>m\<in>M. space m)"
  2658   unfolding Sup_measure'_def by (intro space_measure_of[OF UN_space_closed])
  2659 
  2660 lemma sets_Sup_measure'2: "sets (Sup_measure' M) = sigma_sets (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m)"
  2661   unfolding Sup_measure'_def by (intro sets_measure_of[OF UN_space_closed])
  2662 
  2663 lemma sets_Sup_measure':
  2664   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "M \<noteq> {}"
  2665   shows "sets (Sup_measure' M) = sets A"
  2666   using sets_eq[THEN sets_eq_imp_space_eq, simp] \<open>M \<noteq> {}\<close> by (simp add: Sup_measure'_def)
  2667 
  2668 lemma space_Sup_measure':
  2669   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "M \<noteq> {}"
  2670   shows "space (Sup_measure' M) = space A"
  2671   using sets_eq[THEN sets_eq_imp_space_eq, simp] \<open>M \<noteq> {}\<close>
  2672   by (simp add: Sup_measure'_def )
  2673 
  2674 lemma emeasure_Sup_measure':
  2675   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "X \<in> sets A" "M \<noteq> {}"
  2676   shows "emeasure (Sup_measure' M) X = (SUP P:{P. finite P \<and> P \<subseteq> M}. sup_measure.F id P X)"
  2677     (is "_ = ?S X")
  2678   using Sup_measure'_def
  2679 proof (rule emeasure_measure_of)
  2680   note sets_eq[THEN sets_eq_imp_space_eq, simp]
  2681   have *: "sets (Sup_measure' M) = sets A" "space (Sup_measure' M) = space A"
  2682     using \<open>M \<noteq> {}\<close> by (simp_all add: Sup_measure'_def)
  2683   let ?\<mu> = "sup_measure.F id"
  2684   show "countably_additive (sets (Sup_measure' M)) ?S"
  2685   proof (rule countably_additiveI, goal_cases)
  2686     case (1 F)
  2687     then have **: "range F \<subseteq> sets A"
  2688       by (auto simp: *)
  2689     show "(\<Sum>i. ?S (F i)) = ?S (\<Union>i. F i)"
  2690     proof (subst ennreal_suminf_SUP_eq_directed)
  2691       fix i j and N :: "nat set" assume ij: "i \<in> {P. finite P \<and> P \<subseteq> M}" "j \<in> {P. finite P \<and> P \<subseteq> M}"
  2692       have "(i \<noteq> {} \<longrightarrow> sets (?\<mu> i) = sets A) \<and> (j \<noteq> {} \<longrightarrow> sets (?\<mu> j) = sets A) \<and>
  2693         (i \<noteq> {} \<or> j \<noteq> {} \<longrightarrow> sets (?\<mu> (i \<union> j)) = sets A)"
  2694         using ij by (intro impI sets_sup_measure_F conjI) auto
  2695       then have "?\<mu> j (F n) \<le> ?\<mu> (i \<union> j) (F n) \<and> ?\<mu> i (F n) \<le> ?\<mu> (i \<union> j) (F n)" for n
  2696         using ij
  2697         by (cases "i = {}"; cases "j = {}")
  2698            (auto intro!: le_measureD3 sup_measure_F_mono simp: sets_sup_measure_F
  2699                  simp del: id_apply)
  2700       with ij show "\<exists>k\<in>{P. finite P \<and> P \<subseteq> M}. \<forall>n\<in>N. ?\<mu> i (F n) \<le> ?\<mu> k (F n) \<and> ?\<mu> j (F n) \<le> ?\<mu> k (F n)"
  2701         by (safe intro!: bexI[of _ "i \<union> j"]) auto
  2702     next
  2703       show "(SUP P : {P. finite P \<and> P \<subseteq> M}. \<Sum>n. ?\<mu> P (F n)) = (SUP P : {P. finite P \<and> P \<subseteq> M}. ?\<mu> P (UNION UNIV F))"
  2704       proof (intro SUP_cong refl)
  2705         fix i assume i: "i \<in> {P. finite P \<and> P \<subseteq> M}"
  2706         show "(\<Sum>n. ?\<mu> i (F n)) = ?\<mu> i (UNION UNIV F)"
  2707         proof cases
  2708           assume "i \<noteq> {}" with i ** show ?thesis
  2709             apply (intro suminf_emeasure \<open>disjoint_family F\<close>)
  2710             apply (subst sets_sup_measure_F[OF _ _ sets_eq])
  2711             apply auto
  2712             done
  2713         qed simp
  2714       qed
  2715     qed
  2716   qed
  2717   show "positive (sets (Sup_measure' M)) ?S"
  2718     by (auto simp: positive_def bot_ennreal[symmetric])
  2719   show "X \<in> sets (Sup_measure' M)"
  2720     using assms * by auto
  2721 qed (rule UN_space_closed)
  2722 
  2723 definition Sup_lexord :: "('a \<Rightarrow> 'b::complete_lattice) \<Rightarrow> ('a set \<Rightarrow> 'a) \<Rightarrow> ('a set \<Rightarrow> 'a) \<Rightarrow> 'a set \<Rightarrow> 'a"
  2724 where
  2725   "Sup_lexord k c s A = (let U = (SUP a:A. k a) in if \<exists>a\<in>A. k a = U then c {a\<in>A. k a = U} else s A)"
  2726 
  2727 lemma Sup_lexord:
  2728   "(\<And>a S. a \<in> A \<Longrightarrow> k a = (SUP a:A. k a) \<Longrightarrow> S = {a'\<in>A. k a' = k a} \<Longrightarrow> P (c S)) \<Longrightarrow> ((\<And>a. a \<in> A \<Longrightarrow> k a \<noteq> (SUP a:A. k a)) \<Longrightarrow> P (s A)) \<Longrightarrow>
  2729     P (Sup_lexord k c s A)"
  2730   by (auto simp: Sup_lexord_def Let_def)
  2731 
  2732 lemma Sup_lexord1:
  2733   assumes A: "A \<noteq> {}" "(\<And>a. a \<in> A \<Longrightarrow> k a = (\<Union>a\<in>A. k a))" "P (c A)"
  2734   shows "P (Sup_lexord k c s A)"
  2735   unfolding Sup_lexord_def Let_def
  2736 proof (clarsimp, safe)
  2737   show "\<forall>a\<in>A. k a \<noteq> (\<Union>x\<in>A. k x) \<Longrightarrow> P (s A)"
  2738     by (metis assms(1,2) ex_in_conv)
  2739 next
  2740   fix a assume "a \<in> A" "k a = (\<Union>x\<in>A. k x)"
  2741   then have "{a \<in> A. k a = (\<Union>x\<in>A. k x)} = {a \<in> A. k a = k a}"
  2742     by (metis A(2)[symmetric])
  2743   then show "P (c {a \<in> A. k a = (\<Union>x\<in>A. k x)})"
  2744     by (simp add: A(3))
  2745 qed
  2746 
  2747 instantiation measure :: (type) complete_lattice
  2748 begin
  2749 
  2750 definition Sup_measure :: "'a measure set \<Rightarrow> 'a measure"
  2751 where
  2752   "Sup_measure = Sup_lexord space (Sup_lexord sets Sup_measure'
  2753     (\<lambda>U. sigma (\<Union>u\<in>U. space u) (\<Union>u\<in>U. sets u))) (\<lambda>U. sigma (\<Union>u\<in>U. space u) {})"
  2754 
  2755 definition Inf_measure :: "'a measure set \<Rightarrow> 'a measure"
  2756 where
  2757   "Inf_measure A = Sup {x. \<forall>a\<in>A. x \<le> a}"
  2758 
  2759 definition inf_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2760 where
  2761   "inf_measure a b = Inf {a, b}"
  2762 
  2763 definition top_measure :: "'a measure"
  2764 where
  2765   "top_measure = Inf {}"
  2766 
  2767 instance
  2768 proof
  2769   note UN_space_closed [simp]
  2770   show upper: "x \<le> Sup A" if x: "x \<in> A" for x :: "'a measure" and A
  2771     unfolding Sup_measure_def
  2772   proof (intro Sup_lexord[where P="\<lambda>y. x \<le> y"])
  2773     assume "\<And>a. a \<in> A \<Longrightarrow> space a \<noteq> (\<Union>a\<in>A. space a)"
  2774     from this[OF \<open>x \<in> A\<close>] \<open>x \<in> A\<close> show "x \<le> sigma (\<Union>a\<in>A. space a) {}"
  2775       by (intro less_eq_measure.intros) auto
  2776   next
  2777     fix a S assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  2778       and neq: "\<And>aa. aa \<in> S \<Longrightarrow> sets aa \<noteq> (\<Union>a\<in>S. sets a)"
  2779     have sp_a: "space a = (UNION S space)"
  2780       using \<open>a\<in>A\<close> by (auto simp: S)
  2781     show "x \<le> sigma (UNION S space) (UNION S sets)"
  2782     proof cases
  2783       assume [simp]: "space x = space a"
  2784       have "sets x \<subset> (\<Union>a\<in>S. sets a)"
  2785         using \<open>x\<in>A\<close> neq[of x] by (auto simp: S)
  2786       also have "\<dots> \<subseteq> sigma_sets (\<Union>x\<in>S. space x) (\<Union>x\<in>S. sets x)"
  2787         by (rule sigma_sets_superset_generator)
  2788       finally show ?thesis
  2789         by (intro less_eq_measure.intros(2)) (simp_all add: sp_a)
  2790     next
  2791       assume "space x \<noteq> space a"
  2792       moreover have "space x \<le> space a"
  2793         unfolding a using \<open>x\<in>A\<close> by auto
  2794       ultimately show ?thesis
  2795         by (intro less_eq_measure.intros) (simp add: less_le sp_a)
  2796     qed
  2797   next
  2798     fix a b S S' assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  2799       and "b \<in> S" and b: "sets b = (\<Union>a\<in>S. sets a)" and S': "S' = {a' \<in> S. sets a' = sets b}"
  2800     then have "S' \<noteq> {}" "space b = space a"
  2801       by auto
  2802     have sets_eq: "\<And>x. x \<in> S' \<Longrightarrow> sets x = sets b"
  2803       by (auto simp: S')
  2804     note sets_eq[THEN sets_eq_imp_space_eq, simp]
  2805     have *: "sets (Sup_measure' S') = sets b" "space (Sup_measure' S') = space b"
  2806       using \<open>S' \<noteq> {}\<close> by (simp_all add: Sup_measure'_def sets_eq)
  2807     show "x \<le> Sup_measure' S'"
  2808     proof cases
  2809       assume "x \<in> S"
  2810       with \<open>b \<in> S\<close> have "space x = space b"
  2811         by (simp add: S)
  2812       show ?thesis
  2813       proof cases
  2814         assume "x \<in> S'"
  2815         show "x \<le> Sup_measure' S'"
  2816         proof (intro le_measure[THEN iffD2] ballI)
  2817           show "sets x = sets (Sup_measure' S')"
  2818             using \<open>x\<in>S'\<close> * by (simp add: S')
  2819           fix X assume "X \<in> sets x"
  2820           show "emeasure x X \<le> emeasure (Sup_measure' S') X"
  2821           proof (subst emeasure_Sup_measure'[OF _ \<open>X \<in> sets x\<close>])
  2822             show "emeasure x X \<le> (SUP P : {P. finite P \<and> P \<subseteq> S'}. emeasure (sup_measure.F id P) X)"
  2823               using \<open>x\<in>S'\<close> by (intro SUP_upper2[where i="{x}"]) auto
  2824           qed (insert \<open>x\<in>S'\<close> S', auto)
  2825         qed
  2826       next
  2827         assume "x \<notin> S'"
  2828         then have "sets x \<noteq> sets b"
  2829           using \<open>x\<in>S\<close> by (auto simp: S')
  2830         moreover have "sets x \<le> sets b"
  2831           using \<open>x\<in>S\<close> unfolding b by auto
  2832         ultimately show ?thesis
  2833           using * \<open>x \<in> S\<close>
  2834           by (intro less_eq_measure.intros(2))
  2835              (simp_all add: * \<open>space x = space b\<close> less_le)
  2836       qed
  2837     next
  2838       assume "x \<notin> S"
  2839       with \<open>x\<in>A\<close> \<open>x \<notin> S\<close> \<open>space b = space a\<close> show ?thesis
  2840         by (intro less_eq_measure.intros)
  2841            (simp_all add: * less_le a SUP_upper S)
  2842     qed
  2843   qed
  2844   show least: "Sup A \<le> x" if x: "\<And>z. z \<in> A \<Longrightarrow> z \<le> x" for x :: "'a measure" and A
  2845     unfolding Sup_measure_def
  2846   proof (intro Sup_lexord[where P="\<lambda>y. y \<le> x"])
  2847     assume "\<And>a. a \<in> A \<Longrightarrow> space a \<noteq> (\<Union>a\<in>A. space a)"
  2848     show "sigma (UNION A space) {} \<le> x"
  2849       using x[THEN le_measureD1] by (subst sigma_le_iff) auto
  2850   next
  2851     fix a S assume "a \<in> A" "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  2852       "\<And>a. a \<in> S \<Longrightarrow> sets a \<noteq> (\<Union>a\<in>S. sets a)"
  2853     have "UNION S space \<subseteq> space x"
  2854       using S le_measureD1[OF x] by auto
  2855     moreover
  2856     have "UNION S space = space a"
  2857       using \<open>a\<in>A\<close> S by auto
  2858     then have "space x = UNION S space \<Longrightarrow> UNION S sets \<subseteq> sets x"
  2859       using \<open>a \<in> A\<close> le_measureD2[OF x] by (auto simp: S)
  2860     ultimately show "sigma (UNION S space) (UNION S sets) \<le> x"
  2861       by (subst sigma_le_iff) simp_all
  2862   next
  2863     fix a b S S' assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  2864       and "b \<in> S" and b: "sets b = (\<Union>a\<in>S. sets a)" and S': "S' = {a' \<in> S. sets a' = sets b}"
  2865     then have "S' \<noteq> {}" "space b = space a"
  2866       by auto
  2867     have sets_eq: "\<And>x. x \<in> S' \<Longrightarrow> sets x = sets b"
  2868       by (auto simp: S')
  2869     note sets_eq[THEN sets_eq_imp_space_eq, simp]
  2870     have *: "sets (Sup_measure' S') = sets b" "space (Sup_measure' S') = space b"
  2871       using \<open>S' \<noteq> {}\<close> by (simp_all add: Sup_measure'_def sets_eq)
  2872     show "Sup_measure' S' \<le> x"
  2873     proof cases
  2874       assume "space x = space a"
  2875       show ?thesis
  2876       proof cases
  2877         assume **: "sets x = sets b"
  2878         show ?thesis
  2879         proof (intro le_measure[THEN iffD2] ballI)
  2880           show ***: "sets (Sup_measure' S') = sets x"
  2881             by (simp add: * **)
  2882           fix X assume "X \<in> sets (Sup_measure' S')"
  2883           show "emeasure (Sup_measure' S') X \<le> emeasure x X"
  2884             unfolding ***
  2885           proof (subst emeasure_Sup_measure'[OF _ \<open>X \<in> sets (Sup_measure' S')\<close>])
  2886             show "(SUP P : {P. finite P \<and> P \<subseteq> S'}. emeasure (sup_measure.F id P) X) \<le> emeasure x X"
  2887             proof (safe intro!: SUP_least)
  2888               fix P assume P: "finite P" "P \<subseteq> S'"
  2889               show "emeasure (sup_measure.F id P) X \<le> emeasure x X"
  2890               proof cases
  2891                 assume "P = {}" then show ?thesis
  2892                   by auto
  2893               next
  2894                 assume "P \<noteq> {}"
  2895                 from P have "finite P" "P \<subseteq> A"
  2896                   unfolding S' S by (simp_all add: subset_eq)
  2897                 then have "sup_measure.F id P \<le> x"
  2898                   by (induction P) (auto simp: x)
  2899                 moreover have "sets (sup_measure.F id P) = sets x"
  2900                   using \<open>finite P\<close> \<open>P \<noteq> {}\<close> \<open>P \<subseteq> S'\<close> \<open>sets x = sets b\<close>
  2901                   by (intro sets_sup_measure_F) (auto simp: S')
  2902                 ultimately show "emeasure (sup_measure.F id P) X \<le> emeasure x X"
  2903                   by (rule le_measureD3)
  2904               qed
  2905             qed
  2906             show "m \<in> S' \<Longrightarrow> sets m = sets (Sup_measure' S')" for m
  2907               unfolding * by (simp add: S')
  2908           qed fact
  2909         qed
  2910       next
  2911         assume "sets x \<noteq> sets b"
  2912         moreover have "sets b \<le> sets x"
  2913           unfolding b S using x[THEN le_measureD2] \<open>space x = space a\<close> by auto
  2914         ultimately show "Sup_measure' S' \<le> x"
  2915           using \<open>space x = space a\<close> \<open>b \<in> S\<close>
  2916           by (intro less_eq_measure.intros(2)) (simp_all add: * S)
  2917       qed
  2918     next
  2919       assume "space x \<noteq> space a"
  2920       then have "space a < space x"
  2921         using le_measureD1[OF x[OF \<open>a\<in>A\<close>]] by auto
  2922       then show "Sup_measure' S' \<le> x"
  2923         by (intro less_eq_measure.intros) (simp add: * \<open>space b = space a\<close>)
  2924     qed
  2925   qed
  2926   show "Sup {} = (bot::'a measure)" "Inf {} = (top::'a measure)"
  2927     by (auto intro!: antisym least simp: top_measure_def)
  2928   show lower: "x \<in> A \<Longrightarrow> Inf A \<le> x" for x :: "'a measure" and A
  2929     unfolding Inf_measure_def by (intro least) auto
  2930   show greatest: "(\<And>z. z \<in> A \<Longrightarrow> x \<le> z) \<Longrightarrow> x \<le> Inf A" for x :: "'a measure" and A
  2931     unfolding Inf_measure_def by (intro upper) auto
  2932   show "inf x y \<le> x" "inf x y \<le> y" "x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> inf y z" for x y z :: "'a measure"
  2933     by (auto simp: inf_measure_def intro!: lower greatest)
  2934 qed
  2935 
  2936 end
  2937 
  2938 lemma sets_SUP:
  2939   assumes "\<And>x. x \<in> I \<Longrightarrow> sets (M x) = sets N"
  2940   shows "I \<noteq> {} \<Longrightarrow> sets (SUP i:I. M i) = sets N"
  2941   unfolding Sup_measure_def
  2942   using assms assms[THEN sets_eq_imp_space_eq]
  2943     sets_Sup_measure'[where A=N and M="M`I"]
  2944   by (intro Sup_lexord1[where P="\<lambda>x. sets x = sets N"]) auto
  2945 
  2946 lemma emeasure_SUP:
  2947   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets N" "X \<in> sets N" "I \<noteq> {}"
  2948   shows "emeasure (SUP i:I. M i) X = (SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emeasure (SUP i:J. M i) X)"
  2949 proof -
  2950   have eq: "finite J \<Longrightarrow> sup_measure.F id J = (SUP i:J. i)" for J :: "'b measure set"
  2951     by (induction J rule: finite_induct) auto
  2952   have 1: "J \<noteq> {} \<Longrightarrow> J \<subseteq> I \<Longrightarrow> sets (SUP x:J. M x) = sets N" for J
  2953     by (intro sets_SUP sets) (auto )
  2954 
  2955   from \<open>I \<noteq> {}\<close> obtain i where "i\<in>I" by auto
  2956   have "Sup_measure' (M`I) X = (SUP P:{P. finite P \<and> P \<subseteq> M`I}. sup_measure.F id P X)"
  2957     using sets by (intro emeasure_Sup_measure') auto
  2958   also have "Sup_measure' (M`I) = (SUP i:I. M i)"
  2959     unfolding Sup_measure_def using \<open>I \<noteq> {}\<close> sets sets(1)[THEN sets_eq_imp_space_eq]
  2960     by (intro Sup_lexord1[where P="\<lambda>x. _ = x"]) auto
  2961   also have "(SUP P:{P. finite P \<and> P \<subseteq> M`I}. sup_measure.F id P X) =
  2962     (SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. (SUP i:J. M i) X)"
  2963   proof (intro SUP_eq)
  2964     fix J assume "J \<in> {P. finite P \<and> P \<subseteq> M`I}"
  2965     then obtain J' where J': "J' \<subseteq> I" "finite J'" and J: "J = M`J'" and "finite J"
  2966       using finite_subset_image[of J M I] by auto
  2967     show "\<exists>j\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. sup_measure.F id J X \<le> (SUP i:j. M i) X"
  2968     proof cases
  2969       assume "J' = {}" with \<open>i \<in> I\<close> show ?thesis
  2970         by (auto simp add: J)
  2971     next
  2972       assume "J' \<noteq> {}" with J J' show ?thesis
  2973         by (intro bexI[of _ "J'"]) (auto simp add: eq simp del: id_apply)
  2974     qed
  2975   next
  2976     fix J assume J: "J \<in> {P. P \<noteq> {} \<and> finite P \<and> P \<subseteq> I}"
  2977     show "\<exists>J'\<in>{J. finite J \<and> J \<subseteq> M`I}. (SUP i:J. M i) X \<le> sup_measure.F id J' X"
  2978       using J by (intro bexI[of _ "M`J"]) (auto simp add: eq simp del: id_apply)
  2979   qed
  2980   finally show ?thesis .
  2981 qed
  2982 
  2983 lemma emeasure_SUP_chain:
  2984   assumes sets: "\<And>i. i \<in> A \<Longrightarrow> sets (M i) = sets N" "X \<in> sets N"
  2985   assumes ch: "Complete_Partial_Order.chain op \<le> (M ` A)" and "A \<noteq> {}"
  2986   shows "emeasure (SUP i:A. M i) X = (SUP i:A. emeasure (M i) X)"
  2987 proof (subst emeasure_SUP[OF sets \<open>A \<noteq> {}\<close>])
  2988   show "(SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}. emeasure (SUPREMUM J M) X) = (SUP i:A. emeasure (M i) X)"
  2989   proof (rule SUP_eq)
  2990     fix J assume "J \<in> {J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}"
  2991     then have J: "Complete_Partial_Order.chain op \<le> (M ` J)" "finite J" "J \<noteq> {}" and "J \<subseteq> A"
  2992       using ch[THEN chain_subset, of "M`J"] by auto
  2993     with in_chain_finite[OF J(1)] obtain j where "j \<in> J" "(SUP j:J. M j) = M j"
  2994       by auto
  2995     with \<open>J \<subseteq> A\<close> show "\<exists>j\<in>A. emeasure (SUPREMUM J M) X \<le> emeasure (M j) X"
  2996       by auto
  2997   next
  2998     fix j assume "j\<in>A" then show "\<exists>i\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}. emeasure (M j) X \<le> emeasure (SUPREMUM i M) X"
  2999       by (intro bexI[of _ "{j}"]) auto
  3000   qed
  3001 qed
  3002 
  3003 subsubsection \<open>Supremum of a set of $\sigma$-algebras\<close>
  3004 
  3005 lemma space_Sup_eq_UN: "space (Sup M) = (\<Union>x\<in>M. space x)"
  3006   unfolding Sup_measure_def
  3007   apply (intro Sup_lexord[where P="\<lambda>x. space x = _"])
  3008   apply (subst space_Sup_measure'2)
  3009   apply auto []
  3010   apply (subst space_measure_of[OF UN_space_closed])
  3011   apply auto
  3012   done
  3013 
  3014 lemma sets_Sup_eq:
  3015   assumes *: "\<And>m. m \<in> M \<Longrightarrow> space m = X" and "M \<noteq> {}"
  3016   shows "sets (Sup M) = sigma_sets X (\<Union>x\<in>M. sets x)"
  3017   unfolding Sup_measure_def
  3018   apply (rule Sup_lexord1)
  3019   apply fact
  3020   apply (simp add: assms)
  3021   apply (rule Sup_lexord)
  3022   subgoal premises that for a S
  3023     unfolding that(3) that(2)[symmetric]
  3024     using that(1)
  3025     apply (subst sets_Sup_measure'2)
  3026     apply (intro arg_cong2[where f=sigma_sets])
  3027     apply (auto simp: *)
  3028     done
  3029   apply (subst sets_measure_of[OF UN_space_closed])
  3030   apply (simp add:  assms)
  3031   done
  3032 
  3033 lemma in_sets_Sup: "(\<And>m. m \<in> M \<Longrightarrow> space m = X) \<Longrightarrow> m \<in> M \<Longrightarrow> A \<in> sets m \<Longrightarrow> A \<in> sets (Sup M)"
  3034   by (subst sets_Sup_eq[where X=X]) auto
  3035 
  3036 lemma Sup_lexord_rel:
  3037   assumes "\<And>i. i \<in> I \<Longrightarrow> k (A i) = k (B i)"
  3038     "R (c (A ` {a \<in> I. k (B a) = (SUP x:I. k (B x))})) (c (B ` {a \<in> I. k (B a) = (SUP x:I. k (B x))}))"
  3039     "R (s (A`I)) (s (B`I))"
  3040   shows "R (Sup_lexord k c s (A`I)) (Sup_lexord k c s (B`I))"
  3041 proof -
  3042   have "A ` {a \<in> I. k (B a) = (SUP x:I. k (B x))} =  {a \<in> A ` I. k a = (SUP x:I. k (B x))}"
  3043     using assms(1) by auto
  3044   moreover have "B ` {a \<in> I. k (B a) = (SUP x:I. k (B x))} =  {a \<in> B ` I. k a = (SUP x:I. k (B x))}"
  3045     by auto
  3046   ultimately show ?thesis
  3047     using assms by (auto simp: Sup_lexord_def Let_def)
  3048 qed
  3049 
  3050 lemma sets_SUP_cong:
  3051   assumes eq: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (SUP i:I. M i) = sets (SUP i:I. N i)"
  3052   unfolding Sup_measure_def
  3053   using eq eq[THEN sets_eq_imp_space_eq]
  3054   apply (intro Sup_lexord_rel[where R="\<lambda>x y. sets x = sets y"])
  3055   apply simp
  3056   apply simp
  3057   apply (simp add: sets_Sup_measure'2)
  3058   apply (intro arg_cong2[where f="\<lambda>x y. sets (sigma x y)"])
  3059   apply auto
  3060   done
  3061 
  3062 lemma sets_Sup_in_sets:
  3063   assumes "M \<noteq> {}"
  3064   assumes "\<And>m. m \<in> M \<Longrightarrow> space m = space N"
  3065   assumes "\<And>m. m \<in> M \<Longrightarrow> sets m \<subseteq> sets N"
  3066   shows "sets (Sup M) \<subseteq> sets N"
  3067 proof -
  3068   have *: "UNION M space = space N"
  3069     using assms by auto
  3070   show ?thesis
  3071     unfolding * using assms by (subst sets_Sup_eq[of M "space N"]) (auto intro!: sets.sigma_sets_subset)
  3072 qed
  3073 
  3074 lemma measurable_Sup1:
  3075   assumes m: "m \<in> M" and f: "f \<in> measurable m N"
  3076     and const_space: "\<And>m n. m \<in> M \<Longrightarrow> n \<in> M \<Longrightarrow> space m = space n"
  3077   shows "f \<in> measurable (Sup M) N"
  3078 proof -
  3079   have "space (Sup M) = space m"
  3080     using m by (auto simp add: space_Sup_eq_UN dest: const_space)
  3081   then show ?thesis
  3082     using m f unfolding measurable_def by (auto intro: in_sets_Sup[OF const_space])
  3083 qed
  3084 
  3085 lemma measurable_Sup2:
  3086   assumes M: "M \<noteq> {}"
  3087   assumes f: "\<And>m. m \<in> M \<Longrightarrow> f \<in> measurable N m"
  3088     and const_space: "\<And>m n. m \<in> M \<Longrightarrow> n \<in> M \<Longrightarrow> space m = space n"
  3089   shows "f \<in> measurable N (Sup M)"
  3090 proof -
  3091   from M obtain m where "m \<in> M" by auto
  3092   have space_eq: "\<And>n. n \<in> M \<Longrightarrow> space n = space m"
  3093     by (intro const_space \<open>m \<in> M\<close>)
  3094   have "f \<in> measurable N (sigma (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m))"
  3095   proof (rule measurable_measure_of)
  3096     show "f \<in> space N \<rightarrow> UNION M space"
  3097       using measurable_space[OF f] M by auto
  3098   qed (auto intro: measurable_sets f dest: sets.sets_into_space)
  3099   also have "measurable N (sigma (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m)) = measurable N (Sup M)"
  3100     apply (intro measurable_cong_sets refl)
  3101     apply (subst sets_Sup_eq[OF space_eq M])
  3102     apply simp
  3103     apply (subst sets_measure_of[OF UN_space_closed])
  3104     apply (simp add: space_eq M)
  3105     done
  3106   finally show ?thesis .
  3107 qed
  3108 
  3109 lemma sets_Sup_sigma:
  3110   assumes [simp]: "M \<noteq> {}" and M: "\<And>m. m \<in> M \<Longrightarrow> m \<subseteq> Pow \<Omega>"
  3111   shows "sets (SUP m:M. sigma \<Omega> m) = sets (sigma \<Omega> (\<Union>M))"
  3112 proof -
  3113   { fix a m assume "a \<in> sigma_sets \<Omega> m" "m \<in> M"
  3114     then have "a \<in> sigma_sets \<Omega> (\<Union>M)"
  3115      by induction (auto intro: sigma_sets.intros) }
  3116   then show "sets (SUP m:M. sigma \<Omega> m) = sets (sigma \<Omega> (\<Union>M))"
  3117     apply (subst sets_Sup_eq[where X="\<Omega>"])
  3118     apply (auto simp add: M) []
  3119     apply auto []
  3120     apply (simp add: space_measure_of_conv M Union_least)
  3121     apply (rule sigma_sets_eqI)
  3122     apply auto
  3123     done
  3124 qed
  3125 
  3126 lemma Sup_sigma:
  3127   assumes [simp]: "M \<noteq> {}" and M: "\<And>m. m \<in> M \<Longrightarrow> m \<subseteq> Pow \<Omega>"
  3128   shows "(SUP m:M. sigma \<Omega> m) = (sigma \<Omega> (\<Union>M))"
  3129 proof (intro antisym SUP_least)
  3130   have *: "\<Union>M \<subseteq> Pow \<Omega>"
  3131     using M by auto
  3132   show "sigma \<Omega> (\<Union>M) \<le> (SUP m:M. sigma \<Omega> m)"
  3133   proof (intro less_eq_measure.intros(3))
  3134     show "space (sigma \<Omega> (\<Union>M)) = space (SUP m:M. sigma \<Omega> m)"
  3135       "sets (sigma \<Omega> (\<Union>M)) = sets (SUP m:M. sigma \<Omega> m)"
  3136       using sets_Sup_sigma[OF assms] sets_Sup_sigma[OF assms, THEN sets_eq_imp_space_eq]
  3137       by auto
  3138   qed (simp add: emeasure_sigma le_fun_def)
  3139   fix m assume "m \<in> M" then show "sigma \<Omega> m \<le> sigma \<Omega> (\<Union>M)"
  3140     by (subst sigma_le_iff) (auto simp add: M *)
  3141 qed
  3142 
  3143 lemma SUP_sigma_sigma:
  3144   "M \<noteq> {} \<Longrightarrow> (\<And>m. m \<in> M \<Longrightarrow> f m \<subseteq> Pow \<Omega>) \<Longrightarrow> (SUP m:M. sigma \<Omega> (f m)) = sigma \<Omega> (\<Union>m\<in>M. f m)"
  3145   using Sup_sigma[of "f`M" \<Omega>] by auto
  3146 
  3147 lemma sets_vimage_Sup_eq:
  3148   assumes *: "M \<noteq> {}" "f \<in> X \<rightarrow> Y" "\<And>m. m \<in> M \<Longrightarrow> space m = Y"
  3149   shows "sets (vimage_algebra X f (Sup M)) = sets (SUP m : M. vimage_algebra X f m)"
  3150   (is "?IS = ?SI")
  3151 proof
  3152   show "?IS \<subseteq> ?SI"
  3153     apply (intro sets_image_in_sets measurable_Sup2)
  3154     apply (simp add: space_Sup_eq_UN *)
  3155     apply (simp add: *)
  3156     apply (intro measurable_Sup1)
  3157     apply (rule imageI)
  3158     apply assumption
  3159     apply (rule measurable_vimage_algebra1)
  3160     apply (auto simp: *)
  3161     done
  3162   show "?SI \<subseteq> ?IS"
  3163     apply (intro sets_Sup_in_sets)
  3164     apply (auto simp: *) []
  3165     apply (auto simp: *) []
  3166     apply (elim imageE)
  3167     apply simp
  3168     apply (rule sets_image_in_sets)
  3169     apply simp
  3170     apply (simp add: measurable_def)
  3171     apply (simp add: * space_Sup_eq_UN sets_vimage_algebra2)
  3172     apply (auto intro: in_sets_Sup[OF *(3)])
  3173     done
  3174 qed
  3175 
  3176 lemma restrict_space_eq_vimage_algebra':
  3177   "sets (restrict_space M \<Omega>) = sets (vimage_algebra (\<Omega> \<inter> space M) (\<lambda>x. x) M)"
  3178 proof -
  3179   have *: "{A \<inter> (\<Omega> \<inter> space M) |A. A \<in> sets M} = {A \<inter> \<Omega> |A. A \<in> sets M}"
  3180     using sets.sets_into_space[of _ M] by blast
  3181 
  3182   show ?thesis
  3183     unfolding restrict_space_def
  3184     by (subst sets_measure_of)
  3185        (auto simp add: image_subset_iff sets_vimage_algebra * dest: sets.sets_into_space intro!: arg_cong2[where f=sigma_sets])
  3186 qed
  3187 
  3188 lemma sigma_le_sets:
  3189   assumes [simp]: "A \<subseteq> Pow X" shows "sets (sigma X A) \<subseteq> sets N \<longleftrightarrow> X \<in> sets N \<and> A \<subseteq> sets N"
  3190 proof
  3191   have "X \<in> sigma_sets X A" "A \<subseteq> sigma_sets X A"
  3192     by (auto intro: sigma_sets_top)
  3193   moreover assume "sets (sigma X A) \<subseteq> sets N"
  3194   ultimately show "X \<in> sets N \<and> A \<subseteq> sets N"
  3195     by auto
  3196 next
  3197   assume *: "X \<in> sets N \<and> A \<subseteq> sets N"
  3198   { fix Y assume "Y \<in> sigma_sets X A" from this * have "Y \<in> sets N"
  3199       by induction auto }
  3200   then show "sets (sigma X A) \<subseteq> sets N"
  3201     by auto
  3202 qed
  3203 
  3204 lemma measurable_iff_sets:
  3205   "f \<in> measurable M N \<longleftrightarrow> (f \<in> space M \<rightarrow> space N \<and> sets (vimage_algebra (space M) f N) \<subseteq> sets M)"
  3206 proof -
  3207   have *: "{f -` A \<inter> space M |A. A \<in> sets N} \<subseteq> Pow (space M)"
  3208     by auto
  3209   show ?thesis
  3210     unfolding measurable_def
  3211     by (auto simp add: vimage_algebra_def sigma_le_sets[OF *])
  3212 qed
  3213 
  3214 lemma sets_vimage_algebra_space: "X \<in> sets (vimage_algebra X f M)"
  3215   using sets.top[of "vimage_algebra X f M"] by simp
  3216 
  3217 lemma measurable_mono:
  3218   assumes N: "sets N' \<le> sets N" "space N = space N'"
  3219   assumes M: "sets M \<le> sets M'" "space M = space M'"
  3220   shows "measurable M N \<subseteq> measurable M' N'"
  3221   unfolding measurable_def
  3222 proof safe
  3223   fix f A assume "f \<in> space M \<rightarrow> space N" "A \<in> sets N'"
  3224   moreover assume "\<forall>y\<in>sets N. f -` y \<inter> space M \<in> sets M" note this[THEN bspec, of A]
  3225   ultimately show "f -` A \<inter> space M' \<in> sets M'"
  3226     using assms by auto
  3227 qed (insert N M, auto)
  3228 
  3229 lemma measurable_Sup_measurable:
  3230   assumes f: "f \<in> space N \<rightarrow> A"
  3231   shows "f \<in> measurable N (Sup {M. space M = A \<and> f \<in> measurable N M})"
  3232 proof (rule measurable_Sup2)
  3233   show "{M. space M = A \<and> f \<in> measurable N M} \<noteq> {}"
  3234     using f unfolding ex_in_conv[symmetric]
  3235     by (intro exI[of _ "sigma A {}"]) (auto intro!: measurable_measure_of)
  3236 qed auto
  3237 
  3238 lemma (in sigma_algebra) sigma_sets_subset':
  3239   assumes a: "a \<subseteq> M" "\<Omega>' \<in> M"
  3240   shows "sigma_sets \<Omega>' a \<subseteq> M"
  3241 proof
  3242   show "x \<in> M" if x: "x \<in> sigma_sets \<Omega>' a" for x
  3243     using x by (induct rule: sigma_sets.induct) (insert a, auto)
  3244 qed
  3245 
  3246 lemma in_sets_SUP: "i \<in> I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> space (M i) = Y) \<Longrightarrow> X \<in> sets (M i) \<Longrightarrow> X \<in> sets (SUP i:I. M i)"
  3247   by (intro in_sets_Sup[where X=Y]) auto
  3248 
  3249 lemma measurable_SUP1:
  3250   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<And>m n. m \<in> I \<Longrightarrow> n \<in> I \<Longrightarrow> space (M m) = space (M n)) \<Longrightarrow>
  3251     f \<in> measurable (SUP i:I. M i) N"
  3252   by (auto intro: measurable_Sup1)
  3253 
  3254 lemma sets_image_in_sets':
  3255   assumes X: "X \<in> sets N"
  3256   assumes f: "\<And>A. A \<in> sets M \<Longrightarrow> f -` A \<inter> X \<in> sets N"
  3257   shows "sets (vimage_algebra X f M) \<subseteq> sets N"
  3258   unfolding sets_vimage_algebra
  3259   by (rule sets.sigma_sets_subset') (auto intro!: measurable_sets X f)
  3260 
  3261 lemma mono_vimage_algebra:
  3262   "sets M \<le> sets N \<Longrightarrow> sets (vimage_algebra X f M) \<subseteq> sets (vimage_algebra X f N)"
  3263   using sets.top[of "sigma X {f -` A \<inter> X |A. A \<in> sets N}"]
  3264   unfolding vimage_algebra_def
  3265   apply (subst (asm) space_measure_of)
  3266   apply auto []
  3267   apply (subst sigma_le_sets)
  3268   apply auto
  3269   done
  3270 
  3271 lemma mono_restrict_space: "sets M \<le> sets N \<Longrightarrow> sets (restrict_space M X) \<subseteq> sets (restrict_space N X)"
  3272   unfolding sets_restrict_space by (rule image_mono)
  3273 
  3274 lemma sets_eq_bot: "sets M = {{}} \<longleftrightarrow> M = bot"
  3275   apply safe
  3276   apply (intro measure_eqI)
  3277   apply auto
  3278   done
  3279 
  3280 lemma sets_eq_bot2: "{{}} = sets M \<longleftrightarrow> M = bot"
  3281   using sets_eq_bot[of M] by blast
  3282 
  3283 
  3284 lemma (in finite_measure) countable_support:
  3285   "countable {x. measure M {x} \<noteq> 0}"
  3286 proof cases
  3287   assume "measure M (space M) = 0"
  3288   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
  3289     by auto
  3290   then show ?thesis
  3291     by simp
  3292 next
  3293   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
  3294   assume "?M \<noteq> 0"
  3295   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
  3296     using reals_Archimedean[of "?m x / ?M" for x]
  3297     by (auto simp: field_simps not_le[symmetric] measure_nonneg divide_le_0_iff measure_le_0_iff)
  3298   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
  3299   proof (rule ccontr)
  3300     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
  3301     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
  3302       by (metis infinite_arbitrarily_large)
  3303     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x"
  3304       by auto
  3305     { fix x assume "x \<in> X"
  3306       from \<open>?M \<noteq> 0\<close> *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
  3307       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
  3308     note singleton_sets = this
  3309     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
  3310       using \<open>?M \<noteq> 0\<close>
  3311       by (simp add: \<open>card X = Suc (Suc n)\<close> of_nat_Suc field_simps less_le measure_nonneg)
  3312     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
  3313       by (rule setsum_mono) fact
  3314     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
  3315       using singleton_sets \<open>finite X\<close>
  3316       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
  3317     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
  3318     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
  3319       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
  3320     ultimately show False by simp
  3321   qed
  3322   show ?thesis
  3323     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
  3324 qed
  3325 
  3326 end