src/Pure/library.ML
author wenzelm
Wed Dec 05 20:56:42 2007 +0100 (2007-12-05)
changeset 25549 7040555f20c7
parent 25538 58e8ba3b792b
child 25681 ded611be9604
permissions -rw-r--r--
tuned signature;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68 
    69   (*lists*)
    70   exception UnequalLengths
    71   val single: 'a -> 'a list
    72   val the_single: 'a list -> 'a
    73   val singleton: ('a list -> 'b list) -> 'a -> 'b
    74   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    75   val apply: ('a -> 'a) list -> 'a -> 'a
    76   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    77   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    78   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    79   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    80   val flat: 'a list list -> 'a list
    81   val unflat: 'a list list -> 'b list -> 'b list list
    82   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    83   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    84   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    85   val maps: ('a -> 'b list) -> 'a list -> 'b list
    86   val filter: ('a -> bool) -> 'a list -> 'a list
    87   val filter_out: ('a -> bool) -> 'a list -> 'a list
    88   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    89   val chop: int -> 'a list -> 'a list * 'a list
    90   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    91   val nth: 'a list -> int -> 'a
    92   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    93   val nth_drop: int -> 'a list -> 'a list
    94   val nth_list: 'a list list -> int -> 'a list
    95   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    96   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    97   val split_last: 'a list -> 'a list * 'a
    98   val find_index: ('a -> bool) -> 'a list -> int
    99   val find_index_eq: ''a -> ''a list -> int
   100   val find_first: ('a -> bool) -> 'a list -> 'a option
   101   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   102   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   103   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   104   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   105   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   106   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   107   val ~~ : 'a list * 'b list -> ('a * 'b) list
   108   val split_list: ('a * 'b) list -> 'a list * 'b list
   109   val separate: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val inc: int ref -> int
   122   val dec: int ref -> int
   123   val upto: int * int -> int list
   124   val downto: int * int -> int list
   125   val radixpand: int * int -> int list
   126   val radixstring: int * string * int -> string
   127   val string_of_int: int -> string
   128   val signed_string_of_int: int -> string
   129   val string_of_indexname: string * int -> string
   130   val read_radix_int: int -> string list -> int * string list
   131   val read_int: string list -> int * string list
   132   val oct_char: string -> string
   133 
   134   (*strings*)
   135   val nth_string: string -> int -> string
   136   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   137   val exists_string: (string -> bool) -> string -> bool
   138   val forall_string: (string -> bool) -> string -> bool
   139   val enclose: string -> string -> string -> string
   140   val unenclose: string -> string
   141   val quote: string -> string
   142   val space_implode: string -> string list -> string
   143   val commas: string list -> string
   144   val commas_quote: string list -> string
   145   val cat_lines: string list -> string
   146   val space_explode: string -> string -> string list
   147   val split_lines: string -> string list
   148   val prefix_lines: string -> string -> string
   149   val untabify: string list -> string list
   150   val prefix: string -> string -> string
   151   val suffix: string -> string -> string
   152   val unprefix: string -> string -> string
   153   val unsuffix: string -> string -> string
   154   val replicate_string: int -> string -> string
   155   val translate_string: (string -> string) -> string -> string
   156   val multiply: 'a list -> 'a list list -> 'a list list
   157   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   158   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   159 
   160   (*lists as sets -- see also Pure/General/ord_list.ML*)
   161   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   162   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   163   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   164   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   165   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   166   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   167   val mem: ''a * ''a list -> bool
   168   val mem_int: int * int list -> bool
   169   val mem_string: string * string list -> bool
   170   val union: ''a list * ''a list -> ''a list
   171   val union_int: int list * int list -> int list
   172   val union_string: string list * string list -> string list
   173   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   174   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   175   val inter: ''a list * ''a list -> ''a list
   176   val inter_int: int list * int list -> int list
   177   val inter_string: string list * string list -> string list
   178   val subset: ''a list * ''a list -> bool
   179   val subset_int: int list * int list -> bool
   180   val subset_string: string list * string list -> bool
   181   val eq_set: ''a list * ''a list -> bool
   182   val eq_set_string: string list * string list -> bool
   183   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   184   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   185   val \ : ''a list * ''a -> ''a list
   186   val \\ : ''a list * ''a list -> ''a list
   187   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   188   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   189   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   190 
   191   (*lists as multisets*)
   192   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   193   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   194 
   195   (*orders*)
   196   val is_equal: order -> bool
   197   val rev_order: order -> order
   198   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   199   val bool_ord: bool * bool -> order
   200   val int_ord: int * int -> order
   201   val string_ord: string * string -> order
   202   val fast_string_ord: string * string -> order
   203   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   204   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   205   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   206   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   207   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   208   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   209   val sort_strings: string list -> string list
   210   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   211 
   212   (*random numbers*)
   213   exception RANDOM
   214   val random: unit -> real
   215   val random_range: int -> int -> int
   216   val one_of: 'a list -> 'a
   217   val frequency: (int * 'a) list -> 'a
   218 
   219   (*misc*)
   220   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   221   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   222   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   223   val gensym: string -> string
   224   type stamp
   225   val stamp: unit -> stamp
   226   type serial
   227   val serial: unit -> serial
   228   val serial_string: unit -> string
   229   structure Object: sig type T end
   230 end;
   231 
   232 signature LIBRARY =
   233 sig
   234   include BASIC_LIBRARY
   235   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   236   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   237   val take: int * 'a list -> 'a list
   238   val drop: int * 'a list -> 'a list
   239   val last_elem: 'a list -> 'a
   240 end;
   241 
   242 structure Library: LIBRARY =
   243 struct
   244 
   245 (* functions *)
   246 
   247 fun undefined _ = raise Match;
   248 
   249 fun I x = x;
   250 fun K x = fn _ => x;
   251 fun curry f x y = f (x, y);
   252 fun uncurry f (x, y) = f x y;
   253 
   254 (*application and structured results -- old version*)
   255 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   256 
   257 (*conditional application*)
   258 fun b ? f = fn x => if b then f x else x;
   259 
   260 (*composition with multiple args*)
   261 fun (f oo g) x y = f (g x y);
   262 fun (f ooo g) x y z = f (g x y z);
   263 fun (f oooo g) x y z w = f (g x y z w);
   264 
   265 (*function exponentiation: f(...(f x)...) with n applications of f*)
   266 fun funpow (0: int) _ x = x
   267   | funpow n f x = funpow (n - 1) f (f x);
   268 
   269 
   270 (* errors *)
   271 
   272 exception SYS_ERROR of string;
   273 fun sys_error msg = raise SYS_ERROR msg;
   274 
   275 exception ERROR of string;
   276 fun error msg = raise ERROR msg;
   277 
   278 fun cat_error "" msg = error msg
   279   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   280 
   281 fun assert_all pred list msg =
   282   let
   283     fun ass [] = ()
   284       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   285   in ass list end;
   286 
   287 
   288 (* pairs *)
   289 
   290 fun pair x y = (x, y);
   291 fun rpair x y = (y, x);
   292 
   293 fun fst (x, y) = x;
   294 fun snd (x, y) = y;
   295 
   296 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   297 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   298 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   299 
   300 fun swap (x, y) = (y, x);
   301 
   302 fun apfst f (x, y) = (f x, y);
   303 fun apsnd f (x, y) = (x, f y);
   304 fun pairself f (x, y) = (f x, f y);
   305 
   306 
   307 (* booleans *)
   308 
   309 (*polymorphic equality*)
   310 fun equal x y = x = y;
   311 fun not_equal x y = x <> y;
   312 
   313 (*combining predicates*)
   314 fun p orf q = fn x => p x orelse q x;
   315 fun p andf q = fn x => p x andalso q x;
   316 
   317 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   318 fun exists (pred: 'a -> bool) : 'a list -> bool =
   319   let fun boolf [] = false
   320         | boolf (x :: xs) = pred x orelse boolf xs
   321   in boolf end;
   322 
   323 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   324 fun forall (pred: 'a -> bool) : 'a list -> bool =
   325   let fun boolf [] = true
   326         | boolf (x :: xs) = pred x andalso boolf xs
   327   in boolf end;
   328 
   329 
   330 (* flags *)
   331 
   332 fun set flag = (flag := true; true);
   333 fun reset flag = (flag := false; false);
   334 fun toggle flag = (flag := not (! flag); ! flag);
   335 
   336 fun change r f = r := f (! r);
   337 
   338 (*temporarily set flag during execution*)
   339 fun setmp_noncritical flag value f x =
   340   let
   341     val orig_value = ! flag;
   342     val _ = flag := value;
   343     val result = Exn.capture f x;
   344     val _ = flag := orig_value;
   345   in Exn.release result end;
   346 
   347 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   348 
   349 
   350 
   351 (** lists **)
   352 
   353 exception UnequalLengths;
   354 
   355 fun single x = [x];
   356 
   357 fun the_single [x] = x
   358   | the_single _ = raise Empty;
   359 
   360 fun singleton f x = the_single (f [x]);
   361 
   362 fun yield_singleton f x = f [x] #>> the_single;
   363 
   364 fun apply [] x = x
   365   | apply (f :: fs) x = apply fs (f x);
   366 
   367 fun perhaps_apply funs arg =
   368   let
   369     fun app [] res = res
   370       | app (f :: fs) (changed, x) =
   371           (case f x of
   372             NONE => app fs (changed, x)
   373           | SOME x' => app fs (true, x'));
   374   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   375 
   376 fun perhaps_loop f arg =
   377   let
   378     fun loop (changed, x) =
   379       (case f x of
   380         NONE => (changed, x)
   381       | SOME x' => loop (true, x'));
   382   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   383 
   384 
   385 (* fold -- old versions *)
   386 
   387 (*the following versions of fold are designed to fit nicely with infixes*)
   388 
   389 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   390     for operators that associate to the left (TAIL RECURSIVE)*)
   391 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   392   let fun itl (e, [])  = e
   393         | itl (e, a::l) = itl (f(e, a), l)
   394   in  itl end;
   395 
   396 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   397     for operators that associate to the right (not tail recursive)*)
   398 fun foldr f (l, e) =
   399   let fun itr [] = e
   400         | itr (a::l) = f(a, itr l)
   401   in  itr l  end;
   402 
   403 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   404     for n > 0, operators that associate to the right (not tail recursive)*)
   405 fun foldr1 f [] = raise Empty
   406   | foldr1 f l =
   407       let fun itr [x] = x
   408             | itr (x::l) = f(x, itr l)
   409       in  itr l  end;
   410 
   411 fun foldl_map f =
   412   let
   413     fun fold_aux (x, []) = (x, [])
   414       | fold_aux (x, y :: ys) =
   415           let
   416             val (x', y') = f (x, y);
   417             val (x'', ys') = fold_aux (x', ys);
   418           in (x'', y' :: ys') end;
   419   in fold_aux end;
   420 
   421 
   422 (* basic list functions *)
   423 
   424 fun eq_list eq (list1, list2) =
   425   let
   426     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   427       | eq_lst _ = true;
   428   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   429 
   430 fun maps f [] = []
   431   | maps f (x :: xs) = f x @ maps f xs;
   432 
   433 val filter = List.filter;
   434 fun filter_out f = filter (not o f);
   435 val map_filter = List.mapPartial;
   436 
   437 fun chop (0: int) xs = ([], xs)
   438   | chop _ [] = ([], [])
   439   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   440 
   441 (*take the first n elements from a list*)
   442 fun take (n: int, []) = []
   443   | take (n, x :: xs) =
   444       if n > 0 then x :: take (n - 1, xs) else [];
   445 
   446 (*drop the first n elements from a list*)
   447 fun drop (n: int, []) = []
   448   | drop (n, x :: xs) =
   449       if n > 0 then drop (n - 1, xs) else x :: xs;
   450 
   451 fun dropwhile P [] = []
   452   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   453 
   454 (*return nth element of a list, where 0 designates the first element;
   455   raise Subscript if list too short*)
   456 fun nth xs i = List.nth (xs, i);
   457 
   458 fun nth_list xss i = nth xss i handle Subscript => [];
   459 
   460 fun nth_map 0 f (x :: xs) = f x :: xs
   461   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   462   | nth_map (_: int) _ [] = raise Subscript;
   463 
   464 fun nth_drop n xs =
   465   List.take (xs, n) @ List.drop (xs, n + 1);
   466 
   467 fun map_index f =
   468   let
   469     fun mapp (_: int) [] = []
   470       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   471   in mapp 0 end;
   472 
   473 fun fold_index f =
   474   let
   475     fun fold_aux (_: int) [] y = y
   476       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   477   in fold_aux 0 end;
   478 
   479 val last_elem = List.last;
   480 
   481 (*rear decomposition*)
   482 fun split_last [] = raise Empty
   483   | split_last [x] = ([], x)
   484   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   485 
   486 (*find the position of an element in a list*)
   487 fun find_index pred =
   488   let fun find (_: int) [] = ~1
   489         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   490   in find 0 end;
   491 
   492 fun find_index_eq x = find_index (equal x);
   493 
   494 (*find first element satisfying predicate*)
   495 val find_first = List.find;
   496 
   497 (*get first element by lookup function*)
   498 fun get_first _ [] = NONE
   499   | get_first f (x :: xs) =
   500       (case f x of
   501         NONE => get_first f xs
   502       | some => some);
   503 
   504 fun get_index f =
   505   let
   506     fun get (_: int) [] = NONE
   507       | get i (x :: xs) =
   508           case f x
   509            of NONE => get (i + 1) xs
   510             | SOME y => SOME (i, y)
   511   in get 0 end;
   512 
   513 val flat = List.concat;
   514 
   515 fun unflat (xs :: xss) ys =
   516       let val (ps, qs) = chop (length xs) ys
   517       in ps :: unflat xss qs end
   518   | unflat [] [] = []
   519   | unflat _ _ = raise UnequalLengths;
   520 
   521 fun burrow f xss = unflat xss (f (flat xss));
   522 
   523 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   524 
   525 fun fold_burrow f xss s =
   526   apfst (unflat xss) (f (flat xss) s);
   527 
   528 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   529 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   530   | separate _ xs = xs;
   531 
   532 (*make the list [x, x, ..., x] of length n*)
   533 fun replicate (n: int) x =
   534   let fun rep (0, xs) = xs
   535         | rep (n, xs) = rep (n - 1, x :: xs)
   536   in
   537     if n < 0 then raise Subscript
   538     else rep (n, [])
   539   end;
   540 
   541 fun translate_string f = String.translate (f o String.str);
   542 
   543 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   544 fun multiply [] _ = []
   545   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   546 
   547 
   548 (* direct product *)
   549 
   550 fun map_product f _ [] = []
   551   | map_product f [] _ = []
   552   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   553 
   554 fun fold_product f _ [] z = z
   555   | fold_product f [] _ z = z
   556   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   557 
   558 
   559 (* lists of pairs *)
   560 
   561 exception UnequalLengths;
   562 
   563 fun map2 _ [] [] = []
   564   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   565   | map2 _ _ _ = raise UnequalLengths;
   566 
   567 fun fold2 f [] [] z = z
   568   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   569   | fold2 f _ _ _ = raise UnequalLengths;
   570 
   571 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   572   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   573   | zip_options _ [] = []
   574   | zip_options [] _ = raise UnequalLengths;
   575 
   576 (*combine two lists forming a list of pairs:
   577   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   578 fun [] ~~ [] = []
   579   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   580   | _ ~~ _ = raise UnequalLengths;
   581 
   582 (*inverse of ~~; the old 'split':
   583   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   584 val split_list = ListPair.unzip;
   585 
   586 
   587 (* prefixes, suffixes *)
   588 
   589 fun is_prefix _ [] _ = true
   590   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   591   | is_prefix eq _ _ = false;
   592 
   593 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   594    where xi is the first element that does not satisfy the predicate*)
   595 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   596   let fun take (rxs, []) = (rev rxs, [])
   597         | take (rxs, x :: xs) =
   598             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   599   in  take([], xs)  end;
   600 
   601 fun chop_prefix eq ([], ys) = ([], ([], ys))
   602   | chop_prefix eq (xs, []) = ([], (xs, []))
   603   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   604       if eq (x, y) then
   605         let val (ps', xys'') = chop_prefix eq (xs', ys')
   606         in (x :: ps', xys'') end
   607       else ([], (xs, ys));
   608 
   609 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   610    where xi is the last element that does not satisfy the predicate*)
   611 fun take_suffix _ [] = ([], [])
   612   | take_suffix pred (x :: xs) =
   613       (case take_suffix pred xs of
   614         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   615       | (prfx, sffx) => (x :: prfx, sffx));
   616 
   617 fun prefixes1 [] = []
   618   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   619 
   620 fun prefixes xs = [] :: prefixes1 xs;
   621 
   622 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   623 fun suffixes xs = [] :: suffixes1 xs;
   624 
   625 
   626 
   627 (** integers **)
   628 
   629 fun inc i = (i := ! i + (1: int); ! i);
   630 fun dec i = (i := ! i - (1: int); ! i);
   631 
   632 
   633 (* lists of integers *)
   634 
   635 (*make the list [from, from + 1, ..., to]*)
   636 fun ((i: int) upto j) =
   637   if i > j then [] else i :: (i + 1 upto j);
   638 
   639 (*make the list [from, from - 1, ..., to]*)
   640 fun ((i: int) downto j) =
   641   if i < j then [] else i :: (i - 1 downto j);
   642 
   643 
   644 (* convert integers to strings *)
   645 
   646 (*expand the number in the given base;
   647   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   648 fun radixpand (base, num) : int list =
   649   let
   650     fun radix (n, tail) =
   651       if n < base then n :: tail
   652       else radix (n div base, (n mod base) :: tail)
   653   in radix (num, []) end;
   654 
   655 (*expands a number into a string of characters starting from "zerochar";
   656   example: radixstring (2, "0", 8) gives "1000"*)
   657 fun radixstring (base, zerochar, num) =
   658   let val offset = ord zerochar;
   659       fun chrof n = chr (offset + n)
   660   in implode (map chrof (radixpand (base, num))) end;
   661 
   662 
   663 val string_of_int = Int.toString;
   664 
   665 fun signed_string_of_int i =
   666   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   667 
   668 fun string_of_indexname (a, 0) = a
   669   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   670 
   671 
   672 (* read integers *)
   673 
   674 fun read_radix_int radix cs =
   675   let
   676     val zero = ord "0";
   677     val limit = zero + radix;
   678     fun scan (num, []) = (num, [])
   679       | scan (num, c :: cs) =
   680         if zero <= ord c andalso ord c < limit then
   681           scan (radix * num + (ord c - zero), cs)
   682         else (num, c :: cs);
   683   in scan (0, cs) end;
   684 
   685 val read_int = read_radix_int 10;
   686 
   687 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   688 
   689 
   690 
   691 (** strings **)
   692 
   693 (* functions tuned for strings, avoiding explode *)
   694 
   695 fun nth_string str i =
   696   (case try String.substring (str, i, 1) of
   697     SOME s => s
   698   | NONE => raise Subscript);
   699 
   700 fun fold_string f str x0 =
   701   let
   702     val n = size str;
   703     fun iter (x, i) =
   704       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   705   in iter (x0, 0) end;
   706 
   707 fun exists_string pred str =
   708   let
   709     val n = size str;
   710     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   711   in ex 0 end;
   712 
   713 fun forall_string pred = not o exists_string (not o pred);
   714 
   715 (*enclose in brackets*)
   716 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   717 fun unenclose str = String.substring (str, 1, size str - 2);
   718 
   719 (*simple quoting (does not escape special chars)*)
   720 val quote = enclose "\"" "\"";
   721 
   722 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   723 fun space_implode a bs = implode (separate a bs);
   724 
   725 val commas = space_implode ", ";
   726 val commas_quote = commas o map quote;
   727 
   728 (*concatenate messages, one per line, into a string*)
   729 val cat_lines = space_implode "\n";
   730 
   731 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   732 fun space_explode _ "" = []
   733   | space_explode sep s = String.fields (fn c => str c = sep) s;
   734 
   735 val split_lines = space_explode "\n";
   736 
   737 fun prefix_lines "" txt = txt
   738   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   739 
   740 fun untabify chs =
   741   let
   742     val tab_width = 8;
   743 
   744     fun untab pos [] ys = rev ys
   745       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   746       | untab pos ("\t" :: xs) ys =
   747           let val d = tab_width - (pos mod tab_width)
   748           in untab (pos + d) xs (funpow d (cons " ") ys) end
   749       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   750   in
   751     if not (exists (fn c => c = "\t") chs) then chs
   752     else untab 0 chs []
   753   end;
   754 
   755 fun prefix prfx s = prfx ^ s;
   756 fun suffix sffx s = s ^ sffx;
   757 
   758 fun unprefix prfx s =
   759   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   760   else raise Fail "unprefix";
   761 
   762 fun unsuffix sffx s =
   763   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   764   else raise Fail "unsuffix";
   765 
   766 fun replicate_string (0: int) _ = ""
   767   | replicate_string 1 a = a
   768   | replicate_string k a =
   769       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   770       else replicate_string (k div 2) (a ^ a) ^ a;
   771 
   772 
   773 
   774 (** lists as sets -- see also Pure/General/ord_list.ML **)
   775 
   776 (*canonical member, insert, remove*)
   777 fun member eq list x =
   778   let
   779     fun memb [] = false
   780       | memb (y :: ys) = eq (x, y) orelse memb ys;
   781   in memb list end;
   782 
   783 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   784 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   785 fun update eq x xs = cons x (remove eq x xs);
   786 
   787 fun subtract eq = fold (remove eq);
   788 
   789 fun merge _ ([], ys) = ys
   790   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   791 
   792 (*old-style infixes*)
   793 fun x mem xs = member (op =) xs x;
   794 fun (x: int) mem_int xs = member (op =) xs x;
   795 fun (x: string) mem_string xs = member (op =) xs x;
   796 
   797 
   798 (*union of sets represented as lists: no repetitions*)
   799 fun xs union [] = xs
   800   | [] union ys = ys
   801   | (x :: xs) union ys = xs union (insert (op =) x ys);
   802 
   803 (*union of sets, optimized version for ints*)
   804 fun (xs:int list) union_int [] = xs
   805   | [] union_int ys = ys
   806   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   807 
   808 (*union of sets, optimized version for strings*)
   809 fun (xs:string list) union_string [] = xs
   810   | [] union_string ys = ys
   811   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   812 
   813 (*generalized union*)
   814 fun gen_union eq (xs, []) = xs
   815   | gen_union eq ([], ys) = ys
   816   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   817 
   818 
   819 (*intersection*)
   820 fun [] inter ys = []
   821   | (x :: xs) inter ys =
   822       if x mem ys then x :: (xs inter ys) else xs inter ys;
   823 
   824 (*intersection, optimized version for ints*)
   825 fun ([]:int list) inter_int ys = []
   826   | (x :: xs) inter_int ys =
   827       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   828 
   829 (*intersection, optimized version for strings *)
   830 fun ([]:string list) inter_string ys = []
   831   | (x :: xs) inter_string ys =
   832       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   833 
   834 (*generalized intersection*)
   835 fun gen_inter eq ([], ys) = []
   836   | gen_inter eq (x::xs, ys) =
   837       if member eq ys x then x :: gen_inter eq (xs, ys)
   838       else gen_inter eq (xs, ys);
   839 
   840 
   841 (*subset*)
   842 fun [] subset ys = true
   843   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   844 
   845 (*subset, optimized version for ints*)
   846 fun ([]: int list) subset_int ys = true
   847   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   848 
   849 (*subset, optimized version for strings*)
   850 fun ([]: string list) subset_string ys = true
   851   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   852 
   853 (*set equality*)
   854 fun eq_set (xs, ys) =
   855   xs = ys orelse (xs subset ys andalso ys subset xs);
   856 
   857 (*set equality for strings*)
   858 fun eq_set_string ((xs: string list), ys) =
   859   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   860 
   861 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   862 
   863 fun gen_eq_set eq (xs, ys) =
   864   eq_list eq (xs, ys) orelse
   865     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   866 
   867 
   868 (*removing an element from a list WITHOUT duplicates*)
   869 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   870   | [] \ x = [];
   871 fun ys \\ xs = foldl (op \) (ys,xs);
   872 
   873 
   874 (*makes a list of the distinct members of the input; preserves order, takes
   875   first of equal elements*)
   876 fun distinct eq lst =
   877   let
   878     fun dist (rev_seen, []) = rev rev_seen
   879       | dist (rev_seen, x :: xs) =
   880           if member eq rev_seen x then dist (rev_seen, xs)
   881           else dist (x :: rev_seen, xs);
   882   in dist ([], lst) end;
   883 
   884 (*returns a list containing all repeated elements exactly once; preserves
   885   order, takes first of equal elements*)
   886 fun duplicates eq lst =
   887   let
   888     fun dups (rev_dups, []) = rev rev_dups
   889       | dups (rev_dups, x :: xs) =
   890           if member eq rev_dups x orelse not (member eq xs x) then
   891             dups (rev_dups, xs)
   892           else dups (x :: rev_dups, xs);
   893   in dups ([], lst) end;
   894 
   895 fun has_duplicates eq =
   896   let
   897     fun dups [] = false
   898       | dups (x :: xs) = member eq xs x orelse dups xs;
   899   in dups end;
   900 
   901 
   902 
   903 (** lists as multisets **)
   904 
   905 fun remove1 _ _ [] = raise Empty
   906   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   907 
   908 fun submultiset _ ([], _)  = true
   909   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   910 
   911 
   912 
   913 (** orders **)
   914 
   915 fun is_equal EQUAL = true
   916   | is_equal _ = false;
   917 
   918 fun rev_order LESS = GREATER
   919   | rev_order EQUAL = EQUAL
   920   | rev_order GREATER = LESS;
   921 
   922 (*assume rel is a linear strict order*)
   923 fun make_ord rel (x, y) =
   924   if rel (x, y) then LESS
   925   else if rel (y, x) then GREATER
   926   else EQUAL;
   927 
   928 fun bool_ord (false, true) = LESS
   929   | bool_ord (true, false) = GREATER
   930   | bool_ord _ = EQUAL;
   931 
   932 val int_ord = Int.compare;
   933 val string_ord = String.compare;
   934 
   935 fun fast_string_ord (s1, s2) =
   936   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   937 
   938 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   939   | option_ord _ (NONE, NONE) = EQUAL
   940   | option_ord _ (NONE, SOME _) = LESS
   941   | option_ord _ (SOME _, NONE) = GREATER;
   942 
   943 (*lexicographic product*)
   944 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   945   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   946 
   947 (*dictionary order -- in general NOT well-founded!*)
   948 fun dict_ord elem_ord (x :: xs, y :: ys) =
   949       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   950   | dict_ord _ ([], []) = EQUAL
   951   | dict_ord _ ([], _ :: _) = LESS
   952   | dict_ord _ (_ :: _, []) = GREATER;
   953 
   954 (*lexicographic product of lists*)
   955 fun list_ord elem_ord (xs, ys) =
   956   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   957 
   958 
   959 (* sorting *)
   960 
   961 (*quicksort -- stable, i.e. does not reorder equal elements*)
   962 fun quicksort unique ord =
   963   let
   964     fun qsort [] = []
   965       | qsort (xs as [_]) = xs
   966       | qsort (xs as [x, y]) =
   967           (case ord (x, y) of
   968             LESS => xs
   969           | EQUAL => if unique then [x] else xs
   970           | GREATER => [y, x])
   971       | qsort xs =
   972           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   973           in qsort lts @ eqs @ qsort gts end
   974     and part _ [] = ([], [], [])
   975       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   976     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   977       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   978       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   979       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   980   in qsort end;
   981 
   982 fun sort ord = quicksort false ord;
   983 fun sort_distinct ord = quicksort true ord;
   984 
   985 val sort_strings = sort string_ord;
   986 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   987 
   988 
   989 
   990 (** random numbers **)
   991 
   992 exception RANDOM;
   993 
   994 fun rmod x y = x - y * Real.realFloor (x / y);
   995 
   996 local
   997   val a = 16807.0;
   998   val m = 2147483647.0;
   999   val random_seed = ref 1.0;
  1000 in
  1001 
  1002 fun random () = CRITICAL (fn () =>
  1003   let val r = rmod (a * ! random_seed) m
  1004   in (random_seed := r; r) end);
  1005 
  1006 end;
  1007 
  1008 fun random_range l h =
  1009   if h < l orelse l < 0 then raise RANDOM
  1010   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1011 
  1012 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1013 
  1014 fun frequency xs =
  1015   let
  1016     val sum = foldl op + (0, map fst xs);
  1017     fun pick n ((k: int, x) :: xs) =
  1018       if n <= k then x else pick (n - k) xs
  1019   in pick (random_range 1 sum) xs end;
  1020 
  1021 
  1022 
  1023 (** misc **)
  1024 
  1025 fun divide_and_conquer decomp x =
  1026   let val (ys, recomb) = decomp x
  1027   in recomb (map (divide_and_conquer decomp) ys) end;
  1028 
  1029 
  1030 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1031    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1032 fun partition_list p i j =
  1033   let fun part k xs =
  1034             if k>j then
  1035               (case xs of [] => []
  1036                          | _ => raise Fail "partition_list")
  1037             else
  1038             let val (ns, rest) = List.partition (p k) xs;
  1039             in  ns :: part(k+1)rest  end
  1040   in  part (i: int) end;
  1041 
  1042 fun partition_eq (eq:'a * 'a -> bool) =
  1043   let
  1044     fun part [] = []
  1045       | part (x :: ys) =
  1046           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1047           in (x::xs)::(part xs') end
  1048   in part end;
  1049 
  1050 
  1051 
  1052 (* generating identifiers *)
  1053 
  1054 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1055 local
  1056 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1057 fun gensym_char i =
  1058   if i<26 then chr (ord "A" + i)
  1059   else if i<52 then chr (ord "a" + i - 26)
  1060   else chr (ord "0" + i - 52);
  1061 
  1062 val char_vec = Vector.tabulate (62, gensym_char);
  1063 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1064 
  1065 val gensym_seed = ref (0: int);
  1066 
  1067 in
  1068   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1069 end;
  1070 
  1071 
  1072 (* stamps and serial numbers *)
  1073 
  1074 type stamp = unit ref;
  1075 val stamp: unit -> stamp = ref;
  1076 
  1077 type serial = int;
  1078 local val count = ref (0: int)
  1079 in fun serial () = NAMED_CRITICAL "serial" (fn () => inc count) end;
  1080 
  1081 val serial_string = string_of_int o serial;
  1082 
  1083 
  1084 (* generic objects *)
  1085 
  1086 (*note that the builtin exception datatype may be extended by new
  1087   constructors at any time*)
  1088 structure Object = struct type T = exn end;
  1089 
  1090 end;
  1091 
  1092 structure BasicLibrary: BASIC_LIBRARY = Library;
  1093 open BasicLibrary;