src/HOL/RealVector.thy
author nipkow
Mon Jan 30 21:49:41 2012 +0100 (2012-01-30)
changeset 46372 6fa9cdb8b850
parent 44937 22c0857b8aab
child 46868 6c250adbe101
permissions -rw-r--r--
added "'a rel"
     1 (*  Title:      HOL/RealVector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Vector Spaces and Algebras over the Reals *}
     6 
     7 theory RealVector
     8 imports RComplete
     9 begin
    10 
    11 subsection {* Locale for additive functions *}
    12 
    13 locale additive =
    14   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    15   assumes add: "f (x + y) = f x + f y"
    16 begin
    17 
    18 lemma zero: "f 0 = 0"
    19 proof -
    20   have "f 0 = f (0 + 0)" by simp
    21   also have "\<dots> = f 0 + f 0" by (rule add)
    22   finally show "f 0 = 0" by simp
    23 qed
    24 
    25 lemma minus: "f (- x) = - f x"
    26 proof -
    27   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    28   also have "\<dots> = - f x + f x" by (simp add: zero)
    29   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    30 qed
    31 
    32 lemma diff: "f (x - y) = f x - f y"
    33 by (simp add: add minus diff_minus)
    34 
    35 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    36 apply (cases "finite A")
    37 apply (induct set: finite)
    38 apply (simp add: zero)
    39 apply (simp add: add)
    40 apply (simp add: zero)
    41 done
    42 
    43 end
    44 
    45 subsection {* Vector spaces *}
    46 
    47 locale vector_space =
    48   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    49   assumes scale_right_distrib [algebra_simps]:
    50     "scale a (x + y) = scale a x + scale a y"
    51   and scale_left_distrib [algebra_simps]:
    52     "scale (a + b) x = scale a x + scale b x"
    53   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    54   and scale_one [simp]: "scale 1 x = x"
    55 begin
    56 
    57 lemma scale_left_commute:
    58   "scale a (scale b x) = scale b (scale a x)"
    59 by (simp add: mult_commute)
    60 
    61 lemma scale_zero_left [simp]: "scale 0 x = 0"
    62   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    63   and scale_left_diff_distrib [algebra_simps]:
    64         "scale (a - b) x = scale a x - scale b x"
    65   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    66 proof -
    67   interpret s: additive "\<lambda>a. scale a x"
    68     proof qed (rule scale_left_distrib)
    69   show "scale 0 x = 0" by (rule s.zero)
    70   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    71   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    72   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    73 qed
    74 
    75 lemma scale_zero_right [simp]: "scale a 0 = 0"
    76   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    77   and scale_right_diff_distrib [algebra_simps]:
    78         "scale a (x - y) = scale a x - scale a y"
    79   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    80 proof -
    81   interpret s: additive "\<lambda>x. scale a x"
    82     proof qed (rule scale_right_distrib)
    83   show "scale a 0 = 0" by (rule s.zero)
    84   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    85   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    86   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    87 qed
    88 
    89 lemma scale_eq_0_iff [simp]:
    90   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    91 proof cases
    92   assume "a = 0" thus ?thesis by simp
    93 next
    94   assume anz [simp]: "a \<noteq> 0"
    95   { assume "scale a x = 0"
    96     hence "scale (inverse a) (scale a x) = 0" by simp
    97     hence "x = 0" by simp }
    98   thus ?thesis by force
    99 qed
   100 
   101 lemma scale_left_imp_eq:
   102   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   103 proof -
   104   assume nonzero: "a \<noteq> 0"
   105   assume "scale a x = scale a y"
   106   hence "scale a (x - y) = 0"
   107      by (simp add: scale_right_diff_distrib)
   108   hence "x - y = 0" by (simp add: nonzero)
   109   thus "x = y" by (simp only: right_minus_eq)
   110 qed
   111 
   112 lemma scale_right_imp_eq:
   113   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   114 proof -
   115   assume nonzero: "x \<noteq> 0"
   116   assume "scale a x = scale b x"
   117   hence "scale (a - b) x = 0"
   118      by (simp add: scale_left_diff_distrib)
   119   hence "a - b = 0" by (simp add: nonzero)
   120   thus "a = b" by (simp only: right_minus_eq)
   121 qed
   122 
   123 lemma scale_cancel_left [simp]:
   124   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   125 by (auto intro: scale_left_imp_eq)
   126 
   127 lemma scale_cancel_right [simp]:
   128   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   129 by (auto intro: scale_right_imp_eq)
   130 
   131 end
   132 
   133 subsection {* Real vector spaces *}
   134 
   135 class scaleR =
   136   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   137 begin
   138 
   139 abbreviation
   140   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   141 where
   142   "x /\<^sub>R r == scaleR (inverse r) x"
   143 
   144 end
   145 
   146 class real_vector = scaleR + ab_group_add +
   147   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   148   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   149   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   150   and scaleR_one: "scaleR 1 x = x"
   151 
   152 interpretation real_vector:
   153   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   154 apply unfold_locales
   155 apply (rule scaleR_add_right)
   156 apply (rule scaleR_add_left)
   157 apply (rule scaleR_scaleR)
   158 apply (rule scaleR_one)
   159 done
   160 
   161 text {* Recover original theorem names *}
   162 
   163 lemmas scaleR_left_commute = real_vector.scale_left_commute
   164 lemmas scaleR_zero_left = real_vector.scale_zero_left
   165 lemmas scaleR_minus_left = real_vector.scale_minus_left
   166 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   167 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   168 lemmas scaleR_zero_right = real_vector.scale_zero_right
   169 lemmas scaleR_minus_right = real_vector.scale_minus_right
   170 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   171 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   172 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   173 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   174 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   175 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   176 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   177 
   178 text {* Legacy names *}
   179 
   180 lemmas scaleR_left_distrib = scaleR_add_left
   181 lemmas scaleR_right_distrib = scaleR_add_right
   182 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   183 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   184 
   185 lemma scaleR_minus1_left [simp]:
   186   fixes x :: "'a::real_vector"
   187   shows "scaleR (-1) x = - x"
   188   using scaleR_minus_left [of 1 x] by simp
   189 
   190 class real_algebra = real_vector + ring +
   191   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   192   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   193 
   194 class real_algebra_1 = real_algebra + ring_1
   195 
   196 class real_div_algebra = real_algebra_1 + division_ring
   197 
   198 class real_field = real_div_algebra + field
   199 
   200 instantiation real :: real_field
   201 begin
   202 
   203 definition
   204   real_scaleR_def [simp]: "scaleR a x = a * x"
   205 
   206 instance proof
   207 qed (simp_all add: algebra_simps)
   208 
   209 end
   210 
   211 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   212 proof qed (rule scaleR_left_distrib)
   213 
   214 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   215 proof qed (rule scaleR_right_distrib)
   216 
   217 lemma nonzero_inverse_scaleR_distrib:
   218   fixes x :: "'a::real_div_algebra" shows
   219   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   220 by (rule inverse_unique, simp)
   221 
   222 lemma inverse_scaleR_distrib:
   223   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   224   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   225 apply (case_tac "a = 0", simp)
   226 apply (case_tac "x = 0", simp)
   227 apply (erule (1) nonzero_inverse_scaleR_distrib)
   228 done
   229 
   230 
   231 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   232 @{term of_real} *}
   233 
   234 definition
   235   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   236   "of_real r = scaleR r 1"
   237 
   238 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   239 by (simp add: of_real_def)
   240 
   241 lemma of_real_0 [simp]: "of_real 0 = 0"
   242 by (simp add: of_real_def)
   243 
   244 lemma of_real_1 [simp]: "of_real 1 = 1"
   245 by (simp add: of_real_def)
   246 
   247 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   248 by (simp add: of_real_def scaleR_left_distrib)
   249 
   250 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   251 by (simp add: of_real_def)
   252 
   253 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   254 by (simp add: of_real_def scaleR_left_diff_distrib)
   255 
   256 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   257 by (simp add: of_real_def mult_commute)
   258 
   259 lemma nonzero_of_real_inverse:
   260   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   261    inverse (of_real x :: 'a::real_div_algebra)"
   262 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   263 
   264 lemma of_real_inverse [simp]:
   265   "of_real (inverse x) =
   266    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   267 by (simp add: of_real_def inverse_scaleR_distrib)
   268 
   269 lemma nonzero_of_real_divide:
   270   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   271    (of_real x / of_real y :: 'a::real_field)"
   272 by (simp add: divide_inverse nonzero_of_real_inverse)
   273 
   274 lemma of_real_divide [simp]:
   275   "of_real (x / y) =
   276    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   277 by (simp add: divide_inverse)
   278 
   279 lemma of_real_power [simp]:
   280   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   281 by (induct n) simp_all
   282 
   283 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   284 by (simp add: of_real_def)
   285 
   286 lemma inj_of_real:
   287   "inj of_real"
   288   by (auto intro: injI)
   289 
   290 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   291 
   292 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   293 proof
   294   fix r
   295   show "of_real r = id r"
   296     by (simp add: of_real_def)
   297 qed
   298 
   299 text{*Collapse nested embeddings*}
   300 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   301 by (induct n) auto
   302 
   303 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   304 by (cases z rule: int_diff_cases, simp)
   305 
   306 lemma of_real_number_of_eq:
   307   "of_real (number_of w) = (number_of w :: 'a::{number_ring,real_algebra_1})"
   308 by (simp add: number_of_eq)
   309 
   310 text{*Every real algebra has characteristic zero*}
   311 
   312 instance real_algebra_1 < ring_char_0
   313 proof
   314   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   315   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   316 qed
   317 
   318 instance real_field < field_char_0 ..
   319 
   320 
   321 subsection {* The Set of Real Numbers *}
   322 
   323 definition Reals :: "'a::real_algebra_1 set" where
   324   "Reals = range of_real"
   325 
   326 notation (xsymbols)
   327   Reals  ("\<real>")
   328 
   329 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   330 by (simp add: Reals_def)
   331 
   332 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   333 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   334 
   335 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   336 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   337 
   338 lemma Reals_number_of [simp]:
   339   "(number_of w::'a::{number_ring,real_algebra_1}) \<in> Reals"
   340 by (subst of_real_number_of_eq [symmetric], rule Reals_of_real)
   341 
   342 lemma Reals_0 [simp]: "0 \<in> Reals"
   343 apply (unfold Reals_def)
   344 apply (rule range_eqI)
   345 apply (rule of_real_0 [symmetric])
   346 done
   347 
   348 lemma Reals_1 [simp]: "1 \<in> Reals"
   349 apply (unfold Reals_def)
   350 apply (rule range_eqI)
   351 apply (rule of_real_1 [symmetric])
   352 done
   353 
   354 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   355 apply (auto simp add: Reals_def)
   356 apply (rule range_eqI)
   357 apply (rule of_real_add [symmetric])
   358 done
   359 
   360 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   361 apply (auto simp add: Reals_def)
   362 apply (rule range_eqI)
   363 apply (rule of_real_minus [symmetric])
   364 done
   365 
   366 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   367 apply (auto simp add: Reals_def)
   368 apply (rule range_eqI)
   369 apply (rule of_real_diff [symmetric])
   370 done
   371 
   372 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   373 apply (auto simp add: Reals_def)
   374 apply (rule range_eqI)
   375 apply (rule of_real_mult [symmetric])
   376 done
   377 
   378 lemma nonzero_Reals_inverse:
   379   fixes a :: "'a::real_div_algebra"
   380   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   381 apply (auto simp add: Reals_def)
   382 apply (rule range_eqI)
   383 apply (erule nonzero_of_real_inverse [symmetric])
   384 done
   385 
   386 lemma Reals_inverse [simp]:
   387   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   388   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   389 apply (auto simp add: Reals_def)
   390 apply (rule range_eqI)
   391 apply (rule of_real_inverse [symmetric])
   392 done
   393 
   394 lemma nonzero_Reals_divide:
   395   fixes a b :: "'a::real_field"
   396   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   397 apply (auto simp add: Reals_def)
   398 apply (rule range_eqI)
   399 apply (erule nonzero_of_real_divide [symmetric])
   400 done
   401 
   402 lemma Reals_divide [simp]:
   403   fixes a b :: "'a::{real_field, field_inverse_zero}"
   404   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   405 apply (auto simp add: Reals_def)
   406 apply (rule range_eqI)
   407 apply (rule of_real_divide [symmetric])
   408 done
   409 
   410 lemma Reals_power [simp]:
   411   fixes a :: "'a::{real_algebra_1}"
   412   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   413 apply (auto simp add: Reals_def)
   414 apply (rule range_eqI)
   415 apply (rule of_real_power [symmetric])
   416 done
   417 
   418 lemma Reals_cases [cases set: Reals]:
   419   assumes "q \<in> \<real>"
   420   obtains (of_real) r where "q = of_real r"
   421   unfolding Reals_def
   422 proof -
   423   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   424   then obtain r where "q = of_real r" ..
   425   then show thesis ..
   426 qed
   427 
   428 lemma Reals_induct [case_names of_real, induct set: Reals]:
   429   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   430   by (rule Reals_cases) auto
   431 
   432 
   433 subsection {* Topological spaces *}
   434 
   435 class "open" =
   436   fixes "open" :: "'a set \<Rightarrow> bool"
   437 
   438 class topological_space = "open" +
   439   assumes open_UNIV [simp, intro]: "open UNIV"
   440   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
   441   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
   442 begin
   443 
   444 definition
   445   closed :: "'a set \<Rightarrow> bool" where
   446   "closed S \<longleftrightarrow> open (- S)"
   447 
   448 lemma open_empty [intro, simp]: "open {}"
   449   using open_Union [of "{}"] by simp
   450 
   451 lemma open_Un [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
   452   using open_Union [of "{S, T}"] by simp
   453 
   454 lemma open_UN [intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
   455   unfolding SUP_def by (rule open_Union) auto
   456 
   457 lemma open_Inter [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
   458   by (induct set: finite) auto
   459 
   460 lemma open_INT [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
   461   unfolding INF_def by (rule open_Inter) auto
   462 
   463 lemma closed_empty [intro, simp]:  "closed {}"
   464   unfolding closed_def by simp
   465 
   466 lemma closed_Un [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
   467   unfolding closed_def by auto
   468 
   469 lemma closed_UNIV [intro, simp]: "closed UNIV"
   470   unfolding closed_def by simp
   471 
   472 lemma closed_Int [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
   473   unfolding closed_def by auto
   474 
   475 lemma closed_INT [intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
   476   unfolding closed_def by auto
   477 
   478 lemma closed_Inter [intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
   479   unfolding closed_def uminus_Inf by auto
   480 
   481 lemma closed_Union [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
   482   by (induct set: finite) auto
   483 
   484 lemma closed_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
   485   unfolding SUP_def by (rule closed_Union) auto
   486 
   487 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
   488   unfolding closed_def by simp
   489 
   490 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
   491   unfolding closed_def by simp
   492 
   493 lemma open_Diff [intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
   494   unfolding closed_open Diff_eq by (rule open_Int)
   495 
   496 lemma closed_Diff [intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
   497   unfolding open_closed Diff_eq by (rule closed_Int)
   498 
   499 lemma open_Compl [intro]: "closed S \<Longrightarrow> open (- S)"
   500   unfolding closed_open .
   501 
   502 lemma closed_Compl [intro]: "open S \<Longrightarrow> closed (- S)"
   503   unfolding open_closed .
   504 
   505 end
   506 
   507 
   508 subsection {* Metric spaces *}
   509 
   510 class dist =
   511   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   512 
   513 class open_dist = "open" + dist +
   514   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   515 
   516 class metric_space = open_dist +
   517   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   518   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   519 begin
   520 
   521 lemma dist_self [simp]: "dist x x = 0"
   522 by simp
   523 
   524 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   525 using dist_triangle2 [of x x y] by simp
   526 
   527 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   528 by (simp add: less_le)
   529 
   530 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   531 by (simp add: not_less)
   532 
   533 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   534 by (simp add: le_less)
   535 
   536 lemma dist_commute: "dist x y = dist y x"
   537 proof (rule order_antisym)
   538   show "dist x y \<le> dist y x"
   539     using dist_triangle2 [of x y x] by simp
   540   show "dist y x \<le> dist x y"
   541     using dist_triangle2 [of y x y] by simp
   542 qed
   543 
   544 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   545 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   546 
   547 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   548 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   549 
   550 lemma dist_triangle_alt:
   551   shows "dist y z <= dist x y + dist x z"
   552 by (rule dist_triangle3)
   553 
   554 lemma dist_pos_lt:
   555   shows "x \<noteq> y ==> 0 < dist x y"
   556 by (simp add: zero_less_dist_iff)
   557 
   558 lemma dist_nz:
   559   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   560 by (simp add: zero_less_dist_iff)
   561 
   562 lemma dist_triangle_le:
   563   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   564 by (rule order_trans [OF dist_triangle2])
   565 
   566 lemma dist_triangle_lt:
   567   shows "dist x z + dist y z < e ==> dist x y < e"
   568 by (rule le_less_trans [OF dist_triangle2])
   569 
   570 lemma dist_triangle_half_l:
   571   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   572 by (rule dist_triangle_lt [where z=y], simp)
   573 
   574 lemma dist_triangle_half_r:
   575   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   576 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   577 
   578 subclass topological_space
   579 proof
   580   have "\<exists>e::real. 0 < e"
   581     by (fast intro: zero_less_one)
   582   then show "open UNIV"
   583     unfolding open_dist by simp
   584 next
   585   fix S T assume "open S" "open T"
   586   then show "open (S \<inter> T)"
   587     unfolding open_dist
   588     apply clarify
   589     apply (drule (1) bspec)+
   590     apply (clarify, rename_tac r s)
   591     apply (rule_tac x="min r s" in exI, simp)
   592     done
   593 next
   594   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   595     unfolding open_dist by fast
   596 qed
   597 
   598 lemma (in metric_space) open_ball: "open {y. dist x y < d}"
   599 proof (unfold open_dist, intro ballI)
   600   fix y assume *: "y \<in> {y. dist x y < d}"
   601   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   602     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   603 qed
   604 
   605 end
   606 
   607 
   608 subsection {* Real normed vector spaces *}
   609 
   610 class norm =
   611   fixes norm :: "'a \<Rightarrow> real"
   612 
   613 class sgn_div_norm = scaleR + norm + sgn +
   614   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   615 
   616 class dist_norm = dist + norm + minus +
   617   assumes dist_norm: "dist x y = norm (x - y)"
   618 
   619 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   620   assumes norm_ge_zero [simp]: "0 \<le> norm x"
   621   and norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   622   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   623   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   624 
   625 class real_normed_algebra = real_algebra + real_normed_vector +
   626   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   627 
   628 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   629   assumes norm_one [simp]: "norm 1 = 1"
   630 
   631 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   632   assumes norm_mult: "norm (x * y) = norm x * norm y"
   633 
   634 class real_normed_field = real_field + real_normed_div_algebra
   635 
   636 instance real_normed_div_algebra < real_normed_algebra_1
   637 proof
   638   fix x y :: 'a
   639   show "norm (x * y) \<le> norm x * norm y"
   640     by (simp add: norm_mult)
   641 next
   642   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   643     by (rule norm_mult)
   644   thus "norm (1::'a) = 1" by simp
   645 qed
   646 
   647 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   648 by simp
   649 
   650 lemma zero_less_norm_iff [simp]:
   651   fixes x :: "'a::real_normed_vector"
   652   shows "(0 < norm x) = (x \<noteq> 0)"
   653 by (simp add: order_less_le)
   654 
   655 lemma norm_not_less_zero [simp]:
   656   fixes x :: "'a::real_normed_vector"
   657   shows "\<not> norm x < 0"
   658 by (simp add: linorder_not_less)
   659 
   660 lemma norm_le_zero_iff [simp]:
   661   fixes x :: "'a::real_normed_vector"
   662   shows "(norm x \<le> 0) = (x = 0)"
   663 by (simp add: order_le_less)
   664 
   665 lemma norm_minus_cancel [simp]:
   666   fixes x :: "'a::real_normed_vector"
   667   shows "norm (- x) = norm x"
   668 proof -
   669   have "norm (- x) = norm (scaleR (- 1) x)"
   670     by (simp only: scaleR_minus_left scaleR_one)
   671   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   672     by (rule norm_scaleR)
   673   finally show ?thesis by simp
   674 qed
   675 
   676 lemma norm_minus_commute:
   677   fixes a b :: "'a::real_normed_vector"
   678   shows "norm (a - b) = norm (b - a)"
   679 proof -
   680   have "norm (- (b - a)) = norm (b - a)"
   681     by (rule norm_minus_cancel)
   682   thus ?thesis by simp
   683 qed
   684 
   685 lemma norm_triangle_ineq2:
   686   fixes a b :: "'a::real_normed_vector"
   687   shows "norm a - norm b \<le> norm (a - b)"
   688 proof -
   689   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   690     by (rule norm_triangle_ineq)
   691   thus ?thesis by simp
   692 qed
   693 
   694 lemma norm_triangle_ineq3:
   695   fixes a b :: "'a::real_normed_vector"
   696   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   697 apply (subst abs_le_iff)
   698 apply auto
   699 apply (rule norm_triangle_ineq2)
   700 apply (subst norm_minus_commute)
   701 apply (rule norm_triangle_ineq2)
   702 done
   703 
   704 lemma norm_triangle_ineq4:
   705   fixes a b :: "'a::real_normed_vector"
   706   shows "norm (a - b) \<le> norm a + norm b"
   707 proof -
   708   have "norm (a + - b) \<le> norm a + norm (- b)"
   709     by (rule norm_triangle_ineq)
   710   thus ?thesis
   711     by (simp only: diff_minus norm_minus_cancel)
   712 qed
   713 
   714 lemma norm_diff_ineq:
   715   fixes a b :: "'a::real_normed_vector"
   716   shows "norm a - norm b \<le> norm (a + b)"
   717 proof -
   718   have "norm a - norm (- b) \<le> norm (a - - b)"
   719     by (rule norm_triangle_ineq2)
   720   thus ?thesis by simp
   721 qed
   722 
   723 lemma norm_diff_triangle_ineq:
   724   fixes a b c d :: "'a::real_normed_vector"
   725   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   726 proof -
   727   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   728     by (simp add: diff_minus add_ac)
   729   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   730     by (rule norm_triangle_ineq)
   731   finally show ?thesis .
   732 qed
   733 
   734 lemma abs_norm_cancel [simp]:
   735   fixes a :: "'a::real_normed_vector"
   736   shows "\<bar>norm a\<bar> = norm a"
   737 by (rule abs_of_nonneg [OF norm_ge_zero])
   738 
   739 lemma norm_add_less:
   740   fixes x y :: "'a::real_normed_vector"
   741   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   742 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   743 
   744 lemma norm_mult_less:
   745   fixes x y :: "'a::real_normed_algebra"
   746   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   747 apply (rule order_le_less_trans [OF norm_mult_ineq])
   748 apply (simp add: mult_strict_mono')
   749 done
   750 
   751 lemma norm_of_real [simp]:
   752   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   753 unfolding of_real_def by simp
   754 
   755 lemma norm_number_of [simp]:
   756   "norm (number_of w::'a::{number_ring,real_normed_algebra_1})
   757     = \<bar>number_of w\<bar>"
   758 by (subst of_real_number_of_eq [symmetric], rule norm_of_real)
   759 
   760 lemma norm_of_int [simp]:
   761   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   762 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   763 
   764 lemma norm_of_nat [simp]:
   765   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   766 apply (subst of_real_of_nat_eq [symmetric])
   767 apply (subst norm_of_real, simp)
   768 done
   769 
   770 lemma nonzero_norm_inverse:
   771   fixes a :: "'a::real_normed_div_algebra"
   772   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   773 apply (rule inverse_unique [symmetric])
   774 apply (simp add: norm_mult [symmetric])
   775 done
   776 
   777 lemma norm_inverse:
   778   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   779   shows "norm (inverse a) = inverse (norm a)"
   780 apply (case_tac "a = 0", simp)
   781 apply (erule nonzero_norm_inverse)
   782 done
   783 
   784 lemma nonzero_norm_divide:
   785   fixes a b :: "'a::real_normed_field"
   786   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   787 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   788 
   789 lemma norm_divide:
   790   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   791   shows "norm (a / b) = norm a / norm b"
   792 by (simp add: divide_inverse norm_mult norm_inverse)
   793 
   794 lemma norm_power_ineq:
   795   fixes x :: "'a::{real_normed_algebra_1}"
   796   shows "norm (x ^ n) \<le> norm x ^ n"
   797 proof (induct n)
   798   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   799 next
   800   case (Suc n)
   801   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   802     by (rule norm_mult_ineq)
   803   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   804     using norm_ge_zero by (rule mult_left_mono)
   805   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   806     by simp
   807 qed
   808 
   809 lemma norm_power:
   810   fixes x :: "'a::{real_normed_div_algebra}"
   811   shows "norm (x ^ n) = norm x ^ n"
   812 by (induct n) (simp_all add: norm_mult)
   813 
   814 text {* Every normed vector space is a metric space. *}
   815 
   816 instance real_normed_vector < metric_space
   817 proof
   818   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   819     unfolding dist_norm by simp
   820 next
   821   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
   822     unfolding dist_norm
   823     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
   824 qed
   825 
   826 
   827 subsection {* Class instances for real numbers *}
   828 
   829 instantiation real :: real_normed_field
   830 begin
   831 
   832 definition real_norm_def [simp]:
   833   "norm r = \<bar>r\<bar>"
   834 
   835 definition dist_real_def:
   836   "dist x y = \<bar>x - y\<bar>"
   837 
   838 definition open_real_def:
   839   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   840 
   841 instance
   842 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   843 apply (rule dist_real_def)
   844 apply (rule open_real_def)
   845 apply (simp add: sgn_real_def)
   846 apply (rule abs_ge_zero)
   847 apply (rule abs_eq_0)
   848 apply (rule abs_triangle_ineq)
   849 apply (rule abs_mult)
   850 apply (rule abs_mult)
   851 done
   852 
   853 end
   854 
   855 lemma open_real_lessThan [simp]:
   856   fixes a :: real shows "open {..<a}"
   857 unfolding open_real_def dist_real_def
   858 proof (clarify)
   859   fix x assume "x < a"
   860   hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
   861   thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
   862 qed
   863 
   864 lemma open_real_greaterThan [simp]:
   865   fixes a :: real shows "open {a<..}"
   866 unfolding open_real_def dist_real_def
   867 proof (clarify)
   868   fix x assume "a < x"
   869   hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
   870   thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
   871 qed
   872 
   873 lemma open_real_greaterThanLessThan [simp]:
   874   fixes a b :: real shows "open {a<..<b}"
   875 proof -
   876   have "{a<..<b} = {a<..} \<inter> {..<b}" by auto
   877   thus "open {a<..<b}" by (simp add: open_Int)
   878 qed
   879 
   880 lemma closed_real_atMost [simp]: 
   881   fixes a :: real shows "closed {..a}"
   882 unfolding closed_open by simp
   883 
   884 lemma closed_real_atLeast [simp]:
   885   fixes a :: real shows "closed {a..}"
   886 unfolding closed_open by simp
   887 
   888 lemma closed_real_atLeastAtMost [simp]:
   889   fixes a b :: real shows "closed {a..b}"
   890 proof -
   891   have "{a..b} = {a..} \<inter> {..b}" by auto
   892   thus "closed {a..b}" by (simp add: closed_Int)
   893 qed
   894 
   895 
   896 subsection {* Extra type constraints *}
   897 
   898 text {* Only allow @{term "open"} in class @{text topological_space}. *}
   899 
   900 setup {* Sign.add_const_constraint
   901   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
   902 
   903 text {* Only allow @{term dist} in class @{text metric_space}. *}
   904 
   905 setup {* Sign.add_const_constraint
   906   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
   907 
   908 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
   909 
   910 setup {* Sign.add_const_constraint
   911   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
   912 
   913 
   914 subsection {* Sign function *}
   915 
   916 lemma norm_sgn:
   917   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
   918 by (simp add: sgn_div_norm)
   919 
   920 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
   921 by (simp add: sgn_div_norm)
   922 
   923 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
   924 by (simp add: sgn_div_norm)
   925 
   926 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
   927 by (simp add: sgn_div_norm)
   928 
   929 lemma sgn_scaleR:
   930   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
   931 by (simp add: sgn_div_norm mult_ac)
   932 
   933 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
   934 by (simp add: sgn_div_norm)
   935 
   936 lemma sgn_of_real:
   937   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
   938 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
   939 
   940 lemma sgn_mult:
   941   fixes x y :: "'a::real_normed_div_algebra"
   942   shows "sgn (x * y) = sgn x * sgn y"
   943 by (simp add: sgn_div_norm norm_mult mult_commute)
   944 
   945 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
   946 by (simp add: sgn_div_norm divide_inverse)
   947 
   948 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
   949 unfolding real_sgn_eq by simp
   950 
   951 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
   952 unfolding real_sgn_eq by simp
   953 
   954 
   955 subsection {* Bounded Linear and Bilinear Operators *}
   956 
   957 locale bounded_linear = additive +
   958   constrains f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
   959   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
   960   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
   961 begin
   962 
   963 lemma pos_bounded:
   964   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
   965 proof -
   966   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
   967     using bounded by fast
   968   show ?thesis
   969   proof (intro exI impI conjI allI)
   970     show "0 < max 1 K"
   971       by (rule order_less_le_trans [OF zero_less_one le_maxI1])
   972   next
   973     fix x
   974     have "norm (f x) \<le> norm x * K" using K .
   975     also have "\<dots> \<le> norm x * max 1 K"
   976       by (rule mult_left_mono [OF le_maxI2 norm_ge_zero])
   977     finally show "norm (f x) \<le> norm x * max 1 K" .
   978   qed
   979 qed
   980 
   981 lemma nonneg_bounded:
   982   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
   983 proof -
   984   from pos_bounded
   985   show ?thesis by (auto intro: order_less_imp_le)
   986 qed
   987 
   988 end
   989 
   990 lemma bounded_linear_intro:
   991   assumes "\<And>x y. f (x + y) = f x + f y"
   992   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
   993   assumes "\<And>x. norm (f x) \<le> norm x * K"
   994   shows "bounded_linear f"
   995   by default (fast intro: assms)+
   996 
   997 locale bounded_bilinear =
   998   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
   999                  \<Rightarrow> 'c::real_normed_vector"
  1000     (infixl "**" 70)
  1001   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1002   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1003   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1004   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1005   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1006 begin
  1007 
  1008 lemma pos_bounded:
  1009   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1010 apply (cut_tac bounded, erule exE)
  1011 apply (rule_tac x="max 1 K" in exI, safe)
  1012 apply (rule order_less_le_trans [OF zero_less_one le_maxI1])
  1013 apply (drule spec, drule spec, erule order_trans)
  1014 apply (rule mult_left_mono [OF le_maxI2])
  1015 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1016 done
  1017 
  1018 lemma nonneg_bounded:
  1019   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1020 proof -
  1021   from pos_bounded
  1022   show ?thesis by (auto intro: order_less_imp_le)
  1023 qed
  1024 
  1025 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1026 by (rule additive.intro, rule add_right)
  1027 
  1028 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1029 by (rule additive.intro, rule add_left)
  1030 
  1031 lemma zero_left: "prod 0 b = 0"
  1032 by (rule additive.zero [OF additive_left])
  1033 
  1034 lemma zero_right: "prod a 0 = 0"
  1035 by (rule additive.zero [OF additive_right])
  1036 
  1037 lemma minus_left: "prod (- a) b = - prod a b"
  1038 by (rule additive.minus [OF additive_left])
  1039 
  1040 lemma minus_right: "prod a (- b) = - prod a b"
  1041 by (rule additive.minus [OF additive_right])
  1042 
  1043 lemma diff_left:
  1044   "prod (a - a') b = prod a b - prod a' b"
  1045 by (rule additive.diff [OF additive_left])
  1046 
  1047 lemma diff_right:
  1048   "prod a (b - b') = prod a b - prod a b'"
  1049 by (rule additive.diff [OF additive_right])
  1050 
  1051 lemma bounded_linear_left:
  1052   "bounded_linear (\<lambda>a. a ** b)"
  1053 apply (cut_tac bounded, safe)
  1054 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1055 apply (rule add_left)
  1056 apply (rule scaleR_left)
  1057 apply (simp add: mult_ac)
  1058 done
  1059 
  1060 lemma bounded_linear_right:
  1061   "bounded_linear (\<lambda>b. a ** b)"
  1062 apply (cut_tac bounded, safe)
  1063 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1064 apply (rule add_right)
  1065 apply (rule scaleR_right)
  1066 apply (simp add: mult_ac)
  1067 done
  1068 
  1069 lemma prod_diff_prod:
  1070   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1071 by (simp add: diff_left diff_right)
  1072 
  1073 end
  1074 
  1075 lemma bounded_bilinear_mult:
  1076   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1077 apply (rule bounded_bilinear.intro)
  1078 apply (rule left_distrib)
  1079 apply (rule right_distrib)
  1080 apply (rule mult_scaleR_left)
  1081 apply (rule mult_scaleR_right)
  1082 apply (rule_tac x="1" in exI)
  1083 apply (simp add: norm_mult_ineq)
  1084 done
  1085 
  1086 lemma bounded_linear_mult_left:
  1087   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1088   using bounded_bilinear_mult
  1089   by (rule bounded_bilinear.bounded_linear_left)
  1090 
  1091 lemma bounded_linear_mult_right:
  1092   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1093   using bounded_bilinear_mult
  1094   by (rule bounded_bilinear.bounded_linear_right)
  1095 
  1096 lemma bounded_linear_divide:
  1097   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1098   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1099 
  1100 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1101 apply (rule bounded_bilinear.intro)
  1102 apply (rule scaleR_left_distrib)
  1103 apply (rule scaleR_right_distrib)
  1104 apply simp
  1105 apply (rule scaleR_left_commute)
  1106 apply (rule_tac x="1" in exI, simp)
  1107 done
  1108 
  1109 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1110   using bounded_bilinear_scaleR
  1111   by (rule bounded_bilinear.bounded_linear_left)
  1112 
  1113 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1114   using bounded_bilinear_scaleR
  1115   by (rule bounded_bilinear.bounded_linear_right)
  1116 
  1117 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1118   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1119 
  1120 subsection{* Hausdorff and other separation properties *}
  1121 
  1122 class t0_space = topological_space +
  1123   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
  1124 
  1125 class t1_space = topological_space +
  1126   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
  1127 
  1128 instance t1_space \<subseteq> t0_space
  1129 proof qed (fast dest: t1_space)
  1130 
  1131 lemma separation_t1:
  1132   fixes x y :: "'a::t1_space"
  1133   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
  1134   using t1_space[of x y] by blast
  1135 
  1136 lemma closed_singleton:
  1137   fixes a :: "'a::t1_space"
  1138   shows "closed {a}"
  1139 proof -
  1140   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
  1141   have "open ?T" by (simp add: open_Union)
  1142   also have "?T = - {a}"
  1143     by (simp add: set_eq_iff separation_t1, auto)
  1144   finally show "closed {a}" unfolding closed_def .
  1145 qed
  1146 
  1147 lemma closed_insert [simp]:
  1148   fixes a :: "'a::t1_space"
  1149   assumes "closed S" shows "closed (insert a S)"
  1150 proof -
  1151   from closed_singleton assms
  1152   have "closed ({a} \<union> S)" by (rule closed_Un)
  1153   thus "closed (insert a S)" by simp
  1154 qed
  1155 
  1156 lemma finite_imp_closed:
  1157   fixes S :: "'a::t1_space set"
  1158   shows "finite S \<Longrightarrow> closed S"
  1159 by (induct set: finite, simp_all)
  1160 
  1161 text {* T2 spaces are also known as Hausdorff spaces. *}
  1162 
  1163 class t2_space = topological_space +
  1164   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1165 
  1166 instance t2_space \<subseteq> t1_space
  1167 proof qed (fast dest: hausdorff)
  1168 
  1169 instance metric_space \<subseteq> t2_space
  1170 proof
  1171   fix x y :: "'a::metric_space"
  1172   assume xy: "x \<noteq> y"
  1173   let ?U = "{y'. dist x y' < dist x y / 2}"
  1174   let ?V = "{x'. dist y x' < dist x y / 2}"
  1175   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
  1176                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
  1177   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
  1178     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
  1179     using open_ball[of _ "dist x y / 2"] by auto
  1180   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1181     by blast
  1182 qed
  1183 
  1184 lemma separation_t2:
  1185   fixes x y :: "'a::t2_space"
  1186   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
  1187   using hausdorff[of x y] by blast
  1188 
  1189 lemma separation_t0:
  1190   fixes x y :: "'a::t0_space"
  1191   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
  1192   using t0_space[of x y] by blast
  1193 
  1194 text {* A perfect space is a topological space with no isolated points. *}
  1195 
  1196 class perfect_space = topological_space +
  1197   assumes not_open_singleton: "\<not> open {x}"
  1198 
  1199 instance real_normed_algebra_1 \<subseteq> perfect_space
  1200 proof
  1201   fix x::'a
  1202   show "\<not> open {x}"
  1203     unfolding open_dist dist_norm
  1204     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1205 qed
  1206 
  1207 end