src/HOL/Real/RealDef.thy
author chaieb
Mon Jul 21 13:36:59 2008 +0200 (2008-07-21)
changeset 27668 6eb20b2cecf8
parent 27652 818666de6c24
child 27682 25aceefd4786
permissions -rw-r--r--
Tuned and simplified proofs
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   [code func del]: "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 definition
    24   (** these don't use the overloaded "real" function: users don't see them **)
    25   real_of_preal :: "preal => real" where
    26   "real_of_preal m = Abs_Real(realrel``{(m + 1, 1)})"
    27 
    28 instantiation real :: "{zero, one, plus, minus, uminus, times, inverse, ord, abs, sgn}"
    29 begin
    30 
    31 definition
    32   real_zero_def [code func del]: "0 = Abs_Real(realrel``{(1, 1)})"
    33 
    34 definition
    35   real_one_def [code func del]: "1 = Abs_Real(realrel``{(1 + 1, 1)})"
    36 
    37 definition
    38   real_add_def [code func del]: "z + w =
    39        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    40 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    41 
    42 definition
    43   real_minus_def [code func del]: "- r =  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    44 
    45 definition
    46   real_diff_def [code func del]: "r - (s::real) = r + - s"
    47 
    48 definition
    49   real_mult_def [code func del]:
    50     "z * w =
    51        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    52 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    53 
    54 definition
    55   real_inverse_def [code func del]: "inverse (R::real) = (THE S. (R = 0 & S = 0) | S * R = 1)"
    56 
    57 definition
    58   real_divide_def [code func del]: "R / (S::real) = R * inverse S"
    59 
    60 definition
    61   real_le_def [code func del]: "z \<le> (w::real) \<longleftrightarrow>
    62     (\<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w)"
    63 
    64 definition
    65   real_less_def [code func del]: "x < (y\<Colon>real) \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
    66 
    67 definition
    68   real_abs_def:  "abs (r::real) = (if r < 0 then - r else r)"
    69 
    70 definition
    71   real_sgn_def: "sgn (x::real) = (if x=0 then 0 else if 0<x then 1 else - 1)"
    72 
    73 instance ..
    74 
    75 end
    76 
    77 subsection {* Equivalence relation over positive reals *}
    78 
    79 lemma preal_trans_lemma:
    80   assumes "x + y1 = x1 + y"
    81       and "x + y2 = x2 + y"
    82   shows "x1 + y2 = x2 + (y1::preal)"
    83 proof -
    84   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    85   also have "... = (x2 + y) + x1"  by (simp add: prems)
    86   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    87   also have "... = x2 + (x + y1)"  by (simp add: prems)
    88   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    89   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    90   thus ?thesis by (rule add_right_imp_eq)
    91 qed
    92 
    93 
    94 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    95 by (simp add: realrel_def)
    96 
    97 lemma equiv_realrel: "equiv UNIV realrel"
    98 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    99 apply (blast dest: preal_trans_lemma) 
   100 done
   101 
   102 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   103   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   104 lemmas equiv_realrel_iff = 
   105        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   106 
   107 declare equiv_realrel_iff [simp]
   108 
   109 
   110 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   111 by (simp add: Real_def realrel_def quotient_def, blast)
   112 
   113 declare Abs_Real_inject [simp]
   114 declare Abs_Real_inverse [simp]
   115 
   116 
   117 text{*Case analysis on the representation of a real number as an equivalence
   118       class of pairs of positive reals.*}
   119 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   120      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   121 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   122 apply (drule arg_cong [where f=Abs_Real])
   123 apply (auto simp add: Rep_Real_inverse)
   124 done
   125 
   126 
   127 subsection {* Addition and Subtraction *}
   128 
   129 lemma real_add_congruent2_lemma:
   130      "[|a + ba = aa + b; ab + bc = ac + bb|]
   131       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   132 apply (simp add: add_assoc)
   133 apply (rule add_left_commute [of ab, THEN ssubst])
   134 apply (simp add: add_assoc [symmetric])
   135 apply (simp add: add_ac)
   136 done
   137 
   138 lemma real_add:
   139      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   140       Abs_Real (realrel``{(x+u, y+v)})"
   141 proof -
   142   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   143         respects2 realrel"
   144     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   145   thus ?thesis
   146     by (simp add: real_add_def UN_UN_split_split_eq
   147                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   148 qed
   149 
   150 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   151 proof -
   152   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   153     by (simp add: congruent_def add_commute) 
   154   thus ?thesis
   155     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   156 qed
   157 
   158 instance real :: ab_group_add
   159 proof
   160   fix x y z :: real
   161   show "(x + y) + z = x + (y + z)"
   162     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   163   show "x + y = y + x"
   164     by (cases x, cases y, simp add: real_add add_commute)
   165   show "0 + x = x"
   166     by (cases x, simp add: real_add real_zero_def add_ac)
   167   show "- x + x = 0"
   168     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   169   show "x - y = x + - y"
   170     by (simp add: real_diff_def)
   171 qed
   172 
   173 
   174 subsection {* Multiplication *}
   175 
   176 lemma real_mult_congruent2_lemma:
   177      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   178           x * x1 + y * y1 + (x * y2 + y * x2) =
   179           x * x2 + y * y2 + (x * y1 + y * x1)"
   180 apply (simp add: add_left_commute add_assoc [symmetric])
   181 apply (simp add: add_assoc right_distrib [symmetric])
   182 apply (simp add: add_commute)
   183 done
   184 
   185 lemma real_mult_congruent2:
   186     "(%p1 p2.
   187         (%(x1,y1). (%(x2,y2). 
   188           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   189      respects2 realrel"
   190 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   191 apply (simp add: mult_commute add_commute)
   192 apply (auto simp add: real_mult_congruent2_lemma)
   193 done
   194 
   195 lemma real_mult:
   196       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   197        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   198 by (simp add: real_mult_def UN_UN_split_split_eq
   199          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   200 
   201 lemma real_mult_commute: "(z::real) * w = w * z"
   202 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   203 
   204 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   205 apply (cases z1, cases z2, cases z3)
   206 apply (simp add: real_mult right_distrib add_ac mult_ac)
   207 done
   208 
   209 lemma real_mult_1: "(1::real) * z = z"
   210 apply (cases z)
   211 apply (simp add: real_mult real_one_def right_distrib
   212                   mult_1_right mult_ac add_ac)
   213 done
   214 
   215 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   216 apply (cases z1, cases z2, cases w)
   217 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   218 done
   219 
   220 text{*one and zero are distinct*}
   221 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   222 proof -
   223   have "(1::preal) < 1 + 1"
   224     by (simp add: preal_self_less_add_left)
   225   thus ?thesis
   226     by (simp add: real_zero_def real_one_def)
   227 qed
   228 
   229 instance real :: comm_ring_1
   230 proof
   231   fix x y z :: real
   232   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   233   show "x * y = y * x" by (rule real_mult_commute)
   234   show "1 * x = x" by (rule real_mult_1)
   235   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   236   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   237 qed
   238 
   239 subsection {* Inverse and Division *}
   240 
   241 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   242 by (simp add: real_zero_def add_commute)
   243 
   244 text{*Instead of using an existential quantifier and constructing the inverse
   245 within the proof, we could define the inverse explicitly.*}
   246 
   247 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   248 apply (simp add: real_zero_def real_one_def, cases x)
   249 apply (cut_tac x = xa and y = y in linorder_less_linear)
   250 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   251 apply (rule_tac
   252         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   253        in exI)
   254 apply (rule_tac [2]
   255         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   256        in exI)
   257 apply (auto simp add: real_mult preal_mult_inverse_right ring_simps)
   258 done
   259 
   260 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   261 apply (simp add: real_inverse_def)
   262 apply (drule real_mult_inverse_left_ex, safe)
   263 apply (rule theI, assumption, rename_tac z)
   264 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   265 apply (simp add: mult_commute)
   266 apply (rule mult_assoc)
   267 done
   268 
   269 
   270 subsection{*The Real Numbers form a Field*}
   271 
   272 instance real :: field
   273 proof
   274   fix x y z :: real
   275   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   276   show "x / y = x * inverse y" by (simp add: real_divide_def)
   277 qed
   278 
   279 
   280 text{*Inverse of zero!  Useful to simplify certain equations*}
   281 
   282 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   283 by (simp add: real_inverse_def)
   284 
   285 instance real :: division_by_zero
   286 proof
   287   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   288 qed
   289 
   290 
   291 subsection{*The @{text "\<le>"} Ordering*}
   292 
   293 lemma real_le_refl: "w \<le> (w::real)"
   294 by (cases w, force simp add: real_le_def)
   295 
   296 text{*The arithmetic decision procedure is not set up for type preal.
   297   This lemma is currently unused, but it could simplify the proofs of the
   298   following two lemmas.*}
   299 lemma preal_eq_le_imp_le:
   300   assumes eq: "a+b = c+d" and le: "c \<le> a"
   301   shows "b \<le> (d::preal)"
   302 proof -
   303   have "c+d \<le> a+d" by (simp add: prems)
   304   hence "a+b \<le> a+d" by (simp add: prems)
   305   thus "b \<le> d" by simp
   306 qed
   307 
   308 lemma real_le_lemma:
   309   assumes l: "u1 + v2 \<le> u2 + v1"
   310       and "x1 + v1 = u1 + y1"
   311       and "x2 + v2 = u2 + y2"
   312   shows "x1 + y2 \<le> x2 + (y1::preal)"
   313 proof -
   314   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   315   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   316   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   317   finally show ?thesis by simp
   318 qed
   319 
   320 lemma real_le: 
   321      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   322       (x1 + y2 \<le> x2 + y1)"
   323 apply (simp add: real_le_def)
   324 apply (auto intro: real_le_lemma)
   325 done
   326 
   327 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   328 by (cases z, cases w, simp add: real_le)
   329 
   330 lemma real_trans_lemma:
   331   assumes "x + v \<le> u + y"
   332       and "u + v' \<le> u' + v"
   333       and "x2 + v2 = u2 + y2"
   334   shows "x + v' \<le> u' + (y::preal)"
   335 proof -
   336   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   337   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   338   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   339   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   340   finally show ?thesis by simp
   341 qed
   342 
   343 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   344 apply (cases i, cases j, cases k)
   345 apply (simp add: real_le)
   346 apply (blast intro: real_trans_lemma)
   347 done
   348 
   349 (* Axiom 'order_less_le' of class 'order': *)
   350 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   351 by (simp add: real_less_def)
   352 
   353 instance real :: order
   354 proof qed
   355  (assumption |
   356   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   357 
   358 (* Axiom 'linorder_linear' of class 'linorder': *)
   359 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   360 apply (cases z, cases w)
   361 apply (auto simp add: real_le real_zero_def add_ac)
   362 done
   363 
   364 
   365 instance real :: linorder
   366   by (intro_classes, rule real_le_linear)
   367 
   368 
   369 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   370 apply (cases x, cases y) 
   371 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   372                       add_ac)
   373 apply (simp_all add: add_assoc [symmetric])
   374 done
   375 
   376 lemma real_add_left_mono: 
   377   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   378 proof -
   379   have "z + x - (z + y) = (z + -z) + (x - y)" 
   380     by (simp add: diff_minus add_ac) 
   381   with le show ?thesis 
   382     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   383 qed
   384 
   385 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   386 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   387 
   388 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   389 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   390 
   391 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   392 apply (cases x, cases y)
   393 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   394                  linorder_not_le [where 'a = preal] 
   395                   real_zero_def real_le real_mult)
   396   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   397 apply (auto dest!: less_add_left_Ex
   398      simp add: add_ac mult_ac
   399           right_distrib preal_self_less_add_left)
   400 done
   401 
   402 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   403 apply (rule real_sum_gt_zero_less)
   404 apply (drule real_less_sum_gt_zero [of x y])
   405 apply (drule real_mult_order, assumption)
   406 apply (simp add: right_distrib)
   407 done
   408 
   409 instantiation real :: distrib_lattice
   410 begin
   411 
   412 definition
   413   "(inf \<Colon> real \<Rightarrow> real \<Rightarrow> real) = min"
   414 
   415 definition
   416   "(sup \<Colon> real \<Rightarrow> real \<Rightarrow> real) = max"
   417 
   418 instance
   419   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   420 
   421 end
   422 
   423 
   424 subsection{*The Reals Form an Ordered Field*}
   425 
   426 instance real :: ordered_field
   427 proof
   428   fix x y z :: real
   429   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   430   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   431   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   432   show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
   433     by (simp only: real_sgn_def)
   434 qed
   435 
   436 instance real :: lordered_ab_group_add ..
   437 
   438 text{*The function @{term real_of_preal} requires many proofs, but it seems
   439 to be essential for proving completeness of the reals from that of the
   440 positive reals.*}
   441 
   442 lemma real_of_preal_add:
   443      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   444 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   445 
   446 lemma real_of_preal_mult:
   447      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   448 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   449 
   450 
   451 text{*Gleason prop 9-4.4 p 127*}
   452 lemma real_of_preal_trichotomy:
   453       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   454 apply (simp add: real_of_preal_def real_zero_def, cases x)
   455 apply (auto simp add: real_minus add_ac)
   456 apply (cut_tac x = x and y = y in linorder_less_linear)
   457 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   458 done
   459 
   460 lemma real_of_preal_leD:
   461       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   462 by (simp add: real_of_preal_def real_le)
   463 
   464 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   465 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   466 
   467 lemma real_of_preal_lessD:
   468       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   469 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   470 
   471 lemma real_of_preal_less_iff [simp]:
   472      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   473 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   474 
   475 lemma real_of_preal_le_iff:
   476      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   477 by (simp add: linorder_not_less [symmetric])
   478 
   479 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   480 apply (insert preal_self_less_add_left [of 1 m])
   481 apply (auto simp add: real_zero_def real_of_preal_def
   482                       real_less_def real_le_def add_ac)
   483 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   484 apply (simp add: add_ac)
   485 done
   486 
   487 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   488 by (simp add: real_of_preal_zero_less)
   489 
   490 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   491 proof -
   492   from real_of_preal_minus_less_zero
   493   show ?thesis by (blast dest: order_less_trans)
   494 qed
   495 
   496 
   497 subsection{*Theorems About the Ordering*}
   498 
   499 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   500 apply (auto simp add: real_of_preal_zero_less)
   501 apply (cut_tac x = x in real_of_preal_trichotomy)
   502 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   503 done
   504 
   505 lemma real_gt_preal_preal_Ex:
   506      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   507 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   508              intro: real_gt_zero_preal_Ex [THEN iffD1])
   509 
   510 lemma real_ge_preal_preal_Ex:
   511      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   512 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   513 
   514 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   515 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   516             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   517             simp add: real_of_preal_zero_less)
   518 
   519 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   520 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   521 
   522 
   523 subsection{*More Lemmas*}
   524 
   525 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   526 by auto
   527 
   528 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   529 by auto
   530 
   531 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   532   by (force elim: order_less_asym
   533             simp add: Ring_and_Field.mult_less_cancel_right)
   534 
   535 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   536 apply (simp add: mult_le_cancel_right)
   537 apply (blast intro: elim: order_less_asym)
   538 done
   539 
   540 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   541 by(simp add:mult_commute)
   542 
   543 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   544 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   545 
   546 
   547 subsection {* Embedding numbers into the Reals *}
   548 
   549 abbreviation
   550   real_of_nat :: "nat \<Rightarrow> real"
   551 where
   552   "real_of_nat \<equiv> of_nat"
   553 
   554 abbreviation
   555   real_of_int :: "int \<Rightarrow> real"
   556 where
   557   "real_of_int \<equiv> of_int"
   558 
   559 abbreviation
   560   real_of_rat :: "rat \<Rightarrow> real"
   561 where
   562   "real_of_rat \<equiv> of_rat"
   563 
   564 consts
   565   (*overloaded constant for injecting other types into "real"*)
   566   real :: "'a => real"
   567 
   568 defs (overloaded)
   569   real_of_nat_def [code inline]: "real == real_of_nat"
   570   real_of_int_def [code inline]: "real == real_of_int"
   571 
   572 lemma real_eq_of_nat: "real = of_nat"
   573   unfolding real_of_nat_def ..
   574 
   575 lemma real_eq_of_int: "real = of_int"
   576   unfolding real_of_int_def ..
   577 
   578 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   579 by (simp add: real_of_int_def) 
   580 
   581 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   582 by (simp add: real_of_int_def) 
   583 
   584 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   585 by (simp add: real_of_int_def) 
   586 
   587 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   588 by (simp add: real_of_int_def) 
   589 
   590 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   591 by (simp add: real_of_int_def) 
   592 
   593 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   594 by (simp add: real_of_int_def) 
   595 
   596 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   597   apply (subst real_eq_of_int)+
   598   apply (rule of_int_setsum)
   599 done
   600 
   601 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   602     (PROD x:A. real(f x))"
   603   apply (subst real_eq_of_int)+
   604   apply (rule of_int_setprod)
   605 done
   606 
   607 lemma real_of_int_zero_cancel [simp, algebra, presburger]: "(real x = 0) = (x = (0::int))"
   608 by (simp add: real_of_int_def) 
   609 
   610 lemma real_of_int_inject [iff, algebra, presburger]: "(real (x::int) = real y) = (x = y)"
   611 by (simp add: real_of_int_def) 
   612 
   613 lemma real_of_int_less_iff [iff, presburger]: "(real (x::int) < real y) = (x < y)"
   614 by (simp add: real_of_int_def) 
   615 
   616 lemma real_of_int_le_iff [simp, presburger]: "(real (x::int) \<le> real y) = (x \<le> y)"
   617 by (simp add: real_of_int_def) 
   618 
   619 lemma real_of_int_gt_zero_cancel_iff [simp, presburger]: "(0 < real (n::int)) = (0 < n)"
   620 by (simp add: real_of_int_def) 
   621 
   622 lemma real_of_int_ge_zero_cancel_iff [simp, presburger]: "(0 <= real (n::int)) = (0 <= n)"
   623 by (simp add: real_of_int_def) 
   624 
   625 lemma real_of_int_lt_zero_cancel_iff [simp, presburger]: "(real (n::int) < 0) = (n < 0)" 
   626 by (simp add: real_of_int_def)
   627 
   628 lemma real_of_int_le_zero_cancel_iff [simp, presburger]: "(real (n::int) <= 0) = (n <= 0)"
   629 by (simp add: real_of_int_def)
   630 
   631 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   632 by (auto simp add: abs_if)
   633 
   634 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   635   apply (subgoal_tac "real n + 1 = real (n + 1)")
   636   apply (simp del: real_of_int_add)
   637   apply auto
   638 done
   639 
   640 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   641   apply (subgoal_tac "real m + 1 = real (m + 1)")
   642   apply (simp del: real_of_int_add)
   643   apply simp
   644 done
   645 
   646 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   647     real (x div d) + (real (x mod d)) / (real d)"
   648 proof -
   649   assume "d ~= 0"
   650   have "x = (x div d) * d + x mod d"
   651     by auto
   652   then have "real x = real (x div d) * real d + real(x mod d)"
   653     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   654   then have "real x / real d = ... / real d"
   655     by simp
   656   then show ?thesis
   657     by (auto simp add: add_divide_distrib ring_simps prems)
   658 qed
   659 
   660 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   661     real(n div d) = real n / real d"
   662   apply (frule real_of_int_div_aux [of d n])
   663   apply simp
   664   apply (simp add: zdvd_iff_zmod_eq_0)
   665 done
   666 
   667 lemma real_of_int_div2:
   668   "0 <= real (n::int) / real (x) - real (n div x)"
   669   apply (case_tac "x = 0")
   670   apply simp
   671   apply (case_tac "0 < x")
   672   apply (simp add: compare_rls)
   673   apply (subst real_of_int_div_aux)
   674   apply simp
   675   apply simp
   676   apply (subst zero_le_divide_iff)
   677   apply auto
   678   apply (simp add: compare_rls)
   679   apply (subst real_of_int_div_aux)
   680   apply simp
   681   apply simp
   682   apply (subst zero_le_divide_iff)
   683   apply auto
   684 done
   685 
   686 lemma real_of_int_div3:
   687   "real (n::int) / real (x) - real (n div x) <= 1"
   688   apply(case_tac "x = 0")
   689   apply simp
   690   apply (simp add: compare_rls)
   691   apply (subst real_of_int_div_aux)
   692   apply assumption
   693   apply simp
   694   apply (subst divide_le_eq)
   695   apply clarsimp
   696   apply (rule conjI)
   697   apply (rule impI)
   698   apply (rule order_less_imp_le)
   699   apply simp
   700   apply (rule impI)
   701   apply (rule order_less_imp_le)
   702   apply simp
   703 done
   704 
   705 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   706   by (insert real_of_int_div2 [of n x], simp)
   707 
   708 subsection{*Embedding the Naturals into the Reals*}
   709 
   710 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   711 by (simp add: real_of_nat_def)
   712 
   713 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   714 by (simp add: real_of_nat_def)
   715 
   716 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   717 by (simp add: real_of_nat_def)
   718 
   719 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   720 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   721 by (simp add: real_of_nat_def)
   722 
   723 lemma real_of_nat_less_iff [iff]: 
   724      "(real (n::nat) < real m) = (n < m)"
   725 by (simp add: real_of_nat_def)
   726 
   727 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   728 by (simp add: real_of_nat_def)
   729 
   730 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   731 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   732 
   733 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   734 by (simp add: real_of_nat_def del: of_nat_Suc)
   735 
   736 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   737 by (simp add: real_of_nat_def of_nat_mult)
   738 
   739 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   740     (SUM x:A. real(f x))"
   741   apply (subst real_eq_of_nat)+
   742   apply (rule of_nat_setsum)
   743 done
   744 
   745 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   746     (PROD x:A. real(f x))"
   747   apply (subst real_eq_of_nat)+
   748   apply (rule of_nat_setprod)
   749 done
   750 
   751 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   752   apply (subst card_eq_setsum)
   753   apply (subst real_of_nat_setsum)
   754   apply simp
   755 done
   756 
   757 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   758 by (simp add: real_of_nat_def)
   759 
   760 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   761 by (simp add: real_of_nat_def)
   762 
   763 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   764 by (simp add: add: real_of_nat_def of_nat_diff)
   765 
   766 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   767 by (auto simp: real_of_nat_def)
   768 
   769 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   770 by (simp add: add: real_of_nat_def)
   771 
   772 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   773 by (simp add: add: real_of_nat_def)
   774 
   775 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat))"
   776 by (simp add: add: real_of_nat_def)
   777 
   778 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   779   apply (subgoal_tac "real n + 1 = real (Suc n)")
   780   apply simp
   781   apply (auto simp add: real_of_nat_Suc)
   782 done
   783 
   784 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   785   apply (subgoal_tac "real m + 1 = real (Suc m)")
   786   apply (simp add: less_Suc_eq_le)
   787   apply (simp add: real_of_nat_Suc)
   788 done
   789 
   790 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   791     real (x div d) + (real (x mod d)) / (real d)"
   792 proof -
   793   assume "0 < d"
   794   have "x = (x div d) * d + x mod d"
   795     by auto
   796   then have "real x = real (x div d) * real d + real(x mod d)"
   797     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   798   then have "real x / real d = \<dots> / real d"
   799     by simp
   800   then show ?thesis
   801     by (auto simp add: add_divide_distrib ring_simps prems)
   802 qed
   803 
   804 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   805     real(n div d) = real n / real d"
   806   apply (frule real_of_nat_div_aux [of d n])
   807   apply simp
   808   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   809   apply assumption
   810 done
   811 
   812 lemma real_of_nat_div2:
   813   "0 <= real (n::nat) / real (x) - real (n div x)"
   814 apply(case_tac "x = 0")
   815  apply (simp)
   816 apply (simp add: compare_rls)
   817 apply (subst real_of_nat_div_aux)
   818  apply simp
   819 apply simp
   820 apply (subst zero_le_divide_iff)
   821 apply simp
   822 done
   823 
   824 lemma real_of_nat_div3:
   825   "real (n::nat) / real (x) - real (n div x) <= 1"
   826 apply(case_tac "x = 0")
   827 apply (simp)
   828 apply (simp add: compare_rls)
   829 apply (subst real_of_nat_div_aux)
   830  apply simp
   831 apply simp
   832 done
   833 
   834 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   835   by (insert real_of_nat_div2 [of n x], simp)
   836 
   837 lemma real_of_int_real_of_nat: "real (int n) = real n"
   838 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   839 
   840 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   841 by (simp add: real_of_int_def real_of_nat_def)
   842 
   843 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   844   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   845   apply force
   846   apply (simp only: real_of_int_real_of_nat)
   847 done
   848 
   849 subsection{*Numerals and Arithmetic*}
   850 
   851 instantiation real :: number_ring
   852 begin
   853 
   854 definition
   855   real_number_of_def [code func del]: "number_of w = real_of_int w"
   856 
   857 instance
   858   by intro_classes (simp add: real_number_of_def)
   859 
   860 end
   861 
   862 lemma [code unfold, symmetric, code post]:
   863   "number_of k = real_of_int (number_of k)"
   864   unfolding number_of_is_id real_number_of_def ..
   865 
   866 
   867 text{*Collapse applications of @{term real} to @{term number_of}*}
   868 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   869 by (simp add:  real_of_int_def of_int_number_of_eq)
   870 
   871 lemma real_of_nat_number_of [simp]:
   872      "real (number_of v :: nat) =  
   873         (if neg (number_of v :: int) then 0  
   874          else (number_of v :: real))"
   875 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   876  
   877 
   878 use "real_arith.ML"
   879 declaration {* K real_arith_setup *}
   880 
   881 
   882 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   883 
   884 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   885 lemma real_0_le_divide_iff:
   886      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   887 by (simp add: real_divide_def zero_le_mult_iff, auto)
   888 
   889 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   890 by arith
   891 
   892 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   893 by auto
   894 
   895 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   896 by auto
   897 
   898 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   899 by auto
   900 
   901 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   902 by auto
   903 
   904 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   905 by auto
   906 
   907 
   908 (*
   909 FIXME: we should have this, as for type int, but many proofs would break.
   910 It replaces x+-y by x-y.
   911 declare real_diff_def [symmetric, simp]
   912 *)
   913 
   914 
   915 subsubsection{*Density of the Reals*}
   916 
   917 lemma real_lbound_gt_zero:
   918      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   919 apply (rule_tac x = " (min d1 d2) /2" in exI)
   920 apply (simp add: min_def)
   921 done
   922 
   923 
   924 text{*Similar results are proved in @{text Ring_and_Field}*}
   925 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   926   by auto
   927 
   928 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   929   by auto
   930 
   931 
   932 subsection{*Absolute Value Function for the Reals*}
   933 
   934 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   935 by (simp add: abs_if)
   936 
   937 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
   938 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   939 by (force simp add: OrderedGroup.abs_le_iff)
   940 
   941 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   942 by (simp add: abs_if)
   943 
   944 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   945 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   946 
   947 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   948 by simp
   949  
   950 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   951 by simp
   952 
   953 instance real :: lordered_ring
   954 proof
   955   fix a::real
   956   show "abs a = sup a (-a)"
   957     by (auto simp add: real_abs_def sup_real_def)
   958 qed
   959 
   960 
   961 subsection {* Implementation of rational real numbers *}
   962 
   963 definition Ratreal :: "rat \<Rightarrow> real" where
   964   [simp]: "Ratreal = of_rat"
   965 
   966 code_datatype Ratreal
   967 
   968 lemma Ratreal_number_collapse [code post]:
   969   "Ratreal 0 = 0"
   970   "Ratreal 1 = 1"
   971   "Ratreal (number_of k) = number_of k"
   972 by simp_all
   973 
   974 lemma zero_real_code [code, code unfold]:
   975   "0 = Ratreal 0"
   976 by simp
   977 
   978 lemma one_real_code [code, code unfold]:
   979   "1 = Ratreal 1"
   980 by simp
   981 
   982 lemma number_of_real_code [code unfold]:
   983   "number_of k = Ratreal (number_of k)"
   984 by simp
   985 
   986 lemma Ratreal_number_of_quotient [code post]:
   987   "Ratreal (number_of r) / Ratreal (number_of s) = number_of r / number_of s"
   988 by simp
   989 
   990 lemma Ratreal_number_of_quotient2 [code post]:
   991   "Ratreal (number_of r / number_of s) = number_of r / number_of s"
   992 unfolding Ratreal_number_of_quotient [symmetric] Ratreal_def of_rat_divide ..
   993 
   994 instantiation real :: eq
   995 begin
   996 
   997 definition "eq_class.eq (x\<Colon>real) y \<longleftrightarrow> x - y = 0"
   998 
   999 instance by default (simp add: eq_real_def)
  1000 
  1001 lemma real_eq_code [code]: "eq_class.eq (Ratreal x) (Ratreal y) \<longleftrightarrow> eq_class.eq x y"
  1002   by (simp add: eq_real_def eq)
  1003 
  1004 end
  1005 
  1006 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
  1007   by (simp add: of_rat_less_eq)
  1008 
  1009 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
  1010   by (simp add: of_rat_less)
  1011 
  1012 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
  1013   by (simp add: of_rat_add)
  1014 
  1015 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
  1016   by (simp add: of_rat_mult)
  1017 
  1018 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
  1019   by (simp add: of_rat_minus)
  1020 
  1021 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
  1022   by (simp add: of_rat_diff)
  1023 
  1024 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
  1025   by (simp add: of_rat_inverse)
  1026  
  1027 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
  1028   by (simp add: of_rat_divide)
  1029 
  1030 text {* Setup for SML code generator *}
  1031 
  1032 types_code
  1033   real ("(int */ int)")
  1034 attach (term_of) {*
  1035 fun term_of_real (p, q) =
  1036   let
  1037     val rT = HOLogic.realT
  1038   in
  1039     if q = 1 orelse p = 0 then HOLogic.mk_number rT p
  1040     else @{term "op / \<Colon> real \<Rightarrow> real \<Rightarrow> real"} $
  1041       HOLogic.mk_number rT p $ HOLogic.mk_number rT q
  1042   end;
  1043 *}
  1044 attach (test) {*
  1045 fun gen_real i =
  1046   let
  1047     val p = random_range 0 i;
  1048     val q = random_range 1 (i + 1);
  1049     val g = Integer.gcd p q;
  1050     val p' = p div g;
  1051     val q' = q div g;
  1052     val r = (if one_of [true, false] then p' else ~ p',
  1053       if p' = 0 then 0 else q')
  1054   in
  1055     (r, fn () => term_of_real r)
  1056   end;
  1057 *}
  1058 
  1059 consts_code
  1060   Ratreal ("(_)")
  1061 
  1062 consts_code
  1063   "of_int :: int \<Rightarrow> real" ("\<module>real'_of'_int")
  1064 attach {*
  1065 fun real_of_int 0 = (0, 0)
  1066   | real_of_int i = (i, 1);
  1067 *}
  1068 
  1069 declare real_of_int_of_nat_eq [symmetric, code]
  1070 
  1071 end