src/HOL/Library/Multiset.thy
 author blanchet Sun Aug 17 22:27:58 2014 +0200 (2014-08-17) changeset 57966 6fab7e95587d parent 57518 2f640245fc6d child 58035 177eeda93a8c permissions -rw-r--r--
use 'image_mset' as BNF map function
1 (*  Title:      HOL/Library/Multiset.thy
2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
3     Author:     Andrei Popescu, TU Muenchen
4 *)
6 header {* (Finite) multisets *}
8 theory Multiset
9 imports Main
10 begin
12 subsection {* The type of multisets *}
14 definition "multiset = {f :: 'a => nat. finite {x. f x > 0}}"
16 typedef 'a multiset = "multiset :: ('a => nat) set"
17   morphisms count Abs_multiset
18   unfolding multiset_def
19 proof
20   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
21 qed
23 setup_lifting type_definition_multiset
25 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
26   "a :# M == 0 < count M a"
28 notation (xsymbols)
29   Melem (infix "\<in>#" 50)
31 lemma multiset_eq_iff:
32   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
33   by (simp only: count_inject [symmetric] fun_eq_iff)
35 lemma multiset_eqI:
36   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
37   using multiset_eq_iff by auto
39 text {*
40  \medskip Preservation of the representing set @{term multiset}.
41 *}
43 lemma const0_in_multiset:
44   "(\<lambda>a. 0) \<in> multiset"
45   by (simp add: multiset_def)
47 lemma only1_in_multiset:
48   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
49   by (simp add: multiset_def)
51 lemma union_preserves_multiset:
52   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
53   by (simp add: multiset_def)
55 lemma diff_preserves_multiset:
56   assumes "M \<in> multiset"
57   shows "(\<lambda>a. M a - N a) \<in> multiset"
58 proof -
59   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
60     by auto
61   with assms show ?thesis
62     by (auto simp add: multiset_def intro: finite_subset)
63 qed
65 lemma filter_preserves_multiset:
66   assumes "M \<in> multiset"
67   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
68 proof -
69   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
70     by auto
71   with assms show ?thesis
72     by (auto simp add: multiset_def intro: finite_subset)
73 qed
75 lemmas in_multiset = const0_in_multiset only1_in_multiset
76   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
79 subsection {* Representing multisets *}
81 text {* Multiset enumeration *}
83 instantiation multiset :: (type) cancel_comm_monoid_add
84 begin
86 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
87 by (rule const0_in_multiset)
89 abbreviation Mempty :: "'a multiset" ("{#}") where
90   "Mempty \<equiv> 0"
92 lift_definition plus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
93 by (rule union_preserves_multiset)
95 instance
96 by default (transfer, simp add: fun_eq_iff)+
98 end
100 lift_definition single :: "'a => 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
101 by (rule only1_in_multiset)
103 syntax
104   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
105 translations
106   "{#x, xs#}" == "{#x#} + {#xs#}"
107   "{#x#}" == "CONST single x"
109 lemma count_empty [simp]: "count {#} a = 0"
110   by (simp add: zero_multiset.rep_eq)
112 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
113   by (simp add: single.rep_eq)
116 subsection {* Basic operations *}
118 subsubsection {* Union *}
120 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
121   by (simp add: plus_multiset.rep_eq)
124 subsubsection {* Difference *}
126 instantiation multiset :: (type) comm_monoid_diff
127 begin
129 lift_definition minus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
130 by (rule diff_preserves_multiset)
132 instance
133 by default (transfer, simp add: fun_eq_iff)+
135 end
137 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
138   by (simp add: minus_multiset.rep_eq)
140 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
141   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
143 lemma diff_cancel[simp]: "A - A = {#}"
144   by (fact Groups.diff_cancel)
146 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
147   by (fact add_diff_cancel_right')
149 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
150   by (fact add_diff_cancel_left')
152 lemma diff_right_commute:
153   "(M::'a multiset) - N - Q = M - Q - N"
154   by (fact diff_right_commute)
157   "(M::'a multiset) - (N + Q) = M - N - Q"
158   by (rule sym) (fact diff_diff_add)
160 lemma insert_DiffM:
161   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
162   by (clarsimp simp: multiset_eq_iff)
164 lemma insert_DiffM2 [simp]:
165   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
166   by (clarsimp simp: multiset_eq_iff)
168 lemma diff_union_swap:
169   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
170   by (auto simp add: multiset_eq_iff)
172 lemma diff_union_single_conv:
173   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
174   by (simp add: multiset_eq_iff)
177 subsubsection {* Equality of multisets *}
179 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
180   by (simp add: multiset_eq_iff)
182 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
183   by (auto simp add: multiset_eq_iff)
185 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
186   by (auto simp add: multiset_eq_iff)
188 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
189   by (auto simp add: multiset_eq_iff)
191 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
192   by (auto simp add: multiset_eq_iff)
194 lemma diff_single_trivial:
195   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
196   by (auto simp add: multiset_eq_iff)
198 lemma diff_single_eq_union:
199   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
200   by auto
202 lemma union_single_eq_diff:
203   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
204   by (auto dest: sym)
206 lemma union_single_eq_member:
207   "M + {#x#} = N \<Longrightarrow> x \<in># N"
208   by auto
210 lemma union_is_single:
211   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")
212 proof
213   assume ?rhs then show ?lhs by auto
214 next
215   assume ?lhs then show ?rhs
216     by (simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
217 qed
219 lemma single_is_union:
220   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
221   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
224   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
225 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
226 proof
227   assume ?rhs then show ?lhs
229     (drule sym, simp add: add.assoc [symmetric])
230 next
231   assume ?lhs
232   show ?rhs
233   proof (cases "a = b")
234     case True with `?lhs` show ?thesis by simp
235   next
236     case False
237     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
238     with False have "a \<in># N" by auto
239     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
240     moreover note False
241     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
242   qed
243 qed
245 lemma insert_noteq_member:
246   assumes BC: "B + {#b#} = C + {#c#}"
247    and bnotc: "b \<noteq> c"
248   shows "c \<in># B"
249 proof -
250   have "c \<in># C + {#c#}" by simp
251   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
252   then have "c \<in># B + {#b#}" using BC by simp
253   then show "c \<in># B" using nc by simp
254 qed
257   "(M + {#a#} = N + {#b#}) =
258     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
261 lemma multi_member_split:
262   "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
263   by (rule_tac x = "M - {#x#}" in exI, simp)
266 subsubsection {* Pointwise ordering induced by count *}
268 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
269 begin
271 lift_definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" is "\<lambda> A B. (\<forall>a. A a \<le> B a)" .
273 lemmas mset_le_def = less_eq_multiset_def
275 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
276   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
278 instance
279   by default (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
281 end
283 lemma mset_less_eqI:
284   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
285   by (simp add: mset_le_def)
287 lemma mset_le_exists_conv:
288   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
289 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
290 apply (auto intro: multiset_eq_iff [THEN iffD2])
291 done
293 instance multiset :: (type) ordered_cancel_comm_monoid_diff
294   by default (simp, fact mset_le_exists_conv)
296 lemma mset_le_mono_add_right_cancel [simp]:
297   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
298   by (fact add_le_cancel_right)
300 lemma mset_le_mono_add_left_cancel [simp]:
301   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
302   by (fact add_le_cancel_left)
305   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
306   by (fact add_mono)
308 lemma mset_le_add_left [simp]:
309   "(A::'a multiset) \<le> A + B"
310   unfolding mset_le_def by auto
312 lemma mset_le_add_right [simp]:
313   "B \<le> (A::'a multiset) + B"
314   unfolding mset_le_def by auto
316 lemma mset_le_single:
317   "a :# B \<Longrightarrow> {#a#} \<le> B"
318   by (simp add: mset_le_def)
320 lemma multiset_diff_union_assoc:
321   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
322   by (simp add: multiset_eq_iff mset_le_def)
324 lemma mset_le_multiset_union_diff_commute:
325   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
326 by (simp add: multiset_eq_iff mset_le_def)
328 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
329 by(simp add: mset_le_def)
331 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
332 apply (clarsimp simp: mset_le_def mset_less_def)
333 apply (erule_tac x=x in allE)
334 apply auto
335 done
337 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
338 apply (clarsimp simp: mset_le_def mset_less_def)
339 apply (erule_tac x = x in allE)
340 apply auto
341 done
343 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
344 apply (rule conjI)
345  apply (simp add: mset_lessD)
346 apply (clarsimp simp: mset_le_def mset_less_def)
347 apply safe
348  apply (erule_tac x = a in allE)
349  apply (auto split: split_if_asm)
350 done
352 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
353 apply (rule conjI)
354  apply (simp add: mset_leD)
355 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
356 done
358 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
359   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
361 lemma empty_le[simp]: "{#} \<le> A"
362   unfolding mset_le_exists_conv by auto
364 lemma le_empty[simp]: "(M \<le> {#}) = (M = {#})"
365   unfolding mset_le_exists_conv by auto
367 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
368   by (auto simp: mset_le_def mset_less_def)
370 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
371   by simp
374   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
375   by (fact add_less_imp_less_right)
377 lemma mset_less_empty_nonempty:
378   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
379   by (auto simp: mset_le_def mset_less_def)
381 lemma mset_less_diff_self:
382   "c \<in># B \<Longrightarrow> B - {#c#} < B"
383   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
386 subsubsection {* Intersection *}
388 instantiation multiset :: (type) semilattice_inf
389 begin
391 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
392   multiset_inter_def: "inf_multiset A B = A - (A - B)"
394 instance
395 proof -
396   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
397   show "OFCLASS('a multiset, semilattice_inf_class)"
398     by default (auto simp add: multiset_inter_def mset_le_def aux)
399 qed
401 end
403 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
404   "multiset_inter \<equiv> inf"
406 lemma multiset_inter_count [simp]:
407   "count (A #\<inter> B) x = min (count A x) (count B x)"
408   by (simp add: multiset_inter_def)
410 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
411   by (rule multiset_eqI) auto
413 lemma multiset_union_diff_commute:
414   assumes "B #\<inter> C = {#}"
415   shows "A + B - C = A - C + B"
416 proof (rule multiset_eqI)
417   fix x
418   from assms have "min (count B x) (count C x) = 0"
419     by (auto simp add: multiset_eq_iff)
420   then have "count B x = 0 \<or> count C x = 0"
421     by auto
422   then show "count (A + B - C) x = count (A - C + B) x"
423     by auto
424 qed
426 lemma empty_inter [simp]:
427   "{#} #\<inter> M = {#}"
428   by (simp add: multiset_eq_iff)
430 lemma inter_empty [simp]:
431   "M #\<inter> {#} = {#}"
432   by (simp add: multiset_eq_iff)
435   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
436   by (simp add: multiset_eq_iff)
439   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
440   by (simp add: multiset_eq_iff)
443   "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
444   by (simp add: multiset_eq_iff)
447   "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
448   by (simp add: multiset_eq_iff)
451 subsubsection {* Bounded union *}
453 instantiation multiset :: (type) semilattice_sup
454 begin
456 definition sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
457   "sup_multiset A B = A + (B - A)"
459 instance
460 proof -
461   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" by arith
462   show "OFCLASS('a multiset, semilattice_sup_class)"
463     by default (auto simp add: sup_multiset_def mset_le_def aux)
464 qed
466 end
468 abbreviation sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<union>" 70) where
469   "sup_multiset \<equiv> sup"
471 lemma sup_multiset_count [simp]:
472   "count (A #\<union> B) x = max (count A x) (count B x)"
473   by (simp add: sup_multiset_def)
475 lemma empty_sup [simp]:
476   "{#} #\<union> M = M"
477   by (simp add: multiset_eq_iff)
479 lemma sup_empty [simp]:
480   "M #\<union> {#} = M"
481   by (simp add: multiset_eq_iff)
484   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
485   by (simp add: multiset_eq_iff)
488   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
489   by (simp add: multiset_eq_iff)
492   "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
493   by (simp add: multiset_eq_iff)
496   "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
497   by (simp add: multiset_eq_iff)
500 subsubsection {* Filter (with comprehension syntax) *}
502 text {* Multiset comprehension *}
504 lift_definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
505 by (rule filter_preserves_multiset)
507 hide_const (open) filter
509 lemma count_filter [simp]:
510   "count (Multiset.filter P M) a = (if P a then count M a else 0)"
511   by (simp add: filter.rep_eq)
513 lemma filter_empty [simp]:
514   "Multiset.filter P {#} = {#}"
515   by (rule multiset_eqI) simp
517 lemma filter_single [simp]:
518   "Multiset.filter P {#x#} = (if P x then {#x#} else {#})"
519   by (rule multiset_eqI) simp
521 lemma filter_union [simp]:
522   "Multiset.filter P (M + N) = Multiset.filter P M + Multiset.filter P N"
523   by (rule multiset_eqI) simp
525 lemma filter_diff [simp]:
526   "Multiset.filter P (M - N) = Multiset.filter P M - Multiset.filter P N"
527   by (rule multiset_eqI) simp
529 lemma filter_inter [simp]:
530   "Multiset.filter P (M #\<inter> N) = Multiset.filter P M #\<inter> Multiset.filter P N"
531   by (rule multiset_eqI) simp
533 syntax
534   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
535 syntax (xsymbol)
536   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
537 translations
538   "{#x \<in># M. P#}" == "CONST Multiset.filter (\<lambda>x. P) M"
541 subsubsection {* Set of elements *}
543 definition set_of :: "'a multiset => 'a set" where
544   "set_of M = {x. x :# M}"
546 lemma set_of_empty [simp]: "set_of {#} = {}"
547 by (simp add: set_of_def)
549 lemma set_of_single [simp]: "set_of {#b#} = {b}"
550 by (simp add: set_of_def)
552 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
553 by (auto simp add: set_of_def)
555 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
556 by (auto simp add: set_of_def multiset_eq_iff)
558 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
559 by (auto simp add: set_of_def)
561 lemma set_of_filter [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
562 by (auto simp add: set_of_def)
564 lemma finite_set_of [iff]: "finite (set_of M)"
565   using count [of M] by (simp add: multiset_def set_of_def)
567 lemma finite_Collect_mem [iff]: "finite {x. x :# M}"
568   unfolding set_of_def[symmetric] by simp
570 lemma set_of_mono: "A \<le> B \<Longrightarrow> set_of A \<subseteq> set_of B"
571   by (metis mset_leD subsetI mem_set_of_iff)
573 subsubsection {* Size *}
575 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
577 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
578   by (auto simp: wcount_def add_mult_distrib)
580 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
581   "size_multiset f M = setsum (wcount f M) (set_of M)"
583 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
585 instantiation multiset :: (type) size begin
586 definition size_multiset where
587   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
588 instance ..
589 end
591 lemmas size_multiset_overloaded_eq =
592   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
594 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
595 by (simp add: size_multiset_def)
597 lemma size_empty [simp]: "size {#} = 0"
600 lemma size_multiset_single [simp]: "size_multiset f {#b#} = Suc (f b)"
601 by (simp add: size_multiset_eq)
603 lemma size_single [simp]: "size {#b#} = 1"
606 lemma setsum_wcount_Int:
607   "finite A \<Longrightarrow> setsum (wcount f N) (A \<inter> set_of N) = setsum (wcount f N) A"
608 apply (induct rule: finite_induct)
609  apply simp
610 apply (simp add: Int_insert_left set_of_def wcount_def)
611 done
613 lemma size_multiset_union [simp]:
614   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
615 apply (simp add: size_multiset_def setsum_Un_nat setsum.distrib setsum_wcount_Int wcount_union)
616 apply (subst Int_commute)
617 apply (simp add: setsum_wcount_Int)
618 done
620 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
623 lemma size_multiset_eq_0_iff_empty [iff]: "(size_multiset f M = 0) = (M = {#})"
624 by (auto simp add: size_multiset_eq multiset_eq_iff)
626 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
629 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
630 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
632 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
633 apply (unfold size_multiset_overloaded_eq)
634 apply (drule setsum_SucD)
635 apply auto
636 done
638 lemma size_eq_Suc_imp_eq_union:
639   assumes "size M = Suc n"
640   shows "\<exists>a N. M = N + {#a#}"
641 proof -
642   from assms obtain a where "a \<in># M"
643     by (erule size_eq_Suc_imp_elem [THEN exE])
644   then have "M = M - {#a#} + {#a#}" by simp
645   then show ?thesis by blast
646 qed
649 subsection {* Induction and case splits *}
651 theorem multiset_induct [case_names empty add, induct type: multiset]:
652   assumes empty: "P {#}"
653   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
654   shows "P M"
655 proof (induct n \<equiv> "size M" arbitrary: M)
656   case 0 thus "P M" by (simp add: empty)
657 next
658   case (Suc k)
659   obtain N x where "M = N + {#x#}"
660     using `Suc k = size M` [symmetric]
661     using size_eq_Suc_imp_eq_union by fast
662   with Suc add show "P M" by simp
663 qed
665 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
666 by (induct M) auto
668 lemma multiset_cases [cases type]:
669   obtains (empty) "M = {#}"
670     | (add) N x where "M = N + {#x#}"
671   using assms by (induct M) simp_all
673 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
674 by (cases "B = {#}") (auto dest: multi_member_split)
676 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
677 apply (subst multiset_eq_iff)
678 apply auto
679 done
681 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
682 proof (induct A arbitrary: B)
683   case (empty M)
684   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
685   then obtain M' x where "M = M' + {#x#}"
686     by (blast dest: multi_nonempty_split)
687   then show ?case by simp
688 next
689   case (add S x T)
690   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
691   have SxsubT: "S + {#x#} < T" by fact
692   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
693   then obtain T' where T: "T = T' + {#x#}"
694     by (blast dest: multi_member_split)
695   then have "S < T'" using SxsubT
696     by (blast intro: mset_less_add_bothsides)
697   then have "size S < size T'" using IH by simp
698   then show ?case using T by simp
699 qed
702 subsubsection {* Strong induction and subset induction for multisets *}
704 text {* Well-foundedness of proper subset operator: *}
706 text {* proper multiset subset *}
708 definition
709   mset_less_rel :: "('a multiset * 'a multiset) set" where
710   "mset_less_rel = {(A,B). A < B}"
713   assumes "c \<in># B" and "b \<noteq> c"
714   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
715 proof -
716   from `c \<in># B` obtain A where B: "B = A + {#c#}"
717     by (blast dest: multi_member_split)
718   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
719   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}"
720     by (simp add: ac_simps)
721   then show ?thesis using B by simp
722 qed
724 lemma wf_mset_less_rel: "wf mset_less_rel"
725 apply (unfold mset_less_rel_def)
726 apply (rule wf_measure [THEN wf_subset, where f1=size])
727 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
728 done
730 text {* The induction rules: *}
732 lemma full_multiset_induct [case_names less]:
733 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
734 shows "P B"
735 apply (rule wf_mset_less_rel [THEN wf_induct])
736 apply (rule ih, auto simp: mset_less_rel_def)
737 done
739 lemma multi_subset_induct [consumes 2, case_names empty add]:
740 assumes "F \<le> A"
741   and empty: "P {#}"
742   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
743 shows "P F"
744 proof -
745   from `F \<le> A`
746   show ?thesis
747   proof (induct F)
748     show "P {#}" by fact
749   next
750     fix x F
751     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
752     show "P (F + {#x#})"
753     proof (rule insert)
754       from i show "x \<in># A" by (auto dest: mset_le_insertD)
755       from i have "F \<le> A" by (auto dest: mset_le_insertD)
756       with P show "P F" .
757     qed
758   qed
759 qed
762 subsection {* The fold combinator *}
764 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
765 where
766   "fold f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_of M)"
768 lemma fold_mset_empty [simp]:
769   "fold f s {#} = s"
770   by (simp add: fold_def)
772 context comp_fun_commute
773 begin
775 lemma fold_mset_insert:
776   "fold f s (M + {#x#}) = f x (fold f s M)"
777 proof -
778   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
779     by (fact comp_fun_commute_funpow)
780   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
781     by (fact comp_fun_commute_funpow)
782   show ?thesis
783   proof (cases "x \<in> set_of M")
784     case False
785     then have *: "count (M + {#x#}) x = 1" by simp
786     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_of M) =
787       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_of M)"
788       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
789     with False * show ?thesis
790       by (simp add: fold_def del: count_union)
791   next
792     case True
793     def N \<equiv> "set_of M - {x}"
794     from N_def True have *: "set_of M = insert x N" "x \<notin> N" "finite N" by auto
795     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
796       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
797       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
798     with * show ?thesis by (simp add: fold_def del: count_union) simp
799   qed
800 qed
802 corollary fold_mset_single [simp]:
803   "fold f s {#x#} = f x s"
804 proof -
805   have "fold f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
806   then show ?thesis by simp
807 qed
809 lemma fold_mset_fun_left_comm:
810   "f x (fold f s M) = fold f (f x s) M"
811   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
813 lemma fold_mset_union [simp]:
814   "fold f s (M + N) = fold f (fold f s M) N"
815 proof (induct M)
816   case empty then show ?case by simp
817 next
818   case (add M x)
819   have "M + {#x#} + N = (M + N) + {#x#}"
820     by (simp add: ac_simps)
821   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
822 qed
824 lemma fold_mset_fusion:
825   assumes "comp_fun_commute g"
826   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold g w A) = fold f (h w) A" (is "PROP ?P")
827 proof -
828   interpret comp_fun_commute g by (fact assms)
829   show "PROP ?P" by (induct A) auto
830 qed
832 end
834 text {*
835   A note on code generation: When defining some function containing a
836   subterm @{term "fold F"}, code generation is not automatic. When
837   interpreting locale @{text left_commutative} with @{text F}, the
838   would be code thms for @{const fold} become thms like
839   @{term "fold F z {#} = z"} where @{text F} is not a pattern but
840   contains defined symbols, i.e.\ is not a code thm. Hence a separate
841   constant with its own code thms needs to be introduced for @{text
842   F}. See the image operator below.
843 *}
846 subsection {* Image *}
848 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
849   "image_mset f = fold (plus o single o f) {#}"
851 lemma comp_fun_commute_mset_image:
852   "comp_fun_commute (plus o single o f)"
853 proof
854 qed (simp add: ac_simps fun_eq_iff)
856 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
857   by (simp add: image_mset_def)
859 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
860 proof -
861   interpret comp_fun_commute "plus o single o f"
862     by (fact comp_fun_commute_mset_image)
863   show ?thesis by (simp add: image_mset_def)
864 qed
866 lemma image_mset_union [simp]:
867   "image_mset f (M + N) = image_mset f M + image_mset f N"
868 proof -
869   interpret comp_fun_commute "plus o single o f"
870     by (fact comp_fun_commute_mset_image)
871   show ?thesis by (induct N) (simp_all add: image_mset_def ac_simps)
872 qed
874 corollary image_mset_insert:
875   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
876   by simp
878 lemma set_of_image_mset [simp]:
879   "set_of (image_mset f M) = image f (set_of M)"
880   by (induct M) simp_all
882 lemma size_image_mset [simp]:
883   "size (image_mset f M) = size M"
884   by (induct M) simp_all
886 lemma image_mset_is_empty_iff [simp]:
887   "image_mset f M = {#} \<longleftrightarrow> M = {#}"
888   by (cases M) auto
890 syntax
891   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
892       ("({#_/. _ :# _#})")
893 translations
894   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
896 syntax
897   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
898       ("({#_/ | _ :# _./ _#})")
899 translations
900   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
902 text {*
903   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
904   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
905   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
906   @{term "{#x+x|x:#M. x<c#}"}.
907 *}
909 functor image_mset: image_mset
910 proof -
911   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
912   proof
913     fix A
914     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
915       by (induct A) simp_all
916   qed
917   show "image_mset id = id"
918   proof
919     fix A
920     show "image_mset id A = id A"
921       by (induct A) simp_all
922   qed
923 qed
925 declare image_mset.identity [simp]
928 subsection {* Further conversions *}
930 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
931   "multiset_of [] = {#}" |
932   "multiset_of (a # x) = multiset_of x + {# a #}"
934 lemma in_multiset_in_set:
935   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
936   by (induct xs) simp_all
938 lemma count_multiset_of:
939   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
940   by (induct xs) simp_all
942 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
943 by (induct x) auto
945 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
946 by (induct x) auto
948 lemma set_of_multiset_of[simp]: "set_of (multiset_of x) = set x"
949 by (induct x) auto
951 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
952 by (induct xs) auto
954 lemma size_multiset_of [simp]: "size (multiset_of xs) = length xs"
955   by (induct xs) simp_all
957 lemma multiset_of_append [simp]:
958   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
959   by (induct xs arbitrary: ys) (auto simp: ac_simps)
961 lemma multiset_of_filter:
962   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
963   by (induct xs) simp_all
965 lemma multiset_of_rev [simp]:
966   "multiset_of (rev xs) = multiset_of xs"
967   by (induct xs) simp_all
969 lemma surj_multiset_of: "surj multiset_of"
970 apply (unfold surj_def)
971 apply (rule allI)
972 apply (rule_tac M = y in multiset_induct)
973  apply auto
974 apply (rule_tac x = "x # xa" in exI)
975 apply auto
976 done
978 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
979 by (induct x) auto
981 lemma distinct_count_atmost_1:
982   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
983 apply (induct x, simp, rule iffI, simp_all)
984 apply (rename_tac a b)
985 apply (rule conjI)
986 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
987 apply (erule_tac x = a in allE, simp, clarify)
988 apply (erule_tac x = aa in allE, simp)
989 done
991 lemma multiset_of_eq_setD:
992   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
993 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
995 lemma set_eq_iff_multiset_of_eq_distinct:
996   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
997     (set x = set y) = (multiset_of x = multiset_of y)"
998 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
1000 lemma set_eq_iff_multiset_of_remdups_eq:
1001    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
1002 apply (rule iffI)
1003 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
1004 apply (drule distinct_remdups [THEN distinct_remdups
1005       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
1006 apply simp
1007 done
1009 lemma multiset_of_compl_union [simp]:
1010   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
1011   by (induct xs) (auto simp: ac_simps)
1013 lemma count_multiset_of_length_filter:
1014   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
1015   by (induct xs) auto
1017 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
1018 apply (induct ls arbitrary: i)
1019  apply simp
1020 apply (case_tac i)
1021  apply auto
1022 done
1024 lemma multiset_of_remove1[simp]:
1025   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
1026 by (induct xs) (auto simp add: multiset_eq_iff)
1028 lemma multiset_of_eq_length:
1029   assumes "multiset_of xs = multiset_of ys"
1030   shows "length xs = length ys"
1031   using assms by (metis size_multiset_of)
1033 lemma multiset_of_eq_length_filter:
1034   assumes "multiset_of xs = multiset_of ys"
1035   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
1036   using assms by (metis count_multiset_of)
1038 lemma fold_multiset_equiv:
1039   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
1040     and equiv: "multiset_of xs = multiset_of ys"
1041   shows "List.fold f xs = List.fold f ys"
1042 using f equiv [symmetric]
1043 proof (induct xs arbitrary: ys)
1044   case Nil then show ?case by simp
1045 next
1046   case (Cons x xs)
1047   then have *: "set ys = set (x # xs)" by (blast dest: multiset_of_eq_setD)
1048   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
1049     by (rule Cons.prems(1)) (simp_all add: *)
1050   moreover from * have "x \<in> set ys" by simp
1051   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x" by (fact fold_remove1_split)
1052   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)" by (auto intro: Cons.hyps)
1053   ultimately show ?case by simp
1054 qed
1056 lemma multiset_of_insort [simp]:
1057   "multiset_of (insort x xs) = multiset_of xs + {#x#}"
1058   by (induct xs) (simp_all add: ac_simps)
1060 lemma in_multiset_of:
1061   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
1062   by (induct xs) simp_all
1064 lemma multiset_of_map:
1065   "multiset_of (map f xs) = image_mset f (multiset_of xs)"
1066   by (induct xs) simp_all
1068 definition multiset_of_set :: "'a set \<Rightarrow> 'a multiset"
1069 where
1070   "multiset_of_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
1072 interpretation multiset_of_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
1073 where
1074   "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set"
1075 proof -
1076   interpret comp_fun_commute "\<lambda>x M. {#x#} + M" by default (simp add: fun_eq_iff ac_simps)
1077   show "folding (\<lambda>x M. {#x#} + M)" by default (fact comp_fun_commute)
1078   from multiset_of_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set" ..
1079 qed
1081 lemma count_multiset_of_set [simp]:
1082   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (multiset_of_set A) x = 1" (is "PROP ?P")
1083   "\<not> finite A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?Q")
1084   "x \<notin> A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?R")
1085 proof -
1086   { fix A
1087     assume "x \<notin> A"
1088     have "count (multiset_of_set A) x = 0"
1089     proof (cases "finite A")
1090       case False then show ?thesis by simp
1091     next
1092       case True from True `x \<notin> A` show ?thesis by (induct A) auto
1093     qed
1094   } note * = this
1095   then show "PROP ?P" "PROP ?Q" "PROP ?R"
1096   by (auto elim!: Set.set_insert)
1097 qed -- {* TODO: maybe define @{const multiset_of_set} also in terms of @{const Abs_multiset} *}
1099 context linorder
1100 begin
1102 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
1103 where
1104   "sorted_list_of_multiset M = fold insort [] M"
1106 lemma sorted_list_of_multiset_empty [simp]:
1107   "sorted_list_of_multiset {#} = []"
1108   by (simp add: sorted_list_of_multiset_def)
1110 lemma sorted_list_of_multiset_singleton [simp]:
1111   "sorted_list_of_multiset {#x#} = [x]"
1112 proof -
1113   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
1114   show ?thesis by (simp add: sorted_list_of_multiset_def)
1115 qed
1117 lemma sorted_list_of_multiset_insert [simp]:
1118   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
1119 proof -
1120   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
1121   show ?thesis by (simp add: sorted_list_of_multiset_def)
1122 qed
1124 end
1126 lemma multiset_of_sorted_list_of_multiset [simp]:
1127   "multiset_of (sorted_list_of_multiset M) = M"
1128   by (induct M) simp_all
1130 lemma sorted_list_of_multiset_multiset_of [simp]:
1131   "sorted_list_of_multiset (multiset_of xs) = sort xs"
1132   by (induct xs) simp_all
1134 lemma finite_set_of_multiset_of_set:
1135   assumes "finite A"
1136   shows "set_of (multiset_of_set A) = A"
1137   using assms by (induct A) simp_all
1139 lemma infinite_set_of_multiset_of_set:
1140   assumes "\<not> finite A"
1141   shows "set_of (multiset_of_set A) = {}"
1142   using assms by simp
1144 lemma set_sorted_list_of_multiset [simp]:
1145   "set (sorted_list_of_multiset M) = set_of M"
1146   by (induct M) (simp_all add: set_insort)
1148 lemma sorted_list_of_multiset_of_set [simp]:
1149   "sorted_list_of_multiset (multiset_of_set A) = sorted_list_of_set A"
1150   by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
1153 subsection {* Big operators *}
1155 no_notation times (infixl "*" 70)
1156 no_notation Groups.one ("1")
1158 locale comm_monoid_mset = comm_monoid
1159 begin
1161 definition F :: "'a multiset \<Rightarrow> 'a"
1162 where
1163   eq_fold: "F M = Multiset.fold f 1 M"
1165 lemma empty [simp]:
1166   "F {#} = 1"
1167   by (simp add: eq_fold)
1169 lemma singleton [simp]:
1170   "F {#x#} = x"
1171 proof -
1172   interpret comp_fun_commute
1173     by default (simp add: fun_eq_iff left_commute)
1174   show ?thesis by (simp add: eq_fold)
1175 qed
1177 lemma union [simp]:
1178   "F (M + N) = F M * F N"
1179 proof -
1180   interpret comp_fun_commute f
1181     by default (simp add: fun_eq_iff left_commute)
1182   show ?thesis by (induct N) (simp_all add: left_commute eq_fold)
1183 qed
1185 end
1187 notation times (infixl "*" 70)
1188 notation Groups.one ("1")
1191 begin
1193 definition msetsum :: "'a multiset \<Rightarrow> 'a"
1194 where
1195   "msetsum = comm_monoid_mset.F plus 0"
1197 sublocale msetsum!: comm_monoid_mset plus 0
1198 where
1199   "comm_monoid_mset.F plus 0 = msetsum"
1200 proof -
1201   show "comm_monoid_mset plus 0" ..
1202   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
1203 qed
1205 lemma setsum_unfold_msetsum:
1206   "setsum f A = msetsum (image_mset f (multiset_of_set A))"
1207   by (cases "finite A") (induct A rule: finite_induct, simp_all)
1209 end
1211 syntax
1212   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
1213       ("(3SUM _:#_. _)" [0, 51, 10] 10)
1215 syntax (xsymbols)
1216   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
1217       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
1219 syntax (HTML output)
1220   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
1221       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
1223 translations
1224   "SUM i :# A. b" == "CONST msetsum (CONST image_mset (\<lambda>i. b) A)"
1226 context comm_monoid_mult
1227 begin
1229 definition msetprod :: "'a multiset \<Rightarrow> 'a"
1230 where
1231   "msetprod = comm_monoid_mset.F times 1"
1233 sublocale msetprod!: comm_monoid_mset times 1
1234 where
1235   "comm_monoid_mset.F times 1 = msetprod"
1236 proof -
1237   show "comm_monoid_mset times 1" ..
1238   from msetprod_def show "comm_monoid_mset.F times 1 = msetprod" ..
1239 qed
1241 lemma msetprod_empty:
1242   "msetprod {#} = 1"
1243   by (fact msetprod.empty)
1245 lemma msetprod_singleton:
1246   "msetprod {#x#} = x"
1247   by (fact msetprod.singleton)
1249 lemma msetprod_Un:
1250   "msetprod (A + B) = msetprod A * msetprod B"
1251   by (fact msetprod.union)
1253 lemma setprod_unfold_msetprod:
1254   "setprod f A = msetprod (image_mset f (multiset_of_set A))"
1255   by (cases "finite A") (induct A rule: finite_induct, simp_all)
1257 lemma msetprod_multiplicity:
1258   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_of M)"
1259   by (simp add: Multiset.fold_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
1261 end
1263 syntax
1264   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
1265       ("(3PROD _:#_. _)" [0, 51, 10] 10)
1267 syntax (xsymbols)
1268   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
1269       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
1271 syntax (HTML output)
1272   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
1273       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
1275 translations
1276   "PROD i :# A. b" == "CONST msetprod (CONST image_mset (\<lambda>i. b) A)"
1278 lemma (in comm_semiring_1) dvd_msetprod:
1279   assumes "x \<in># A"
1280   shows "x dvd msetprod A"
1281 proof -
1282   from assms have "A = (A - {#x#}) + {#x#}" by simp
1283   then obtain B where "A = B + {#x#}" ..
1284   then show ?thesis by simp
1285 qed
1288 subsection {* Cardinality *}
1290 definition mcard :: "'a multiset \<Rightarrow> nat"
1291 where
1292   "mcard = msetsum \<circ> image_mset (\<lambda>_. 1)"
1294 lemma mcard_empty [simp]:
1295   "mcard {#} = 0"
1296   by (simp add: mcard_def)
1298 lemma mcard_singleton [simp]:
1299   "mcard {#a#} = Suc 0"
1300   by (simp add: mcard_def)
1302 lemma mcard_plus [simp]:
1303   "mcard (M + N) = mcard M + mcard N"
1304   by (simp add: mcard_def)
1306 lemma mcard_empty_iff [simp]:
1307   "mcard M = 0 \<longleftrightarrow> M = {#}"
1308   by (induct M) simp_all
1310 lemma mcard_unfold_setsum:
1311   "mcard M = setsum (count M) (set_of M)"
1312 proof (induct M)
1313   case empty then show ?case by simp
1314 next
1315   case (add M x) then show ?case
1316     by (cases "x \<in> set_of M")
1317       (simp_all del: mem_set_of_iff add: setsum.distrib setsum.delta' insert_absorb, simp)
1318 qed
1320 lemma size_eq_mcard:
1321   "size = mcard"
1322   by (simp add: fun_eq_iff size_multiset_overloaded_eq mcard_unfold_setsum)
1324 lemma mcard_multiset_of:
1325   "mcard (multiset_of xs) = length xs"
1326   by (induct xs) simp_all
1329 subsection {* Alternative representations *}
1331 subsubsection {* Lists *}
1333 context linorder
1334 begin
1336 lemma multiset_of_insort [simp]:
1337   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
1338   by (induct xs) (simp_all add: ac_simps)
1340 lemma multiset_of_sort [simp]:
1341   "multiset_of (sort_key k xs) = multiset_of xs"
1342   by (induct xs) (simp_all add: ac_simps)
1344 text {*
1345   This lemma shows which properties suffice to show that a function
1346   @{text "f"} with @{text "f xs = ys"} behaves like sort.
1347 *}
1349 lemma properties_for_sort_key:
1350   assumes "multiset_of ys = multiset_of xs"
1351   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
1352   and "sorted (map f ys)"
1353   shows "sort_key f xs = ys"
1354 using assms
1355 proof (induct xs arbitrary: ys)
1356   case Nil then show ?case by simp
1357 next
1358   case (Cons x xs)
1359   from Cons.prems(2) have
1360     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
1361     by (simp add: filter_remove1)
1362   with Cons.prems have "sort_key f xs = remove1 x ys"
1363     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
1364   moreover from Cons.prems have "x \<in> set ys"
1365     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
1366   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
1367 qed
1369 lemma properties_for_sort:
1370   assumes multiset: "multiset_of ys = multiset_of xs"
1371   and "sorted ys"
1372   shows "sort xs = ys"
1373 proof (rule properties_for_sort_key)
1374   from multiset show "multiset_of ys = multiset_of xs" .
1375   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
1376   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
1377     by (rule multiset_of_eq_length_filter)
1378   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
1379     by simp
1380   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
1381     by (simp add: replicate_length_filter)
1382 qed
1384 lemma sort_key_by_quicksort:
1385   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
1386     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
1387     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
1388 proof (rule properties_for_sort_key)
1389   show "multiset_of ?rhs = multiset_of ?lhs"
1390     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
1391 next
1392   show "sorted (map f ?rhs)"
1393     by (auto simp add: sorted_append intro: sorted_map_same)
1394 next
1395   fix l
1396   assume "l \<in> set ?rhs"
1397   let ?pivot = "f (xs ! (length xs div 2))"
1398   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
1399   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
1400     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
1401   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
1402   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
1403   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
1404     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
1405   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
1406   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
1407   proof (cases "f l" ?pivot rule: linorder_cases)
1408     case less
1409     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
1410     with less show ?thesis
1411       by (simp add: filter_sort [symmetric] ** ***)
1412   next
1413     case equal then show ?thesis
1414       by (simp add: * less_le)
1415   next
1416     case greater
1417     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
1418     with greater show ?thesis
1419       by (simp add: filter_sort [symmetric] ** ***)
1420   qed
1421 qed
1423 lemma sort_by_quicksort:
1424   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
1425     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
1426     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
1427   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
1429 text {* A stable parametrized quicksort *}
1431 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
1432   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
1434 lemma part_code [code]:
1435   "part f pivot [] = ([], [], [])"
1436   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
1437      if x' < pivot then (x # lts, eqs, gts)
1438      else if x' > pivot then (lts, eqs, x # gts)
1439      else (lts, x # eqs, gts))"
1440   by (auto simp add: part_def Let_def split_def)
1442 lemma sort_key_by_quicksort_code [code]:
1443   "sort_key f xs = (case xs of [] \<Rightarrow> []
1444     | [x] \<Rightarrow> xs
1445     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
1446     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
1447        in sort_key f lts @ eqs @ sort_key f gts))"
1448 proof (cases xs)
1449   case Nil then show ?thesis by simp
1450 next
1451   case (Cons _ ys) note hyps = Cons show ?thesis
1452   proof (cases ys)
1453     case Nil with hyps show ?thesis by simp
1454   next
1455     case (Cons _ zs) note hyps = hyps Cons show ?thesis
1456     proof (cases zs)
1457       case Nil with hyps show ?thesis by auto
1458     next
1459       case Cons
1460       from sort_key_by_quicksort [of f xs]
1461       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
1462         in sort_key f lts @ eqs @ sort_key f gts)"
1463       by (simp only: split_def Let_def part_def fst_conv snd_conv)
1464       with hyps Cons show ?thesis by (simp only: list.cases)
1465     qed
1466   qed
1467 qed
1469 end
1471 hide_const (open) part
1473 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
1474   by (induct xs) (auto intro: order_trans)
1476 lemma multiset_of_update:
1477   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
1478 proof (induct ls arbitrary: i)
1479   case Nil then show ?case by simp
1480 next
1481   case (Cons x xs)
1482   show ?case
1483   proof (cases i)
1484     case 0 then show ?thesis by simp
1485   next
1486     case (Suc i')
1487     with Cons show ?thesis
1488       apply simp
1489       apply (subst add.assoc)
1490       apply (subst add.commute [of "{#v#}" "{#x#}"])
1491       apply (subst add.assoc [symmetric])
1492       apply simp
1493       apply (rule mset_le_multiset_union_diff_commute)
1494       apply (simp add: mset_le_single nth_mem_multiset_of)
1495       done
1496   qed
1497 qed
1499 lemma multiset_of_swap:
1500   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
1501     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
1502   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
1505 subsection {* The multiset order *}
1507 subsubsection {* Well-foundedness *}
1509 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
1510   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
1511       (\<forall>b. b :# K --> (b, a) \<in> r)}"
1513 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
1514   "mult r = (mult1 r)\<^sup>+"
1516 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
1517 by (simp add: mult1_def)
1519 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
1520     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
1521     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
1522   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
1523 proof (unfold mult1_def)
1524   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
1525   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
1526   let ?case1 = "?case1 {(N, M). ?R N M}"
1528   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
1529   then have "\<exists>a' M0' K.
1530       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
1531   then show "?case1 \<or> ?case2"
1532   proof (elim exE conjE)
1533     fix a' M0' K
1534     assume N: "N = M0' + K" and r: "?r K a'"
1535     assume "M0 + {#a#} = M0' + {#a'#}"
1536     then have "M0 = M0' \<and> a = a' \<or>
1537         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
1538       by (simp only: add_eq_conv_ex)
1539     then show ?thesis
1540     proof (elim disjE conjE exE)
1541       assume "M0 = M0'" "a = a'"
1542       with N r have "?r K a \<and> N = M0 + K" by simp
1543       then have ?case2 .. then show ?thesis ..
1544     next
1545       fix K'
1546       assume "M0' = K' + {#a#}"
1547       with N have n: "N = K' + K + {#a#}" by (simp add: ac_simps)
1549       assume "M0 = K' + {#a'#}"
1550       with r have "?R (K' + K) M0" by blast
1551       with n have ?case1 by simp then show ?thesis ..
1552     qed
1553   qed
1554 qed
1556 lemma all_accessible: "wf r ==> \<forall>M. M \<in> Wellfounded.acc (mult1 r)"
1557 proof
1558   let ?R = "mult1 r"
1559   let ?W = "Wellfounded.acc ?R"
1560   {
1561     fix M M0 a
1562     assume M0: "M0 \<in> ?W"
1563       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
1564       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
1565     have "M0 + {#a#} \<in> ?W"
1566     proof (rule accI [of "M0 + {#a#}"])
1567       fix N
1568       assume "(N, M0 + {#a#}) \<in> ?R"
1569       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
1570           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
1571         by (rule less_add)
1572       then show "N \<in> ?W"
1573       proof (elim exE disjE conjE)
1574         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
1575         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
1576         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
1577         then show "N \<in> ?W" by (simp only: N)
1578       next
1579         fix K
1580         assume N: "N = M0 + K"
1581         assume "\<forall>b. b :# K --> (b, a) \<in> r"
1582         then have "M0 + K \<in> ?W"
1583         proof (induct K)
1584           case empty
1585           from M0 show "M0 + {#} \<in> ?W" by simp
1586         next
1587           case (add K x)
1588           from add.prems have "(x, a) \<in> r" by simp
1589           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
1590           moreover from add have "M0 + K \<in> ?W" by simp
1591           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
1592           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add.assoc)
1593         qed
1594         then show "N \<in> ?W" by (simp only: N)
1595       qed
1596     qed
1597   } note tedious_reasoning = this
1599   assume wf: "wf r"
1600   fix M
1601   show "M \<in> ?W"
1602   proof (induct M)
1603     show "{#} \<in> ?W"
1604     proof (rule accI)
1605       fix b assume "(b, {#}) \<in> ?R"
1606       with not_less_empty show "b \<in> ?W" by contradiction
1607     qed
1609     fix M a assume "M \<in> ?W"
1610     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
1611     proof induct
1612       fix a
1613       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
1614       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
1615       proof
1616         fix M assume "M \<in> ?W"
1617         then show "M + {#a#} \<in> ?W"
1618           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
1619       qed
1620     qed
1621     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
1622   qed
1623 qed
1625 theorem wf_mult1: "wf r ==> wf (mult1 r)"
1626 by (rule acc_wfI) (rule all_accessible)
1628 theorem wf_mult: "wf r ==> wf (mult r)"
1629 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
1632 subsubsection {* Closure-free presentation *}
1634 text {* One direction. *}
1636 lemma mult_implies_one_step:
1637   "trans r ==> (M, N) \<in> mult r ==>
1638     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
1639     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
1640 apply (unfold mult_def mult1_def set_of_def)
1641 apply (erule converse_trancl_induct, clarify)
1642  apply (rule_tac x = M0 in exI, simp, clarify)
1643 apply (case_tac "a :# K")
1644  apply (rule_tac x = I in exI)
1645  apply (simp (no_asm))
1646  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
1647  apply (simp (no_asm_simp) add: add.assoc [symmetric])
1648  apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="?S + ?T" in arg_cong)
1649  apply (simp add: diff_union_single_conv)
1650  apply (simp (no_asm_use) add: trans_def)
1651  apply blast
1652 apply (subgoal_tac "a :# I")
1653  apply (rule_tac x = "I - {#a#}" in exI)
1654  apply (rule_tac x = "J + {#a#}" in exI)
1655  apply (rule_tac x = "K + Ka" in exI)
1656  apply (rule conjI)
1657   apply (simp add: multiset_eq_iff split: nat_diff_split)
1658  apply (rule conjI)
1659   apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="?S + ?T" in arg_cong, simp)
1660   apply (simp add: multiset_eq_iff split: nat_diff_split)
1661  apply (simp (no_asm_use) add: trans_def)
1662  apply blast
1663 apply (subgoal_tac "a :# (M0 + {#a#})")
1664  apply simp
1665 apply (simp (no_asm))
1666 done
1668 lemma one_step_implies_mult_aux:
1669   "trans r ==>
1670     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
1671       --> (I + K, I + J) \<in> mult r"
1672 apply (induct_tac n, auto)
1673 apply (frule size_eq_Suc_imp_eq_union, clarify)
1674 apply (rename_tac "J'", simp)
1675 apply (erule notE, auto)
1676 apply (case_tac "J' = {#}")
1677  apply (simp add: mult_def)
1678  apply (rule r_into_trancl)
1679  apply (simp add: mult1_def set_of_def, blast)
1680 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
1681 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
1682 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
1683 apply (erule ssubst)
1684 apply (simp add: Ball_def, auto)
1685 apply (subgoal_tac
1686   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
1687     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
1688  prefer 2
1689  apply force
1690 apply (simp (no_asm_use) add: add.assoc [symmetric] mult_def)
1691 apply (erule trancl_trans)
1692 apply (rule r_into_trancl)
1693 apply (simp add: mult1_def set_of_def)
1694 apply (rule_tac x = a in exI)
1695 apply (rule_tac x = "I + J'" in exI)
1696 apply (simp add: ac_simps)
1697 done
1699 lemma one_step_implies_mult:
1700   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
1701     ==> (I + K, I + J) \<in> mult r"
1702 using one_step_implies_mult_aux by blast
1705 subsubsection {* Partial-order properties *}
1707 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
1708   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
1710 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
1711   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
1713 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
1714 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
1716 interpretation multiset_order: order le_multiset less_multiset
1717 proof -
1718   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
1719   proof
1720     fix M :: "'a multiset"
1721     assume "M \<subset># M"
1722     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
1723     have "trans {(x'::'a, x). x' < x}"
1724       by (rule transI) simp
1725     moreover note MM
1726     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
1727       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
1728       by (rule mult_implies_one_step)
1729     then obtain I J K where "M = I + J" and "M = I + K"
1730       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
1731     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
1732     have "finite (set_of K)" by simp
1733     moreover note aux2
1734     ultimately have "set_of K = {}"
1735       by (induct rule: finite_induct) (auto intro: order_less_trans)
1736     with aux1 show False by simp
1737   qed
1738   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
1739     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
1740   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
1741     by default (auto simp add: le_multiset_def irrefl dest: trans)
1742 qed
1744 lemma mult_less_irrefl [elim!]: "M \<subset># (M::'a::order multiset) ==> R"
1745   by simp
1748 subsubsection {* Monotonicity of multiset union *}
1750 lemma mult1_union: "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
1751 apply (unfold mult1_def)
1752 apply auto
1753 apply (rule_tac x = a in exI)
1754 apply (rule_tac x = "C + M0" in exI)
1756 done
1758 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
1759 apply (unfold less_multiset_def mult_def)
1760 apply (erule trancl_induct)
1761  apply (blast intro: mult1_union)
1762 apply (blast intro: mult1_union trancl_trans)
1763 done
1765 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
1766 apply (subst add.commute [of B C])
1767 apply (subst add.commute [of D C])
1768 apply (erule union_less_mono2)
1769 done
1771 lemma union_less_mono:
1772   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
1773   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
1775 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
1776 proof
1777 qed (auto simp add: le_multiset_def intro: union_less_mono2)
1780 subsection {* Termination proofs with multiset orders *}
1782 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
1783   and multi_member_this: "x \<in># {# x #} + XS"
1784   and multi_member_last: "x \<in># {# x #}"
1785   by auto
1787 definition "ms_strict = mult pair_less"
1788 definition "ms_weak = ms_strict \<union> Id"
1790 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
1791 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
1792 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
1794 lemma smsI:
1795   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
1796   unfolding ms_strict_def
1797 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
1799 lemma wmsI:
1800   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
1801   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
1802 unfolding ms_weak_def ms_strict_def
1803 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
1805 inductive pw_leq
1806 where
1807   pw_leq_empty: "pw_leq {#} {#}"
1808 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
1810 lemma pw_leq_lstep:
1811   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
1812 by (drule pw_leq_step) (rule pw_leq_empty, simp)
1814 lemma pw_leq_split:
1815   assumes "pw_leq X Y"
1816   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
1817   using assms
1818 proof (induct)
1819   case pw_leq_empty thus ?case by auto
1820 next
1821   case (pw_leq_step x y X Y)
1822   then obtain A B Z where
1823     [simp]: "X = A + Z" "Y = B + Z"
1824       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
1825     by auto
1826   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less"
1827     unfolding pair_leq_def by auto
1828   thus ?case
1829   proof
1830     assume [simp]: "x = y"
1831     have
1832       "{#x#} + X = A + ({#y#}+Z)
1833       \<and> {#y#} + Y = B + ({#y#}+Z)
1834       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
1835       by (auto simp: ac_simps)
1836     thus ?case by (intro exI)
1837   next
1838     assume A: "(x, y) \<in> pair_less"
1839     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
1840     have "{#x#} + X = ?A' + Z"
1841       "{#y#} + Y = ?B' + Z"
1842       by (auto simp add: ac_simps)
1843     moreover have
1844       "(set_of ?A', set_of ?B') \<in> max_strict"
1845       using 1 A unfolding max_strict_def
1846       by (auto elim!: max_ext.cases)
1847     ultimately show ?thesis by blast
1848   qed
1849 qed
1851 lemma
1852   assumes pwleq: "pw_leq Z Z'"
1853   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
1854   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
1855   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
1856 proof -
1857   from pw_leq_split[OF pwleq]
1858   obtain A' B' Z''
1859     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
1860     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
1861     by blast
1862   {
1863     assume max: "(set_of A, set_of B) \<in> max_strict"
1864     from mx_or_empty
1865     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
1866     proof
1867       assume max': "(set_of A', set_of B') \<in> max_strict"
1868       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
1869         by (auto simp: max_strict_def intro: max_ext_additive)
1870       thus ?thesis by (rule smsI)
1871     next
1872       assume [simp]: "A' = {#} \<and> B' = {#}"
1873       show ?thesis by (rule smsI) (auto intro: max)
1874     qed
1875     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:ac_simps)
1876     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
1877   }
1878   from mx_or_empty
1879   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
1880   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:ac_simps)
1881 qed
1883 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
1884 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
1885 and nonempty_single: "{# x #} \<noteq> {#}"
1886 by auto
1888 setup {*
1889 let
1890   fun msetT T = Type (@{type_name multiset}, [T]);
1892   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
1893     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) \$ x
1894     | mk_mset T (x :: xs) =
1895           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) \$
1896                 mk_mset T [x] \$ mk_mset T xs
1898   fun mset_member_tac m i =
1899       (if m <= 0 then
1900            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
1901        else
1902            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
1904   val mset_nonempty_tac =
1905       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
1907   val regroup_munion_conv =
1908       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
1909         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
1911   fun unfold_pwleq_tac i =
1912     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
1913       ORELSE (rtac @{thm pw_leq_lstep} i)
1914       ORELSE (rtac @{thm pw_leq_empty} i)
1916   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
1917                       @{thm Un_insert_left}, @{thm Un_empty_left}]
1918 in
1919   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
1920   {
1921     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
1922     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
1923     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
1924     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
1925     reduction_pair= @{thm ms_reduction_pair}
1926   })
1927 end
1928 *}
1931 subsection {* Legacy theorem bindings *}
1933 lemmas multi_count_eq = multiset_eq_iff [symmetric]
1935 lemma union_commute: "M + N = N + (M::'a multiset)"
1936   by (fact add.commute)
1938 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
1939   by (fact add.assoc)
1941 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
1942   by (fact add.left_commute)
1944 lemmas union_ac = union_assoc union_commute union_lcomm
1946 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
1947   by (fact add_right_cancel)
1949 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
1950   by (fact add_left_cancel)
1952 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
1953   by (fact add_imp_eq)
1955 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
1956   by (fact order_less_trans)
1958 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
1959   by (fact inf.commute)
1961 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
1962   by (fact inf.assoc [symmetric])
1964 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
1965   by (fact inf.left_commute)
1967 lemmas multiset_inter_ac =
1968   multiset_inter_commute
1969   multiset_inter_assoc
1970   multiset_inter_left_commute
1972 lemma mult_less_not_refl:
1973   "\<not> M \<subset># (M::'a::order multiset)"
1974   by (fact multiset_order.less_irrefl)
1976 lemma mult_less_trans:
1977   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
1978   by (fact multiset_order.less_trans)
1980 lemma mult_less_not_sym:
1981   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
1982   by (fact multiset_order.less_not_sym)
1984 lemma mult_less_asym:
1985   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
1986   by (fact multiset_order.less_asym)
1988 ML {*
1989 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
1990                       (Const _ \$ t') =
1991     let
1992       val (maybe_opt, ps) =
1993         Nitpick_Model.dest_plain_fun t' ||> op ~~
1994         ||> map (apsnd (snd o HOLogic.dest_number))
1995       fun elems_for t =
1996         case AList.lookup (op =) ps t of
1997           SOME n => replicate n t
1998         | NONE => [Const (maybe_name, elem_T --> elem_T) \$ t]
1999     in
2000       case maps elems_for (all_values elem_T) @
2001            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
2002             else []) of
2003         [] => Const (@{const_name zero_class.zero}, T)
2004       | ts => foldl1 (fn (t1, t2) =>
2005                          Const (@{const_name plus_class.plus}, T --> T --> T)
2006                          \$ t1 \$ t2)
2007                      (map (curry (op \$) (Const (@{const_name single},
2008                                                 elem_T --> T))) ts)
2009     end
2010   | multiset_postproc _ _ _ _ t = t
2011 *}
2013 declaration {*
2014 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
2015     multiset_postproc
2016 *}
2018 hide_const (open) fold
2021 subsection {* Naive implementation using lists *}
2023 code_datatype multiset_of
2025 lemma [code]:
2026   "{#} = multiset_of []"
2027   by simp
2029 lemma [code]:
2030   "{#x#} = multiset_of [x]"
2031   by simp
2033 lemma union_code [code]:
2034   "multiset_of xs + multiset_of ys = multiset_of (xs @ ys)"
2035   by simp
2037 lemma [code]:
2038   "image_mset f (multiset_of xs) = multiset_of (map f xs)"
2039   by (simp add: multiset_of_map)
2041 lemma [code]:
2042   "Multiset.filter f (multiset_of xs) = multiset_of (filter f xs)"
2043   by (simp add: multiset_of_filter)
2045 lemma [code]:
2046   "multiset_of xs - multiset_of ys = multiset_of (fold remove1 ys xs)"
2047   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
2049 lemma [code]:
2050   "multiset_of xs #\<inter> multiset_of ys =
2051     multiset_of (snd (fold (\<lambda>x (ys, zs).
2052       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
2053 proof -
2054   have "\<And>zs. multiset_of (snd (fold (\<lambda>x (ys, zs).
2055     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
2056       (multiset_of xs #\<inter> multiset_of ys) + multiset_of zs"
2057     by (induct xs arbitrary: ys)
2059   then show ?thesis by simp
2060 qed
2062 lemma [code]:
2063   "multiset_of xs #\<union> multiset_of ys =
2064     multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
2065 proof -
2066   have "\<And>zs. multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
2067       (multiset_of xs #\<union> multiset_of ys) + multiset_of zs"
2068     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
2069   then show ?thesis by simp
2070 qed
2072 lemma [code_unfold]:
2073   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
2074   by (simp add: in_multiset_of)
2076 lemma [code]:
2077   "count (multiset_of xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
2078 proof -
2079   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (multiset_of xs) x + n"
2080     by (induct xs) simp_all
2081   then show ?thesis by simp
2082 qed
2084 lemma [code]:
2085   "set_of (multiset_of xs) = set xs"
2086   by simp
2088 lemma [code]:
2089   "sorted_list_of_multiset (multiset_of xs) = sort xs"
2090   by (induct xs) simp_all
2092 lemma [code]: -- {* not very efficient, but representation-ignorant! *}
2093   "multiset_of_set A = multiset_of (sorted_list_of_set A)"
2094   apply (cases "finite A")
2095   apply simp_all
2096   apply (induct A rule: finite_induct)
2097   apply (simp_all add: union_commute)
2098   done
2100 lemma [code]:
2101   "mcard (multiset_of xs) = length xs"
2102   by (simp add: mcard_multiset_of)
2104 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
2105   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
2106 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of
2107      None \<Rightarrow> None
2108    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
2110 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> multiset_of xs \<le> multiset_of ys) \<and>
2111   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> multiset_of xs < multiset_of ys) \<and>
2112   (ms_lesseq_impl xs ys = Some False \<longrightarrow> multiset_of xs = multiset_of ys)"
2113 proof (induct xs arbitrary: ys)
2114   case (Nil ys)
2115   show ?case by (auto simp: mset_less_empty_nonempty)
2116 next
2117   case (Cons x xs ys)
2118   show ?case
2119   proof (cases "List.extract (op = x) ys")
2120     case None
2121     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
2122     {
2123       assume "multiset_of (x # xs) \<le> multiset_of ys"
2124       from set_of_mono[OF this] x have False by simp
2125     } note nle = this
2126     moreover
2127     {
2128       assume "multiset_of (x # xs) < multiset_of ys"
2129       hence "multiset_of (x # xs) \<le> multiset_of ys" by auto
2130       from nle[OF this] have False .
2131     }
2132     ultimately show ?thesis using None by auto
2133   next
2134     case (Some res)
2135     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
2136     note Some = Some[unfolded res]
2137     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
2138     hence id: "multiset_of ys = multiset_of (ys1 @ ys2) + {#x#}"
2139       by (auto simp: ac_simps)
2140     show ?thesis unfolding ms_lesseq_impl.simps
2141       unfolding Some option.simps split
2142       unfolding id
2143       using Cons[of "ys1 @ ys2"]
2144       unfolding mset_le_def mset_less_def by auto
2145   qed
2146 qed
2148 lemma [code]: "multiset_of xs \<le> multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
2149   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
2151 lemma [code]: "multiset_of xs < multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
2152   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
2154 instantiation multiset :: (equal) equal
2155 begin
2157 definition
2158   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
2159 lemma [code]: "HOL.equal (multiset_of xs) (multiset_of ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
2160   unfolding equal_multiset_def
2161   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
2163 instance
2164   by default (simp add: equal_multiset_def)
2165 end
2167 lemma [code]:
2168   "msetsum (multiset_of xs) = listsum xs"
2169   by (induct xs) (simp_all add: add.commute)
2171 lemma [code]:
2172   "msetprod (multiset_of xs) = fold times xs 1"
2173 proof -
2174   have "\<And>x. fold times xs x = msetprod (multiset_of xs) * x"
2175     by (induct xs) (simp_all add: mult.assoc)
2176   then show ?thesis by simp
2177 qed
2179 lemma [code]:
2180   "size = mcard"
2181   by (fact size_eq_mcard)
2183 text {*
2184   Exercise for the casual reader: add implementations for @{const le_multiset}
2185   and @{const less_multiset} (multiset order).
2186 *}
2188 text {* Quickcheck generators *}
2190 definition (in term_syntax)
2191   msetify :: "'a\<Colon>typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
2192     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
2193   [code_unfold]: "msetify xs = Code_Evaluation.valtermify multiset_of {\<cdot>} xs"
2195 notation fcomp (infixl "\<circ>>" 60)
2196 notation scomp (infixl "\<circ>\<rightarrow>" 60)
2198 instantiation multiset :: (random) random
2199 begin
2201 definition
2202   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
2204 instance ..
2206 end
2208 no_notation fcomp (infixl "\<circ>>" 60)
2209 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
2211 instantiation multiset :: (full_exhaustive) full_exhaustive
2212 begin
2214 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
2215 where
2216   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
2218 instance ..
2220 end
2222 hide_const (open) msetify
2225 subsection {* BNF setup *}
2227 definition rel_mset where
2228   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. multiset_of xs = X \<and> multiset_of ys = Y \<and> list_all2 R xs ys)"
2230 lemma multiset_of_zip_take_Cons_drop_twice:
2231   assumes "length xs = length ys" "j \<le> length xs"
2232   shows "multiset_of (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
2233     multiset_of (zip xs ys) + {#(x, y)#}"
2234 using assms
2235 proof (induct xs ys arbitrary: x y j rule: list_induct2)
2236   case Nil
2237   thus ?case
2238     by simp
2239 next
2240   case (Cons x xs y ys)
2241   thus ?case
2242   proof (cases "j = 0")
2243     case True
2244     thus ?thesis
2245       by simp
2246   next
2247     case False
2248     then obtain k where k: "j = Suc k"
2249       by (case_tac j) simp
2250     hence "k \<le> length xs"
2251       using Cons.prems by auto
2252     hence "multiset_of (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
2253       multiset_of (zip xs ys) + {#(x, y)#}"
2254       by (rule Cons.hyps(2))
2255     thus ?thesis
2256       unfolding k by (auto simp: add.commute union_lcomm)
2257   qed
2258 qed
2260 lemma ex_multiset_of_zip_left:
2261   assumes "length xs = length ys" "multiset_of xs' = multiset_of xs"
2262   shows "\<exists>ys'. length ys' = length xs' \<and> multiset_of (zip xs' ys') = multiset_of (zip xs ys)"
2263 using assms
2264 proof (induct xs ys arbitrary: xs' rule: list_induct2)
2265   case Nil
2266   thus ?case
2267     by auto
2268 next
2269   case (Cons x xs y ys xs')
2270   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
2271   proof -
2272     assume "\<And>j. \<lbrakk>j < length xs'; xs' ! j = x\<rbrakk> \<Longrightarrow> ?thesis"
2273     moreover have "\<And>k m n. (m\<Colon>nat) + n < m + k \<or> \<not> n < k" by linarith
2274     moreover have "\<And>n a as. n - n < length (a # as) \<or> n < n"
2277     moreover have "\<not> length xs' < length xs'" by blast
2278     ultimately show ?thesis
2279       by (metis (no_types) Cons.prems Nat.add_diff_inverse diff_add_inverse2 length_append
2280         less_diff_conv list.set_intros(1) multiset_of_eq_setD nth_append_length split_list)
2281   qed
2283   def xsa \<equiv> "take j xs' @ drop (Suc j) xs'"
2284   have "multiset_of xs' = {#x#} + multiset_of xsa"
2285     unfolding xsa_def using j_len nth_j
2286     by (metis (no_types) ab_semigroup_add_class.add_ac(1) append_take_drop_id drop_Suc_conv_tl
2287       multiset_of.simps(2) union_code union_commute)
2288   hence ms_x: "multiset_of xsa = multiset_of xs"
2289     by (metis Cons.prems add.commute add_right_imp_eq multiset_of.simps(2))
2290   then obtain ysa where
2291     len_a: "length ysa = length xsa" and ms_a: "multiset_of (zip xsa ysa) = multiset_of (zip xs ys)"
2292     using Cons.hyps(2) by blast
2294   def ys' \<equiv> "take j ysa @ y # drop j ysa"
2295   have xs': "xs' = take j xsa @ x # drop j xsa"
2296     using ms_x j_len nth_j Cons.prems xsa_def
2297     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc drop_Suc_conv_tl length_Cons
2298       length_drop mcard_multiset_of)
2299   have j_len': "j \<le> length xsa"
2300     using j_len xs' xsa_def
2301     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
2302   have "length ys' = length xs'"
2303     unfolding ys'_def using Cons.prems len_a ms_x
2304     by (metis add_Suc_right append_take_drop_id length_Cons length_append multiset_of_eq_length)
2305   moreover have "multiset_of (zip xs' ys') = multiset_of (zip (x # xs) (y # ys))"
2306     unfolding xs' ys'_def
2307     by (rule trans[OF multiset_of_zip_take_Cons_drop_twice])
2308       (auto simp: len_a ms_a j_len' add.commute)
2309   ultimately show ?case
2310     by blast
2311 qed
2313 lemma list_all2_reorder_left_invariance:
2314   assumes rel: "list_all2 R xs ys" and ms_x: "multiset_of xs' = multiset_of xs"
2315   shows "\<exists>ys'. list_all2 R xs' ys' \<and> multiset_of ys' = multiset_of ys"
2316 proof -
2317   have len: "length xs = length ys"
2318     using rel list_all2_conv_all_nth by auto
2319   obtain ys' where
2320     len': "length xs' = length ys'" and ms_xy: "multiset_of (zip xs' ys') = multiset_of (zip xs ys)"
2321     using len ms_x by (metis ex_multiset_of_zip_left)
2322   have "list_all2 R xs' ys'"
2323     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: multiset_of_eq_setD)
2324   moreover have "multiset_of ys' = multiset_of ys"
2325     using len len' ms_xy map_snd_zip multiset_of_map by metis
2326   ultimately show ?thesis
2327     by blast
2328 qed
2330 lemma ex_multiset_of: "\<exists>xs. multiset_of xs = X"
2331   by (induct X) (simp, metis multiset_of.simps(2))
2333 bnf "'a multiset"
2334   map: image_mset
2335   sets: set_of
2336   bd: natLeq
2337   wits: "{#}"
2338   rel: rel_mset
2339 proof -
2340   show "image_mset id = id"
2341     by (rule image_mset.id)
2342 next
2343   show "\<And>f g. image_mset (g \<circ> f) = image_mset g \<circ> image_mset f"
2344     unfolding comp_def by (rule ext) (simp add: image_mset.compositionality comp_def)
2345 next
2346   fix X :: "'a multiset"
2347   show "\<And>f g. (\<And>z. z \<in> set_of X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X"
2348     by (induct X, (simp (no_asm))+,
2349       metis One_nat_def Un_iff count_single mem_set_of_iff set_of_union zero_less_Suc)
2350 next
2351   show "\<And>f. set_of \<circ> image_mset f = op ` f \<circ> set_of"
2352     by auto
2353 next
2354   show "card_order natLeq"
2355     by (rule natLeq_card_order)
2356 next
2357   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
2358     by (rule natLeq_cinfinite)
2359 next
2360   show "\<And>X. ordLeq3 (card_of (set_of X)) natLeq"
2361     by transfer
2362       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
2363 next
2364   show "\<And>R S. rel_mset R OO rel_mset S \<le> rel_mset (R OO S)"
2365     unfolding rel_mset_def[abs_def] OO_def
2366     apply clarify
2367     apply (rename_tac X Z Y xs ys' ys zs)
2368     apply (drule_tac xs = ys' and ys = zs and xs' = ys in list_all2_reorder_left_invariance)
2369     by (auto intro: list_all2_trans)
2370 next
2371   show "\<And>R. rel_mset R =
2372     (BNF_Def.Grp {x. set_of x \<subseteq> {(x, y). R x y}} (image_mset fst))\<inverse>\<inverse> OO
2373     BNF_Def.Grp {x. set_of x \<subseteq> {(x, y). R x y}} (image_mset snd)"
2374     unfolding rel_mset_def[abs_def] BNF_Def.Grp_def OO_def
2375     apply (rule ext)+
2376     apply auto
2377      apply (rule_tac x = "multiset_of (zip xs ys)" in exI)
2378      apply auto
2379         apply (metis list_all2_lengthD map_fst_zip multiset_of_map)
2380        apply (auto simp: list_all2_iff)
2381       apply (metis list_all2_lengthD map_snd_zip multiset_of_map)
2382      apply (auto simp: list_all2_iff)
2383     apply (rename_tac XY)
2384     apply (cut_tac X = XY in ex_multiset_of)
2385     apply (erule exE)
2386     apply (rename_tac xys)
2387     apply (rule_tac x = "map fst xys" in exI)
2388     apply (auto simp: multiset_of_map)
2389     apply (rule_tac x = "map snd xys" in exI)
2390     by (auto simp: multiset_of_map list_all2I subset_eq zip_map_fst_snd)
2391 next
2392   show "\<And>z. z \<in> set_of {#} \<Longrightarrow> False"
2393     by auto
2394 qed
2396 inductive rel_mset' where
2397   Zero[intro]: "rel_mset' R {#} {#}"
2398 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (M + {#a#}) (N + {#b#})"
2400 lemma rel_mset_Zero: "rel_mset R {#} {#}"
2401 unfolding rel_mset_def Grp_def by auto
2403 declare multiset.count[simp]
2404 declare Abs_multiset_inverse[simp]
2405 declare multiset.count_inverse[simp]
2406 declare union_preserves_multiset[simp]
2408 lemma rel_mset_Plus:
2409 assumes ab: "R a b" and MN: "rel_mset R M N"
2410 shows "rel_mset R (M + {#a#}) (N + {#b#})"
2411 proof-
2412   {fix y assume "R a b" and "set_of y \<subseteq> {(x, y). R x y}"
2413    hence "\<exists>ya. image_mset fst y + {#a#} = image_mset fst ya \<and>
2414                image_mset snd y + {#b#} = image_mset snd ya \<and>
2415                set_of ya \<subseteq> {(x, y). R x y}"
2416    apply(intro exI[of _ "y + {#(a,b)#}"]) by auto
2417   }
2418   thus ?thesis
2419   using assms
2420   unfolding multiset.rel_compp_Grp Grp_def by blast
2421 qed
2423 lemma rel_mset'_imp_rel_mset:
2424 "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
2425 apply(induct rule: rel_mset'.induct)
2426 using rel_mset_Zero rel_mset_Plus by auto
2428 lemma mcard_image_mset[simp]: "mcard (image_mset f M) = mcard M"
2429   unfolding size_eq_mcard[symmetric] by (rule size_image_mset)
2431 lemma rel_mset_mcard:
2432   assumes "rel_mset R M N"
2433   shows "mcard M = mcard N"
2434 using assms unfolding multiset.rel_compp_Grp Grp_def by auto
2437 assumes empty: "P {#} {#}"
2438 and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
2439 and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
2440 shows "P M N"
2441 apply(induct N rule: multiset_induct)
2442   apply(induct M rule: multiset_induct, rule empty, erule addL)
2443   apply(induct M rule: multiset_induct, erule addR, erule addR)
2444 done
2446 lemma multiset_induct2_mcard[consumes 1, case_names empty add]:
2447 assumes c: "mcard M = mcard N"
2448 and empty: "P {#} {#}"
2449 and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
2450 shows "P M N"
2451 using c proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
2452   case (less M)  show ?case
2453   proof(cases "M = {#}")
2454     case True hence "N = {#}" using less.prems by auto
2455     thus ?thesis using True empty by auto
2456   next
2457     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
2458     have "N \<noteq> {#}" using False less.prems by auto
2459     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
2460     have "mcard M1 = mcard N1" using less.prems unfolding M N by auto
2461     thus ?thesis using M N less.hyps add by auto
2462   qed
2463 qed
2465 lemma msed_map_invL:
2466 assumes "image_mset f (M + {#a#}) = N"
2467 shows "\<exists>N1. N = N1 + {#f a#} \<and> image_mset f M = N1"
2468 proof-
2469   have "f a \<in># N"
2470   using assms multiset.set_map[of f "M + {#a#}"] by auto
2471   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
2472   have "image_mset f M = N1" using assms unfolding N by simp
2473   thus ?thesis using N by blast
2474 qed
2476 lemma msed_map_invR:
2477 assumes "image_mset f M = N + {#b#}"
2478 shows "\<exists>M1 a. M = M1 + {#a#} \<and> f a = b \<and> image_mset f M1 = N"
2479 proof-
2480   obtain a where a: "a \<in># M" and fa: "f a = b"
2481   using multiset.set_map[of f M] unfolding assms
2482   by (metis image_iff mem_set_of_iff union_single_eq_member)
2483   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
2484   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
2485   thus ?thesis using M fa by blast
2486 qed
2488 lemma msed_rel_invL:
2489 assumes "rel_mset R (M + {#a#}) N"
2490 shows "\<exists>N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_mset R M N1"
2491 proof-
2492   obtain K where KM: "image_mset fst K = M + {#a#}"
2493   and KN: "image_mset snd K = N" and sK: "set_of K \<subseteq> {(a, b). R a b}"
2494   using assms
2495   unfolding multiset.rel_compp_Grp Grp_def by auto
2496   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
2497   and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
2498   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "image_mset snd K1 = N1"
2499   using msed_map_invL[OF KN[unfolded K]] by auto
2500   have Rab: "R a (snd ab)" using sK a unfolding K by auto
2501   have "rel_mset R M N1" using sK K1M K1N1
2502   unfolding K multiset.rel_compp_Grp Grp_def by auto
2503   thus ?thesis using N Rab by auto
2504 qed
2506 lemma msed_rel_invR:
2507 assumes "rel_mset R M (N + {#b#})"
2508 shows "\<exists>M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_mset R M1 N"
2509 proof-
2510   obtain K where KN: "image_mset snd K = N + {#b#}"
2511   and KM: "image_mset fst K = M" and sK: "set_of K \<subseteq> {(a, b). R a b}"
2512   using assms
2513   unfolding multiset.rel_compp_Grp Grp_def by auto
2514   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
2515   and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
2516   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "image_mset fst K1 = M1"
2517   using msed_map_invL[OF KM[unfolded K]] by auto
2518   have Rab: "R (fst ab) b" using sK b unfolding K by auto
2519   have "rel_mset R M1 N" using sK K1N K1M1
2520   unfolding K multiset.rel_compp_Grp Grp_def by auto
2521   thus ?thesis using M Rab by auto
2522 qed
2524 lemma rel_mset_imp_rel_mset':
2525 assumes "rel_mset R M N"
2526 shows "rel_mset' R M N"
2527 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
2528   case (less M)
2529   have c: "mcard M = mcard N" using rel_mset_mcard[OF less.prems] .
2530   show ?case
2531   proof(cases "M = {#}")
2532     case True hence "N = {#}" using c by simp
2533     thus ?thesis using True rel_mset'.Zero by auto
2534   next
2535     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
2536     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_mset R M1 N1"
2537     using msed_rel_invL[OF less.prems[unfolded M]] by auto
2538     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
2539     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
2540   qed
2541 qed
2543 lemma rel_mset_rel_mset':
2544 "rel_mset R M N = rel_mset' R M N"
2545 using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
2547 (* The main end product for rel_mset: inductive characterization *)
2548 theorems rel_mset_induct[case_names empty add, induct pred: rel_mset] =
2549          rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
2552 subsection {* Size setup *}
2554 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
2555   unfolding o_apply by (rule ext) (induct_tac, auto)
2557 setup {*
2558 BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
2559   @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
2560     size_union}
2561   @{thms multiset_size_o_map}
2562 *}
2564 hide_const (open) wcount
2566 end