src/HOL/Limits.thy
author haftmann
Mon Nov 29 13:44:54 2010 +0100 (2010-11-29)
changeset 40815 6e2d17cc0d1d
parent 39302 d7728f65b353
child 41970 47d6e13d1710
permissions -rw-r--r--
equivI has replaced equiv.intro
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Nets *}
    12 
    13 text {*
    14   A net is now defined simply as a filter on a set.
    15   The definition also allows non-proper filters.
    16 *}
    17 
    18 locale is_filter =
    19   fixes net :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "net (\<lambda>x. True)"
    21   assumes conj: "net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x) \<Longrightarrow> net (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x)"
    23 
    24 typedef (open) 'a net =
    25   "{net :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter net}"
    26 proof
    27   show "(\<lambda>x. True) \<in> ?net" by (auto intro: is_filter.intro)
    28 qed
    29 
    30 lemma is_filter_Rep_net: "is_filter (Rep_net net)"
    31 using Rep_net [of net] by simp
    32 
    33 lemma Abs_net_inverse':
    34   assumes "is_filter net" shows "Rep_net (Abs_net net) = net"
    35 using assms by (simp add: Abs_net_inverse)
    36 
    37 
    38 subsection {* Eventually *}
    39 
    40 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a net \<Rightarrow> bool" where
    41   "eventually P net \<longleftrightarrow> Rep_net net P"
    42 
    43 lemma eventually_Abs_net:
    44   assumes "is_filter net" shows "eventually P (Abs_net net) = net P"
    45 unfolding eventually_def using assms by (simp add: Abs_net_inverse)
    46 
    47 lemma expand_net_eq:
    48   shows "net = net' \<longleftrightarrow> (\<forall>P. eventually P net = eventually P net')"
    49 unfolding Rep_net_inject [symmetric] fun_eq_iff eventually_def ..
    50 
    51 lemma eventually_True [simp]: "eventually (\<lambda>x. True) net"
    52 unfolding eventually_def
    53 by (rule is_filter.True [OF is_filter_Rep_net])
    54 
    55 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P net"
    56 proof -
    57   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    58   thus "eventually P net" by simp
    59 qed
    60 
    61 lemma eventually_mono:
    62   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P net \<Longrightarrow> eventually Q net"
    63 unfolding eventually_def
    64 by (rule is_filter.mono [OF is_filter_Rep_net])
    65 
    66 lemma eventually_conj:
    67   assumes P: "eventually (\<lambda>x. P x) net"
    68   assumes Q: "eventually (\<lambda>x. Q x) net"
    69   shows "eventually (\<lambda>x. P x \<and> Q x) net"
    70 using assms unfolding eventually_def
    71 by (rule is_filter.conj [OF is_filter_Rep_net])
    72 
    73 lemma eventually_mp:
    74   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
    75   assumes "eventually (\<lambda>x. P x) net"
    76   shows "eventually (\<lambda>x. Q x) net"
    77 proof (rule eventually_mono)
    78   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    79   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) net"
    80     using assms by (rule eventually_conj)
    81 qed
    82 
    83 lemma eventually_rev_mp:
    84   assumes "eventually (\<lambda>x. P x) net"
    85   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
    86   shows "eventually (\<lambda>x. Q x) net"
    87 using assms(2) assms(1) by (rule eventually_mp)
    88 
    89 lemma eventually_conj_iff:
    90   "eventually (\<lambda>x. P x \<and> Q x) net \<longleftrightarrow> eventually P net \<and> eventually Q net"
    91 by (auto intro: eventually_conj elim: eventually_rev_mp)
    92 
    93 lemma eventually_elim1:
    94   assumes "eventually (\<lambda>i. P i) net"
    95   assumes "\<And>i. P i \<Longrightarrow> Q i"
    96   shows "eventually (\<lambda>i. Q i) net"
    97 using assms by (auto elim!: eventually_rev_mp)
    98 
    99 lemma eventually_elim2:
   100   assumes "eventually (\<lambda>i. P i) net"
   101   assumes "eventually (\<lambda>i. Q i) net"
   102   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   103   shows "eventually (\<lambda>i. R i) net"
   104 using assms by (auto elim!: eventually_rev_mp)
   105 
   106 
   107 subsection {* Finer-than relation *}
   108 
   109 text {* @{term "net \<le> net'"} means that @{term net} is finer than
   110 @{term net'}. *}
   111 
   112 instantiation net :: (type) complete_lattice
   113 begin
   114 
   115 definition
   116   le_net_def: "net \<le> net' \<longleftrightarrow> (\<forall>P. eventually P net' \<longrightarrow> eventually P net)"
   117 
   118 definition
   119   less_net_def: "(net :: 'a net) < net' \<longleftrightarrow> net \<le> net' \<and> \<not> net' \<le> net"
   120 
   121 definition
   122   top_net_def: "top = Abs_net (\<lambda>P. \<forall>x. P x)"
   123 
   124 definition
   125   bot_net_def: "bot = Abs_net (\<lambda>P. True)"
   126 
   127 definition
   128   sup_net_def: "sup net net' = Abs_net (\<lambda>P. eventually P net \<and> eventually P net')"
   129 
   130 definition
   131   inf_net_def: "inf a b = Abs_net
   132       (\<lambda>P. \<exists>Q R. eventually Q a \<and> eventually R b \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   133 
   134 definition
   135   Sup_net_def: "Sup A = Abs_net (\<lambda>P. \<forall>net\<in>A. eventually P net)"
   136 
   137 definition
   138   Inf_net_def: "Inf A = Sup {x::'a net. \<forall>y\<in>A. x \<le> y}"
   139 
   140 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   141 unfolding top_net_def
   142 by (rule eventually_Abs_net, rule is_filter.intro, auto)
   143 
   144 lemma eventually_bot [simp]: "eventually P bot"
   145 unfolding bot_net_def
   146 by (subst eventually_Abs_net, rule is_filter.intro, auto)
   147 
   148 lemma eventually_sup:
   149   "eventually P (sup net net') \<longleftrightarrow> eventually P net \<and> eventually P net'"
   150 unfolding sup_net_def
   151 by (rule eventually_Abs_net, rule is_filter.intro)
   152    (auto elim!: eventually_rev_mp)
   153 
   154 lemma eventually_inf:
   155   "eventually P (inf a b) \<longleftrightarrow>
   156    (\<exists>Q R. eventually Q a \<and> eventually R b \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   157 unfolding inf_net_def
   158 apply (rule eventually_Abs_net, rule is_filter.intro)
   159 apply (fast intro: eventually_True)
   160 apply clarify
   161 apply (intro exI conjI)
   162 apply (erule (1) eventually_conj)
   163 apply (erule (1) eventually_conj)
   164 apply simp
   165 apply auto
   166 done
   167 
   168 lemma eventually_Sup:
   169   "eventually P (Sup A) \<longleftrightarrow> (\<forall>net\<in>A. eventually P net)"
   170 unfolding Sup_net_def
   171 apply (rule eventually_Abs_net, rule is_filter.intro)
   172 apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   173 done
   174 
   175 instance proof
   176   fix x y :: "'a net" show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
   177     by (rule less_net_def)
   178 next
   179   fix x :: "'a net" show "x \<le> x"
   180     unfolding le_net_def by simp
   181 next
   182   fix x y z :: "'a net" assume "x \<le> y" and "y \<le> z" thus "x \<le> z"
   183     unfolding le_net_def by simp
   184 next
   185   fix x y :: "'a net" assume "x \<le> y" and "y \<le> x" thus "x = y"
   186     unfolding le_net_def expand_net_eq by fast
   187 next
   188   fix x :: "'a net" show "x \<le> top"
   189     unfolding le_net_def eventually_top by (simp add: always_eventually)
   190 next
   191   fix x :: "'a net" show "bot \<le> x"
   192     unfolding le_net_def by simp
   193 next
   194   fix x y :: "'a net" show "x \<le> sup x y" and "y \<le> sup x y"
   195     unfolding le_net_def eventually_sup by simp_all
   196 next
   197   fix x y z :: "'a net" assume "x \<le> z" and "y \<le> z" thus "sup x y \<le> z"
   198     unfolding le_net_def eventually_sup by simp
   199 next
   200   fix x y :: "'a net" show "inf x y \<le> x" and "inf x y \<le> y"
   201     unfolding le_net_def eventually_inf by (auto intro: eventually_True)
   202 next
   203   fix x y z :: "'a net" assume "x \<le> y" and "x \<le> z" thus "x \<le> inf y z"
   204     unfolding le_net_def eventually_inf
   205     by (auto elim!: eventually_mono intro: eventually_conj)
   206 next
   207   fix x :: "'a net" and A assume "x \<in> A" thus "x \<le> Sup A"
   208     unfolding le_net_def eventually_Sup by simp
   209 next
   210   fix A and y :: "'a net" assume "\<And>x. x \<in> A \<Longrightarrow> x \<le> y" thus "Sup A \<le> y"
   211     unfolding le_net_def eventually_Sup by simp
   212 next
   213   fix z :: "'a net" and A assume "z \<in> A" thus "Inf A \<le> z"
   214     unfolding le_net_def Inf_net_def eventually_Sup Ball_def by simp
   215 next
   216   fix A and x :: "'a net" assume "\<And>y. y \<in> A \<Longrightarrow> x \<le> y" thus "x \<le> Inf A"
   217     unfolding le_net_def Inf_net_def eventually_Sup Ball_def by simp
   218 qed
   219 
   220 end
   221 
   222 lemma net_leD:
   223   "net \<le> net' \<Longrightarrow> eventually P net' \<Longrightarrow> eventually P net"
   224 unfolding le_net_def by simp
   225 
   226 lemma net_leI:
   227   "(\<And>P. eventually P net' \<Longrightarrow> eventually P net) \<Longrightarrow> net \<le> net'"
   228 unfolding le_net_def by simp
   229 
   230 lemma eventually_False:
   231   "eventually (\<lambda>x. False) net \<longleftrightarrow> net = bot"
   232 unfolding expand_net_eq by (auto elim: eventually_rev_mp)
   233 
   234 
   235 subsection {* Map function for nets *}
   236 
   237 definition netmap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a net \<Rightarrow> 'b net" where
   238   "netmap f net = Abs_net (\<lambda>P. eventually (\<lambda>x. P (f x)) net)"
   239 
   240 lemma eventually_netmap:
   241   "eventually P (netmap f net) = eventually (\<lambda>x. P (f x)) net"
   242 unfolding netmap_def
   243 apply (rule eventually_Abs_net)
   244 apply (rule is_filter.intro)
   245 apply (auto elim!: eventually_rev_mp)
   246 done
   247 
   248 lemma netmap_ident: "netmap (\<lambda>x. x) net = net"
   249 by (simp add: expand_net_eq eventually_netmap)
   250 
   251 lemma netmap_netmap: "netmap f (netmap g net) = netmap (\<lambda>x. f (g x)) net"
   252 by (simp add: expand_net_eq eventually_netmap)
   253 
   254 lemma netmap_mono: "net \<le> net' \<Longrightarrow> netmap f net \<le> netmap f net'"
   255 unfolding le_net_def eventually_netmap by simp
   256 
   257 lemma netmap_bot [simp]: "netmap f bot = bot"
   258 by (simp add: expand_net_eq eventually_netmap)
   259 
   260 
   261 subsection {* Sequentially *}
   262 
   263 definition sequentially :: "nat net" where
   264   "sequentially = Abs_net (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   265 
   266 lemma eventually_sequentially:
   267   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   268 unfolding sequentially_def
   269 proof (rule eventually_Abs_net, rule is_filter.intro)
   270   fix P Q :: "nat \<Rightarrow> bool"
   271   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   272   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   273   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   274   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   275 qed auto
   276 
   277 lemma sequentially_bot [simp]: "sequentially \<noteq> bot"
   278 unfolding expand_net_eq eventually_sequentially by auto
   279 
   280 lemma eventually_False_sequentially [simp]:
   281   "\<not> eventually (\<lambda>n. False) sequentially"
   282 by (simp add: eventually_False)
   283 
   284 lemma le_sequentially:
   285   "net \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) net)"
   286 unfolding le_net_def eventually_sequentially
   287 by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   288 
   289 
   290 subsection {* Standard Nets *}
   291 
   292 definition within :: "'a net \<Rightarrow> 'a set \<Rightarrow> 'a net" (infixr "within" 70) where
   293   "net within S = Abs_net (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net)"
   294 
   295 definition nhds :: "'a::topological_space \<Rightarrow> 'a net" where
   296   "nhds a = Abs_net (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   297 
   298 definition at :: "'a::topological_space \<Rightarrow> 'a net" where
   299   "at a = nhds a within - {a}"
   300 
   301 lemma eventually_within:
   302   "eventually P (net within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net"
   303 unfolding within_def
   304 by (rule eventually_Abs_net, rule is_filter.intro)
   305    (auto elim!: eventually_rev_mp)
   306 
   307 lemma within_UNIV: "net within UNIV = net"
   308   unfolding expand_net_eq eventually_within by simp
   309 
   310 lemma eventually_nhds:
   311   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   312 unfolding nhds_def
   313 proof (rule eventually_Abs_net, rule is_filter.intro)
   314   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   315   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
   316 next
   317   fix P Q
   318   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   319      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   320   then obtain S T where
   321     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   322     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   323   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   324     by (simp add: open_Int)
   325   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
   326 qed auto
   327 
   328 lemma eventually_nhds_metric:
   329   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   330 unfolding eventually_nhds open_dist
   331 apply safe
   332 apply fast
   333 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   334 apply clarsimp
   335 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   336 apply (simp only: less_diff_eq)
   337 apply (erule le_less_trans [OF dist_triangle])
   338 done
   339 
   340 lemma eventually_at_topological:
   341   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   342 unfolding at_def eventually_within eventually_nhds by simp
   343 
   344 lemma eventually_at:
   345   fixes a :: "'a::metric_space"
   346   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   347 unfolding at_def eventually_within eventually_nhds_metric by auto
   348 
   349 
   350 subsection {* Boundedness *}
   351 
   352 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
   353   "Bfun f net = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) net)"
   354 
   355 lemma BfunI:
   356   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) net" shows "Bfun f net"
   357 unfolding Bfun_def
   358 proof (intro exI conjI allI)
   359   show "0 < max K 1" by simp
   360 next
   361   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) net"
   362     using K by (rule eventually_elim1, simp)
   363 qed
   364 
   365 lemma BfunE:
   366   assumes "Bfun f net"
   367   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) net"
   368 using assms unfolding Bfun_def by fast
   369 
   370 
   371 subsection {* Convergence to Zero *}
   372 
   373 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
   374   "Zfun f net = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) net)"
   375 
   376 lemma ZfunI:
   377   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net) \<Longrightarrow> Zfun f net"
   378 unfolding Zfun_def by simp
   379 
   380 lemma ZfunD:
   381   "\<lbrakk>Zfun f net; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net"
   382 unfolding Zfun_def by simp
   383 
   384 lemma Zfun_ssubst:
   385   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> Zfun g net \<Longrightarrow> Zfun f net"
   386 unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   387 
   388 lemma Zfun_zero: "Zfun (\<lambda>x. 0) net"
   389 unfolding Zfun_def by simp
   390 
   391 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) net = Zfun (\<lambda>x. f x) net"
   392 unfolding Zfun_def by simp
   393 
   394 lemma Zfun_imp_Zfun:
   395   assumes f: "Zfun f net"
   396   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) net"
   397   shows "Zfun (\<lambda>x. g x) net"
   398 proof (cases)
   399   assume K: "0 < K"
   400   show ?thesis
   401   proof (rule ZfunI)
   402     fix r::real assume "0 < r"
   403     hence "0 < r / K"
   404       using K by (rule divide_pos_pos)
   405     then have "eventually (\<lambda>x. norm (f x) < r / K) net"
   406       using ZfunD [OF f] by fast
   407     with g show "eventually (\<lambda>x. norm (g x) < r) net"
   408     proof (rule eventually_elim2)
   409       fix x
   410       assume *: "norm (g x) \<le> norm (f x) * K"
   411       assume "norm (f x) < r / K"
   412       hence "norm (f x) * K < r"
   413         by (simp add: pos_less_divide_eq K)
   414       thus "norm (g x) < r"
   415         by (simp add: order_le_less_trans [OF *])
   416     qed
   417   qed
   418 next
   419   assume "\<not> 0 < K"
   420   hence K: "K \<le> 0" by (simp only: not_less)
   421   show ?thesis
   422   proof (rule ZfunI)
   423     fix r :: real
   424     assume "0 < r"
   425     from g show "eventually (\<lambda>x. norm (g x) < r) net"
   426     proof (rule eventually_elim1)
   427       fix x
   428       assume "norm (g x) \<le> norm (f x) * K"
   429       also have "\<dots> \<le> norm (f x) * 0"
   430         using K norm_ge_zero by (rule mult_left_mono)
   431       finally show "norm (g x) < r"
   432         using `0 < r` by simp
   433     qed
   434   qed
   435 qed
   436 
   437 lemma Zfun_le: "\<lbrakk>Zfun g net; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f net"
   438 by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   439 
   440 lemma Zfun_add:
   441   assumes f: "Zfun f net" and g: "Zfun g net"
   442   shows "Zfun (\<lambda>x. f x + g x) net"
   443 proof (rule ZfunI)
   444   fix r::real assume "0 < r"
   445   hence r: "0 < r / 2" by simp
   446   have "eventually (\<lambda>x. norm (f x) < r/2) net"
   447     using f r by (rule ZfunD)
   448   moreover
   449   have "eventually (\<lambda>x. norm (g x) < r/2) net"
   450     using g r by (rule ZfunD)
   451   ultimately
   452   show "eventually (\<lambda>x. norm (f x + g x) < r) net"
   453   proof (rule eventually_elim2)
   454     fix x
   455     assume *: "norm (f x) < r/2" "norm (g x) < r/2"
   456     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   457       by (rule norm_triangle_ineq)
   458     also have "\<dots> < r/2 + r/2"
   459       using * by (rule add_strict_mono)
   460     finally show "norm (f x + g x) < r"
   461       by simp
   462   qed
   463 qed
   464 
   465 lemma Zfun_minus: "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. - f x) net"
   466 unfolding Zfun_def by simp
   467 
   468 lemma Zfun_diff: "\<lbrakk>Zfun f net; Zfun g net\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) net"
   469 by (simp only: diff_minus Zfun_add Zfun_minus)
   470 
   471 lemma (in bounded_linear) Zfun:
   472   assumes g: "Zfun g net"
   473   shows "Zfun (\<lambda>x. f (g x)) net"
   474 proof -
   475   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   476     using bounded by fast
   477   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) net"
   478     by simp
   479   with g show ?thesis
   480     by (rule Zfun_imp_Zfun)
   481 qed
   482 
   483 lemma (in bounded_bilinear) Zfun:
   484   assumes f: "Zfun f net"
   485   assumes g: "Zfun g net"
   486   shows "Zfun (\<lambda>x. f x ** g x) net"
   487 proof (rule ZfunI)
   488   fix r::real assume r: "0 < r"
   489   obtain K where K: "0 < K"
   490     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   491     using pos_bounded by fast
   492   from K have K': "0 < inverse K"
   493     by (rule positive_imp_inverse_positive)
   494   have "eventually (\<lambda>x. norm (f x) < r) net"
   495     using f r by (rule ZfunD)
   496   moreover
   497   have "eventually (\<lambda>x. norm (g x) < inverse K) net"
   498     using g K' by (rule ZfunD)
   499   ultimately
   500   show "eventually (\<lambda>x. norm (f x ** g x) < r) net"
   501   proof (rule eventually_elim2)
   502     fix x
   503     assume *: "norm (f x) < r" "norm (g x) < inverse K"
   504     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   505       by (rule norm_le)
   506     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   507       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero * K)
   508     also from K have "r * inverse K * K = r"
   509       by simp
   510     finally show "norm (f x ** g x) < r" .
   511   qed
   512 qed
   513 
   514 lemma (in bounded_bilinear) Zfun_left:
   515   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. f x ** a) net"
   516 by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   517 
   518 lemma (in bounded_bilinear) Zfun_right:
   519   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. a ** f x) net"
   520 by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   521 
   522 lemmas Zfun_mult = mult.Zfun
   523 lemmas Zfun_mult_right = mult.Zfun_right
   524 lemmas Zfun_mult_left = mult.Zfun_left
   525 
   526 
   527 subsection {* Limits *}
   528 
   529 definition tendsto :: "('a \<Rightarrow> 'b::topological_space) \<Rightarrow> 'b \<Rightarrow> 'a net \<Rightarrow> bool"
   530     (infixr "--->" 55) where
   531   "(f ---> l) net \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
   532 
   533 ML {*
   534 structure Tendsto_Intros = Named_Thms
   535 (
   536   val name = "tendsto_intros"
   537   val description = "introduction rules for tendsto"
   538 )
   539 *}
   540 
   541 setup Tendsto_Intros.setup
   542 
   543 lemma tendsto_mono: "net \<le> net' \<Longrightarrow> (f ---> l) net' \<Longrightarrow> (f ---> l) net"
   544 unfolding tendsto_def le_net_def by fast
   545 
   546 lemma topological_tendstoI:
   547   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net)
   548     \<Longrightarrow> (f ---> l) net"
   549   unfolding tendsto_def by auto
   550 
   551 lemma topological_tendstoD:
   552   "(f ---> l) net \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net"
   553   unfolding tendsto_def by auto
   554 
   555 lemma tendstoI:
   556   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
   557   shows "(f ---> l) net"
   558 apply (rule topological_tendstoI)
   559 apply (simp add: open_dist)
   560 apply (drule (1) bspec, clarify)
   561 apply (drule assms)
   562 apply (erule eventually_elim1, simp)
   563 done
   564 
   565 lemma tendstoD:
   566   "(f ---> l) net \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
   567 apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   568 apply (clarsimp simp add: open_dist)
   569 apply (rule_tac x="e - dist x l" in exI, clarsimp)
   570 apply (simp only: less_diff_eq)
   571 apply (erule le_less_trans [OF dist_triangle])
   572 apply simp
   573 apply simp
   574 done
   575 
   576 lemma tendsto_iff:
   577   "(f ---> l) net \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
   578 using tendstoI tendstoD by fast
   579 
   580 lemma tendsto_Zfun_iff: "(f ---> a) net = Zfun (\<lambda>x. f x - a) net"
   581 by (simp only: tendsto_iff Zfun_def dist_norm)
   582 
   583 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   584 unfolding tendsto_def eventually_at_topological by auto
   585 
   586 lemma tendsto_ident_at_within [tendsto_intros]:
   587   "((\<lambda>x. x) ---> a) (at a within S)"
   588 unfolding tendsto_def eventually_within eventually_at_topological by auto
   589 
   590 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) net"
   591 by (simp add: tendsto_def)
   592 
   593 lemma tendsto_const_iff:
   594   fixes k l :: "'a::metric_space"
   595   assumes "net \<noteq> bot" shows "((\<lambda>n. k) ---> l) net \<longleftrightarrow> k = l"
   596 apply (safe intro!: tendsto_const)
   597 apply (rule ccontr)
   598 apply (drule_tac e="dist k l" in tendstoD)
   599 apply (simp add: zero_less_dist_iff)
   600 apply (simp add: eventually_False assms)
   601 done
   602 
   603 lemma tendsto_dist [tendsto_intros]:
   604   assumes f: "(f ---> l) net" and g: "(g ---> m) net"
   605   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) net"
   606 proof (rule tendstoI)
   607   fix e :: real assume "0 < e"
   608   hence e2: "0 < e/2" by simp
   609   from tendstoD [OF f e2] tendstoD [OF g e2]
   610   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) net"
   611   proof (rule eventually_elim2)
   612     fix x assume "dist (f x) l < e/2" "dist (g x) m < e/2"
   613     then show "dist (dist (f x) (g x)) (dist l m) < e"
   614       unfolding dist_real_def
   615       using dist_triangle2 [of "f x" "g x" "l"]
   616       using dist_triangle2 [of "g x" "l" "m"]
   617       using dist_triangle3 [of "l" "m" "f x"]
   618       using dist_triangle [of "f x" "m" "g x"]
   619       by arith
   620   qed
   621 qed
   622 
   623 lemma norm_conv_dist: "norm x = dist x 0"
   624 unfolding dist_norm by simp
   625 
   626 lemma tendsto_norm [tendsto_intros]:
   627   "(f ---> a) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) net"
   628 unfolding norm_conv_dist by (intro tendsto_intros)
   629 
   630 lemma tendsto_norm_zero:
   631   "(f ---> 0) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) net"
   632 by (drule tendsto_norm, simp)
   633 
   634 lemma tendsto_norm_zero_cancel:
   635   "((\<lambda>x. norm (f x)) ---> 0) net \<Longrightarrow> (f ---> 0) net"
   636 unfolding tendsto_iff dist_norm by simp
   637 
   638 lemma tendsto_norm_zero_iff:
   639   "((\<lambda>x. norm (f x)) ---> 0) net \<longleftrightarrow> (f ---> 0) net"
   640 unfolding tendsto_iff dist_norm by simp
   641 
   642 lemma add_diff_add:
   643   fixes a b c d :: "'a::ab_group_add"
   644   shows "(a + c) - (b + d) = (a - b) + (c - d)"
   645 by simp
   646 
   647 lemma minus_diff_minus:
   648   fixes a b :: "'a::ab_group_add"
   649   shows "(- a) - (- b) = - (a - b)"
   650 by simp
   651 
   652 lemma tendsto_add [tendsto_intros]:
   653   fixes a b :: "'a::real_normed_vector"
   654   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) net"
   655 by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   656 
   657 lemma tendsto_minus [tendsto_intros]:
   658   fixes a :: "'a::real_normed_vector"
   659   shows "(f ---> a) net \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) net"
   660 by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   661 
   662 lemma tendsto_minus_cancel:
   663   fixes a :: "'a::real_normed_vector"
   664   shows "((\<lambda>x. - f x) ---> - a) net \<Longrightarrow> (f ---> a) net"
   665 by (drule tendsto_minus, simp)
   666 
   667 lemma tendsto_diff [tendsto_intros]:
   668   fixes a b :: "'a::real_normed_vector"
   669   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) net"
   670 by (simp add: diff_minus tendsto_add tendsto_minus)
   671 
   672 lemma tendsto_setsum [tendsto_intros]:
   673   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   674   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) net"
   675   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) net"
   676 proof (cases "finite S")
   677   assume "finite S" thus ?thesis using assms
   678   proof (induct set: finite)
   679     case empty show ?case
   680       by (simp add: tendsto_const)
   681   next
   682     case (insert i F) thus ?case
   683       by (simp add: tendsto_add)
   684   qed
   685 next
   686   assume "\<not> finite S" thus ?thesis
   687     by (simp add: tendsto_const)
   688 qed
   689 
   690 lemma (in bounded_linear) tendsto [tendsto_intros]:
   691   "(g ---> a) net \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) net"
   692 by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   693 
   694 lemma (in bounded_bilinear) tendsto [tendsto_intros]:
   695   "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) net"
   696 by (simp only: tendsto_Zfun_iff prod_diff_prod
   697                Zfun_add Zfun Zfun_left Zfun_right)
   698 
   699 
   700 subsection {* Continuity of Inverse *}
   701 
   702 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   703   assumes f: "Zfun f net"
   704   assumes g: "Bfun g net"
   705   shows "Zfun (\<lambda>x. f x ** g x) net"
   706 proof -
   707   obtain K where K: "0 \<le> K"
   708     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   709     using nonneg_bounded by fast
   710   obtain B where B: "0 < B"
   711     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) net"
   712     using g by (rule BfunE)
   713   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) net"
   714   using norm_g proof (rule eventually_elim1)
   715     fix x
   716     assume *: "norm (g x) \<le> B"
   717     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   718       by (rule norm_le)
   719     also have "\<dots> \<le> norm (f x) * B * K"
   720       by (intro mult_mono' order_refl norm_g norm_ge_zero
   721                 mult_nonneg_nonneg K *)
   722     also have "\<dots> = norm (f x) * (B * K)"
   723       by (rule mult_assoc)
   724     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   725   qed
   726   with f show ?thesis
   727     by (rule Zfun_imp_Zfun)
   728 qed
   729 
   730 lemma (in bounded_bilinear) flip:
   731   "bounded_bilinear (\<lambda>x y. y ** x)"
   732 apply default
   733 apply (rule add_right)
   734 apply (rule add_left)
   735 apply (rule scaleR_right)
   736 apply (rule scaleR_left)
   737 apply (subst mult_commute)
   738 using bounded by fast
   739 
   740 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   741   assumes f: "Bfun f net"
   742   assumes g: "Zfun g net"
   743   shows "Zfun (\<lambda>x. f x ** g x) net"
   744 using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   745 
   746 lemma inverse_diff_inverse:
   747   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
   748    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   749 by (simp add: algebra_simps)
   750 
   751 lemma Bfun_inverse_lemma:
   752   fixes x :: "'a::real_normed_div_algebra"
   753   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   754 apply (subst nonzero_norm_inverse, clarsimp)
   755 apply (erule (1) le_imp_inverse_le)
   756 done
   757 
   758 lemma Bfun_inverse:
   759   fixes a :: "'a::real_normed_div_algebra"
   760   assumes f: "(f ---> a) net"
   761   assumes a: "a \<noteq> 0"
   762   shows "Bfun (\<lambda>x. inverse (f x)) net"
   763 proof -
   764   from a have "0 < norm a" by simp
   765   hence "\<exists>r>0. r < norm a" by (rule dense)
   766   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   767   have "eventually (\<lambda>x. dist (f x) a < r) net"
   768     using tendstoD [OF f r1] by fast
   769   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) net"
   770   proof (rule eventually_elim1)
   771     fix x
   772     assume "dist (f x) a < r"
   773     hence 1: "norm (f x - a) < r"
   774       by (simp add: dist_norm)
   775     hence 2: "f x \<noteq> 0" using r2 by auto
   776     hence "norm (inverse (f x)) = inverse (norm (f x))"
   777       by (rule nonzero_norm_inverse)
   778     also have "\<dots> \<le> inverse (norm a - r)"
   779     proof (rule le_imp_inverse_le)
   780       show "0 < norm a - r" using r2 by simp
   781     next
   782       have "norm a - norm (f x) \<le> norm (a - f x)"
   783         by (rule norm_triangle_ineq2)
   784       also have "\<dots> = norm (f x - a)"
   785         by (rule norm_minus_commute)
   786       also have "\<dots> < r" using 1 .
   787       finally show "norm a - r \<le> norm (f x)" by simp
   788     qed
   789     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   790   qed
   791   thus ?thesis by (rule BfunI)
   792 qed
   793 
   794 lemma tendsto_inverse_lemma:
   795   fixes a :: "'a::real_normed_div_algebra"
   796   shows "\<lbrakk>(f ---> a) net; a \<noteq> 0; eventually (\<lambda>x. f x \<noteq> 0) net\<rbrakk>
   797          \<Longrightarrow> ((\<lambda>x. inverse (f x)) ---> inverse a) net"
   798 apply (subst tendsto_Zfun_iff)
   799 apply (rule Zfun_ssubst)
   800 apply (erule eventually_elim1)
   801 apply (erule (1) inverse_diff_inverse)
   802 apply (rule Zfun_minus)
   803 apply (rule Zfun_mult_left)
   804 apply (rule mult.Bfun_prod_Zfun)
   805 apply (erule (1) Bfun_inverse)
   806 apply (simp add: tendsto_Zfun_iff)
   807 done
   808 
   809 lemma tendsto_inverse [tendsto_intros]:
   810   fixes a :: "'a::real_normed_div_algebra"
   811   assumes f: "(f ---> a) net"
   812   assumes a: "a \<noteq> 0"
   813   shows "((\<lambda>x. inverse (f x)) ---> inverse a) net"
   814 proof -
   815   from a have "0 < norm a" by simp
   816   with f have "eventually (\<lambda>x. dist (f x) a < norm a) net"
   817     by (rule tendstoD)
   818   then have "eventually (\<lambda>x. f x \<noteq> 0) net"
   819     unfolding dist_norm by (auto elim!: eventually_elim1)
   820   with f a show ?thesis
   821     by (rule tendsto_inverse_lemma)
   822 qed
   823 
   824 lemma tendsto_divide [tendsto_intros]:
   825   fixes a b :: "'a::real_normed_field"
   826   shows "\<lbrakk>(f ---> a) net; (g ---> b) net; b \<noteq> 0\<rbrakk>
   827     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) net"
   828 by (simp add: mult.tendsto tendsto_inverse divide_inverse)
   829 
   830 end