src/ZF/Constructible/Datatype_absolute.thy
author paulson
Fri Jul 19 13:29:22 2002 +0200 (2002-07-19)
changeset 13397 6e5f4d911435
parent 13395 4eb948d1eb4e
child 13398 1cadd412da48
permissions -rw-r--r--
Absoluteness of the function "nth"
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   directed :: "i=>o"
    10    "directed(A) == A\<noteq>0 & (\<forall>x\<in>A. \<forall>y\<in>A. x \<union> y \<in> A)"
    11 
    12   contin :: "(i=>i) => o"
    13    "contin(h) == (\<forall>A. directed(A) --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    14 
    15 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    16 apply (induct_tac n) 
    17  apply (simp_all add: bnd_mono_def, blast) 
    18 done
    19 
    20 lemma bnd_mono_increasing [rule_format]:
    21      "[|i \<in> nat; j \<in> nat; bnd_mono(D,h)|] ==> i \<le> j --> h^i(0) \<subseteq> h^j(0)"
    22 apply (rule_tac m=i and n=j in diff_induct, simp_all)
    23 apply (blast del: subsetI
    24 	     intro: bnd_mono_iterates_subset bnd_monoD2 [of concl: h] ) 
    25 done
    26 
    27 lemma directed_iterates: "bnd_mono(D,h) ==> directed({h^n (0). n\<in>nat})"
    28 apply (simp add: directed_def, clarify) 
    29 apply (rename_tac i j)
    30 apply (rule_tac x="i \<union> j" in bexI) 
    31 apply (rule_tac i = i and j = j in Ord_linear_le)
    32 apply (simp_all add: subset_Un_iff [THEN iffD1] le_imp_subset
    33                      subset_Un_iff2 [THEN iffD1])
    34 apply (simp_all add: subset_Un_iff [THEN iff_sym] bnd_mono_increasing
    35                      subset_Un_iff2 [THEN iff_sym])
    36 done
    37 
    38 
    39 lemma contin_iterates_eq: 
    40     "[|bnd_mono(D, h); contin(h)|] 
    41      ==> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    42 apply (simp add: contin_def directed_iterates) 
    43 apply (rule trans) 
    44 apply (rule equalityI) 
    45  apply (simp_all add: UN_subset_iff)
    46  apply safe
    47  apply (erule_tac [2] natE) 
    48   apply (rule_tac a="succ(x)" in UN_I) 
    49    apply simp_all 
    50 apply blast 
    51 done
    52 
    53 lemma lfp_subset_Union:
    54      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    55 apply (rule lfp_lowerbound) 
    56  apply (simp add: contin_iterates_eq) 
    57 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    58 done
    59 
    60 lemma Union_subset_lfp:
    61      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    62 apply (simp add: UN_subset_iff)
    63 apply (rule ballI)  
    64 apply (induct_tac n, simp_all) 
    65 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    66  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset] )  
    67 apply (erule lfp_lemma2) 
    68 done
    69 
    70 lemma lfp_eq_Union:
    71      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    72 by (blast del: subsetI 
    73           intro: lfp_subset_Union Union_subset_lfp)
    74 
    75 
    76 subsubsection{*Some Standard Datatype Constructions Preserve Continuity*}
    77 
    78 lemma contin_imp_mono: "[|X\<subseteq>Y; contin(F)|] ==> F(X) \<subseteq> F(Y)"
    79 apply (simp add: contin_def) 
    80 apply (drule_tac x="{X,Y}" in spec) 
    81 apply (simp add: directed_def subset_Un_iff2 Un_commute) 
    82 done
    83 
    84 lemma sum_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) + G(X))"
    85 by (simp add: contin_def, blast)
    86 
    87 lemma prod_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) * G(X))" 
    88 apply (subgoal_tac "\<forall>B C. F(B) \<subseteq> F(B \<union> C)")
    89  prefer 2 apply (simp add: Un_upper1 contin_imp_mono) 
    90 apply (subgoal_tac "\<forall>B C. G(C) \<subseteq> G(B \<union> C)")
    91  prefer 2 apply (simp add: Un_upper2 contin_imp_mono) 
    92 apply (simp add: contin_def, clarify) 
    93 apply (rule equalityI) 
    94  prefer 2 apply blast 
    95 apply clarify 
    96 apply (rename_tac B C) 
    97 apply (rule_tac a="B \<union> C" in UN_I) 
    98  apply (simp add: directed_def, blast)  
    99 done
   100 
   101 lemma const_contin: "contin(\<lambda>X. A)"
   102 by (simp add: contin_def directed_def)
   103 
   104 lemma id_contin: "contin(\<lambda>X. X)"
   105 by (simp add: contin_def)
   106 
   107 
   108 
   109 subsection {*Absoluteness for "Iterates"*}
   110 
   111 constdefs
   112 
   113   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o"
   114    "iterates_MH(M,isF,v,n,g,z) ==
   115         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   116                     n, z)"
   117 
   118   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o"
   119    "iterates_replacement(M,isF,v) ==
   120       \<forall>n[M]. n\<in>nat --> 
   121          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   122 
   123 lemma (in M_axioms) iterates_MH_abs:
   124   "[| relativize1(M,isF,F); M(n); M(g); M(z) |] 
   125    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   126 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   127               relativize1_def iterates_MH_def)  
   128 
   129 lemma (in M_axioms) iterates_imp_wfrec_replacement:
   130   "[|relativize1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   131    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   132                        Memrel(succ(n)))" 
   133 by (simp add: iterates_replacement_def iterates_MH_abs)
   134 
   135 theorem (in M_trancl) iterates_abs:
   136   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   137       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   138    ==> is_wfrec(M, iterates_MH(M,isF,v), Memrel(succ(n)), n, z) <->
   139        z = iterates(F,n,v)" 
   140 apply (frule iterates_imp_wfrec_replacement, assumption+)
   141 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   142                  relativize2_def iterates_MH_abs 
   143                  iterates_nat_def recursor_def transrec_def 
   144                  eclose_sing_Ord_eq nat_into_M
   145          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   146 done
   147 
   148 
   149 lemma (in M_wfrank) iterates_closed [intro,simp]:
   150   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   151       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   152    ==> M(iterates(F,n,v))"
   153 apply (frule iterates_imp_wfrec_replacement, assumption+)
   154 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   155                  relativize2_def iterates_MH_abs 
   156                  iterates_nat_def recursor_def transrec_def 
   157                  eclose_sing_Ord_eq nat_into_M
   158          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   159 done
   160 
   161 
   162 subsection {*lists without univ*}
   163 
   164 lemmas datatype_univs = Inl_in_univ Inr_in_univ 
   165                         Pair_in_univ nat_into_univ A_into_univ 
   166 
   167 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
   168 apply (rule bnd_monoI)
   169  apply (intro subset_refl zero_subset_univ A_subset_univ 
   170 	      sum_subset_univ Sigma_subset_univ) 
   171 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   172 done
   173 
   174 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
   175 by (intro sum_contin prod_contin id_contin const_contin) 
   176 
   177 text{*Re-expresses lists using sum and product*}
   178 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
   179 apply (simp add: list_def) 
   180 apply (rule equalityI) 
   181  apply (rule lfp_lowerbound) 
   182   prefer 2 apply (rule lfp_subset)
   183  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
   184  apply (simp add: Nil_def Cons_def)
   185  apply blast 
   186 txt{*Opposite inclusion*}
   187 apply (rule lfp_lowerbound) 
   188  prefer 2 apply (rule lfp_subset) 
   189 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
   190 apply (simp add: Nil_def Cons_def)
   191 apply (blast intro: datatype_univs
   192              dest: lfp_subset [THEN subsetD])
   193 done
   194 
   195 text{*Re-expresses lists using "iterates", no univ.*}
   196 lemma list_eq_Union:
   197      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
   198 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
   199 
   200 
   201 constdefs
   202   is_list_functor :: "[i=>o,i,i,i] => o"
   203     "is_list_functor(M,A,X,Z) == 
   204         \<exists>n1[M]. \<exists>AX[M]. 
   205          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   206 
   207 lemma (in M_axioms) list_functor_abs [simp]: 
   208      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   209 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   210 
   211 
   212 subsection {*formulas without univ*}
   213 
   214 lemma formula_fun_bnd_mono:
   215      "bnd_mono(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X)))"
   216 apply (rule bnd_monoI)
   217  apply (intro subset_refl zero_subset_univ A_subset_univ 
   218 	      sum_subset_univ Sigma_subset_univ nat_subset_univ) 
   219 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   220 done
   221 
   222 lemma formula_fun_contin:
   223      "contin(\<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X)))"
   224 by (intro sum_contin prod_contin id_contin const_contin) 
   225 
   226 
   227 text{*Re-expresses formulas using sum and product*}
   228 lemma formula_eq_lfp2:
   229     "formula = lfp(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X)))"
   230 apply (simp add: formula_def) 
   231 apply (rule equalityI) 
   232  apply (rule lfp_lowerbound) 
   233   prefer 2 apply (rule lfp_subset)
   234  apply (clarify, subst lfp_unfold [OF formula_fun_bnd_mono])
   235  apply (simp add: Member_def Equal_def Neg_def And_def Forall_def)
   236  apply blast 
   237 txt{*Opposite inclusion*}
   238 apply (rule lfp_lowerbound) 
   239  prefer 2 apply (rule lfp_subset, clarify) 
   240 apply (subst lfp_unfold [OF formula.bnd_mono, simplified]) 
   241 apply (simp add: Member_def Equal_def Neg_def And_def Forall_def)  
   242 apply (elim sumE SigmaE, simp_all) 
   243 apply (blast intro: datatype_univs dest: lfp_subset [THEN subsetD])+  
   244 done
   245 
   246 text{*Re-expresses formulas using "iterates", no univ.*}
   247 lemma formula_eq_Union:
   248      "formula = 
   249       (\<Union>n\<in>nat. (\<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X))) ^ n (0))"
   250 by (simp add: formula_eq_lfp2 lfp_eq_Union formula_fun_bnd_mono 
   251               formula_fun_contin)
   252 
   253 
   254 constdefs
   255   is_formula_functor :: "[i=>o,i,i] => o"
   256     "is_formula_functor(M,X,Z) == 
   257         \<exists>nat'[M]. \<exists>natnat[M]. \<exists>natnatsum[M]. \<exists>XX[M]. \<exists>X3[M]. \<exists>X4[M]. 
   258           omega(M,nat') & cartprod(M,nat',nat',natnat) & 
   259           is_sum(M,natnat,natnat,natnatsum) &
   260           cartprod(M,X,X,XX) & is_sum(M,XX,X,X3) & is_sum(M,X,X3,X4) &
   261           is_sum(M,natnatsum,X4,Z)"
   262 
   263 lemma (in M_axioms) formula_functor_abs [simp]: 
   264      "[| M(X); M(Z) |] 
   265       ==> is_formula_functor(M,X,Z) <-> 
   266           Z = ((nat*nat) + (nat*nat)) + (X + (X*X + X))"
   267 by (simp add: is_formula_functor_def) 
   268 
   269 
   270 subsection{*@{term M} Contains the List and Formula Datatypes*}
   271 
   272 constdefs
   273   list_N :: "[i,i] => i"
   274     "list_N(A,n) == (\<lambda>X. {0} + A * X)^n (0)"
   275 
   276 lemma Nil_in_list_N [simp]: "[] \<in> list_N(A,succ(n))"
   277 by (simp add: list_N_def Nil_def)
   278 
   279 lemma Cons_in_list_N [simp]:
   280      "Cons(a,l) \<in> list_N(A,succ(n)) <-> a\<in>A & l \<in> list_N(A,n)"
   281 by (simp add: list_N_def Cons_def) 
   282 
   283 text{*These two aren't simprules because they reveal the underlying
   284 list representation.*}
   285 lemma list_N_0: "list_N(A,0) = 0"
   286 by (simp add: list_N_def)
   287 
   288 lemma list_N_succ: "list_N(A,succ(n)) = {0} + A * (list_N(A,n))"
   289 by (simp add: list_N_def)
   290 
   291 lemma list_N_imp_list:
   292   "[| l \<in> list_N(A,n); n \<in> nat |] ==> l \<in> list(A)"
   293 by (force simp add: list_eq_Union list_N_def)
   294 
   295 lemma list_N_imp_length_lt [rule_format]:
   296      "n \<in> nat ==> \<forall>l \<in> list_N(A,n). length(l) < n"
   297 apply (induct_tac n)  
   298 apply (auto simp add: list_N_0 list_N_succ 
   299                       Nil_def [symmetric] Cons_def [symmetric]) 
   300 done
   301 
   302 lemma list_imp_list_N [rule_format]:
   303      "l \<in> list(A) ==> \<forall>n\<in>nat. length(l) < n --> l \<in> list_N(A, n)"
   304 apply (induct_tac l)
   305 apply (force elim: natE)+
   306 done
   307 
   308 lemma list_N_imp_eq_length:
   309       "[|n \<in> nat; l \<notin> list_N(A, n); l \<in> list_N(A, succ(n))|] 
   310        ==> n = length(l)"
   311 apply (rule le_anti_sym) 
   312  prefer 2 apply (simp add: list_N_imp_length_lt) 
   313 apply (frule list_N_imp_list, simp)
   314 apply (simp add: not_lt_iff_le [symmetric]) 
   315 apply (blast intro: list_imp_list_N) 
   316 done
   317   
   318 text{*Express @{term list_rec} without using @{term rank} or @{term Vset},
   319 neither of which is absolute.*}
   320 lemma (in M_triv_axioms) list_rec_eq:
   321   "l \<in> list(A) ==>
   322    list_rec(a,g,l) = 
   323    transrec (succ(length(l)),
   324       \<lambda>x h. Lambda (list_N(A,x),
   325              list_case' (a, 
   326                 \<lambda>a l. g(a, l, h ` succ(length(l)) ` l)))) ` l"
   327 apply (induct_tac l) 
   328 apply (subst transrec, simp) 
   329 apply (subst transrec) 
   330 apply (simp add: list_imp_list_N) 
   331 done
   332 
   333 constdefs
   334   is_list_N :: "[i=>o,i,i,i] => o"
   335     "is_list_N(M,A,n,Z) == 
   336       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   337        empty(M,zero) & 
   338        successor(M,n,sn) & membership(M,sn,msn) &
   339        is_wfrec(M, iterates_MH(M, is_list_functor(M,A),zero), msn, n, Z)"
   340   
   341   mem_list :: "[i=>o,i,i] => o"
   342     "mem_list(M,A,l) == 
   343       \<exists>n[M]. \<exists>listn[M]. 
   344        finite_ordinal(M,n) & is_list_N(M,A,n,listn) & l \<in> listn"
   345 
   346   is_list :: "[i=>o,i,i] => o"
   347     "is_list(M,A,Z) == \<forall>l[M]. l \<in> Z <-> mem_list(M,A,l)"
   348 
   349 constdefs
   350   is_formula_n :: "[i=>o,i,i] => o"
   351     "is_formula_n(M,n,Z) == 
   352       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   353        empty(M,zero) & 
   354        successor(M,n,sn) & membership(M,sn,msn) &
   355        is_wfrec(M, iterates_MH(M, is_formula_functor(M),zero), msn, n, Z)"
   356   
   357   mem_formula :: "[i=>o,i] => o"
   358     "mem_formula(M,p) == 
   359       \<exists>n[M]. \<exists>formn[M]. 
   360        finite_ordinal(M,n) & is_formula_n(M,n,formn) & p \<in> formn"
   361 
   362   is_formula :: "[i=>o,i] => o"
   363     "is_formula(M,Z) == \<forall>p[M]. p \<in> Z <-> mem_formula(M,p)"
   364 
   365 locale (open) M_datatypes = M_wfrank +
   366  assumes list_replacement1: 
   367    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   368   and list_replacement2: 
   369    "M(A) ==> strong_replacement(M, 
   370          \<lambda>n y. n\<in>nat & 
   371                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   372                is_wfrec(M, iterates_MH(M,is_list_functor(M,A), 0), 
   373                         msn, n, y)))"
   374   and formula_replacement1: 
   375    "iterates_replacement(M, is_formula_functor(M), 0)"
   376   and formula_replacement2: 
   377    "strong_replacement(M, 
   378          \<lambda>n y. n\<in>nat & 
   379                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   380                is_wfrec(M, iterates_MH(M,is_formula_functor(M), 0), 
   381                         msn, n, y)))"
   382 
   383 
   384 subsubsection{*Absoluteness of the List Construction*}
   385 
   386 lemma (in M_datatypes) list_replacement2': 
   387   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   388 apply (insert list_replacement2 [of A]) 
   389 apply (rule strong_replacement_cong [THEN iffD1])  
   390 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]]) 
   391 apply (simp_all add: list_replacement1 relativize1_def) 
   392 done
   393 
   394 lemma (in M_datatypes) list_closed [intro,simp]:
   395      "M(A) ==> M(list(A))"
   396 apply (insert list_replacement1)
   397 by  (simp add: RepFun_closed2 list_eq_Union 
   398                list_replacement2' relativize1_def
   399                iterates_closed [of "is_list_functor(M,A)"])
   400 
   401 lemma (in M_datatypes) list_N_abs [simp]:
   402      "[|M(A); n\<in>nat; M(Z)|] 
   403       ==> is_list_N(M,A,n,Z) <-> Z = list_N(A,n)"
   404 apply (insert list_replacement1)
   405 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   406                  iterates_abs [of "is_list_functor(M,A)" _ "\<lambda>X. {0} + A*X"])
   407 done
   408 
   409 lemma (in M_datatypes) list_N_closed [intro,simp]:
   410      "[|M(A); n\<in>nat|] ==> M(list_N(A,n))"
   411 apply (insert list_replacement1)
   412 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   413                  iterates_closed [of "is_list_functor(M,A)"])
   414 done
   415 
   416 lemma (in M_datatypes) mem_list_abs [simp]:
   417      "M(A) ==> mem_list(M,A,l) <-> l \<in> list(A)"
   418 apply (insert list_replacement1)
   419 apply (simp add: mem_list_def list_N_def relativize1_def list_eq_Union
   420                  iterates_closed [of "is_list_functor(M,A)"]) 
   421 done
   422 
   423 lemma (in M_datatypes) list_abs [simp]:
   424      "[|M(A); M(Z)|] ==> is_list(M,A,Z) <-> Z = list(A)"
   425 apply (simp add: is_list_def, safe)
   426 apply (rule M_equalityI, simp_all)
   427 done
   428 
   429 subsubsection{*Absoluteness of Formulas*}
   430 
   431 lemma (in M_datatypes) formula_replacement2': 
   432   "strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X)))^n (0))"
   433 apply (insert formula_replacement2) 
   434 apply (rule strong_replacement_cong [THEN iffD1])  
   435 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_formula_functor(M)"]]) 
   436 apply (simp_all add: formula_replacement1 relativize1_def) 
   437 done
   438 
   439 lemma (in M_datatypes) formula_closed [intro,simp]:
   440      "M(formula)"
   441 apply (insert formula_replacement1)
   442 apply  (simp add: RepFun_closed2 formula_eq_Union 
   443                   formula_replacement2' relativize1_def
   444                   iterates_closed [of "is_formula_functor(M)"])
   445 done
   446 
   447 lemma (in M_datatypes) is_formula_n_abs [simp]:
   448      "[|n\<in>nat; M(Z)|] 
   449       ==> is_formula_n(M,n,Z) <-> 
   450           Z = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X)))^n (0)"
   451 apply (insert formula_replacement1)
   452 apply (simp add: is_formula_n_def relativize1_def nat_into_M
   453                  iterates_abs [of "is_formula_functor(M)" _ 
   454                         "\<lambda>X. ((nat*nat) + (nat*nat)) + (X + (X*X + X))"])
   455 done
   456 
   457 lemma (in M_datatypes) mem_formula_abs [simp]:
   458      "mem_formula(M,l) <-> l \<in> formula"
   459 apply (insert formula_replacement1)
   460 apply (simp add: mem_formula_def relativize1_def formula_eq_Union
   461                  iterates_closed [of "is_formula_functor(M)"]) 
   462 done
   463 
   464 lemma (in M_datatypes) formula_abs [simp]:
   465      "[|M(Z)|] ==> is_formula(M,Z) <-> Z = formula"
   466 apply (simp add: is_formula_def, safe)
   467 apply (rule M_equalityI, simp_all)
   468 done
   469 
   470 
   471 subsection{*Absoluteness for Some List Operators*}
   472 
   473 subsection{*Absoluteness for @{text \<epsilon>}-Closure: the @{term eclose} Operator*}
   474 
   475 text{*Re-expresses eclose using "iterates"*}
   476 lemma eclose_eq_Union:
   477      "eclose(A) = (\<Union>n\<in>nat. Union^n (A))"
   478 apply (simp add: eclose_def) 
   479 apply (rule UN_cong) 
   480 apply (rule refl)
   481 apply (induct_tac n)
   482 apply (simp add: nat_rec_0)  
   483 apply (simp add: nat_rec_succ) 
   484 done
   485 
   486 constdefs
   487   is_eclose_n :: "[i=>o,i,i,i] => o"
   488     "is_eclose_n(M,A,n,Z) == 
   489       \<exists>sn[M]. \<exists>msn[M]. 
   490        successor(M,n,sn) & membership(M,sn,msn) &
   491        is_wfrec(M, iterates_MH(M, big_union(M), A), msn, n, Z)"
   492   
   493   mem_eclose :: "[i=>o,i,i] => o"
   494     "mem_eclose(M,A,l) == 
   495       \<exists>n[M]. \<exists>eclosen[M]. 
   496        finite_ordinal(M,n) & is_eclose_n(M,A,n,eclosen) & l \<in> eclosen"
   497 
   498   is_eclose :: "[i=>o,i,i] => o"
   499     "is_eclose(M,A,Z) == \<forall>u[M]. u \<in> Z <-> mem_eclose(M,A,u)"
   500 
   501 
   502 locale (open) M_eclose = M_wfrank +
   503  assumes eclose_replacement1: 
   504    "M(A) ==> iterates_replacement(M, big_union(M), A)"
   505   and eclose_replacement2: 
   506    "M(A) ==> strong_replacement(M, 
   507          \<lambda>n y. n\<in>nat & 
   508                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   509                is_wfrec(M, iterates_MH(M,big_union(M), A), 
   510                         msn, n, y)))"
   511 
   512 lemma (in M_eclose) eclose_replacement2': 
   513   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = Union^n (A))"
   514 apply (insert eclose_replacement2 [of A]) 
   515 apply (rule strong_replacement_cong [THEN iffD1])  
   516 apply (rule conj_cong [OF iff_refl iterates_abs [of "big_union(M)"]]) 
   517 apply (simp_all add: eclose_replacement1 relativize1_def) 
   518 done
   519 
   520 lemma (in M_eclose) eclose_closed [intro,simp]:
   521      "M(A) ==> M(eclose(A))"
   522 apply (insert eclose_replacement1)
   523 by  (simp add: RepFun_closed2 eclose_eq_Union 
   524                eclose_replacement2' relativize1_def
   525                iterates_closed [of "big_union(M)"])
   526 
   527 lemma (in M_eclose) is_eclose_n_abs [simp]:
   528      "[|M(A); n\<in>nat; M(Z)|] ==> is_eclose_n(M,A,n,Z) <-> Z = Union^n (A)"
   529 apply (insert eclose_replacement1)
   530 apply (simp add: is_eclose_n_def relativize1_def nat_into_M
   531                  iterates_abs [of "big_union(M)" _ "Union"])
   532 done
   533 
   534 lemma (in M_eclose) mem_eclose_abs [simp]:
   535      "M(A) ==> mem_eclose(M,A,l) <-> l \<in> eclose(A)"
   536 apply (insert eclose_replacement1)
   537 apply (simp add: mem_eclose_def relativize1_def eclose_eq_Union
   538                  iterates_closed [of "big_union(M)"]) 
   539 done
   540 
   541 lemma (in M_eclose) eclose_abs [simp]:
   542      "[|M(A); M(Z)|] ==> is_eclose(M,A,Z) <-> Z = eclose(A)"
   543 apply (simp add: is_eclose_def, safe)
   544 apply (rule M_equalityI, simp_all)
   545 done
   546 
   547 
   548 
   549 
   550 subsection {*Absoluteness for @{term transrec}*}
   551 
   552 
   553 text{* @{term "transrec(a,H) \<equiv> wfrec(Memrel(eclose({a})), a, H)"} *}
   554 constdefs
   555 
   556   is_transrec :: "[i=>o, [i,i,i]=>o, i, i] => o"
   557    "is_transrec(M,MH,a,z) == 
   558       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   559        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   560        is_wfrec(M,MH,mesa,a,z)"
   561 
   562   transrec_replacement :: "[i=>o, [i,i,i]=>o, i] => o"
   563    "transrec_replacement(M,MH,a) ==
   564       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   565        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   566        wfrec_replacement(M,MH,mesa)"
   567 
   568 text{*The condition @{term "Ord(i)"} lets us use the simpler 
   569   @{text "trans_wfrec_abs"} rather than @{text "trans_wfrec_abs"},
   570   which I haven't even proved yet. *}
   571 theorem (in M_eclose) transrec_abs:
   572   "[|Ord(i);  M(i);  M(z);
   573      transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   574      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   575    ==> is_transrec(M,MH,i,z) <-> z = transrec(i,H)" 
   576 by (simp add: trans_wfrec_abs transrec_replacement_def is_transrec_def
   577        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   578 
   579 
   580 theorem (in M_eclose) transrec_closed:
   581      "[|Ord(i);  M(i);  M(z);
   582 	transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   583 	\<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   584       ==> M(transrec(i,H))"
   585 by (simp add: trans_wfrec_closed transrec_replacement_def is_transrec_def
   586        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   587 
   588 
   589 
   590 subsection{*Absoluteness for the List Operator @{term length}*}
   591 constdefs
   592 
   593   is_length :: "[i=>o,i,i,i] => o"
   594     "is_length(M,A,l,n) == 
   595        \<exists>sn[M]. \<exists>list_n[M]. \<exists>list_sn[M]. 
   596         is_list_N(M,A,n,list_n) & l \<notin> list_n &
   597         successor(M,n,sn) & is_list_N(M,A,sn,list_sn) & l \<in> list_sn"
   598 
   599 
   600 lemma (in M_datatypes) length_abs [simp]:
   601      "[|M(A); l \<in> list(A); n \<in> nat|] ==> is_length(M,A,l,n) <-> n = length(l)"
   602 apply (subgoal_tac "M(l) & M(n)")
   603  prefer 2 apply (blast dest: transM)  
   604 apply (simp add: is_length_def)
   605 apply (blast intro: list_imp_list_N nat_into_Ord list_N_imp_eq_length
   606              dest: list_N_imp_length_lt)
   607 done
   608 
   609 text{*Proof is trivial since @{term length} returns natural numbers.*}
   610 lemma (in M_triv_axioms) length_closed [intro,simp]:
   611      "l \<in> list(A) ==> M(length(l))"
   612 by (simp add: nat_into_M ) 
   613 
   614 
   615 subsection {*Absoluteness for @{term nth}*}
   616 
   617 lemma nth_eq_hd_iterates_tl [rule_format]:
   618      "xs \<in> list(A) ==> \<forall>n \<in> nat. nth(n,xs) = hd' (tl'^n (xs))"
   619 apply (induct_tac xs) 
   620 apply (simp add: iterates_tl_Nil hd'_Nil, clarify) 
   621 apply (erule natE)
   622 apply (simp add: hd'_Cons) 
   623 apply (simp add: tl'_Cons iterates_commute) 
   624 done
   625 
   626 lemma (in M_axioms) iterates_tl'_closed:
   627      "[|n \<in> nat; M(x)|] ==> M(tl'^n (x))"
   628 apply (induct_tac n, simp) 
   629 apply (simp add: tl'_Cons tl'_closed) 
   630 done
   631 
   632 locale (open) M_nth = M_datatypes +
   633  assumes nth_replacement1: 
   634    "M(xs) ==> iterates_replacement(M, %l t. is_tl(M,l,t), xs)"
   635 
   636 text{*Immediate by type-checking*}
   637 lemma (in M_datatypes) nth_closed [intro,simp]:
   638      "[|xs \<in> list(A); n \<in> nat; M(A)|] ==> M(nth(n,xs))" 
   639 apply (case_tac "n < length(xs)")
   640  apply (blast intro: nth_type transM)
   641 apply (simp add: not_lt_iff_le nth_eq_0)
   642 done
   643 
   644 constdefs
   645   is_nth :: "[i=>o,i,i,i] => o"
   646     "is_nth(M,n,l,Z) == 
   647       \<exists>X[M]. \<exists>sn[M]. \<exists>msn[M]. 
   648        successor(M,n,sn) & membership(M,sn,msn) &
   649        is_wfrec(M, iterates_MH(M, is_tl(M), l), msn, n, X) &
   650        is_hd(M,X,Z)"
   651  
   652 lemma (in M_nth) nth_abs [simp]:
   653      "[|M(A); n \<in> nat; l \<in> list(A); M(Z)|] 
   654       ==> is_nth(M,n,l,Z) <-> Z = nth(n,l)"
   655 apply (subgoal_tac "M(l)") 
   656  prefer 2 apply (blast intro: transM)
   657 apply (insert nth_replacement1)
   658 apply (simp add: is_nth_def nth_eq_hd_iterates_tl nat_into_M
   659                  tl'_closed iterates_tl'_closed 
   660                  iterates_abs [OF _ relativize1_tl])
   661 done
   662 
   663 
   664 end