src/Pure/theory.ML
author wenzelm
Thu Oct 11 16:05:39 2007 +0200 (2007-10-11)
changeset 24966 70111480b84b
parent 24763 da4a9986eccd
child 24981 4ec3f95190bf
permissions -rw-r--r--
added specify_const;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   val eq_thy: theory * theory -> bool
    11   val subthy: theory * theory -> bool
    12 end
    13 
    14 signature THEORY =
    15 sig
    16   include BASIC_THEORY
    17   include SIGN_THEORY
    18   val assert_super: theory -> theory -> theory
    19   val parents_of: theory -> theory list
    20   val ancestors_of: theory -> theory list
    21   val check_thy: theory -> theory_ref
    22   val deref: theory_ref -> theory
    23   val merge: theory * theory -> theory
    24   val merge_refs: theory_ref * theory_ref -> theory_ref
    25   val merge_list: theory list -> theory
    26   val checkpoint: theory -> theory
    27   val copy: theory -> theory
    28   val requires: theory -> string -> string -> unit
    29   val axiom_space: theory -> NameSpace.T
    30   val axiom_table: theory -> term Symtab.table
    31   val oracle_space: theory -> NameSpace.T
    32   val oracle_table: theory -> ((theory * Object.T -> term) * stamp) Symtab.table
    33   val axioms_of: theory -> (string * term) list
    34   val all_axioms_of: theory -> (string * term) list
    35   val defs_of: theory -> Defs.T
    36   val at_begin: (theory -> theory option) -> theory -> theory
    37   val at_end: (theory -> theory option) -> theory -> theory
    38   val begin_theory: string -> theory list -> theory
    39   val end_theory: theory -> theory
    40   val add_axioms: (bstring * string) list -> theory -> theory
    41   val add_axioms_i: (bstring * term) list -> theory -> theory
    42   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    43   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    44   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    45   val add_finals: bool -> string list -> theory -> theory
    46   val add_finals_i: bool -> term list -> theory -> theory
    47   val specify_const: Markup.property list -> bstring * typ * mixfix -> theory -> term * theory
    48   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    49 end
    50 
    51 structure Theory: THEORY =
    52 struct
    53 
    54 
    55 (** theory context operations **)
    56 
    57 val eq_thy = Context.eq_thy;
    58 val subthy = Context.subthy;
    59 
    60 fun assert_super thy1 thy2 =
    61   if subthy (thy1, thy2) then thy2
    62   else raise THEORY ("Not a super theory", [thy1, thy2]);
    63 
    64 val parents_of = Context.parents_of;
    65 val ancestors_of = Context.ancestors_of;
    66 
    67 val check_thy = Context.check_thy;
    68 val deref = Context.deref;
    69 
    70 val merge = Context.merge;
    71 val merge_refs = Context.merge_refs;
    72 
    73 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    74   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    75 
    76 val checkpoint = Context.checkpoint_thy;
    77 val copy = Context.copy_thy;
    78 
    79 fun requires thy name what =
    80   if Context.exists_name name thy then ()
    81   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    82 
    83 
    84 
    85 (** theory wrappers **)
    86 
    87 type wrapper = (theory -> theory option) * stamp;
    88 
    89 fun apply_wrappers (wrappers: wrapper list) =
    90   let
    91     fun app [] res = res
    92       | app ((f, _) :: fs) (changed, thy) =
    93           (case f thy of
    94             NONE => app fs (changed, thy)
    95           | SOME thy' => app fs (true, thy'));
    96     fun app_fixpoint thy =
    97       (case app wrappers (false, thy) of
    98         (false, _) => thy
    99       | (true, thy') => app_fixpoint thy');
   100   in app_fixpoint end;
   101 
   102 
   103 
   104 (** datatype thy **)
   105 
   106 datatype thy = Thy of
   107  {axioms: term NameSpace.table,
   108   defs: Defs.T,
   109   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table,
   110   wrappers: wrapper list * wrapper list};
   111 
   112 fun make_thy (axioms, defs, oracles, wrappers) =
   113   Thy {axioms = axioms, defs = defs, oracles = oracles, wrappers = wrappers};
   114 
   115 fun err_dup_axm dup = error ("Duplicate axiom: " ^ quote dup);
   116 fun err_dup_ora dup = error ("Duplicate oracle: " ^ quote dup);
   117 
   118 structure ThyData = TheoryDataFun
   119 (
   120   type T = thy;
   121   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table, ([], []));
   122   val copy = I;
   123 
   124   fun extend (Thy {axioms, defs, oracles, wrappers}) =
   125     make_thy (NameSpace.empty_table, defs, oracles, wrappers);
   126 
   127   fun merge pp (thy1, thy2) =
   128     let
   129       val Thy {axioms = _, defs = defs1, oracles = oracles1, wrappers = (bgs1, ens1)} = thy1;
   130       val Thy {axioms = _, defs = defs2, oracles = oracles2, wrappers = (bgs2, ens2)} = thy2;
   131 
   132       val axioms' = NameSpace.empty_table;
   133       val defs' = Defs.merge pp (defs1, defs2);
   134       val oracles' = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   135         handle Symtab.DUP dup => err_dup_ora dup;
   136       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   137       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   138     in make_thy (axioms', defs', oracles', (bgs', ens')) end;
   139 );
   140 
   141 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   142 
   143 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles, wrappers}) =>
   144   make_thy (f (axioms, defs, oracles, wrappers)));
   145 
   146 
   147 fun map_axioms f = map_thy
   148   (fn (axioms, defs, oracles, wrappers) => (f axioms, defs, oracles, wrappers));
   149 
   150 fun map_defs f = map_thy
   151   (fn (axioms, defs, oracles, wrappers) => (axioms, f defs, oracles, wrappers));
   152 
   153 fun map_oracles f = map_thy
   154   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, f oracles, wrappers));
   155 
   156 fun map_wrappers f = map_thy
   157   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, oracles, f wrappers));
   158 
   159 
   160 (* basic operations *)
   161 
   162 val axiom_space = #1 o #axioms o rep_theory;
   163 val axiom_table = #2 o #axioms o rep_theory;
   164 
   165 val oracle_space = #1 o #oracles o rep_theory;
   166 val oracle_table = #2 o #oracles o rep_theory;
   167 
   168 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   169 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   170 
   171 val defs_of = #defs o rep_theory;
   172 
   173 
   174 (* begin/end theory *)
   175 
   176 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   177 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   178 
   179 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   180 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   181 
   182 fun begin_theory name imports =
   183   let
   184     val thy = Context.begin_thy Sign.pp name imports;
   185     val wrappers = begin_wrappers thy;
   186   in thy |> Sign.local_path |> apply_wrappers wrappers end;
   187 
   188 fun end_theory thy =
   189   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   190 
   191 
   192 (* signature operations *)
   193 
   194 structure SignTheory: SIGN_THEORY = Sign;
   195 open SignTheory;
   196 
   197 
   198 
   199 (** add axioms **)
   200 
   201 (* prepare axioms *)
   202 
   203 fun err_in_axm msg name =
   204   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   205 
   206 fun cert_axm thy (name, raw_tm) =
   207   let
   208     val (t, T, _) = Sign.certify_prop thy raw_tm
   209       handle TYPE (msg, _, _) => error msg
   210         | TERM (msg, _) => error msg;
   211   in
   212     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   213     (name, Sign.no_vars (Sign.pp thy) t)
   214   end;
   215 
   216 fun read_axm thy (name, str) =
   217   cert_axm thy (name, Syntax.read_prop_global thy str)
   218     handle ERROR msg => err_in_axm msg name;
   219 
   220 
   221 (* add_axioms(_i) *)
   222 
   223 local
   224 
   225 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   226   let
   227     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   228     val axioms' = NameSpace.extend_table (Sign.naming_of thy) axms axioms
   229       handle Symtab.DUP dup => err_dup_axm dup;
   230   in axioms' end);
   231 
   232 in
   233 
   234 val add_axioms = gen_add_axioms read_axm;
   235 val add_axioms_i = gen_add_axioms cert_axm;
   236 
   237 end;
   238 
   239 
   240 
   241 (** add constant definitions **)
   242 
   243 (* dependencies *)
   244 
   245 fun dependencies thy unchecked is_def name lhs rhs =
   246   let
   247     val pp = Sign.pp thy;
   248     val consts = Sign.consts_of thy;
   249     fun prep const =
   250       let val Const (c, T) = Sign.no_vars pp (Const const)
   251       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   252 
   253     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   254     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   255       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   256     val _ =
   257       if null rhs_extras then ()
   258       else error ("Specification depends on extra type variables: " ^
   259         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   260         "\nThe error(s) above occurred in " ^ quote name);
   261   in Defs.define pp unchecked is_def name (prep lhs) (map prep rhs) end;
   262 
   263 fun add_deps a raw_lhs raw_rhs thy =
   264   let
   265     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   266     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   267   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   268 
   269 
   270 (* check_overloading *)
   271 
   272 fun check_overloading thy overloaded (c, T) =
   273   let
   274     val declT = Sign.the_const_constraint thy c
   275       handle TYPE (msg, _, _) => error msg;
   276     val T' = Logic.varifyT T;
   277 
   278     fun message txt =
   279       [Pretty.block [Pretty.str "Specification of constant ",
   280         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   281         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   282   in
   283     if Sign.typ_instance thy (declT, T') then ()
   284     else if Type.raw_instance (declT, T') then
   285       error (Library.setmp show_sorts true
   286         message "imposes additional sort constraints on the constant declaration")
   287     else if overloaded then ()
   288     else warning (message "is strictly less general than the declared type");
   289     (c, T)
   290   end;
   291 
   292 
   293 (* check_def *)
   294 
   295 fun check_def thy unchecked overloaded (bname, tm) defs =
   296   let
   297     val name = Sign.full_name thy bname;
   298     val (lhs_const, rhs) = Sign.cert_def (Sign.pp thy) tm;
   299     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   300     val _ = check_overloading thy overloaded lhs_const;
   301   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   302   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   303    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   304     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   305 
   306 
   307 (* add_defs(_i) *)
   308 
   309 local
   310 
   311 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   312   let val axms = map (prep_axm thy) raw_axms in
   313     thy
   314     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   315     |> add_axioms_i axms
   316   end;
   317 
   318 in
   319 
   320 val add_defs_i = gen_add_defs cert_axm;
   321 val add_defs = gen_add_defs read_axm;
   322 
   323 end;
   324 
   325 
   326 (* add_finals(_i) *)
   327 
   328 local
   329 
   330 fun gen_add_finals prep_term overloaded args thy =
   331   let
   332     fun const_of (Const const) = const
   333       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   334       | const_of _ = error "Attempt to finalize non-constant term";
   335     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   336     val finalize = specify o check_overloading thy overloaded o const_of o
   337       Sign.cert_term thy o prep_term thy;
   338   in thy |> map_defs (fold finalize args) end;
   339 
   340 in
   341 
   342 val add_finals = gen_add_finals Syntax.read_term_global;
   343 val add_finals_i = gen_add_finals (K I);
   344 
   345 end;
   346 
   347 fun specify_const tags decl thy =
   348   let val (const, thy') = Sign.declare_const tags decl thy
   349   in (const, add_finals_i false [const] thy') end;
   350 
   351 
   352 
   353 (** add oracle **)
   354 
   355 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   356   NameSpace.extend_table (Sign.naming_of thy) [(bname, (oracle, stamp ()))] oracles
   357     handle Symtab.DUP dup => err_dup_ora dup);
   358 
   359 end;
   360 
   361 structure BasicTheory: BASIC_THEORY = Theory;
   362 open BasicTheory;