src/HOL/Finite_Set.thy
author haftmann
Mon Nov 29 13:44:54 2010 +0100 (2010-11-29)
changeset 40815 6e2d17cc0d1d
parent 40786 0a54cfc9add3
child 40922 4d0f96a54e76
permissions -rw-r--r--
equivI has replaced equiv.intro
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad
     4 *)
     5 
     6 header {* Finite sets *}
     7 
     8 theory Finite_Set
     9 imports Option Power
    10 begin
    11 
    12 subsection {* Predicate for finite sets *}
    13 
    14 inductive finite :: "'a set => bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A ==> finite (insert a A)"
    18 
    19 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    20   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    21   shows "\<exists>a::'a. a \<notin> A"
    22 proof -
    23   from assms have "A \<noteq> UNIV" by blast
    24   thus ?thesis by blast
    25 qed
    26 
    27 lemma finite_induct [case_names empty insert, induct set: finite]:
    28   "finite F ==>
    29     P {} ==> (!!x F. finite F ==> x \<notin> F ==> P F ==> P (insert x F)) ==> P F"
    30   -- {* Discharging @{text "x \<notin> F"} entails extra work. *}
    31 proof -
    32   assume "P {}" and
    33     insert: "!!x F. finite F ==> x \<notin> F ==> P F ==> P (insert x F)"
    34   assume "finite F"
    35   thus "P F"
    36   proof induct
    37     show "P {}" by fact
    38     fix x F assume F: "finite F" and P: "P F"
    39     show "P (insert x F)"
    40     proof cases
    41       assume "x \<in> F"
    42       hence "insert x F = F" by (rule insert_absorb)
    43       with P show ?thesis by (simp only:)
    44     next
    45       assume "x \<notin> F"
    46       from F this P show ?thesis by (rule insert)
    47     qed
    48   qed
    49 qed
    50 
    51 lemma finite_ne_induct[case_names singleton insert, consumes 2]:
    52 assumes fin: "finite F" shows "F \<noteq> {} \<Longrightarrow>
    53  \<lbrakk> \<And>x. P{x};
    54    \<And>x F. \<lbrakk> finite F; F \<noteq> {}; x \<notin> F; P F \<rbrakk> \<Longrightarrow> P (insert x F) \<rbrakk>
    55  \<Longrightarrow> P F"
    56 using fin
    57 proof induct
    58   case empty thus ?case by simp
    59 next
    60   case (insert x F)
    61   show ?case
    62   proof cases
    63     assume "F = {}"
    64     thus ?thesis using `P {x}` by simp
    65   next
    66     assume "F \<noteq> {}"
    67     thus ?thesis using insert by blast
    68   qed
    69 qed
    70 
    71 lemma finite_subset_induct [consumes 2, case_names empty insert]:
    72   assumes "finite F" and "F \<subseteq> A"
    73     and empty: "P {}"
    74     and insert: "!!a F. finite F ==> a \<in> A ==> a \<notin> F ==> P F ==> P (insert a F)"
    75   shows "P F"
    76 proof -
    77   from `finite F` and `F \<subseteq> A`
    78   show ?thesis
    79   proof induct
    80     show "P {}" by fact
    81   next
    82     fix x F
    83     assume "finite F" and "x \<notin> F" and
    84       P: "F \<subseteq> A ==> P F" and i: "insert x F \<subseteq> A"
    85     show "P (insert x F)"
    86     proof (rule insert)
    87       from i show "x \<in> A" by blast
    88       from i have "F \<subseteq> A" by blast
    89       with P show "P F" .
    90       show "finite F" by fact
    91       show "x \<notin> F" by fact
    92     qed
    93   qed
    94 qed
    95 
    96 
    97 text{* A finite choice principle. Does not need the SOME choice operator. *}
    98 lemma finite_set_choice:
    99   "finite A \<Longrightarrow> ALL x:A. (EX y. P x y) \<Longrightarrow> EX f. ALL x:A. P x (f x)"
   100 proof (induct set: finite)
   101   case empty thus ?case by simp
   102 next
   103   case (insert a A)
   104   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
   105   show ?case (is "EX f. ?P f")
   106   proof
   107     show "?P(%x. if x = a then b else f x)" using f ab by auto
   108   qed
   109 qed
   110 
   111 
   112 text{* Finite sets are the images of initial segments of natural numbers: *}
   113 
   114 lemma finite_imp_nat_seg_image_inj_on:
   115   assumes fin: "finite A" 
   116   shows "\<exists> (n::nat) f. A = f ` {i. i<n} & inj_on f {i. i<n}"
   117 using fin
   118 proof induct
   119   case empty
   120   show ?case  
   121   proof show "\<exists>f. {} = f ` {i::nat. i < 0} & inj_on f {i. i<0}" by simp 
   122   qed
   123 next
   124   case (insert a A)
   125   have notinA: "a \<notin> A" by fact
   126   from insert.hyps obtain n f
   127     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
   128   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
   129         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
   130     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
   131   thus ?case by blast
   132 qed
   133 
   134 lemma nat_seg_image_imp_finite:
   135   "!!f A. A = f ` {i::nat. i<n} \<Longrightarrow> finite A"
   136 proof (induct n)
   137   case 0 thus ?case by simp
   138 next
   139   case (Suc n)
   140   let ?B = "f ` {i. i < n}"
   141   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
   142   show ?case
   143   proof cases
   144     assume "\<exists>k<n. f n = f k"
   145     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   146     thus ?thesis using finB by simp
   147   next
   148     assume "\<not>(\<exists> k<n. f n = f k)"
   149     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   150     thus ?thesis using finB by simp
   151   qed
   152 qed
   153 
   154 lemma finite_conv_nat_seg_image:
   155   "finite A = (\<exists> (n::nat) f. A = f ` {i::nat. i<n})"
   156 by(blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   157 
   158 lemma finite_imp_inj_to_nat_seg:
   159 assumes "finite A"
   160 shows "EX f n::nat. f`A = {i. i<n} & inj_on f A"
   161 proof -
   162   from finite_imp_nat_seg_image_inj_on[OF `finite A`]
   163   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   164     by (auto simp:bij_betw_def)
   165   let ?f = "the_inv_into {i. i<n} f"
   166   have "inj_on ?f A & ?f ` A = {i. i<n}"
   167     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   168   thus ?thesis by blast
   169 qed
   170 
   171 lemma finite_Collect_less_nat[iff]: "finite{n::nat. n<k}"
   172 by(fastsimp simp: finite_conv_nat_seg_image)
   173 
   174 text {* Finiteness and set theoretic constructions *}
   175 
   176 lemma finite_UnI: "finite F ==> finite G ==> finite (F Un G)"
   177 by (induct set: finite) simp_all
   178 
   179 lemma finite_subset: "A \<subseteq> B ==> finite B ==> finite A"
   180   -- {* Every subset of a finite set is finite. *}
   181 proof -
   182   assume "finite B"
   183   thus "!!A. A \<subseteq> B ==> finite A"
   184   proof induct
   185     case empty
   186     thus ?case by simp
   187   next
   188     case (insert x F A)
   189     have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F ==> finite (A - {x})" by fact+
   190     show "finite A"
   191     proof cases
   192       assume x: "x \<in> A"
   193       with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   194       with r have "finite (A - {x})" .
   195       hence "finite (insert x (A - {x}))" ..
   196       also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   197       finally show ?thesis .
   198     next
   199       show "A \<subseteq> F ==> ?thesis" by fact
   200       assume "x \<notin> A"
   201       with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   202     qed
   203   qed
   204 qed
   205 
   206 lemma rev_finite_subset: "finite B ==> A \<subseteq> B ==> finite A"
   207 by (rule finite_subset)
   208 
   209 lemma finite_Un [iff]: "finite (F Un G) = (finite F & finite G)"
   210 by (blast intro: finite_subset [of _ "X Un Y", standard] finite_UnI)
   211 
   212 lemma finite_Collect_disjI[simp]:
   213   "finite{x. P x | Q x} = (finite{x. P x} & finite{x. Q x})"
   214 by(simp add:Collect_disj_eq)
   215 
   216 lemma finite_Int [simp, intro]: "finite F | finite G ==> finite (F Int G)"
   217   -- {* The converse obviously fails. *}
   218 by (blast intro: finite_subset)
   219 
   220 lemma finite_Collect_conjI [simp, intro]:
   221   "finite{x. P x} | finite{x. Q x} ==> finite{x. P x & Q x}"
   222   -- {* The converse obviously fails. *}
   223 by(simp add:Collect_conj_eq)
   224 
   225 lemma finite_Collect_le_nat[iff]: "finite{n::nat. n<=k}"
   226 by(simp add: le_eq_less_or_eq)
   227 
   228 lemma finite_insert [simp]: "finite (insert a A) = finite A"
   229   apply (subst insert_is_Un)
   230   apply (simp only: finite_Un, blast)
   231   done
   232 
   233 lemma finite_Union[simp, intro]:
   234  "\<lbrakk> finite A; !!M. M \<in> A \<Longrightarrow> finite M \<rbrakk> \<Longrightarrow> finite(\<Union>A)"
   235 by (induct rule:finite_induct) simp_all
   236 
   237 lemma finite_Inter[intro]: "EX A:M. finite(A) \<Longrightarrow> finite(Inter M)"
   238 by (blast intro: Inter_lower finite_subset)
   239 
   240 lemma finite_INT[intro]: "EX x:I. finite(A x) \<Longrightarrow> finite(INT x:I. A x)"
   241 by (blast intro: INT_lower finite_subset)
   242 
   243 lemma finite_empty_induct:
   244   assumes "finite A"
   245     and "P A"
   246     and "!!a A. finite A ==> a:A ==> P A ==> P (A - {a})"
   247   shows "P {}"
   248 proof -
   249   have "P (A - A)"
   250   proof -
   251     {
   252       fix c b :: "'a set"
   253       assume c: "finite c" and b: "finite b"
   254         and P1: "P b" and P2: "!!x y. finite y ==> x \<in> y ==> P y ==> P (y - {x})"
   255       have "c \<subseteq> b ==> P (b - c)"
   256         using c
   257       proof induct
   258         case empty
   259         from P1 show ?case by simp
   260       next
   261         case (insert x F)
   262         have "P (b - F - {x})"
   263         proof (rule P2)
   264           from _ b show "finite (b - F)" by (rule finite_subset) blast
   265           from insert show "x \<in> b - F" by simp
   266           from insert show "P (b - F)" by simp
   267         qed
   268         also have "b - F - {x} = b - insert x F" by (rule Diff_insert [symmetric])
   269         finally show ?case .
   270       qed
   271     }
   272     then show ?thesis by this (simp_all add: assms)
   273   qed
   274   then show ?thesis by simp
   275 qed
   276 
   277 lemma finite_Diff [simp, intro]: "finite A ==> finite (A - B)"
   278 by (rule Diff_subset [THEN finite_subset])
   279 
   280 lemma finite_Diff2 [simp]:
   281   assumes "finite B" shows "finite (A - B) = finite A"
   282 proof -
   283   have "finite A \<longleftrightarrow> finite((A-B) Un (A Int B))" by(simp add: Un_Diff_Int)
   284   also have "\<dots> \<longleftrightarrow> finite(A-B)" using `finite B` by(simp)
   285   finally show ?thesis ..
   286 qed
   287 
   288 lemma finite_compl[simp]:
   289   "finite(A::'a set) \<Longrightarrow> finite(-A) = finite(UNIV::'a set)"
   290 by(simp add:Compl_eq_Diff_UNIV)
   291 
   292 lemma finite_Collect_not[simp]:
   293   "finite{x::'a. P x} \<Longrightarrow> finite{x. ~P x} = finite(UNIV::'a set)"
   294 by(simp add:Collect_neg_eq)
   295 
   296 lemma finite_Diff_insert [iff]: "finite (A - insert a B) = finite (A - B)"
   297   apply (subst Diff_insert)
   298   apply (case_tac "a : A - B")
   299    apply (rule finite_insert [symmetric, THEN trans])
   300    apply (subst insert_Diff, simp_all)
   301   done
   302 
   303 
   304 text {* Image and Inverse Image over Finite Sets *}
   305 
   306 lemma finite_imageI[simp, intro]: "finite F ==> finite (h ` F)"
   307   -- {* The image of a finite set is finite. *}
   308   by (induct set: finite) simp_all
   309 
   310 lemma finite_image_set [simp]:
   311   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   312   by (simp add: image_Collect [symmetric])
   313 
   314 lemma finite_surj: "finite A ==> B <= f ` A ==> finite B"
   315   apply (frule finite_imageI)
   316   apply (erule finite_subset, assumption)
   317   done
   318 
   319 lemma finite_range_imageI:
   320     "finite (range g) ==> finite (range (%x. f (g x)))"
   321   apply (drule finite_imageI, simp add: range_composition)
   322   done
   323 
   324 lemma finite_imageD: "finite (f`A) ==> inj_on f A ==> finite A"
   325 proof -
   326   have aux: "!!A. finite (A - {}) = finite A" by simp
   327   fix B :: "'a set"
   328   assume "finite B"
   329   thus "!!A. f`A = B ==> inj_on f A ==> finite A"
   330     apply induct
   331      apply simp
   332     apply (subgoal_tac "EX y:A. f y = x & F = f ` (A - {y})")
   333      apply clarify
   334      apply (simp (no_asm_use) add: inj_on_def)
   335      apply (blast dest!: aux [THEN iffD1], atomize)
   336     apply (erule_tac V = "ALL A. ?PP (A)" in thin_rl)
   337     apply (frule subsetD [OF equalityD2 insertI1], clarify)
   338     apply (rule_tac x = xa in bexI)
   339      apply (simp_all add: inj_on_image_set_diff)
   340     done
   341 qed (rule refl)
   342 
   343 
   344 lemma inj_vimage_singleton: "inj f ==> f-`{a} \<subseteq> {THE x. f x = a}"
   345   -- {* The inverse image of a singleton under an injective function
   346          is included in a singleton. *}
   347   apply (auto simp add: inj_on_def)
   348   apply (blast intro: the_equality [symmetric])
   349   done
   350 
   351 lemma finite_vimageI: "[|finite F; inj h|] ==> finite (h -` F)"
   352   -- {* The inverse image of a finite set under an injective function
   353          is finite. *}
   354   apply (induct set: finite)
   355    apply simp_all
   356   apply (subst vimage_insert)
   357   apply (simp add: finite_subset [OF inj_vimage_singleton])
   358   done
   359 
   360 lemma finite_vimageD:
   361   assumes fin: "finite (h -` F)" and surj: "surj h"
   362   shows "finite F"
   363 proof -
   364   have "finite (h ` (h -` F))" using fin by (rule finite_imageI)
   365   also have "h ` (h -` F) = F" using surj by (rule surj_image_vimage_eq)
   366   finally show "finite F" .
   367 qed
   368 
   369 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   370   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   371 
   372 
   373 text {* The finite UNION of finite sets *}
   374 
   375 lemma finite_UN_I[intro]:
   376   "finite A ==> (!!a. a:A ==> finite (B a)) ==> finite (UN a:A. B a)"
   377 by (induct set: finite) simp_all
   378 
   379 text {*
   380   Strengthen RHS to
   381   @{prop "((ALL x:A. finite (B x)) & finite {x. x:A & B x \<noteq> {}})"}?
   382 
   383   We'd need to prove
   384   @{prop "finite C ==> ALL A B. (UNION A B) <= C --> finite {x. x:A & B x \<noteq> {}}"}
   385   by induction. *}
   386 
   387 lemma finite_UN [simp]:
   388   "finite A ==> finite (UNION A B) = (ALL x:A. finite (B x))"
   389 by (blast intro: finite_subset)
   390 
   391 lemma finite_Collect_bex[simp]: "finite A \<Longrightarrow>
   392   finite{x. EX y:A. Q x y} = (ALL y:A. finite{x. Q x y})"
   393 apply(subgoal_tac "{x. EX y:A. Q x y} = UNION A (%y. {x. Q x y})")
   394  apply auto
   395 done
   396 
   397 lemma finite_Collect_bounded_ex[simp]: "finite{y. P y} \<Longrightarrow>
   398   finite{x. EX y. P y & Q x y} = (ALL y. P y \<longrightarrow> finite{x. Q x y})"
   399 apply(subgoal_tac "{x. EX y. P y & Q x y} = UNION {y. P y} (%y. {x. Q x y})")
   400  apply auto
   401 done
   402 
   403 
   404 lemma finite_Plus: "[| finite A; finite B |] ==> finite (A <+> B)"
   405 by (simp add: Plus_def)
   406 
   407 lemma finite_PlusD: 
   408   fixes A :: "'a set" and B :: "'b set"
   409   assumes fin: "finite (A <+> B)"
   410   shows "finite A" "finite B"
   411 proof -
   412   have "Inl ` A \<subseteq> A <+> B" by auto
   413   hence "finite (Inl ` A :: ('a + 'b) set)" using fin by(rule finite_subset)
   414   thus "finite A" by(rule finite_imageD)(auto intro: inj_onI)
   415 next
   416   have "Inr ` B \<subseteq> A <+> B" by auto
   417   hence "finite (Inr ` B :: ('a + 'b) set)" using fin by(rule finite_subset)
   418   thus "finite B" by(rule finite_imageD)(auto intro: inj_onI)
   419 qed
   420 
   421 lemma finite_Plus_iff[simp]: "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   422 by(auto intro: finite_PlusD finite_Plus)
   423 
   424 lemma finite_Plus_UNIV_iff[simp]:
   425   "finite (UNIV :: ('a + 'b) set) =
   426   (finite (UNIV :: 'a set) & finite (UNIV :: 'b set))"
   427 by(subst UNIV_Plus_UNIV[symmetric])(rule finite_Plus_iff)
   428 
   429 
   430 text {* Sigma of finite sets *}
   431 
   432 lemma finite_SigmaI [simp, intro]:
   433     "finite A ==> (!!a. a:A ==> finite (B a)) ==> finite (SIGMA a:A. B a)"
   434   by (unfold Sigma_def) blast
   435 
   436 lemma finite_cartesian_product: "[| finite A; finite B |] ==>
   437     finite (A <*> B)"
   438   by (rule finite_SigmaI)
   439 
   440 lemma finite_Prod_UNIV:
   441     "finite (UNIV::'a set) ==> finite (UNIV::'b set) ==> finite (UNIV::('a * 'b) set)"
   442   apply (subgoal_tac "(UNIV:: ('a * 'b) set) = Sigma UNIV (%x. UNIV)")
   443    apply (erule ssubst)
   444    apply (erule finite_SigmaI, auto)
   445   done
   446 
   447 lemma finite_cartesian_productD1:
   448      "[| finite (A <*> B); B \<noteq> {} |] ==> finite A"
   449 apply (auto simp add: finite_conv_nat_seg_image) 
   450 apply (drule_tac x=n in spec) 
   451 apply (drule_tac x="fst o f" in spec) 
   452 apply (auto simp add: o_def) 
   453  prefer 2 apply (force dest!: equalityD2) 
   454 apply (drule equalityD1) 
   455 apply (rename_tac y x)
   456 apply (subgoal_tac "\<exists>k. k<n & f k = (x,y)") 
   457  prefer 2 apply force
   458 apply clarify
   459 apply (rule_tac x=k in image_eqI, auto)
   460 done
   461 
   462 lemma finite_cartesian_productD2:
   463      "[| finite (A <*> B); A \<noteq> {} |] ==> finite B"
   464 apply (auto simp add: finite_conv_nat_seg_image) 
   465 apply (drule_tac x=n in spec) 
   466 apply (drule_tac x="snd o f" in spec) 
   467 apply (auto simp add: o_def) 
   468  prefer 2 apply (force dest!: equalityD2) 
   469 apply (drule equalityD1)
   470 apply (rename_tac x y)
   471 apply (subgoal_tac "\<exists>k. k<n & f k = (x,y)") 
   472  prefer 2 apply force
   473 apply clarify
   474 apply (rule_tac x=k in image_eqI, auto)
   475 done
   476 
   477 
   478 text {* The powerset of a finite set *}
   479 
   480 lemma finite_Pow_iff [iff]: "finite (Pow A) = finite A"
   481 proof
   482   assume "finite (Pow A)"
   483   with _ have "finite ((%x. {x}) ` A)" by (rule finite_subset) blast
   484   thus "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   485 next
   486   assume "finite A"
   487   thus "finite (Pow A)"
   488     by induct (simp_all add: Pow_insert)
   489 qed
   490 
   491 lemma finite_Collect_subsets[simp,intro]: "finite A \<Longrightarrow> finite{B. B \<subseteq> A}"
   492 by(simp add: Pow_def[symmetric])
   493 
   494 
   495 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   496 by(blast intro: finite_subset[OF subset_Pow_Union])
   497 
   498 
   499 lemma finite_subset_image:
   500   assumes "finite B"
   501   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   502 using assms proof(induct)
   503   case empty thus ?case by simp
   504 next
   505   case insert thus ?case
   506     by (clarsimp simp del: image_insert simp add: image_insert[symmetric])
   507        blast
   508 qed
   509 
   510 
   511 subsection {* Class @{text finite}  *}
   512 
   513 class finite =
   514   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   515 begin
   516 
   517 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   518   by (rule subset_UNIV finite_UNIV finite_subset)+
   519 
   520 end
   521 
   522 lemma UNIV_unit [no_atp]:
   523   "UNIV = {()}" by auto
   524 
   525 instance unit :: finite proof
   526 qed (simp add: UNIV_unit)
   527 
   528 lemma UNIV_bool [no_atp]:
   529   "UNIV = {False, True}" by auto
   530 
   531 instance bool :: finite proof
   532 qed (simp add: UNIV_bool)
   533 
   534 instance prod :: (finite, finite) finite proof
   535 qed (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   536 
   537 lemma finite_option_UNIV [simp]:
   538   "finite (UNIV :: 'a option set) = finite (UNIV :: 'a set)"
   539   by (auto simp add: UNIV_option_conv elim: finite_imageD intro: inj_Some)
   540 
   541 instance option :: (finite) finite proof
   542 qed (simp add: UNIV_option_conv)
   543 
   544 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   545   by (rule inj_onI, auto simp add: set_eq_iff fun_eq_iff)
   546 
   547 instance "fun" :: (finite, finite) finite
   548 proof
   549   show "finite (UNIV :: ('a => 'b) set)"
   550   proof (rule finite_imageD)
   551     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   552     have "range ?graph \<subseteq> Pow UNIV" by simp
   553     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   554       by (simp only: finite_Pow_iff finite)
   555     ultimately show "finite (range ?graph)"
   556       by (rule finite_subset)
   557     show "inj ?graph" by (rule inj_graph)
   558   qed
   559 qed
   560 
   561 instance sum :: (finite, finite) finite proof
   562 qed (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   563 
   564 
   565 subsection {* A basic fold functional for finite sets *}
   566 
   567 text {* The intended behaviour is
   568 @{text "fold f z {x\<^isub>1, ..., x\<^isub>n} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
   569 if @{text f} is ``left-commutative'':
   570 *}
   571 
   572 locale fun_left_comm =
   573   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   574   assumes fun_left_comm: "f x (f y z) = f y (f x z)"
   575 begin
   576 
   577 text{* On a functional level it looks much nicer: *}
   578 
   579 lemma fun_comp_comm:  "f x \<circ> f y = f y \<circ> f x"
   580 by (simp add: fun_left_comm fun_eq_iff)
   581 
   582 end
   583 
   584 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   585 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   586   emptyI [intro]: "fold_graph f z {} z" |
   587   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   588       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   589 
   590 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   591 
   592 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   593   "fold f z A = (THE y. fold_graph f z A y)"
   594 
   595 text{*A tempting alternative for the definiens is
   596 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   597 It allows the removal of finiteness assumptions from the theorems
   598 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   599 The proofs become ugly. It is not worth the effort. (???) *}
   600 
   601 
   602 lemma Diff1_fold_graph:
   603   "fold_graph f z (A - {x}) y \<Longrightarrow> x \<in> A \<Longrightarrow> fold_graph f z A (f x y)"
   604 by (erule insert_Diff [THEN subst], rule fold_graph.intros, auto)
   605 
   606 lemma fold_graph_imp_finite: "fold_graph f z A x \<Longrightarrow> finite A"
   607 by (induct set: fold_graph) auto
   608 
   609 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   610 by (induct set: finite) auto
   611 
   612 
   613 subsubsection{*From @{const fold_graph} to @{term fold}*}
   614 
   615 context fun_left_comm
   616 begin
   617 
   618 lemma fold_graph_insertE_aux:
   619   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   620 proof (induct set: fold_graph)
   621   case (insertI x A y) show ?case
   622   proof (cases "x = a")
   623     assume "x = a" with insertI show ?case by auto
   624   next
   625     assume "x \<noteq> a"
   626     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   627       using insertI by auto
   628     have 1: "f x y = f a (f x y')"
   629       unfolding y by (rule fun_left_comm)
   630     have 2: "fold_graph f z (insert x A - {a}) (f x y')"
   631       using y' and `x \<noteq> a` and `x \<notin> A`
   632       by (simp add: insert_Diff_if fold_graph.insertI)
   633     from 1 2 show ?case by fast
   634   qed
   635 qed simp
   636 
   637 lemma fold_graph_insertE:
   638   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   639   obtains y where "v = f x y" and "fold_graph f z A y"
   640 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   641 
   642 lemma fold_graph_determ:
   643   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   644 proof (induct arbitrary: y set: fold_graph)
   645   case (insertI x A y v)
   646   from `fold_graph f z (insert x A) v` and `x \<notin> A`
   647   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   648     by (rule fold_graph_insertE)
   649   from `fold_graph f z A y'` have "y' = y" by (rule insertI)
   650   with `v = f x y'` show "v = f x y" by simp
   651 qed fast
   652 
   653 lemma fold_equality:
   654   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   655 by (unfold fold_def) (blast intro: fold_graph_determ)
   656 
   657 lemma fold_graph_fold: "finite A \<Longrightarrow> fold_graph f z A (fold f z A)"
   658 unfolding fold_def
   659 apply (rule theI')
   660 apply (rule ex_ex1I)
   661 apply (erule finite_imp_fold_graph)
   662 apply (erule (1) fold_graph_determ)
   663 done
   664 
   665 text{* The base case for @{text fold}: *}
   666 
   667 lemma (in -) fold_empty [simp]: "fold f z {} = z"
   668 by (unfold fold_def) blast
   669 
   670 text{* The various recursion equations for @{const fold}: *}
   671 
   672 lemma fold_insert [simp]:
   673   "finite A ==> x \<notin> A ==> fold f z (insert x A) = f x (fold f z A)"
   674 apply (rule fold_equality)
   675 apply (erule fold_graph.insertI)
   676 apply (erule fold_graph_fold)
   677 done
   678 
   679 lemma fold_fun_comm:
   680   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   681 proof (induct rule: finite_induct)
   682   case empty then show ?case by simp
   683 next
   684   case (insert y A) then show ?case
   685     by (simp add: fun_left_comm[of x])
   686 qed
   687 
   688 lemma fold_insert2:
   689   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   690 by (simp add: fold_fun_comm)
   691 
   692 lemma fold_rec:
   693 assumes "finite A" and "x \<in> A"
   694 shows "fold f z A = f x (fold f z (A - {x}))"
   695 proof -
   696   have A: "A = insert x (A - {x})" using `x \<in> A` by blast
   697   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   698   also have "\<dots> = f x (fold f z (A - {x}))"
   699     by (rule fold_insert) (simp add: `finite A`)+
   700   finally show ?thesis .
   701 qed
   702 
   703 lemma fold_insert_remove:
   704   assumes "finite A"
   705   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   706 proof -
   707   from `finite A` have "finite (insert x A)" by auto
   708   moreover have "x \<in> insert x A" by auto
   709   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   710     by (rule fold_rec)
   711   then show ?thesis by simp
   712 qed
   713 
   714 end
   715 
   716 text{* A simplified version for idempotent functions: *}
   717 
   718 locale fun_left_comm_idem = fun_left_comm +
   719   assumes fun_left_idem: "f x (f x z) = f x z"
   720 begin
   721 
   722 text{* The nice version: *}
   723 lemma fun_comp_idem : "f x o f x = f x"
   724 by (simp add: fun_left_idem fun_eq_iff)
   725 
   726 lemma fold_insert_idem:
   727   assumes fin: "finite A"
   728   shows "fold f z (insert x A) = f x (fold f z A)"
   729 proof cases
   730   assume "x \<in> A"
   731   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   732   then show ?thesis using assms by (simp add:fun_left_idem)
   733 next
   734   assume "x \<notin> A" then show ?thesis using assms by simp
   735 qed
   736 
   737 declare fold_insert[simp del] fold_insert_idem[simp]
   738 
   739 lemma fold_insert_idem2:
   740   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   741 by(simp add:fold_fun_comm)
   742 
   743 end
   744 
   745 
   746 subsubsection {* Expressing set operations via @{const fold} *}
   747 
   748 lemma (in fun_left_comm) fun_left_comm_apply:
   749   "fun_left_comm (\<lambda>x. f (g x))"
   750 proof
   751 qed (simp_all add: fun_left_comm)
   752 
   753 lemma (in fun_left_comm_idem) fun_left_comm_idem_apply:
   754   "fun_left_comm_idem (\<lambda>x. f (g x))"
   755   by (rule fun_left_comm_idem.intro, rule fun_left_comm_apply, unfold_locales)
   756     (simp_all add: fun_left_idem)
   757 
   758 lemma fun_left_comm_idem_insert:
   759   "fun_left_comm_idem insert"
   760 proof
   761 qed auto
   762 
   763 lemma fun_left_comm_idem_remove:
   764   "fun_left_comm_idem (\<lambda>x A. A - {x})"
   765 proof
   766 qed auto
   767 
   768 lemma (in semilattice_inf) fun_left_comm_idem_inf:
   769   "fun_left_comm_idem inf"
   770 proof
   771 qed (auto simp add: inf_left_commute)
   772 
   773 lemma (in semilattice_sup) fun_left_comm_idem_sup:
   774   "fun_left_comm_idem sup"
   775 proof
   776 qed (auto simp add: sup_left_commute)
   777 
   778 lemma union_fold_insert:
   779   assumes "finite A"
   780   shows "A \<union> B = fold insert B A"
   781 proof -
   782   interpret fun_left_comm_idem insert by (fact fun_left_comm_idem_insert)
   783   from `finite A` show ?thesis by (induct A arbitrary: B) simp_all
   784 qed
   785 
   786 lemma minus_fold_remove:
   787   assumes "finite A"
   788   shows "B - A = fold (\<lambda>x A. A - {x}) B A"
   789 proof -
   790   interpret fun_left_comm_idem "\<lambda>x A. A - {x}" by (fact fun_left_comm_idem_remove)
   791   from `finite A` show ?thesis by (induct A arbitrary: B) auto
   792 qed
   793 
   794 context complete_lattice
   795 begin
   796 
   797 lemma inf_Inf_fold_inf:
   798   assumes "finite A"
   799   shows "inf B (Inf A) = fold inf B A"
   800 proof -
   801   interpret fun_left_comm_idem inf by (fact fun_left_comm_idem_inf)
   802   from `finite A` show ?thesis by (induct A arbitrary: B)
   803     (simp_all add: Inf_empty Inf_insert inf_commute fold_fun_comm)
   804 qed
   805 
   806 lemma sup_Sup_fold_sup:
   807   assumes "finite A"
   808   shows "sup B (Sup A) = fold sup B A"
   809 proof -
   810   interpret fun_left_comm_idem sup by (fact fun_left_comm_idem_sup)
   811   from `finite A` show ?thesis by (induct A arbitrary: B)
   812     (simp_all add: Sup_empty Sup_insert sup_commute fold_fun_comm)
   813 qed
   814 
   815 lemma Inf_fold_inf:
   816   assumes "finite A"
   817   shows "Inf A = fold inf top A"
   818   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
   819 
   820 lemma Sup_fold_sup:
   821   assumes "finite A"
   822   shows "Sup A = fold sup bot A"
   823   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
   824 
   825 lemma inf_INFI_fold_inf:
   826   assumes "finite A"
   827   shows "inf B (INFI A f) = fold (\<lambda>A. inf (f A)) B A" (is "?inf = ?fold") 
   828 proof (rule sym)
   829   interpret fun_left_comm_idem inf by (fact fun_left_comm_idem_inf)
   830   interpret fun_left_comm_idem "\<lambda>A. inf (f A)" by (fact fun_left_comm_idem_apply)
   831   from `finite A` show "?fold = ?inf"
   832   by (induct A arbitrary: B)
   833     (simp_all add: INFI_def Inf_empty Inf_insert inf_left_commute)
   834 qed
   835 
   836 lemma sup_SUPR_fold_sup:
   837   assumes "finite A"
   838   shows "sup B (SUPR A f) = fold (\<lambda>A. sup (f A)) B A" (is "?sup = ?fold") 
   839 proof (rule sym)
   840   interpret fun_left_comm_idem sup by (fact fun_left_comm_idem_sup)
   841   interpret fun_left_comm_idem "\<lambda>A. sup (f A)" by (fact fun_left_comm_idem_apply)
   842   from `finite A` show "?fold = ?sup"
   843   by (induct A arbitrary: B)
   844     (simp_all add: SUPR_def Sup_empty Sup_insert sup_left_commute)
   845 qed
   846 
   847 lemma INFI_fold_inf:
   848   assumes "finite A"
   849   shows "INFI A f = fold (\<lambda>A. inf (f A)) top A"
   850   using assms inf_INFI_fold_inf [of A top] by simp
   851 
   852 lemma SUPR_fold_sup:
   853   assumes "finite A"
   854   shows "SUPR A f = fold (\<lambda>A. sup (f A)) bot A"
   855   using assms sup_SUPR_fold_sup [of A bot] by simp
   856 
   857 end
   858 
   859 
   860 subsection {* The derived combinator @{text fold_image} *}
   861 
   862 definition fold_image :: "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b"
   863 where "fold_image f g = fold (%x y. f (g x) y)"
   864 
   865 lemma fold_image_empty[simp]: "fold_image f g z {} = z"
   866 by(simp add:fold_image_def)
   867 
   868 context ab_semigroup_mult
   869 begin
   870 
   871 lemma fold_image_insert[simp]:
   872 assumes "finite A" and "a \<notin> A"
   873 shows "fold_image times g z (insert a A) = g a * (fold_image times g z A)"
   874 proof -
   875   interpret I: fun_left_comm "%x y. (g x) * y"
   876     by unfold_locales (simp add: mult_ac)
   877   show ?thesis using assms by(simp add:fold_image_def)
   878 qed
   879 
   880 (*
   881 lemma fold_commute:
   882   "finite A ==> (!!z. x * (fold times g z A) = fold times g (x * z) A)"
   883   apply (induct set: finite)
   884    apply simp
   885   apply (simp add: mult_left_commute [of x])
   886   done
   887 
   888 lemma fold_nest_Un_Int:
   889   "finite A ==> finite B
   890     ==> fold times g (fold times g z B) A = fold times g (fold times g z (A Int B)) (A Un B)"
   891   apply (induct set: finite)
   892    apply simp
   893   apply (simp add: fold_commute Int_insert_left insert_absorb)
   894   done
   895 
   896 lemma fold_nest_Un_disjoint:
   897   "finite A ==> finite B ==> A Int B = {}
   898     ==> fold times g z (A Un B) = fold times g (fold times g z B) A"
   899   by (simp add: fold_nest_Un_Int)
   900 *)
   901 
   902 lemma fold_image_reindex:
   903 assumes fin: "finite A"
   904 shows "inj_on h A \<Longrightarrow> fold_image times g z (h`A) = fold_image times (g\<circ>h) z A"
   905 using fin by induct auto
   906 
   907 (*
   908 text{*
   909   Fusion theorem, as described in Graham Hutton's paper,
   910   A Tutorial on the Universality and Expressiveness of Fold,
   911   JFP 9:4 (355-372), 1999.
   912 *}
   913 
   914 lemma fold_fusion:
   915   assumes "ab_semigroup_mult g"
   916   assumes fin: "finite A"
   917     and hyp: "\<And>x y. h (g x y) = times x (h y)"
   918   shows "h (fold g j w A) = fold times j (h w) A"
   919 proof -
   920   class_interpret ab_semigroup_mult [g] by fact
   921   show ?thesis using fin hyp by (induct set: finite) simp_all
   922 qed
   923 *)
   924 
   925 lemma fold_image_cong:
   926   "finite A \<Longrightarrow>
   927   (!!x. x:A ==> g x = h x) ==> fold_image times g z A = fold_image times h z A"
   928 apply (subgoal_tac "ALL C. C <= A --> (ALL x:C. g x = h x) --> fold_image times g z C = fold_image times h z C")
   929  apply simp
   930 apply (erule finite_induct, simp)
   931 apply (simp add: subset_insert_iff, clarify)
   932 apply (subgoal_tac "finite C")
   933  prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
   934 apply (subgoal_tac "C = insert x (C - {x})")
   935  prefer 2 apply blast
   936 apply (erule ssubst)
   937 apply (drule spec)
   938 apply (erule (1) notE impE)
   939 apply (simp add: Ball_def del: insert_Diff_single)
   940 done
   941 
   942 end
   943 
   944 context comm_monoid_mult
   945 begin
   946 
   947 lemma fold_image_1:
   948   "finite S \<Longrightarrow> (\<forall>x\<in>S. f x = 1) \<Longrightarrow> fold_image op * f 1 S = 1"
   949   apply (induct set: finite)
   950   apply simp by auto
   951 
   952 lemma fold_image_Un_Int:
   953   "finite A ==> finite B ==>
   954     fold_image times g 1 A * fold_image times g 1 B =
   955     fold_image times g 1 (A Un B) * fold_image times g 1 (A Int B)"
   956 by (induct set: finite) 
   957    (auto simp add: mult_ac insert_absorb Int_insert_left)
   958 
   959 lemma fold_image_Un_one:
   960   assumes fS: "finite S" and fT: "finite T"
   961   and I0: "\<forall>x \<in> S\<inter>T. f x = 1"
   962   shows "fold_image (op *) f 1 (S \<union> T) = fold_image (op *) f 1 S * fold_image (op *) f 1 T"
   963 proof-
   964   have "fold_image op * f 1 (S \<inter> T) = 1" 
   965     apply (rule fold_image_1)
   966     using fS fT I0 by auto 
   967   with fold_image_Un_Int[OF fS fT] show ?thesis by simp
   968 qed
   969 
   970 corollary fold_Un_disjoint:
   971   "finite A ==> finite B ==> A Int B = {} ==>
   972    fold_image times g 1 (A Un B) =
   973    fold_image times g 1 A * fold_image times g 1 B"
   974 by (simp add: fold_image_Un_Int)
   975 
   976 lemma fold_image_UN_disjoint:
   977   "\<lbrakk> finite I; ALL i:I. finite (A i);
   978      ALL i:I. ALL j:I. i \<noteq> j --> A i Int A j = {} \<rbrakk>
   979    \<Longrightarrow> fold_image times g 1 (UNION I A) =
   980        fold_image times (%i. fold_image times g 1 (A i)) 1 I"
   981 apply (induct set: finite, simp, atomize)
   982 apply (subgoal_tac "ALL i:F. x \<noteq> i")
   983  prefer 2 apply blast
   984 apply (subgoal_tac "A x Int UNION F A = {}")
   985  prefer 2 apply blast
   986 apply (simp add: fold_Un_disjoint)
   987 done
   988 
   989 lemma fold_image_Sigma: "finite A ==> ALL x:A. finite (B x) ==>
   990   fold_image times (%x. fold_image times (g x) 1 (B x)) 1 A =
   991   fold_image times (split g) 1 (SIGMA x:A. B x)"
   992 apply (subst Sigma_def)
   993 apply (subst fold_image_UN_disjoint, assumption, simp)
   994  apply blast
   995 apply (erule fold_image_cong)
   996 apply (subst fold_image_UN_disjoint, simp, simp)
   997  apply blast
   998 apply simp
   999 done
  1000 
  1001 lemma fold_image_distrib: "finite A \<Longrightarrow>
  1002    fold_image times (%x. g x * h x) 1 A =
  1003    fold_image times g 1 A *  fold_image times h 1 A"
  1004 by (erule finite_induct) (simp_all add: mult_ac)
  1005 
  1006 lemma fold_image_related: 
  1007   assumes Re: "R e e" 
  1008   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1009   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1010   shows "R (fold_image (op *) h e S) (fold_image (op *) g e S)"
  1011   using fS by (rule finite_subset_induct) (insert assms, auto)
  1012 
  1013 lemma  fold_image_eq_general:
  1014   assumes fS: "finite S"
  1015   and h: "\<forall>y\<in>S'. \<exists>!x. x\<in> S \<and> h(x) = y" 
  1016   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2(h x) = f1 x"
  1017   shows "fold_image (op *) f1 e S = fold_image (op *) f2 e S'"
  1018 proof-
  1019   from h f12 have hS: "h ` S = S'" by auto
  1020   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1021     from f12 h H  have "x = y" by auto }
  1022   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1023   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1024   from hS have "fold_image (op *) f2 e S' = fold_image (op *) f2 e (h ` S)" by simp
  1025   also have "\<dots> = fold_image (op *) (f2 o h) e S" 
  1026     using fold_image_reindex[OF fS hinj, of f2 e] .
  1027   also have "\<dots> = fold_image (op *) f1 e S " using th fold_image_cong[OF fS, of "f2 o h" f1 e]
  1028     by blast
  1029   finally show ?thesis ..
  1030 qed
  1031 
  1032 lemma fold_image_eq_general_inverses:
  1033   assumes fS: "finite S" 
  1034   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1035   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x  \<and> g (h x) = f x"
  1036   shows "fold_image (op *) f e S = fold_image (op *) g e T"
  1037   (* metis solves it, but not yet available here *)
  1038   apply (rule fold_image_eq_general[OF fS, of T h g f e])
  1039   apply (rule ballI)
  1040   apply (frule kh)
  1041   apply (rule ex1I[])
  1042   apply blast
  1043   apply clarsimp
  1044   apply (drule hk) apply simp
  1045   apply (rule sym)
  1046   apply (erule conjunct1[OF conjunct2[OF hk]])
  1047   apply (rule ballI)
  1048   apply (drule  hk)
  1049   apply blast
  1050   done
  1051 
  1052 end
  1053 
  1054 
  1055 subsection {* A fold functional for non-empty sets *}
  1056 
  1057 text{* Does not require start value. *}
  1058 
  1059 inductive
  1060   fold1Set :: "('a => 'a => 'a) => 'a set => 'a => bool"
  1061   for f :: "'a => 'a => 'a"
  1062 where
  1063   fold1Set_insertI [intro]:
  1064    "\<lbrakk> fold_graph f a A x; a \<notin> A \<rbrakk> \<Longrightarrow> fold1Set f (insert a A) x"
  1065 
  1066 definition fold1 :: "('a => 'a => 'a) => 'a set => 'a" where
  1067   "fold1 f A == THE x. fold1Set f A x"
  1068 
  1069 lemma fold1Set_nonempty:
  1070   "fold1Set f A x \<Longrightarrow> A \<noteq> {}"
  1071 by(erule fold1Set.cases, simp_all)
  1072 
  1073 inductive_cases empty_fold1SetE [elim!]: "fold1Set f {} x"
  1074 
  1075 inductive_cases insert_fold1SetE [elim!]: "fold1Set f (insert a X) x"
  1076 
  1077 
  1078 lemma fold1Set_sing [iff]: "(fold1Set f {a} b) = (a = b)"
  1079 by (blast elim: fold_graph.cases)
  1080 
  1081 lemma fold1_singleton [simp]: "fold1 f {a} = a"
  1082 by (unfold fold1_def) blast
  1083 
  1084 lemma finite_nonempty_imp_fold1Set:
  1085   "\<lbrakk> finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> EX x. fold1Set f A x"
  1086 apply (induct A rule: finite_induct)
  1087 apply (auto dest: finite_imp_fold_graph [of _ f])
  1088 done
  1089 
  1090 text{*First, some lemmas about @{const fold_graph}.*}
  1091 
  1092 context ab_semigroup_mult
  1093 begin
  1094 
  1095 lemma fun_left_comm: "fun_left_comm(op *)"
  1096 by unfold_locales (simp add: mult_ac)
  1097 
  1098 lemma fold_graph_insert_swap:
  1099 assumes fold: "fold_graph times (b::'a) A y" and "b \<notin> A"
  1100 shows "fold_graph times z (insert b A) (z * y)"
  1101 proof -
  1102   interpret fun_left_comm "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule fun_left_comm)
  1103 from assms show ?thesis
  1104 proof (induct rule: fold_graph.induct)
  1105   case emptyI show ?case by (subst mult_commute [of z b], fast)
  1106 next
  1107   case (insertI x A y)
  1108     have "fold_graph times z (insert x (insert b A)) (x * (z * y))"
  1109       using insertI by force  --{*how does @{term id} get unfolded?*}
  1110     thus ?case by (simp add: insert_commute mult_ac)
  1111 qed
  1112 qed
  1113 
  1114 lemma fold_graph_permute_diff:
  1115 assumes fold: "fold_graph times b A x"
  1116 shows "!!a. \<lbrakk>a \<in> A; b \<notin> A\<rbrakk> \<Longrightarrow> fold_graph times a (insert b (A-{a})) x"
  1117 using fold
  1118 proof (induct rule: fold_graph.induct)
  1119   case emptyI thus ?case by simp
  1120 next
  1121   case (insertI x A y)
  1122   have "a = x \<or> a \<in> A" using insertI by simp
  1123   thus ?case
  1124   proof
  1125     assume "a = x"
  1126     with insertI show ?thesis
  1127       by (simp add: id_def [symmetric], blast intro: fold_graph_insert_swap)
  1128   next
  1129     assume ainA: "a \<in> A"
  1130     hence "fold_graph times a (insert x (insert b (A - {a}))) (x * y)"
  1131       using insertI by force
  1132     moreover
  1133     have "insert x (insert b (A - {a})) = insert b (insert x A - {a})"
  1134       using ainA insertI by blast
  1135     ultimately show ?thesis by simp
  1136   qed
  1137 qed
  1138 
  1139 lemma fold1_eq_fold:
  1140 assumes "finite A" "a \<notin> A" shows "fold1 times (insert a A) = fold times a A"
  1141 proof -
  1142   interpret fun_left_comm "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule fun_left_comm)
  1143   from assms show ?thesis
  1144 apply (simp add: fold1_def fold_def)
  1145 apply (rule the_equality)
  1146 apply (best intro: fold_graph_determ theI dest: finite_imp_fold_graph [of _ times])
  1147 apply (rule sym, clarify)
  1148 apply (case_tac "Aa=A")
  1149  apply (best intro: fold_graph_determ)
  1150 apply (subgoal_tac "fold_graph times a A x")
  1151  apply (best intro: fold_graph_determ)
  1152 apply (subgoal_tac "insert aa (Aa - {a}) = A")
  1153  prefer 2 apply (blast elim: equalityE)
  1154 apply (auto dest: fold_graph_permute_diff [where a=a])
  1155 done
  1156 qed
  1157 
  1158 lemma nonempty_iff: "(A \<noteq> {}) = (\<exists>x B. A = insert x B & x \<notin> B)"
  1159 apply safe
  1160  apply simp
  1161  apply (drule_tac x=x in spec)
  1162  apply (drule_tac x="A-{x}" in spec, auto)
  1163 done
  1164 
  1165 lemma fold1_insert:
  1166   assumes nonempty: "A \<noteq> {}" and A: "finite A" "x \<notin> A"
  1167   shows "fold1 times (insert x A) = x * fold1 times A"
  1168 proof -
  1169   interpret fun_left_comm "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a" by (rule fun_left_comm)
  1170   from nonempty obtain a A' where "A = insert a A' & a ~: A'"
  1171     by (auto simp add: nonempty_iff)
  1172   with A show ?thesis
  1173     by (simp add: insert_commute [of x] fold1_eq_fold eq_commute)
  1174 qed
  1175 
  1176 end
  1177 
  1178 context ab_semigroup_idem_mult
  1179 begin
  1180 
  1181 lemma fun_left_comm_idem: "fun_left_comm_idem(op *)"
  1182 apply unfold_locales
  1183  apply (rule mult_left_commute)
  1184 apply (rule mult_left_idem)
  1185 done
  1186 
  1187 lemma fold1_insert_idem [simp]:
  1188   assumes nonempty: "A \<noteq> {}" and A: "finite A" 
  1189   shows "fold1 times (insert x A) = x * fold1 times A"
  1190 proof -
  1191   interpret fun_left_comm_idem "op *::'a \<Rightarrow> 'a \<Rightarrow> 'a"
  1192     by (rule fun_left_comm_idem)
  1193   from nonempty obtain a A' where A': "A = insert a A' & a ~: A'"
  1194     by (auto simp add: nonempty_iff)
  1195   show ?thesis
  1196   proof cases
  1197     assume "a = x"
  1198     thus ?thesis
  1199     proof cases
  1200       assume "A' = {}"
  1201       with prems show ?thesis by simp
  1202     next
  1203       assume "A' \<noteq> {}"
  1204       with prems show ?thesis
  1205         by (simp add: fold1_insert mult_assoc [symmetric])
  1206     qed
  1207   next
  1208     assume "a \<noteq> x"
  1209     with prems show ?thesis
  1210       by (simp add: insert_commute fold1_eq_fold)
  1211   qed
  1212 qed
  1213 
  1214 lemma hom_fold1_commute:
  1215 assumes hom: "!!x y. h (x * y) = h x * h y"
  1216 and N: "finite N" "N \<noteq> {}" shows "h (fold1 times N) = fold1 times (h ` N)"
  1217 using N proof (induct rule: finite_ne_induct)
  1218   case singleton thus ?case by simp
  1219 next
  1220   case (insert n N)
  1221   then have "h (fold1 times (insert n N)) = h (n * fold1 times N)" by simp
  1222   also have "\<dots> = h n * h (fold1 times N)" by(rule hom)
  1223   also have "h (fold1 times N) = fold1 times (h ` N)" by(rule insert)
  1224   also have "times (h n) \<dots> = fold1 times (insert (h n) (h ` N))"
  1225     using insert by(simp)
  1226   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1227   finally show ?case .
  1228 qed
  1229 
  1230 lemma fold1_eq_fold_idem:
  1231   assumes "finite A"
  1232   shows "fold1 times (insert a A) = fold times a A"
  1233 proof (cases "a \<in> A")
  1234   case False
  1235   with assms show ?thesis by (simp add: fold1_eq_fold)
  1236 next
  1237   interpret fun_left_comm_idem times by (fact fun_left_comm_idem)
  1238   case True then obtain b B
  1239     where A: "A = insert a B" and "a \<notin> B" by (rule set_insert)
  1240   with assms have "finite B" by auto
  1241   then have "fold times a (insert a B) = fold times (a * a) B"
  1242     using `a \<notin> B` by (rule fold_insert2)
  1243   then show ?thesis
  1244     using `a \<notin> B` `finite B` by (simp add: fold1_eq_fold A)
  1245 qed
  1246 
  1247 end
  1248 
  1249 
  1250 text{* Now the recursion rules for definitions: *}
  1251 
  1252 lemma fold1_singleton_def: "g = fold1 f \<Longrightarrow> g {a} = a"
  1253 by simp
  1254 
  1255 lemma (in ab_semigroup_mult) fold1_insert_def:
  1256   "\<lbrakk> g = fold1 times; finite A; x \<notin> A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1257 by (simp add:fold1_insert)
  1258 
  1259 lemma (in ab_semigroup_idem_mult) fold1_insert_idem_def:
  1260   "\<lbrakk> g = fold1 times; finite A; A \<noteq> {} \<rbrakk> \<Longrightarrow> g (insert x A) = x * g A"
  1261 by simp
  1262 
  1263 subsubsection{* Determinacy for @{term fold1Set} *}
  1264 
  1265 (*Not actually used!!*)
  1266 (*
  1267 context ab_semigroup_mult
  1268 begin
  1269 
  1270 lemma fold_graph_permute:
  1271   "[|fold_graph times id b (insert a A) x; a \<notin> A; b \<notin> A|]
  1272    ==> fold_graph times id a (insert b A) x"
  1273 apply (cases "a=b") 
  1274 apply (auto dest: fold_graph_permute_diff) 
  1275 done
  1276 
  1277 lemma fold1Set_determ:
  1278   "fold1Set times A x ==> fold1Set times A y ==> y = x"
  1279 proof (clarify elim!: fold1Set.cases)
  1280   fix A x B y a b
  1281   assume Ax: "fold_graph times id a A x"
  1282   assume By: "fold_graph times id b B y"
  1283   assume anotA:  "a \<notin> A"
  1284   assume bnotB:  "b \<notin> B"
  1285   assume eq: "insert a A = insert b B"
  1286   show "y=x"
  1287   proof cases
  1288     assume same: "a=b"
  1289     hence "A=B" using anotA bnotB eq by (blast elim!: equalityE)
  1290     thus ?thesis using Ax By same by (blast intro: fold_graph_determ)
  1291   next
  1292     assume diff: "a\<noteq>b"
  1293     let ?D = "B - {a}"
  1294     have B: "B = insert a ?D" and A: "A = insert b ?D"
  1295      and aB: "a \<in> B" and bA: "b \<in> A"
  1296       using eq anotA bnotB diff by (blast elim!:equalityE)+
  1297     with aB bnotB By
  1298     have "fold_graph times id a (insert b ?D) y" 
  1299       by (auto intro: fold_graph_permute simp add: insert_absorb)
  1300     moreover
  1301     have "fold_graph times id a (insert b ?D) x"
  1302       by (simp add: A [symmetric] Ax) 
  1303     ultimately show ?thesis by (blast intro: fold_graph_determ) 
  1304   qed
  1305 qed
  1306 
  1307 lemma fold1Set_equality: "fold1Set times A y ==> fold1 times A = y"
  1308   by (unfold fold1_def) (blast intro: fold1Set_determ)
  1309 
  1310 end
  1311 *)
  1312 
  1313 declare
  1314   empty_fold_graphE [rule del]  fold_graph.intros [rule del]
  1315   empty_fold1SetE [rule del]  insert_fold1SetE [rule del]
  1316   -- {* No more proofs involve these relations. *}
  1317 
  1318 subsubsection {* Lemmas about @{text fold1} *}
  1319 
  1320 context ab_semigroup_mult
  1321 begin
  1322 
  1323 lemma fold1_Un:
  1324 assumes A: "finite A" "A \<noteq> {}"
  1325 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow> A Int B = {} \<Longrightarrow>
  1326        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1327 using A by (induct rule: finite_ne_induct)
  1328   (simp_all add: fold1_insert mult_assoc)
  1329 
  1330 lemma fold1_in:
  1331   assumes A: "finite (A)" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x,y}"
  1332   shows "fold1 times A \<in> A"
  1333 using A
  1334 proof (induct rule:finite_ne_induct)
  1335   case singleton thus ?case by simp
  1336 next
  1337   case insert thus ?case using elem by (force simp add:fold1_insert)
  1338 qed
  1339 
  1340 end
  1341 
  1342 lemma (in ab_semigroup_idem_mult) fold1_Un2:
  1343 assumes A: "finite A" "A \<noteq> {}"
  1344 shows "finite B \<Longrightarrow> B \<noteq> {} \<Longrightarrow>
  1345        fold1 times (A Un B) = fold1 times A * fold1 times B"
  1346 using A
  1347 proof(induct rule:finite_ne_induct)
  1348   case singleton thus ?case by simp
  1349 next
  1350   case insert thus ?case by (simp add: mult_assoc)
  1351 qed
  1352 
  1353 
  1354 subsection {* Locales as mini-packages for fold operations *}
  1355 
  1356 subsubsection {* The natural case *}
  1357 
  1358 locale folding =
  1359   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1360   fixes F :: "'a set \<Rightarrow> 'b \<Rightarrow> 'b"
  1361   assumes commute_comp: "f y \<circ> f x = f x \<circ> f y"
  1362   assumes eq_fold: "finite A \<Longrightarrow> F A s = fold f s A"
  1363 begin
  1364 
  1365 lemma empty [simp]:
  1366   "F {} = id"
  1367   by (simp add: eq_fold fun_eq_iff)
  1368 
  1369 lemma insert [simp]:
  1370   assumes "finite A" and "x \<notin> A"
  1371   shows "F (insert x A) = F A \<circ> f x"
  1372 proof -
  1373   interpret fun_left_comm f proof
  1374   qed (insert commute_comp, simp add: fun_eq_iff)
  1375   from fold_insert2 assms
  1376   have "\<And>s. fold f s (insert x A) = fold f (f x s) A" .
  1377   with `finite A` show ?thesis by (simp add: eq_fold fun_eq_iff)
  1378 qed
  1379 
  1380 lemma remove:
  1381   assumes "finite A" and "x \<in> A"
  1382   shows "F A = F (A - {x}) \<circ> f x"
  1383 proof -
  1384   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1385     by (auto dest: mk_disjoint_insert)
  1386   moreover from `finite A` this have "finite B" by simp
  1387   ultimately show ?thesis by simp
  1388 qed
  1389 
  1390 lemma insert_remove:
  1391   assumes "finite A"
  1392   shows "F (insert x A) = F (A - {x}) \<circ> f x"
  1393   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1394 
  1395 lemma commute_left_comp:
  1396   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
  1397   by (simp add: o_assoc commute_comp)
  1398 
  1399 lemma commute_comp':
  1400   assumes "finite A"
  1401   shows "f x \<circ> F A = F A \<circ> f x"
  1402   using assms by (induct A)
  1403     (simp, simp del: o_apply add: o_assoc, simp del: o_apply add: o_assoc [symmetric] commute_comp)
  1404 
  1405 lemma commute_left_comp':
  1406   assumes "finite A"
  1407   shows "f x \<circ> (F A \<circ> g) = F A \<circ> (f x \<circ> g)"
  1408   using assms by (simp add: o_assoc commute_comp')
  1409 
  1410 lemma commute_comp'':
  1411   assumes "finite A" and "finite B"
  1412   shows "F B \<circ> F A = F A \<circ> F B"
  1413   using assms by (induct A)
  1414     (simp_all add: o_assoc, simp add: o_assoc [symmetric] commute_comp')
  1415 
  1416 lemma commute_left_comp'':
  1417   assumes "finite A" and "finite B"
  1418   shows "F B \<circ> (F A \<circ> g) = F A \<circ> (F B \<circ> g)"
  1419   using assms by (simp add: o_assoc commute_comp'')
  1420 
  1421 lemmas commute_comps = o_assoc [symmetric] commute_comp commute_left_comp
  1422   commute_comp' commute_left_comp' commute_comp'' commute_left_comp''
  1423 
  1424 lemma union_inter:
  1425   assumes "finite A" and "finite B"
  1426   shows "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B"
  1427   using assms by (induct A)
  1428     (simp_all del: o_apply add: insert_absorb Int_insert_left commute_comps,
  1429       simp add: o_assoc)
  1430 
  1431 lemma union:
  1432   assumes "finite A" and "finite B"
  1433   and "A \<inter> B = {}"
  1434   shows "F (A \<union> B) = F A \<circ> F B"
  1435 proof -
  1436   from union_inter `finite A` `finite B` have "F (A \<union> B) \<circ> F (A \<inter> B) = F A \<circ> F B" .
  1437   with `A \<inter> B = {}` show ?thesis by simp
  1438 qed
  1439 
  1440 end
  1441 
  1442 
  1443 subsubsection {* The natural case with idempotency *}
  1444 
  1445 locale folding_idem = folding +
  1446   assumes idem_comp: "f x \<circ> f x = f x"
  1447 begin
  1448 
  1449 lemma idem_left_comp:
  1450   "f x \<circ> (f x \<circ> g) = f x \<circ> g"
  1451   by (simp add: o_assoc idem_comp)
  1452 
  1453 lemma in_comp_idem:
  1454   assumes "finite A" and "x \<in> A"
  1455   shows "F A \<circ> f x = F A"
  1456 using assms by (induct A)
  1457   (auto simp add: commute_comps idem_comp, simp add: commute_left_comp' [symmetric] commute_comp')
  1458 
  1459 lemma subset_comp_idem:
  1460   assumes "finite A" and "B \<subseteq> A"
  1461   shows "F A \<circ> F B = F A"
  1462 proof -
  1463   from assms have "finite B" by (blast dest: finite_subset)
  1464   then show ?thesis using `B \<subseteq> A` by (induct B)
  1465     (simp_all add: o_assoc in_comp_idem `finite A`)
  1466 qed
  1467 
  1468 declare insert [simp del]
  1469 
  1470 lemma insert_idem [simp]:
  1471   assumes "finite A"
  1472   shows "F (insert x A) = F A \<circ> f x"
  1473   using assms by (cases "x \<in> A") (simp_all add: insert in_comp_idem insert_absorb)
  1474 
  1475 lemma union_idem:
  1476   assumes "finite A" and "finite B"
  1477   shows "F (A \<union> B) = F A \<circ> F B"
  1478 proof -
  1479   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1480   then have "F (A \<union> B) \<circ> F (A \<inter> B) = F (A \<union> B)" by (rule subset_comp_idem)
  1481   with assms show ?thesis by (simp add: union_inter)
  1482 qed
  1483 
  1484 end
  1485 
  1486 
  1487 subsubsection {* The image case with fixed function *}
  1488 
  1489 no_notation times (infixl "*" 70)
  1490 no_notation Groups.one ("1")
  1491 
  1492 locale folding_image_simple = comm_monoid +
  1493   fixes g :: "('b \<Rightarrow> 'a)"
  1494   fixes F :: "'b set \<Rightarrow> 'a"
  1495   assumes eq_fold_g: "finite A \<Longrightarrow> F A = fold_image f g 1 A"
  1496 begin
  1497 
  1498 lemma empty [simp]:
  1499   "F {} = 1"
  1500   by (simp add: eq_fold_g)
  1501 
  1502 lemma insert [simp]:
  1503   assumes "finite A" and "x \<notin> A"
  1504   shows "F (insert x A) = g x * F A"
  1505 proof -
  1506   interpret fun_left_comm "%x y. (g x) * y" proof
  1507   qed (simp add: ac_simps)
  1508   with assms have "fold_image (op *) g 1 (insert x A) = g x * fold_image (op *) g 1 A"
  1509     by (simp add: fold_image_def)
  1510   with `finite A` show ?thesis by (simp add: eq_fold_g)
  1511 qed
  1512 
  1513 lemma remove:
  1514   assumes "finite A" and "x \<in> A"
  1515   shows "F A = g x * F (A - {x})"
  1516 proof -
  1517   from `x \<in> A` obtain B where A: "A = insert x B" and "x \<notin> B"
  1518     by (auto dest: mk_disjoint_insert)
  1519   moreover from `finite A` this have "finite B" by simp
  1520   ultimately show ?thesis by simp
  1521 qed
  1522 
  1523 lemma insert_remove:
  1524   assumes "finite A"
  1525   shows "F (insert x A) = g x * F (A - {x})"
  1526   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1527 
  1528 lemma neutral:
  1529   assumes "finite A" and "\<forall>x\<in>A. g x = 1"
  1530   shows "F A = 1"
  1531   using assms by (induct A) simp_all
  1532 
  1533 lemma union_inter:
  1534   assumes "finite A" and "finite B"
  1535   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1536 using assms proof (induct A)
  1537   case empty then show ?case by simp
  1538 next
  1539   case (insert x A) then show ?case
  1540     by (auto simp add: insert_absorb Int_insert_left commute [of _ "g x"] assoc left_commute)
  1541 qed
  1542 
  1543 corollary union_inter_neutral:
  1544   assumes "finite A" and "finite B"
  1545   and I0: "\<forall>x \<in> A\<inter>B. g x = 1"
  1546   shows "F (A \<union> B) = F A * F B"
  1547   using assms by (simp add: union_inter [symmetric] neutral)
  1548 
  1549 corollary union_disjoint:
  1550   assumes "finite A" and "finite B"
  1551   assumes "A \<inter> B = {}"
  1552   shows "F (A \<union> B) = F A * F B"
  1553   using assms by (simp add: union_inter_neutral)
  1554 
  1555 end
  1556 
  1557 
  1558 subsubsection {* The image case with flexible function *}
  1559 
  1560 locale folding_image = comm_monoid +
  1561   fixes F :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b set \<Rightarrow> 'a"
  1562   assumes eq_fold: "\<And>g. finite A \<Longrightarrow> F g A = fold_image f g 1 A"
  1563 
  1564 sublocale folding_image < folding_image_simple "op *" 1 g "F g" proof
  1565 qed (fact eq_fold)
  1566 
  1567 context folding_image
  1568 begin
  1569 
  1570 lemma reindex: (* FIXME polymorhism *)
  1571   assumes "finite A" and "inj_on h A"
  1572   shows "F g (h ` A) = F (g \<circ> h) A"
  1573   using assms by (induct A) auto
  1574 
  1575 lemma cong:
  1576   assumes "finite A" and "\<And>x. x \<in> A \<Longrightarrow> g x = h x"
  1577   shows "F g A = F h A"
  1578 proof -
  1579   from assms have "ALL C. C <= A --> (ALL x:C. g x = h x) --> F g C = F h C"
  1580   apply - apply (erule finite_induct) apply simp
  1581   apply (simp add: subset_insert_iff, clarify)
  1582   apply (subgoal_tac "finite C")
  1583   prefer 2 apply (blast dest: finite_subset [COMP swap_prems_rl])
  1584   apply (subgoal_tac "C = insert x (C - {x})")
  1585   prefer 2 apply blast
  1586   apply (erule ssubst)
  1587   apply (drule spec)
  1588   apply (erule (1) notE impE)
  1589   apply (simp add: Ball_def del: insert_Diff_single)
  1590   done
  1591   with assms show ?thesis by simp
  1592 qed
  1593 
  1594 lemma UNION_disjoint:
  1595   assumes "finite I" and "\<forall>i\<in>I. finite (A i)"
  1596   and "\<forall>i\<in>I. \<forall>j\<in>I. i \<noteq> j \<longrightarrow> A i \<inter> A j = {}"
  1597   shows "F g (UNION I A) = F (F g \<circ> A) I"
  1598 apply (insert assms)
  1599 apply (induct set: finite, simp, atomize)
  1600 apply (subgoal_tac "\<forall>i\<in>Fa. x \<noteq> i")
  1601  prefer 2 apply blast
  1602 apply (subgoal_tac "A x Int UNION Fa A = {}")
  1603  prefer 2 apply blast
  1604 apply (simp add: union_disjoint)
  1605 done
  1606 
  1607 lemma distrib:
  1608   assumes "finite A"
  1609   shows "F (\<lambda>x. g x * h x) A = F g A * F h A"
  1610   using assms by (rule finite_induct) (simp_all add: assoc commute left_commute)
  1611 
  1612 lemma related: 
  1613   assumes Re: "R 1 1" 
  1614   and Rop: "\<forall>x1 y1 x2 y2. R x1 x2 \<and> R y1 y2 \<longrightarrow> R (x1 * y1) (x2 * y2)" 
  1615   and fS: "finite S" and Rfg: "\<forall>x\<in>S. R (h x) (g x)"
  1616   shows "R (F h S) (F g S)"
  1617   using fS by (rule finite_subset_induct) (insert assms, auto)
  1618 
  1619 lemma eq_general:
  1620   assumes fS: "finite S"
  1621   and h: "\<forall>y\<in>S'. \<exists>!x. x \<in> S \<and> h x = y" 
  1622   and f12:  "\<forall>x\<in>S. h x \<in> S' \<and> f2 (h x) = f1 x"
  1623   shows "F f1 S = F f2 S'"
  1624 proof-
  1625   from h f12 have hS: "h ` S = S'" by blast
  1626   {fix x y assume H: "x \<in> S" "y \<in> S" "h x = h y"
  1627     from f12 h H  have "x = y" by auto }
  1628   hence hinj: "inj_on h S" unfolding inj_on_def Ex1_def by blast
  1629   from f12 have th: "\<And>x. x \<in> S \<Longrightarrow> (f2 \<circ> h) x = f1 x" by auto 
  1630   from hS have "F f2 S' = F f2 (h ` S)" by simp
  1631   also have "\<dots> = F (f2 o h) S" using reindex [OF fS hinj, of f2] .
  1632   also have "\<dots> = F f1 S " using th cong [OF fS, of "f2 o h" f1]
  1633     by blast
  1634   finally show ?thesis ..
  1635 qed
  1636 
  1637 lemma eq_general_inverses:
  1638   assumes fS: "finite S" 
  1639   and kh: "\<And>y. y \<in> T \<Longrightarrow> k y \<in> S \<and> h (k y) = y"
  1640   and hk: "\<And>x. x \<in> S \<Longrightarrow> h x \<in> T \<and> k (h x) = x \<and> g (h x) = j x"
  1641   shows "F j S = F g T"
  1642   (* metis solves it, but not yet available here *)
  1643   apply (rule eq_general [OF fS, of T h g j])
  1644   apply (rule ballI)
  1645   apply (frule kh)
  1646   apply (rule ex1I[])
  1647   apply blast
  1648   apply clarsimp
  1649   apply (drule hk) apply simp
  1650   apply (rule sym)
  1651   apply (erule conjunct1[OF conjunct2[OF hk]])
  1652   apply (rule ballI)
  1653   apply (drule hk)
  1654   apply blast
  1655   done
  1656 
  1657 end
  1658 
  1659 
  1660 subsubsection {* The image case with fixed function and idempotency *}
  1661 
  1662 locale folding_image_simple_idem = folding_image_simple +
  1663   assumes idem: "x * x = x"
  1664 
  1665 sublocale folding_image_simple_idem < semilattice proof
  1666 qed (fact idem)
  1667 
  1668 context folding_image_simple_idem
  1669 begin
  1670 
  1671 lemma in_idem:
  1672   assumes "finite A" and "x \<in> A"
  1673   shows "g x * F A = F A"
  1674   using assms by (induct A) (auto simp add: left_commute)
  1675 
  1676 lemma subset_idem:
  1677   assumes "finite A" and "B \<subseteq> A"
  1678   shows "F B * F A = F A"
  1679 proof -
  1680   from assms have "finite B" by (blast dest: finite_subset)
  1681   then show ?thesis using `B \<subseteq> A` by (induct B)
  1682     (auto simp add: assoc in_idem `finite A`)
  1683 qed
  1684 
  1685 declare insert [simp del]
  1686 
  1687 lemma insert_idem [simp]:
  1688   assumes "finite A"
  1689   shows "F (insert x A) = g x * F A"
  1690   using assms by (cases "x \<in> A") (simp_all add: insert in_idem insert_absorb)
  1691 
  1692 lemma union_idem:
  1693   assumes "finite A" and "finite B"
  1694   shows "F (A \<union> B) = F A * F B"
  1695 proof -
  1696   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1697   then have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (rule subset_idem)
  1698   with assms show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1699 qed
  1700 
  1701 end
  1702 
  1703 
  1704 subsubsection {* The image case with flexible function and idempotency *}
  1705 
  1706 locale folding_image_idem = folding_image +
  1707   assumes idem: "x * x = x"
  1708 
  1709 sublocale folding_image_idem < folding_image_simple_idem "op *" 1 g "F g" proof
  1710 qed (fact idem)
  1711 
  1712 
  1713 subsubsection {* The neutral-less case *}
  1714 
  1715 locale folding_one = abel_semigroup +
  1716   fixes F :: "'a set \<Rightarrow> 'a"
  1717   assumes eq_fold: "finite A \<Longrightarrow> F A = fold1 f A"
  1718 begin
  1719 
  1720 lemma singleton [simp]:
  1721   "F {x} = x"
  1722   by (simp add: eq_fold)
  1723 
  1724 lemma eq_fold':
  1725   assumes "finite A" and "x \<notin> A"
  1726   shows "F (insert x A) = fold (op *) x A"
  1727 proof -
  1728   interpret ab_semigroup_mult "op *" proof qed (simp_all add: ac_simps)
  1729   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold)
  1730 qed
  1731 
  1732 lemma insert [simp]:
  1733   assumes "finite A" and "x \<notin> A" and "A \<noteq> {}"
  1734   shows "F (insert x A) = x * F A"
  1735 proof -
  1736   from `A \<noteq> {}` obtain b where "b \<in> A" by blast
  1737   then obtain B where *: "A = insert b B" "b \<notin> B" by (blast dest: mk_disjoint_insert)
  1738   with `finite A` have "finite B" by simp
  1739   interpret fold: folding "op *" "\<lambda>a b. fold (op *) b a" proof
  1740   qed (simp_all add: fun_eq_iff ac_simps)
  1741   thm fold.commute_comp' [of B b, simplified fun_eq_iff, simplified]
  1742   from `finite B` fold.commute_comp' [of B x]
  1743     have "op * x \<circ> (\<lambda>b. fold op * b B) = (\<lambda>b. fold op * b B) \<circ> op * x" by simp
  1744   then have A: "x * fold op * b B = fold op * (b * x) B" by (simp add: fun_eq_iff commute)
  1745   from `finite B` * fold.insert [of B b]
  1746     have "(\<lambda>x. fold op * x (insert b B)) = (\<lambda>x. fold op * x B) \<circ> op * b" by simp
  1747   then have B: "fold op * x (insert b B) = fold op * (b * x) B" by (simp add: fun_eq_iff)
  1748   from A B assms * show ?thesis by (simp add: eq_fold' del: fold.insert)
  1749 qed
  1750 
  1751 lemma remove:
  1752   assumes "finite A" and "x \<in> A"
  1753   shows "F A = (if A - {x} = {} then x else x * F (A - {x}))"
  1754 proof -
  1755   from assms obtain B where "A = insert x B" and "x \<notin> B" by (blast dest: mk_disjoint_insert)
  1756   with assms show ?thesis by simp
  1757 qed
  1758 
  1759 lemma insert_remove:
  1760   assumes "finite A"
  1761   shows "F (insert x A) = (if A - {x} = {} then x else x * F (A - {x}))"
  1762   using assms by (cases "x \<in> A") (simp_all add: insert_absorb remove)
  1763 
  1764 lemma union_disjoint:
  1765   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}" and "A \<inter> B = {}"
  1766   shows "F (A \<union> B) = F A * F B"
  1767   using assms by (induct A rule: finite_ne_induct) (simp_all add: ac_simps)
  1768 
  1769 lemma union_inter:
  1770   assumes "finite A" and "finite B" and "A \<inter> B \<noteq> {}"
  1771   shows "F (A \<union> B) * F (A \<inter> B) = F A * F B"
  1772 proof -
  1773   from assms have "A \<noteq> {}" and "B \<noteq> {}" by auto
  1774   from `finite A` `A \<noteq> {}` `A \<inter> B \<noteq> {}` show ?thesis proof (induct A rule: finite_ne_induct)
  1775     case (singleton x) then show ?case by (simp add: insert_absorb ac_simps)
  1776   next
  1777     case (insert x A) show ?case proof (cases "x \<in> B")
  1778       case True then have "B \<noteq> {}" by auto
  1779       with insert True `finite B` show ?thesis by (cases "A \<inter> B = {}")
  1780         (simp_all add: insert_absorb ac_simps union_disjoint)
  1781     next
  1782       case False with insert have "F (A \<union> B) * F (A \<inter> B) = F A * F B" by simp
  1783       moreover from False `finite B` insert have "finite (A \<union> B)" "x \<notin> A \<union> B" "A \<union> B \<noteq> {}"
  1784         by auto
  1785       ultimately show ?thesis using False `finite A` `x \<notin> A` `A \<noteq> {}` by (simp add: assoc)
  1786     qed
  1787   qed
  1788 qed
  1789 
  1790 lemma closed:
  1791   assumes "finite A" "A \<noteq> {}" and elem: "\<And>x y. x * y \<in> {x, y}"
  1792   shows "F A \<in> A"
  1793 using `finite A` `A \<noteq> {}` proof (induct rule: finite_ne_induct)
  1794   case singleton then show ?case by simp
  1795 next
  1796   case insert with elem show ?case by force
  1797 qed
  1798 
  1799 end
  1800 
  1801 
  1802 subsubsection {* The neutral-less case with idempotency *}
  1803 
  1804 locale folding_one_idem = folding_one +
  1805   assumes idem: "x * x = x"
  1806 
  1807 sublocale folding_one_idem < semilattice proof
  1808 qed (fact idem)
  1809 
  1810 context folding_one_idem
  1811 begin
  1812 
  1813 lemma in_idem:
  1814   assumes "finite A" and "x \<in> A"
  1815   shows "x * F A = F A"
  1816 proof -
  1817   from assms have "A \<noteq> {}" by auto
  1818   with `finite A` show ?thesis using `x \<in> A` by (induct A rule: finite_ne_induct) (auto simp add: ac_simps)
  1819 qed
  1820 
  1821 lemma subset_idem:
  1822   assumes "finite A" "B \<noteq> {}" and "B \<subseteq> A"
  1823   shows "F B * F A = F A"
  1824 proof -
  1825   from assms have "finite B" by (blast dest: finite_subset)
  1826   then show ?thesis using `B \<noteq> {}` `B \<subseteq> A` by (induct B rule: finite_ne_induct)
  1827     (simp_all add: assoc in_idem `finite A`)
  1828 qed
  1829 
  1830 lemma eq_fold_idem':
  1831   assumes "finite A"
  1832   shows "F (insert a A) = fold (op *) a A"
  1833 proof -
  1834   interpret ab_semigroup_idem_mult "op *" proof qed (simp_all add: ac_simps)
  1835   with assms show ?thesis by (simp add: eq_fold fold1_eq_fold_idem)
  1836 qed
  1837 
  1838 lemma insert_idem [simp]:
  1839   assumes "finite A" and "A \<noteq> {}"
  1840   shows "F (insert x A) = x * F A"
  1841 proof (cases "x \<in> A")
  1842   case False from `finite A` `x \<notin> A` `A \<noteq> {}` show ?thesis by (rule insert)
  1843 next
  1844   case True
  1845   from `finite A` `A \<noteq> {}` show ?thesis by (simp add: in_idem insert_absorb True)
  1846 qed
  1847   
  1848 lemma union_idem:
  1849   assumes "finite A" "A \<noteq> {}" and "finite B" "B \<noteq> {}"
  1850   shows "F (A \<union> B) = F A * F B"
  1851 proof (cases "A \<inter> B = {}")
  1852   case True with assms show ?thesis by (simp add: union_disjoint)
  1853 next
  1854   case False
  1855   from assms have "finite (A \<union> B)" and "A \<inter> B \<subseteq> A \<union> B" by auto
  1856   with False have "F (A \<inter> B) * F (A \<union> B) = F (A \<union> B)" by (auto intro: subset_idem)
  1857   with assms False show ?thesis by (simp add: union_inter [of A B, symmetric] commute)
  1858 qed
  1859 
  1860 lemma hom_commute:
  1861   assumes hom: "\<And>x y. h (x * y) = h x * h y"
  1862   and N: "finite N" "N \<noteq> {}" shows "h (F N) = F (h ` N)"
  1863 using N proof (induct rule: finite_ne_induct)
  1864   case singleton thus ?case by simp
  1865 next
  1866   case (insert n N)
  1867   then have "h (F (insert n N)) = h (n * F N)" by simp
  1868   also have "\<dots> = h n * h (F N)" by (rule hom)
  1869   also have "h (F N) = F (h ` N)" by(rule insert)
  1870   also have "h n * \<dots> = F (insert (h n) (h ` N))"
  1871     using insert by(simp)
  1872   also have "insert (h n) (h ` N) = h ` insert n N" by simp
  1873   finally show ?case .
  1874 qed
  1875 
  1876 end
  1877 
  1878 notation times (infixl "*" 70)
  1879 notation Groups.one ("1")
  1880 
  1881 
  1882 subsection {* Finite cardinality *}
  1883 
  1884 text {* This definition, although traditional, is ugly to work with:
  1885 @{text "card A == LEAST n. EX f. A = {f i | i. i < n}"}.
  1886 But now that we have @{text fold_image} things are easy:
  1887 *}
  1888 
  1889 definition card :: "'a set \<Rightarrow> nat" where
  1890   "card A = (if finite A then fold_image (op +) (\<lambda>x. 1) 0 A else 0)"
  1891 
  1892 interpretation card: folding_image_simple "op +" 0 "\<lambda>x. 1" card proof
  1893 qed (simp add: card_def)
  1894 
  1895 lemma card_infinite [simp]:
  1896   "\<not> finite A \<Longrightarrow> card A = 0"
  1897   by (simp add: card_def)
  1898 
  1899 lemma card_empty:
  1900   "card {} = 0"
  1901   by (fact card.empty)
  1902 
  1903 lemma card_insert_disjoint:
  1904   "finite A ==> x \<notin> A ==> card (insert x A) = Suc (card A)"
  1905   by simp
  1906 
  1907 lemma card_insert_if:
  1908   "finite A ==> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1909   by auto (simp add: card.insert_remove card.remove)
  1910 
  1911 lemma card_ge_0_finite:
  1912   "card A > 0 \<Longrightarrow> finite A"
  1913   by (rule ccontr) simp
  1914 
  1915 lemma card_0_eq [simp, no_atp]:
  1916   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1917   by (auto dest: mk_disjoint_insert)
  1918 
  1919 lemma finite_UNIV_card_ge_0:
  1920   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1921   by (rule ccontr) simp
  1922 
  1923 lemma card_eq_0_iff:
  1924   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1925   by auto
  1926 
  1927 lemma card_gt_0_iff:
  1928   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1929   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1930 
  1931 lemma card_Suc_Diff1: "finite A ==> x: A ==> Suc (card (A - {x})) = card A"
  1932 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1933 apply(simp del:insert_Diff_single)
  1934 done
  1935 
  1936 lemma card_Diff_singleton:
  1937   "finite A ==> x: A ==> card (A - {x}) = card A - 1"
  1938 by (simp add: card_Suc_Diff1 [symmetric])
  1939 
  1940 lemma card_Diff_singleton_if:
  1941   "finite A ==> card (A-{x}) = (if x : A then card A - 1 else card A)"
  1942 by (simp add: card_Diff_singleton)
  1943 
  1944 lemma card_Diff_insert[simp]:
  1945 assumes "finite A" and "a:A" and "a ~: B"
  1946 shows "card(A - insert a B) = card(A - B) - 1"
  1947 proof -
  1948   have "A - insert a B = (A - B) - {a}" using assms by blast
  1949   then show ?thesis using assms by(simp add:card_Diff_singleton)
  1950 qed
  1951 
  1952 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1953 by (simp add: card_insert_if card_Suc_Diff1 del:card_Diff_insert)
  1954 
  1955 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1956 by (simp add: card_insert_if)
  1957 
  1958 lemma card_mono:
  1959   assumes "finite B" and "A \<subseteq> B"
  1960   shows "card A \<le> card B"
  1961 proof -
  1962   from assms have "finite A" by (auto intro: finite_subset)
  1963   then show ?thesis using assms proof (induct A arbitrary: B)
  1964     case empty then show ?case by simp
  1965   next
  1966     case (insert x A)
  1967     then have "x \<in> B" by simp
  1968     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1969     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1970     with `finite A` `x \<notin> A` `finite B` `x \<in> B` show ?case by simp (simp only: card.remove)
  1971   qed
  1972 qed
  1973 
  1974 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1975 apply (induct set: finite, simp, clarify)
  1976 apply (subgoal_tac "finite A & A - {x} <= F")
  1977  prefer 2 apply (blast intro: finite_subset, atomize)
  1978 apply (drule_tac x = "A - {x}" in spec)
  1979 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1980 apply (case_tac "card A", auto)
  1981 done
  1982 
  1983 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1984 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1985 apply (blast dest: card_seteq)
  1986 done
  1987 
  1988 lemma card_Un_Int: "finite A ==> finite B
  1989     ==> card A + card B = card (A Un B) + card (A Int B)"
  1990   by (fact card.union_inter [symmetric])
  1991 
  1992 lemma card_Un_disjoint: "finite A ==> finite B
  1993     ==> A Int B = {} ==> card (A Un B) = card A + card B"
  1994   by (fact card.union_disjoint)
  1995 
  1996 lemma card_Diff_subset:
  1997   assumes "finite B" and "B \<subseteq> A"
  1998   shows "card (A - B) = card A - card B"
  1999 proof (cases "finite A")
  2000   case False with assms show ?thesis by simp
  2001 next
  2002   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  2003 qed
  2004 
  2005 lemma card_Diff_subset_Int:
  2006   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  2007 proof -
  2008   have "A - B = A - A \<inter> B" by auto
  2009   thus ?thesis
  2010     by (simp add: card_Diff_subset AB) 
  2011 qed
  2012 
  2013 lemma diff_card_le_card_Diff:
  2014 assumes "finite B" shows "card A - card B \<le> card(A - B)"
  2015 proof-
  2016   have "card A - card B \<le> card A - card (A \<inter> B)"
  2017     using card_mono[OF assms Int_lower2, of A] by arith
  2018   also have "\<dots> = card(A-B)" using assms by(simp add: card_Diff_subset_Int)
  2019   finally show ?thesis .
  2020 qed
  2021 
  2022 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  2023 apply (rule Suc_less_SucD)
  2024 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  2025 done
  2026 
  2027 lemma card_Diff2_less:
  2028   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  2029 apply (case_tac "x = y")
  2030  apply (simp add: card_Diff1_less del:card_Diff_insert)
  2031 apply (rule less_trans)
  2032  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  2033 done
  2034 
  2035 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  2036 apply (case_tac "x : A")
  2037  apply (simp_all add: card_Diff1_less less_imp_le)
  2038 done
  2039 
  2040 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  2041 by (erule psubsetI, blast)
  2042 
  2043 lemma insert_partition:
  2044   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  2045   \<Longrightarrow> x \<inter> \<Union> F = {}"
  2046 by auto
  2047 
  2048 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  2049   assumes fin: "finite A" 
  2050   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  2051   shows "P A"
  2052 using fin
  2053 proof (induct A taking: card rule: measure_induct_rule)
  2054   case (less A)
  2055   have fin: "finite A" by fact
  2056   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  2057   { fix B 
  2058     assume asm: "B \<subset> A"
  2059     from asm have "card B < card A" using psubset_card_mono fin by blast
  2060     moreover
  2061     from asm have "B \<subseteq> A" by auto
  2062     then have "finite B" using fin finite_subset by blast
  2063     ultimately 
  2064     have "P B" using ih by simp
  2065   }
  2066   with fin show "P A" using major by blast
  2067 qed
  2068 
  2069 text{* main cardinality theorem *}
  2070 lemma card_partition [rule_format]:
  2071   "finite C ==>
  2072      finite (\<Union> C) -->
  2073      (\<forall>c\<in>C. card c = k) -->
  2074      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  2075      k * card(C) = card (\<Union> C)"
  2076 apply (erule finite_induct, simp)
  2077 apply (simp add: card_Un_disjoint insert_partition 
  2078        finite_subset [of _ "\<Union> (insert x F)"])
  2079 done
  2080 
  2081 lemma card_eq_UNIV_imp_eq_UNIV:
  2082   assumes fin: "finite (UNIV :: 'a set)"
  2083   and card: "card A = card (UNIV :: 'a set)"
  2084   shows "A = (UNIV :: 'a set)"
  2085 proof
  2086   show "A \<subseteq> UNIV" by simp
  2087   show "UNIV \<subseteq> A"
  2088   proof
  2089     fix x
  2090     show "x \<in> A"
  2091     proof (rule ccontr)
  2092       assume "x \<notin> A"
  2093       then have "A \<subset> UNIV" by auto
  2094       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  2095       with card show False by simp
  2096     qed
  2097   qed
  2098 qed
  2099 
  2100 text{*The form of a finite set of given cardinality*}
  2101 
  2102 lemma card_eq_SucD:
  2103 assumes "card A = Suc k"
  2104 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  2105 proof -
  2106   have fin: "finite A" using assms by (auto intro: ccontr)
  2107   moreover have "card A \<noteq> 0" using assms by auto
  2108   ultimately obtain b where b: "b \<in> A" by auto
  2109   show ?thesis
  2110   proof (intro exI conjI)
  2111     show "A = insert b (A-{b})" using b by blast
  2112     show "b \<notin> A - {b}" by blast
  2113     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  2114       using assms b fin by(fastsimp dest:mk_disjoint_insert)+
  2115   qed
  2116 qed
  2117 
  2118 lemma card_Suc_eq:
  2119   "(card A = Suc k) =
  2120    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  2121 apply(rule iffI)
  2122  apply(erule card_eq_SucD)
  2123 apply(auto)
  2124 apply(subst card_insert)
  2125  apply(auto intro:ccontr)
  2126 done
  2127 
  2128 lemma finite_fun_UNIVD2:
  2129   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  2130   shows "finite (UNIV :: 'b set)"
  2131 proof -
  2132   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  2133     by(rule finite_imageI)
  2134   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  2135     by(rule UNIV_eq_I) auto
  2136   ultimately show "finite (UNIV :: 'b set)" by simp
  2137 qed
  2138 
  2139 lemma card_UNIV_unit: "card (UNIV :: unit set) = 1"
  2140   unfolding UNIV_unit by simp
  2141 
  2142 
  2143 subsubsection {* Cardinality of image *}
  2144 
  2145 lemma card_image_le: "finite A ==> card (f ` A) <= card A"
  2146 apply (induct set: finite)
  2147  apply simp
  2148 apply (simp add: le_SucI card_insert_if)
  2149 done
  2150 
  2151 lemma card_image:
  2152   assumes "inj_on f A"
  2153   shows "card (f ` A) = card A"
  2154 proof (cases "finite A")
  2155   case True then show ?thesis using assms by (induct A) simp_all
  2156 next
  2157   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  2158   with False show ?thesis by simp
  2159 qed
  2160 
  2161 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  2162 by(auto simp: card_image bij_betw_def)
  2163 
  2164 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  2165 by (simp add: card_seteq card_image)
  2166 
  2167 lemma eq_card_imp_inj_on:
  2168   "[| finite A; card(f ` A) = card A |] ==> inj_on f A"
  2169 apply (induct rule:finite_induct)
  2170 apply simp
  2171 apply(frule card_image_le[where f = f])
  2172 apply(simp add:card_insert_if split:if_splits)
  2173 done
  2174 
  2175 lemma inj_on_iff_eq_card:
  2176   "finite A ==> inj_on f A = (card(f ` A) = card A)"
  2177 by(blast intro: card_image eq_card_imp_inj_on)
  2178 
  2179 
  2180 lemma card_inj_on_le:
  2181   "[|inj_on f A; f ` A \<subseteq> B; finite B |] ==> card A \<le> card B"
  2182 apply (subgoal_tac "finite A") 
  2183  apply (force intro: card_mono simp add: card_image [symmetric])
  2184 apply (blast intro: finite_imageD dest: finite_subset) 
  2185 done
  2186 
  2187 lemma card_bij_eq:
  2188   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  2189      finite A; finite B |] ==> card A = card B"
  2190 by (auto intro: le_antisym card_inj_on_le)
  2191 
  2192 lemma bij_betw_finite:
  2193   assumes "bij_betw f A B"
  2194   shows "finite A \<longleftrightarrow> finite B"
  2195 using assms unfolding bij_betw_def
  2196 using finite_imageD[of f A] by auto
  2197 
  2198 subsubsection {* Pigeonhole Principles *}
  2199 
  2200 lemma pigeonhole: "card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  2201 by (auto dest: card_image less_irrefl_nat)
  2202 
  2203 lemma pigeonhole_infinite:
  2204 assumes  "~ finite A" and "finite(f`A)"
  2205 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  2206 proof -
  2207   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  2208   proof(induct "f`A" arbitrary: A rule: finite_induct)
  2209     case empty thus ?case by simp
  2210   next
  2211     case (insert b F)
  2212     show ?case
  2213     proof cases
  2214       assume "finite{a:A. f a = b}"
  2215       hence "~ finite(A - {a:A. f a = b})" using `\<not> finite A` by simp
  2216       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  2217       finally have "~ finite({a:A. f a \<noteq> b})" .
  2218       from insert(3)[OF _ this]
  2219       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  2220     next
  2221       assume 1: "~finite{a:A. f a = b}"
  2222       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  2223       thus ?thesis using 1 by blast
  2224     qed
  2225   qed
  2226   from this[OF assms(2,1)] show ?thesis .
  2227 qed
  2228 
  2229 lemma pigeonhole_infinite_rel:
  2230 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  2231 shows "EX b:B. ~finite{a:A. R a b}"
  2232 proof -
  2233    let ?F = "%a. {b:B. R a b}"
  2234    from finite_Pow_iff[THEN iffD2, OF `finite B`]
  2235    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  2236    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  2237    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  2238    obtain b0 where "b0 : B" and "R a0 b0" using `a0:A` assms(3) by blast
  2239    { assume "finite{a:A. R a b0}"
  2240      then have "finite {a\<in>A. ?F a = ?F a0}"
  2241        using `b0 : B` `R a0 b0` by(blast intro: rev_finite_subset)
  2242    }
  2243    with 1 `b0 : B` show ?thesis by blast
  2244 qed
  2245 
  2246 
  2247 subsubsection {* Cardinality of sums *}
  2248 
  2249 lemma card_Plus:
  2250   assumes "finite A" and "finite B"
  2251   shows "card (A <+> B) = card A + card B"
  2252 proof -
  2253   have "Inl`A \<inter> Inr`B = {}" by fast
  2254   with assms show ?thesis
  2255     unfolding Plus_def
  2256     by (simp add: card_Un_disjoint card_image)
  2257 qed
  2258 
  2259 lemma card_Plus_conv_if:
  2260   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  2261   by (auto simp add: card_Plus)
  2262 
  2263 
  2264 subsubsection {* Cardinality of the Powerset *}
  2265 
  2266 lemma card_Pow: "finite A ==> card (Pow A) = Suc (Suc 0) ^ card A"  (* FIXME numeral 2 (!?) *)
  2267 apply (induct set: finite)
  2268  apply (simp_all add: Pow_insert)
  2269 apply (subst card_Un_disjoint, blast)
  2270   apply (blast, blast)
  2271 apply (subgoal_tac "inj_on (insert x) (Pow F)")
  2272  apply (simp add: card_image Pow_insert)
  2273 apply (unfold inj_on_def)
  2274 apply (blast elim!: equalityE)
  2275 done
  2276 
  2277 text {* Relates to equivalence classes.  Based on a theorem of F. Kammüller.  *}
  2278 
  2279 lemma dvd_partition:
  2280   "finite (Union C) ==>
  2281     ALL c : C. k dvd card c ==>
  2282     (ALL c1: C. ALL c2: C. c1 \<noteq> c2 --> c1 Int c2 = {}) ==>
  2283   k dvd card (Union C)"
  2284 apply(frule finite_UnionD)
  2285 apply(rotate_tac -1)
  2286 apply (induct set: finite, simp_all, clarify)
  2287 apply (subst card_Un_disjoint)
  2288    apply (auto simp add: disjoint_eq_subset_Compl)
  2289 done
  2290 
  2291 
  2292 subsubsection {* Relating injectivity and surjectivity *}
  2293 
  2294 lemma finite_surj_inj: "finite(A) \<Longrightarrow> A <= f`A \<Longrightarrow> inj_on f A"
  2295 apply(rule eq_card_imp_inj_on, assumption)
  2296 apply(frule finite_imageI)
  2297 apply(drule (1) card_seteq)
  2298  apply(erule card_image_le)
  2299 apply simp
  2300 done
  2301 
  2302 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  2303 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  2304 by (blast intro: finite_surj_inj subset_UNIV)
  2305 
  2306 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  2307 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  2308 by(fastsimp simp:surj_def dest!: endo_inj_surj)
  2309 
  2310 corollary infinite_UNIV_nat[iff]: "~finite(UNIV::nat set)"
  2311 proof
  2312   assume "finite(UNIV::nat set)"
  2313   with finite_UNIV_inj_surj[of Suc]
  2314   show False by simp (blast dest: Suc_neq_Zero surjD)
  2315 qed
  2316 
  2317 (* Often leads to bogus ATP proofs because of reduced type information, hence no_atp *)
  2318 lemma infinite_UNIV_char_0[no_atp]:
  2319   "\<not> finite (UNIV::'a::semiring_char_0 set)"
  2320 proof
  2321   assume "finite (UNIV::'a set)"
  2322   with subset_UNIV have "finite (range of_nat::'a set)"
  2323     by (rule finite_subset)
  2324   moreover have "inj (of_nat::nat \<Rightarrow> 'a)"
  2325     by (simp add: inj_on_def)
  2326   ultimately have "finite (UNIV::nat set)"
  2327     by (rule finite_imageD)
  2328   then show "False"
  2329     by simp
  2330 qed
  2331 
  2332 end