src/HOL/Limits.thy
 author nipkow Mon Jan 30 21:49:41 2012 +0100 (2012-01-30) changeset 46372 6fa9cdb8b850 parent 45892 8dcf6692433f child 46886 4cd29473c65d permissions -rw-r--r--
added "'a rel"
```     1 (*  Title       : Limits.thy
```
```     2     Author      : Brian Huffman
```
```     3 *)
```
```     4
```
```     5 header {* Filters and Limits *}
```
```     6
```
```     7 theory Limits
```
```     8 imports RealVector
```
```     9 begin
```
```    10
```
```    11 subsection {* Filters *}
```
```    12
```
```    13 text {*
```
```    14   This definition also allows non-proper filters.
```
```    15 *}
```
```    16
```
```    17 locale is_filter =
```
```    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
```
```    19   assumes True: "F (\<lambda>x. True)"
```
```    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
```
```    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
```
```    22
```
```    23 typedef (open) 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
```
```    24 proof
```
```    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
```
```    26 qed
```
```    27
```
```    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
```
```    29   using Rep_filter [of F] by simp
```
```    30
```
```    31 lemma Abs_filter_inverse':
```
```    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
```
```    33   using assms by (simp add: Abs_filter_inverse)
```
```    34
```
```    35
```
```    36 subsection {* Eventually *}
```
```    37
```
```    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
```
```    40
```
```    41 lemma eventually_Abs_filter:
```
```    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
```
```    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
```
```    44
```
```    45 lemma filter_eq_iff:
```
```    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
```
```    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
```
```    48
```
```    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
```
```    50   unfolding eventually_def
```
```    51   by (rule is_filter.True [OF is_filter_Rep_filter])
```
```    52
```
```    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
```
```    54 proof -
```
```    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
```
```    56   thus "eventually P F" by simp
```
```    57 qed
```
```    58
```
```    59 lemma eventually_mono:
```
```    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
```
```    61   unfolding eventually_def
```
```    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
```
```    63
```
```    64 lemma eventually_conj:
```
```    65   assumes P: "eventually (\<lambda>x. P x) F"
```
```    66   assumes Q: "eventually (\<lambda>x. Q x) F"
```
```    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
```
```    68   using assms unfolding eventually_def
```
```    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
```
```    70
```
```    71 lemma eventually_mp:
```
```    72   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```    73   assumes "eventually (\<lambda>x. P x) F"
```
```    74   shows "eventually (\<lambda>x. Q x) F"
```
```    75 proof (rule eventually_mono)
```
```    76   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
```
```    77   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
```
```    78     using assms by (rule eventually_conj)
```
```    79 qed
```
```    80
```
```    81 lemma eventually_rev_mp:
```
```    82   assumes "eventually (\<lambda>x. P x) F"
```
```    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```    84   shows "eventually (\<lambda>x. Q x) F"
```
```    85 using assms(2) assms(1) by (rule eventually_mp)
```
```    86
```
```    87 lemma eventually_conj_iff:
```
```    88   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
```
```    89   by (auto intro: eventually_conj elim: eventually_rev_mp)
```
```    90
```
```    91 lemma eventually_elim1:
```
```    92   assumes "eventually (\<lambda>i. P i) F"
```
```    93   assumes "\<And>i. P i \<Longrightarrow> Q i"
```
```    94   shows "eventually (\<lambda>i. Q i) F"
```
```    95   using assms by (auto elim!: eventually_rev_mp)
```
```    96
```
```    97 lemma eventually_elim2:
```
```    98   assumes "eventually (\<lambda>i. P i) F"
```
```    99   assumes "eventually (\<lambda>i. Q i) F"
```
```   100   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
```
```   101   shows "eventually (\<lambda>i. R i) F"
```
```   102   using assms by (auto elim!: eventually_rev_mp)
```
```   103
```
```   104 lemma eventually_subst:
```
```   105   assumes "eventually (\<lambda>n. P n = Q n) F"
```
```   106   shows "eventually P F = eventually Q F" (is "?L = ?R")
```
```   107 proof -
```
```   108   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```   109       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
```
```   110     by (auto elim: eventually_elim1)
```
```   111   then show ?thesis by (auto elim: eventually_elim2)
```
```   112 qed
```
```   113
```
```   114
```
```   115
```
```   116 subsection {* Finer-than relation *}
```
```   117
```
```   118 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
```
```   119 filter @{term F'}. *}
```
```   120
```
```   121 instantiation filter :: (type) complete_lattice
```
```   122 begin
```
```   123
```
```   124 definition le_filter_def:
```
```   125   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
```
```   126
```
```   127 definition
```
```   128   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
```
```   129
```
```   130 definition
```
```   131   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
```
```   132
```
```   133 definition
```
```   134   "bot = Abs_filter (\<lambda>P. True)"
```
```   135
```
```   136 definition
```
```   137   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
```
```   138
```
```   139 definition
```
```   140   "inf F F' = Abs_filter
```
```   141       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
```
```   142
```
```   143 definition
```
```   144   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
```
```   145
```
```   146 definition
```
```   147   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
```
```   148
```
```   149 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
```
```   150   unfolding top_filter_def
```
```   151   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
```
```   152
```
```   153 lemma eventually_bot [simp]: "eventually P bot"
```
```   154   unfolding bot_filter_def
```
```   155   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
```
```   156
```
```   157 lemma eventually_sup:
```
```   158   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
```
```   159   unfolding sup_filter_def
```
```   160   by (rule eventually_Abs_filter, rule is_filter.intro)
```
```   161      (auto elim!: eventually_rev_mp)
```
```   162
```
```   163 lemma eventually_inf:
```
```   164   "eventually P (inf F F') \<longleftrightarrow>
```
```   165    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
```
```   166   unfolding inf_filter_def
```
```   167   apply (rule eventually_Abs_filter, rule is_filter.intro)
```
```   168   apply (fast intro: eventually_True)
```
```   169   apply clarify
```
```   170   apply (intro exI conjI)
```
```   171   apply (erule (1) eventually_conj)
```
```   172   apply (erule (1) eventually_conj)
```
```   173   apply simp
```
```   174   apply auto
```
```   175   done
```
```   176
```
```   177 lemma eventually_Sup:
```
```   178   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
```
```   179   unfolding Sup_filter_def
```
```   180   apply (rule eventually_Abs_filter, rule is_filter.intro)
```
```   181   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
```
```   182   done
```
```   183
```
```   184 instance proof
```
```   185   fix F F' F'' :: "'a filter" and S :: "'a filter set"
```
```   186   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
```
```   187     by (rule less_filter_def) }
```
```   188   { show "F \<le> F"
```
```   189     unfolding le_filter_def by simp }
```
```   190   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
```
```   191     unfolding le_filter_def by simp }
```
```   192   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
```
```   193     unfolding le_filter_def filter_eq_iff by fast }
```
```   194   { show "F \<le> top"
```
```   195     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
```
```   196   { show "bot \<le> F"
```
```   197     unfolding le_filter_def by simp }
```
```   198   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
```
```   199     unfolding le_filter_def eventually_sup by simp_all }
```
```   200   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
```
```   201     unfolding le_filter_def eventually_sup by simp }
```
```   202   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
```
```   203     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
```
```   204   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
```
```   205     unfolding le_filter_def eventually_inf
```
```   206     by (auto elim!: eventually_mono intro: eventually_conj) }
```
```   207   { assume "F \<in> S" thus "F \<le> Sup S"
```
```   208     unfolding le_filter_def eventually_Sup by simp }
```
```   209   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
```
```   210     unfolding le_filter_def eventually_Sup by simp }
```
```   211   { assume "F'' \<in> S" thus "Inf S \<le> F''"
```
```   212     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
```
```   213   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
```
```   214     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
```
```   215 qed
```
```   216
```
```   217 end
```
```   218
```
```   219 lemma filter_leD:
```
```   220   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
```
```   221   unfolding le_filter_def by simp
```
```   222
```
```   223 lemma filter_leI:
```
```   224   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
```
```   225   unfolding le_filter_def by simp
```
```   226
```
```   227 lemma eventually_False:
```
```   228   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
```
```   229   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
```
```   230
```
```   231 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
```
```   232   where "trivial_limit F \<equiv> F = bot"
```
```   233
```
```   234 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
```
```   235   by (rule eventually_False [symmetric])
```
```   236
```
```   237
```
```   238 subsection {* Map function for filters *}
```
```   239
```
```   240 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
```
```   241   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
```
```   242
```
```   243 lemma eventually_filtermap:
```
```   244   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
```
```   245   unfolding filtermap_def
```
```   246   apply (rule eventually_Abs_filter)
```
```   247   apply (rule is_filter.intro)
```
```   248   apply (auto elim!: eventually_rev_mp)
```
```   249   done
```
```   250
```
```   251 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
```
```   252   by (simp add: filter_eq_iff eventually_filtermap)
```
```   253
```
```   254 lemma filtermap_filtermap:
```
```   255   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
```
```   256   by (simp add: filter_eq_iff eventually_filtermap)
```
```   257
```
```   258 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
```
```   259   unfolding le_filter_def eventually_filtermap by simp
```
```   260
```
```   261 lemma filtermap_bot [simp]: "filtermap f bot = bot"
```
```   262   by (simp add: filter_eq_iff eventually_filtermap)
```
```   263
```
```   264
```
```   265 subsection {* Sequentially *}
```
```   266
```
```   267 definition sequentially :: "nat filter"
```
```   268   where "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
```
```   269
```
```   270 lemma eventually_sequentially:
```
```   271   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
```
```   272 unfolding sequentially_def
```
```   273 proof (rule eventually_Abs_filter, rule is_filter.intro)
```
```   274   fix P Q :: "nat \<Rightarrow> bool"
```
```   275   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
```
```   276   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
```
```   277   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
```
```   278   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
```
```   279 qed auto
```
```   280
```
```   281 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
```
```   282   unfolding filter_eq_iff eventually_sequentially by auto
```
```   283
```
```   284 lemmas trivial_limit_sequentially = sequentially_bot
```
```   285
```
```   286 lemma eventually_False_sequentially [simp]:
```
```   287   "\<not> eventually (\<lambda>n. False) sequentially"
```
```   288   by (simp add: eventually_False)
```
```   289
```
```   290 lemma le_sequentially:
```
```   291   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
```
```   292   unfolding le_filter_def eventually_sequentially
```
```   293   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
```
```   294
```
```   295 lemma eventually_sequentiallyI:
```
```   296   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
```
```   297   shows "eventually P sequentially"
```
```   298 using assms by (auto simp: eventually_sequentially)
```
```   299
```
```   300
```
```   301 subsection {* Standard filters *}
```
```   302
```
```   303 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
```
```   304   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
```
```   305
```
```   306 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
```
```   307   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
```
```   308
```
```   309 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
```
```   310   where "at a = nhds a within - {a}"
```
```   311
```
```   312 lemma eventually_within:
```
```   313   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
```
```   314   unfolding within_def
```
```   315   by (rule eventually_Abs_filter, rule is_filter.intro)
```
```   316      (auto elim!: eventually_rev_mp)
```
```   317
```
```   318 lemma within_UNIV [simp]: "F within UNIV = F"
```
```   319   unfolding filter_eq_iff eventually_within by simp
```
```   320
```
```   321 lemma within_empty [simp]: "F within {} = bot"
```
```   322   unfolding filter_eq_iff eventually_within by simp
```
```   323
```
```   324 lemma eventually_nhds:
```
```   325   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
```
```   326 unfolding nhds_def
```
```   327 proof (rule eventually_Abs_filter, rule is_filter.intro)
```
```   328   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
```
```   329   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
```
```   330 next
```
```   331   fix P Q
```
```   332   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
```
```   333      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
```
```   334   then obtain S T where
```
```   335     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
```
```   336     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
```
```   337   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
```
```   338     by (simp add: open_Int)
```
```   339   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
```
```   340 qed auto
```
```   341
```
```   342 lemma eventually_nhds_metric:
```
```   343   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
```
```   344 unfolding eventually_nhds open_dist
```
```   345 apply safe
```
```   346 apply fast
```
```   347 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
```
```   348 apply clarsimp
```
```   349 apply (rule_tac x="d - dist x a" in exI, clarsimp)
```
```   350 apply (simp only: less_diff_eq)
```
```   351 apply (erule le_less_trans [OF dist_triangle])
```
```   352 done
```
```   353
```
```   354 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
```
```   355   unfolding trivial_limit_def eventually_nhds by simp
```
```   356
```
```   357 lemma eventually_at_topological:
```
```   358   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
```
```   359 unfolding at_def eventually_within eventually_nhds by simp
```
```   360
```
```   361 lemma eventually_at:
```
```   362   fixes a :: "'a::metric_space"
```
```   363   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
```
```   364 unfolding at_def eventually_within eventually_nhds_metric by auto
```
```   365
```
```   366 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
```
```   367   unfolding trivial_limit_def eventually_at_topological
```
```   368   by (safe, case_tac "S = {a}", simp, fast, fast)
```
```   369
```
```   370 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
```
```   371   by (simp add: at_eq_bot_iff not_open_singleton)
```
```   372
```
```   373
```
```   374 subsection {* Boundedness *}
```
```   375
```
```   376 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```   377   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
```
```   378
```
```   379 lemma BfunI:
```
```   380   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
```
```   381 unfolding Bfun_def
```
```   382 proof (intro exI conjI allI)
```
```   383   show "0 < max K 1" by simp
```
```   384 next
```
```   385   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
```
```   386     using K by (rule eventually_elim1, simp)
```
```   387 qed
```
```   388
```
```   389 lemma BfunE:
```
```   390   assumes "Bfun f F"
```
```   391   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
```
```   392 using assms unfolding Bfun_def by fast
```
```   393
```
```   394
```
```   395 subsection {* Convergence to Zero *}
```
```   396
```
```   397 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```   398   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
```
```   399
```
```   400 lemma ZfunI:
```
```   401   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
```
```   402   unfolding Zfun_def by simp
```
```   403
```
```   404 lemma ZfunD:
```
```   405   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
```
```   406   unfolding Zfun_def by simp
```
```   407
```
```   408 lemma Zfun_ssubst:
```
```   409   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
```
```   410   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
```
```   411
```
```   412 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
```
```   413   unfolding Zfun_def by simp
```
```   414
```
```   415 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
```
```   416   unfolding Zfun_def by simp
```
```   417
```
```   418 lemma Zfun_imp_Zfun:
```
```   419   assumes f: "Zfun f F"
```
```   420   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
```
```   421   shows "Zfun (\<lambda>x. g x) F"
```
```   422 proof (cases)
```
```   423   assume K: "0 < K"
```
```   424   show ?thesis
```
```   425   proof (rule ZfunI)
```
```   426     fix r::real assume "0 < r"
```
```   427     hence "0 < r / K"
```
```   428       using K by (rule divide_pos_pos)
```
```   429     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
```
```   430       using ZfunD [OF f] by fast
```
```   431     with g show "eventually (\<lambda>x. norm (g x) < r) F"
```
```   432     proof (rule eventually_elim2)
```
```   433       fix x
```
```   434       assume *: "norm (g x) \<le> norm (f x) * K"
```
```   435       assume "norm (f x) < r / K"
```
```   436       hence "norm (f x) * K < r"
```
```   437         by (simp add: pos_less_divide_eq K)
```
```   438       thus "norm (g x) < r"
```
```   439         by (simp add: order_le_less_trans [OF *])
```
```   440     qed
```
```   441   qed
```
```   442 next
```
```   443   assume "\<not> 0 < K"
```
```   444   hence K: "K \<le> 0" by (simp only: not_less)
```
```   445   show ?thesis
```
```   446   proof (rule ZfunI)
```
```   447     fix r :: real
```
```   448     assume "0 < r"
```
```   449     from g show "eventually (\<lambda>x. norm (g x) < r) F"
```
```   450     proof (rule eventually_elim1)
```
```   451       fix x
```
```   452       assume "norm (g x) \<le> norm (f x) * K"
```
```   453       also have "\<dots> \<le> norm (f x) * 0"
```
```   454         using K norm_ge_zero by (rule mult_left_mono)
```
```   455       finally show "norm (g x) < r"
```
```   456         using `0 < r` by simp
```
```   457     qed
```
```   458   qed
```
```   459 qed
```
```   460
```
```   461 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
```
```   462   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
```
```   463
```
```   464 lemma Zfun_add:
```
```   465   assumes f: "Zfun f F" and g: "Zfun g F"
```
```   466   shows "Zfun (\<lambda>x. f x + g x) F"
```
```   467 proof (rule ZfunI)
```
```   468   fix r::real assume "0 < r"
```
```   469   hence r: "0 < r / 2" by simp
```
```   470   have "eventually (\<lambda>x. norm (f x) < r/2) F"
```
```   471     using f r by (rule ZfunD)
```
```   472   moreover
```
```   473   have "eventually (\<lambda>x. norm (g x) < r/2) F"
```
```   474     using g r by (rule ZfunD)
```
```   475   ultimately
```
```   476   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
```
```   477   proof (rule eventually_elim2)
```
```   478     fix x
```
```   479     assume *: "norm (f x) < r/2" "norm (g x) < r/2"
```
```   480     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
```
```   481       by (rule norm_triangle_ineq)
```
```   482     also have "\<dots> < r/2 + r/2"
```
```   483       using * by (rule add_strict_mono)
```
```   484     finally show "norm (f x + g x) < r"
```
```   485       by simp
```
```   486   qed
```
```   487 qed
```
```   488
```
```   489 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
```
```   490   unfolding Zfun_def by simp
```
```   491
```
```   492 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
```
```   493   by (simp only: diff_minus Zfun_add Zfun_minus)
```
```   494
```
```   495 lemma (in bounded_linear) Zfun:
```
```   496   assumes g: "Zfun g F"
```
```   497   shows "Zfun (\<lambda>x. f (g x)) F"
```
```   498 proof -
```
```   499   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
```
```   500     using bounded by fast
```
```   501   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
```
```   502     by simp
```
```   503   with g show ?thesis
```
```   504     by (rule Zfun_imp_Zfun)
```
```   505 qed
```
```   506
```
```   507 lemma (in bounded_bilinear) Zfun:
```
```   508   assumes f: "Zfun f F"
```
```   509   assumes g: "Zfun g F"
```
```   510   shows "Zfun (\<lambda>x. f x ** g x) F"
```
```   511 proof (rule ZfunI)
```
```   512   fix r::real assume r: "0 < r"
```
```   513   obtain K where K: "0 < K"
```
```   514     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
```
```   515     using pos_bounded by fast
```
```   516   from K have K': "0 < inverse K"
```
```   517     by (rule positive_imp_inverse_positive)
```
```   518   have "eventually (\<lambda>x. norm (f x) < r) F"
```
```   519     using f r by (rule ZfunD)
```
```   520   moreover
```
```   521   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
```
```   522     using g K' by (rule ZfunD)
```
```   523   ultimately
```
```   524   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
```
```   525   proof (rule eventually_elim2)
```
```   526     fix x
```
```   527     assume *: "norm (f x) < r" "norm (g x) < inverse K"
```
```   528     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
```
```   529       by (rule norm_le)
```
```   530     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
```
```   531       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero * K)
```
```   532     also from K have "r * inverse K * K = r"
```
```   533       by simp
```
```   534     finally show "norm (f x ** g x) < r" .
```
```   535   qed
```
```   536 qed
```
```   537
```
```   538 lemma (in bounded_bilinear) Zfun_left:
```
```   539   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
```
```   540   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
```
```   541
```
```   542 lemma (in bounded_bilinear) Zfun_right:
```
```   543   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
```
```   544   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
```
```   545
```
```   546 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
```
```   547 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
```
```   548 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
```
```   549
```
```   550
```
```   551 subsection {* Limits *}
```
```   552
```
```   553 definition (in topological_space)
```
```   554   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
```
```   555   "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
```
```   556
```
```   557 definition real_tendsto_inf :: "('a \<Rightarrow> real) \<Rightarrow> 'a filter \<Rightarrow> bool" where
```
```   558   "real_tendsto_inf f F \<equiv> \<forall>x. eventually (\<lambda>y. x < f y) F"
```
```   559
```
```   560 ML {*
```
```   561 structure Tendsto_Intros = Named_Thms
```
```   562 (
```
```   563   val name = @{binding tendsto_intros}
```
```   564   val description = "introduction rules for tendsto"
```
```   565 )
```
```   566 *}
```
```   567
```
```   568 setup Tendsto_Intros.setup
```
```   569
```
```   570 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
```
```   571   unfolding tendsto_def le_filter_def by fast
```
```   572
```
```   573 lemma topological_tendstoI:
```
```   574   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
```
```   575     \<Longrightarrow> (f ---> l) F"
```
```   576   unfolding tendsto_def by auto
```
```   577
```
```   578 lemma topological_tendstoD:
```
```   579   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
```
```   580   unfolding tendsto_def by auto
```
```   581
```
```   582 lemma tendstoI:
```
```   583   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
```
```   584   shows "(f ---> l) F"
```
```   585   apply (rule topological_tendstoI)
```
```   586   apply (simp add: open_dist)
```
```   587   apply (drule (1) bspec, clarify)
```
```   588   apply (drule assms)
```
```   589   apply (erule eventually_elim1, simp)
```
```   590   done
```
```   591
```
```   592 lemma tendstoD:
```
```   593   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
```
```   594   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
```
```   595   apply (clarsimp simp add: open_dist)
```
```   596   apply (rule_tac x="e - dist x l" in exI, clarsimp)
```
```   597   apply (simp only: less_diff_eq)
```
```   598   apply (erule le_less_trans [OF dist_triangle])
```
```   599   apply simp
```
```   600   apply simp
```
```   601   done
```
```   602
```
```   603 lemma tendsto_iff:
```
```   604   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
```
```   605   using tendstoI tendstoD by fast
```
```   606
```
```   607 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
```
```   608   by (simp only: tendsto_iff Zfun_def dist_norm)
```
```   609
```
```   610 lemma tendsto_bot [simp]: "(f ---> a) bot"
```
```   611   unfolding tendsto_def by simp
```
```   612
```
```   613 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
```
```   614   unfolding tendsto_def eventually_at_topological by auto
```
```   615
```
```   616 lemma tendsto_ident_at_within [tendsto_intros]:
```
```   617   "((\<lambda>x. x) ---> a) (at a within S)"
```
```   618   unfolding tendsto_def eventually_within eventually_at_topological by auto
```
```   619
```
```   620 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
```
```   621   by (simp add: tendsto_def)
```
```   622
```
```   623 lemma tendsto_unique:
```
```   624   fixes f :: "'a \<Rightarrow> 'b::t2_space"
```
```   625   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
```
```   626   shows "a = b"
```
```   627 proof (rule ccontr)
```
```   628   assume "a \<noteq> b"
```
```   629   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
```
```   630     using hausdorff [OF `a \<noteq> b`] by fast
```
```   631   have "eventually (\<lambda>x. f x \<in> U) F"
```
```   632     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
```
```   633   moreover
```
```   634   have "eventually (\<lambda>x. f x \<in> V) F"
```
```   635     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
```
```   636   ultimately
```
```   637   have "eventually (\<lambda>x. False) F"
```
```   638   proof (rule eventually_elim2)
```
```   639     fix x
```
```   640     assume "f x \<in> U" "f x \<in> V"
```
```   641     hence "f x \<in> U \<inter> V" by simp
```
```   642     with `U \<inter> V = {}` show "False" by simp
```
```   643   qed
```
```   644   with `\<not> trivial_limit F` show "False"
```
```   645     by (simp add: trivial_limit_def)
```
```   646 qed
```
```   647
```
```   648 lemma tendsto_const_iff:
```
```   649   fixes a b :: "'a::t2_space"
```
```   650   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
```
```   651   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
```
```   652
```
```   653 lemma tendsto_compose:
```
```   654   assumes g: "(g ---> g l) (at l)"
```
```   655   assumes f: "(f ---> l) F"
```
```   656   shows "((\<lambda>x. g (f x)) ---> g l) F"
```
```   657 proof (rule topological_tendstoI)
```
```   658   fix B assume B: "open B" "g l \<in> B"
```
```   659   obtain A where A: "open A" "l \<in> A"
```
```   660     and gB: "\<forall>y. y \<in> A \<longrightarrow> g y \<in> B"
```
```   661     using topological_tendstoD [OF g B] B(2)
```
```   662     unfolding eventually_at_topological by fast
```
```   663   hence "\<forall>x. f x \<in> A \<longrightarrow> g (f x) \<in> B" by simp
```
```   664   from this topological_tendstoD [OF f A]
```
```   665   show "eventually (\<lambda>x. g (f x) \<in> B) F"
```
```   666     by (rule eventually_mono)
```
```   667 qed
```
```   668
```
```   669 lemma tendsto_compose_eventually:
```
```   670   assumes g: "(g ---> m) (at l)"
```
```   671   assumes f: "(f ---> l) F"
```
```   672   assumes inj: "eventually (\<lambda>x. f x \<noteq> l) F"
```
```   673   shows "((\<lambda>x. g (f x)) ---> m) F"
```
```   674 proof (rule topological_tendstoI)
```
```   675   fix B assume B: "open B" "m \<in> B"
```
```   676   obtain A where A: "open A" "l \<in> A"
```
```   677     and gB: "\<And>y. y \<in> A \<Longrightarrow> y \<noteq> l \<Longrightarrow> g y \<in> B"
```
```   678     using topological_tendstoD [OF g B]
```
```   679     unfolding eventually_at_topological by fast
```
```   680   show "eventually (\<lambda>x. g (f x) \<in> B) F"
```
```   681     using topological_tendstoD [OF f A] inj
```
```   682     by (rule eventually_elim2) (simp add: gB)
```
```   683 qed
```
```   684
```
```   685 lemma metric_tendsto_imp_tendsto:
```
```   686   assumes f: "(f ---> a) F"
```
```   687   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
```
```   688   shows "(g ---> b) F"
```
```   689 proof (rule tendstoI)
```
```   690   fix e :: real assume "0 < e"
```
```   691   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
```
```   692   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
```
```   693     using le_less_trans by (rule eventually_elim2)
```
```   694 qed
```
```   695
```
```   696 lemma real_tendsto_inf_real: "real_tendsto_inf real sequentially"
```
```   697 proof (unfold real_tendsto_inf_def, rule allI)
```
```   698   fix x show "eventually (\<lambda>y. x < real y) sequentially"
```
```   699     by (rule eventually_sequentiallyI[of "natceiling (x + 1)"])
```
```   700         (simp add: natceiling_le_eq)
```
```   701 qed
```
```   702
```
```   703
```
```   704
```
```   705 subsubsection {* Distance and norms *}
```
```   706
```
```   707 lemma tendsto_dist [tendsto_intros]:
```
```   708   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
```
```   709   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
```
```   710 proof (rule tendstoI)
```
```   711   fix e :: real assume "0 < e"
```
```   712   hence e2: "0 < e/2" by simp
```
```   713   from tendstoD [OF f e2] tendstoD [OF g e2]
```
```   714   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
```
```   715   proof (rule eventually_elim2)
```
```   716     fix x assume "dist (f x) l < e/2" "dist (g x) m < e/2"
```
```   717     then show "dist (dist (f x) (g x)) (dist l m) < e"
```
```   718       unfolding dist_real_def
```
```   719       using dist_triangle2 [of "f x" "g x" "l"]
```
```   720       using dist_triangle2 [of "g x" "l" "m"]
```
```   721       using dist_triangle3 [of "l" "m" "f x"]
```
```   722       using dist_triangle [of "f x" "m" "g x"]
```
```   723       by arith
```
```   724   qed
```
```   725 qed
```
```   726
```
```   727 lemma norm_conv_dist: "norm x = dist x 0"
```
```   728   unfolding dist_norm by simp
```
```   729
```
```   730 lemma tendsto_norm [tendsto_intros]:
```
```   731   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
```
```   732   unfolding norm_conv_dist by (intro tendsto_intros)
```
```   733
```
```   734 lemma tendsto_norm_zero:
```
```   735   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
```
```   736   by (drule tendsto_norm, simp)
```
```   737
```
```   738 lemma tendsto_norm_zero_cancel:
```
```   739   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
```
```   740   unfolding tendsto_iff dist_norm by simp
```
```   741
```
```   742 lemma tendsto_norm_zero_iff:
```
```   743   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
```
```   744   unfolding tendsto_iff dist_norm by simp
```
```   745
```
```   746 lemma tendsto_rabs [tendsto_intros]:
```
```   747   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
```
```   748   by (fold real_norm_def, rule tendsto_norm)
```
```   749
```
```   750 lemma tendsto_rabs_zero:
```
```   751   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
```
```   752   by (fold real_norm_def, rule tendsto_norm_zero)
```
```   753
```
```   754 lemma tendsto_rabs_zero_cancel:
```
```   755   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
```
```   756   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
```
```   757
```
```   758 lemma tendsto_rabs_zero_iff:
```
```   759   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
```
```   760   by (fold real_norm_def, rule tendsto_norm_zero_iff)
```
```   761
```
```   762 subsubsection {* Addition and subtraction *}
```
```   763
```
```   764 lemma tendsto_add [tendsto_intros]:
```
```   765   fixes a b :: "'a::real_normed_vector"
```
```   766   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
```
```   767   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
```
```   768
```
```   769 lemma tendsto_add_zero:
```
```   770   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
```
```   771   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
```
```   772   by (drule (1) tendsto_add, simp)
```
```   773
```
```   774 lemma tendsto_minus [tendsto_intros]:
```
```   775   fixes a :: "'a::real_normed_vector"
```
```   776   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
```
```   777   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
```
```   778
```
```   779 lemma tendsto_minus_cancel:
```
```   780   fixes a :: "'a::real_normed_vector"
```
```   781   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
```
```   782   by (drule tendsto_minus, simp)
```
```   783
```
```   784 lemma tendsto_diff [tendsto_intros]:
```
```   785   fixes a b :: "'a::real_normed_vector"
```
```   786   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
```
```   787   by (simp add: diff_minus tendsto_add tendsto_minus)
```
```   788
```
```   789 lemma tendsto_setsum [tendsto_intros]:
```
```   790   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
```
```   791   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
```
```   792   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
```
```   793 proof (cases "finite S")
```
```   794   assume "finite S" thus ?thesis using assms
```
```   795     by (induct, simp add: tendsto_const, simp add: tendsto_add)
```
```   796 next
```
```   797   assume "\<not> finite S" thus ?thesis
```
```   798     by (simp add: tendsto_const)
```
```   799 qed
```
```   800
```
```   801 lemma real_tendsto_sandwich:
```
```   802   fixes f g h :: "'a \<Rightarrow> real"
```
```   803   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
```
```   804   assumes lim: "(f ---> c) net" "(h ---> c) net"
```
```   805   shows "(g ---> c) net"
```
```   806 proof -
```
```   807   have "((\<lambda>n. g n - f n) ---> 0) net"
```
```   808   proof (rule metric_tendsto_imp_tendsto)
```
```   809     show "eventually (\<lambda>n. dist (g n - f n) 0 \<le> dist (h n - f n) 0) net"
```
```   810       using ev by (rule eventually_elim2) (simp add: dist_real_def)
```
```   811     show "((\<lambda>n. h n - f n) ---> 0) net"
```
```   812       using tendsto_diff[OF lim(2,1)] by simp
```
```   813   qed
```
```   814   from tendsto_add[OF this lim(1)] show ?thesis by simp
```
```   815 qed
```
```   816
```
```   817 subsubsection {* Linear operators and multiplication *}
```
```   818
```
```   819 lemma (in bounded_linear) tendsto:
```
```   820   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
```
```   821   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
```
```   822
```
```   823 lemma (in bounded_linear) tendsto_zero:
```
```   824   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
```
```   825   by (drule tendsto, simp only: zero)
```
```   826
```
```   827 lemma (in bounded_bilinear) tendsto:
```
```   828   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
```
```   829   by (simp only: tendsto_Zfun_iff prod_diff_prod
```
```   830                  Zfun_add Zfun Zfun_left Zfun_right)
```
```   831
```
```   832 lemma (in bounded_bilinear) tendsto_zero:
```
```   833   assumes f: "(f ---> 0) F"
```
```   834   assumes g: "(g ---> 0) F"
```
```   835   shows "((\<lambda>x. f x ** g x) ---> 0) F"
```
```   836   using tendsto [OF f g] by (simp add: zero_left)
```
```   837
```
```   838 lemma (in bounded_bilinear) tendsto_left_zero:
```
```   839   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
```
```   840   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
```
```   841
```
```   842 lemma (in bounded_bilinear) tendsto_right_zero:
```
```   843   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
```
```   844   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
```
```   845
```
```   846 lemmas tendsto_of_real [tendsto_intros] =
```
```   847   bounded_linear.tendsto [OF bounded_linear_of_real]
```
```   848
```
```   849 lemmas tendsto_scaleR [tendsto_intros] =
```
```   850   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
```
```   851
```
```   852 lemmas tendsto_mult [tendsto_intros] =
```
```   853   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
```
```   854
```
```   855 lemmas tendsto_mult_zero =
```
```   856   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
```
```   857
```
```   858 lemmas tendsto_mult_left_zero =
```
```   859   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
```
```   860
```
```   861 lemmas tendsto_mult_right_zero =
```
```   862   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
```
```   863
```
```   864 lemma tendsto_power [tendsto_intros]:
```
```   865   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
```
```   866   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
```
```   867   by (induct n) (simp_all add: tendsto_const tendsto_mult)
```
```   868
```
```   869 lemma tendsto_setprod [tendsto_intros]:
```
```   870   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
```
```   871   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
```
```   872   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
```
```   873 proof (cases "finite S")
```
```   874   assume "finite S" thus ?thesis using assms
```
```   875     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
```
```   876 next
```
```   877   assume "\<not> finite S" thus ?thesis
```
```   878     by (simp add: tendsto_const)
```
```   879 qed
```
```   880
```
```   881 subsubsection {* Inverse and division *}
```
```   882
```
```   883 lemma (in bounded_bilinear) Zfun_prod_Bfun:
```
```   884   assumes f: "Zfun f F"
```
```   885   assumes g: "Bfun g F"
```
```   886   shows "Zfun (\<lambda>x. f x ** g x) F"
```
```   887 proof -
```
```   888   obtain K where K: "0 \<le> K"
```
```   889     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
```
```   890     using nonneg_bounded by fast
```
```   891   obtain B where B: "0 < B"
```
```   892     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
```
```   893     using g by (rule BfunE)
```
```   894   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
```
```   895   using norm_g proof (rule eventually_elim1)
```
```   896     fix x
```
```   897     assume *: "norm (g x) \<le> B"
```
```   898     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
```
```   899       by (rule norm_le)
```
```   900     also have "\<dots> \<le> norm (f x) * B * K"
```
```   901       by (intro mult_mono' order_refl norm_g norm_ge_zero
```
```   902                 mult_nonneg_nonneg K *)
```
```   903     also have "\<dots> = norm (f x) * (B * K)"
```
```   904       by (rule mult_assoc)
```
```   905     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
```
```   906   qed
```
```   907   with f show ?thesis
```
```   908     by (rule Zfun_imp_Zfun)
```
```   909 qed
```
```   910
```
```   911 lemma (in bounded_bilinear) flip:
```
```   912   "bounded_bilinear (\<lambda>x y. y ** x)"
```
```   913   apply default
```
```   914   apply (rule add_right)
```
```   915   apply (rule add_left)
```
```   916   apply (rule scaleR_right)
```
```   917   apply (rule scaleR_left)
```
```   918   apply (subst mult_commute)
```
```   919   using bounded by fast
```
```   920
```
```   921 lemma (in bounded_bilinear) Bfun_prod_Zfun:
```
```   922   assumes f: "Bfun f F"
```
```   923   assumes g: "Zfun g F"
```
```   924   shows "Zfun (\<lambda>x. f x ** g x) F"
```
```   925   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
```
```   926
```
```   927 lemma Bfun_inverse_lemma:
```
```   928   fixes x :: "'a::real_normed_div_algebra"
```
```   929   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
```
```   930   apply (subst nonzero_norm_inverse, clarsimp)
```
```   931   apply (erule (1) le_imp_inverse_le)
```
```   932   done
```
```   933
```
```   934 lemma Bfun_inverse:
```
```   935   fixes a :: "'a::real_normed_div_algebra"
```
```   936   assumes f: "(f ---> a) F"
```
```   937   assumes a: "a \<noteq> 0"
```
```   938   shows "Bfun (\<lambda>x. inverse (f x)) F"
```
```   939 proof -
```
```   940   from a have "0 < norm a" by simp
```
```   941   hence "\<exists>r>0. r < norm a" by (rule dense)
```
```   942   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
```
```   943   have "eventually (\<lambda>x. dist (f x) a < r) F"
```
```   944     using tendstoD [OF f r1] by fast
```
```   945   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
```
```   946   proof (rule eventually_elim1)
```
```   947     fix x
```
```   948     assume "dist (f x) a < r"
```
```   949     hence 1: "norm (f x - a) < r"
```
```   950       by (simp add: dist_norm)
```
```   951     hence 2: "f x \<noteq> 0" using r2 by auto
```
```   952     hence "norm (inverse (f x)) = inverse (norm (f x))"
```
```   953       by (rule nonzero_norm_inverse)
```
```   954     also have "\<dots> \<le> inverse (norm a - r)"
```
```   955     proof (rule le_imp_inverse_le)
```
```   956       show "0 < norm a - r" using r2 by simp
```
```   957     next
```
```   958       have "norm a - norm (f x) \<le> norm (a - f x)"
```
```   959         by (rule norm_triangle_ineq2)
```
```   960       also have "\<dots> = norm (f x - a)"
```
```   961         by (rule norm_minus_commute)
```
```   962       also have "\<dots> < r" using 1 .
```
```   963       finally show "norm a - r \<le> norm (f x)" by simp
```
```   964     qed
```
```   965     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
```
```   966   qed
```
```   967   thus ?thesis by (rule BfunI)
```
```   968 qed
```
```   969
```
```   970 lemma tendsto_inverse [tendsto_intros]:
```
```   971   fixes a :: "'a::real_normed_div_algebra"
```
```   972   assumes f: "(f ---> a) F"
```
```   973   assumes a: "a \<noteq> 0"
```
```   974   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
```
```   975 proof -
```
```   976   from a have "0 < norm a" by simp
```
```   977   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
```
```   978     by (rule tendstoD)
```
```   979   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
```
```   980     unfolding dist_norm by (auto elim!: eventually_elim1)
```
```   981   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
```
```   982     - (inverse (f x) * (f x - a) * inverse a)) F"
```
```   983     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
```
```   984   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
```
```   985     by (intro Zfun_minus Zfun_mult_left
```
```   986       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
```
```   987       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
```
```   988   ultimately show ?thesis
```
```   989     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
```
```   990 qed
```
```   991
```
```   992 lemma tendsto_divide [tendsto_intros]:
```
```   993   fixes a b :: "'a::real_normed_field"
```
```   994   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
```
```   995     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
```
```   996   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
```
```   997
```
```   998 lemma tendsto_sgn [tendsto_intros]:
```
```   999   fixes l :: "'a::real_normed_vector"
```
```  1000   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
```
```  1001   unfolding sgn_div_norm by (simp add: tendsto_intros)
```
```  1002
```
```  1003 end
```