src/HOL/Enum.thy
author haftmann
Mon Nov 29 13:44:54 2010 +0100 (2010-11-29)
changeset 40815 6e2d17cc0d1d
parent 40683 a3f37b3d303a
child 40898 882e860a1e83
permissions -rw-r--r--
equivI has replaced equiv.intro
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Finite types as explicit enumerations *}
     4 
     5 theory Enum
     6 imports Map String
     7 begin
     8 
     9 subsection {* Class @{text enum} *}
    10 
    11 class enum =
    12   fixes enum :: "'a list"
    13   assumes UNIV_enum: "UNIV = set enum"
    14     and enum_distinct: "distinct enum"
    15 begin
    16 
    17 subclass finite proof
    18 qed (simp add: UNIV_enum)
    19 
    20 lemma enum_all: "set enum = UNIV" unfolding UNIV_enum ..
    21 
    22 lemma in_enum: "x \<in> set enum"
    23   unfolding enum_all by auto
    24 
    25 lemma enum_eq_I:
    26   assumes "\<And>x. x \<in> set xs"
    27   shows "set enum = set xs"
    28 proof -
    29   from assms UNIV_eq_I have "UNIV = set xs" by auto
    30   with enum_all show ?thesis by simp
    31 qed
    32 
    33 end
    34 
    35 
    36 subsection {* Equality and order on functions *}
    37 
    38 instantiation "fun" :: (enum, equal) equal
    39 begin
    40 
    41 definition
    42   "HOL.equal f g \<longleftrightarrow> (\<forall>x \<in> set enum. f x = g x)"
    43 
    44 instance proof
    45 qed (simp_all add: equal_fun_def enum_all fun_eq_iff)
    46 
    47 end
    48 
    49 lemma [code nbe]:
    50   "HOL.equal (f :: _ \<Rightarrow> _) f \<longleftrightarrow> True"
    51   by (fact equal_refl)
    52 
    53 lemma [code]:
    54   "HOL.equal f g \<longleftrightarrow>  list_all (%x. f x = g x) enum"
    55 by (auto simp add: list_all_iff enum_all equal fun_eq_iff)
    56 
    57 lemma order_fun [code]:
    58   fixes f g :: "'a\<Colon>enum \<Rightarrow> 'b\<Colon>order"
    59   shows "f \<le> g \<longleftrightarrow> list_all (\<lambda>x. f x \<le> g x) enum"
    60     and "f < g \<longleftrightarrow> f \<le> g \<and> list_ex (\<lambda>x. f x \<noteq> g x) enum"
    61   by (simp_all add: list_all_iff list_ex_iff enum_all fun_eq_iff le_fun_def order_less_le)
    62 
    63 
    64 subsection {* Quantifiers *}
    65 
    66 lemma all_code [code]: "(\<forall>x. P x) \<longleftrightarrow> list_all P enum"
    67   by (simp add: list_all_iff enum_all)
    68 
    69 lemma exists_code [code]: "(\<exists>x. P x) \<longleftrightarrow> list_ex P enum"
    70   by (simp add: list_ex_iff enum_all)
    71 
    72 lemma exists1_code[code]: "(\<exists>!x. P x) \<longleftrightarrow> list_ex1 P enum"
    73 unfolding list_ex1_iff enum_all by auto
    74 
    75 
    76 subsection {* Default instances *}
    77 
    78 primrec n_lists :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list list" where
    79   "n_lists 0 xs = [[]]"
    80   | "n_lists (Suc n) xs = concat (map (\<lambda>ys. map (\<lambda>y. y # ys) xs) (n_lists n xs))"
    81 
    82 lemma n_lists_Nil [simp]: "n_lists n [] = (if n = 0 then [[]] else [])"
    83   by (induct n) simp_all
    84 
    85 lemma length_n_lists: "length (n_lists n xs) = length xs ^ n"
    86   by (induct n) (auto simp add: length_concat o_def listsum_triv)
    87 
    88 lemma length_n_lists_elem: "ys \<in> set (n_lists n xs) \<Longrightarrow> length ys = n"
    89   by (induct n arbitrary: ys) auto
    90 
    91 lemma set_n_lists: "set (n_lists n xs) = {ys. length ys = n \<and> set ys \<subseteq> set xs}"
    92 proof (rule set_eqI)
    93   fix ys :: "'a list"
    94   show "ys \<in> set (n_lists n xs) \<longleftrightarrow> ys \<in> {ys. length ys = n \<and> set ys \<subseteq> set xs}"
    95   proof -
    96     have "ys \<in> set (n_lists n xs) \<Longrightarrow> length ys = n"
    97       by (induct n arbitrary: ys) auto
    98     moreover have "\<And>x. ys \<in> set (n_lists n xs) \<Longrightarrow> x \<in> set ys \<Longrightarrow> x \<in> set xs"
    99       by (induct n arbitrary: ys) auto
   100     moreover have "set ys \<subseteq> set xs \<Longrightarrow> ys \<in> set (n_lists (length ys) xs)"
   101       by (induct ys) auto
   102     ultimately show ?thesis by auto
   103   qed
   104 qed
   105 
   106 lemma distinct_n_lists:
   107   assumes "distinct xs"
   108   shows "distinct (n_lists n xs)"
   109 proof (rule card_distinct)
   110   from assms have card_length: "card (set xs) = length xs" by (rule distinct_card)
   111   have "card (set (n_lists n xs)) = card (set xs) ^ n"
   112   proof (induct n)
   113     case 0 then show ?case by simp
   114   next
   115     case (Suc n)
   116     moreover have "card (\<Union>ys\<in>set (n_lists n xs). (\<lambda>y. y # ys) ` set xs)
   117       = (\<Sum>ys\<in>set (n_lists n xs). card ((\<lambda>y. y # ys) ` set xs))"
   118       by (rule card_UN_disjoint) auto
   119     moreover have "\<And>ys. card ((\<lambda>y. y # ys) ` set xs) = card (set xs)"
   120       by (rule card_image) (simp add: inj_on_def)
   121     ultimately show ?case by auto
   122   qed
   123   also have "\<dots> = length xs ^ n" by (simp add: card_length)
   124   finally show "card (set (n_lists n xs)) = length (n_lists n xs)"
   125     by (simp add: length_n_lists)
   126 qed
   127 
   128 lemma map_of_zip_enum_is_Some:
   129   assumes "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   130   shows "\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y"
   131 proof -
   132   from assms have "x \<in> set (enum \<Colon> 'a\<Colon>enum list) \<longleftrightarrow>
   133     (\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y)"
   134     by (auto intro!: map_of_zip_is_Some)
   135   then show ?thesis using enum_all by auto
   136 qed
   137 
   138 lemma map_of_zip_enum_inject:
   139   fixes xs ys :: "'b\<Colon>enum list"
   140   assumes length: "length xs = length (enum \<Colon> 'a\<Colon>enum list)"
   141       "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   142     and map_of: "the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys)"
   143   shows "xs = ys"
   144 proof -
   145   have "map_of (zip (enum \<Colon> 'a list) xs) = map_of (zip (enum \<Colon> 'a list) ys)"
   146   proof
   147     fix x :: 'a
   148     from length map_of_zip_enum_is_Some obtain y1 y2
   149       where "map_of (zip (enum \<Colon> 'a list) xs) x = Some y1"
   150         and "map_of (zip (enum \<Colon> 'a list) ys) x = Some y2" by blast
   151     moreover from map_of have "the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x) = the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x)"
   152       by (auto dest: fun_cong)
   153     ultimately show "map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x = map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x"
   154       by simp
   155   qed
   156   with length enum_distinct show "xs = ys" by (rule map_of_zip_inject)
   157 qed
   158 
   159 instantiation "fun" :: (enum, enum) enum
   160 begin
   161 
   162 definition
   163   "enum = map (\<lambda>ys. the o map_of (zip (enum\<Colon>'a list) ys)) (n_lists (length (enum\<Colon>'a\<Colon>enum list)) enum)"
   164 
   165 instance proof
   166   show "UNIV = set (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   167   proof (rule UNIV_eq_I)
   168     fix f :: "'a \<Rightarrow> 'b"
   169     have "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   170       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   171     then show "f \<in> set enum"
   172       by (auto simp add: enum_fun_def set_n_lists intro: in_enum)
   173   qed
   174 next
   175   from map_of_zip_enum_inject
   176   show "distinct (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   177     by (auto intro!: inj_onI simp add: enum_fun_def
   178       distinct_map distinct_n_lists enum_distinct set_n_lists enum_all)
   179 qed
   180 
   181 end
   182 
   183 lemma enum_fun_code [code]: "enum = (let enum_a = (enum \<Colon> 'a\<Colon>{enum, equal} list)
   184   in map (\<lambda>ys. the o map_of (zip enum_a ys)) (n_lists (length enum_a) enum))"
   185   by (simp add: enum_fun_def Let_def)
   186 
   187 instantiation unit :: enum
   188 begin
   189 
   190 definition
   191   "enum = [()]"
   192 
   193 instance proof
   194 qed (simp_all add: enum_unit_def UNIV_unit)
   195 
   196 end
   197 
   198 instantiation bool :: enum
   199 begin
   200 
   201 definition
   202   "enum = [False, True]"
   203 
   204 instance proof
   205 qed (simp_all add: enum_bool_def UNIV_bool)
   206 
   207 end
   208 
   209 primrec product :: "'a list \<Rightarrow> 'b list \<Rightarrow> ('a \<times> 'b) list" where
   210   "product [] _ = []"
   211   | "product (x#xs) ys = map (Pair x) ys @ product xs ys"
   212 
   213 lemma product_list_set:
   214   "set (product xs ys) = set xs \<times> set ys"
   215   by (induct xs) auto
   216 
   217 lemma distinct_product:
   218   assumes "distinct xs" and "distinct ys"
   219   shows "distinct (product xs ys)"
   220   using assms by (induct xs)
   221     (auto intro: inj_onI simp add: product_list_set distinct_map)
   222 
   223 instantiation prod :: (enum, enum) enum
   224 begin
   225 
   226 definition
   227   "enum = product enum enum"
   228 
   229 instance by default
   230   (simp_all add: enum_prod_def product_list_set distinct_product enum_all enum_distinct)
   231 
   232 end
   233 
   234 instantiation sum :: (enum, enum) enum
   235 begin
   236 
   237 definition
   238   "enum = map Inl enum @ map Inr enum"
   239 
   240 instance by default
   241   (auto simp add: enum_all enum_sum_def, case_tac x, auto intro: inj_onI simp add: distinct_map enum_distinct)
   242 
   243 end
   244 
   245 primrec sublists :: "'a list \<Rightarrow> 'a list list" where
   246   "sublists [] = [[]]"
   247   | "sublists (x#xs) = (let xss = sublists xs in map (Cons x) xss @ xss)"
   248 
   249 lemma length_sublists:
   250   "length (sublists xs) = Suc (Suc (0\<Colon>nat)) ^ length xs"
   251   by (induct xs) (simp_all add: Let_def)
   252 
   253 lemma sublists_powset:
   254   "set ` set (sublists xs) = Pow (set xs)"
   255 proof -
   256   have aux: "\<And>x A. set ` Cons x ` A = insert x ` set ` A"
   257     by (auto simp add: image_def)
   258   have "set (map set (sublists xs)) = Pow (set xs)"
   259     by (induct xs)
   260       (simp_all add: aux Let_def Pow_insert Un_commute comp_def del: map_map)
   261   then show ?thesis by simp
   262 qed
   263 
   264 lemma distinct_set_sublists:
   265   assumes "distinct xs"
   266   shows "distinct (map set (sublists xs))"
   267 proof (rule card_distinct)
   268   have "finite (set xs)" by rule
   269   then have "card (Pow (set xs)) = Suc (Suc 0) ^ card (set xs)" by (rule card_Pow)
   270   with assms distinct_card [of xs]
   271     have "card (Pow (set xs)) = Suc (Suc 0) ^ length xs" by simp
   272   then show "card (set (map set (sublists xs))) = length (map set (sublists xs))"
   273     by (simp add: sublists_powset length_sublists)
   274 qed
   275 
   276 instantiation nibble :: enum
   277 begin
   278 
   279 definition
   280   "enum = [Nibble0, Nibble1, Nibble2, Nibble3, Nibble4, Nibble5, Nibble6, Nibble7,
   281     Nibble8, Nibble9, NibbleA, NibbleB, NibbleC, NibbleD, NibbleE, NibbleF]"
   282 
   283 instance proof
   284 qed (simp_all add: enum_nibble_def UNIV_nibble)
   285 
   286 end
   287 
   288 instantiation char :: enum
   289 begin
   290 
   291 definition
   292   "enum = map (split Char) (product enum enum)"
   293 
   294 lemma enum_chars [code]:
   295   "enum = chars"
   296   unfolding enum_char_def chars_def enum_nibble_def by simp
   297 
   298 instance proof
   299 qed (auto intro: char.exhaust injI simp add: enum_char_def product_list_set enum_all full_SetCompr_eq [symmetric]
   300   distinct_map distinct_product enum_distinct)
   301 
   302 end
   303 
   304 instantiation option :: (enum) enum
   305 begin
   306 
   307 definition
   308   "enum = None # map Some enum"
   309 
   310 instance proof
   311 qed (auto simp add: enum_all enum_option_def, rule option.exhaust, auto intro: simp add: distinct_map enum_distinct)
   312 
   313 end
   314 
   315 subsection {* Small finite types *}
   316 
   317 text {* We define small finite types for the use in Quickcheck *}
   318 
   319 datatype finite_1 = a\<^isub>1
   320 
   321 instantiation finite_1 :: enum
   322 begin
   323 
   324 definition
   325   "enum = [a\<^isub>1]"
   326 
   327 instance proof
   328 qed (auto simp add: enum_finite_1_def intro: finite_1.exhaust)
   329 
   330 end
   331 
   332 instantiation finite_1 :: linorder
   333 begin
   334 
   335 definition less_eq_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   336 where
   337   "less_eq_finite_1 x y = True"
   338 
   339 definition less_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   340 where
   341   "less_finite_1 x y = False"
   342 
   343 instance
   344 apply (intro_classes)
   345 apply (auto simp add: less_finite_1_def less_eq_finite_1_def)
   346 apply (metis finite_1.exhaust)
   347 done
   348 
   349 end
   350 
   351 hide_const a\<^isub>1
   352 
   353 datatype finite_2 = a\<^isub>1 | a\<^isub>2
   354 
   355 instantiation finite_2 :: enum
   356 begin
   357 
   358 definition
   359   "enum = [a\<^isub>1, a\<^isub>2]"
   360 
   361 instance proof
   362 qed (auto simp add: enum_finite_2_def intro: finite_2.exhaust)
   363 
   364 end
   365 
   366 instantiation finite_2 :: linorder
   367 begin
   368 
   369 definition less_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   370 where
   371   "less_finite_2 x y = ((x = a\<^isub>1) & (y = a\<^isub>2))"
   372 
   373 definition less_eq_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   374 where
   375   "less_eq_finite_2 x y = ((x = y) \<or> (x < y))"
   376 
   377 
   378 instance
   379 apply (intro_classes)
   380 apply (auto simp add: less_finite_2_def less_eq_finite_2_def)
   381 apply (metis finite_2.distinct finite_2.nchotomy)+
   382 done
   383 
   384 end
   385 
   386 hide_const a\<^isub>1 a\<^isub>2
   387 
   388 
   389 datatype finite_3 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3
   390 
   391 instantiation finite_3 :: enum
   392 begin
   393 
   394 definition
   395   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3]"
   396 
   397 instance proof
   398 qed (auto simp add: enum_finite_3_def intro: finite_3.exhaust)
   399 
   400 end
   401 
   402 instantiation finite_3 :: linorder
   403 begin
   404 
   405 definition less_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   406 where
   407   "less_finite_3 x y = (case x of a\<^isub>1 => (y \<noteq> a\<^isub>1)
   408      | a\<^isub>2 => (y = a\<^isub>3)| a\<^isub>3 => False)"
   409 
   410 definition less_eq_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   411 where
   412   "less_eq_finite_3 x y = ((x = y) \<or> (x < y))"
   413 
   414 
   415 instance proof (intro_classes)
   416 qed (auto simp add: less_finite_3_def less_eq_finite_3_def split: finite_3.split_asm)
   417 
   418 end
   419 
   420 hide_const a\<^isub>1 a\<^isub>2 a\<^isub>3
   421 
   422 
   423 datatype finite_4 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3 | a\<^isub>4
   424 
   425 instantiation finite_4 :: enum
   426 begin
   427 
   428 definition
   429   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3, a\<^isub>4]"
   430 
   431 instance proof
   432 qed (auto simp add: enum_finite_4_def intro: finite_4.exhaust)
   433 
   434 end
   435 
   436 hide_const a\<^isub>1 a\<^isub>2 a\<^isub>3 a\<^isub>4
   437 
   438 
   439 datatype finite_5 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3 | a\<^isub>4 | a\<^isub>5
   440 
   441 instantiation finite_5 :: enum
   442 begin
   443 
   444 definition
   445   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3, a\<^isub>4, a\<^isub>5]"
   446 
   447 instance proof
   448 qed (auto simp add: enum_finite_5_def intro: finite_5.exhaust)
   449 
   450 end
   451 
   452 hide_const a\<^isub>1 a\<^isub>2 a\<^isub>3 a\<^isub>4 a\<^isub>5
   453 
   454 
   455 hide_type finite_1 finite_2 finite_3 finite_4 finite_5
   456 hide_const (open) enum n_lists product
   457 
   458 end