src/HOL/Power.thy
author paulson
Fri Jan 09 10:46:18 2004 +0100 (2004-01-09)
changeset 14348 744c868ee0b7
parent 8844 db71c334e854
child 14353 79f9fbef9106
permissions -rw-r--r--
Defining the type class "ringpower" and deleting superseded theorems for
types nat, int, real, hypreal
     1 (*  Title:      HOL/Power.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1997  University of Cambridge
     5 
     6 *)
     7 
     8 header{*Exponentiation and Binomial Coefficients*}
     9 
    10 theory Power = Divides:
    11 
    12 subsection{*Powers for Arbitrary (Semi)Rings*}
    13 
    14 axclass ringpower \<subseteq> semiring, power
    15   power_0 [simp]:   "a ^ 0       = 1"
    16   power_Suc: "a ^ (Suc n) = a * (a ^ n)"
    17 
    18 lemma power_0_Suc [simp]: "(0::'a::ringpower) ^ (Suc n) = 0"
    19 by (simp add: power_Suc)
    20 
    21 text{*It looks plausible as a simprule, but its effect can be strange.*}
    22 lemma power_0_left: "0^n = (if n=0 then 1 else (0::'a::ringpower))"
    23 by (induct_tac "n", auto)
    24 
    25 lemma power_one [simp]: "1^n = (1::'a::ringpower)"
    26 apply (induct_tac "n")
    27 apply (auto simp add: power_Suc)  
    28 done
    29 
    30 lemma power_one_right [simp]: "(a::'a::ringpower) ^ 1 = a"
    31 by (simp add: power_Suc)
    32 
    33 lemma power_add: "(a::'a::ringpower) ^ (m+n) = (a^m) * (a^n)"
    34 apply (induct_tac "n")
    35 apply (simp_all add: power_Suc mult_ac)
    36 done
    37 
    38 lemma power_mult: "(a::'a::ringpower) ^ (m*n) = (a^m) ^ n"
    39 apply (induct_tac "n")
    40 apply (simp_all add: power_Suc power_add)
    41 done
    42 
    43 lemma power_mult_distrib: "((a::'a::ringpower) * b) ^ n = (a^n) * (b^n)"
    44 apply (induct_tac "n") 
    45 apply (auto simp add: power_Suc mult_ac)
    46 done
    47 
    48 lemma zero_less_power:
    49      "0 < (a::'a::{ordered_semiring,ringpower}) ==> 0 < a^n"
    50 apply (induct_tac "n")
    51 apply (simp_all add: power_Suc zero_less_one mult_pos)
    52 done
    53 
    54 lemma zero_le_power:
    55      "0 \<le> (a::'a::{ordered_semiring,ringpower}) ==> 0 \<le> a^n"
    56 apply (simp add: order_le_less)
    57 apply (erule disjE) 
    58 apply (simp_all add: zero_less_power zero_less_one power_0_left)
    59 done
    60 
    61 lemma one_le_power:
    62      "1 \<le> (a::'a::{ordered_semiring,ringpower}) ==> 1 \<le> a^n"
    63 apply (induct_tac "n")
    64 apply (simp_all add: power_Suc)
    65 apply (rule order_trans [OF _ mult_mono [of 1 _ 1]]) 
    66 apply (simp_all add: zero_le_one order_trans [OF zero_le_one]) 
    67 done
    68 
    69 lemma gt1_imp_ge0: "1 < a ==> 0 \<le> (a::'a::ordered_semiring)"
    70   by (simp add: order_trans [OF zero_le_one order_less_imp_le])
    71 
    72 lemma power_gt1_lemma:
    73      assumes gt1: "1 < (a::'a::{ordered_semiring,ringpower})"
    74         shows     "1 < a * a^n"
    75 proof -
    76   have "1*1 < a * a^n"
    77     proof (rule order_less_le_trans) 
    78       show "1*1 < a*1" by (simp add: gt1)
    79       show  "a*1 \<le> a * a^n"
    80    by (simp only: mult_mono gt1 gt1_imp_ge0 one_le_power order_less_imp_le 
    81                   zero_le_one order_refl)
    82     qed
    83   thus ?thesis by simp
    84 qed
    85 
    86 lemma power_gt1:
    87      "1 < (a::'a::{ordered_semiring,ringpower}) ==> 1 < a ^ (Suc n)"
    88 by (simp add: power_gt1_lemma power_Suc)
    89 
    90 lemma power_le_imp_le_exp:
    91      assumes gt1: "(1::'a::{ringpower,ordered_semiring}) < a"
    92        shows      "!!n. a^m \<le> a^n ==> m \<le> n"
    93 proof (induct "m")
    94   case 0
    95     show ?case by simp
    96 next
    97   case (Suc m)
    98     show ?case 
    99       proof (cases n)
   100         case 0
   101           from prems have "a * a^m \<le> 1" by (simp add: power_Suc)
   102           with gt1 show ?thesis
   103             by (force simp only: power_gt1_lemma 
   104                                  linorder_not_less [symmetric])
   105       next
   106         case (Suc n)
   107           from prems show ?thesis 
   108 	    by (force dest: mult_left_le_imp_le
   109 	          simp add: power_Suc order_less_trans [OF zero_less_one gt1]) 
   110       qed
   111 qed
   112 
   113 text{*Surely we can strengthen this? It holds for 0<a<1 too.*}
   114 lemma power_inject_exp [simp]:
   115      "1 < (a::'a::{ordered_semiring,ringpower}) ==> (a^m = a^n) = (m=n)"
   116   by (force simp add: order_antisym power_le_imp_le_exp)  
   117 
   118 text{*Can relax the first premise to @{term "0<a"} in the case of the
   119 natural numbers.*}
   120 lemma power_less_imp_less_exp:
   121      "[| (1::'a::{ringpower,ordered_semiring}) < a; a^m < a^n |] ==> m < n"
   122 by (simp add: order_less_le [of m n] order_less_le [of "a^m" "a^n"] 
   123               power_le_imp_le_exp) 
   124 
   125 
   126 lemma power_mono:
   127      "[|a \<le> b; (0::'a::{ringpower,ordered_semiring}) \<le> a|] ==> a^n \<le> b^n"
   128 apply (induct_tac "n") 
   129 apply (simp_all add: power_Suc)
   130 apply (auto intro: mult_mono zero_le_power order_trans [of 0 a b])
   131 done
   132 
   133 lemma power_strict_mono [rule_format]:
   134      "[|a < b; (0::'a::{ringpower,ordered_semiring}) \<le> a|] 
   135       ==> 0 < n --> a^n < b^n" 
   136 apply (induct_tac "n") 
   137 apply (auto simp add: mult_strict_mono zero_le_power power_Suc
   138                       order_le_less_trans [of 0 a b])
   139 done
   140 
   141 lemma power_eq_0_iff [simp]:
   142      "(a^n = 0) = (a = (0::'a::{ordered_ring,ringpower}) & 0<n)"
   143 apply (induct_tac "n")
   144 apply (auto simp add: power_Suc zero_neq_one [THEN not_sym])
   145 done
   146 
   147 lemma field_power_eq_0_iff [simp]:
   148      "(a^n = 0) = (a = (0::'a::{field,ringpower}) & 0<n)"
   149 apply (induct_tac "n")
   150 apply (auto simp add: power_Suc field_mult_eq_0_iff zero_neq_one[THEN not_sym])
   151 done
   152 
   153 lemma field_power_not_zero: "a \<noteq> (0::'a::{field,ringpower}) ==> a^n \<noteq> 0"
   154 by force
   155 
   156 text{*Perhaps these should be simprules.*}
   157 lemma power_inverse:
   158   "inverse ((a::'a::{field,division_by_zero,ringpower}) ^ n) = (inverse a) ^ n"
   159 apply (induct_tac "n")
   160 apply (auto simp add: power_Suc inverse_mult_distrib)
   161 done
   162 
   163 lemma power_abs: "abs(a ^ n) = abs(a::'a::{ordered_field,ringpower}) ^ n"
   164 apply (induct_tac "n")
   165 apply (auto simp add: power_Suc abs_mult)
   166 done
   167 
   168 lemma power_minus: "(-a) ^ n = (- 1)^n * (a::'a::{ring,ringpower}) ^ n"
   169 proof -
   170   have "-a = (- 1) * a"  by (simp add: minus_mult_left [symmetric])
   171   thus ?thesis by (simp only: power_mult_distrib)
   172 qed
   173 
   174 text{*Lemma for @{text power_strict_decreasing}*}
   175 lemma power_Suc_less:
   176      "[|(0::'a::{ordered_semiring,ringpower}) < a; a < 1|]
   177       ==> a * a^n < a^n"
   178 apply (induct_tac n) 
   179 apply (auto simp add: power_Suc mult_strict_left_mono) 
   180 done
   181 
   182 lemma power_strict_decreasing:
   183      "[|n < N; 0 < a; a < (1::'a::{ordered_semiring,ringpower})|]
   184       ==> a^N < a^n"
   185 apply (erule rev_mp) 
   186 apply (induct_tac "N")  
   187 apply (auto simp add: power_Suc power_Suc_less less_Suc_eq) 
   188 apply (rename_tac m)  
   189 apply (subgoal_tac "a * a^m < 1 * a^n", simp)
   190 apply (rule mult_strict_mono) 
   191 apply (auto simp add: zero_le_power zero_less_one order_less_imp_le)
   192 done
   193 
   194 text{*Proof resembles that of @{text power_strict_decreasing}*}
   195 lemma power_decreasing:
   196      "[|n \<le> N; 0 \<le> a; a \<le> (1::'a::{ordered_semiring,ringpower})|]
   197       ==> a^N \<le> a^n"
   198 apply (erule rev_mp) 
   199 apply (induct_tac "N") 
   200 apply (auto simp add: power_Suc  le_Suc_eq) 
   201 apply (rename_tac m)  
   202 apply (subgoal_tac "a * a^m \<le> 1 * a^n", simp)
   203 apply (rule mult_mono) 
   204 apply (auto simp add: zero_le_power zero_le_one)
   205 done
   206 
   207 lemma power_Suc_less_one:
   208      "[| 0 < a; a < (1::'a::{ordered_semiring,ringpower}) |] ==> a ^ Suc n < 1"
   209 apply (insert power_strict_decreasing [of 0 "Suc n" a], simp) 
   210 done
   211 
   212 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   213 lemma power_increasing:
   214      "[|n \<le> N; (1::'a::{ordered_semiring,ringpower}) \<le> a|] ==> a^n \<le> a^N"
   215 apply (erule rev_mp) 
   216 apply (induct_tac "N") 
   217 apply (auto simp add: power_Suc le_Suc_eq) 
   218 apply (rename_tac m)
   219 apply (subgoal_tac "1 * a^n \<le> a * a^m", simp)
   220 apply (rule mult_mono) 
   221 apply (auto simp add: order_trans [OF zero_le_one] zero_le_power)
   222 done
   223 
   224 text{*Lemma for @{text power_strict_increasing}*}
   225 lemma power_less_power_Suc:
   226      "(1::'a::{ordered_semiring,ringpower}) < a ==> a^n < a * a^n"
   227 apply (induct_tac n) 
   228 apply (auto simp add: power_Suc mult_strict_left_mono order_less_trans [OF zero_less_one]) 
   229 done
   230 
   231 lemma power_strict_increasing:
   232      "[|n < N; (1::'a::{ordered_semiring,ringpower}) < a|] ==> a^n < a^N"
   233 apply (erule rev_mp) 
   234 apply (induct_tac "N")  
   235 apply (auto simp add: power_less_power_Suc power_Suc less_Suc_eq) 
   236 apply (rename_tac m)
   237 apply (subgoal_tac "1 * a^n < a * a^m", simp)
   238 apply (rule mult_strict_mono)  
   239 apply (auto simp add: order_less_trans [OF zero_less_one] zero_le_power
   240                  order_less_imp_le)
   241 done
   242 
   243 lemma power_le_imp_le_base:
   244   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   245       and xnonneg: "(0::'a::{ordered_semiring,ringpower}) \<le> a"
   246       and ynonneg: "0 \<le> b"
   247   shows "a \<le> b"
   248  proof (rule ccontr)
   249    assume "~ a \<le> b"
   250    then have "b < a" by (simp only: linorder_not_le)
   251    then have "b ^ Suc n < a ^ Suc n"
   252      by (simp only: prems power_strict_mono) 
   253    from le and this show "False"
   254       by (simp add: linorder_not_less [symmetric])
   255  qed
   256   
   257 lemma power_inject_base:
   258      "[| a ^ Suc n = b ^ Suc n; 0 \<le> a; 0 \<le> b |] 
   259       ==> a = (b::'a::{ordered_semiring,ringpower})"
   260 by (blast intro: power_le_imp_le_base order_antisym order_eq_refl sym)
   261 
   262 
   263 subsection{*Exponentiation for the Natural Numbers*}
   264 
   265 primrec (power)
   266   "p ^ 0 = 1"
   267   "p ^ (Suc n) = (p::nat) * (p ^ n)"
   268   
   269 instance nat :: ringpower
   270 proof
   271   fix z :: nat
   272   fix n :: nat
   273   show "z^0 = 1" by simp
   274   show "z^(Suc n) = z * (z^n)" by simp
   275 qed
   276 
   277 lemma nat_one_le_power [simp]: "1 \<le> i ==> Suc 0 \<le> i^n"
   278 by (insert one_le_power [of i n], simp)
   279 
   280 lemma le_imp_power_dvd: "!!i::nat. m \<le> n ==> i^m dvd i^n"
   281 apply (unfold dvd_def)
   282 apply (erule not_less_iff_le [THEN iffD2, THEN add_diff_inverse, THEN subst])
   283 apply (simp add: power_add)
   284 done
   285 
   286 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   287 Premises cannot be weakened: consider the case where @{term "i=0"},
   288 @{term "m=1"} and @{term "n=0"}.*}
   289 lemma nat_power_less_imp_less: "!!i::nat. [| 0 < i; i^m < i^n |] ==> m < n"
   290 apply (rule ccontr)
   291 apply (drule leI [THEN le_imp_power_dvd, THEN dvd_imp_le, THEN leD])
   292 apply (erule zero_less_power, auto) 
   293 done
   294 
   295 lemma nat_zero_less_power_iff [simp]: "(0 < x^n) = (x \<noteq> (0::nat) | n=0)"
   296 by (induct_tac "n", auto)
   297 
   298 lemma power_le_dvd [rule_format]: "k^j dvd n --> i\<le>j --> k^i dvd (n::nat)"
   299 apply (induct_tac "j")
   300 apply (simp_all add: le_Suc_eq)
   301 apply (blast dest!: dvd_mult_right)
   302 done
   303 
   304 lemma power_dvd_imp_le: "[|i^m dvd i^n;  (1::nat) < i|] ==> m \<le> n"
   305 apply (rule power_le_imp_le_exp, assumption)
   306 apply (erule dvd_imp_le, simp)
   307 done
   308 
   309 
   310 subsection{*Binomial Coefficients*}
   311 
   312 text{*This development is based on the work of Andy Gordon and 
   313 Florian Kammueller*}
   314 
   315 consts
   316   binomial :: "[nat,nat] => nat"      (infixl "choose" 65)
   317 
   318 primrec
   319   binomial_0:   "(0     choose k) = (if k = 0 then 1 else 0)"
   320 
   321   binomial_Suc: "(Suc n choose k) =
   322                  (if k = 0 then 1 else (n choose (k - 1)) + (n choose k))"
   323 
   324 lemma binomial_n_0 [simp]: "(n choose 0) = 1"
   325 by (case_tac "n", simp_all)
   326 
   327 lemma binomial_0_Suc [simp]: "(0 choose Suc k) = 0"
   328 by simp
   329 
   330 lemma binomial_Suc_Suc [simp]:
   331      "(Suc n choose Suc k) = (n choose k) + (n choose Suc k)"
   332 by simp
   333 
   334 lemma binomial_eq_0 [rule_format]: "\<forall>k. n < k --> (n choose k) = 0"
   335 apply (induct_tac "n", auto)
   336 apply (erule allE)
   337 apply (erule mp, arith)
   338 done
   339 
   340 declare binomial_0 [simp del] binomial_Suc [simp del]
   341 
   342 lemma binomial_n_n [simp]: "(n choose n) = 1"
   343 apply (induct_tac "n")
   344 apply (simp_all add: binomial_eq_0)
   345 done
   346 
   347 lemma binomial_Suc_n [simp]: "(Suc n choose n) = Suc n"
   348 by (induct_tac "n", simp_all)
   349 
   350 lemma binomial_1 [simp]: "(n choose Suc 0) = n"
   351 by (induct_tac "n", simp_all)
   352 
   353 lemma zero_less_binomial [rule_format]: "k \<le> n --> 0 < (n choose k)"
   354 by (rule_tac m = n and n = k in diff_induct, simp_all)
   355 
   356 lemma binomial_eq_0_iff: "(n choose k = 0) = (n<k)"
   357 apply (safe intro!: binomial_eq_0)
   358 apply (erule contrapos_pp)
   359 apply (simp add: zero_less_binomial)
   360 done
   361 
   362 lemma zero_less_binomial_iff: "(0 < n choose k) = (k\<le>n)"
   363 by (simp add: linorder_not_less [symmetric] binomial_eq_0_iff [symmetric])
   364 
   365 (*Might be more useful if re-oriented*)
   366 lemma Suc_times_binomial_eq [rule_format]:
   367      "\<forall>k. k \<le> n --> Suc n * (n choose k) = (Suc n choose Suc k) * Suc k"
   368 apply (induct_tac "n")
   369 apply (simp add: binomial_0, clarify)
   370 apply (case_tac "k")
   371 apply (auto simp add: add_mult_distrib add_mult_distrib2 le_Suc_eq 
   372                       binomial_eq_0)
   373 done
   374 
   375 text{*This is the well-known version, but it's harder to use because of the
   376   need to reason about division.*}
   377 lemma binomial_Suc_Suc_eq_times:
   378      "k \<le> n ==> (Suc n choose Suc k) = (Suc n * (n choose k)) div Suc k"
   379 by (simp add: Suc_times_binomial_eq div_mult_self_is_m zero_less_Suc 
   380         del: mult_Suc mult_Suc_right)
   381 
   382 text{*Another version, with -1 instead of Suc.*}
   383 lemma times_binomial_minus1_eq:
   384      "[|k \<le> n;  0<k|] ==> (n choose k) * k = n * ((n - 1) choose (k - 1))"
   385 apply (cut_tac n = "n - 1" and k = "k - 1" in Suc_times_binomial_eq)
   386 apply (simp split add: nat_diff_split, auto)
   387 done
   388 
   389 text{*ML bindings for the general exponentiation theorems*}
   390 ML
   391 {*
   392 val power_0 = thm"power_0";
   393 val power_Suc = thm"power_Suc";
   394 val power_0_Suc = thm"power_0_Suc";
   395 val power_0_left = thm"power_0_left";
   396 val power_one = thm"power_one";
   397 val power_one_right = thm"power_one_right";
   398 val power_add = thm"power_add";
   399 val power_mult = thm"power_mult";
   400 val power_mult_distrib = thm"power_mult_distrib";
   401 val zero_less_power = thm"zero_less_power";
   402 val zero_le_power = thm"zero_le_power";
   403 val one_le_power = thm"one_le_power";
   404 val gt1_imp_ge0 = thm"gt1_imp_ge0";
   405 val power_gt1_lemma = thm"power_gt1_lemma";
   406 val power_gt1 = thm"power_gt1";
   407 val power_le_imp_le_exp = thm"power_le_imp_le_exp";
   408 val power_inject_exp = thm"power_inject_exp";
   409 val power_less_imp_less_exp = thm"power_less_imp_less_exp";
   410 val power_mono = thm"power_mono";
   411 val power_strict_mono = thm"power_strict_mono";
   412 val power_eq_0_iff = thm"power_eq_0_iff";
   413 val field_power_eq_0_iff = thm"field_power_eq_0_iff";
   414 val field_power_not_zero = thm"field_power_not_zero";
   415 val power_inverse = thm"power_inverse";
   416 val power_abs = thm"power_abs";
   417 val power_minus = thm"power_minus";
   418 val power_Suc_less = thm"power_Suc_less";
   419 val power_strict_decreasing = thm"power_strict_decreasing";
   420 val power_decreasing = thm"power_decreasing";
   421 val power_Suc_less_one = thm"power_Suc_less_one";
   422 val power_increasing = thm"power_increasing";
   423 val power_strict_increasing = thm"power_strict_increasing";
   424 val power_le_imp_le_base = thm"power_le_imp_le_base";
   425 val power_inject_base = thm"power_inject_base";
   426 *}
   427  
   428 text{*ML bindings for the remaining theorems*}
   429 ML
   430 {*
   431 val nat_one_le_power = thm"nat_one_le_power";
   432 val le_imp_power_dvd = thm"le_imp_power_dvd";
   433 val nat_power_less_imp_less = thm"nat_power_less_imp_less";
   434 val nat_zero_less_power_iff = thm"nat_zero_less_power_iff";
   435 val power_le_dvd = thm"power_le_dvd";
   436 val power_dvd_imp_le = thm"power_dvd_imp_le";
   437 val binomial_n_0 = thm"binomial_n_0";
   438 val binomial_0_Suc = thm"binomial_0_Suc";
   439 val binomial_Suc_Suc = thm"binomial_Suc_Suc";
   440 val binomial_eq_0 = thm"binomial_eq_0";
   441 val binomial_n_n = thm"binomial_n_n";
   442 val binomial_Suc_n = thm"binomial_Suc_n";
   443 val binomial_1 = thm"binomial_1";
   444 val zero_less_binomial = thm"zero_less_binomial";
   445 val binomial_eq_0_iff = thm"binomial_eq_0_iff";
   446 val zero_less_binomial_iff = thm"zero_less_binomial_iff";
   447 val Suc_times_binomial_eq = thm"Suc_times_binomial_eq";
   448 val binomial_Suc_Suc_eq_times = thm"binomial_Suc_Suc_eq_times";
   449 val times_binomial_minus1_eq = thm"times_binomial_minus1_eq";
   450 *}
   451 
   452 end
   453