author hoelzl
Mon Aug 08 14:13:14 2016 +0200 (2016-08-08)
changeset 63627 6ddb43c6b711
parent 63626 src/HOL/Multivariate_Analysis/Radon_Nikodym.thy@44ce6b524ff3
child 64283 979cdfdf7a79
permissions -rw-r--r--
rename HOL-Multivariate_Analysis to HOL-Analysis.
     1 (*  Title:      HOL/Analysis/Radon_Nikodym.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     5 section \<open>Radon-Nikod{\'y}m derivative\<close>
     7 theory Radon_Nikodym
     8 imports Bochner_Integration
     9 begin
    11 definition diff_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
    12 where
    13   "diff_measure M N = measure_of (space M) (sets M) (\<lambda>A. emeasure M A - emeasure N A)"
    15 lemma
    16   shows space_diff_measure[simp]: "space (diff_measure M N) = space M"
    17     and sets_diff_measure[simp]: "sets (diff_measure M N) = sets M"
    18   by (auto simp: diff_measure_def)
    20 lemma emeasure_diff_measure:
    21   assumes fin: "finite_measure M" "finite_measure N" and sets_eq: "sets M = sets N"
    22   assumes pos: "\<And>A. A \<in> sets M \<Longrightarrow> emeasure N A \<le> emeasure M A" and A: "A \<in> sets M"
    23   shows "emeasure (diff_measure M N) A = emeasure M A - emeasure N A" (is "_ = ?\<mu> A")
    24   unfolding diff_measure_def
    25 proof (rule emeasure_measure_of_sigma)
    26   show "sigma_algebra (space M) (sets M)" ..
    27   show "positive (sets M) ?\<mu>"
    28     using pos by (simp add: positive_def)
    29   show "countably_additive (sets M) ?\<mu>"
    30   proof (rule countably_additiveI)
    31     fix A :: "nat \<Rightarrow> _"  assume A: "range A \<subseteq> sets M" and "disjoint_family A"
    32     then have suminf:
    33       "(\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
    34       "(\<Sum>i. emeasure N (A i)) = emeasure N (\<Union>i. A i)"
    35       by (simp_all add: suminf_emeasure sets_eq)
    36     with A have "(\<Sum>i. emeasure M (A i) - emeasure N (A i)) =
    37       (\<Sum>i. emeasure M (A i)) - (\<Sum>i. emeasure N (A i))"
    38       using fin pos[of "A _"]
    39       by (intro ennreal_suminf_minus)
    40          (auto simp: sets_eq finite_measure.emeasure_eq_measure suminf_emeasure)
    41     then show "(\<Sum>i. emeasure M (A i) - emeasure N (A i)) =
    42       emeasure M (\<Union>i. A i) - emeasure N (\<Union>i. A i) "
    43       by (simp add: suminf)
    44   qed
    45 qed fact
    47 lemma (in sigma_finite_measure) Ex_finite_integrable_function:
    48   "\<exists>h\<in>borel_measurable M. integral\<^sup>N M h \<noteq> \<infinity> \<and> (\<forall>x\<in>space M. 0 < h x \<and> h x < \<infinity>)"
    49 proof -
    50   obtain A :: "nat \<Rightarrow> 'a set" where
    51     range[measurable]: "range A \<subseteq> sets M" and
    52     space: "(\<Union>i. A i) = space M" and
    53     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>" and
    54     disjoint: "disjoint_family A"
    55     using sigma_finite_disjoint by blast
    56   let ?B = "\<lambda>i. 2^Suc i * emeasure M (A i)"
    57   have [measurable]: "\<And>i. A i \<in> sets M"
    58     using range by fastforce+
    59   have "\<forall>i. \<exists>x. 0 < x \<and> x < inverse (?B i)"
    60   proof
    61     fix i show "\<exists>x. 0 < x \<and> x < inverse (?B i)"
    62       using measure[of i]
    63       by (auto intro!: dense simp: ennreal_inverse_positive ennreal_mult_eq_top_iff power_eq_top_ennreal)
    64   qed
    65   from choice[OF this] obtain n where n: "\<And>i. 0 < n i"
    66     "\<And>i. n i < inverse (2^Suc i * emeasure M (A i))" by auto
    67   { fix i have "0 \<le> n i" using n(1)[of i] by auto } note pos = this
    68   let ?h = "\<lambda>x. \<Sum>i. n i * indicator (A i) x"
    69   show ?thesis
    70   proof (safe intro!: bexI[of _ ?h] del: notI)
    71     have "integral\<^sup>N M ?h = (\<Sum>i. n i * emeasure M (A i))" using pos
    72       by (simp add: nn_integral_suminf nn_integral_cmult_indicator)
    73     also have "\<dots> \<le> (\<Sum>i. ennreal ((1/2)^Suc i))"
    74     proof (intro suminf_le allI)
    75       fix N
    76       have "n N * emeasure M (A N) \<le> inverse (2^Suc N * emeasure M (A N)) * emeasure M (A N)"
    77         using n[of N] by (intro mult_right_mono) auto
    78       also have "\<dots> = (1/2)^Suc N * (inverse (emeasure M (A N)) * emeasure M (A N))"
    79         using measure[of N]
    80         by (simp add: ennreal_inverse_power divide_ennreal_def ennreal_inverse_mult
    81                       power_eq_top_ennreal less_top[symmetric] mult_ac
    82                  del: power_Suc)
    83       also have "\<dots> \<le> inverse (ennreal 2) ^ Suc N"
    84         using measure[of N]
    85         by (cases "emeasure M (A N)"; cases "emeasure M (A N) = 0")
    86            (auto simp: inverse_ennreal ennreal_mult[symmetric] divide_ennreal_def simp del: power_Suc)
    87       also have "\<dots> = ennreal (inverse 2 ^ Suc N)"
    88         by (subst ennreal_power[symmetric], simp) (simp add: inverse_ennreal)
    89       finally show "n N * emeasure M (A N) \<le> ennreal ((1/2)^Suc N)"
    90         by simp
    91     qed auto
    92     also have "\<dots> < top"
    93       unfolding less_top[symmetric]
    94       by (rule ennreal_suminf_neq_top)
    95          (auto simp: summable_geometric summable_Suc_iff simp del: power_Suc)
    96     finally show "integral\<^sup>N M ?h \<noteq> \<infinity>"
    97       by (auto simp: top_unique)
    98   next
    99     { fix x assume "x \<in> space M"
   100       then obtain i where "x \<in> A i" using space[symmetric] by auto
   101       with disjoint n have "?h x = n i"
   102         by (auto intro!: suminf_cmult_indicator intro: less_imp_le)
   103       then show "0 < ?h x" and "?h x < \<infinity>" using n[of i] by (auto simp: less_top[symmetric]) }
   104     note pos = this
   105   qed measurable
   106 qed
   108 subsection "Absolutely continuous"
   110 definition absolutely_continuous :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
   111   "absolutely_continuous M N \<longleftrightarrow> null_sets M \<subseteq> null_sets N"
   113 lemma absolutely_continuousI_count_space: "absolutely_continuous (count_space A) M"
   114   unfolding absolutely_continuous_def by (auto simp: null_sets_count_space)
   116 lemma absolutely_continuousI_density:
   117   "f \<in> borel_measurable M \<Longrightarrow> absolutely_continuous M (density M f)"
   118   by (force simp add: absolutely_continuous_def null_sets_density_iff dest: AE_not_in)
   120 lemma absolutely_continuousI_point_measure_finite:
   121   "(\<And>x. \<lbrakk> x \<in> A ; f x \<le> 0 \<rbrakk> \<Longrightarrow> g x \<le> 0) \<Longrightarrow> absolutely_continuous (point_measure A f) (point_measure A g)"
   122   unfolding absolutely_continuous_def by (force simp: null_sets_point_measure_iff)
   124 lemma absolutely_continuousD:
   125   "absolutely_continuous M N \<Longrightarrow> A \<in> sets M \<Longrightarrow> emeasure M A = 0 \<Longrightarrow> emeasure N A = 0"
   126   by (auto simp: absolutely_continuous_def null_sets_def)
   128 lemma absolutely_continuous_AE:
   129   assumes sets_eq: "sets M' = sets M"
   130     and "absolutely_continuous M M'" "AE x in M. P x"
   131    shows "AE x in M'. P x"
   132 proof -
   133   from \<open>AE x in M. P x\<close> obtain N where N: "N \<in> null_sets M" "{x\<in>space M. \<not> P x} \<subseteq> N"
   134     unfolding eventually_ae_filter by auto
   135   show "AE x in M'. P x"
   136   proof (rule AE_I')
   137     show "{x\<in>space M'. \<not> P x} \<subseteq> N" using sets_eq_imp_space_eq[OF sets_eq] N(2) by simp
   138     from \<open>absolutely_continuous M M'\<close> show "N \<in> null_sets M'"
   139       using N unfolding absolutely_continuous_def sets_eq null_sets_def by auto
   140   qed
   141 qed
   143 subsection "Existence of the Radon-Nikodym derivative"
   145 lemma (in finite_measure) Radon_Nikodym_finite_measure:
   146   assumes "finite_measure N" and sets_eq[simp]: "sets N = sets M"
   147   assumes "absolutely_continuous M N"
   148   shows "\<exists>f \<in> borel_measurable M. density M f = N"
   149 proof -
   150   interpret N: finite_measure N by fact
   151   define G where "G = {g \<in> borel_measurable M. \<forall>A\<in>sets M. (\<integral>\<^sup>+x. g x * indicator A x \<partial>M) \<le> N A}"
   152   have [measurable_dest]: "f \<in> G \<Longrightarrow> f \<in> borel_measurable M"
   153     and G_D: "\<And>A. f \<in> G \<Longrightarrow> A \<in> sets M \<Longrightarrow> (\<integral>\<^sup>+x. f x * indicator A x \<partial>M) \<le> N A" for f
   154     by (auto simp: G_def)
   155   note this[measurable_dest]
   156   have "(\<lambda>x. 0) \<in> G" unfolding G_def by auto
   157   hence "G \<noteq> {}" by auto
   158   { fix f g assume f[measurable]: "f \<in> G" and g[measurable]: "g \<in> G"
   159     have "(\<lambda>x. max (g x) (f x)) \<in> G" (is "?max \<in> G") unfolding G_def
   160     proof safe
   161       let ?A = "{x \<in> space M. f x \<le> g x}"
   162       have "?A \<in> sets M" using f g unfolding G_def by auto
   163       fix A assume [measurable]: "A \<in> sets M"
   164       have union: "((?A \<inter> A) \<union> ((space M - ?A) \<inter> A)) = A"
   165         using sets.sets_into_space[OF \<open>A \<in> sets M\<close>] by auto
   166       have "\<And>x. x \<in> space M \<Longrightarrow> max (g x) (f x) * indicator A x =
   167         g x * indicator (?A \<inter> A) x + f x * indicator ((space M - ?A) \<inter> A) x"
   168         by (auto simp: indicator_def max_def)
   169       hence "(\<integral>\<^sup>+x. max (g x) (f x) * indicator A x \<partial>M) =
   170         (\<integral>\<^sup>+x. g x * indicator (?A \<inter> A) x \<partial>M) +
   171         (\<integral>\<^sup>+x. f x * indicator ((space M - ?A) \<inter> A) x \<partial>M)"
   172         by (auto cong: nn_integral_cong intro!: nn_integral_add)
   173       also have "\<dots> \<le> N (?A \<inter> A) + N ((space M - ?A) \<inter> A)"
   174         using f g unfolding G_def by (auto intro!: add_mono)
   175       also have "\<dots> = N A"
   176         using union by (subst plus_emeasure) auto
   177       finally show "(\<integral>\<^sup>+x. max (g x) (f x) * indicator A x \<partial>M) \<le> N A" .
   178     qed auto }
   179   note max_in_G = this
   180   { fix f assume  "incseq f" and f: "\<And>i. f i \<in> G"
   181     then have [measurable]: "\<And>i. f i \<in> borel_measurable M" by (auto simp: G_def)
   182     have "(\<lambda>x. SUP i. f i x) \<in> G" unfolding G_def
   183     proof safe
   184       show "(\<lambda>x. SUP i. f i x) \<in> borel_measurable M" by measurable
   185     next
   186       fix A assume "A \<in> sets M"
   187       have "(\<integral>\<^sup>+x. (SUP i. f i x) * indicator A x \<partial>M) =
   188         (\<integral>\<^sup>+x. (SUP i. f i x * indicator A x) \<partial>M)"
   189         by (intro nn_integral_cong) (simp split: split_indicator)
   190       also have "\<dots> = (SUP i. (\<integral>\<^sup>+x. f i x * indicator A x \<partial>M))"
   191         using \<open>incseq f\<close> f \<open>A \<in> sets M\<close>
   192         by (intro nn_integral_monotone_convergence_SUP)
   193            (auto simp: G_def incseq_Suc_iff le_fun_def split: split_indicator)
   194       finally show "(\<integral>\<^sup>+x. (SUP i. f i x) * indicator A x \<partial>M) \<le> N A"
   195         using f \<open>A \<in> sets M\<close> by (auto intro!: SUP_least simp: G_D)
   196     qed }
   197   note SUP_in_G = this
   198   let ?y = "SUP g : G. integral\<^sup>N M g"
   199   have y_le: "?y \<le> N (space M)" unfolding G_def
   200   proof (safe intro!: SUP_least)
   201     fix g assume "\<forall>A\<in>sets M. (\<integral>\<^sup>+x. g x * indicator A x \<partial>M) \<le> N A"
   202     from this[THEN bspec, OF] show "integral\<^sup>N M g \<le> N (space M)"
   203       by (simp cong: nn_integral_cong)
   204   qed
   205   from ennreal_SUP_countable_SUP [OF \<open>G \<noteq> {}\<close>, of "integral\<^sup>N M"] guess ys .. note ys = this
   206   then have "\<forall>n. \<exists>g. g\<in>G \<and> integral\<^sup>N M g = ys n"
   207   proof safe
   208     fix n assume "range ys \<subseteq> integral\<^sup>N M ` G"
   209     hence "ys n \<in> integral\<^sup>N M ` G" by auto
   210     thus "\<exists>g. g\<in>G \<and> integral\<^sup>N M g = ys n" by auto
   211   qed
   212   from choice[OF this] obtain gs where "\<And>i. gs i \<in> G" "\<And>n. integral\<^sup>N M (gs n) = ys n" by auto
   213   hence y_eq: "?y = (SUP i. integral\<^sup>N M (gs i))" using ys by auto
   214   let ?g = "\<lambda>i x. Max ((\<lambda>n. gs n x) ` {..i})"
   215   define f where [abs_def]: "f x = (SUP i. ?g i x)" for x
   216   let ?F = "\<lambda>A x. f x * indicator A x"
   217   have gs_not_empty: "\<And>i x. (\<lambda>n. gs n x) ` {..i} \<noteq> {}" by auto
   218   { fix i have "?g i \<in> G"
   219     proof (induct i)
   220       case 0 thus ?case by simp fact
   221     next
   222       case (Suc i)
   223       with Suc gs_not_empty \<open>gs (Suc i) \<in> G\<close> show ?case
   224         by (auto simp add: atMost_Suc intro!: max_in_G)
   225     qed }
   226   note g_in_G = this
   227   have "incseq ?g" using gs_not_empty
   228     by (auto intro!: incseq_SucI le_funI simp add: atMost_Suc)
   230   from SUP_in_G[OF this g_in_G] have [measurable]: "f \<in> G" unfolding f_def .
   231   then have [measurable]: "f \<in> borel_measurable M" unfolding G_def by auto
   233   have "integral\<^sup>N M f = (SUP i. integral\<^sup>N M (?g i))" unfolding f_def
   234     using g_in_G \<open>incseq ?g\<close> by (auto intro!: nn_integral_monotone_convergence_SUP simp: G_def)
   235   also have "\<dots> = ?y"
   236   proof (rule antisym)
   237     show "(SUP i. integral\<^sup>N M (?g i)) \<le> ?y"
   238       using g_in_G by (auto intro: SUP_mono)
   239     show "?y \<le> (SUP i. integral\<^sup>N M (?g i))" unfolding y_eq
   240       by (auto intro!: SUP_mono nn_integral_mono Max_ge)
   241   qed
   242   finally have int_f_eq_y: "integral\<^sup>N M f = ?y" .
   244   have upper_bound: "\<forall>A\<in>sets M. N A \<le> density M f A"
   245   proof (rule ccontr)
   246     assume "\<not> ?thesis"
   247     then obtain A where A[measurable]: "A \<in> sets M" and f_less_N: "density M f A < N A"
   248       by (auto simp: not_le)
   249     then have pos_A: "0 < M A"
   250       using \<open>absolutely_continuous M N\<close>[THEN absolutely_continuousD, OF A]
   251       by (auto simp: zero_less_iff_neq_zero)
   253     define b where "b = (N A - density M f A) / M A / 2"
   254     with f_less_N pos_A have "0 < b" "b \<noteq> top"
   255       by (auto intro!: diff_gr0_ennreal simp: zero_less_iff_neq_zero diff_eq_0_iff_ennreal ennreal_divide_eq_top_iff)
   257     let ?f = "\<lambda>x. f x + b"
   258     have "nn_integral M f \<noteq> top"
   259       using `f \<in> G`[THEN G_D, of "space M"] by (auto simp: top_unique cong: nn_integral_cong)
   260     with \<open>b \<noteq> top\<close> interpret Mf: finite_measure "density M ?f"
   261       by (intro finite_measureI)
   262          (auto simp: field_simps mult_indicator_subset ennreal_mult_eq_top_iff
   263                      emeasure_density nn_integral_cmult_indicator nn_integral_add
   264                cong: nn_integral_cong)
   266     from unsigned_Hahn_decomposition[of "density M ?f" N A]
   267     obtain Y where [measurable]: "Y \<in> sets M" and [simp]: "Y \<subseteq> A"
   268        and Y1: "\<And>C. C \<in> sets M \<Longrightarrow> C \<subseteq> Y \<Longrightarrow> density M ?f C \<le> N C"
   269        and Y2: "\<And>C. C \<in> sets M \<Longrightarrow> C \<subseteq> A \<Longrightarrow> C \<inter> Y = {} \<Longrightarrow> N C \<le> density M ?f C"
   270        by auto
   272     let ?f' = "\<lambda>x. f x + b * indicator Y x"
   273     have "M Y \<noteq> 0"
   274     proof
   275       assume "M Y = 0"
   276       then have "N Y = 0"
   277         using \<open>absolutely_continuous M N\<close>[THEN absolutely_continuousD, of Y] by auto
   278       then have "N A = N (A - Y)"
   279         by (subst emeasure_Diff) auto
   280       also have "\<dots> \<le> density M ?f (A - Y)"
   281         by (rule Y2) auto
   282       also have "\<dots> \<le> density M ?f A - density M ?f Y"
   283         by (subst emeasure_Diff) auto
   284       also have "\<dots> \<le> density M ?f A - 0"
   285         by (intro ennreal_minus_mono) auto
   286       also have "density M ?f A = b * M A + density M f A"
   287         by (simp add: emeasure_density field_simps mult_indicator_subset nn_integral_add nn_integral_cmult_indicator)
   288       also have "\<dots> < N A"
   289         using f_less_N pos_A
   290         by (cases "density M f A"; cases "M A"; cases "N A")
   291            (auto simp: b_def ennreal_less_iff ennreal_minus divide_ennreal ennreal_numeral[symmetric]
   292                        ennreal_plus[symmetric] ennreal_mult[symmetric] field_simps
   293                     simp del: ennreal_numeral ennreal_plus)
   294       finally show False
   295         by simp
   296     qed
   297     then have "nn_integral M f < nn_integral M ?f'"
   298       using \<open>0 < b\<close> \<open>nn_integral M f \<noteq> top\<close>
   299       by (simp add: nn_integral_add nn_integral_cmult_indicator ennreal_zero_less_mult_iff zero_less_iff_neq_zero)
   300     moreover
   301     have "?f' \<in> G"
   302       unfolding G_def
   303     proof safe
   304       fix X assume [measurable]: "X \<in> sets M"
   305       have "(\<integral>\<^sup>+ x. ?f' x * indicator X x \<partial>M) = density M f (X - Y) + density M ?f (X \<inter> Y)"
   306         by (auto simp add: emeasure_density nn_integral_add[symmetric] split: split_indicator intro!: nn_integral_cong)
   307       also have "\<dots> \<le> N (X - Y) + N (X \<inter> Y)"
   308         using G_D[OF \<open>f \<in> G\<close>] by (intro add_mono Y1) (auto simp: emeasure_density)
   309       also have "\<dots> = N X"
   310         by (subst plus_emeasure) (auto intro!: arg_cong2[where f=emeasure])
   311       finally show "(\<integral>\<^sup>+ x. ?f' x * indicator X x \<partial>M) \<le> N X" .
   312     qed simp
   313     then have "nn_integral M ?f' \<le> ?y"
   314       by (rule SUP_upper)
   315     ultimately show False
   316       by (simp add: int_f_eq_y)
   317   qed
   318   show ?thesis
   319   proof (intro bexI[of _ f] measure_eqI conjI antisym)
   320     fix A assume "A \<in> sets (density M f)" then show "emeasure (density M f) A \<le> emeasure N A"
   321       by (auto simp: emeasure_density intro!: G_D[OF \<open>f \<in> G\<close>])
   322   next
   323     fix A assume A: "A \<in> sets (density M f)" then show "emeasure N A \<le> emeasure (density M f) A"
   324       using upper_bound by auto
   325   qed auto
   326 qed
   328 lemma (in finite_measure) split_space_into_finite_sets_and_rest:
   329   assumes ac: "absolutely_continuous M N" and sets_eq[simp]: "sets N = sets M"
   330   shows "\<exists>B::nat\<Rightarrow>'a set. disjoint_family B \<and> range B \<subseteq> sets M \<and> (\<forall>i. N (B i) \<noteq> \<infinity>) \<and>
   331     (\<forall>A\<in>sets M. A \<inter> (\<Union>i. B i) = {} \<longrightarrow> (emeasure M A = 0 \<and> N A = 0) \<or> (emeasure M A > 0 \<and> N A = \<infinity>))"
   332 proof -
   333   let ?Q = "{Q\<in>sets M. N Q \<noteq> \<infinity>}"
   334   let ?a = "SUP Q:?Q. emeasure M Q"
   335   have "{} \<in> ?Q" by auto
   336   then have Q_not_empty: "?Q \<noteq> {}" by blast
   337   have "?a \<le> emeasure M (space M)" using sets.sets_into_space
   338     by (auto intro!: SUP_least emeasure_mono)
   339   then have "?a \<noteq> \<infinity>"
   340     using finite_emeasure_space
   341     by (auto simp: less_top[symmetric] top_unique simp del: SUP_eq_top_iff Sup_eq_top_iff)
   342   from ennreal_SUP_countable_SUP [OF Q_not_empty, of "emeasure M"]
   343   obtain Q'' where "range Q'' \<subseteq> emeasure M ` ?Q" and a: "?a = (SUP i::nat. Q'' i)"
   344     by auto
   345   then have "\<forall>i. \<exists>Q'. Q'' i = emeasure M Q' \<and> Q' \<in> ?Q" by auto
   346   from choice[OF this] obtain Q' where Q': "\<And>i. Q'' i = emeasure M (Q' i)" "\<And>i. Q' i \<in> ?Q"
   347     by auto
   348   then have a_Lim: "?a = (SUP i::nat. emeasure M (Q' i))" using a by simp
   349   let ?O = "\<lambda>n. \<Union>i\<le>n. Q' i"
   350   have Union: "(SUP i. emeasure M (?O i)) = emeasure M (\<Union>i. ?O i)"
   351   proof (rule SUP_emeasure_incseq[of ?O])
   352     show "range ?O \<subseteq> sets M" using Q' by auto
   353     show "incseq ?O" by (fastforce intro!: incseq_SucI)
   354   qed
   355   have Q'_sets[measurable]: "\<And>i. Q' i \<in> sets M" using Q' by auto
   356   have O_sets: "\<And>i. ?O i \<in> sets M" using Q' by auto
   357   then have O_in_G: "\<And>i. ?O i \<in> ?Q"
   358   proof (safe del: notI)
   359     fix i have "Q' ` {..i} \<subseteq> sets M" using Q' by auto
   360     then have "N (?O i) \<le> (\<Sum>i\<le>i. N (Q' i))"
   361       by (simp add: emeasure_subadditive_finite)
   362     also have "\<dots> < \<infinity>" using Q' by (simp add: less_top)
   363     finally show "N (?O i) \<noteq> \<infinity>" by simp
   364   qed auto
   365   have O_mono: "\<And>n. ?O n \<subseteq> ?O (Suc n)" by fastforce
   366   have a_eq: "?a = emeasure M (\<Union>i. ?O i)" unfolding Union[symmetric]
   367   proof (rule antisym)
   368     show "?a \<le> (SUP i. emeasure M (?O i))" unfolding a_Lim
   369       using Q' by (auto intro!: SUP_mono emeasure_mono)
   370     show "(SUP i. emeasure M (?O i)) \<le> ?a"
   371     proof (safe intro!: Sup_mono, unfold bex_simps)
   372       fix i
   373       have *: "(\<Union>(Q' ` {..i})) = ?O i" by auto
   374       then show "\<exists>x. (x \<in> sets M \<and> N x \<noteq> \<infinity>) \<and>
   375         emeasure M (\<Union>(Q' ` {..i})) \<le> emeasure M x"
   376         using O_in_G[of i] by (auto intro!: exI[of _ "?O i"])
   377     qed
   378   qed
   379   let ?O_0 = "(\<Union>i. ?O i)"
   380   have "?O_0 \<in> sets M" using Q' by auto
   381   have "disjointed Q' i \<in> sets M" for i
   382     using sets.range_disjointed_sets[of Q' M] using Q'_sets by (auto simp: subset_eq)
   383   note Q_sets = this
   384   show ?thesis
   385   proof (intro bexI exI conjI ballI impI allI)
   386     show "disjoint_family (disjointed Q')"
   387       by (rule disjoint_family_disjointed)
   388     show "range (disjointed Q') \<subseteq> sets M"
   389       using Q'_sets by (intro sets.range_disjointed_sets) auto
   390     { fix A assume A: "A \<in> sets M" "A \<inter> (\<Union>i. disjointed Q' i) = {}"
   391       then have A1: "A \<inter> (\<Union>i. Q' i) = {}"
   392         unfolding UN_disjointed_eq by auto
   393       show "emeasure M A = 0 \<and> N A = 0 \<or> 0 < emeasure M A \<and> N A = \<infinity>"
   394       proof (rule disjCI, simp)
   395         assume *: "emeasure M A = 0 \<or> N A \<noteq> top"
   396         show "emeasure M A = 0 \<and> N A = 0"
   397         proof (cases "emeasure M A = 0")
   398           case True
   399           with ac A have "N A = 0"
   400             unfolding absolutely_continuous_def by auto
   401           with True show ?thesis by simp
   402         next
   403           case False
   404           with * have "N A \<noteq> \<infinity>" by auto
   405           with A have "emeasure M ?O_0 + emeasure M A = emeasure M (?O_0 \<union> A)"
   406             using Q' A1 by (auto intro!: plus_emeasure simp: set_eq_iff)
   407           also have "\<dots> = (SUP i. emeasure M (?O i \<union> A))"
   408           proof (rule SUP_emeasure_incseq[of "\<lambda>i. ?O i \<union> A", symmetric, simplified])
   409             show "range (\<lambda>i. ?O i \<union> A) \<subseteq> sets M"
   410               using \<open>N A \<noteq> \<infinity>\<close> O_sets A by auto
   411           qed (fastforce intro!: incseq_SucI)
   412           also have "\<dots> \<le> ?a"
   413           proof (safe intro!: SUP_least)
   414             fix i have "?O i \<union> A \<in> ?Q"
   415             proof (safe del: notI)
   416               show "?O i \<union> A \<in> sets M" using O_sets A by auto
   417               from O_in_G[of i] have "N (?O i \<union> A) \<le> N (?O i) + N A"
   418                 using emeasure_subadditive[of "?O i" N A] A O_sets by auto
   419               with O_in_G[of i] show "N (?O i \<union> A) \<noteq> \<infinity>"
   420                 using \<open>N A \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   421             qed
   422             then show "emeasure M (?O i \<union> A) \<le> ?a" by (rule SUP_upper)
   423           qed
   424           finally have "emeasure M A = 0"
   425             unfolding a_eq using measure_nonneg[of M A] by (simp add: emeasure_eq_measure)
   426           with \<open>emeasure M A \<noteq> 0\<close> show ?thesis by auto
   427         qed
   428       qed }
   429     { fix i
   430       have "N (disjointed Q' i) \<le> N (Q' i)"
   431         by (auto intro!: emeasure_mono simp: disjointed_def)
   432       then show "N (disjointed Q' i) \<noteq> \<infinity>"
   433         using Q'(2)[of i] by (auto simp: top_unique) }
   434   qed
   435 qed
   437 lemma (in finite_measure) Radon_Nikodym_finite_measure_infinite:
   438   assumes "absolutely_continuous M N" and sets_eq: "sets N = sets M"
   439   shows "\<exists>f\<in>borel_measurable M. density M f = N"
   440 proof -
   441   from split_space_into_finite_sets_and_rest[OF assms]
   442   obtain Q :: "nat \<Rightarrow> 'a set"
   443     where Q: "disjoint_family Q" "range Q \<subseteq> sets M"
   444     and in_Q0: "\<And>A. A \<in> sets M \<Longrightarrow> A \<inter> (\<Union>i. Q i) = {} \<Longrightarrow> emeasure M A = 0 \<and> N A = 0 \<or> 0 < emeasure M A \<and> N A = \<infinity>"
   445     and Q_fin: "\<And>i. N (Q i) \<noteq> \<infinity>" by force
   446   from Q have Q_sets: "\<And>i. Q i \<in> sets M" by auto
   447   let ?N = "\<lambda>i. density N (indicator (Q i))" and ?M = "\<lambda>i. density M (indicator (Q i))"
   448   have "\<forall>i. \<exists>f\<in>borel_measurable (?M i). density (?M i) f = ?N i"
   449   proof (intro allI finite_measure.Radon_Nikodym_finite_measure)
   450     fix i
   451     from Q show "finite_measure (?M i)"
   452       by (auto intro!: finite_measureI cong: nn_integral_cong
   453                simp add: emeasure_density subset_eq sets_eq)
   454     from Q have "emeasure (?N i) (space N) = emeasure N (Q i)"
   455       by (simp add: sets_eq[symmetric] emeasure_density subset_eq cong: nn_integral_cong)
   456     with Q_fin show "finite_measure (?N i)"
   457       by (auto intro!: finite_measureI)
   458     show "sets (?N i) = sets (?M i)" by (simp add: sets_eq)
   459     have [measurable]: "\<And>A. A \<in> sets M \<Longrightarrow> A \<in> sets N" by (simp add: sets_eq)
   460     show "absolutely_continuous (?M i) (?N i)"
   461       using \<open>absolutely_continuous M N\<close> \<open>Q i \<in> sets M\<close>
   462       by (auto simp: absolutely_continuous_def null_sets_density_iff sets_eq
   463                intro!: absolutely_continuous_AE[OF sets_eq])
   464   qed
   465   from choice[OF this[unfolded Bex_def]]
   466   obtain f where borel: "\<And>i. f i \<in> borel_measurable M" "\<And>i x. 0 \<le> f i x"
   467     and f_density: "\<And>i. density (?M i) (f i) = ?N i"
   468     by force
   469   { fix A i assume A: "A \<in> sets M"
   470     with Q borel have "(\<integral>\<^sup>+x. f i x * indicator (Q i \<inter> A) x \<partial>M) = emeasure (density (?M i) (f i)) A"
   471       by (auto simp add: emeasure_density nn_integral_density subset_eq
   472                intro!: nn_integral_cong split: split_indicator)
   473     also have "\<dots> = emeasure N (Q i \<inter> A)"
   474       using A Q by (simp add: f_density emeasure_restricted subset_eq sets_eq)
   475     finally have "emeasure N (Q i \<inter> A) = (\<integral>\<^sup>+x. f i x * indicator (Q i \<inter> A) x \<partial>M)" .. }
   476   note integral_eq = this
   477   let ?f = "\<lambda>x. (\<Sum>i. f i x * indicator (Q i) x) + \<infinity> * indicator (space M - (\<Union>i. Q i)) x"
   478   show ?thesis
   479   proof (safe intro!: bexI[of _ ?f])
   480     show "?f \<in> borel_measurable M" using borel Q_sets
   481       by (auto intro!: measurable_If)
   482     show "density M ?f = N"
   483     proof (rule measure_eqI)
   484       fix A assume "A \<in> sets (density M ?f)"
   485       then have "A \<in> sets M" by simp
   486       have Qi: "\<And>i. Q i \<in> sets M" using Q by auto
   487       have [intro,simp]: "\<And>i. (\<lambda>x. f i x * indicator (Q i \<inter> A) x) \<in> borel_measurable M"
   488         "\<And>i. AE x in M. 0 \<le> f i x * indicator (Q i \<inter> A) x"
   489         using borel Qi \<open>A \<in> sets M\<close> by auto
   490       have "(\<integral>\<^sup>+x. ?f x * indicator A x \<partial>M) = (\<integral>\<^sup>+x. (\<Sum>i. f i x * indicator (Q i \<inter> A) x) + \<infinity> * indicator ((space M - (\<Union>i. Q i)) \<inter> A) x \<partial>M)"
   491         using borel by (intro nn_integral_cong) (auto simp: indicator_def)
   492       also have "\<dots> = (\<integral>\<^sup>+x. (\<Sum>i. f i x * indicator (Q i \<inter> A) x) \<partial>M) + \<infinity> * emeasure M ((space M - (\<Union>i. Q i)) \<inter> A)"
   493         using borel Qi \<open>A \<in> sets M\<close>
   494         by (subst nn_integral_add)
   495            (auto simp add: nn_integral_cmult_indicator sets.Int intro!: suminf_0_le)
   496       also have "\<dots> = (\<Sum>i. N (Q i \<inter> A)) + \<infinity> * emeasure M ((space M - (\<Union>i. Q i)) \<inter> A)"
   497         by (subst integral_eq[OF \<open>A \<in> sets M\<close>], subst nn_integral_suminf) auto
   498       finally have "(\<integral>\<^sup>+x. ?f x * indicator A x \<partial>M) = (\<Sum>i. N (Q i \<inter> A)) + \<infinity> * emeasure M ((space M - (\<Union>i. Q i)) \<inter> A)" .
   499       moreover have "(\<Sum>i. N (Q i \<inter> A)) = N ((\<Union>i. Q i) \<inter> A)"
   500         using Q Q_sets \<open>A \<in> sets M\<close>
   501         by (subst suminf_emeasure) (auto simp: disjoint_family_on_def sets_eq)
   502       moreover
   503       have "(space M - (\<Union>x. Q x)) \<inter> A \<inter> (\<Union>x. Q x) = {}"
   504         by auto
   505       then have "\<infinity> * emeasure M ((space M - (\<Union>i. Q i)) \<inter> A) = N ((space M - (\<Union>i. Q i)) \<inter> A)"
   506         using in_Q0[of "(space M - (\<Union>i. Q i)) \<inter> A"] \<open>A \<in> sets M\<close> Q by (auto simp: ennreal_top_mult)
   507       moreover have "(space M - (\<Union>i. Q i)) \<inter> A \<in> sets M" "((\<Union>i. Q i) \<inter> A) \<in> sets M"
   508         using Q_sets \<open>A \<in> sets M\<close> by auto
   509       moreover have "((\<Union>i. Q i) \<inter> A) \<union> ((space M - (\<Union>i. Q i)) \<inter> A) = A" "((\<Union>i. Q i) \<inter> A) \<inter> ((space M - (\<Union>i. Q i)) \<inter> A) = {}"
   510         using \<open>A \<in> sets M\<close> sets.sets_into_space by auto
   511       ultimately have "N A = (\<integral>\<^sup>+x. ?f x * indicator A x \<partial>M)"
   512         using plus_emeasure[of "(\<Union>i. Q i) \<inter> A" N "(space M - (\<Union>i. Q i)) \<inter> A"] by (simp add: sets_eq)
   513       with \<open>A \<in> sets M\<close> borel Q show "emeasure (density M ?f) A = N A"
   514         by (auto simp: subset_eq emeasure_density)
   515     qed (simp add: sets_eq)
   516   qed
   517 qed
   519 lemma (in sigma_finite_measure) Radon_Nikodym:
   520   assumes ac: "absolutely_continuous M N" assumes sets_eq: "sets N = sets M"
   521   shows "\<exists>f \<in> borel_measurable M. density M f = N"
   522 proof -
   523   from Ex_finite_integrable_function
   524   obtain h where finite: "integral\<^sup>N M h \<noteq> \<infinity>" and
   525     borel: "h \<in> borel_measurable M" and
   526     nn: "\<And>x. 0 \<le> h x" and
   527     pos: "\<And>x. x \<in> space M \<Longrightarrow> 0 < h x" and
   528     "\<And>x. x \<in> space M \<Longrightarrow> h x < \<infinity>" by auto
   529   let ?T = "\<lambda>A. (\<integral>\<^sup>+x. h x * indicator A x \<partial>M)"
   530   let ?MT = "density M h"
   531   from borel finite nn interpret T: finite_measure ?MT
   532     by (auto intro!: finite_measureI cong: nn_integral_cong simp: emeasure_density)
   533   have "absolutely_continuous ?MT N" "sets N = sets ?MT"
   534   proof (unfold absolutely_continuous_def, safe)
   535     fix A assume "A \<in> null_sets ?MT"
   536     with borel have "A \<in> sets M" "AE x in M. x \<in> A \<longrightarrow> h x \<le> 0"
   537       by (auto simp add: null_sets_density_iff)
   538     with pos sets.sets_into_space have "AE x in M. x \<notin> A"
   539       by (elim eventually_mono) (auto simp: not_le[symmetric])
   540     then have "A \<in> null_sets M"
   541       using \<open>A \<in> sets M\<close> by (simp add: AE_iff_null_sets)
   542     with ac show "A \<in> null_sets N"
   543       by (auto simp: absolutely_continuous_def)
   544   qed (auto simp add: sets_eq)
   545   from T.Radon_Nikodym_finite_measure_infinite[OF this]
   546   obtain f where f_borel: "f \<in> borel_measurable M" "density ?MT f = N" by auto
   547   with nn borel show ?thesis
   548     by (auto intro!: bexI[of _ "\<lambda>x. h x * f x"] simp: density_density_eq)
   549 qed
   551 subsection \<open>Uniqueness of densities\<close>
   553 lemma finite_density_unique:
   554   assumes borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   555   assumes pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> g x"
   556   and fin: "integral\<^sup>N M f \<noteq> \<infinity>"
   557   shows "density M f = density M g \<longleftrightarrow> (AE x in M. f x = g x)"
   558 proof (intro iffI ballI)
   559   fix A assume eq: "AE x in M. f x = g x"
   560   with borel show "density M f = density M g"
   561     by (auto intro: density_cong)
   562 next
   563   let ?P = "\<lambda>f A. \<integral>\<^sup>+ x. f x * indicator A x \<partial>M"
   564   assume "density M f = density M g"
   565   with borel have eq: "\<forall>A\<in>sets M. ?P f A = ?P g A"
   566     by (simp add: emeasure_density[symmetric])
   567   from this[THEN bspec, OF] fin
   568   have g_fin: "integral\<^sup>N M g \<noteq> \<infinity>" by (simp cong: nn_integral_cong)
   569   { fix f g assume borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   570       and pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> g x"
   571       and g_fin: "integral\<^sup>N M g \<noteq> \<infinity>" and eq: "\<forall>A\<in>sets M. ?P f A = ?P g A"
   572     let ?N = "{x\<in>space M. g x < f x}"
   573     have N: "?N \<in> sets M" using borel by simp
   574     have "?P g ?N \<le> integral\<^sup>N M g" using pos
   575       by (intro nn_integral_mono_AE) (auto split: split_indicator)
   576     then have Pg_fin: "?P g ?N \<noteq> \<infinity>" using g_fin by (auto simp: top_unique)
   577     have "?P (\<lambda>x. (f x - g x)) ?N = (\<integral>\<^sup>+x. f x * indicator ?N x - g x * indicator ?N x \<partial>M)"
   578       by (auto intro!: nn_integral_cong simp: indicator_def)
   579     also have "\<dots> = ?P f ?N - ?P g ?N"
   580     proof (rule nn_integral_diff)
   581       show "(\<lambda>x. f x * indicator ?N x) \<in> borel_measurable M" "(\<lambda>x. g x * indicator ?N x) \<in> borel_measurable M"
   582         using borel N by auto
   583       show "AE x in M. g x * indicator ?N x \<le> f x * indicator ?N x"
   584         using pos by (auto split: split_indicator)
   585     qed fact
   586     also have "\<dots> = 0"
   587       unfolding eq[THEN bspec, OF N] using Pg_fin by auto
   588     finally have "AE x in M. f x \<le> g x"
   589       using pos borel nn_integral_PInf_AE[OF borel(2) g_fin]
   590       by (subst (asm) nn_integral_0_iff_AE)
   591          (auto split: split_indicator simp: not_less ennreal_minus_eq_0) }
   592   from this[OF borel pos g_fin eq] this[OF borel(2,1) pos(2,1) fin] eq
   593   show "AE x in M. f x = g x" by auto
   594 qed
   596 lemma (in finite_measure) density_unique_finite_measure:
   597   assumes borel: "f \<in> borel_measurable M" "f' \<in> borel_measurable M"
   598   assumes pos: "AE x in M. 0 \<le> f x" "AE x in M. 0 \<le> f' x"
   599   assumes f: "\<And>A. A \<in> sets M \<Longrightarrow> (\<integral>\<^sup>+x. f x * indicator A x \<partial>M) = (\<integral>\<^sup>+x. f' x * indicator A x \<partial>M)"
   600     (is "\<And>A. A \<in> sets M \<Longrightarrow> ?P f A = ?P f' A")
   601   shows "AE x in M. f x = f' x"
   602 proof -
   603   let ?D = "\<lambda>f. density M f"
   604   let ?N = "\<lambda>A. ?P f A" and ?N' = "\<lambda>A. ?P f' A"
   605   let ?f = "\<lambda>A x. f x * indicator A x" and ?f' = "\<lambda>A x. f' x * indicator A x"
   607   have ac: "absolutely_continuous M (density M f)" "sets (density M f) = sets M"
   608     using borel by (auto intro!: absolutely_continuousI_density)
   609   from split_space_into_finite_sets_and_rest[OF this]
   610   obtain Q :: "nat \<Rightarrow> 'a set"
   611     where Q: "disjoint_family Q" "range Q \<subseteq> sets M"
   612     and in_Q0: "\<And>A. A \<in> sets M \<Longrightarrow> A \<inter> (\<Union>i. Q i) = {} \<Longrightarrow> emeasure M A = 0 \<and> ?D f A = 0 \<or> 0 < emeasure M A \<and> ?D f A = \<infinity>"
   613     and Q_fin: "\<And>i. ?D f (Q i) \<noteq> \<infinity>" by force
   614   with borel pos have in_Q0: "\<And>A. A \<in> sets M \<Longrightarrow> A \<inter> (\<Union>i. Q i) = {} \<Longrightarrow> emeasure M A = 0 \<and> ?N A = 0 \<or> 0 < emeasure M A \<and> ?N A = \<infinity>"
   615     and Q_fin: "\<And>i. ?N (Q i) \<noteq> \<infinity>" by (auto simp: emeasure_density subset_eq)
   617   from Q have Q_sets[measurable]: "\<And>i. Q i \<in> sets M" by auto
   618   let ?D = "{x\<in>space M. f x \<noteq> f' x}"
   619   have "?D \<in> sets M" using borel by auto
   620   have *: "\<And>i x A. \<And>y::ennreal. y * indicator (Q i) x * indicator A x = y * indicator (Q i \<inter> A) x"
   621     unfolding indicator_def by auto
   622   have "\<forall>i. AE x in M. ?f (Q i) x = ?f' (Q i) x" using borel Q_fin Q pos
   623     by (intro finite_density_unique[THEN iffD1] allI)
   624        (auto intro!: f measure_eqI simp: emeasure_density * subset_eq)
   625   moreover have "AE x in M. ?f (space M - (\<Union>i. Q i)) x = ?f' (space M - (\<Union>i. Q i)) x"
   626   proof (rule AE_I')
   627     { fix f :: "'a \<Rightarrow> ennreal" assume borel: "f \<in> borel_measurable M"
   628         and eq: "\<And>A. A \<in> sets M \<Longrightarrow> ?N A = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   629       let ?A = "\<lambda>i. (space M - (\<Union>i. Q i)) \<inter> {x \<in> space M. f x < (i::nat)}"
   630       have "(\<Union>i. ?A i) \<in> null_sets M"
   631       proof (rule null_sets_UN)
   632         fix i ::nat have "?A i \<in> sets M"
   633           using borel by auto
   634         have "?N (?A i) \<le> (\<integral>\<^sup>+x. (i::ennreal) * indicator (?A i) x \<partial>M)"
   635           unfolding eq[OF \<open>?A i \<in> sets M\<close>]
   636           by (auto intro!: nn_integral_mono simp: indicator_def)
   637         also have "\<dots> = i * emeasure M (?A i)"
   638           using \<open>?A i \<in> sets M\<close> by (auto intro!: nn_integral_cmult_indicator)
   639         also have "\<dots> < \<infinity>" using emeasure_real[of "?A i"] by (auto simp: ennreal_mult_less_top of_nat_less_top)
   640         finally have "?N (?A i) \<noteq> \<infinity>" by simp
   641         then show "?A i \<in> null_sets M" using in_Q0[OF \<open>?A i \<in> sets M\<close>] \<open>?A i \<in> sets M\<close> by auto
   642       qed
   643       also have "(\<Union>i. ?A i) = (space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f x \<noteq> \<infinity>}"
   644         by (auto simp: ennreal_Ex_less_of_nat less_top[symmetric])
   645       finally have "(space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f x \<noteq> \<infinity>} \<in> null_sets M" by simp }
   646     from this[OF borel(1) refl] this[OF borel(2) f]
   647     have "(space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f x \<noteq> \<infinity>} \<in> null_sets M" "(space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f' x \<noteq> \<infinity>} \<in> null_sets M" by simp_all
   648     then show "((space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f x \<noteq> \<infinity>}) \<union> ((space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f' x \<noteq> \<infinity>}) \<in> null_sets M" by (rule null_sets.Un)
   649     show "{x \<in> space M. ?f (space M - (\<Union>i. Q i)) x \<noteq> ?f' (space M - (\<Union>i. Q i)) x} \<subseteq>
   650       ((space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f x \<noteq> \<infinity>}) \<union> ((space M - (\<Union>i. Q i)) \<inter> {x\<in>space M. f' x \<noteq> \<infinity>})" by (auto simp: indicator_def)
   651   qed
   652   moreover have "AE x in M. (?f (space M - (\<Union>i. Q i)) x = ?f' (space M - (\<Union>i. Q i)) x) \<longrightarrow> (\<forall>i. ?f (Q i) x = ?f' (Q i) x) \<longrightarrow>
   653     ?f (space M) x = ?f' (space M) x"
   654     by (auto simp: indicator_def)
   655   ultimately have "AE x in M. ?f (space M) x = ?f' (space M) x"
   656     unfolding AE_all_countable[symmetric]
   657     by eventually_elim (auto split: if_split_asm simp: indicator_def)
   658   then show "AE x in M. f x = f' x" by auto
   659 qed
   661 lemma (in sigma_finite_measure) density_unique:
   662   assumes f: "f \<in> borel_measurable M"
   663   assumes f': "f' \<in> borel_measurable M"
   664   assumes density_eq: "density M f = density M f'"
   665   shows "AE x in M. f x = f' x"
   666 proof -
   667   obtain h where h_borel: "h \<in> borel_measurable M"
   668     and fin: "integral\<^sup>N M h \<noteq> \<infinity>" and pos: "\<And>x. x \<in> space M \<Longrightarrow> 0 < h x \<and> h x < \<infinity>" "\<And>x. 0 \<le> h x"
   669     using Ex_finite_integrable_function by auto
   670   then have h_nn: "AE x in M. 0 \<le> h x" by auto
   671   let ?H = "density M h"
   672   interpret h: finite_measure ?H
   673     using fin h_borel pos
   674     by (intro finite_measureI) (simp cong: nn_integral_cong emeasure_density add: fin)
   675   let ?fM = "density M f"
   676   let ?f'M = "density M f'"
   677   { fix A assume "A \<in> sets M"
   678     then have "{x \<in> space M. h x * indicator A x \<noteq> 0} = A"
   679       using pos(1) sets.sets_into_space by (force simp: indicator_def)
   680     then have "(\<integral>\<^sup>+x. h x * indicator A x \<partial>M) = 0 \<longleftrightarrow> A \<in> null_sets M"
   681       using h_borel \<open>A \<in> sets M\<close> h_nn by (subst nn_integral_0_iff) auto }
   682   note h_null_sets = this
   683   { fix A assume "A \<in> sets M"
   684     have "(\<integral>\<^sup>+x. f x * (h x * indicator A x) \<partial>M) = (\<integral>\<^sup>+x. h x * indicator A x \<partial>?fM)"
   685       using \<open>A \<in> sets M\<close> h_borel h_nn f f'
   686       by (intro nn_integral_density[symmetric]) auto
   687     also have "\<dots> = (\<integral>\<^sup>+x. h x * indicator A x \<partial>?f'M)"
   688       by (simp_all add: density_eq)
   689     also have "\<dots> = (\<integral>\<^sup>+x. f' x * (h x * indicator A x) \<partial>M)"
   690       using \<open>A \<in> sets M\<close> h_borel h_nn f f'
   691       by (intro nn_integral_density) auto
   692     finally have "(\<integral>\<^sup>+x. h x * (f x * indicator A x) \<partial>M) = (\<integral>\<^sup>+x. h x * (f' x * indicator A x) \<partial>M)"
   693       by (simp add: ac_simps)
   694     then have "(\<integral>\<^sup>+x. (f x * indicator A x) \<partial>?H) = (\<integral>\<^sup>+x. (f' x * indicator A x) \<partial>?H)"
   695       using \<open>A \<in> sets M\<close> h_borel h_nn f f'
   696       by (subst (asm) (1 2) nn_integral_density[symmetric]) auto }
   697   then have "AE x in ?H. f x = f' x" using h_borel h_nn f f'
   698     by (intro h.density_unique_finite_measure absolutely_continuous_AE[of M]) auto
   699   with AE_space[of M] pos show "AE x in M. f x = f' x"
   700     unfolding AE_density[OF h_borel] by auto
   701 qed
   703 lemma (in sigma_finite_measure) density_unique_iff:
   704   assumes f: "f \<in> borel_measurable M" and f': "f' \<in> borel_measurable M"
   705   shows "density M f = density M f' \<longleftrightarrow> (AE x in M. f x = f' x)"
   706   using density_unique[OF assms] density_cong[OF f f'] by auto
   708 lemma sigma_finite_density_unique:
   709   assumes borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   710   and fin: "sigma_finite_measure (density M f)"
   711   shows "density M f = density M g \<longleftrightarrow> (AE x in M. f x = g x)"
   712 proof
   713   assume "AE x in M. f x = g x" with borel show "density M f = density M g"
   714     by (auto intro: density_cong)
   715 next
   716   assume eq: "density M f = density M g"
   717   interpret f: sigma_finite_measure "density M f" by fact
   718   from f.sigma_finite_incseq guess A . note cover = this
   720   have "AE x in M. \<forall>i. x \<in> A i \<longrightarrow> f x = g x"
   721     unfolding AE_all_countable
   722   proof
   723     fix i
   724     have "density (density M f) (indicator (A i)) = density (density M g) (indicator (A i))"
   725       unfolding eq ..
   726     moreover have "(\<integral>\<^sup>+x. f x * indicator (A i) x \<partial>M) \<noteq> \<infinity>"
   727       using cover(1) cover(3)[of i] borel by (auto simp: emeasure_density subset_eq)
   728     ultimately have "AE x in M. f x * indicator (A i) x = g x * indicator (A i) x"
   729       using borel cover(1)
   730       by (intro finite_density_unique[THEN iffD1]) (auto simp: density_density_eq subset_eq)
   731     then show "AE x in M. x \<in> A i \<longrightarrow> f x = g x"
   732       by auto
   733   qed
   734   with AE_space show "AE x in M. f x = g x"
   735     apply eventually_elim
   736     using cover(2)[symmetric]
   737     apply auto
   738     done
   739 qed
   741 lemma (in sigma_finite_measure) sigma_finite_iff_density_finite':
   742   assumes f: "f \<in> borel_measurable M"
   743   shows "sigma_finite_measure (density M f) \<longleftrightarrow> (AE x in M. f x \<noteq> \<infinity>)"
   744     (is "sigma_finite_measure ?N \<longleftrightarrow> _")
   745 proof
   746   assume "sigma_finite_measure ?N"
   747   then interpret N: sigma_finite_measure ?N .
   748   from N.Ex_finite_integrable_function obtain h where
   749     h: "h \<in> borel_measurable M" "integral\<^sup>N ?N h \<noteq> \<infinity>" and
   750     fin: "\<forall>x\<in>space M. 0 < h x \<and> h x < \<infinity>"
   751     by auto
   752   have "AE x in M. f x * h x \<noteq> \<infinity>"
   753   proof (rule AE_I')
   754     have "integral\<^sup>N ?N h = (\<integral>\<^sup>+x. f x * h x \<partial>M)"
   755       using f h by (auto intro!: nn_integral_density)
   756     then have "(\<integral>\<^sup>+x. f x * h x \<partial>M) \<noteq> \<infinity>"
   757       using h(2) by simp
   758     then show "(\<lambda>x. f x * h x) -` {\<infinity>} \<inter> space M \<in> null_sets M"
   759       using f h(1) by (auto intro!: nn_integral_PInf[unfolded infinity_ennreal_def] borel_measurable_vimage)
   760   qed auto
   761   then show "AE x in M. f x \<noteq> \<infinity>"
   762     using fin by (auto elim!: AE_Ball_mp simp: less_top ennreal_mult_less_top)
   763 next
   764   assume AE: "AE x in M. f x \<noteq> \<infinity>"
   765   from sigma_finite guess Q . note Q = this
   766   define A where "A i =
   767     f -` (case i of 0 \<Rightarrow> {\<infinity>} | Suc n \<Rightarrow> {.. ennreal(of_nat (Suc n))}) \<inter> space M" for i
   768   { fix i j have "A i \<inter> Q j \<in> sets M"
   769     unfolding A_def using f Q
   770     apply (rule_tac sets.Int)
   771     by (cases i) (auto intro: measurable_sets[OF f(1)]) }
   772   note A_in_sets = this
   774   show "sigma_finite_measure ?N"
   775   proof (standard, intro exI conjI ballI)
   776     show "countable (range (\<lambda>(i, j). A i \<inter> Q j))"
   777       by auto
   778     show "range (\<lambda>(i, j). A i \<inter> Q j) \<subseteq> sets (density M f)"
   779       using A_in_sets by auto
   780   next
   781     have "\<Union>range (\<lambda>(i, j). A i \<inter> Q j) = (\<Union>i j. A i \<inter> Q j)"
   782       by auto
   783     also have "\<dots> = (\<Union>i. A i) \<inter> space M" using Q by auto
   784     also have "(\<Union>i. A i) = space M"
   785     proof safe
   786       fix x assume x: "x \<in> space M"
   787       show "x \<in> (\<Union>i. A i)"
   788       proof (cases "f x" rule: ennreal_cases)
   789         case top with x show ?thesis unfolding A_def by (auto intro: exI[of _ 0])
   790       next
   791         case (real r)
   792         with ennreal_Ex_less_of_nat[of "f x"] obtain n :: nat where "f x < n"
   793           by auto
   794         also have "n < (Suc n :: ennreal)"
   795           by simp
   796         finally show ?thesis
   797           using x real by (auto simp: A_def ennreal_of_nat_eq_real_of_nat intro!: exI[of _ "Suc n"])
   798       qed
   799     qed (auto simp: A_def)
   800     finally show "\<Union>range (\<lambda>(i, j). A i \<inter> Q j) = space ?N" by simp
   801   next
   802     fix X assume "X \<in> range (\<lambda>(i, j). A i \<inter> Q j)"
   803     then obtain i j where [simp]:"X = A i \<inter> Q j" by auto
   804     have "(\<integral>\<^sup>+x. f x * indicator (A i \<inter> Q j) x \<partial>M) \<noteq> \<infinity>"
   805     proof (cases i)
   806       case 0
   807       have "AE x in M. f x * indicator (A i \<inter> Q j) x = 0"
   808         using AE by (auto simp: A_def \<open>i = 0\<close>)
   809       from nn_integral_cong_AE[OF this] show ?thesis by simp
   810     next
   811       case (Suc n)
   812       then have "(\<integral>\<^sup>+x. f x * indicator (A i \<inter> Q j) x \<partial>M) \<le>
   813         (\<integral>\<^sup>+x. (Suc n :: ennreal) * indicator (Q j) x \<partial>M)"
   814         by (auto intro!: nn_integral_mono simp: indicator_def A_def ennreal_of_nat_eq_real_of_nat)
   815       also have "\<dots> = Suc n * emeasure M (Q j)"
   816         using Q by (auto intro!: nn_integral_cmult_indicator)
   817       also have "\<dots> < \<infinity>"
   818         using Q by (auto simp: ennreal_mult_less_top less_top of_nat_less_top)
   819       finally show ?thesis by simp
   820     qed
   821     then show "emeasure ?N X \<noteq> \<infinity>"
   822       using A_in_sets Q f by (auto simp: emeasure_density)
   823   qed
   824 qed
   826 lemma (in sigma_finite_measure) sigma_finite_iff_density_finite:
   827   "f \<in> borel_measurable M \<Longrightarrow> sigma_finite_measure (density M f) \<longleftrightarrow> (AE x in M. f x \<noteq> \<infinity>)"
   828   by (subst sigma_finite_iff_density_finite')
   829      (auto simp: max_def intro!: measurable_If)
   831 subsection \<open>Radon-Nikodym derivative\<close>
   833 definition RN_deriv :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a \<Rightarrow> ennreal" where
   834   "RN_deriv M N =
   835     (if \<exists>f. f \<in> borel_measurable M \<and> density M f = N
   836        then SOME f. f \<in> borel_measurable M \<and> density M f = N
   837        else (\<lambda>_. 0))"
   839 lemma RN_derivI:
   840   assumes "f \<in> borel_measurable M" "density M f = N"
   841   shows "density M (RN_deriv M N) = N"
   842 proof -
   843   have *: "\<exists>f. f \<in> borel_measurable M \<and> density M f = N"
   844     using assms by auto
   845   then have "density M (SOME f. f \<in> borel_measurable M \<and> density M f = N) = N"
   846     by (rule someI2_ex) auto
   847   with * show ?thesis
   848     by (auto simp: RN_deriv_def)
   849 qed
   851 lemma borel_measurable_RN_deriv[measurable]: "RN_deriv M N \<in> borel_measurable M"
   852 proof -
   853   { assume ex: "\<exists>f. f \<in> borel_measurable M \<and> density M f = N"
   854     have 1: "(SOME f. f \<in> borel_measurable M \<and> density M f = N) \<in> borel_measurable M"
   855       using ex by (rule someI2_ex) auto }
   856   from this show ?thesis
   857     by (auto simp: RN_deriv_def)
   858 qed
   860 lemma density_RN_deriv_density:
   861   assumes f: "f \<in> borel_measurable M"
   862   shows "density M (RN_deriv M (density M f)) = density M f"
   863   by (rule RN_derivI[OF f]) simp
   865 lemma (in sigma_finite_measure) density_RN_deriv:
   866   "absolutely_continuous M N \<Longrightarrow> sets N = sets M \<Longrightarrow> density M (RN_deriv M N) = N"
   867   by (metis RN_derivI Radon_Nikodym)
   869 lemma (in sigma_finite_measure) RN_deriv_nn_integral:
   870   assumes N: "absolutely_continuous M N" "sets N = sets M"
   871     and f: "f \<in> borel_measurable M"
   872   shows "integral\<^sup>N N f = (\<integral>\<^sup>+x. RN_deriv M N x * f x \<partial>M)"
   873 proof -
   874   have "integral\<^sup>N N f = integral\<^sup>N (density M (RN_deriv M N)) f"
   875     using N by (simp add: density_RN_deriv)
   876   also have "\<dots> = (\<integral>\<^sup>+x. RN_deriv M N x * f x \<partial>M)"
   877     using f by (simp add: nn_integral_density)
   878   finally show ?thesis by simp
   879 qed
   881 lemma null_setsD_AE: "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
   882   using AE_iff_null_sets[of N M] by auto
   884 lemma (in sigma_finite_measure) RN_deriv_unique:
   885   assumes f: "f \<in> borel_measurable M"
   886   and eq: "density M f = N"
   887   shows "AE x in M. f x = RN_deriv M N x"
   888   unfolding eq[symmetric]
   889   by (intro density_unique_iff[THEN iffD1] f borel_measurable_RN_deriv
   890             density_RN_deriv_density[symmetric])
   892 lemma RN_deriv_unique_sigma_finite:
   893   assumes f: "f \<in> borel_measurable M"
   894   and eq: "density M f = N" and fin: "sigma_finite_measure N"
   895   shows "AE x in M. f x = RN_deriv M N x"
   896   using fin unfolding eq[symmetric]
   897   by (intro sigma_finite_density_unique[THEN iffD1] f borel_measurable_RN_deriv
   898             density_RN_deriv_density[symmetric])
   900 lemma (in sigma_finite_measure) RN_deriv_distr:
   901   fixes T :: "'a \<Rightarrow> 'b"
   902   assumes T: "T \<in> measurable M M'" and T': "T' \<in> measurable M' M"
   903     and inv: "\<forall>x\<in>space M. T' (T x) = x"
   904   and ac[simp]: "absolutely_continuous (distr M M' T) (distr N M' T)"
   905   and N: "sets N = sets M"
   906   shows "AE x in M. RN_deriv (distr M M' T) (distr N M' T) (T x) = RN_deriv M N x"
   907 proof (rule RN_deriv_unique)
   908   have [simp]: "sets N = sets M" by fact
   909   note sets_eq_imp_space_eq[OF N, simp]
   910   have measurable_N[simp]: "\<And>M'. measurable N M' = measurable M M'" by (auto simp: measurable_def)
   911   { fix A assume "A \<in> sets M"
   912     with inv T T' sets.sets_into_space[OF this]
   913     have "T -` T' -` A \<inter> T -` space M' \<inter> space M = A"
   914       by (auto simp: measurable_def) }
   915   note eq = this[simp]
   916   { fix A assume "A \<in> sets M"
   917     with inv T T' sets.sets_into_space[OF this]
   918     have "(T' \<circ> T) -` A \<inter> space M = A"
   919       by (auto simp: measurable_def) }
   920   note eq2 = this[simp]
   921   let ?M' = "distr M M' T" and ?N' = "distr N M' T"
   922   interpret M': sigma_finite_measure ?M'
   923   proof
   924     from sigma_finite_countable guess F .. note F = this
   925     show "\<exists>A. countable A \<and> A \<subseteq> sets (distr M M' T) \<and> \<Union>A = space (distr M M' T) \<and> (\<forall>a\<in>A. emeasure (distr M M' T) a \<noteq> \<infinity>)"
   926     proof (intro exI conjI ballI)
   927       show *: "(\<lambda>A. T' -` A \<inter> space ?M') ` F \<subseteq> sets ?M'"
   928         using F T' by (auto simp: measurable_def)
   929       show "\<Union>((\<lambda>A. T' -` A \<inter> space ?M')`F) = space ?M'"
   930         using F T'[THEN measurable_space] by (auto simp: set_eq_iff)
   931     next
   932       fix X assume "X \<in> (\<lambda>A. T' -` A \<inter> space ?M')`F"
   933       then obtain A where [simp]: "X = T' -` A \<inter> space ?M'" and "A \<in> F" by auto
   934       have "X \<in> sets M'" using F T' \<open>A\<in>F\<close> by auto
   935       moreover
   936       have Fi: "A \<in> sets M" using F \<open>A\<in>F\<close> by auto
   937       ultimately show "emeasure ?M' X \<noteq> \<infinity>"
   938         using F T T' \<open>A\<in>F\<close> by (simp add: emeasure_distr)
   939     qed (insert F, auto)
   940   qed
   941   have "(RN_deriv ?M' ?N') \<circ> T \<in> borel_measurable M"
   942     using T ac by measurable
   943   then show "(\<lambda>x. RN_deriv ?M' ?N' (T x)) \<in> borel_measurable M"
   944     by (simp add: comp_def)
   946   have "N = distr N M (T' \<circ> T)"
   947     by (subst measure_of_of_measure[of N, symmetric])
   948        (auto simp add: distr_def sets.sigma_sets_eq intro!: measure_of_eq sets.space_closed)
   949   also have "\<dots> = distr (distr N M' T) M T'"
   950     using T T' by (simp add: distr_distr)
   951   also have "\<dots> = distr (density (distr M M' T) (RN_deriv (distr M M' T) (distr N M' T))) M T'"
   952     using ac by (simp add: M'.density_RN_deriv)
   953   also have "\<dots> = density M (RN_deriv (distr M M' T) (distr N M' T) \<circ> T)"
   954     by (simp add: distr_density_distr[OF T T', OF inv])
   955   finally show "density M (\<lambda>x. RN_deriv (distr M M' T) (distr N M' T) (T x)) = N"
   956     by (simp add: comp_def)
   957 qed
   959 lemma (in sigma_finite_measure) RN_deriv_finite:
   960   assumes N: "sigma_finite_measure N" and ac: "absolutely_continuous M N" "sets N = sets M"
   961   shows "AE x in M. RN_deriv M N x \<noteq> \<infinity>"
   962 proof -
   963   interpret N: sigma_finite_measure N by fact
   964   from N show ?thesis
   965     using sigma_finite_iff_density_finite[OF borel_measurable_RN_deriv, of N] density_RN_deriv[OF ac]
   966     by simp
   967 qed
   969 lemma (in sigma_finite_measure)
   970   assumes N: "sigma_finite_measure N" and ac: "absolutely_continuous M N" "sets N = sets M"
   971     and f: "f \<in> borel_measurable M"
   972   shows RN_deriv_integrable: "integrable N f \<longleftrightarrow>
   973       integrable M (\<lambda>x. enn2real (RN_deriv M N x) * f x)" (is ?integrable)
   974     and RN_deriv_integral: "integral\<^sup>L N f = (\<integral>x. enn2real (RN_deriv M N x) * f x \<partial>M)" (is ?integral)
   975 proof -
   976   note ac(2)[simp] and sets_eq_imp_space_eq[OF ac(2), simp]
   977   interpret N: sigma_finite_measure N by fact
   979   have eq: "density M (RN_deriv M N) = density M (\<lambda>x. enn2real (RN_deriv M N x))"
   980   proof (rule density_cong)
   981     from RN_deriv_finite[OF assms(1,2,3)]
   982     show "AE x in M. RN_deriv M N x = ennreal (enn2real (RN_deriv M N x))"
   983       by eventually_elim (auto simp: less_top)
   984   qed (insert ac, auto)
   986   show ?integrable
   987     apply (subst density_RN_deriv[OF ac, symmetric])
   988     unfolding eq
   989     apply (intro integrable_real_density f AE_I2 enn2real_nonneg)
   990     apply (insert ac, auto)
   991     done
   993   show ?integral
   994     apply (subst density_RN_deriv[OF ac, symmetric])
   995     unfolding eq
   996     apply (intro integral_real_density f AE_I2 enn2real_nonneg)
   997     apply (insert ac, auto)
   998     done
   999 qed
  1001 lemma (in sigma_finite_measure) real_RN_deriv:
  1002   assumes "finite_measure N"
  1003   assumes ac: "absolutely_continuous M N" "sets N = sets M"
  1004   obtains D where "D \<in> borel_measurable M"
  1005     and "AE x in M. RN_deriv M N x = ennreal (D x)"
  1006     and "AE x in N. 0 < D x"
  1007     and "\<And>x. 0 \<le> D x"
  1008 proof
  1009   interpret N: finite_measure N by fact
  1011   note RN = borel_measurable_RN_deriv density_RN_deriv[OF ac]
  1013   let ?RN = "\<lambda>t. {x \<in> space M. RN_deriv M N x = t}"
  1015   show "(\<lambda>x. enn2real (RN_deriv M N x)) \<in> borel_measurable M"
  1016     using RN by auto
  1018   have "N (?RN \<infinity>) = (\<integral>\<^sup>+ x. RN_deriv M N x * indicator (?RN \<infinity>) x \<partial>M)"
  1019     using RN(1) by (subst RN(2)[symmetric]) (auto simp: emeasure_density)
  1020   also have "\<dots> = (\<integral>\<^sup>+ x. \<infinity> * indicator (?RN \<infinity>) x \<partial>M)"
  1021     by (intro nn_integral_cong) (auto simp: indicator_def)
  1022   also have "\<dots> = \<infinity> * emeasure M (?RN \<infinity>)"
  1023     using RN by (intro nn_integral_cmult_indicator) auto
  1024   finally have eq: "N (?RN \<infinity>) = \<infinity> * emeasure M (?RN \<infinity>)" .
  1025   moreover
  1026   have "emeasure M (?RN \<infinity>) = 0"
  1027   proof (rule ccontr)
  1028     assume "emeasure M {x \<in> space M. RN_deriv M N x = \<infinity>} \<noteq> 0"
  1029     then have "0 < emeasure M {x \<in> space M. RN_deriv M N x = \<infinity>}"
  1030       by (auto simp: zero_less_iff_neq_zero)
  1031     with eq have "N (?RN \<infinity>) = \<infinity>" by (simp add: ennreal_mult_eq_top_iff)
  1032     with N.emeasure_finite[of "?RN \<infinity>"] RN show False by auto
  1033   qed
  1034   ultimately have "AE x in M. RN_deriv M N x < \<infinity>"
  1035     using RN by (intro AE_iff_measurable[THEN iffD2]) (auto simp: less_top[symmetric])
  1036   then show "AE x in M. RN_deriv M N x = ennreal (enn2real (RN_deriv M N x))"
  1037     by auto
  1038   then have eq: "AE x in N. RN_deriv M N x = ennreal (enn2real (RN_deriv M N x))"
  1039     using ac absolutely_continuous_AE by auto
  1042   have "N (?RN 0) = (\<integral>\<^sup>+ x. RN_deriv M N x * indicator (?RN 0) x \<partial>M)"
  1043     by (subst RN(2)[symmetric]) (auto simp: emeasure_density)
  1044   also have "\<dots> = (\<integral>\<^sup>+ x. 0 \<partial>M)"
  1045     by (intro nn_integral_cong) (auto simp: indicator_def)
  1046   finally have "AE x in N. RN_deriv M N x \<noteq> 0"
  1047     using RN by (subst AE_iff_measurable[OF _ refl]) (auto simp: ac cong: sets_eq_imp_space_eq)
  1048   with eq show "AE x in N. 0 < enn2real (RN_deriv M N x)"
  1049     by (auto simp: enn2real_positive_iff less_top[symmetric] zero_less_iff_neq_zero)
  1050 qed (rule enn2real_nonneg)
  1052 lemma (in sigma_finite_measure) RN_deriv_singleton:
  1053   assumes ac: "absolutely_continuous M N" "sets N = sets M"
  1054   and x: "{x} \<in> sets M"
  1055   shows "N {x} = RN_deriv M N x * emeasure M {x}"
  1056 proof -
  1057   from \<open>{x} \<in> sets M\<close>
  1058   have "density M (RN_deriv M N) {x} = (\<integral>\<^sup>+w. RN_deriv M N x * indicator {x} w \<partial>M)"
  1059     by (auto simp: indicator_def emeasure_density intro!: nn_integral_cong)
  1060   with x density_RN_deriv[OF ac] show ?thesis
  1061     by (auto simp: max_def)
  1062 qed
  1064 end