src/HOL/Library/FuncSet.thy
author wenzelm
Thu May 06 14:14:18 2004 +0200 (2004-05-06)
changeset 14706 71590b7733b7
parent 14565 c6dc17aab88a
child 14745 94be403deb84
permissions -rw-r--r--
tuned document;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     ID:         $Id$
     3     Author:     Florian Kammueller and Lawrence C Paulson
     4 *)
     5 
     6 header {* Pi and Function Sets *}
     7 
     8 theory FuncSet = Main:
     9 
    10 constdefs
    11   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set"
    12   "Pi A B == {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    13 
    14   extensional :: "'a set => ('a => 'b) set"
    15   "extensional A == {f. \<forall>x. x~:A --> f x = arbitrary}"
    16 
    17   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)"
    18   "restrict f A == (%x. if x \<in> A then f x else arbitrary)"
    19 
    20 syntax
    21   "@Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    22   funcset :: "['a set, 'b set] => ('a => 'b) set"      (infixr "->" 60)
    23   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    24 
    25 syntax (xsymbols)
    26   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    27   funcset :: "['a set, 'b set] => ('a => 'b) set"  (infixr "\<rightarrow>" 60)
    28   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    29 
    30 syntax (HTML output)
    31   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    32   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    33 
    34 translations
    35   "PI x:A. B" => "Pi A (%x. B)"
    36   "A -> B" => "Pi A (_K B)"
    37   "%x:A. f" == "restrict (%x. f) A"
    38 
    39 constdefs
    40   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)"
    41   "compose A g f == \<lambda>x\<in>A. g (f x)"
    42 
    43 print_translation {* [("Pi", dependent_tr' ("@Pi", "funcset"))] *}
    44 
    45 
    46 subsection{*Basic Properties of @{term Pi}*}
    47 
    48 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    49   by (simp add: Pi_def)
    50 
    51 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    52   by (simp add: Pi_def)
    53 
    54 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    55   by (simp add: Pi_def)
    56 
    57 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    58   by (simp add: Pi_def)
    59 
    60 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    61 apply (simp add: Pi_def, auto)
    62 txt{*Converse direction requires Axiom of Choice to exhibit a function
    63 picking an element from each non-empty @{term "B x"}*}
    64 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    65 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    66 done
    67 
    68 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    69   by (simp add: Pi_def)
    70 
    71 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    72   by (simp add: Pi_def)
    73 
    74 text{*Covariance of Pi-sets in their second argument*}
    75 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    76   by (simp add: Pi_def, blast)
    77 
    78 text{*Contravariance of Pi-sets in their first argument*}
    79 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    80   by (simp add: Pi_def, blast)
    81 
    82 
    83 subsection{*Composition With a Restricted Domain: @{term compose}*}
    84 
    85 lemma funcset_compose:
    86     "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
    87   by (simp add: Pi_def compose_def restrict_def)
    88 
    89 lemma compose_assoc:
    90     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
    91       ==> compose A h (compose A g f) = compose A (compose B h g) f"
    92   by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
    93 
    94 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
    95   by (simp add: compose_def restrict_def)
    96 
    97 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
    98   by (auto simp add: image_def compose_eq)
    99 
   100 lemma inj_on_compose:
   101     "[| f ` A = B; inj_on f A; inj_on g B |] ==> inj_on (compose A g f) A"
   102   by (auto simp add: inj_on_def compose_eq)
   103 
   104 
   105 subsection{*Bounded Abstraction: @{term restrict}*}
   106 
   107 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   108   by (simp add: Pi_def restrict_def)
   109 
   110 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   111   by (simp add: Pi_def restrict_def)
   112 
   113 lemma restrict_apply [simp]:
   114     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else arbitrary)"
   115   by (simp add: restrict_def)
   116 
   117 lemma restrict_ext:
   118     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   119   by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   120 
   121 lemma inj_on_restrict_eq: "inj_on (restrict f A) A = inj_on f A"
   122   by (simp add: inj_on_def restrict_def)
   123 
   124 lemma Id_compose:
   125     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   126   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   127 
   128 lemma compose_Id:
   129     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   130   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   131 
   132 
   133 subsection{*Extensionality*}
   134 
   135 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = arbitrary"
   136   by (simp add: extensional_def)
   137 
   138 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   139   by (simp add: restrict_def extensional_def)
   140 
   141 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   142   by (simp add: compose_def)
   143 
   144 lemma extensionalityI:
   145     "[| f \<in> extensional A; g \<in> extensional A;
   146       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   147   by (force simp add: expand_fun_eq extensional_def)
   148 
   149 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   150   by (unfold Inv_def) (fast intro: restrict_in_funcset someI2)
   151 
   152 lemma compose_Inv_id:
   153     "[| inj_on f A;  f ` A = B |]
   154       ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   155   apply (simp add: compose_def)
   156   apply (rule restrict_ext, auto)
   157   apply (erule subst)
   158   apply (simp add: Inv_f_f)
   159   done
   160 
   161 lemma compose_id_Inv:
   162     "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   163   apply (simp add: compose_def)
   164   apply (rule restrict_ext)
   165   apply (simp add: f_Inv_f)
   166   done
   167 
   168 end