src/Pure/Isar/calculation.ML
author wenzelm
Fri Jan 28 12:03:59 2000 +0100 (2000-01-28)
changeset 8150 7021549ef32d
parent 7600 73f91da46230
child 8300 4c3f83414de3
permissions -rw-r--r--
map data;
     1 (*  Title:      Pure/Isar/calculation.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Support for calculational proofs.
     6 *)
     7 
     8 signature CALCULATION =
     9 sig
    10   val print_global_rules: theory -> unit
    11   val print_local_rules: Proof.context -> unit
    12   val trans_add_global: theory attribute
    13   val trans_del_global: theory attribute
    14   val trans_add_local: Proof.context attribute
    15   val trans_del_local: Proof.context attribute
    16   val also: thm list option -> (thm list -> unit) -> Proof.state -> Proof.state Seq.seq
    17   val finally: thm list option -> (thm list -> unit) -> Proof.state -> Proof.state Seq.seq
    18   val setup: (theory -> theory) list
    19 end;
    20 
    21 structure Calculation: CALCULATION =
    22 struct
    23 
    24 
    25 (** global and local calculation data **)
    26 
    27 fun print_rules ths =
    28   Pretty.writeln (Pretty.big_list "calculation rules:" (map Display.pretty_thm ths));
    29 
    30 
    31 (* theory data kind 'Isar/calculation' *)
    32 
    33 structure GlobalCalculationArgs =
    34 struct
    35   val name = "Isar/calculation";
    36   type T = thm list;
    37 
    38   val empty = [];
    39   val copy = I;
    40   val prep_ext = I;
    41   fun merge (ths1, ths2) = Library.generic_merge Thm.eq_thm I I ths1 ths2;
    42   fun print _ = print_rules;
    43 end;
    44 
    45 structure GlobalCalculation = TheoryDataFun(GlobalCalculationArgs);
    46 val print_global_rules = GlobalCalculation.print;
    47 
    48 
    49 (* proof data kind 'Isar/calculation' *)
    50 
    51 structure LocalCalculationArgs =
    52 struct
    53   val name = "Isar/calculation";
    54   type T = thm list * (thm list * int) option;
    55 
    56   fun init thy = (GlobalCalculation.get thy, None);
    57   fun print _ (ths, _) = print_rules ths;
    58 end;
    59 
    60 structure LocalCalculation = ProofDataFun(LocalCalculationArgs);
    61 val get_local_rules = #1 o LocalCalculation.get_st;
    62 val print_local_rules = LocalCalculation.print;
    63 
    64 
    65 (* access calculation *)
    66 
    67 fun get_calculation state =
    68   (case #2 (LocalCalculation.get_st state) of
    69     None => None
    70   | Some (thms, lev) => if lev = Proof.level state then Some thms else None);
    71 
    72 fun put_calculation thms state =
    73   LocalCalculation.put_st (get_local_rules state, Some (thms, Proof.level state)) state;
    74 
    75 fun reset_calculation state =
    76   LocalCalculation.put_st (get_local_rules state, None) state;
    77 
    78 
    79 
    80 (** attributes **)
    81 
    82 (* trans add/del *)
    83 
    84 local
    85 
    86 fun add_trans thm rules = Library.gen_ins Thm.eq_thm (thm, rules);
    87 fun del_trans thm rules = Library.gen_rem Thm.eq_thm (rules, thm);
    88 
    89 fun mk_att f g (x, thm) = (f (g thm) x, thm);
    90 
    91 in
    92 
    93 val trans_add_global = mk_att GlobalCalculation.map add_trans;
    94 val trans_del_global = mk_att GlobalCalculation.map del_trans;
    95 val trans_add_local = mk_att LocalCalculation.map (Library.apfst o add_trans);
    96 val trans_del_local = mk_att LocalCalculation.map (Library.apfst o del_trans);
    97 
    98 end;
    99 
   100 
   101 (* concrete syntax *)
   102 
   103 val transN = "trans";
   104 val addN = "add";
   105 val delN = "del";
   106 
   107 fun trans_att add del =
   108   Attrib.syntax (Scan.lift (Args.$$$ addN >> K add || Args.$$$ delN >> K del || Scan.succeed add));
   109 
   110 val trans_attr =
   111   (trans_att trans_add_global trans_del_global, trans_att trans_add_local trans_del_local);
   112 
   113 
   114 
   115 (** proof commands **)
   116 
   117 val calculationN = "calculation";
   118 
   119 fun calculate final opt_rules print state =
   120   let
   121     fun err_if b msg = if b then raise Proof.STATE (msg, state) else ();
   122     val facts = Proof.the_facts state;
   123     val rules = Seq.of_list (if_none opt_rules [] @ get_local_rules state);
   124 
   125     val eq_prop = op aconv o pairself (#prop o Thm.rep_thm);
   126     fun differ thms thms' = not (Library.equal_lists eq_prop (thms, thms'));
   127     fun combine thms =
   128       Seq.map Library.single (Seq.flat (Seq.map (Method.multi_resolve (thms @ facts)) rules));
   129 
   130     val (initial, calculations) =
   131       (case get_calculation state of
   132         None => (true, Seq.single facts)
   133       | Some thms => (false, Seq.filter (differ thms) (combine thms)))
   134   in
   135     err_if (initial andalso final) "No calculation yet";
   136     err_if (initial andalso is_some opt_rules) "Initial calculation -- no rules to be given";
   137     calculations |> Seq.map (fn calc =>
   138       (print calc;
   139         (if final then
   140           state
   141           |> reset_calculation
   142           |> Proof.reset_thms calculationN
   143           |> Proof.simple_have_thms "" calc
   144           |> Proof.chain
   145         else
   146           state
   147           |> put_calculation calc
   148           |> Proof.simple_have_thms calculationN calc
   149           |> Proof.reset_facts)))
   150   end;
   151 
   152 fun also print = calculate false print;
   153 fun finally print = calculate true print;
   154 
   155 
   156 
   157 (** theory setup **)
   158 
   159 val setup = [GlobalCalculation.init, LocalCalculation.init,
   160   Attrib.add_attributes [(transN, trans_attr, "transitivity rule")]];
   161 
   162 
   163 end;