src/Pure/sign.ML
author wenzelm
Sun Dec 28 14:58:56 1997 +0100 (1997-12-28)
changeset 4489 749600cb5573
parent 4344 e000b5db4087
child 4568 7be03035c553
permissions -rw-r--r--
renamed Symtab.null to Symtab.empty;
renamed Symtan.extend_new to Symtab.extend;
renamed Symtan.DUPLICATE to Symtab.DUP;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 (*base names*)
     9 type bstring = string;
    10 type bclass = class;
    11 (*external forms -- partially qualified names*)
    12 type xstring = string;
    13 type xclass = class;
    14 type xsort = sort;
    15 type xtyp = typ;
    16 type xterm = term;
    17 
    18 signature SIGN =
    19 sig
    20   type sg
    21   type sg_ref
    22   type data
    23   val rep_sg: sg ->
    24    {self: sg_ref,
    25     tsig: Type.type_sig,
    26     const_tab: typ Symtab.table,
    27     syn: Syntax.syntax,
    28     path: string list,
    29     spaces: (string * NameSpace.T) list,
    30     data: data}
    31   val name_of: sg -> string
    32   val stamp_names_of: sg -> string list
    33   val tsig_of: sg -> Type.type_sig
    34   val deref: sg_ref -> sg
    35   val self_ref: sg -> sg_ref
    36   val subsig: sg * sg -> bool
    37   val eq_sg: sg * sg -> bool
    38   val same_sg: sg * sg -> bool
    39   val is_draft: sg -> bool
    40   val const_type: sg -> string -> typ option
    41   val classes: sg -> class list
    42   val subsort: sg -> sort * sort -> bool
    43   val nodup_Vars: term -> unit
    44   val norm_sort: sg -> sort -> sort
    45   val nonempty_sort: sg -> sort list -> sort -> bool
    46   val long_names: bool ref
    47   val classK: string
    48   val typeK: string
    49   val constK: string
    50   val full_name: sg -> bstring -> string
    51   val base_name: string -> bstring
    52   val intern: sg -> string -> xstring -> string
    53   val extern: sg -> string -> string -> xstring
    54   val cond_extern: sg -> string -> string -> xstring
    55   val intern_class: sg -> xclass -> class
    56   val intern_tycon: sg -> xstring -> string
    57   val intern_const: sg -> xstring -> string
    58   val intern_sort: sg -> xsort -> sort
    59   val intern_typ: sg -> xtyp -> typ
    60   val intern_term: sg -> xterm -> term
    61   val intern_tycons: sg -> xtyp -> typ
    62   val pretty_sg: sg -> Pretty.T
    63   val str_of_sg: sg -> string
    64   val pprint_sg: sg -> pprint_args -> unit
    65   val pretty_term: sg -> term -> Pretty.T
    66   val pretty_typ: sg -> typ -> Pretty.T
    67   val pretty_sort: sg -> sort -> Pretty.T
    68   val pretty_classrel: sg -> class * class -> Pretty.T
    69   val pretty_arity: sg -> string * sort list * sort -> Pretty.T
    70   val string_of_term: sg -> term -> string
    71   val string_of_typ: sg -> typ -> string
    72   val string_of_sort: sg -> sort -> string
    73   val str_of_sort: sg -> sort -> string
    74   val str_of_classrel: sg -> class * class -> string
    75   val str_of_arity: sg -> string * sort list * sort -> string
    76   val pprint_term: sg -> term -> pprint_args -> unit
    77   val pprint_typ: sg -> typ -> pprint_args -> unit
    78   val certify_typ: sg -> typ -> typ
    79   val certify_term: sg -> term -> term * typ * int
    80   val read_raw_typ: sg * (indexname -> sort option) -> string -> typ
    81   val read_typ: sg * (indexname -> sort option) -> string -> typ
    82   val infer_types: sg -> (indexname -> typ option) ->
    83     (indexname -> sort option) -> string list -> bool
    84     -> xterm list * typ -> term * (indexname * typ) list
    85   val infer_types_simult: sg -> (indexname -> typ option) ->
    86     (indexname -> sort option) -> string list -> bool
    87     -> (xterm list * typ) list -> term list * (indexname * typ) list
    88   val add_classes: (bclass * xclass list) list -> sg -> sg
    89   val add_classes_i: (bclass * class list) list -> sg -> sg
    90   val add_classrel: (xclass * xclass) list -> sg -> sg
    91   val add_classrel_i: (class * class) list -> sg -> sg
    92   val add_defsort: xsort -> sg -> sg
    93   val add_defsort_i: sort -> sg -> sg
    94   val add_types: (bstring * int * mixfix) list -> sg -> sg
    95   val add_tyabbrs: (bstring * string list * string * mixfix) list -> sg -> sg
    96   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> sg -> sg
    97   val add_arities: (xstring * xsort list * xsort) list -> sg -> sg
    98   val add_arities_i: (string * sort list * sort) list -> sg -> sg
    99   val add_consts: (bstring * string * mixfix) list -> sg -> sg
   100   val add_consts_i: (bstring * typ * mixfix) list -> sg -> sg
   101   val add_syntax: (bstring * string * mixfix) list -> sg -> sg
   102   val add_syntax_i: (bstring * typ * mixfix) list -> sg -> sg
   103   val add_modesyntax: (string * bool) * (bstring * string * mixfix) list -> sg -> sg
   104   val add_modesyntax_i: (string * bool) * (bstring * typ * mixfix) list -> sg -> sg
   105   val add_trfuns:
   106     (string * (ast list -> ast)) list *
   107     (string * (term list -> term)) list *
   108     (string * (term list -> term)) list *
   109     (string * (ast list -> ast)) list -> sg -> sg
   110   val add_trfunsT:
   111     (string * (bool -> typ -> term list -> term)) list -> sg -> sg
   112   val add_tokentrfuns:
   113     (string * string * (string -> string * int)) list -> sg -> sg
   114   val add_trrules: (string * string) Syntax.trrule list -> sg -> sg
   115   val add_trrules_i: ast Syntax.trrule list -> sg -> sg
   116   val add_path: string -> sg -> sg
   117   val add_space: string * string list -> sg -> sg
   118   val add_name: string -> sg -> sg
   119   val data_kinds: data -> string list
   120   val init_data: string * (object * (object -> object) *
   121     (object * object -> object) * (sg -> object -> unit)) -> sg -> sg
   122   val get_data: sg -> string -> object
   123   val put_data: string * object -> sg -> sg
   124   val print_data: sg -> string -> unit
   125   val merge_refs: sg_ref * sg_ref -> sg_ref
   126   val prep_ext: sg -> sg
   127   val merge: sg * sg -> sg
   128   val pre_pure: sg
   129   val const_of_class: class -> string
   130   val class_of_const: string -> class
   131 end;
   132 
   133 structure Sign: SIGN =
   134 struct
   135 
   136 
   137 (** datatype sg **)
   138 
   139 (* types sg, data, sg_ref *)
   140 
   141 datatype sg =
   142   Sg of
   143    {id: string ref,                             (*id*)
   144     stamps: string ref list} *                  (*unique theory indentifier*)
   145    {self: sg_ref,                               (*mutable self reference*)
   146     tsig: Type.type_sig,                        (*order-sorted signature of types*)
   147     const_tab: typ Symtab.table,                (*type schemes of constants*)
   148     syn: Syntax.syntax,                         (*syntax for parsing and printing*)
   149     path: string list,                          (*current name space entry prefix*)
   150     spaces: (string * NameSpace.T) list,        (*name spaces for consts, types etc.*)
   151     data: data}                                 (*anytype data*)
   152 and data =
   153   Data of
   154     (object *                             	(*value*)
   155      ((object -> object) *                	(*prepare extend method*)
   156       (object * object -> object) *       	(*merge and prepare extend method*)
   157       (sg -> object -> unit)))                 	(*print method*)
   158     Symtab.table
   159 and sg_ref =
   160   SgRef of sg ref option
   161 
   162 (*make signature*)
   163 fun make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps) =
   164   Sg ({id = id, stamps = stamps}, {self = self, tsig = tsig, const_tab = const_tab,
   165     syn = syn, path = path, spaces = spaces, data = data});
   166 
   167 
   168 (* basic operations *)
   169 
   170 fun rep_sg (Sg (_, args)) = args;
   171 
   172 (*show stamps*)
   173 fun stamp_names_of (Sg ({stamps, ...}, _)) = rev (map ! stamps);
   174 fun pretty_sg sg = Pretty.str_list "{" "}" (stamp_names_of sg);
   175 val str_of_sg = Pretty.str_of o pretty_sg;
   176 val pprint_sg = Pretty.pprint o pretty_sg;
   177 
   178 val tsig_of = #tsig o rep_sg;
   179 
   180 fun const_type (Sg (_, {const_tab, ...})) c = Symtab.lookup (const_tab, c);
   181 val classes = #classes o Type.rep_tsig o tsig_of;
   182 
   183 val subsort = Type.subsort o tsig_of;
   184 val norm_sort = Type.norm_sort o tsig_of;
   185 val nonempty_sort = Type.nonempty_sort o tsig_of;
   186 
   187 
   188 (* id and self *)
   189 
   190 fun check_stale (sg as Sg ({id, ...},
   191         {self = SgRef (Some (ref (Sg ({id = id', ...}, _)))), ...})) =
   192       if id = id' then sg
   193       else raise TERM ("Stale signature: " ^ str_of_sg sg, [])
   194   | check_stale _ = sys_error "Sign.check_stale";
   195 
   196 fun self_ref (sg as Sg (_, {self, ...})) = (check_stale sg; self);
   197 
   198 fun deref (SgRef (Some (ref sg))) = sg
   199   | deref (SgRef None) = sys_error "Sign.deref";
   200 
   201 fun name_of (sg as Sg ({id = ref name, ...}, _)) =
   202   if name = "" orelse name = "#" then
   203     raise TERM ("Nameless signature " ^ str_of_sg sg, [])
   204   else name;
   205 
   206 
   207 (* inclusion and equality *)
   208 
   209 local
   210   (*avoiding polymorphic equality: factor 10 speedup*)
   211   fun mem_stamp (_:string ref, []) = false
   212     | mem_stamp (x, y :: ys) = x = y orelse mem_stamp (x, ys);
   213 
   214   fun subset_stamp ([], ys) = true
   215     | subset_stamp (x :: xs, ys) =
   216         mem_stamp (x, ys) andalso subset_stamp (xs, ys);
   217 
   218   (*fast partial test*)
   219   fun fast_sub ([]: string ref list, _) = true
   220     | fast_sub (_, []) = false
   221     | fast_sub (x :: xs, y :: ys) =
   222         if x = y then fast_sub (xs, ys)
   223         else fast_sub (x :: xs, ys);
   224 in
   225   fun eq_sg (sg1 as Sg ({id = id1, ...}, _), sg2 as Sg ({id = id2, ...}, _)) =
   226     (check_stale sg1; check_stale sg2; id1 = id2);
   227 
   228   fun subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   229     eq_sg (sg1, sg2) orelse subset_stamp (s1, s2);
   230 
   231   fun fast_subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   232     eq_sg (sg1, sg2) orelse fast_sub (s1, s2);
   233 end;
   234 
   235 
   236 (*test if same theory names are contained in signatures' stamps,
   237   i.e. if signatures belong to same theory but not necessarily to the
   238   same version of it*)
   239 fun same_sg (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   240   eq_sg (sg1, sg2) orelse eq_set_string (pairself (map (op !)) (s1, s2));
   241 
   242 (*test for drafts*)
   243 fun is_draft (Sg ({stamps = ref "#" :: _, ...}, _)) = true
   244   | is_draft _ = false;
   245 
   246 
   247 
   248 (** signature data **)
   249 
   250 (* errors *)
   251 
   252 fun of_theory sg = "\nof theory " ^ str_of_sg sg;
   253 
   254 fun err_method name kind =
   255   error ("Error while invoking " ^ quote kind ^ " method " ^ name);
   256 
   257 fun err_dup_init sg kind =
   258   error ("Duplicate initialization of " ^ quote kind ^ " data" ^ of_theory sg);
   259 
   260 fun err_uninit sg kind =
   261   error ("Tried to access uninitialized " ^ quote kind ^ " data" ^ of_theory sg);
   262 
   263 
   264 (* prepare data *)
   265 
   266 val empty_data = Data Symtab.empty;
   267 
   268 fun merge_data (Data tab1, Data tab2) =
   269   let
   270     val data1 = Symtab.dest tab1;
   271     val data2 = Symtab.dest tab2;
   272     val all_data = data1 @ data2;
   273     val kinds = distinct (map fst all_data);
   274 
   275    fun entry data kind =
   276      (case assoc (data, kind) of
   277        None => []
   278      | Some x => [(kind, x)]);
   279 
   280     fun merge_entries [(kind, (e, mths as (ext, _, _)))] =
   281           (kind, (ext e handle _ => err_method "prep_ext" kind, mths))
   282       | merge_entries [(kind, (e1, mths as (_, mrg, _))), (_, (e2, _))] =
   283           (kind, (mrg (e1, e2) handle _ => err_method "merge" kind, mths))
   284       | merge_entries _ = sys_error "merge_entries";
   285 
   286     val data = map (fn k => merge_entries (entry data1 k @ entry data2 k)) kinds;
   287   in Data (Symtab.make data) end;
   288 
   289 fun prep_ext_data data = merge_data (data, empty_data);
   290 
   291 fun init_data_sg sg (Data tab) kind e ext mrg prt =
   292   Data (Symtab.update_new ((kind, (e, (ext, mrg, prt))), tab))
   293     handle Symtab.DUP _ => err_dup_init sg kind;
   294 
   295 
   296 (* access data *)
   297 
   298 fun data_kinds (Data tab) = map fst (Symtab.dest tab);
   299 
   300 fun lookup_data sg tab kind =
   301   (case Symtab.lookup (tab, kind) of
   302     Some x => x
   303   | None => err_uninit sg kind);
   304 
   305 fun get_data (sg as Sg (_, {data = Data tab, ...})) kind =
   306   fst (lookup_data sg tab kind);
   307 
   308 fun print_data (sg as Sg (_, {data = Data tab, ...})) kind =
   309   let val (e, (_, _, prt)) = lookup_data sg tab kind
   310   in prt sg e handle _ => err_method ("print" ^ of_theory sg) kind end;
   311 
   312 fun put_data_sg sg (Data tab) kind e =
   313   Data (Symtab.update ((kind, (e, snd (lookup_data sg tab kind))), tab));
   314 
   315 
   316 
   317 (** build signatures **)
   318 
   319 fun ext_stamps stamps (id as ref name) =
   320   let val stmps = (case stamps of ref "#" :: ss => ss | ss => ss) in
   321     if exists (equal name o !) stmps then
   322       error ("Theory already contains a " ^ quote name ^ " component")
   323     else id :: stmps
   324   end;
   325 
   326 fun create_sign self stamps name (syn, tsig, ctab, (path, spaces), data) =
   327   let
   328     val id = ref name;
   329     val sign =
   330       make_sign (id, self, tsig, ctab, syn, path, spaces, data, ext_stamps stamps id);
   331   in
   332     (case self of
   333       SgRef (Some r) => r := sign
   334     | _ => sys_error "Sign.create_sign");
   335     sign
   336   end;
   337 
   338 fun extend_sign keep extfun name decls
   339     (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
   340   let
   341     val _ = check_stale sg;
   342     val (self', data') =
   343       if is_draft sg andalso keep then (self, data)
   344       else (SgRef (Some (ref sg)), prep_ext_data data);
   345   in
   346     create_sign self' stamps name
   347       (extfun (syn, tsig, const_tab, (path, spaces), data') decls)
   348   end;
   349 
   350 
   351 
   352 (** name spaces **)
   353 
   354 (*prune names on output by default*)
   355 val long_names = ref false;
   356 
   357 
   358 (* kinds *)
   359 
   360 val classK = "class";
   361 val typeK = "type";
   362 val constK = "const";
   363 
   364 
   365 (* add and retrieve names *)
   366 
   367 fun space_of spaces kind =
   368   if_none (assoc (spaces, kind)) NameSpace.empty;
   369 
   370 (*input and output of qualified names*)
   371 fun intrn spaces kind = NameSpace.intern (space_of spaces kind);
   372 fun extrn spaces kind = NameSpace.extern (space_of spaces kind);
   373 
   374 (*add names*)
   375 fun add_names spaces kind names =
   376   let val space' = NameSpace.extend (space_of spaces kind, names) in
   377     overwrite (spaces, (kind, space'))
   378   end;
   379 
   380 (*make full names*)
   381 fun full path name =
   382   if name = "" then error "Attempt to declare empty name \"\""
   383   else if NameSpace.qualified name then
   384     error ("Attempt to declare qualified name " ^ quote name)
   385   else NameSpace.pack (path @ [name]);
   386 
   387 (*base name*)
   388 val base_name = NameSpace.base;
   389 
   390 
   391 (* intern / extern names *)
   392 
   393 local
   394   (*prepare mapping of names*)
   395   fun mapping f add_xs t =
   396     let
   397       fun f' x = let val y = f x in if x = y then None else Some (x, y) end;
   398       val table = mapfilter f' (add_xs (t, []));
   399       fun lookup x = if_none (assoc (table, x)) x;
   400     in lookup end;
   401 
   402   (*intern / extern typ*)
   403   fun trn_typ trn T =
   404     T |> map_typ
   405       (mapping (trn classK) add_typ_classes T)
   406       (mapping (trn typeK) add_typ_tycons T);
   407 
   408   (*intern / extern term*)
   409   fun trn_term trn t =
   410     t |> map_term
   411       (mapping (trn classK) add_term_classes t)
   412       (mapping (trn typeK) add_term_tycons t)
   413       (mapping (trn constK) add_term_consts t);
   414 
   415   val spaces_of = #spaces o rep_sg;
   416 in
   417   fun intrn_class spaces = intrn spaces classK;
   418   fun extrn_class spaces = extrn spaces classK;
   419 
   420   val intrn_sort = map o intrn_class;
   421   val intrn_typ = trn_typ o intrn;
   422   val intrn_term = trn_term o intrn;
   423 
   424   val extrn_sort = map o extrn_class;
   425   val extrn_typ = trn_typ o extrn;
   426   val extrn_term = trn_term o extrn;
   427 
   428   fun intrn_tycons spaces T =
   429     map_typ I (mapping (intrn spaces typeK) add_typ_tycons T) T;
   430 
   431   val intern = intrn o spaces_of;
   432   val extern = extrn o spaces_of;
   433   fun cond_extern sg kind = if ! long_names then I else extern sg kind;
   434 
   435   val intern_class = intrn_class o spaces_of;
   436   val intern_sort = intrn_sort o spaces_of;
   437   val intern_typ = intrn_typ o spaces_of;
   438   val intern_term = intrn_term o spaces_of;
   439 
   440   fun intern_tycon sg = intrn (spaces_of sg) typeK;
   441   fun intern_const sg = intrn (spaces_of sg) constK;
   442 
   443   val intern_tycons = intrn_tycons o spaces_of;
   444 
   445   val full_name = full o #path o rep_sg;
   446 end;
   447 
   448 
   449 
   450 (** pretty printing of terms, types etc. **)
   451 
   452 fun pretty_term (sg as Sg ({stamps, ...}, {syn, spaces, ...})) t =
   453   Syntax.pretty_term syn
   454     (exists (equal "CPure" o !) stamps)
   455     (if ! long_names then t else extrn_term spaces t);
   456 
   457 fun pretty_typ (Sg (_, {syn, spaces, ...})) T =
   458   Syntax.pretty_typ syn
   459     (if ! long_names then T else extrn_typ spaces T);
   460 
   461 fun pretty_sort (Sg (_, {syn, spaces, ...})) S =
   462   Syntax.pretty_sort syn
   463     (if ! long_names then S else extrn_sort spaces S);
   464 
   465 fun pretty_classrel sg (c1, c2) = Pretty.block
   466   [pretty_sort sg [c1], Pretty.str " <", Pretty.brk 1, pretty_sort sg [c2]];
   467 
   468 fun pretty_arity sg (t, Ss, S) =
   469   let
   470     val t' = cond_extern sg typeK t;
   471     val dom =
   472       if null Ss then []
   473       else [Pretty.list "(" ")" (map (pretty_sort sg) Ss), Pretty.brk 1];
   474   in
   475     Pretty.block
   476       ([Pretty.str (t' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort sg S])
   477   end;
   478 
   479 fun string_of_term sg t = Pretty.string_of (pretty_term sg t);
   480 fun string_of_typ sg T = Pretty.string_of (pretty_typ sg T);
   481 fun string_of_sort sg S = Pretty.string_of (pretty_sort sg S);
   482 
   483 fun str_of_sort sg S = Pretty.str_of (pretty_sort sg S);
   484 fun str_of_classrel sg c1_c2 = Pretty.str_of (pretty_classrel sg c1_c2);
   485 fun str_of_arity sg ar = Pretty.str_of (pretty_arity sg ar);
   486 
   487 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   488 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   489 
   490 
   491 
   492 (** read types **)  (*exception ERROR*)
   493 
   494 fun err_in_type s =
   495   error ("The error(s) above occurred in type " ^ quote s);
   496 
   497 fun rd_raw_typ syn tsig spaces def_sort str =
   498   intrn_tycons spaces
   499     (Syntax.read_typ syn (Type.get_sort tsig def_sort (intrn_sort spaces)) str
   500       handle ERROR => err_in_type str);
   501 
   502 fun read_raw_typ (sg as Sg (_, {tsig, syn, spaces, ...}), def_sort) str =
   503   (check_stale sg; rd_raw_typ syn tsig spaces def_sort str);
   504 
   505 (*read and certify typ wrt a signature*)
   506 fun read_typ (sg, def_sort) str =
   507   (Type.cert_typ (tsig_of sg) (read_raw_typ (sg, def_sort) str)
   508       handle TYPE (msg, _, _) => (error_msg msg; err_in_type str));
   509 
   510 
   511 
   512 (** certify types and terms **)   (*exception TYPE*)
   513 
   514 val certify_typ = Type.cert_typ o tsig_of;
   515 
   516 (*check for duplicate TVars with distinct sorts*)
   517 fun nodup_TVars (tvars, T) =
   518   (case T of
   519     Type (_, Ts) => nodup_TVars_list (tvars, Ts)
   520   | TFree _ => tvars
   521   | TVar (v as (a, S)) =>
   522       (case assoc_string_int (tvars, a) of
   523         Some S' =>
   524           if S = S' then tvars
   525           else raise TYPE ("Type variable " ^ Syntax.string_of_vname a ^
   526             " has two distinct sorts", [TVar (a, S'), T], [])
   527       | None => v :: tvars))
   528 (*equivalent to foldl nodup_TVars_list, but 3X faster under Poly/ML*)
   529 and nodup_TVars_list (tvars, []) = tvars
   530   | nodup_TVars_list (tvars, T :: Ts) =
   531       nodup_TVars_list (nodup_TVars (tvars, T), Ts);
   532 
   533 (*check for duplicate Vars with distinct types*)
   534 fun nodup_Vars tm =
   535   let
   536     fun nodups vars tvars tm =
   537       (case tm of
   538         Const (c, T) => (vars, nodup_TVars (tvars, T))
   539       | Free (a, T) => (vars, nodup_TVars (tvars, T))
   540       | Var (v as (ixn, T)) =>
   541           (case assoc_string_int (vars, ixn) of
   542             Some T' =>
   543               if T = T' then (vars, nodup_TVars (tvars, T))
   544               else raise TYPE ("Variable " ^ Syntax.string_of_vname ixn ^
   545                 " has two distinct types", [T', T], [])
   546           | None => (v :: vars, tvars))
   547       | Bound _ => (vars, tvars)
   548       | Abs (_, T, t) => nodups vars (nodup_TVars (tvars, T)) t
   549       | s $ t =>
   550           let val (vars',tvars') = nodups vars tvars s in
   551             nodups vars' tvars' t
   552           end);
   553   in nodups [] [] tm; () end;
   554 
   555 
   556 fun mapfilt_atoms f (Abs (_, _, t)) = mapfilt_atoms f t
   557   | mapfilt_atoms f (t $ u) = mapfilt_atoms f t @ mapfilt_atoms f u
   558   | mapfilt_atoms f a = (case f a of Some y => [y] | None => []);
   559 
   560 
   561 fun certify_term sg tm =
   562   let
   563     val _ = check_stale sg;
   564     val tsig = tsig_of sg;
   565 
   566     fun show_const a T = quote a ^ " :: " ^ quote (string_of_typ sg T);
   567 
   568     fun atom_err (Const (a, T)) =
   569         (case const_type sg a of
   570           None => Some ("Undeclared constant " ^ show_const a T)
   571         | Some U =>
   572             if Type.typ_instance (tsig, T, U) then None
   573             else Some ("Illegal type for constant " ^ show_const a T))
   574       | atom_err (Var ((x, i), _)) =
   575           if i < 0 then Some ("Negative index for Var " ^ quote x) else None
   576       | atom_err _ = None;
   577 
   578     val norm_tm =
   579       (case it_term_types (Type.typ_errors tsig) (tm, []) of
   580         [] => map_term_types (Type.norm_typ tsig) tm
   581       | errs => raise TYPE (cat_lines errs, [], [tm]));
   582     val _ = nodup_Vars norm_tm;
   583   in
   584     (case mapfilt_atoms atom_err norm_tm of
   585       [] => (norm_tm, type_of norm_tm, maxidx_of_term norm_tm)
   586     | errs => raise TYPE (cat_lines errs, [], [norm_tm]))
   587   end;
   588 
   589 
   590 
   591 (** infer_types **)         (*exception ERROR*)
   592 
   593 (*
   594   def_type: partial map from indexnames to types (constrains Frees, Vars)
   595   def_sort: partial map from indexnames to sorts (constrains TFrees, TVars)
   596   used: list of already used type variables
   597   freeze: if true then generated parameters are turned into TFrees, else TVars
   598 
   599   termss: lists of alternative parses (only one combination should be type-correct)
   600   typs: expected types
   601 *)
   602 
   603 fun infer_types_simult sg def_type def_sort used freeze args =
   604   let
   605     val tsig = tsig_of sg;
   606     val prt =
   607       setmp Syntax.show_brackets true
   608         (setmp long_names true (pretty_term sg));
   609     val prT = setmp long_names true (pretty_typ sg);
   610 
   611     val termss = foldr multiply (map fst args, [[]]);
   612     val typs =
   613       map (fn (_, T) => certify_typ sg T handle TYPE (msg, _, _) => error msg) args;
   614 
   615     fun infer ts = OK
   616       (Type.infer_types prt prT tsig (const_type sg) def_type def_sort
   617         (intern_const sg) (intern_tycons sg) (intern_sort sg) used freeze typs ts)
   618       handle TYPE (msg, _, _) => Error msg;
   619 
   620     val err_results = map infer termss;
   621     val errs = mapfilter get_error err_results;
   622     val results = mapfilter get_ok err_results;
   623 
   624     val ambiguity = length termss;	(* FIXME !? *)
   625     (* FIXME to syntax.ML!? *)
   626     fun ambig_msg () =
   627       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   628       then
   629         error_msg "Got more than one parse tree.\n\
   630           \Retry with smaller Syntax.ambiguity_level for more information."
   631       else ();
   632   in
   633     if null results then (ambig_msg (); error (cat_lines errs))
   634     else if length results = 1 then
   635       (if ambiguity > ! Syntax.ambiguity_level then
   636         warning "Fortunately, only one parse tree is type correct.\n\
   637           \You may still want to disambiguate your grammar or your input."
   638       else (); hd results)
   639     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   640       (cat_lines (map (Pretty.string_of o prt) (flat (map fst results))))))
   641   end;
   642 
   643 
   644 fun infer_types sg def_type def_sort used freeze tsT =
   645   apfst hd (infer_types_simult sg def_type def_sort used freeze [tsT]);
   646 
   647 
   648 
   649 (** extend signature **)    (*exception ERROR*)
   650 
   651 (** signature extension functions **)  (*exception ERROR*)
   652 
   653 fun decls_of path name_of mfixs =
   654   map (fn (x, y, mx) => (full path (name_of x mx), y)) mfixs;
   655 
   656 fun no_read _ _ _ decl = decl;
   657 
   658 
   659 (* add default sort *)
   660 
   661 fun ext_defsort int (syn, tsig, ctab, (path, spaces), data) S =
   662   (syn, Type.ext_tsig_defsort tsig (if int then intrn_sort spaces S else S),
   663     ctab, (path, spaces), data);
   664 
   665 
   666 (* add type constructors *)
   667 
   668 fun ext_types (syn, tsig, ctab, (path, spaces), data) types =
   669   let val decls = decls_of path Syntax.type_name types in
   670     (Syntax.extend_type_gram syn types,
   671       Type.ext_tsig_types tsig decls, ctab,
   672       (path, add_names spaces typeK (map fst decls)), data)
   673   end;
   674 
   675 
   676 (* add type abbreviations *)
   677 
   678 fun read_abbr syn tsig spaces (t, vs, rhs_src) =
   679   (t, vs, rd_raw_typ syn tsig spaces (K None) rhs_src)
   680     handle ERROR => error ("in type abbreviation " ^ t);
   681 
   682 fun ext_abbrs rd_abbr (syn, tsig, ctab, (path, spaces), data) abbrs =
   683   let
   684     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   685     val syn' = Syntax.extend_type_gram syn (map mfix_of abbrs);
   686 
   687     val abbrs' =
   688       map (fn (t, vs, rhs, mx) =>
   689         (full path (Syntax.type_name t mx), vs, rhs)) abbrs;
   690     val spaces' = add_names spaces typeK (map #1 abbrs');
   691     val decls = map (rd_abbr syn' tsig spaces') abbrs';
   692   in
   693     (syn', Type.ext_tsig_abbrs tsig decls, ctab, (path, spaces'), data)
   694   end;
   695 
   696 fun ext_tyabbrs abbrs = ext_abbrs read_abbr abbrs;
   697 fun ext_tyabbrs_i abbrs = ext_abbrs no_read abbrs;
   698 
   699 
   700 (* add type arities *)
   701 
   702 fun ext_arities int (syn, tsig, ctab, (path, spaces), data) arities =
   703   let
   704     fun intrn_arity (c, Ss, S) =
   705       (intrn spaces typeK c, map (intrn_sort spaces) Ss, intrn_sort spaces S);
   706     val intrn = if int then map intrn_arity else I;
   707     val tsig' = Type.ext_tsig_arities tsig (intrn arities);
   708     val log_types = Type.logical_types tsig';
   709   in
   710     (Syntax.extend_log_types syn log_types, tsig', ctab, (path, spaces), data)
   711   end;
   712 
   713 
   714 (* add term constants and syntax *)
   715 
   716 fun const_name path c mx =
   717   full path (Syntax.const_name c mx);
   718 
   719 fun err_in_const c =
   720   error ("in declaration of constant " ^ quote c);
   721 
   722 fun err_dup_consts cs =
   723   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   724 
   725 
   726 fun read_const syn tsig (path, spaces) (c, ty_src, mx) =
   727   (c, rd_raw_typ syn tsig spaces (K None) ty_src, mx)
   728     handle ERROR => err_in_const (const_name path c mx);
   729 
   730 fun ext_cnsts rd_const syn_only prmode (syn, tsig, ctab, (path, spaces), data) raw_consts =
   731   let
   732     fun prep_const (c, ty, mx) =
   733       (c, compress_type (Type.varifyT (Type.cert_typ tsig (Type.no_tvars ty))), mx)
   734         handle TYPE (msg, _, _) =>
   735           (error_msg msg; err_in_const (const_name path c mx));
   736 
   737     val consts = map (prep_const o rd_const syn tsig (path, spaces)) raw_consts;
   738     val decls =
   739       if syn_only then []
   740       else decls_of path Syntax.const_name consts;
   741   in
   742     (Syntax.extend_const_gram syn prmode consts, tsig,
   743       Symtab.extend (ctab, decls)
   744         handle Symtab.DUPS cs => err_dup_consts cs,
   745       (path, add_names spaces constK (map fst decls)), data)
   746   end;
   747 
   748 fun ext_consts_i sg = ext_cnsts no_read false ("", true) sg;
   749 fun ext_consts sg = ext_cnsts read_const false ("", true) sg;
   750 fun ext_syntax_i sg = ext_cnsts no_read true ("", true) sg;
   751 fun ext_syntax sg = ext_cnsts read_const true ("", true) sg;
   752 fun ext_modesyntax_i sg (prmode, consts) = ext_cnsts no_read true prmode sg consts;
   753 fun ext_modesyntax sg (prmode, consts) = ext_cnsts read_const true prmode sg consts;
   754 
   755 
   756 (* add type classes *)
   757 
   758 fun const_of_class c = c ^ "_class";
   759 
   760 fun class_of_const c_class =
   761   let
   762     val c = implode (take (size c_class - size "_class", explode c_class));
   763   in
   764     if const_of_class c = c_class then c
   765     else raise TERM ("class_of_const: bad name " ^ quote c_class, [])
   766   end;
   767 
   768 
   769 fun ext_classes int (syn, tsig, ctab, (path, spaces), data) classes =
   770   let
   771     val names = map fst classes;
   772     val consts =
   773       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   774 
   775     val full_names = map (full path) names;
   776     val spaces' = add_names spaces classK full_names;
   777     val intrn = if int then map (intrn_class spaces') else I;
   778     val classes' =
   779       ListPair.map (fn (c, (_, cs)) => (c, intrn cs)) (full_names, classes);
   780   in
   781     ext_consts_i
   782       (Syntax.extend_consts syn names,
   783         Type.ext_tsig_classes tsig classes', ctab, (path, spaces'), data)
   784     consts
   785   end;
   786 
   787 
   788 (* add to classrel *)
   789 
   790 fun ext_classrel int (syn, tsig, ctab, (path, spaces), data) pairs =
   791   let val intrn = if int then map (pairself (intrn_class spaces)) else I in
   792     (syn, Type.ext_tsig_classrel tsig (intrn pairs), ctab, (path, spaces), data)
   793   end;
   794 
   795 
   796 (* add to syntax *)
   797 
   798 fun ext_syn extfun (syn, tsig, ctab, names, data) args =
   799   (extfun syn args, tsig, ctab, names, data);
   800 
   801 
   802 (* add to path *)
   803 
   804 fun ext_path (syn, tsig, ctab, (path, spaces), data) elem =
   805   let
   806     val path' =
   807       if elem = ".." andalso not (null path) then fst (split_last path)
   808       else if elem = "/" then []
   809       else path @ NameSpace.unpack elem;
   810   in
   811     (syn, tsig, ctab, (path', spaces), data)
   812   end;      
   813 
   814 
   815 (* add to name space *)
   816 
   817 fun ext_space (syn, tsig, ctab, (path, spaces), data) (kind, names) =
   818   (syn, tsig, ctab, (path, add_names spaces kind names), data);
   819 
   820 
   821 (* signature data *)
   822 
   823 fun ext_init_data sg (syn, tsig, ctab, names, data) (kind, (e, ext, mrg, prt)) =
   824   (syn, tsig, ctab, names, init_data_sg sg data kind e ext mrg prt);
   825 
   826 fun ext_put_data sg (syn, tsig, ctab, names, data) (kind, e) =
   827   (syn, tsig, ctab, names, put_data_sg sg data kind e);
   828 
   829 
   830 (* the external interfaces *)
   831 
   832 val add_classes      = extend_sign true (ext_classes true) "#";
   833 val add_classes_i    = extend_sign true (ext_classes false) "#";
   834 val add_classrel     = extend_sign true (ext_classrel true) "#";
   835 val add_classrel_i   = extend_sign true (ext_classrel false) "#";
   836 val add_defsort      = extend_sign true (ext_defsort true) "#";
   837 val add_defsort_i    = extend_sign true (ext_defsort false) "#";
   838 val add_types        = extend_sign true ext_types "#";
   839 val add_tyabbrs      = extend_sign true ext_tyabbrs "#";
   840 val add_tyabbrs_i    = extend_sign true ext_tyabbrs_i "#";
   841 val add_arities      = extend_sign true (ext_arities true) "#";
   842 val add_arities_i    = extend_sign true (ext_arities false) "#";
   843 val add_consts       = extend_sign true ext_consts "#";
   844 val add_consts_i     = extend_sign true ext_consts_i "#";
   845 val add_syntax       = extend_sign true ext_syntax "#";
   846 val add_syntax_i     = extend_sign true ext_syntax_i "#";
   847 val add_modesyntax   = extend_sign true ext_modesyntax "#";
   848 val add_modesyntax_i = extend_sign true ext_modesyntax_i "#";
   849 val add_trfuns       = extend_sign true (ext_syn Syntax.extend_trfuns) "#";
   850 val add_trfunsT      = extend_sign true (ext_syn Syntax.extend_trfunsT) "#";
   851 val add_tokentrfuns  = extend_sign true (ext_syn Syntax.extend_tokentrfuns) "#";
   852 val add_trrules      = extend_sign true (ext_syn Syntax.extend_trrules) "#";
   853 val add_trrules_i    = extend_sign true (ext_syn Syntax.extend_trrules_i) "#";
   854 val add_path         = extend_sign true ext_path "#";
   855 val add_space        = extend_sign true ext_space "#";
   856 fun init_data arg sg = extend_sign true (ext_init_data sg) "#" arg sg;
   857 fun put_data arg sg  = extend_sign true (ext_put_data sg) "#" arg sg;
   858 fun add_name name sg = extend_sign true K name () sg;
   859 fun prep_ext sg      = extend_sign false K "#" () sg;
   860 
   861 
   862 
   863 (** merge signatures **)    	(*exception TERM*)
   864 
   865 (* merge_stamps *)
   866 
   867 fun merge_stamps stamps1 stamps2 =
   868   let val stamps = merge_rev_lists stamps1 stamps2 in
   869     (case duplicates (map ! stamps) of
   870       [] => stamps
   871     | dups => raise TERM ("Attempt to merge different versions of theories "
   872         ^ commas_quote dups, []))
   873   end;
   874 
   875 
   876 (* merge of sg_refs -- trivial only *)
   877 
   878 fun merge_refs (sgr1 as SgRef (Some (ref (sg1 as Sg ({stamps = s1, ...}, _)))),
   879         sgr2 as SgRef (Some (ref (sg2 as Sg ({stamps = s2, ...}, _))))) =
   880       if fast_subsig (sg2, sg1) then sgr1
   881       else if fast_subsig (sg1, sg2) then sgr2
   882       else if subsig (sg2, sg1) then sgr1
   883       else if subsig (sg1, sg2) then sgr2
   884       else (merge_stamps s1 s2; (*check for different versions*)
   885         raise TERM ("Attempt to do non-trivial merge of signatures", []))
   886   | merge_refs _ = sys_error "Sign.merge_refs";
   887 
   888 
   889 (* proper merge *)
   890 
   891 fun merge_aux (sg1, sg2) =
   892   if subsig (sg2, sg1) then sg1
   893   else if subsig (sg1, sg2) then sg2
   894   else if is_draft sg1 orelse is_draft sg2 then
   895     raise TERM ("Attempt to merge draft signatures", [])
   896   else
   897     (*neither is union already; must form union*)
   898     let
   899       val Sg ({id = _, stamps = stamps1}, {self = _, tsig = tsig1, const_tab = const_tab1,
   900         syn = syn1, path = _, spaces = spaces1, data = data1}) = sg1;
   901       val Sg ({id = _, stamps = stamps2}, {self = _, tsig = tsig2, const_tab = const_tab2,
   902         syn = syn2, path = _, spaces = spaces2, data = data2}) = sg2;
   903 
   904       val id = ref "";
   905       val self_ref = ref sg1;                   (*dummy value*)
   906       val self = SgRef (Some self_ref);
   907 
   908       val stamps = merge_stamps stamps1 stamps2;
   909       val tsig = Type.merge_tsigs (tsig1, tsig2);
   910       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
   911         handle Symtab.DUPS cs =>
   912           raise TERM ("Incompatible types for constant(s) " ^ commas_quote cs, []);
   913       val syn = Syntax.merge_syntaxes syn1 syn2;
   914 
   915       val path = [];
   916       val kinds = distinct (map fst (spaces1 @ spaces2));
   917       val spaces =
   918         kinds ~~
   919           ListPair.map NameSpace.merge
   920             (map (space_of spaces1) kinds, map (space_of spaces2) kinds);
   921 
   922       val data = merge_data (data1, data2);
   923 
   924       val sign = make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps);
   925     in
   926       self_ref := sign; sign
   927     end;
   928 
   929 fun merge sg1_sg2 =
   930   (case handle_error merge_aux sg1_sg2 of
   931     OK sg => sg
   932   | Error msg => raise TERM (msg, []));
   933 
   934 
   935 
   936 (** partial Pure signature **)
   937 
   938 val dummy_sg = make_sign (ref "", SgRef None, Type.tsig0,
   939   Symtab.empty, Syntax.pure_syn, [], [], empty_data, []);
   940 
   941 val pre_pure =
   942   create_sign (SgRef (Some (ref dummy_sg))) [] "#"
   943     (Syntax.pure_syn, Type.tsig0, Symtab.empty, ([], []), empty_data);
   944 
   945 
   946 end;
   947 
   948 
   949 val long_names = Sign.long_names;