src/HOL/Product_Type.thy
author nipkow
Mon Jan 30 21:49:41 2012 +0100 (2012-01-30)
changeset 46372 6fa9cdb8b850
parent 46128 53e7cc599f58
child 46556 2848e36e0348
permissions -rw-r--r--
added "'a rel"
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13 begin
    14 
    15 subsection {* @{typ bool} is a datatype *}
    16 
    17 rep_datatype True False by (auto intro: bool_induct)
    18 
    19 declare case_split [cases type: bool]
    20   -- "prefer plain propositional version"
    21 
    22 lemma
    23   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    24     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    25     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    26     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    27     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    28   by (simp_all add: equal)
    29 
    30 lemma If_case_cert:
    31   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    32   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    33   using assms by simp_all
    34 
    35 setup {*
    36   Code.add_case @{thm If_case_cert}
    37 *}
    38 
    39 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    40   (Haskell infix 4 "==")
    41 
    42 code_instance bool :: equal
    43   (Haskell -)
    44 
    45 
    46 subsection {* The @{text unit} type *}
    47 
    48 typedef (open) unit = "{True}"
    49   by auto
    50 
    51 definition Unity :: unit  ("'(')")
    52   where "() = Abs_unit True"
    53 
    54 lemma unit_eq [no_atp]: "u = ()"
    55   by (induct u) (simp add: Unity_def)
    56 
    57 text {*
    58   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    59   this rule directly --- it loops!
    60 *}
    61 
    62 simproc_setup unit_eq ("x::unit") = {*
    63   fn _ => fn _ => fn ct =>
    64     if HOLogic.is_unit (term_of ct) then NONE
    65     else SOME (mk_meta_eq @{thm unit_eq})
    66 *}
    67 
    68 rep_datatype "()" by simp
    69 
    70 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    71   by simp
    72 
    73 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    74   by (rule triv_forall_equality)
    75 
    76 text {*
    77   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    78   [source] "%u::unit. f u"}, replacing it by @{term [source]
    79   f} rather than by @{term [source] "%u. f ()"}.
    80 *}
    81 
    82 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    83   by (rule ext) simp
    84 
    85 lemma UNIV_unit [no_atp]:
    86   "UNIV = {()}" by auto
    87 
    88 instantiation unit :: default
    89 begin
    90 
    91 definition "default = ()"
    92 
    93 instance ..
    94 
    95 end
    96 
    97 lemma [code]:
    98   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    99 
   100 code_type unit
   101   (SML "unit")
   102   (OCaml "unit")
   103   (Haskell "()")
   104   (Scala "Unit")
   105 
   106 code_const Unity
   107   (SML "()")
   108   (OCaml "()")
   109   (Haskell "()")
   110   (Scala "()")
   111 
   112 code_instance unit :: equal
   113   (Haskell -)
   114 
   115 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   116   (Haskell infix 4 "==")
   117 
   118 code_reserved SML
   119   unit
   120 
   121 code_reserved OCaml
   122   unit
   123 
   124 code_reserved Scala
   125   Unit
   126 
   127 
   128 subsection {* The product type *}
   129 
   130 subsubsection {* Type definition *}
   131 
   132 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   133   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   134 
   135 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   136 
   137 typedef (open) ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   138   unfolding prod_def by auto
   139 
   140 type_notation (xsymbols)
   141   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   142 type_notation (HTML output)
   143   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   144 
   145 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   146   "Pair a b = Abs_prod (Pair_Rep a b)"
   147 
   148 rep_datatype Pair proof -
   149   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   150   assume "\<And>a b. P (Pair a b)"
   151   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   152 next
   153   fix a c :: 'a and b d :: 'b
   154   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   155     by (auto simp add: Pair_Rep_def fun_eq_iff)
   156   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   157     by (auto simp add: prod_def)
   158   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   159     by (simp add: Pair_def Abs_prod_inject)
   160 qed
   161 
   162 declare prod.simps(2) [nitpick_simp del]
   163 
   164 declare prod.weak_case_cong [cong del]
   165 
   166 
   167 subsubsection {* Tuple syntax *}
   168 
   169 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   170   "split \<equiv> prod_case"
   171 
   172 text {*
   173   Patterns -- extends pre-defined type @{typ pttrn} used in
   174   abstractions.
   175 *}
   176 
   177 nonterminal tuple_args and patterns
   178 
   179 syntax
   180   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   181   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   182   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   183   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   184   ""            :: "pttrn => patterns"                  ("_")
   185   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   186 
   187 translations
   188   "(x, y)" == "CONST Pair x y"
   189   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   190   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   191   "%(x, y). b" == "CONST prod_case (%x y. b)"
   192   "_abs (CONST Pair x y) t" => "%(x, y). t"
   193   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   194      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   195 
   196 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   197   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   198 print_translation {*
   199 let
   200   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   201         (* split (%x y. t) => %(x,y) t *)
   202         let
   203           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   204           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   205         in
   206           Syntax.const @{syntax_const "_abs"} $
   207             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   208         end
   209     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   210         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   211         let
   212           val Const (@{syntax_const "_abs"}, _) $
   213             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   214           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   215         in
   216           Syntax.const @{syntax_const "_abs"} $
   217             (Syntax.const @{syntax_const "_pattern"} $ x' $
   218               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   219         end
   220     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   221         (* split (split (%x y z. t)) => %((x, y), z). t *)
   222         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   223     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   224         (* split (%pttrn z. t) => %(pttrn,z). t *)
   225         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   226           Syntax.const @{syntax_const "_abs"} $
   227             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   228         end
   229     | split_tr' _ = raise Match;
   230 in [(@{const_syntax prod_case}, split_tr')] end
   231 *}
   232 
   233 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   234 typed_print_translation {*
   235 let
   236   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   237     | split_guess_names_tr' T [Abs (x, xT, t)] =
   238         (case (head_of t) of
   239           Const (@{const_syntax prod_case}, _) => raise Match
   240         | _ =>
   241           let 
   242             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   243             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   244             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   245           in
   246             Syntax.const @{syntax_const "_abs"} $
   247               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   248           end)
   249     | split_guess_names_tr' T [t] =
   250         (case head_of t of
   251           Const (@{const_syntax prod_case}, _) => raise Match
   252         | _ =>
   253           let
   254             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   255             val (y, t') =
   256               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   257             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   258           in
   259             Syntax.const @{syntax_const "_abs"} $
   260               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   261           end)
   262     | split_guess_names_tr' _ _ = raise Match;
   263 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   264 *}
   265 
   266 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   267    where Q is some bounded quantifier or set operator.
   268    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   269    whereas we want "Q (x,y):A. P x y".
   270    Otherwise prevent eta-contraction.
   271 *)
   272 print_translation {*
   273 let
   274   fun contract Q f ts =
   275     case ts of
   276       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   277       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   278     | _ => f ts;
   279   fun contract2 (Q,f) = (Q, contract Q f);
   280   val pairs =
   281     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   282      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   283      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   284      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   285 in map contract2 pairs end
   286 *}
   287 
   288 subsubsection {* Code generator setup *}
   289 
   290 code_type prod
   291   (SML infix 2 "*")
   292   (OCaml infix 2 "*")
   293   (Haskell "!((_),/ (_))")
   294   (Scala "((_),/ (_))")
   295 
   296 code_const Pair
   297   (SML "!((_),/ (_))")
   298   (OCaml "!((_),/ (_))")
   299   (Haskell "!((_),/ (_))")
   300   (Scala "!((_),/ (_))")
   301 
   302 code_instance prod :: equal
   303   (Haskell -)
   304 
   305 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   306   (Haskell infix 4 "==")
   307 
   308 
   309 subsubsection {* Fundamental operations and properties *}
   310 
   311 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   312   by (cases p) simp
   313 
   314 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   315   "fst p = (case p of (a, b) \<Rightarrow> a)"
   316 
   317 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   318   "snd p = (case p of (a, b) \<Rightarrow> b)"
   319 
   320 lemma fst_conv [simp, code]: "fst (a, b) = a"
   321   unfolding fst_def by simp
   322 
   323 lemma snd_conv [simp, code]: "snd (a, b) = b"
   324   unfolding snd_def by simp
   325 
   326 code_const fst and snd
   327   (Haskell "fst" and "snd")
   328 
   329 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   330   by (simp add: fun_eq_iff split: prod.split)
   331 
   332 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   333   by simp
   334 
   335 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   336   by simp
   337 
   338 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   339   by (cases p) simp
   340 
   341 lemmas surjective_pairing = pair_collapse [symmetric]
   342 
   343 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   344   by (cases s, cases t) simp
   345 
   346 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   347   by (simp add: prod_eq_iff)
   348 
   349 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   350   by (fact prod.cases)
   351 
   352 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   353   by (rule split_conv [THEN iffD2])
   354 
   355 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   356   by (rule split_conv [THEN iffD1])
   357 
   358 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   359   by (simp add: fun_eq_iff split: prod.split)
   360 
   361 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   362   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   363   by (simp add: fun_eq_iff split: prod.split)
   364 
   365 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   366   by (cases x) simp
   367 
   368 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   369   by (cases p) simp
   370 
   371 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   372   by (simp add: prod_case_unfold)
   373 
   374 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   375   -- {* Prevents simplification of @{term c}: much faster *}
   376   by (fact prod.weak_case_cong)
   377 
   378 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   379   by (simp add: split_eta)
   380 
   381 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   382 proof
   383   fix a b
   384   assume "!!x. PROP P x"
   385   then show "PROP P (a, b)" .
   386 next
   387   fix x
   388   assume "!!a b. PROP P (a, b)"
   389   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   390 qed
   391 
   392 text {*
   393   The rule @{thm [source] split_paired_all} does not work with the
   394   Simplifier because it also affects premises in congrence rules,
   395   where this can lead to premises of the form @{text "!!a b. ... =
   396   ?P(a, b)"} which cannot be solved by reflexivity.
   397 *}
   398 
   399 lemmas split_tupled_all = split_paired_all unit_all_eq2
   400 
   401 ML {*
   402   (* replace parameters of product type by individual component parameters *)
   403   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   404   local (* filtering with exists_paired_all is an essential optimization *)
   405     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   406           can HOLogic.dest_prodT T orelse exists_paired_all t
   407       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   408       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   409       | exists_paired_all _ = false;
   410     val ss = HOL_basic_ss
   411       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   412       addsimprocs [@{simproc unit_eq}];
   413   in
   414     val split_all_tac = SUBGOAL (fn (t, i) =>
   415       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   416     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   417       if exists_paired_all t then full_simp_tac ss i else no_tac);
   418     fun split_all th =
   419    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   420   end;
   421 *}
   422 
   423 declaration {* fn _ =>
   424   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   425 *}
   426 
   427 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   428   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   429   by fast
   430 
   431 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   432   by fast
   433 
   434 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   435   -- {* Can't be added to simpset: loops! *}
   436   by (simp add: split_eta)
   437 
   438 text {*
   439   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   440   @{thm [source] split_eta} as a rewrite rule is not general enough,
   441   and using @{thm [source] cond_split_eta} directly would render some
   442   existing proofs very inefficient; similarly for @{text
   443   split_beta}.
   444 *}
   445 
   446 ML {*
   447 local
   448   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   449   fun Pair_pat k 0 (Bound m) = (m = k)
   450     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   451         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   452     | Pair_pat _ _ _ = false;
   453   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   454     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   455     | no_args k i (Bound m) = m < k orelse m > k + i
   456     | no_args _ _ _ = true;
   457   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   458     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   459     | split_pat tp i _ = NONE;
   460   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   461         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   462         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   463 
   464   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   465     | beta_term_pat k i (t $ u) =
   466         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   467     | beta_term_pat k i t = no_args k i t;
   468   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   469     | eta_term_pat _ _ _ = false;
   470   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   471     | subst arg k i (t $ u) =
   472         if Pair_pat k i (t $ u) then incr_boundvars k arg
   473         else (subst arg k i t $ subst arg k i u)
   474     | subst arg k i t = t;
   475 in
   476   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   477         (case split_pat beta_term_pat 1 t of
   478           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   479         | NONE => NONE)
   480     | beta_proc _ _ = NONE;
   481   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   482         (case split_pat eta_term_pat 1 t of
   483           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   484         | NONE => NONE)
   485     | eta_proc _ _ = NONE;
   486 end;
   487 *}
   488 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   489 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   490 
   491 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   492   by (subst surjective_pairing, rule split_conv)
   493 
   494 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   495   -- {* For use with @{text split} and the Simplifier. *}
   496   by (insert surj_pair [of p], clarify, simp)
   497 
   498 text {*
   499   @{thm [source] split_split} could be declared as @{text "[split]"}
   500   done after the Splitter has been speeded up significantly;
   501   precompute the constants involved and don't do anything unless the
   502   current goal contains one of those constants.
   503 *}
   504 
   505 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   506 by (subst split_split, simp)
   507 
   508 text {*
   509   \medskip @{term split} used as a logical connective or set former.
   510 
   511   \medskip These rules are for use with @{text blast}; could instead
   512   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   513 
   514 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   515   apply (simp only: split_tupled_all)
   516   apply (simp (no_asm_simp))
   517   done
   518 
   519 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   520   apply (simp only: split_tupled_all)
   521   apply (simp (no_asm_simp))
   522   done
   523 
   524 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   525   by (induct p) auto
   526 
   527 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   528   by (induct p) auto
   529 
   530 lemma splitE2:
   531   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   532 proof -
   533   assume q: "Q (split P z)"
   534   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   535   show R
   536     apply (rule r surjective_pairing)+
   537     apply (rule split_beta [THEN subst], rule q)
   538     done
   539 qed
   540 
   541 lemma splitD': "split R (a,b) c ==> R a b c"
   542   by simp
   543 
   544 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   545   by simp
   546 
   547 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   548 by (simp only: split_tupled_all, simp)
   549 
   550 lemma mem_splitE:
   551   assumes major: "z \<in> split c p"
   552     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   553   shows Q
   554   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   555 
   556 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   557 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   558 
   559 ML {*
   560 local (* filtering with exists_p_split is an essential optimization *)
   561   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   562     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   563     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   564     | exists_p_split _ = false;
   565   val ss = HOL_basic_ss addsimps @{thms split_conv};
   566 in
   567 val split_conv_tac = SUBGOAL (fn (t, i) =>
   568     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   569 end;
   570 *}
   571 
   572 (* This prevents applications of splitE for already splitted arguments leading
   573    to quite time-consuming computations (in particular for nested tuples) *)
   574 declaration {* fn _ =>
   575   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   576 *}
   577 
   578 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   579   by (rule ext) fast
   580 
   581 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   582   by (rule ext) fast
   583 
   584 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   585   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   586   by (rule ext) blast
   587 
   588 (* Do NOT make this a simp rule as it
   589    a) only helps in special situations
   590    b) can lead to nontermination in the presence of split_def
   591 *)
   592 lemma split_comp_eq: 
   593   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   594   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   595   by (rule ext) auto
   596 
   597 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   598   apply (rule_tac x = "(a, b)" in image_eqI)
   599    apply auto
   600   done
   601 
   602 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   603   by blast
   604 
   605 (*
   606 the following  would be slightly more general,
   607 but cannot be used as rewrite rule:
   608 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   609 ### ?y = .x
   610 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   611 by (rtac some_equality 1)
   612 by ( Simp_tac 1)
   613 by (split_all_tac 1)
   614 by (Asm_full_simp_tac 1)
   615 qed "The_split_eq";
   616 *)
   617 
   618 text {*
   619   Setup of internal @{text split_rule}.
   620 *}
   621 
   622 lemmas prod_caseI = prod.cases [THEN iffD2]
   623 
   624 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   625   by (fact splitI2)
   626 
   627 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   628   by (fact splitI2')
   629 
   630 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   631   by (fact splitE)
   632 
   633 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   634   by (fact splitE')
   635 
   636 declare prod_caseI [intro!]
   637 
   638 lemma prod_case_beta:
   639   "prod_case f p = f (fst p) (snd p)"
   640   by (fact split_beta)
   641 
   642 lemma prod_cases3 [cases type]:
   643   obtains (fields) a b c where "y = (a, b, c)"
   644   by (cases y, case_tac b) blast
   645 
   646 lemma prod_induct3 [case_names fields, induct type]:
   647     "(!!a b c. P (a, b, c)) ==> P x"
   648   by (cases x) blast
   649 
   650 lemma prod_cases4 [cases type]:
   651   obtains (fields) a b c d where "y = (a, b, c, d)"
   652   by (cases y, case_tac c) blast
   653 
   654 lemma prod_induct4 [case_names fields, induct type]:
   655     "(!!a b c d. P (a, b, c, d)) ==> P x"
   656   by (cases x) blast
   657 
   658 lemma prod_cases5 [cases type]:
   659   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   660   by (cases y, case_tac d) blast
   661 
   662 lemma prod_induct5 [case_names fields, induct type]:
   663     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   664   by (cases x) blast
   665 
   666 lemma prod_cases6 [cases type]:
   667   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   668   by (cases y, case_tac e) blast
   669 
   670 lemma prod_induct6 [case_names fields, induct type]:
   671     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   672   by (cases x) blast
   673 
   674 lemma prod_cases7 [cases type]:
   675   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   676   by (cases y, case_tac f) blast
   677 
   678 lemma prod_induct7 [case_names fields, induct type]:
   679     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   680   by (cases x) blast
   681 
   682 lemma split_def:
   683   "split = (\<lambda>c p. c (fst p) (snd p))"
   684   by (fact prod_case_unfold)
   685 
   686 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   687   "internal_split == split"
   688 
   689 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   690   by (simp only: internal_split_def split_conv)
   691 
   692 use "Tools/split_rule.ML"
   693 setup Split_Rule.setup
   694 
   695 hide_const internal_split
   696 
   697 
   698 subsubsection {* Derived operations *}
   699 
   700 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   701   "curry = (\<lambda>c x y. c (x, y))"
   702 
   703 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   704   by (simp add: curry_def)
   705 
   706 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   707   by (simp add: curry_def)
   708 
   709 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   710   by (simp add: curry_def)
   711 
   712 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   713   by (simp add: curry_def)
   714 
   715 lemma curry_split [simp]: "curry (split f) = f"
   716   by (simp add: curry_def split_def)
   717 
   718 lemma split_curry [simp]: "split (curry f) = f"
   719   by (simp add: curry_def split_def)
   720 
   721 text {*
   722   The composition-uncurry combinator.
   723 *}
   724 
   725 notation fcomp (infixl "\<circ>>" 60)
   726 
   727 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   728   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   729 
   730 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   731   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   732 
   733 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   734   by (simp add: scomp_unfold prod_case_unfold)
   735 
   736 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   737   by (simp add: fun_eq_iff)
   738 
   739 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   740   by (simp add: fun_eq_iff)
   741 
   742 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   743   by (simp add: fun_eq_iff scomp_unfold)
   744 
   745 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   746   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   747 
   748 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   749   by (simp add: fun_eq_iff scomp_unfold)
   750 
   751 code_const scomp
   752   (Eval infixl 3 "#->")
   753 
   754 no_notation fcomp (infixl "\<circ>>" 60)
   755 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   756 
   757 text {*
   758   @{term map_pair} --- action of the product functor upon
   759   functions.
   760 *}
   761 
   762 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   763   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   764 
   765 lemma map_pair_simp [simp, code]:
   766   "map_pair f g (a, b) = (f a, g b)"
   767   by (simp add: map_pair_def)
   768 
   769 enriched_type map_pair: map_pair
   770   by (auto simp add: split_paired_all)
   771 
   772 lemma fst_map_pair [simp]:
   773   "fst (map_pair f g x) = f (fst x)"
   774   by (cases x) simp_all
   775 
   776 lemma snd_prod_fun [simp]:
   777   "snd (map_pair f g x) = g (snd x)"
   778   by (cases x) simp_all
   779 
   780 lemma fst_comp_map_pair [simp]:
   781   "fst \<circ> map_pair f g = f \<circ> fst"
   782   by (rule ext) simp_all
   783 
   784 lemma snd_comp_map_pair [simp]:
   785   "snd \<circ> map_pair f g = g \<circ> snd"
   786   by (rule ext) simp_all
   787 
   788 lemma map_pair_compose:
   789   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   790   by (rule ext) (simp add: map_pair.compositionality comp_def)
   791 
   792 lemma map_pair_ident [simp]:
   793   "map_pair (%x. x) (%y. y) = (%z. z)"
   794   by (rule ext) (simp add: map_pair.identity)
   795 
   796 lemma map_pair_imageI [intro]:
   797   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   798   by (rule image_eqI) simp_all
   799 
   800 lemma prod_fun_imageE [elim!]:
   801   assumes major: "c \<in> map_pair f g ` R"
   802     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   803   shows P
   804   apply (rule major [THEN imageE])
   805   apply (case_tac x)
   806   apply (rule cases)
   807   apply simp_all
   808   done
   809 
   810 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   811   "apfst f = map_pair f id"
   812 
   813 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   814   "apsnd f = map_pair id f"
   815 
   816 lemma apfst_conv [simp, code]:
   817   "apfst f (x, y) = (f x, y)" 
   818   by (simp add: apfst_def)
   819 
   820 lemma apsnd_conv [simp, code]:
   821   "apsnd f (x, y) = (x, f y)" 
   822   by (simp add: apsnd_def)
   823 
   824 lemma fst_apfst [simp]:
   825   "fst (apfst f x) = f (fst x)"
   826   by (cases x) simp
   827 
   828 lemma fst_apsnd [simp]:
   829   "fst (apsnd f x) = fst x"
   830   by (cases x) simp
   831 
   832 lemma snd_apfst [simp]:
   833   "snd (apfst f x) = snd x"
   834   by (cases x) simp
   835 
   836 lemma snd_apsnd [simp]:
   837   "snd (apsnd f x) = f (snd x)"
   838   by (cases x) simp
   839 
   840 lemma apfst_compose:
   841   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   842   by (cases x) simp
   843 
   844 lemma apsnd_compose:
   845   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   846   by (cases x) simp
   847 
   848 lemma apfst_apsnd [simp]:
   849   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   850   by (cases x) simp
   851 
   852 lemma apsnd_apfst [simp]:
   853   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   854   by (cases x) simp
   855 
   856 lemma apfst_id [simp] :
   857   "apfst id = id"
   858   by (simp add: fun_eq_iff)
   859 
   860 lemma apsnd_id [simp] :
   861   "apsnd id = id"
   862   by (simp add: fun_eq_iff)
   863 
   864 lemma apfst_eq_conv [simp]:
   865   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   866   by (cases x) simp
   867 
   868 lemma apsnd_eq_conv [simp]:
   869   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   870   by (cases x) simp
   871 
   872 lemma apsnd_apfst_commute:
   873   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   874   by simp
   875 
   876 text {*
   877   Disjoint union of a family of sets -- Sigma.
   878 *}
   879 
   880 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
   881   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   882 
   883 abbreviation
   884   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
   885     (infixr "<*>" 80) where
   886   "A <*> B == Sigma A (%_. B)"
   887 
   888 notation (xsymbols)
   889   Times  (infixr "\<times>" 80)
   890 
   891 notation (HTML output)
   892   Times  (infixr "\<times>" 80)
   893 
   894 hide_const (open) Times
   895 
   896 syntax
   897   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   898 translations
   899   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   900 
   901 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   902   by (unfold Sigma_def) blast
   903 
   904 lemma SigmaE [elim!]:
   905     "[| c: Sigma A B;
   906         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   907      |] ==> P"
   908   -- {* The general elimination rule. *}
   909   by (unfold Sigma_def) blast
   910 
   911 text {*
   912   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   913   eigenvariables.
   914 *}
   915 
   916 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   917   by blast
   918 
   919 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   920   by blast
   921 
   922 lemma SigmaE2:
   923     "[| (a, b) : Sigma A B;
   924         [| a:A;  b:B(a) |] ==> P
   925      |] ==> P"
   926   by blast
   927 
   928 lemma Sigma_cong:
   929      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   930       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   931   by auto
   932 
   933 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   934   by blast
   935 
   936 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   937   by blast
   938 
   939 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   940   by blast
   941 
   942 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   943   by auto
   944 
   945 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   946   by auto
   947 
   948 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   949   by auto
   950 
   951 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   952   by blast
   953 
   954 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   955   by blast
   956 
   957 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   958   by (blast elim: equalityE)
   959 
   960 lemma SetCompr_Sigma_eq:
   961     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   962   by blast
   963 
   964 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   965   by blast
   966 
   967 lemma UN_Times_distrib:
   968   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   969   -- {* Suggested by Pierre Chartier *}
   970   by blast
   971 
   972 lemma split_paired_Ball_Sigma [simp,no_atp]:
   973     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   974   by blast
   975 
   976 lemma split_paired_Bex_Sigma [simp,no_atp]:
   977     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   978   by blast
   979 
   980 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   981   by blast
   982 
   983 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   984   by blast
   985 
   986 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   987   by blast
   988 
   989 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   990   by blast
   991 
   992 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   993   by blast
   994 
   995 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   996   by blast
   997 
   998 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   999   by blast
  1000 
  1001 text {*
  1002   Non-dependent versions are needed to avoid the need for higher-order
  1003   matching, especially when the rules are re-oriented.
  1004 *}
  1005 
  1006 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1007 by blast
  1008 
  1009 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1010 by blast
  1011 
  1012 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1013 by blast
  1014 
  1015 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1016   by auto
  1017 
  1018 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1019   by force
  1020 
  1021 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1022   by force
  1023 
  1024 lemma insert_times_insert[simp]:
  1025   "insert a A \<times> insert b B =
  1026    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1027 by blast
  1028 
  1029 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1030   by (auto, case_tac "f x", auto)
  1031 
  1032 lemma swap_inj_on:
  1033   "inj_on (\<lambda>(i, j). (j, i)) A"
  1034   by (auto intro!: inj_onI)
  1035 
  1036 lemma swap_product:
  1037   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1038   by (simp add: split_def image_def) blast
  1039 
  1040 lemma image_split_eq_Sigma:
  1041   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1042 proof (safe intro!: imageI)
  1043   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1044   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1045     using * eq[symmetric] by auto
  1046 qed simp_all
  1047 
  1048 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1049   [code_abbrev]: "product A B = A \<times> B"
  1050 
  1051 hide_const (open) product
  1052 
  1053 lemma member_product:
  1054   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1055   by (simp add: product_def)
  1056 
  1057 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1058 
  1059 lemma map_pair_inj_on:
  1060   assumes "inj_on f A" and "inj_on g B"
  1061   shows "inj_on (map_pair f g) (A \<times> B)"
  1062 proof (rule inj_onI)
  1063   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1064   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1065   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1066   assume "map_pair f g x = map_pair f g y"
  1067   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1068   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1069   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1070   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1071   moreover from `map_pair f g x = map_pair f g y`
  1072   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1073   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1074   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1075   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1076   ultimately show "x = y" by(rule prod_eqI)
  1077 qed
  1078 
  1079 lemma map_pair_surj:
  1080   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1081   assumes "surj f" and "surj g"
  1082   shows "surj (map_pair f g)"
  1083 unfolding surj_def
  1084 proof
  1085   fix y :: "'b \<times> 'd"
  1086   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1087   moreover
  1088   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1089   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1090   thus "\<exists>x. y = map_pair f g x" by auto
  1091 qed
  1092 
  1093 lemma map_pair_surj_on:
  1094   assumes "f ` A = A'" and "g ` B = B'"
  1095   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1096 unfolding image_def
  1097 proof(rule set_eqI,rule iffI)
  1098   fix x :: "'a \<times> 'c"
  1099   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1100   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1101   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1102   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1103   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1104   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1105 next
  1106   fix x :: "'a \<times> 'c"
  1107   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1108   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1109   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1110   moreover from `image g B = B'` and `snd x \<in> B'`
  1111   obtain b where "b \<in> B" and "snd x = g b" by auto
  1112   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1113   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1114   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1115   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1116 qed
  1117 
  1118 
  1119 subsection {* Inductively defined sets *}
  1120 
  1121 use "Tools/inductive_set.ML"
  1122 setup Inductive_Set.setup
  1123 
  1124 
  1125 subsection {* Legacy theorem bindings and duplicates *}
  1126 
  1127 lemma PairE:
  1128   obtains x y where "p = (x, y)"
  1129   by (fact prod.exhaust)
  1130 
  1131 lemma Pair_inject:
  1132   assumes "(a, b) = (a', b')"
  1133     and "a = a' ==> b = b' ==> R"
  1134   shows R
  1135   using assms by simp
  1136 
  1137 lemmas Pair_eq = prod.inject
  1138 
  1139 lemmas split = split_conv  -- {* for backwards compatibility *}
  1140 
  1141 lemmas Pair_fst_snd_eq = prod_eq_iff
  1142 
  1143 hide_const (open) prod
  1144 
  1145 end