src/Pure/sign.ML
author wenzelm
Sat Oct 20 18:54:30 2007 +0200 (2007-10-20)
changeset 25117 74b279146ecb
parent 25071 6680bebdfc28
child 25323 50d4c8257d06
permissions -rw-r--r--
no_variables: tuned error msg;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_trfuns:
    27     (string * (ast list -> ast)) list *
    28     (string * (term list -> term)) list *
    29     (string * (term list -> term)) list *
    30     (string * (ast list -> ast)) list -> theory -> theory
    31   val add_trfunsT:
    32     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    33   val add_advanced_trfuns:
    34     (string * (Proof.context -> ast list -> ast)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> term list -> term)) list *
    37     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    38   val add_advanced_trfunsT:
    39     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    40   val add_tokentrfuns:
    41     (string * string * (string -> output * int)) list -> theory -> theory
    42   val add_mode_tokentrfuns: string -> (string * (string -> output * int)) list
    43     -> theory -> theory
    44   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    46   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    48   val add_path: string -> theory -> theory
    49   val parent_path: theory -> theory
    50   val root_path: theory -> theory
    51   val absolute_path: theory -> theory
    52   val local_path: theory -> theory
    53   val no_base_names: theory -> theory
    54   val qualified_names: theory -> theory
    55   val sticky_prefix: string -> theory -> theory
    56   val restore_naming: theory -> theory -> theory
    57 end
    58 
    59 signature SIGN =
    60 sig
    61   val rep_sg: theory ->
    62    {naming: NameSpace.naming,
    63     syn: Syntax.syntax,
    64     tsig: Type.tsig,
    65     consts: Consts.T}
    66   val naming_of: theory -> NameSpace.naming
    67   val base_name: string -> bstring
    68   val full_name: theory -> bstring -> string
    69   val full_name_path: theory -> string -> bstring -> string
    70   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    71   val syn_of: theory -> Syntax.syntax
    72   val tsig_of: theory -> Type.tsig
    73   val classes_of: theory -> Sorts.algebra
    74   val all_classes: theory -> class list
    75   val super_classes: theory -> class -> class list
    76   val minimize_sort: theory -> sort -> sort
    77   val complete_sort: theory -> sort -> sort
    78   val defaultS: theory -> sort
    79   val subsort: theory -> sort * sort -> bool
    80   val of_sort: theory -> typ * sort -> bool
    81   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    82   val universal_witness: theory -> (typ * sort) option
    83   val all_sorts_nonempty: theory -> bool
    84   val is_logtype: theory -> string -> bool
    85   val typ_instance: theory -> typ * typ -> bool
    86   val typ_equiv: theory -> typ * typ -> bool
    87   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    88   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    89   val consts_of: theory -> Consts.T
    90   val the_const_constraint: theory -> string -> typ
    91   val const_type: theory -> string -> typ option
    92   val the_const_type: theory -> string -> typ
    93   val declared_tyname: theory -> string -> bool
    94   val declared_const: theory -> string -> bool
    95   val const_monomorphic: theory -> string -> bool
    96   val const_syntax_name: theory -> string -> string
    97   val const_typargs: theory -> string * typ -> typ list
    98   val const_instance: theory -> string * typ list -> typ
    99   val class_space: theory -> NameSpace.T
   100   val type_space: theory -> NameSpace.T
   101   val const_space: theory -> NameSpace.T
   102   val intern_class: theory -> xstring -> string
   103   val extern_class: theory -> string -> xstring
   104   val intern_type: theory -> xstring -> string
   105   val extern_type: theory -> string -> xstring
   106   val intern_const: theory -> xstring -> string
   107   val extern_const: theory -> string -> xstring
   108   val intern_sort: theory -> sort -> sort
   109   val extern_sort: theory -> sort -> sort
   110   val intern_typ: theory -> typ -> typ
   111   val extern_typ: theory -> typ -> typ
   112   val intern_term: theory -> term -> term
   113   val extern_term: (string -> xstring) -> theory -> term -> term
   114   val intern_tycons: theory -> typ -> typ
   115   val pretty_term: theory -> term -> Pretty.T
   116   val pretty_typ: theory -> typ -> Pretty.T
   117   val pretty_sort: theory -> sort -> Pretty.T
   118   val string_of_term: theory -> term -> string
   119   val string_of_typ: theory -> typ -> string
   120   val string_of_sort: theory -> sort -> string
   121   val pp: theory -> Pretty.pp
   122   val arity_number: theory -> string -> int
   123   val arity_sorts: theory -> string -> sort -> sort list
   124   val certify_class: theory -> class -> class
   125   val certify_sort: theory -> sort -> sort
   126   val certify_typ: theory -> typ -> typ
   127   val certify_typ_mode: Type.mode -> theory -> typ -> typ
   128   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
   129   val certify_term: theory -> term -> term * typ * int
   130   val certify_prop: theory -> term -> term * typ * int
   131   val cert_term: theory -> term -> term
   132   val cert_prop: theory -> term -> term
   133   val no_frees: Pretty.pp -> term -> term
   134   val no_vars: Pretty.pp -> term -> term
   135   val cert_def: Proof.context -> term -> (string * typ) * term
   136   val read_class: theory -> xstring -> class
   137   val read_arity: theory -> xstring * string list * string -> arity
   138   val cert_arity: theory -> arity -> arity
   139   val get_sort: theory ->
   140     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   141   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   142   val read_typ: theory -> string -> typ
   143   val read_typ_syntax: theory -> string -> typ
   144   val read_typ_abbrev: theory -> string -> typ
   145   val read_tyname: theory -> string -> typ
   146   val read_const: theory -> string -> term
   147   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   148     (string -> string option) -> Proof.context ->
   149     (indexname -> typ option) * (indexname -> sort option) ->
   150     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   151   val read_def_terms:
   152     theory * (indexname -> typ option) * (indexname -> sort option) ->
   153     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   154   val simple_read_term: theory -> typ -> string -> term
   155   val read_term: theory -> string -> term
   156   val read_prop: theory -> string -> term
   157   val declare_const: Markup.property list -> bstring * typ * mixfix -> theory -> term * theory
   158   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
   159   val add_abbrev: string -> Markup.property list ->
   160     bstring * term -> theory -> (term * term) * theory
   161   val revert_abbrev: string -> string -> theory -> theory
   162   include SIGN_THEORY
   163   val add_const_constraint: string * typ option -> theory -> theory
   164   val primitive_class: string * class list -> theory -> theory
   165   val primitive_classrel: class * class -> theory -> theory
   166   val primitive_arity: arity -> theory -> theory
   167   val hide_classes: bool -> xstring list -> theory -> theory
   168   val hide_classes_i: bool -> string list -> theory -> theory
   169   val hide_types: bool -> xstring list -> theory -> theory
   170   val hide_types_i: bool -> string list -> theory -> theory
   171   val hide_consts: bool -> xstring list -> theory -> theory
   172   val hide_consts_i: bool -> string list -> theory -> theory
   173   val hide_names: bool -> string * xstring list -> theory -> theory
   174   val hide_names_i: bool -> string * string list -> theory -> theory
   175 end
   176 
   177 structure Sign: SIGN =
   178 struct
   179 
   180 (** datatype sign **)
   181 
   182 datatype sign = Sign of
   183  {naming: NameSpace.naming,     (*common naming conventions*)
   184   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   185   tsig: Type.tsig,              (*order-sorted signature of types*)
   186   consts: Consts.T};            (*polymorphic constants*)
   187 
   188 fun make_sign (naming, syn, tsig, consts) =
   189   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   190 
   191 structure SignData = TheoryDataFun
   192 (
   193   type T = sign;
   194   val copy = I;
   195   fun extend (Sign {syn, tsig, consts, ...}) =
   196     make_sign (NameSpace.default_naming, syn, tsig, consts);
   197 
   198   val empty =
   199     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   200 
   201   fun merge pp (sign1, sign2) =
   202     let
   203       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   204       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   205 
   206       val naming = NameSpace.default_naming;
   207       val syn = Syntax.merge_syntaxes syn1 syn2;
   208       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   209       val consts = Consts.merge (consts1, consts2);
   210     in make_sign (naming, syn, tsig, consts) end;
   211 );
   212 
   213 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   214 
   215 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   216   make_sign (f (naming, syn, tsig, consts)));
   217 
   218 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   219 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   220 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   221 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   222 
   223 
   224 (* naming *)
   225 
   226 val naming_of = #naming o rep_sg;
   227 val base_name = NameSpace.base;
   228 val full_name = NameSpace.full o naming_of;
   229 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   230 val declare_name = NameSpace.declare o naming_of;
   231 
   232 
   233 (* syntax *)
   234 
   235 val syn_of = #syn o rep_sg;
   236 
   237 
   238 (* type signature *)
   239 
   240 val tsig_of = #tsig o rep_sg;
   241 
   242 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   243 val all_classes = Sorts.all_classes o classes_of;
   244 val minimal_classes = Sorts.minimal_classes o classes_of;
   245 val super_classes = Sorts.super_classes o classes_of;
   246 val minimize_sort = Sorts.minimize_sort o classes_of;
   247 val complete_sort = Sorts.complete_sort o classes_of;
   248 
   249 val defaultS = Type.defaultS o tsig_of;
   250 val subsort = Type.subsort o tsig_of;
   251 val of_sort = Type.of_sort o tsig_of;
   252 val witness_sorts = Type.witness_sorts o tsig_of;
   253 val universal_witness = Type.universal_witness o tsig_of;
   254 val all_sorts_nonempty = is_some o universal_witness;
   255 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   256 
   257 val typ_instance = Type.typ_instance o tsig_of;
   258 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   259 val typ_match = Type.typ_match o tsig_of;
   260 val typ_unify = Type.unify o tsig_of;
   261 
   262 
   263 (* polymorphic constants *)
   264 
   265 val consts_of = #consts o rep_sg;
   266 val the_const_constraint = Consts.the_constraint o consts_of;
   267 val the_const_type = Consts.the_type o consts_of;
   268 val const_type = try o the_const_type;
   269 val const_monomorphic = Consts.is_monomorphic o consts_of;
   270 val const_syntax_name = Consts.syntax_name o consts_of;
   271 val const_typargs = Consts.typargs o consts_of;
   272 val const_instance = Consts.instance o consts_of;
   273 
   274 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   275 val declared_const = can o the_const_constraint;
   276 
   277 
   278 
   279 (** intern / extern names **)
   280 
   281 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   282 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   283 val const_space = Consts.space_of o consts_of;
   284 
   285 val intern_class = NameSpace.intern o class_space;
   286 val extern_class = NameSpace.extern o class_space;
   287 val intern_type = NameSpace.intern o type_space;
   288 val extern_type = NameSpace.extern o type_space;
   289 val intern_const = NameSpace.intern o const_space;
   290 val extern_const = NameSpace.extern o const_space;
   291 
   292 val intern_sort = map o intern_class;
   293 val extern_sort = map o extern_class;
   294 
   295 local
   296 
   297 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   298   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   299   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   300 
   301 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   302   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   303   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   304   | map_term _ _ _ (t as Bound _) = t
   305   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   306   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   307 
   308 val add_classesT = Term.fold_atyps
   309   (fn TFree (_, S) => fold (insert (op =)) S
   310     | TVar (_, S) => fold (insert (op =)) S
   311     | _ => I);
   312 
   313 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   314   | add_tyconsT _ = I;
   315 
   316 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   317 
   318 fun mapping add_names f t =
   319   let
   320     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   321     val tab = map_filter f' (add_names t []);
   322     fun get x = the_default x (AList.lookup (op =) tab x);
   323   in get end;
   324 
   325 fun typ_mapping f g thy T =
   326   T |> map_typ
   327     (mapping add_classesT (f thy) T)
   328     (mapping add_tyconsT (g thy) T);
   329 
   330 fun term_mapping f g h thy t =
   331   t |> map_term
   332     (mapping (Term.fold_types add_classesT) (f thy) t)
   333     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   334     (mapping add_consts (h thy) t);
   335 
   336 in
   337 
   338 val intern_typ = typ_mapping intern_class intern_type;
   339 val extern_typ = typ_mapping extern_class extern_type;
   340 val intern_term = term_mapping intern_class intern_type intern_const;
   341 fun extern_term h = term_mapping extern_class extern_type (K h);
   342 val intern_tycons = typ_mapping (K I) intern_type;
   343 
   344 end;
   345 
   346 
   347 
   348 (** pretty printing of terms, types etc. **)
   349 
   350 val pretty_term = Syntax.pretty_term o ProofContext.init;
   351 val pretty_typ = Syntax.pretty_typ o ProofContext.init;
   352 val pretty_sort = Syntax.pretty_sort o ProofContext.init;
   353 
   354 val string_of_term = Syntax.string_of_term o ProofContext.init;
   355 val string_of_typ = Syntax.string_of_typ o ProofContext.init;
   356 val string_of_sort = Syntax.string_of_sort o ProofContext.init;
   357 
   358 (*pp operations -- deferred evaluation*)
   359 fun pp thy = Pretty.pp
   360  (fn x => pretty_term thy x,
   361   fn x => pretty_typ thy x,
   362   fn x => pretty_sort thy x,
   363   fn x => Syntax.pretty_classrel (ProofContext.init thy) x,
   364   fn x => Syntax.pretty_arity (ProofContext.init thy) x);
   365 
   366 
   367 
   368 (** certify entities **)    (*exception TYPE*)
   369 
   370 (* certify wrt. type signature *)
   371 
   372 val arity_number = Type.arity_number o tsig_of;
   373 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   374 
   375 val certify_class         = Type.cert_class o tsig_of;
   376 val certify_sort          = Type.cert_sort o tsig_of;
   377 val certify_typ           = Type.cert_typ o tsig_of;
   378 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   379 
   380 
   381 (* certify term/prop *)
   382 
   383 local
   384 
   385 fun type_check pp tm =
   386   let
   387     fun err_appl why bs t T u U =
   388       let
   389         val xs = map Free bs;           (*we do not rename here*)
   390         val t' = subst_bounds (xs, t);
   391         val u' = subst_bounds (xs, u);
   392         val msg = cat_lines
   393           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   394       in raise TYPE (msg, [T, U], [t', u']) end;
   395 
   396     fun typ_of (_, Const (_, T)) = T
   397       | typ_of (_, Free  (_, T)) = T
   398       | typ_of (_, Var (_, T)) = T
   399       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   400           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   401       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   402       | typ_of (bs, t $ u) =
   403           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   404             (case T of
   405               Type ("fun", [T1, T2]) =>
   406                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   407             | _ => err_appl "Operator not of function type" bs t T u U)
   408           end;
   409   in typ_of ([], tm) end;
   410 
   411 fun err msg = raise TYPE (msg, [], []);
   412 
   413 fun check_vars (t $ u) = (check_vars t; check_vars u)
   414   | check_vars (Abs (_, _, t)) = check_vars t
   415   | check_vars (Var (xi as (_, i), _)) =
   416       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   417   | check_vars _ = ();
   418 
   419 in
   420 
   421 fun certify' prop pp do_expand consts thy tm =
   422   let
   423     val _ = check_vars tm;
   424     val tm' = Term.map_types (certify_typ thy) tm;
   425     val T = type_check pp tm';
   426     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   427     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   428   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   429 
   430 fun certify_term thy = certify' false (pp thy) true (consts_of thy) thy;
   431 fun certify_prop thy = certify' true (pp thy) true (consts_of thy) thy;
   432 
   433 fun cert_term_abbrev thy = #1 o certify' false (pp thy) false (consts_of thy) thy;
   434 val cert_term = #1 oo certify_term;
   435 val cert_prop = #1 oo certify_prop;
   436 
   437 end;
   438 
   439 
   440 (* specifications *)
   441 
   442 fun no_variables kind add addT mk mkT pp tm =
   443   (case (add tm [], addT tm []) of
   444     ([], []) => tm
   445   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   446       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   447        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   448 
   449 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   450 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   451 
   452 fun cert_def ctxt tm =
   453   let val ((lhs, rhs), _) = tm
   454     |> no_vars (Syntax.pp ctxt)
   455     |> Logic.strip_imp_concl
   456     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   457   in (Term.dest_Const (Term.head_of lhs), rhs) end
   458   handle TERM (msg, _) => error msg;
   459 
   460 
   461 
   462 (** read and certify entities **)    (*exception ERROR*)
   463 
   464 (* classes *)
   465 
   466 fun read_class thy c = certify_class thy (intern_class thy c)
   467   handle TYPE (msg, _, _) => error msg;
   468 
   469 
   470 (* type arities *)
   471 
   472 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   473   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   474   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   475 
   476 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   477 val cert_arity = prep_arity (K I) certify_sort;
   478 
   479 
   480 (* types *)
   481 
   482 fun get_sort thy def_sort raw_env =
   483   let
   484     val tsig = tsig_of thy;
   485 
   486     fun eq ((xi, S), (xi', S')) =
   487       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   488     val env = distinct eq raw_env;
   489     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   490       | dups => error ("Inconsistent sort constraints for type variable(s) "
   491           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   492 
   493     fun get xi =
   494       (case (AList.lookup (op =) env xi, def_sort xi) of
   495         (NONE, NONE) => Type.defaultS tsig
   496       | (NONE, SOME S) => S
   497       | (SOME S, NONE) => S
   498       | (SOME S, SOME S') =>
   499           if Type.eq_sort tsig (S, S') then S'
   500           else error ("Sort constraint inconsistent with default for type variable " ^
   501             quote (Term.string_of_vname' xi)));
   502   in get end;
   503 
   504 local
   505 
   506 fun gen_read_typ mode (thy, def_sort) str =
   507   let
   508     val ctxt = ProofContext.init thy;
   509     val syn = syn_of thy;
   510     val T = intern_tycons thy
   511       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   512   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   513   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   514 
   515 in
   516 
   517 fun no_def_sort thy = (thy: theory, K NONE);
   518 
   519 val read_def_typ     = gen_read_typ Type.mode_default;
   520 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   521 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   522 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   523 
   524 end;
   525 
   526 
   527 (* type and constant names *)
   528 
   529 fun read_tyname thy raw_c =
   530   let val c = intern_type thy raw_c
   531   in Type (c, replicate (arity_number thy c) dummyT) end;
   532 
   533 val read_const = Consts.read_const o consts_of;
   534 
   535 
   536 
   537 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   538 
   539 (*
   540   def_type: partial map from indexnames to types (constrains Frees and Vars)
   541   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   542   used: context of already used type variables
   543   freeze: if true then generated parameters are turned into TFrees, else TVars
   544 *)
   545 
   546 fun read_def_terms'
   547     pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze raw_args =
   548   let
   549     val thy = ProofContext.theory_of ctxt;
   550     fun check_typs Ts = map (certify_typ thy) Ts
   551       handle TYPE (msg, _, _) => error msg;
   552 
   553     fun infer args = TypeInfer.infer_types pp (tsig_of thy) check_typs
   554         (try (Consts.the_constraint consts)) def_type used ~1 (SOME freeze) args |>> map fst
   555       handle TYPE (msg, _, _) => error msg;
   556 
   557     fun check T t = Exn.Result (singleton (fst o infer) (t, T))
   558       handle ERROR msg => Exn.Exn (ERROR msg);
   559     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   560     fun read T = Syntax.standard_parse_term pp (check T) (get_sort thy def_sort) map_const map_free
   561         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn T;
   562   in
   563     raw_args
   564     |> map (fn (s, raw_T) =>
   565       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   566       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end)
   567     |> infer
   568   end;
   569 
   570 fun read_def_terms (thy, types, sorts) used freeze sTs =
   571   let
   572     val pp = pp thy;
   573     val consts = consts_of thy;
   574     val cert_consts = Consts.certify pp (tsig_of thy) true consts;
   575     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   576     val (ts, inst) =
   577       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   578         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   579   in (map cert_consts ts, inst) end;
   580 
   581 fun simple_read_term thy T s =
   582   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   583   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   584 
   585 fun read_term thy = simple_read_term thy dummyT;
   586 fun read_prop thy = simple_read_term thy propT;
   587 
   588 
   589 
   590 (** signature extension functions **)  (*exception ERROR/TYPE*)
   591 
   592 (* add default sort *)
   593 
   594 fun gen_add_defsort prep_sort s thy =
   595   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   596 
   597 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   598 val add_defsort_i = gen_add_defsort certify_sort;
   599 
   600 
   601 (* add type constructors *)
   602 
   603 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   604   let
   605     val syn' = Syntax.extend_type_gram types syn;
   606     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   607     val tsig' = Type.add_types naming decls tsig;
   608   in (naming, syn', tsig', consts) end);
   609 
   610 fun add_typedecls decls thy =
   611   let
   612     fun type_of (a, vs: string list, mx) =
   613       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   614       else error ("Duplicate parameters in type declaration: " ^ quote a);
   615   in add_types (map type_of decls) thy end;
   616 
   617 
   618 (* add nonterminals *)
   619 
   620 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   621   let
   622     val syn' = Syntax.extend_consts ns syn;
   623     val tsig' = Type.add_nonterminals naming ns tsig;
   624   in (naming, syn', tsig', consts) end);
   625 
   626 
   627 (* add type abbreviations *)
   628 
   629 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   630   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   631     let
   632       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   633       val a' = Syntax.type_name a mx;
   634       val abbr = (a', vs,
   635           certify_typ_mode Type.mode_syntax thy (prep_typ (ProofContext.init thy) rhs))
   636         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   637       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   638     in (naming, syn', tsig', consts) end);
   639 
   640 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   641 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   642 
   643 
   644 (* modify syntax *)
   645 
   646 fun gen_syntax change_gram prep_typ mode args thy =
   647   let
   648     fun prep (c, T, mx) = (c,
   649         certify_typ_mode Type.mode_syntax thy (prep_typ (ProofContext.init thy) T), mx)
   650       handle ERROR msg =>
   651         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   652   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   653 
   654 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   655 
   656 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   657 val add_modesyntax_i = gen_add_syntax (K I);
   658 val add_syntax = add_modesyntax Syntax.mode_default;
   659 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   660 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   661 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   662 
   663 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   664   | const_syntax _ _ = NONE;
   665 
   666 fun notation add mode args thy = thy
   667   |> (if add then add_modesyntax_i else del_modesyntax_i) mode (map_filter (const_syntax thy) args);
   668 
   669 
   670 (* add constants *)
   671 
   672 local
   673 
   674 fun gen_add_consts prep_typ authentic tags raw_args thy =
   675   let
   676     val prepT = Type.no_tvars o Term.no_dummyT o prep_typ thy;
   677     fun prep (raw_c, raw_T, raw_mx) =
   678       let
   679         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   680         val full_c = full_name thy c;
   681         val c' = if authentic then Syntax.constN ^ full_c else c;
   682         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   683           cat_error msg ("in declaration of constant " ^ quote c);
   684         val T' = Compress.typ thy (Logic.varifyT T);
   685       in ((c, T'), (c', T', mx), Const (full_c, T)) end;
   686     val args = map prep raw_args;
   687   in
   688     thy
   689     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags o #1) args)
   690     |> add_syntax_i (map #2 args)
   691     |> pair (map #3 args)
   692   end;
   693 
   694 in
   695 
   696 val add_consts = snd oo gen_add_consts read_typ false [];
   697 val add_consts_i = snd oo gen_add_consts certify_typ false [];
   698 
   699 fun declare_const tags arg = gen_add_consts certify_typ true tags [arg] #>> the_single;
   700 
   701 end;
   702 
   703 
   704 (* abbreviations *)
   705 
   706 fun add_abbrev mode tags (c, raw_t) thy =
   707   let
   708     val pp = pp thy;
   709     val prep_tm = Compress.term thy o no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   710     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   711       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   712     val (res, consts') = consts_of thy
   713       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (c, t);
   714   in (res, thy |> map_consts (K consts')) end;
   715 
   716 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   717 
   718 
   719 (* add constraints *)
   720 
   721 fun add_const_constraint (c, opt_T) thy =
   722   let
   723     fun prepT raw_T =
   724       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   725       in cert_term thy (Const (c, T)); T end
   726       handle TYPE (msg, _, _) => error msg;
   727   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   728 
   729 
   730 (* primitive classes and arities *)
   731 
   732 fun primitive_class (bclass, classes) thy =
   733   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   734     let
   735       val syn' = Syntax.extend_consts [bclass] syn;
   736       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   737     in (naming, syn', tsig', consts) end)
   738   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   739 
   740 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   741 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   742 
   743 
   744 (* add translation functions *)
   745 
   746 local
   747 
   748 fun mk trs = map Syntax.mk_trfun trs;
   749 
   750 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   751   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   752 
   753 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   754 
   755 in
   756 
   757 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   758 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   759 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   760 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   761 
   762 end;
   763 
   764 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   765 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   766 
   767 
   768 (* translation rules *)
   769 
   770 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   771   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   772   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   773 
   774 val add_trrules = gen_trrules Syntax.extend_trrules;
   775 val del_trrules = gen_trrules Syntax.remove_trrules;
   776 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   777 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   778 
   779 
   780 (* modify naming *)
   781 
   782 val add_path        = map_naming o NameSpace.add_path;
   783 val no_base_names   = map_naming NameSpace.no_base_names;
   784 val qualified_names = map_naming NameSpace.qualified_names;
   785 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   786 val restore_naming  = map_naming o K o naming_of;
   787 
   788 val parent_path   = add_path "..";
   789 val root_path     = add_path "/";
   790 val absolute_path = add_path "//";
   791 
   792 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   793 
   794 
   795 (* hide names *)
   796 
   797 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   798 val hide_classes_i = map_tsig oo Type.hide_classes;
   799 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   800 val hide_types_i = map_tsig oo Type.hide_types;
   801 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   802 val hide_consts_i = map_consts oo (fold o Consts.hide);
   803 
   804 local
   805 
   806 val kinds =
   807  [("class", (intern_class, can o certify_class, hide_classes_i)),
   808   ("type", (intern_type, declared_tyname, hide_types_i)),
   809   ("const", (intern_const, declared_const, hide_consts_i))];
   810 
   811 fun gen_hide int b (kind, xnames) thy =
   812   (case AList.lookup (op =) kinds kind of
   813     SOME (intern, check, hide) =>
   814       let
   815         val names = if int then map (intern thy) xnames else xnames;
   816         val bads = filter_out (check thy) names;
   817       in
   818         if null bads then hide b names thy
   819         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   820       end
   821   | NONE => error ("Bad name space specification: " ^ quote kind));
   822 
   823 in
   824 
   825 val hide_names = gen_hide true;
   826 val hide_names_i = gen_hide false;
   827 
   828 end;
   829 
   830 end;