src/Pure/Thy/export_theory.ML
author wenzelm
Sat Sep 29 23:23:43 2018 +0200 (12 months ago)
changeset 69083 6f8ae6ddc26b
parent 69077 11529ae45786
child 69086 2859dcdbc849
permissions -rw-r--r--
more direct locale goal: avoid renaming of type_parameters;
     1 (*  Title:      Pure/Thy/export_theory.ML
     2     Author:     Makarius
     3 
     4 Export foundational theory content and locale/class structure.
     5 *)
     6 
     7 signature EXPORT_THEORY =
     8 sig
     9   val setup_presentation: (Thy_Info.presentation_context -> theory -> unit) -> unit
    10   val export_body: theory -> string -> XML.body -> unit
    11 end;
    12 
    13 structure Export_Theory: EXPORT_THEORY =
    14 struct
    15 
    16 (* approximative syntax *)
    17 
    18 val get_syntax = Syntax.get_approx o Proof_Context.syn_of;
    19 fun get_syntax_type ctxt = get_syntax ctxt o Lexicon.mark_type;
    20 fun get_syntax_const ctxt = get_syntax ctxt o Lexicon.mark_const;
    21 fun get_syntax_fixed ctxt = get_syntax ctxt o Lexicon.mark_fixed;
    22 
    23 fun get_syntax_param ctxt loc x =
    24   let val thy = Proof_Context.theory_of ctxt in
    25     if Class.is_class thy loc then
    26       (case AList.lookup (op =) (Class.these_params thy [loc]) x of
    27         NONE => NONE
    28       | SOME (_, (c, _)) => get_syntax_const ctxt c)
    29     else get_syntax_fixed ctxt x
    30   end;
    31 
    32 val encode_syntax =
    33   XML.Encode.variant
    34    [fn NONE => ([], []),
    35     fn SOME (Syntax.Prefix delim) => ([delim], []),
    36     fn SOME (Syntax.Infix {assoc, delim, pri}) =>
    37       let
    38         val ass =
    39           (case assoc of
    40             Printer.No_Assoc => 0
    41           | Printer.Left_Assoc => 1
    42           | Printer.Right_Assoc => 2);
    43         open XML.Encode Term_XML.Encode;
    44       in ([], triple int string int (ass, delim, pri)) end];
    45 
    46 
    47 (* standardization of variables: only frees and named bounds *)
    48 
    49 local
    50 
    51 fun declare_names (Abs (_, _, b)) = declare_names b
    52   | declare_names (t $ u) = declare_names t #> declare_names u
    53   | declare_names (Const (c, _)) = Name.declare (Long_Name.base_name c)
    54   | declare_names (Free (x, _)) = Name.declare x
    55   | declare_names _ = I;
    56 
    57 fun variant_abs bs (Abs (x, T, t)) =
    58       let
    59         val names = fold Name.declare bs (declare_names t Name.context);
    60         val x' = #1 (Name.variant x names);
    61         val t' = variant_abs (x' :: bs) t;
    62       in Abs (x', T, t') end
    63   | variant_abs bs (t $ u) = variant_abs bs t $ variant_abs bs u
    64   | variant_abs _ t = t;
    65 
    66 in
    67 
    68 fun standard_vars used =
    69   let
    70     fun zero_var_indexes tm =
    71       Term_Subst.instantiate (Term_Subst.zero_var_indexes_inst used [tm]) tm;
    72 
    73     fun unvarifyT ty = ty |> Term.map_atyps
    74       (fn TVar ((a, _), S) => TFree (a, S)
    75         | T as TFree (a, _) =>
    76             if Name.is_declared used a then T
    77             else raise TYPE (Logic.bad_fixed a, [ty], []));
    78 
    79     fun unvarify tm = tm |> Term.map_aterms
    80       (fn Var ((x, _), T) => Free (x, T)
    81         | t as Free (x, _) =>
    82             if Name.is_declared used x then t
    83             else raise TERM (Logic.bad_fixed x, [tm])
    84         | t => t);
    85 
    86   in zero_var_indexes #> map_types unvarifyT #> unvarify #> variant_abs [] end;
    87 
    88 val standard_vars_global = standard_vars Name.context;
    89 
    90 end;
    91 
    92 
    93 (* free variables: not declared in the context *)
    94 
    95 val is_free = not oo Name.is_declared;
    96 
    97 fun add_frees used =
    98   fold_aterms (fn Free (x, T) => is_free used x ? insert (op =) (x, T) | _ => I);
    99 
   100 fun add_tfrees used =
   101   (fold_types o fold_atyps) (fn TFree (a, S) => is_free used a ? insert (op =) (a, S) | _ => I);
   102 
   103 
   104 (* locale content *)
   105 
   106 fun locale_content thy loc =
   107   let
   108     val ctxt = Locale.init loc thy;
   109     val args =
   110       Locale.params_of thy loc
   111       |> map (fn ((x, T), _) => ((x, T), get_syntax_param ctxt loc x));
   112     val axioms =
   113       let
   114         val (asm, defs) = Locale.specification_of thy loc;
   115         val cprops = map (Thm.cterm_of ctxt) (the_list asm @ defs);
   116         val (intro1, intro2) = Locale.intros_of thy loc;
   117         val intros_tac = Method.try_intros_tac ctxt (the_list intro1 @ the_list intro2) [];
   118         val res =
   119           Goal.init (Conjunction.mk_conjunction_balanced cprops)
   120           |> (ALLGOALS Goal.conjunction_tac THEN intros_tac)
   121           |> try Seq.hd;
   122       in
   123         (case res of
   124           SOME goal => Thm.prems_of goal
   125         | NONE => raise Fail ("Cannot unfold locale " ^ quote loc))
   126       end;
   127     val typargs = rev (fold Term.add_tfrees (map (Free o #1) args @ axioms) []);
   128   in {typargs = typargs, args = args, axioms = axioms} end;
   129 
   130 fun locale_dependency_subst thy (dep: Locale.locale_dependency) =
   131   let
   132     val (type_params, params) = Locale.parameters_of thy (#source dep);
   133     (* FIXME proper type_params wrt. locale_content (!?!) *)
   134     val typargs = fold (Term.add_tfreesT o #2 o #1) params type_params;
   135     val substT =
   136       typargs |> map_filter (fn v =>
   137         let
   138           val T = TFree v;
   139           val T' = Morphism.typ (#morphism dep) T;
   140         in if T = T' then NONE else SOME (v, T') end);
   141     val subst =
   142       params |> map_filter (fn (v, _) =>
   143         let
   144           val t = Free v;
   145           val t' = Morphism.term (#morphism dep) t;
   146         in if t aconv t' then NONE else SOME (v, t') end);
   147   in (substT, subst) end;
   148 
   149 
   150 (* general setup *)
   151 
   152 fun setup_presentation f =
   153   Theory.setup (Thy_Info.add_presentation (fn context => fn thy =>
   154     if Options.bool (#options context) "export_theory" then f context thy else ()));
   155 
   156 fun export_body thy name body =
   157   Export.export thy ("theory/" ^ name) (Buffer.chunks (YXML.buffer_body body Buffer.empty));
   158 
   159 
   160 (* presentation *)
   161 
   162 val _ = setup_presentation (fn {adjust_pos, ...} => fn thy =>
   163   let
   164     val parents = Theory.parents_of thy;
   165     val rep_tsig = Type.rep_tsig (Sign.tsig_of thy);
   166 
   167     val thy_ctxt = Proof_Context.init_global thy;
   168 
   169 
   170     (* entities *)
   171 
   172     fun make_entity_markup name xname pos serial =
   173       let
   174         val props =
   175           Position.offset_properties_of (adjust_pos pos) @
   176           Position.id_properties_of pos @
   177           Markup.serial_properties serial;
   178       in (Markup.entityN, (Markup.nameN, name) :: (Markup.xnameN, xname) :: props) end;
   179 
   180     fun entity_markup space name =
   181       let
   182         val xname = Name_Space.extern_shortest thy_ctxt space name;
   183         val {serial, pos, ...} = Name_Space.the_entry space name;
   184       in make_entity_markup name xname pos serial end;
   185 
   186     fun export_entities export_name export get_space decls =
   187       let val elems =
   188         let
   189           val parent_spaces = map get_space parents;
   190           val space = get_space thy;
   191         in
   192           (decls, []) |-> fold (fn (name, decl) =>
   193             if exists (fn space => Name_Space.declared space name) parent_spaces then I
   194             else
   195               (case export name decl of
   196                 NONE => I
   197               | SOME body =>
   198                   cons (#serial (Name_Space.the_entry space name),
   199                     XML.Elem (entity_markup space name, body))))
   200           |> sort (int_ord o apply2 #1) |> map #2
   201         end;
   202       in if null elems then () else export_body thy export_name elems end;
   203 
   204 
   205     (* types *)
   206 
   207     val encode_type =
   208       let open XML.Encode Term_XML.Encode
   209       in triple encode_syntax (list string) (option typ) end;
   210 
   211     fun export_type c (Type.LogicalType n) =
   212           SOME (encode_type (get_syntax_type thy_ctxt c, Name.invent Name.context Name.aT n, NONE))
   213       | export_type c (Type.Abbreviation (args, U, false)) =
   214           SOME (encode_type (get_syntax_type thy_ctxt c, args, SOME U))
   215       | export_type _ _ = NONE;
   216 
   217     val _ =
   218       export_entities "types" export_type Sign.type_space
   219         (Name_Space.dest_table (#types rep_tsig));
   220 
   221 
   222     (* consts *)
   223 
   224     val encode_const =
   225       let open XML.Encode Term_XML.Encode
   226       in pair encode_syntax (pair (list string) (pair typ (option term))) end;
   227 
   228     fun export_const c (T, abbrev) =
   229       let
   230         val syntax = get_syntax_const thy_ctxt c;
   231         val T' = T |> Logic.unvarifyT_global |> Type.strip_sorts;
   232         val abbrev' = abbrev |> Option.map (standard_vars_global #> map_types Type.strip_sorts);
   233         val args = map (#1 o dest_TFree) (Consts.typargs (Sign.consts_of thy) (c, T'));
   234       in encode_const (syntax, (args, (T', abbrev'))) end;
   235 
   236     val _ =
   237       export_entities "consts" (SOME oo export_const) Sign.const_space
   238         (#constants (Consts.dest (Sign.consts_of thy)));
   239 
   240 
   241     (* axioms and facts *)
   242 
   243     fun prop_of raw_thm =
   244       let
   245         val thm = raw_thm
   246           |> Thm.transfer thy
   247           |> Thm.check_hyps (Context.Theory thy)
   248           |> Thm.strip_shyps;
   249         val prop = thm
   250           |> Thm.full_prop_of;
   251       in (Thm.extra_shyps thm, prop) end;
   252 
   253     fun encode_prop used (Ss, raw_prop) =
   254       let
   255         val prop = standard_vars used raw_prop;
   256         val args = rev (add_frees used prop []);
   257         val typargs = rev (add_tfrees used prop []);
   258         val used' = fold (Name.declare o #1) typargs used;
   259         val sorts = Name.invent used' Name.aT (length Ss) ~~ Ss;
   260       in
   261         (sorts @ typargs, args, prop) |>
   262           let open XML.Encode Term_XML.Encode
   263           in triple (list (pair string sort)) (list (pair string typ)) term end
   264       end;
   265 
   266     fun encode_axiom used t = encode_prop used ([], t);
   267 
   268     val encode_fact_single = encode_prop Name.context o prop_of;
   269     val encode_fact_multi = XML.Encode.list (encode_prop Name.context) o map prop_of;
   270 
   271     val _ =
   272       export_entities "axioms" (fn _ => fn t => SOME (encode_axiom Name.context t))
   273         Theory.axiom_space (Theory.axioms_of thy);
   274     val _ =
   275       export_entities "facts" (K (SOME o encode_fact_multi))
   276         (Facts.space_of o Global_Theory.facts_of)
   277         (Facts.dest_static true [] (Global_Theory.facts_of thy));
   278 
   279 
   280     (* type classes *)
   281 
   282     val encode_class =
   283       let open XML.Encode Term_XML.Encode
   284       in pair (list (pair string typ)) (list encode_fact_single) end;
   285 
   286     fun export_class name =
   287       (case try (Axclass.get_info thy) name of
   288         NONE => ([], [])
   289       | SOME {params, axioms, ...} => (params, axioms))
   290       |> encode_class |> SOME;
   291 
   292     val _ =
   293       export_entities "classes" (fn name => fn () => export_class name)
   294         Sign.class_space (map (rpair ()) (Graph.keys (Sorts.classes_of (#2 (#classes rep_tsig)))));
   295 
   296 
   297     (* sort algebra *)
   298 
   299     val {classrel, arities} =
   300       Sorts.dest_algebra (map (#2 o #classes o Type.rep_tsig o Sign.tsig_of) parents)
   301         (#2 (#classes rep_tsig));
   302 
   303     val encode_classrel =
   304       let open XML.Encode
   305       in list (pair string (list string)) end;
   306 
   307     val encode_arities =
   308       let open XML.Encode Term_XML.Encode
   309       in list (triple string (list sort) string) end;
   310 
   311     val _ = if null classrel then () else export_body thy "classrel" (encode_classrel classrel);
   312     val _ = if null arities then () else export_body thy "arities" (encode_arities arities);
   313 
   314 
   315     (* locales *)
   316 
   317     fun encode_locale used =
   318       let open XML.Encode Term_XML.Encode in
   319         triple (list (pair string sort)) (list (pair (pair string typ) encode_syntax))
   320           (list (encode_axiom used))
   321       end;
   322 
   323     fun export_locale loc =
   324       let
   325         val {typargs, args, axioms} = locale_content thy loc;
   326         val used = fold Name.declare (map #1 typargs @ map (#1 o #1) args) Name.context;
   327       in encode_locale used (typargs, args, axioms) end
   328       handle ERROR msg =>
   329         cat_error msg ("The error(s) above occurred in locale " ^
   330           quote (Locale.markup_name thy_ctxt loc));
   331 
   332     val _ =
   333       export_entities "locales" (fn loc => fn () => SOME (export_locale loc))
   334         Locale.locale_space
   335         (map (rpair ()) (Locale.get_locales thy));
   336 
   337 
   338     (* locale dependencies *)
   339 
   340     fun encode_locale_dependency (dep: Locale.locale_dependency) =
   341       (#source dep, (#target dep, (#prefix dep, locale_dependency_subst thy dep))) |>
   342         let
   343           open XML.Encode Term_XML.Encode;
   344           val encode_subst =
   345             pair (list (pair (pair string sort) typ)) (list (pair (pair string typ) term));
   346         in pair string (pair string (pair (list (pair string bool)) encode_subst)) end;
   347 
   348     val _ =
   349       (case Locale.dest_dependencies parents thy of
   350         [] => ()
   351       | deps =>
   352           deps |> map_index (fn (i, dep) =>
   353             let
   354               val xname = string_of_int (i + 1);
   355               val name = Long_Name.implode [Context.theory_name thy, xname];
   356               val body = encode_locale_dependency dep;
   357             in XML.Elem (make_entity_markup name xname (#pos dep) (#serial dep), body) end)
   358           |> export_body thy "locale_dependencies");
   359 
   360 
   361     (* parents *)
   362 
   363     val _ =
   364       export_body thy "parents"
   365         (XML.Encode.string (cat_lines (map Context.theory_long_name parents)));
   366 
   367   in () end);
   368 
   369 end;